src/HOL/Tools/Sledgehammer/clausifier.ML
author blanchet
Mon Aug 23 14:54:17 2010 +0200 (2010-08-23 ago)
changeset 38652 e063be321438
parent 38632 9cde57cdd0e3
child 38795 848be46708dc
permissions -rw-r--r--
perform eta-expansion of quantifier bodies in Sledgehammer translation when needed + transform elim rules later;
it's a mistake to transform the elim rules too early because then we lose some info, e.g. "no_atp" attributes
     1 (*  Title:      HOL/Tools/Sledgehammer/clausifier.ML
     2     Author:     Jia Meng, Cambridge University Computer Laboratory and NICTA
     3     Author:     Jasmin Blanchette, TU Muenchen
     4 
     5 Transformation of axiom rules (elim/intro/etc) into CNF forms.
     6 *)
     7 
     8 signature CLAUSIFIER =
     9 sig
    10   val extensionalize_theorem : thm -> thm
    11   val introduce_combinators_in_cterm : cterm -> thm
    12   val introduce_combinators_in_theorem : thm -> thm
    13   val cnf_axiom: theory -> thm -> thm list
    14 end;
    15 
    16 structure Clausifier : CLAUSIFIER =
    17 struct
    18 
    19 (**** Transformation of Elimination Rules into First-Order Formulas****)
    20 
    21 val cfalse = cterm_of @{theory HOL} HOLogic.false_const;
    22 val ctp_false = cterm_of @{theory HOL} (HOLogic.mk_Trueprop HOLogic.false_const);
    23 
    24 (* Converts an elim-rule into an equivalent theorem that does not have the
    25    predicate variable. Leaves other theorems unchanged. We simply instantiate
    26    the conclusion variable to False. (Cf. "transform_elim_term" in
    27    "Sledgehammer_Util".) *)
    28 fun transform_elim_theorem th =
    29   case concl_of th of    (*conclusion variable*)
    30        @{const Trueprop} $ (v as Var (_, @{typ bool})) =>
    31            Thm.instantiate ([], [(cterm_of @{theory HOL} v, cfalse)]) th
    32     | v as Var(_, @{typ prop}) =>
    33            Thm.instantiate ([], [(cterm_of @{theory HOL} v, ctp_false)]) th
    34     | _ => th
    35 
    36 (*To enforce single-threading*)
    37 exception Clausify_failure of theory;
    38 
    39 
    40 (**** SKOLEMIZATION BY INFERENCE (lcp) ****)
    41 
    42 fun mk_skolem_id t =
    43   let val T = fastype_of t in
    44     Const (@{const_name skolem_id}, T --> T) $ t
    45   end
    46 
    47 fun beta_eta_under_lambdas (Abs (s, T, t')) =
    48     Abs (s, T, beta_eta_under_lambdas t')
    49   | beta_eta_under_lambdas t = Envir.beta_eta_contract t
    50 
    51 (*Traverse a theorem, accumulating Skolem function definitions.*)
    52 fun assume_skolem_funs th =
    53   let
    54     fun dec_sko (Const (@{const_name Ex}, _) $ (body as Abs (s', T, p))) rhss =
    55         (*Existential: declare a Skolem function, then insert into body and continue*)
    56         let
    57           val args = OldTerm.term_frees body
    58           val Ts = map type_of args
    59           val cT = Ts ---> T
    60           (* Forms a lambda-abstraction over the formal parameters *)
    61           val rhs =
    62             list_abs_free (map dest_Free args,
    63                            HOLogic.choice_const T $ beta_eta_under_lambdas body)
    64             |> mk_skolem_id
    65           val comb = list_comb (rhs, args)
    66         in dec_sko (subst_bound (comb, p)) (rhs :: rhss) end
    67       | dec_sko (Const (@{const_name All},_) $ Abs (a, T, p)) rhss =
    68         (*Universal quant: insert a free variable into body and continue*)
    69         let val fname = Name.variant (OldTerm.add_term_names (p,[])) a
    70         in dec_sko (subst_bound (Free(fname,T), p)) rhss end
    71       | dec_sko (@{const "op &"} $ p $ q) rhss = rhss |> dec_sko p |> dec_sko q
    72       | dec_sko (@{const "op |"} $ p $ q) rhss = rhss |> dec_sko p |> dec_sko q
    73       | dec_sko (@{const Trueprop} $ p) rhss = dec_sko p rhss
    74       | dec_sko _ rhss = rhss
    75   in  dec_sko (prop_of th) []  end;
    76 
    77 
    78 (**** REPLACING ABSTRACTIONS BY COMBINATORS ****)
    79 
    80 val fun_cong_all = @{thm expand_fun_eq [THEN iffD1]}
    81 
    82 (* Removes the lambdas from an equation of the form "t = (%x. u)".
    83    (Cf. "extensionalize_term" in "Sledgehammer_Translate".) *)
    84 fun extensionalize_theorem th =
    85   case prop_of th of
    86     _ $ (Const (@{const_name "op ="}, Type (_, [Type (@{type_name fun}, _), _]))
    87          $ _ $ Abs (s, _, _)) => extensionalize_theorem (th RS fun_cong_all)
    88   | _ => th
    89 
    90 fun is_quasi_lambda_free (Const (@{const_name skolem_id}, _) $ _) = true
    91   | is_quasi_lambda_free (t1 $ t2) =
    92     is_quasi_lambda_free t1 andalso is_quasi_lambda_free t2
    93   | is_quasi_lambda_free (Abs _) = false
    94   | is_quasi_lambda_free _ = true
    95 
    96 val [f_B,g_B] = map (cterm_of @{theory}) (OldTerm.term_vars (prop_of @{thm abs_B}));
    97 val [g_C,f_C] = map (cterm_of @{theory}) (OldTerm.term_vars (prop_of @{thm abs_C}));
    98 val [f_S,g_S] = map (cterm_of @{theory}) (OldTerm.term_vars (prop_of @{thm abs_S}));
    99 
   100 (* FIXME: Requires more use of cterm constructors. *)
   101 fun abstract ct =
   102   let
   103       val thy = theory_of_cterm ct
   104       val Abs(x,_,body) = term_of ct
   105       val Type(@{type_name fun}, [xT,bodyT]) = typ_of (ctyp_of_term ct)
   106       val cxT = ctyp_of thy xT
   107       val cbodyT = ctyp_of thy bodyT
   108       fun makeK () =
   109         instantiate' [SOME cxT, SOME cbodyT] [SOME (cterm_of thy body)]
   110                      @{thm abs_K}
   111   in
   112       case body of
   113           Const _ => makeK()
   114         | Free _ => makeK()
   115         | Var _ => makeK()  (*though Var isn't expected*)
   116         | Bound 0 => instantiate' [SOME cxT] [] @{thm abs_I} (*identity: I*)
   117         | rator$rand =>
   118             if loose_bvar1 (rator,0) then (*C or S*)
   119                if loose_bvar1 (rand,0) then (*S*)
   120                  let val crator = cterm_of thy (Abs(x,xT,rator))
   121                      val crand = cterm_of thy (Abs(x,xT,rand))
   122                      val abs_S' = cterm_instantiate [(f_S,crator),(g_S,crand)] @{thm abs_S}
   123                      val (_,rhs) = Thm.dest_equals (cprop_of abs_S')
   124                  in
   125                    Thm.transitive abs_S' (Conv.binop_conv abstract rhs)
   126                  end
   127                else (*C*)
   128                  let val crator = cterm_of thy (Abs(x,xT,rator))
   129                      val abs_C' = cterm_instantiate [(f_C,crator),(g_C,cterm_of thy rand)] @{thm abs_C}
   130                      val (_,rhs) = Thm.dest_equals (cprop_of abs_C')
   131                  in
   132                    Thm.transitive abs_C' (Conv.fun_conv (Conv.arg_conv abstract) rhs)
   133                  end
   134             else if loose_bvar1 (rand,0) then (*B or eta*)
   135                if rand = Bound 0 then Thm.eta_conversion ct
   136                else (*B*)
   137                  let val crand = cterm_of thy (Abs(x,xT,rand))
   138                      val crator = cterm_of thy rator
   139                      val abs_B' = cterm_instantiate [(f_B,crator),(g_B,crand)] @{thm abs_B}
   140                      val (_,rhs) = Thm.dest_equals (cprop_of abs_B')
   141                  in Thm.transitive abs_B' (Conv.arg_conv abstract rhs) end
   142             else makeK()
   143         | _ => raise Fail "abstract: Bad term"
   144   end;
   145 
   146 (* Traverse a theorem, remplacing lambda-abstractions with combinators. *)
   147 fun introduce_combinators_in_cterm ct =
   148   if is_quasi_lambda_free (term_of ct) then
   149     Thm.reflexive ct
   150   else case term_of ct of
   151     Abs _ =>
   152     let
   153       val (cv, cta) = Thm.dest_abs NONE ct
   154       val (v, _) = dest_Free (term_of cv)
   155       val u_th = introduce_combinators_in_cterm cta
   156       val cu = Thm.rhs_of u_th
   157       val comb_eq = abstract (Thm.cabs cv cu)
   158     in Thm.transitive (Thm.abstract_rule v cv u_th) comb_eq end
   159   | _ $ _ =>
   160     let val (ct1, ct2) = Thm.dest_comb ct in
   161         Thm.combination (introduce_combinators_in_cterm ct1)
   162                         (introduce_combinators_in_cterm ct2)
   163     end
   164 
   165 fun introduce_combinators_in_theorem th =
   166   if is_quasi_lambda_free (prop_of th) then
   167     th
   168   else
   169     let
   170       val th = Drule.eta_contraction_rule th
   171       val eqth = introduce_combinators_in_cterm (cprop_of th)
   172     in Thm.equal_elim eqth th end
   173     handle THM (msg, _, _) =>
   174            (warning ("Error in the combinator translation of " ^
   175                      Display.string_of_thm_without_context th ^
   176                      "\nException message: " ^ msg ^ ".");
   177             (* A type variable of sort "{}" will make abstraction fail. *)
   178             TrueI)
   179 
   180 (*cterms are used throughout for efficiency*)
   181 val cTrueprop = cterm_of @{theory HOL} HOLogic.Trueprop;
   182 
   183 (*Given an abstraction over n variables, replace the bound variables by free
   184   ones. Return the body, along with the list of free variables.*)
   185 fun c_variant_abs_multi (ct0, vars) =
   186       let val (cv,ct) = Thm.dest_abs NONE ct0
   187       in  c_variant_abs_multi (ct, cv::vars)  end
   188       handle CTERM _ => (ct0, rev vars);
   189 
   190 val skolem_id_def_raw = @{thms skolem_id_def_raw}
   191 
   192 (* Given the definition of a Skolem function, return a theorem to replace
   193    an existential formula by a use of that function.
   194    Example: "EX x. x : A & x ~: B ==> sko A B : A & sko A B ~: B"  [.] *)
   195 fun skolem_theorem_of_def thy rhs0 =
   196   let
   197     val rhs = rhs0 |> Type.legacy_freeze_thaw |> #1 |> cterm_of thy
   198     val rhs' = rhs |> Thm.dest_comb |> snd
   199     val (ch, frees) = c_variant_abs_multi (rhs', [])
   200     val (hilbert, cabs) = ch |> Thm.dest_comb |>> term_of
   201     val T =
   202       case hilbert of
   203         Const (@{const_name Eps}, Type (@{type_name fun}, [_, T])) => T
   204       | _ => raise TERM ("skolem_theorem_of_def: expected \"Eps\"", [hilbert])
   205     val cex = cterm_of thy (HOLogic.exists_const T)
   206     val ex_tm = Thm.capply cTrueprop (Thm.capply cex cabs)
   207     val conc =
   208       Drule.list_comb (rhs, frees)
   209       |> Drule.beta_conv cabs |> Thm.capply cTrueprop
   210     fun tacf [prem] =
   211       rewrite_goals_tac skolem_id_def_raw
   212       THEN rtac ((prem |> rewrite_rule skolem_id_def_raw) RS @{thm someI_ex}) 1
   213   in
   214     Goal.prove_internal [ex_tm] conc tacf
   215     |> forall_intr_list frees
   216     |> Thm.forall_elim_vars 0  (*Introduce Vars, but don't discharge defs.*)
   217     |> Thm.varifyT_global
   218   end
   219 
   220 (* Converts an Isabelle theorem (intro, elim or simp format, even higher-order)
   221    into NNF. *)
   222 fun to_nnf th ctxt0 =
   223   let
   224     val th1 = th |> transform_elim_theorem |> zero_var_indexes
   225     val ((_, [th2]), ctxt) = Variable.import true [th1] ctxt0
   226     val th3 = th2 |> Conv.fconv_rule Object_Logic.atomize
   227                   |> extensionalize_theorem
   228                   |> Meson.make_nnf ctxt
   229   in (th3, ctxt) end
   230 
   231 (* Convert a theorem to CNF, with Skolem functions as additional premises. *)
   232 fun cnf_axiom thy th =
   233   let
   234     val ctxt0 = Variable.global_thm_context th
   235     val (nnfth, ctxt) = to_nnf th ctxt0
   236     val sko_ths = map (skolem_theorem_of_def thy)
   237                       (assume_skolem_funs nnfth)
   238     val (cnfs, ctxt) = Meson.make_cnf sko_ths nnfth ctxt
   239   in
   240     cnfs |> map introduce_combinators_in_theorem
   241          |> Variable.export ctxt ctxt0
   242          |> Meson.finish_cnf
   243          |> map Thm.close_derivation
   244   end
   245   handle THM _ => []
   246 
   247 end;