src/Pure/axclass.ML
author wenzelm
Tue Jul 07 00:29:34 2009 +0200 (2009-07-07 ago)
changeset 31948 ea8c8bf47ce3
parent 31944 c8a35979a5bc
child 32197 bc341bbe4417
permissions -rw-r--r--
add_classrel/arity: strip_shyps of stored result;
     1 (*  Title:      Pure/axclass.ML
     2     Author:     Markus Wenzel, TU Muenchen
     3 
     4 Type classes defined as predicates, associated with a record of
     5 parameters.
     6 *)
     7 
     8 signature AX_CLASS =
     9 sig
    10   val define_class: binding * class list -> string list ->
    11     (Thm.binding * term list) list -> theory -> class * theory
    12   val add_classrel: thm -> theory -> theory
    13   val add_arity: thm -> theory -> theory
    14   val prove_classrel: class * class -> tactic -> theory -> theory
    15   val prove_arity: string * sort list * sort -> tactic -> theory -> theory
    16   val get_info: theory -> class ->
    17     {def: thm, intro: thm, axioms: thm list, params: (string * typ) list}
    18   val class_intros: theory -> thm list
    19   val class_of_param: theory -> string -> class option
    20   val cert_classrel: theory -> class * class -> class * class
    21   val read_classrel: theory -> xstring * xstring -> class * class
    22   val axiomatize_class: binding * class list -> theory -> theory
    23   val axiomatize_class_cmd: binding * xstring list -> theory -> theory
    24   val axiomatize_classrel: (class * class) list -> theory -> theory
    25   val axiomatize_classrel_cmd: (xstring * xstring) list -> theory -> theory
    26   val axiomatize_arity: arity -> theory -> theory
    27   val axiomatize_arity_cmd: xstring * string list * string -> theory -> theory
    28   val instance_name: string * class -> string
    29   val declare_overloaded: string * typ -> theory -> term * theory
    30   val define_overloaded: binding -> string * term -> theory -> thm * theory
    31   val unoverload: theory -> thm -> thm
    32   val overload: theory -> thm -> thm
    33   val unoverload_conv: theory -> conv
    34   val overload_conv: theory -> conv
    35   val unoverload_const: theory -> string * typ -> string
    36   val lookup_inst_param: Consts.T -> ((string * string) * 'a) list -> string * typ -> 'a option
    37   val param_of_inst: theory -> string * string -> string
    38   val inst_of_param: theory -> string -> (string * string) option
    39   val arity_property: theory -> class * string -> string -> string list
    40   type cache
    41   val of_sort: theory -> typ * sort -> cache -> thm list * cache  (*exception Sorts.CLASS_ERROR*)
    42   val cache: cache
    43   val introN: string
    44   val axiomsN: string
    45 end;
    46 
    47 structure AxClass: AX_CLASS =
    48 struct
    49 
    50 (** theory data **)
    51 
    52 (* class parameters (canonical order) *)
    53 
    54 type param = string * class;
    55 
    56 fun add_param pp ((x, c): param) params =
    57   (case AList.lookup (op =) params x of
    58     NONE => (x, c) :: params
    59   | SOME c' => error ("Duplicate class parameter " ^ quote x ^
    60       " for " ^ Pretty.string_of_sort pp [c] ^
    61       (if c = c' then "" else " and " ^ Pretty.string_of_sort pp [c'])));
    62 
    63 fun merge_params _ ([], qs) = qs
    64   | merge_params pp (ps, qs) =
    65       fold_rev (fn q => if member (op =) ps q then I else add_param pp q) qs ps;
    66 
    67 
    68 (* axclasses *)
    69 
    70 val introN = "intro";
    71 val superN = "super";
    72 val axiomsN = "axioms";
    73 
    74 datatype axclass = AxClass of
    75  {def: thm,
    76   intro: thm,
    77   axioms: thm list,
    78   params: (string * typ) list};
    79 
    80 type axclasses = axclass Symtab.table * param list;
    81 
    82 fun make_axclass ((def, intro, axioms), params) = AxClass
    83   {def = def, intro = intro, axioms = axioms, params = params};
    84 
    85 fun merge_axclasses pp ((tab1, params1), (tab2, params2)) : axclasses =
    86   (Symtab.merge (K true) (tab1, tab2), merge_params pp (params1, params2));
    87 
    88 
    89 (* instances *)
    90 
    91 val classrel_prefix = "classrel_";
    92 val arity_prefix = "arity_";
    93 
    94 type instances =
    95   ((class * class) * thm) list *
    96   ((class * sort list) * thm) list Symtab.table;
    97 
    98 fun merge_instances ((classrel1, arities1): instances, (classrel2, arities2)) =
    99  (merge (eq_fst op =) (classrel1, classrel2),
   100   Symtab.join (K (merge (eq_fst op =))) (arities1, arities2));
   101 
   102 
   103 (* instance parameters *)
   104 
   105 type inst_params =
   106   (string * thm) Symtab.table Symtab.table
   107     (*constant name ~> type constructor ~> (constant name, equation)*)
   108   * (string * string) Symtab.table; (*constant name ~> (constant name, type constructor)*)
   109 
   110 fun merge_inst_params ((const_param1, param_const1), (const_param2, param_const2)) =
   111   (Symtab.join  (K (Symtab.merge (K true))) (const_param1, const_param2),
   112     Symtab.merge (K true) (param_const1, param_const2));
   113 
   114 
   115 (* setup data *)
   116 
   117 structure AxClassData = TheoryDataFun
   118 (
   119   type T = axclasses * (instances * inst_params);
   120   val empty = ((Symtab.empty, []), (([], Symtab.empty), (Symtab.empty, Symtab.empty)));
   121   val copy = I;
   122   val extend = I;
   123   fun merge pp ((axclasses1, (instances1, inst_params1)), (axclasses2, (instances2, inst_params2))) =
   124     (merge_axclasses pp (axclasses1, axclasses2),
   125       (merge_instances (instances1, instances2), merge_inst_params (inst_params1, inst_params2)));
   126 );
   127 
   128 
   129 (* maintain axclasses *)
   130 
   131 val get_axclasses = #1 o AxClassData.get;
   132 val map_axclasses = AxClassData.map o apfst;
   133 
   134 val lookup_def = Symtab.lookup o #1 o get_axclasses;
   135 
   136 fun get_info thy c =
   137   (case lookup_def thy c of
   138     SOME (AxClass info) => info
   139   | NONE => error ("No such axclass: " ^ quote c));
   140 
   141 fun class_intros thy =
   142   let
   143     fun add_intro c =
   144       (case lookup_def thy c of SOME (AxClass {intro, ...}) => cons intro | _ => I);
   145     val classes = Sign.all_classes thy;
   146   in map (Thm.class_triv thy) classes @ fold add_intro classes [] end;
   147 
   148 
   149 fun get_params thy pred =
   150   let val params = #2 (get_axclasses thy);
   151   in fold (fn (x, c) => if pred c then cons x else I) params [] end;
   152 
   153 fun params_of thy c = get_params thy (fn c' => c' = c);
   154 fun all_params_of thy S = get_params thy (fn c => Sign.subsort thy (S, [c]));
   155 
   156 fun class_of_param thy = AList.lookup (op =) (#2 (get_axclasses thy));
   157 
   158 
   159 (* maintain instances *)
   160 
   161 fun instance_name (a, c) = Long_Name.base_name c ^ "_" ^ Long_Name.base_name a;
   162 
   163 val get_instances = #1 o #2 o AxClassData.get;
   164 val map_instances = AxClassData.map o apsnd o apfst;
   165 
   166 
   167 fun the_classrel thy (c1, c2) =
   168   (case AList.lookup (op =) (#1 (get_instances thy)) (c1, c2) of
   169     SOME th => Thm.transfer thy th
   170   | NONE => error ("Unproven class relation " ^
   171       Syntax.string_of_classrel (ProofContext.init thy) [c1, c2]));
   172 
   173 fun put_classrel arg = map_instances (fn (classrel, arities) =>
   174   (insert (eq_fst op =) arg classrel, arities));
   175 
   176 
   177 fun the_arity thy a (c, Ss) =
   178   (case AList.lookup (op =) (Symtab.lookup_list (#2 (get_instances thy)) a) (c, Ss) of
   179     SOME th => Thm.transfer thy th
   180   | NONE => error ("Unproven type arity " ^
   181       Syntax.string_of_arity (ProofContext.init thy) (a, Ss, [c])));
   182 
   183 fun arity_property thy (c, a) x =
   184   Symtab.lookup_list (snd (get_instances thy)) a
   185   |> map_filter (fn ((c', _), th) => if c = c'
   186       then AList.lookup (op =) (Thm.get_tags th) x else NONE)
   187   |> rev;
   188 
   189 fun insert_arity_completions thy (t, ((c, Ss), th)) arities =
   190   let
   191     val algebra = Sign.classes_of thy;
   192     val super_class_completions = Sign.super_classes thy c
   193       |> filter_out (fn c1 => exists (fn ((c2, Ss2), _) => c1 = c2
   194           andalso Sorts.sorts_le algebra (Ss2, Ss)) (Symtab.lookup_list arities t))
   195     val tags = Thm.get_tags th;
   196     val completions = map (fn c1 => (Sorts.weaken algebra
   197       (fn (th, c2) => fn c3 => th RS the_classrel thy (c2, c3)) (th, c) c1
   198         |> Thm.map_tags (K tags) |> Thm.close_derivation, c1)) super_class_completions;
   199     val arities' = fold (fn (th1, c1) => Symtab.cons_list (t, ((c1, Ss), th1)))
   200       completions arities;
   201   in (completions, arities') end;
   202 
   203 fun put_arity ((t, Ss, c), th) thy =
   204   let
   205     val th' = (Thm.map_tags o AList.default (op =))
   206       (Markup.theory_nameN, Context.theory_name thy) th;
   207     val arity' = (t, ((c, Ss), th'));
   208   in
   209     thy
   210     |> map_instances (fn (classrel, arities) => (classrel,
   211       arities
   212       |> Symtab.insert_list (eq_fst op =) arity'
   213       |> insert_arity_completions thy arity'
   214       |> snd))
   215   end;
   216 
   217 fun complete_arities thy =
   218   let
   219     val arities = snd (get_instances thy);
   220     val (completions, arities') = arities
   221       |> fold_map (insert_arity_completions thy) (Symtab.dest_list arities)
   222       |>> flat;
   223   in if null completions
   224     then NONE
   225     else SOME (thy |> map_instances (fn (classrel, _) => (classrel, arities')))
   226   end;
   227 
   228 val _ = Context.>> (Context.map_theory (Theory.at_begin complete_arities));
   229 
   230 
   231 (* maintain instance parameters *)
   232 
   233 val get_inst_params = #2 o #2 o AxClassData.get;
   234 val map_inst_params = AxClassData.map o apsnd o apsnd;
   235 
   236 fun get_inst_param thy (c, tyco) =
   237   case Symtab.lookup ((the_default Symtab.empty o Symtab.lookup (fst (get_inst_params thy))) c) tyco
   238    of SOME c' => c'
   239     | NONE => error ("No instance parameter for constant " ^ quote c
   240         ^ " on type constructor " ^ quote tyco);
   241 
   242 fun add_inst_param (c, tyco) inst = (map_inst_params o apfst
   243       o Symtab.map_default (c, Symtab.empty)) (Symtab.update_new (tyco, inst))
   244   #> (map_inst_params o apsnd) (Symtab.update_new (fst inst, (c, tyco)));
   245 
   246 val inst_of_param = Symtab.lookup o snd o get_inst_params;
   247 val param_of_inst = fst oo get_inst_param;
   248 
   249 fun inst_thms thy = (Symtab.fold (Symtab.fold (cons o snd o snd) o snd) o fst)
   250   (get_inst_params thy) [];
   251 
   252 fun get_inst_tyco consts = try (fst o dest_Type o the_single o Consts.typargs consts);
   253 
   254 fun unoverload thy = MetaSimplifier.simplify true (inst_thms thy);
   255 fun overload thy = MetaSimplifier.simplify true (map Thm.symmetric (inst_thms thy));
   256 
   257 fun unoverload_conv thy = MetaSimplifier.rewrite true (inst_thms thy);
   258 fun overload_conv thy = MetaSimplifier.rewrite true (map Thm.symmetric (inst_thms thy));
   259 
   260 fun lookup_inst_param consts params (c, T) = case get_inst_tyco consts (c, T)
   261  of SOME tyco => AList.lookup (op =) params (c, tyco)
   262   | NONE => NONE;
   263 
   264 fun unoverload_const thy (c_ty as (c, _)) =
   265   case class_of_param thy c
   266    of SOME class => (case get_inst_tyco (Sign.consts_of thy) c_ty
   267        of SOME tyco => try (param_of_inst thy) (c, tyco) |> the_default c
   268         | NONE => c)
   269     | NONE => c;
   270 
   271 
   272 (** instances **)
   273 
   274 (* class relations *)
   275 
   276 fun cert_classrel thy raw_rel =
   277   let
   278     val string_of_sort = Syntax.string_of_sort_global thy;
   279     val (c1, c2) = pairself (Sign.certify_class thy) raw_rel;
   280     val _ = Sign.primitive_classrel (c1, c2) (Theory.copy thy);
   281     val _ =
   282       (case subtract (op =) (all_params_of thy [c1]) (all_params_of thy [c2]) of
   283         [] => ()
   284       | xs => raise TYPE ("Class " ^ string_of_sort [c1] ^ " lacks parameter(s) " ^
   285           commas_quote xs ^ " of " ^ string_of_sort [c2], [], []));
   286   in (c1, c2) end;
   287 
   288 fun read_classrel thy raw_rel =
   289   cert_classrel thy (pairself (Sign.read_class thy) raw_rel)
   290     handle TYPE (msg, _, _) => error msg;
   291 
   292 
   293 (* declaration and definition of instances of overloaded constants *)
   294 
   295 fun inst_tyco_of thy (c, T) = case get_inst_tyco (Sign.consts_of thy) (c, T)
   296  of SOME tyco => tyco
   297   | NONE => error ("Illegal type for instantiation of class parameter: "
   298       ^ quote (c ^ " :: " ^ Syntax.string_of_typ_global thy T));
   299 
   300 fun declare_overloaded (c, T) thy =
   301   let
   302     val class = case class_of_param thy c
   303      of SOME class => class
   304       | NONE => error ("Not a class parameter: " ^ quote c);
   305     val tyco = inst_tyco_of thy (c, T);
   306     val name_inst = instance_name (tyco, class) ^ "_inst";
   307     val c' = Long_Name.base_name c ^ "_" ^ Long_Name.base_name tyco;
   308     val T' = Type.strip_sorts T;
   309   in
   310     thy
   311     |> Sign.mandatory_path name_inst
   312     |> Sign.declare_const [] ((Binding.name c', T'), NoSyn)
   313     |-> (fn const' as Const (c'', _) =>
   314       Thm.add_def false true
   315         (Binding.name (Thm.def_name c'), Logic.mk_equals (Const (c, T'), const'))
   316       #>> Thm.varifyT
   317       #-> (fn thm => add_inst_param (c, tyco) (c'', thm)
   318       #> PureThy.add_thm ((Binding.name c', thm), [Thm.kind_internal])
   319       #> snd
   320       #> Sign.restore_naming thy
   321       #> pair (Const (c, T))))
   322   end;
   323 
   324 fun define_overloaded b (c, t) thy =
   325   let
   326     val T = Term.fastype_of t;
   327     val tyco = inst_tyco_of thy (c, T);
   328     val (c', eq) = get_inst_param thy (c, tyco);
   329     val prop = Logic.mk_equals (Const (c', T), t);
   330     val b' = Thm.def_binding_optional
   331       (Binding.name (Long_Name.base_name c ^ "_" ^ Long_Name.base_name tyco)) b;
   332   in
   333     thy
   334     |> Thm.add_def false false (b', prop)
   335     |>> (fn thm =>  Drule.transitive_thm OF [eq, thm])
   336   end;
   337 
   338 
   339 (* primitive rules *)
   340 
   341 fun add_classrel raw_th thy =
   342   let
   343     val th = Thm.strip_shyps (Thm.transfer thy raw_th);
   344     val prop = Thm.plain_prop_of th;
   345     fun err () = raise THM ("add_classrel: malformed class relation", 0, [th]);
   346     val rel = Logic.dest_classrel prop handle TERM _ => err ();
   347     val (c1, c2) = cert_classrel thy rel handle TYPE _ => err ();
   348   in
   349     thy
   350     |> Sign.primitive_classrel (c1, c2)
   351     |> put_classrel ((c1, c2), Thm.close_derivation (Drule.unconstrainTs th))
   352     |> perhaps complete_arities
   353   end;
   354 
   355 fun add_arity raw_th thy =
   356   let
   357     val th = Thm.strip_shyps (Thm.transfer thy raw_th);
   358     val prop = Thm.plain_prop_of th;
   359     fun err () = raise THM ("add_arity: malformed type arity", 0, [th]);
   360     val (t, Ss, c) = Logic.dest_arity prop handle TERM _ => err ();
   361     val T = Type (t, map TFree (Name.names Name.context Name.aT Ss));
   362     val missing_params = Sign.complete_sort thy [c]
   363       |> maps (these o Option.map #params o try (get_info thy))
   364       |> filter_out (fn (const, _) => can (get_inst_param thy) (const, t))
   365       |> (map o apsnd o map_atyps) (K T);
   366     val _ = map (Sign.certify_sort thy) Ss = Ss orelse err ();
   367     val th' = Drule.unconstrainTs th;
   368   in
   369     thy
   370     |> fold (snd oo declare_overloaded) missing_params
   371     |> Sign.primitive_arity (t, Ss, [c])
   372     |> put_arity ((t, Ss, c), th')
   373   end;
   374 
   375 
   376 (* tactical proofs *)
   377 
   378 fun prove_classrel raw_rel tac thy =
   379   let
   380     val ctxt = ProofContext.init thy;
   381     val (c1, c2) = cert_classrel thy raw_rel;
   382     val th = Goal.prove ctxt [] [] (Logic.mk_classrel (c1, c2)) (K tac) handle ERROR msg =>
   383       cat_error msg ("The error(s) above occurred while trying to prove class relation " ^
   384         quote (Syntax.string_of_classrel ctxt [c1, c2]));
   385   in
   386     thy
   387     |> PureThy.add_thms [((Binding.name
   388         (prefix classrel_prefix (Logic.name_classrel (c1, c2))), th), [])]
   389     |-> (fn [th'] => add_classrel th')
   390   end;
   391 
   392 fun prove_arity raw_arity tac thy =
   393   let
   394     val ctxt = ProofContext.init thy;
   395     val arity = Sign.cert_arity thy raw_arity;
   396     val names = map (prefix arity_prefix) (Logic.name_arities arity);
   397     val props = Logic.mk_arities arity;
   398     val ths = Goal.prove_multi ctxt [] [] props
   399       (fn _ => Goal.precise_conjunction_tac (length props) 1 THEN tac) handle ERROR msg =>
   400         cat_error msg ("The error(s) above occurred while trying to prove type arity " ^
   401           quote (Syntax.string_of_arity ctxt arity));
   402   in
   403     thy
   404     |> PureThy.add_thms (map (rpair []) (map Binding.name names ~~ ths))
   405     |-> fold add_arity
   406   end;
   407 
   408 
   409 
   410 (** class definitions **)
   411 
   412 fun split_defined n eq =
   413   let
   414     val intro =
   415       (eq RS Drule.equal_elim_rule2)
   416       |> Conjunction.curry_balanced n
   417       |> n = 0 ? Thm.eq_assumption 1;
   418     val dests =
   419       if n = 0 then []
   420       else
   421         (eq RS Drule.equal_elim_rule1)
   422         |> BalancedTree.dest (fn th =>
   423           (th RS Conjunction.conjunctionD1, th RS Conjunction.conjunctionD2)) n;
   424   in (intro, dests) end;
   425 
   426 fun define_class (bclass, raw_super) raw_params raw_specs thy =
   427   let
   428     val ctxt = ProofContext.init thy;
   429     val pp = Syntax.pp ctxt;
   430 
   431 
   432     (* class *)
   433 
   434     val bconst = Binding.map_name Logic.const_of_class bclass;
   435     val class = Sign.full_name thy bclass;
   436     val super = Sign.minimize_sort thy (Sign.certify_sort thy raw_super);
   437 
   438     fun check_constraint (a, S) =
   439       if Sign.subsort thy (super, S) then ()
   440       else error ("Sort constraint of type variable " ^
   441         setmp show_sorts true (Pretty.string_of_typ pp) (TFree (a, S)) ^
   442         " needs to be weaker than " ^ Pretty.string_of_sort pp super);
   443 
   444 
   445     (* params *)
   446 
   447     val params = raw_params |> map (fn p =>
   448       let
   449         val T = Sign.the_const_type thy p;
   450         val _ =
   451           (case Term.add_tvarsT T [] of
   452             [((a, _), S)] => check_constraint (a, S)
   453           | _ => error ("Exactly one type variable expected in class parameter " ^ quote p));
   454         val T' = Term.map_type_tvar (fn _ => TFree (Name.aT, [class])) T;
   455       in (p, T') end);
   456 
   457 
   458     (* axioms *)
   459 
   460     fun prep_axiom t =
   461       (case Term.add_tfrees t [] of
   462         [(a, S)] => check_constraint (a, S)
   463       | [] => ()
   464       | _ => error ("Multiple type variables in class axiom:\n" ^ Pretty.string_of_term pp t);
   465       t
   466       |> Term.map_types (Term.map_atyps (fn TFree _ => Term.aT [] | U => U))
   467       |> Logic.close_form);
   468 
   469     val axiomss = map (map (prep_axiom o Sign.cert_prop thy) o snd) raw_specs;
   470     val name_atts = map fst raw_specs;
   471 
   472 
   473     (* definition *)
   474 
   475     val conjs = map (curry Logic.mk_of_class (Term.aT [])) super @ flat axiomss;
   476     val class_eq =
   477       Logic.mk_equals (Logic.mk_of_class (Term.aT [], class), Logic.mk_conjunction_balanced conjs);
   478 
   479     val ([def], def_thy) =
   480       thy
   481       |> Sign.primitive_class (bclass, super)
   482       |> PureThy.add_defs false [((Binding.map_name Thm.def_name bconst, class_eq), [])];
   483     val (raw_intro, (raw_classrel, raw_axioms)) =
   484       split_defined (length conjs) def ||> chop (length super);
   485 
   486 
   487     (* facts *)
   488 
   489     val class_triv = Thm.class_triv def_thy class;
   490     val ([(_, [intro]), (_, classrel), (_, axioms)], facts_thy) =
   491       def_thy
   492       |> Sign.mandatory_path (Binding.name_of bconst)
   493       |> PureThy.note_thmss ""
   494         [((Binding.name introN, []), [([Drule.standard raw_intro], [])]),
   495          ((Binding.name superN, []), [(map Drule.standard raw_classrel, [])]),
   496          ((Binding.name axiomsN, []),
   497            [(map (fn th => Drule.standard (class_triv RS th)) raw_axioms, [])])]
   498       ||> Sign.restore_naming def_thy;
   499 
   500 
   501     (* result *)
   502 
   503     val axclass = make_axclass ((def, intro, axioms), params);
   504     val result_thy =
   505       facts_thy
   506       |> fold put_classrel (map (pair class) super ~~ classrel)
   507       |> Sign.add_path (Binding.name_of bconst)
   508       |> PureThy.note_thmss "" (name_atts ~~ map Thm.simple_fact (unflat axiomss axioms)) |> snd
   509       |> Sign.restore_naming facts_thy
   510       |> map_axclasses (fn (axclasses, parameters) =>
   511         (Symtab.update (class, axclass) axclasses,
   512           fold (fn (x, _) => add_param pp (x, class)) params parameters));
   513 
   514   in (class, result_thy) end;
   515 
   516 
   517 
   518 (** axiomatizations **)
   519 
   520 local
   521 
   522 fun axiomatize prep mk name add raw_args thy =
   523   let
   524     val args = prep thy raw_args;
   525     val specs = mk args;
   526     val names = name args;
   527   in
   528     thy
   529     |> PureThy.add_axioms (map (rpair []) (map Binding.name names ~~ specs))
   530     |-> fold add
   531   end;
   532 
   533 fun ax_classrel prep =
   534   axiomatize (map o prep) (map Logic.mk_classrel)
   535     (map (prefix classrel_prefix o Logic.name_classrel)) add_classrel;
   536 
   537 fun ax_arity prep =
   538   axiomatize prep Logic.mk_arities
   539     (map (prefix arity_prefix) o Logic.name_arities) add_arity;
   540 
   541 fun class_const c =
   542   (Logic.const_of_class c, Term.itselfT (Term.aT []) --> propT);
   543 
   544 fun ax_class prep_class prep_classrel (bclass, raw_super) thy =
   545   let
   546     val class = Sign.full_name thy bclass;
   547     val super = map (prep_class thy) raw_super |> Sign.minimize_sort thy;
   548   in
   549     thy
   550     |> Sign.primitive_class (bclass, super)
   551     |> ax_classrel prep_classrel (map (fn c => (class, c)) super)
   552     |> Theory.add_deps "" (class_const class) (map class_const super)
   553   end;
   554 
   555 in
   556 
   557 val axiomatize_class = ax_class Sign.certify_class cert_classrel;
   558 val axiomatize_class_cmd = ax_class Sign.read_class read_classrel;
   559 val axiomatize_classrel = ax_classrel cert_classrel;
   560 val axiomatize_classrel_cmd = ax_classrel read_classrel;
   561 val axiomatize_arity = ax_arity Sign.cert_arity;
   562 val axiomatize_arity_cmd = ax_arity Sign.read_arity;
   563 
   564 end;
   565 
   566 
   567 
   568 (** explicit derivations -- cached **)
   569 
   570 datatype cache = Types of (class * thm) list Typtab.table;
   571 
   572 local
   573 
   574 fun lookup_type (Types cache) = AList.lookup (op =) o Typtab.lookup_list cache;
   575 fun insert_type T der (Types cache) = Types (Typtab.insert_list (eq_fst op =) (T, der) cache);
   576 
   577 fun derive_type _ (_, []) = []
   578   | derive_type thy (typ, sort) =
   579       let
   580         val certT = Thm.ctyp_of thy;
   581         val vars = Term.fold_atyps
   582             (fn T as TFree (_, S) => insert (eq_fst op =) (T, S)
   583               | T as TVar (_, S) => insert (eq_fst op =) (T, S)
   584               | _ => I) typ [];
   585         val hyps = vars
   586           |> map (fn (T, S) => (T, Thm.of_sort (certT T, S) ~~ S));
   587         val ths = (typ, sort)
   588           |> Sorts.of_sort_derivation (Syntax.pp_global thy) (Sign.classes_of thy)
   589            {class_relation =
   590               fn (th, c1) => fn c2 => th RS the_classrel thy (c1, c2),
   591             type_constructor =
   592               fn a => fn dom => fn c =>
   593                 let val Ss = map (map snd) dom and ths = maps (map fst) dom
   594                 in ths MRS the_arity thy a (c, Ss) end,
   595             type_variable =
   596               the_default [] o AList.lookup (op =) hyps};
   597       in ths end;
   598 
   599 in
   600 
   601 fun of_sort thy (typ, sort) cache =
   602   let
   603     val sort' = filter (is_none o lookup_type cache typ) sort;
   604     val ths' = derive_type thy (typ, sort')
   605       handle ERROR msg => cat_error msg ("The error(s) above occurred for sort derivation: " ^
   606         Syntax.string_of_typ_global thy typ ^ " :: " ^ Syntax.string_of_sort_global thy sort');
   607     val cache' = cache |> fold (insert_type typ) (sort' ~~ ths');
   608     val ths =
   609       sort |> map (fn c =>
   610         Goal.finish (the (lookup_type cache' typ c) RS
   611           Goal.init (Thm.cterm_of thy (Logic.mk_of_class (typ, c))))
   612         |> Thm.adjust_maxidx_thm ~1);
   613   in (ths, cache') end;
   614 
   615 end;
   616 
   617 val cache = Types Typtab.empty;
   618 
   619 end;