src/Pure/proofterm.ML
author wenzelm
Wed Sep 30 22:24:57 2009 +0200 (2009-09-30 ago)
changeset 32785 ec5292653aff
parent 32738 15bb09ca0378
child 32810 f3466a5645fa
permissions -rw-r--r--
eliminated redundant parameters;
     1 (*  Title:      Pure/proofterm.ML
     2     Author:     Stefan Berghofer, TU Muenchen
     3 
     4 LF style proof terms.
     5 *)
     6 
     7 infix 8 % %% %>;
     8 
     9 signature BASIC_PROOFTERM =
    10 sig
    11   val proofs: int Unsynchronized.ref
    12 
    13   datatype proof =
    14      MinProof
    15    | PBound of int
    16    | Abst of string * typ option * proof
    17    | AbsP of string * term option * proof
    18    | op % of proof * term option
    19    | op %% of proof * proof
    20    | Hyp of term
    21    | PAxm of string * term * typ list option
    22    | OfClass of typ * class
    23    | Oracle of string * term * typ list option
    24    | Promise of serial * term * typ list
    25    | PThm of serial * ((string * term * typ list option) * proof_body future)
    26   and proof_body = PBody of
    27     {oracles: (string * term) OrdList.T,
    28      thms: (serial * (string * term * proof_body future)) OrdList.T,
    29      proof: proof}
    30 
    31   val %> : proof * term -> proof
    32 end;
    33 
    34 signature PROOFTERM =
    35 sig
    36   include BASIC_PROOFTERM
    37 
    38   type oracle = string * term
    39   type pthm = serial * (string * term * proof_body future)
    40   val proof_of: proof_body -> proof
    41   val join_proof: proof_body future -> proof
    42   val fold_proof_atoms: bool -> (proof -> 'a -> 'a) -> proof list -> 'a -> 'a
    43   val fold_body_thms: (serial * (string * term * proof_body) -> 'a -> 'a) ->
    44     proof_body list -> 'a -> 'a
    45   val join_bodies: proof_body list -> unit
    46   val status_of: proof_body list -> {failed: bool, oracle: bool, unfinished: bool}
    47 
    48   val oracle_ord: oracle * oracle -> order
    49   val thm_ord: pthm * pthm -> order
    50   val merge_oracles: oracle OrdList.T -> oracle OrdList.T -> oracle OrdList.T
    51   val merge_thms: pthm OrdList.T -> pthm OrdList.T -> pthm OrdList.T
    52   val all_oracles_of: proof_body -> oracle OrdList.T
    53   val approximate_proof_body: proof -> proof_body
    54 
    55   (** primitive operations **)
    56   val proof_combt: proof * term list -> proof
    57   val proof_combt': proof * term option list -> proof
    58   val proof_combP: proof * proof list -> proof
    59   val strip_combt: proof -> proof * term option list
    60   val strip_combP: proof -> proof * proof list
    61   val strip_thm: proof_body -> proof_body
    62   val map_proof_terms_option: (term -> term option) -> (typ -> typ option) -> proof -> proof
    63   val map_proof_terms: (term -> term) -> (typ -> typ) -> proof -> proof
    64   val fold_proof_terms: (term -> 'a -> 'a) -> (typ -> 'a -> 'a) -> proof -> 'a -> 'a
    65   val maxidx_proof: proof -> int -> int
    66   val size_of_proof: proof -> int
    67   val change_type: typ list option -> proof -> proof
    68   val prf_abstract_over: term -> proof -> proof
    69   val prf_incr_bv: int -> int -> int -> int -> proof -> proof
    70   val incr_pboundvars: int -> int -> proof -> proof
    71   val prf_loose_bvar1: proof -> int -> bool
    72   val prf_loose_Pbvar1: proof -> int -> bool
    73   val prf_add_loose_bnos: int -> int -> proof -> int list * int list -> int list * int list
    74   val norm_proof: Envir.env -> proof -> proof
    75   val norm_proof': Envir.env -> proof -> proof
    76   val prf_subst_bounds: term list -> proof -> proof
    77   val prf_subst_pbounds: proof list -> proof -> proof
    78   val freeze_thaw_prf: proof -> proof * (proof -> proof)
    79 
    80   (** proof terms for specific inference rules **)
    81   val implies_intr_proof: term -> proof -> proof
    82   val forall_intr_proof: term -> string -> proof -> proof
    83   val varify_proof: term -> (string * sort) list -> proof -> proof
    84   val freezeT: term -> proof -> proof
    85   val rotate_proof: term list -> term -> int -> proof -> proof
    86   val permute_prems_prf: term list -> int -> int -> proof -> proof
    87   val generalize: string list * string list -> int -> proof -> proof
    88   val instantiate: ((indexname * sort) * typ) list * ((indexname * typ) * term) list
    89     -> proof -> proof
    90   val lift_proof: term -> int -> term -> proof -> proof
    91   val incr_indexes: int -> proof -> proof
    92   val assumption_proof: term list -> term -> int -> proof -> proof
    93   val bicompose_proof: bool -> term list -> term list -> term list -> term option ->
    94     int -> int -> proof -> proof -> proof
    95   val equality_axms: (string * term) list
    96   val reflexive_axm: proof
    97   val symmetric_axm: proof
    98   val transitive_axm: proof
    99   val equal_intr_axm: proof
   100   val equal_elim_axm: proof
   101   val abstract_rule_axm: proof
   102   val combination_axm: proof
   103   val reflexive: proof
   104   val symmetric: proof -> proof
   105   val transitive: term -> typ -> proof -> proof -> proof
   106   val abstract_rule: term -> string -> proof -> proof
   107   val combination: term -> term -> term -> term -> typ -> proof -> proof -> proof
   108   val equal_intr: term -> term -> proof -> proof -> proof
   109   val equal_elim: term -> term -> proof -> proof -> proof
   110   val axm_proof: string -> term -> proof
   111   val oracle_proof: string -> term -> oracle * proof
   112   val promise_proof: theory -> serial -> term -> proof
   113   val fulfill_proof: theory -> serial -> (serial * proof_body) list -> proof_body -> proof_body
   114   val thm_proof: theory -> string -> term list -> term ->
   115     (serial * proof_body future) list -> proof_body -> pthm * proof
   116   val get_name: term list -> term -> proof -> string
   117 
   118   (** rewriting on proof terms **)
   119   val add_prf_rrule: proof * proof -> theory -> theory
   120   val add_prf_rproc: (typ list -> proof -> proof option) -> theory -> theory
   121   val rewrite_proof: theory -> (proof * proof) list *
   122     (typ list -> proof -> proof option) list -> proof -> proof
   123   val rewrite_proof_notypes: (proof * proof) list *
   124     (typ list -> proof -> proof option) list -> proof -> proof
   125   val rew_proof: theory -> proof -> proof
   126 end
   127 
   128 structure Proofterm : PROOFTERM =
   129 struct
   130 
   131 (***** datatype proof *****)
   132 
   133 datatype proof =
   134    MinProof
   135  | PBound of int
   136  | Abst of string * typ option * proof
   137  | AbsP of string * term option * proof
   138  | op % of proof * term option
   139  | op %% of proof * proof
   140  | Hyp of term
   141  | PAxm of string * term * typ list option
   142  | OfClass of typ * class
   143  | Oracle of string * term * typ list option
   144  | Promise of serial * term * typ list
   145  | PThm of serial * ((string * term * typ list option) * proof_body future)
   146 and proof_body = PBody of
   147   {oracles: (string * term) OrdList.T,
   148    thms: (serial * (string * term * proof_body future)) OrdList.T,
   149    proof: proof};
   150 
   151 type oracle = string * term;
   152 type pthm = serial * (string * term * proof_body future);
   153 
   154 fun proof_of (PBody {proof, ...}) = proof;
   155 val join_proof = Future.join #> proof_of;
   156 
   157 
   158 (***** proof atoms *****)
   159 
   160 fun fold_proof_atoms all f =
   161   let
   162     fun app (Abst (_, _, prf)) = app prf
   163       | app (AbsP (_, _, prf)) = app prf
   164       | app (prf % _) = app prf
   165       | app (prf1 %% prf2) = app prf1 #> app prf2
   166       | app (prf as PThm (i, (_, body))) = (fn (x, seen) =>
   167           if Inttab.defined seen i then (x, seen)
   168           else
   169             let val (x', seen') =
   170               (if all then app (join_proof body) else I) (x, Inttab.update (i, ()) seen)
   171             in (f prf x', seen') end)
   172       | app prf = (fn (x, seen) => (f prf x, seen));
   173   in fn prfs => fn x => #1 (fold app prfs (x, Inttab.empty)) end;
   174 
   175 fun fold_body_thms f =
   176   let
   177     fun app (PBody {thms, ...}) =
   178      (Future.join_results (map (#3 o #2) thms);
   179       thms |> fold (fn (i, (name, prop, body)) => fn (x, seen) =>
   180         if Inttab.defined seen i then (x, seen)
   181         else
   182           let
   183             val body' = Future.join body;
   184             val (x', seen') = app body' (x, Inttab.update (i, ()) seen);
   185           in (f (i, (name, prop, body')) x', seen') end));
   186   in fn bodies => fn x => #1 (fold app bodies (x, Inttab.empty)) end;
   187 
   188 fun join_bodies bodies = fold_body_thms (fn _ => fn () => ()) bodies ();
   189 
   190 fun status_of bodies =
   191   let
   192     fun status (PBody {oracles, thms, ...}) x =
   193       let
   194         val ((oracle, unfinished, failed), seen) =
   195           (thms, x) |-> fold (fn (i, (_, _, body)) => fn (st, seen) =>
   196             if Inttab.defined seen i then (st, seen)
   197             else
   198               let val seen' = Inttab.update (i, ()) seen in
   199                 (case Future.peek body of
   200                   SOME (Exn.Result body') => status body' (st, seen')
   201                 | SOME (Exn.Exn _) =>
   202                     let val (oracle, unfinished, _) = st
   203                     in ((oracle, unfinished, true), seen') end
   204                 | NONE =>
   205                     let val (oracle, _, failed) = st
   206                     in ((oracle, true, failed), seen') end)
   207               end);
   208       in ((oracle orelse not (null oracles), unfinished, failed), seen) end;
   209     val (oracle, unfinished, failed) =
   210       #1 (fold status bodies ((false, false, false), Inttab.empty));
   211   in {oracle = oracle, unfinished = unfinished, failed = failed} end;
   212 
   213 
   214 (* proof body *)
   215 
   216 val oracle_ord = prod_ord fast_string_ord TermOrd.fast_term_ord;
   217 fun thm_ord ((i, _): pthm, (j, _)) = int_ord (j, i);
   218 
   219 val merge_oracles = OrdList.union oracle_ord;
   220 val merge_thms = OrdList.union thm_ord;
   221 
   222 val all_oracles_of =
   223   let
   224     fun collect (PBody {oracles, thms, ...}) =
   225      (Future.join_results (map (#3 o #2) thms);
   226       thms |> fold (fn (i, (_, _, body)) => fn (x, seen) =>
   227         if Inttab.defined seen i then (x, seen)
   228         else
   229           let
   230             val body' = Future.join body;
   231             val (x', seen') = collect body' (x, Inttab.update (i, ()) seen);
   232           in (merge_oracles oracles x', seen') end));
   233   in fn body => #1 (collect body ([], Inttab.empty)) end;
   234 
   235 fun approximate_proof_body prf =
   236   let
   237     val (oracles, thms) = fold_proof_atoms false
   238       (fn Oracle (s, prop, _) => apfst (cons (s, prop))
   239         | PThm (i, ((name, prop, _), body)) => apsnd (cons (i, (name, prop, body)))
   240         | _ => I) [prf] ([], []);
   241   in
   242     PBody
   243      {oracles = OrdList.make oracle_ord oracles,
   244       thms = OrdList.make thm_ord thms,
   245       proof = prf}
   246   end;
   247 
   248 
   249 (***** proof objects with different levels of detail *****)
   250 
   251 fun (prf %> t) = prf % SOME t;
   252 
   253 val proof_combt = Library.foldl (op %>);
   254 val proof_combt' = Library.foldl (op %);
   255 val proof_combP = Library.foldl (op %%);
   256 
   257 fun strip_combt prf =
   258     let fun stripc (prf % t, ts) = stripc (prf, t::ts)
   259           | stripc  x =  x
   260     in  stripc (prf, [])  end;
   261 
   262 fun strip_combP prf =
   263     let fun stripc (prf %% prf', prfs) = stripc (prf, prf'::prfs)
   264           | stripc  x =  x
   265     in  stripc (prf, [])  end;
   266 
   267 fun strip_thm (body as PBody {proof, ...}) =
   268   (case strip_combt (fst (strip_combP proof)) of
   269     (PThm (_, (_, body')), _) => Future.join body'
   270   | _ => body);
   271 
   272 val mk_Abst = fold_rev (fn (s, T:typ) => fn prf => Abst (s, NONE, prf));
   273 fun mk_AbsP (i, prf) = funpow i (fn prf => AbsP ("H", NONE, prf)) prf;
   274 
   275 fun map_proof_terms_option f g =
   276   let
   277     val term = Same.function f;
   278     val typ = Same.function g;
   279     val typs = Same.map typ;
   280 
   281     fun proof (Abst (s, T, prf)) =
   282           (Abst (s, Same.map_option typ T, Same.commit proof prf)
   283             handle Same.SAME => Abst (s, T, proof prf))
   284       | proof (AbsP (s, t, prf)) =
   285           (AbsP (s, Same.map_option term t, Same.commit proof prf)
   286             handle Same.SAME => AbsP (s, t, proof prf))
   287       | proof (prf % t) =
   288           (proof prf % Same.commit (Same.map_option term) t
   289             handle Same.SAME => prf % Same.map_option term t)
   290       | proof (prf1 %% prf2) =
   291           (proof prf1 %% Same.commit proof prf2
   292             handle Same.SAME => prf1 %% proof prf2)
   293       | proof (PAxm (a, prop, SOME Ts)) = PAxm (a, prop, SOME (typs Ts))
   294       | proof (OfClass (T, c)) = OfClass (typ T, c)
   295       | proof (Oracle (a, prop, SOME Ts)) = Oracle (a, prop, SOME (typs Ts))
   296       | proof (Promise (i, prop, Ts)) = Promise (i, prop, typs Ts)
   297       | proof (PThm (i, ((a, prop, SOME Ts), body))) =
   298           PThm (i, ((a, prop, SOME (typs Ts)), body))
   299       | proof _ = raise Same.SAME;
   300   in Same.commit proof end;
   301 
   302 fun same eq f x =
   303   let val x' = f x
   304   in if eq (x, x') then raise Same.SAME else x' end;
   305 
   306 fun map_proof_terms f g =
   307   map_proof_terms_option
   308    (fn t => SOME (same (op =) f t) handle Same.SAME => NONE)
   309    (fn T => SOME (same (op =) g T) handle Same.SAME => NONE);
   310 
   311 fun fold_proof_terms f g (Abst (_, SOME T, prf)) = g T #> fold_proof_terms f g prf
   312   | fold_proof_terms f g (Abst (_, NONE, prf)) = fold_proof_terms f g prf
   313   | fold_proof_terms f g (AbsP (_, SOME t, prf)) = f t #> fold_proof_terms f g prf
   314   | fold_proof_terms f g (AbsP (_, NONE, prf)) = fold_proof_terms f g prf
   315   | fold_proof_terms f g (prf % SOME t) = fold_proof_terms f g prf #> f t
   316   | fold_proof_terms f g (prf % NONE) = fold_proof_terms f g prf
   317   | fold_proof_terms f g (prf1 %% prf2) =
   318       fold_proof_terms f g prf1 #> fold_proof_terms f g prf2
   319   | fold_proof_terms _ g (PAxm (_, _, SOME Ts)) = fold g Ts
   320   | fold_proof_terms _ g (OfClass (T, _)) = g T
   321   | fold_proof_terms _ g (Oracle (_, _, SOME Ts)) = fold g Ts
   322   | fold_proof_terms _ g (Promise (_, _, Ts)) = fold g Ts
   323   | fold_proof_terms _ g (PThm (_, ((_, _, SOME Ts), _))) = fold g Ts
   324   | fold_proof_terms _ _ _ = I;
   325 
   326 fun maxidx_proof prf = fold_proof_terms Term.maxidx_term Term.maxidx_typ prf;
   327 
   328 fun size_of_proof (Abst (_, _, prf)) = 1 + size_of_proof prf
   329   | size_of_proof (AbsP (_, t, prf)) = 1 + size_of_proof prf
   330   | size_of_proof (prf % _) = 1 + size_of_proof prf
   331   | size_of_proof (prf1 %% prf2) = size_of_proof prf1 + size_of_proof prf2
   332   | size_of_proof _ = 1;
   333 
   334 fun change_type opTs (PAxm (name, prop, _)) = PAxm (name, prop, opTs)
   335   | change_type (SOME [T]) (OfClass (_, c)) = OfClass (T, c)
   336   | change_type opTs (Oracle (name, prop, _)) = Oracle (name, prop, opTs)
   337   | change_type opTs (Promise _) = error "change_type: unexpected promise"
   338   | change_type opTs (PThm (i, ((name, prop, _), body))) =
   339       PThm (i, ((name, prop, opTs), body))
   340   | change_type _ prf = prf;
   341 
   342 
   343 (***** utilities *****)
   344 
   345 fun strip_abs (_::Ts) (Abs (_, _, t)) = strip_abs Ts t
   346   | strip_abs _ t = t;
   347 
   348 fun mk_abs Ts t = Library.foldl (fn (t', T) => Abs ("", T, t')) (t, Ts);
   349 
   350 
   351 (*Abstraction of a proof term over its occurrences of v,
   352     which must contain no loose bound variables.
   353   The resulting proof term is ready to become the body of an Abst.*)
   354 
   355 fun prf_abstract_over v =
   356   let
   357     fun abst' lev u = if v aconv u then Bound lev else
   358       (case u of
   359          Abs (a, T, t) => Abs (a, T, abst' (lev + 1) t)
   360        | f $ t => (abst' lev f $ absth' lev t handle Same.SAME => f $ abst' lev t)
   361        | _ => raise Same.SAME)
   362     and absth' lev t = (abst' lev t handle Same.SAME => t);
   363 
   364     fun abst lev (AbsP (a, t, prf)) =
   365           (AbsP (a, Same.map_option (abst' lev) t, absth lev prf)
   366            handle Same.SAME => AbsP (a, t, abst lev prf))
   367       | abst lev (Abst (a, T, prf)) = Abst (a, T, abst (lev + 1) prf)
   368       | abst lev (prf1 %% prf2) = (abst lev prf1 %% absth lev prf2
   369           handle Same.SAME => prf1 %% abst lev prf2)
   370       | abst lev (prf % t) = (abst lev prf % Option.map (absth' lev) t
   371           handle Same.SAME => prf % Same.map_option (abst' lev) t)
   372       | abst _ _ = raise Same.SAME
   373     and absth lev prf = (abst lev prf handle Same.SAME => prf);
   374 
   375   in absth 0 end;
   376 
   377 
   378 (*increments a proof term's non-local bound variables
   379   required when moving a proof term within abstractions
   380      inc is  increment for bound variables
   381      lev is  level at which a bound variable is considered 'loose'*)
   382 
   383 fun incr_bv' inct tlev t = incr_bv (inct, tlev, t);
   384 
   385 fun prf_incr_bv' incP inct Plev tlev (PBound i) =
   386       if i >= Plev then PBound (i+incP) else raise Same.SAME
   387   | prf_incr_bv' incP inct Plev tlev (AbsP (a, t, body)) =
   388       (AbsP (a, Same.map_option (same (op =) (incr_bv' inct tlev)) t,
   389          prf_incr_bv incP inct (Plev+1) tlev body) handle Same.SAME =>
   390            AbsP (a, t, prf_incr_bv' incP inct (Plev+1) tlev body))
   391   | prf_incr_bv' incP inct Plev tlev (Abst (a, T, body)) =
   392       Abst (a, T, prf_incr_bv' incP inct Plev (tlev+1) body)
   393   | prf_incr_bv' incP inct Plev tlev (prf %% prf') =
   394       (prf_incr_bv' incP inct Plev tlev prf %% prf_incr_bv incP inct Plev tlev prf'
   395        handle Same.SAME => prf %% prf_incr_bv' incP inct Plev tlev prf')
   396   | prf_incr_bv' incP inct Plev tlev (prf % t) =
   397       (prf_incr_bv' incP inct Plev tlev prf % Option.map (incr_bv' inct tlev) t
   398        handle Same.SAME => prf % Same.map_option (same (op =) (incr_bv' inct tlev)) t)
   399   | prf_incr_bv' _ _ _ _ _ = raise Same.SAME
   400 and prf_incr_bv incP inct Plev tlev prf =
   401       (prf_incr_bv' incP inct Plev tlev prf handle Same.SAME => prf);
   402 
   403 fun incr_pboundvars  0 0 prf = prf
   404   | incr_pboundvars incP inct prf = prf_incr_bv incP inct 0 0 prf;
   405 
   406 
   407 fun prf_loose_bvar1 (prf1 %% prf2) k = prf_loose_bvar1 prf1 k orelse prf_loose_bvar1 prf2 k
   408   | prf_loose_bvar1 (prf % SOME t) k = prf_loose_bvar1 prf k orelse loose_bvar1 (t, k)
   409   | prf_loose_bvar1 (_ % NONE) _ = true
   410   | prf_loose_bvar1 (AbsP (_, SOME t, prf)) k = loose_bvar1 (t, k) orelse prf_loose_bvar1 prf k
   411   | prf_loose_bvar1 (AbsP (_, NONE, _)) k = true
   412   | prf_loose_bvar1 (Abst (_, _, prf)) k = prf_loose_bvar1 prf (k+1)
   413   | prf_loose_bvar1 _ _ = false;
   414 
   415 fun prf_loose_Pbvar1 (PBound i) k = i = k
   416   | prf_loose_Pbvar1 (prf1 %% prf2) k = prf_loose_Pbvar1 prf1 k orelse prf_loose_Pbvar1 prf2 k
   417   | prf_loose_Pbvar1 (prf % _) k = prf_loose_Pbvar1 prf k
   418   | prf_loose_Pbvar1 (AbsP (_, _, prf)) k = prf_loose_Pbvar1 prf (k+1)
   419   | prf_loose_Pbvar1 (Abst (_, _, prf)) k = prf_loose_Pbvar1 prf k
   420   | prf_loose_Pbvar1 _ _ = false;
   421 
   422 fun prf_add_loose_bnos plev tlev (PBound i) (is, js) =
   423       if i < plev then (is, js) else (insert (op =) (i-plev) is, js)
   424   | prf_add_loose_bnos plev tlev (prf1 %% prf2) p =
   425       prf_add_loose_bnos plev tlev prf2
   426         (prf_add_loose_bnos plev tlev prf1 p)
   427   | prf_add_loose_bnos plev tlev (prf % opt) (is, js) =
   428       prf_add_loose_bnos plev tlev prf (case opt of
   429           NONE => (is, insert (op =) ~1 js)
   430         | SOME t => (is, add_loose_bnos (t, tlev, js)))
   431   | prf_add_loose_bnos plev tlev (AbsP (_, opt, prf)) (is, js) =
   432       prf_add_loose_bnos (plev+1) tlev prf (case opt of
   433           NONE => (is, insert (op =) ~1 js)
   434         | SOME t => (is, add_loose_bnos (t, tlev, js)))
   435   | prf_add_loose_bnos plev tlev (Abst (_, _, prf)) p =
   436       prf_add_loose_bnos plev (tlev+1) prf p
   437   | prf_add_loose_bnos _ _ _ _ = ([], []);
   438 
   439 
   440 (**** substitutions ****)
   441 
   442 fun del_conflicting_tvars envT T = Term_Subst.instantiateT
   443   (map_filter (fn ixnS as (_, S) =>
   444      (Type.lookup envT ixnS; NONE) handle TYPE _ =>
   445         SOME (ixnS, TFree ("'dummy", S))) (OldTerm.typ_tvars T)) T;
   446 
   447 fun del_conflicting_vars env t = Term_Subst.instantiate
   448   (map_filter (fn ixnS as (_, S) =>
   449      (Type.lookup (Envir.type_env env) ixnS; NONE) handle TYPE _ =>
   450         SOME (ixnS, TFree ("'dummy", S))) (OldTerm.term_tvars t),
   451    map_filter (fn Var (ixnT as (_, T)) =>
   452      (Envir.lookup (env, ixnT); NONE) handle TYPE _ =>
   453         SOME (ixnT, Free ("dummy", T))) (OldTerm.term_vars t)) t;
   454 
   455 fun norm_proof env =
   456   let
   457     val envT = Envir.type_env env;
   458     fun msg s = warning ("type conflict in norm_proof:\n" ^ s);
   459     fun htype f t = f env t handle TYPE (s, _, _) =>
   460       (msg s; f env (del_conflicting_vars env t));
   461     fun htypeT f T = f envT T handle TYPE (s, _, _) =>
   462       (msg s; f envT (del_conflicting_tvars envT T));
   463     fun htypeTs f Ts = f envT Ts handle TYPE (s, _, _) =>
   464       (msg s; f envT (map (del_conflicting_tvars envT) Ts));
   465 
   466     fun norm (Abst (s, T, prf)) =
   467           (Abst (s, Same.map_option (htypeT Envir.norm_type_same) T, Same.commit norm prf)
   468             handle Same.SAME => Abst (s, T, norm prf))
   469       | norm (AbsP (s, t, prf)) =
   470           (AbsP (s, Same.map_option (htype Envir.norm_term_same) t, Same.commit norm prf)
   471             handle Same.SAME => AbsP (s, t, norm prf))
   472       | norm (prf % t) =
   473           (norm prf % Option.map (htype Envir.norm_term) t
   474             handle Same.SAME => prf % Same.map_option (htype Envir.norm_term_same) t)
   475       | norm (prf1 %% prf2) =
   476           (norm prf1 %% Same.commit norm prf2
   477             handle Same.SAME => prf1 %% norm prf2)
   478       | norm (PAxm (s, prop, Ts)) =
   479           PAxm (s, prop, Same.map_option (htypeTs Envir.norm_types_same) Ts)
   480       | norm (OfClass (T, c)) =
   481           OfClass (htypeT Envir.norm_type_same T, c)
   482       | norm (Oracle (s, prop, Ts)) =
   483           Oracle (s, prop, Same.map_option (htypeTs Envir.norm_types_same) Ts)
   484       | norm (Promise (i, prop, Ts)) =
   485           Promise (i, prop, htypeTs Envir.norm_types_same Ts)
   486       | norm (PThm (i, ((s, t, Ts), body))) =
   487           PThm (i, ((s, t, Same.map_option (htypeTs Envir.norm_types_same) Ts), body))
   488       | norm _ = raise Same.SAME;
   489   in Same.commit norm end;
   490 
   491 
   492 (***** Remove some types in proof term (to save space) *****)
   493 
   494 fun remove_types (Abs (s, _, t)) = Abs (s, dummyT, remove_types t)
   495   | remove_types (t $ u) = remove_types t $ remove_types u
   496   | remove_types (Const (s, _)) = Const (s, dummyT)
   497   | remove_types t = t;
   498 
   499 fun remove_types_env (Envir.Envir {maxidx, tenv, tyenv}) =
   500   Envir.Envir {maxidx = maxidx, tenv = Vartab.map (apsnd remove_types) tenv, tyenv = tyenv};
   501 
   502 fun norm_proof' env prf = norm_proof (remove_types_env env) prf;
   503 
   504 
   505 (**** substitution of bound variables ****)
   506 
   507 fun prf_subst_bounds args prf =
   508   let
   509     val n = length args;
   510     fun subst' lev (Bound i) =
   511          (if i<lev then raise Same.SAME    (*var is locally bound*)
   512           else  incr_boundvars lev (nth args (i-lev))
   513                   handle Subscript => Bound (i-n))  (*loose: change it*)
   514       | subst' lev (Abs (a, T, body)) = Abs (a, T,  subst' (lev+1) body)
   515       | subst' lev (f $ t) = (subst' lev f $ substh' lev t
   516           handle Same.SAME => f $ subst' lev t)
   517       | subst' _ _ = raise Same.SAME
   518     and substh' lev t = (subst' lev t handle Same.SAME => t);
   519 
   520     fun subst lev (AbsP (a, t, body)) =
   521         (AbsP (a, Same.map_option (subst' lev) t, substh lev body)
   522           handle Same.SAME => AbsP (a, t, subst lev body))
   523       | subst lev (Abst (a, T, body)) = Abst (a, T, subst (lev+1) body)
   524       | subst lev (prf %% prf') = (subst lev prf %% substh lev prf'
   525           handle Same.SAME => prf %% subst lev prf')
   526       | subst lev (prf % t) = (subst lev prf % Option.map (substh' lev) t
   527           handle Same.SAME => prf % Same.map_option (subst' lev) t)
   528       | subst _ _ = raise Same.SAME
   529     and substh lev prf = (subst lev prf handle Same.SAME => prf);
   530   in case args of [] => prf | _ => substh 0 prf end;
   531 
   532 fun prf_subst_pbounds args prf =
   533   let
   534     val n = length args;
   535     fun subst (PBound i) Plev tlev =
   536          (if i < Plev then raise Same.SAME    (*var is locally bound*)
   537           else incr_pboundvars Plev tlev (nth args (i-Plev))
   538                  handle Subscript => PBound (i-n)  (*loose: change it*))
   539       | subst (AbsP (a, t, body)) Plev tlev = AbsP (a, t, subst body (Plev+1) tlev)
   540       | subst (Abst (a, T, body)) Plev tlev = Abst (a, T, subst body Plev (tlev+1))
   541       | subst (prf %% prf') Plev tlev = (subst prf Plev tlev %% substh prf' Plev tlev
   542           handle Same.SAME => prf %% subst prf' Plev tlev)
   543       | subst (prf % t) Plev tlev = subst prf Plev tlev % t
   544       | subst  prf _ _ = raise Same.SAME
   545     and substh prf Plev tlev = (subst prf Plev tlev handle Same.SAME => prf)
   546   in case args of [] => prf | _ => substh prf 0 0 end;
   547 
   548 
   549 (**** Freezing and thawing of variables in proof terms ****)
   550 
   551 fun frzT names =
   552   map_type_tvar (fn (ixn, xs) => TFree ((the o AList.lookup (op =) names) ixn, xs));
   553 
   554 fun thawT names =
   555   map_type_tfree (fn (s, xs) => case AList.lookup (op =) names s of
   556       NONE => TFree (s, xs)
   557     | SOME ixn => TVar (ixn, xs));
   558 
   559 fun freeze names names' (t $ u) =
   560       freeze names names' t $ freeze names names' u
   561   | freeze names names' (Abs (s, T, t)) =
   562       Abs (s, frzT names' T, freeze names names' t)
   563   | freeze names names' (Const (s, T)) = Const (s, frzT names' T)
   564   | freeze names names' (Free (s, T)) = Free (s, frzT names' T)
   565   | freeze names names' (Var (ixn, T)) =
   566       Free ((the o AList.lookup (op =) names) ixn, frzT names' T)
   567   | freeze names names' t = t;
   568 
   569 fun thaw names names' (t $ u) =
   570       thaw names names' t $ thaw names names' u
   571   | thaw names names' (Abs (s, T, t)) =
   572       Abs (s, thawT names' T, thaw names names' t)
   573   | thaw names names' (Const (s, T)) = Const (s, thawT names' T)
   574   | thaw names names' (Free (s, T)) =
   575       let val T' = thawT names' T
   576       in case AList.lookup (op =) names s of
   577           NONE => Free (s, T')
   578         | SOME ixn => Var (ixn, T')
   579       end
   580   | thaw names names' (Var (ixn, T)) = Var (ixn, thawT names' T)
   581   | thaw names names' t = t;
   582 
   583 fun freeze_thaw_prf prf =
   584   let
   585     val (fs, Tfs, vs, Tvs) = fold_proof_terms
   586       (fn t => fn (fs, Tfs, vs, Tvs) =>
   587          (Term.add_free_names t fs, Term.add_tfree_names t Tfs,
   588           Term.add_var_names t vs, Term.add_tvar_names t Tvs))
   589       (fn T => fn (fs, Tfs, vs, Tvs) =>
   590          (fs, Term.add_tfree_namesT T Tfs,
   591           vs, Term.add_tvar_namesT T Tvs))
   592       prf ([], [], [], []);
   593     val names = vs ~~ Name.variant_list fs (map fst vs);
   594     val names' = Tvs ~~ Name.variant_list Tfs (map fst Tvs);
   595     val rnames = map swap names;
   596     val rnames' = map swap names';
   597   in
   598     (map_proof_terms (freeze names names') (frzT names') prf,
   599      map_proof_terms (thaw rnames rnames') (thawT rnames'))
   600   end;
   601 
   602 
   603 (***** implication introduction *****)
   604 
   605 fun implies_intr_proof h prf =
   606   let
   607     fun abshyp i (Hyp t) = if h aconv t then PBound i else raise Same.SAME
   608       | abshyp i (Abst (s, T, prf)) = Abst (s, T, abshyp i prf)
   609       | abshyp i (AbsP (s, t, prf)) = AbsP (s, t, abshyp (i + 1) prf)
   610       | abshyp i (prf % t) = abshyp i prf % t
   611       | abshyp i (prf1 %% prf2) =
   612           (abshyp i prf1 %% abshyph i prf2
   613             handle Same.SAME => prf1 %% abshyp i prf2)
   614       | abshyp _ _ = raise Same.SAME
   615     and abshyph i prf = (abshyp i prf handle Same.SAME => prf);
   616   in
   617     AbsP ("H", NONE (*h*), abshyph 0 prf)
   618   end;
   619 
   620 
   621 (***** forall introduction *****)
   622 
   623 fun forall_intr_proof x a prf = Abst (a, NONE, prf_abstract_over x prf);
   624 
   625 
   626 (***** varify *****)
   627 
   628 fun varify_proof t fixed prf =
   629   let
   630     val fs = Term.fold_types (Term.fold_atyps
   631       (fn TFree v => if member (op =) fixed v then I else insert (op =) v | _ => I)) t [];
   632     val used = Name.context
   633       |> fold_types (fold_atyps (fn TVar ((a, _), _) => Name.declare a | _ => I)) t;
   634     val fmap = fs ~~ #1 (Name.variants (map fst fs) used);
   635     fun thaw (f as (a, S)) =
   636       (case AList.lookup (op =) fmap f of
   637         NONE => TFree f
   638       | SOME b => TVar ((b, 0), S));
   639   in map_proof_terms (map_types (map_type_tfree thaw)) (map_type_tfree thaw) prf end;
   640 
   641 
   642 local
   643 
   644 fun new_name (ix, (pairs,used)) =
   645   let val v = Name.variant used (string_of_indexname ix)
   646   in  ((ix, v) :: pairs, v :: used)  end;
   647 
   648 fun freeze_one alist (ix, sort) = (case AList.lookup (op =) alist ix of
   649     NONE => TVar (ix, sort)
   650   | SOME name => TFree (name, sort));
   651 
   652 in
   653 
   654 fun freezeT t prf =
   655   let
   656     val used = OldTerm.it_term_types OldTerm.add_typ_tfree_names (t, [])
   657     and tvars = map #1 (OldTerm.it_term_types OldTerm.add_typ_tvars (t, []));
   658     val (alist, _) = List.foldr new_name ([], used) tvars;
   659   in
   660     (case alist of
   661       [] => prf (*nothing to do!*)
   662     | _ =>
   663       let val frzT = map_type_tvar (freeze_one alist)
   664       in map_proof_terms (map_types frzT) frzT prf end)
   665   end;
   666 
   667 end;
   668 
   669 
   670 (***** rotate assumptions *****)
   671 
   672 fun rotate_proof Bs Bi m prf =
   673   let
   674     val params = Term.strip_all_vars Bi;
   675     val asms = Logic.strip_imp_prems (Term.strip_all_body Bi);
   676     val i = length asms;
   677     val j = length Bs;
   678   in
   679     mk_AbsP (j+1, proof_combP (prf, map PBound
   680       (j downto 1) @ [mk_Abst params (mk_AbsP (i,
   681         proof_combP (proof_combt (PBound i, map Bound ((length params - 1) downto 0)),
   682           map PBound (((i-m-1) downto 0) @ ((i-1) downto (i-m))))))]))
   683   end;
   684 
   685 
   686 (***** permute premises *****)
   687 
   688 fun permute_prems_prf prems j k prf =
   689   let val n = length prems
   690   in mk_AbsP (n, proof_combP (prf,
   691     map PBound ((n-1 downto n-j) @ (k-1 downto 0) @ (n-j-1 downto k))))
   692   end;
   693 
   694 
   695 (***** generalization *****)
   696 
   697 fun generalize (tfrees, frees) idx =
   698   map_proof_terms_option
   699     (Term_Subst.generalize_option (tfrees, frees) idx)
   700     (Term_Subst.generalizeT_option tfrees idx);
   701 
   702 
   703 (***** instantiation *****)
   704 
   705 fun instantiate (instT, inst) =
   706   map_proof_terms_option
   707     (Term_Subst.instantiate_option (instT, map (apsnd remove_types) inst))
   708     (Term_Subst.instantiateT_option instT);
   709 
   710 
   711 (***** lifting *****)
   712 
   713 fun lift_proof Bi inc prop prf =
   714   let
   715     fun lift'' Us Ts t =
   716       strip_abs Ts (Logic.incr_indexes (Us, inc) (mk_abs Ts t));
   717 
   718     fun lift' Us Ts (Abst (s, T, prf)) =
   719           (Abst (s, Same.map_option (Logic.incr_tvar_same inc) T, lifth' Us (dummyT::Ts) prf)
   720            handle Same.SAME => Abst (s, T, lift' Us (dummyT::Ts) prf))
   721       | lift' Us Ts (AbsP (s, t, prf)) =
   722           (AbsP (s, Same.map_option (same (op =) (lift'' Us Ts)) t, lifth' Us Ts prf)
   723            handle Same.SAME => AbsP (s, t, lift' Us Ts prf))
   724       | lift' Us Ts (prf % t) = (lift' Us Ts prf % Option.map (lift'' Us Ts) t
   725           handle Same.SAME => prf % Same.map_option (same (op =) (lift'' Us Ts)) t)
   726       | lift' Us Ts (prf1 %% prf2) = (lift' Us Ts prf1 %% lifth' Us Ts prf2
   727           handle Same.SAME => prf1 %% lift' Us Ts prf2)
   728       | lift' _ _ (PAxm (s, prop, Ts)) =
   729           PAxm (s, prop, (Same.map_option o Same.map) (Logic.incr_tvar_same inc) Ts)
   730       | lift' _ _ (OfClass (T, c)) =
   731           OfClass (Logic.incr_tvar_same inc T, c)
   732       | lift' _ _ (Oracle (s, prop, Ts)) =
   733           Oracle (s, prop, (Same.map_option o Same.map) (Logic.incr_tvar_same inc) Ts)
   734       | lift' _ _ (Promise (i, prop, Ts)) =
   735           Promise (i, prop, Same.map (Logic.incr_tvar_same inc) Ts)
   736       | lift' _ _ (PThm (i, ((s, prop, Ts), body))) =
   737           PThm (i, ((s, prop, (Same.map_option o Same.map) (Logic.incr_tvar inc) Ts), body))
   738       | lift' _ _ _ = raise Same.SAME
   739     and lifth' Us Ts prf = (lift' Us Ts prf handle Same.SAME => prf);
   740 
   741     val ps = map (Logic.lift_all inc Bi) (Logic.strip_imp_prems prop);
   742     val k = length ps;
   743 
   744     fun mk_app b (i, j, prf) =
   745           if b then (i-1, j, prf %% PBound i) else (i, j-1, prf %> Bound j);
   746 
   747     fun lift Us bs i j (Const ("==>", _) $ A $ B) =
   748             AbsP ("H", NONE (*A*), lift Us (true::bs) (i+1) j B)
   749       | lift Us bs i j (Const ("all", _) $ Abs (a, T, t)) =
   750             Abst (a, NONE (*T*), lift (T::Us) (false::bs) i (j+1) t)
   751       | lift Us bs i j _ = proof_combP (lifth' (rev Us) [] prf,
   752             map (fn k => (#3 (fold_rev mk_app bs (i-1, j-1, PBound k))))
   753               (i + k - 1 downto i));
   754   in
   755     mk_AbsP (k, lift [] [] 0 0 Bi)
   756   end;
   757 
   758 fun incr_indexes i =
   759   map_proof_terms_option
   760     (Same.capture (Logic.incr_indexes_same ([], i)))
   761     (Same.capture (Logic.incr_tvar_same i));
   762 
   763 
   764 (***** proof by assumption *****)
   765 
   766 fun mk_asm_prf t i m =
   767   let
   768     fun imp_prf _ i 0 = PBound i
   769       | imp_prf (Const ("==>", _) $ A $ B) i m = AbsP ("H", NONE (*A*), imp_prf B (i+1) (m-1))
   770       | imp_prf _ i _ = PBound i;
   771     fun all_prf (Const ("all", _) $ Abs (a, T, t)) = Abst (a, NONE (*T*), all_prf t)
   772       | all_prf t = imp_prf t (~i) m
   773   in all_prf t end;
   774 
   775 fun assumption_proof Bs Bi n prf =
   776   mk_AbsP (length Bs, proof_combP (prf,
   777     map PBound (length Bs - 1 downto 0) @ [mk_asm_prf Bi n ~1]));
   778 
   779 
   780 (***** Composition of object rule with proof state *****)
   781 
   782 fun flatten_params_proof i j n (Const ("==>", _) $ A $ B, k) =
   783       AbsP ("H", NONE (*A*), flatten_params_proof (i+1) j n (B, k))
   784   | flatten_params_proof i j n (Const ("all", _) $ Abs (a, T, t), k) =
   785       Abst (a, NONE (*T*), flatten_params_proof i (j+1) n (t, k))
   786   | flatten_params_proof i j n (_, k) = proof_combP (proof_combt (PBound (k+i),
   787       map Bound (j-1 downto 0)), map PBound (remove (op =) (i-n) (i-1 downto 0)));
   788 
   789 fun bicompose_proof flatten Bs oldAs newAs A n m rprf sprf =
   790   let
   791     val la = length newAs;
   792     val lb = length Bs;
   793   in
   794     mk_AbsP (lb+la, proof_combP (sprf,
   795       map PBound (lb + la - 1 downto la)) %%
   796         proof_combP (rprf, (if n>0 then [mk_asm_prf (the A) n m] else []) @
   797           map (if flatten then flatten_params_proof 0 0 n else PBound o snd)
   798             (oldAs ~~ (la - 1 downto 0))))
   799   end;
   800 
   801 
   802 (***** axioms for equality *****)
   803 
   804 val aT = TFree ("'a", []);
   805 val bT = TFree ("'b", []);
   806 val x = Free ("x", aT);
   807 val y = Free ("y", aT);
   808 val z = Free ("z", aT);
   809 val A = Free ("A", propT);
   810 val B = Free ("B", propT);
   811 val f = Free ("f", aT --> bT);
   812 val g = Free ("g", aT --> bT);
   813 
   814 local open Logic in
   815 
   816 val equality_axms =
   817   [("reflexive", mk_equals (x, x)),
   818    ("symmetric", mk_implies (mk_equals (x, y), mk_equals (y, x))),
   819    ("transitive", list_implies ([mk_equals (x, y), mk_equals (y, z)], mk_equals (x, z))),
   820    ("equal_intr", list_implies ([mk_implies (A, B), mk_implies (B, A)], mk_equals (A, B))),
   821    ("equal_elim", list_implies ([mk_equals (A, B), A], B)),
   822    ("abstract_rule", mk_implies
   823       (all x (mk_equals (f $ x, g $ x)), mk_equals (lambda x (f $ x), lambda x (g $ x)))),
   824    ("combination", list_implies
   825       ([mk_equals (f, g), mk_equals (x, y)], mk_equals (f $ x, g $ y)))];
   826 
   827 val [reflexive_axm, symmetric_axm, transitive_axm, equal_intr_axm,
   828   equal_elim_axm, abstract_rule_axm, combination_axm] =
   829     map (fn (s, t) => PAxm ("Pure." ^ s, varify t, NONE)) equality_axms;
   830 
   831 end;
   832 
   833 val reflexive = reflexive_axm % NONE;
   834 
   835 fun symmetric (prf as PAxm ("Pure.reflexive", _, _) % _) = prf
   836   | symmetric prf = symmetric_axm % NONE % NONE %% prf;
   837 
   838 fun transitive _ _ (PAxm ("Pure.reflexive", _, _) % _) prf2 = prf2
   839   | transitive _ _ prf1 (PAxm ("Pure.reflexive", _, _) % _) = prf1
   840   | transitive u (Type ("prop", [])) prf1 prf2 =
   841       transitive_axm % NONE % SOME (remove_types u) % NONE %% prf1 %% prf2
   842   | transitive u T prf1 prf2 =
   843       transitive_axm % NONE % NONE % NONE %% prf1 %% prf2;
   844 
   845 fun abstract_rule x a prf =
   846   abstract_rule_axm % NONE % NONE %% forall_intr_proof x a prf;
   847 
   848 fun check_comb (PAxm ("Pure.combination", _, _) % f % g % _ % _ %% prf %% _) =
   849       is_some f orelse check_comb prf
   850   | check_comb (PAxm ("Pure.transitive", _, _) % _ % _ % _ %% prf1 %% prf2) =
   851       check_comb prf1 andalso check_comb prf2
   852   | check_comb (PAxm ("Pure.symmetric", _, _) % _ % _ %% prf) = check_comb prf
   853   | check_comb _ = false;
   854 
   855 fun combination f g t u (Type (_, [T, U])) prf1 prf2 =
   856   let
   857     val f = Envir.beta_norm f;
   858     val g = Envir.beta_norm g;
   859     val prf =  if check_comb prf1 then
   860         combination_axm % NONE % NONE
   861       else (case prf1 of
   862           PAxm ("Pure.reflexive", _, _) % _ =>
   863             combination_axm %> remove_types f % NONE
   864         | _ => combination_axm %> remove_types f %> remove_types g)
   865   in
   866     (case T of
   867        Type ("fun", _) => prf %
   868          (case head_of f of
   869             Abs _ => SOME (remove_types t)
   870           | Var _ => SOME (remove_types t)
   871           | _ => NONE) %
   872          (case head_of g of
   873             Abs _ => SOME (remove_types u)
   874           | Var _ => SOME (remove_types u)
   875           | _ => NONE) %% prf1 %% prf2
   876      | _ => prf % NONE % NONE %% prf1 %% prf2)
   877   end;
   878 
   879 fun equal_intr A B prf1 prf2 =
   880   equal_intr_axm %> remove_types A %> remove_types B %% prf1 %% prf2;
   881 
   882 fun equal_elim A B prf1 prf2 =
   883   equal_elim_axm %> remove_types A %> remove_types B %% prf1 %% prf2;
   884 
   885 
   886 (***** axioms and theorems *****)
   887 
   888 val proofs = Unsynchronized.ref 2;
   889 
   890 fun vars_of t = map Var (rev (Term.add_vars t []));
   891 fun frees_of t = map Free (rev (Term.add_frees t []));
   892 
   893 fun test_args _ [] = true
   894   | test_args is (Bound i :: ts) =
   895       not (member (op =) is i) andalso test_args (i :: is) ts
   896   | test_args _ _ = false;
   897 
   898 fun is_fun (Type ("fun", _)) = true
   899   | is_fun (TVar _) = true
   900   | is_fun _ = false;
   901 
   902 fun add_funvars Ts (vs, t) =
   903   if is_fun (fastype_of1 (Ts, t)) then
   904     vs union map_filter (fn Var (ixn, T) =>
   905       if is_fun T then SOME ixn else NONE | _ => NONE) (vars_of t)
   906   else vs;
   907 
   908 fun add_npvars q p Ts (vs, Const ("==>", _) $ t $ u) =
   909       add_npvars q p Ts (add_npvars q (not p) Ts (vs, t), u)
   910   | add_npvars q p Ts (vs, Const ("all", Type (_, [Type (_, [T, _]), _])) $ t) =
   911       add_npvars q p Ts (vs, if p andalso q then betapply (t, Var (("",0), T)) else t)
   912   | add_npvars q p Ts (vs, Abs (_, T, t)) = add_npvars q p (T::Ts) (vs, t)
   913   | add_npvars _ _ Ts (vs, t) = add_npvars' Ts (vs, t)
   914 and add_npvars' Ts (vs, t) = (case strip_comb t of
   915     (Var (ixn, _), ts) => if test_args [] ts then vs
   916       else Library.foldl (add_npvars' Ts)
   917         (AList.update (op =) (ixn,
   918           Library.foldl (add_funvars Ts) ((these ooo AList.lookup) (op =) vs ixn, ts)) vs, ts)
   919   | (Abs (_, T, u), ts) => Library.foldl (add_npvars' (T::Ts)) (vs, u :: ts)
   920   | (_, ts) => Library.foldl (add_npvars' Ts) (vs, ts));
   921 
   922 fun prop_vars (Const ("==>", _) $ P $ Q) = prop_vars P union prop_vars Q
   923   | prop_vars (Const ("all", _) $ Abs (_, _, t)) = prop_vars t
   924   | prop_vars t = (case strip_comb t of
   925       (Var (ixn, _), _) => [ixn] | _ => []);
   926 
   927 fun is_proj t =
   928   let
   929     fun is_p i t = (case strip_comb t of
   930         (Bound j, []) => false
   931       | (Bound j, ts) => j >= i orelse exists (is_p i) ts
   932       | (Abs (_, _, u), _) => is_p (i+1) u
   933       | (_, ts) => exists (is_p i) ts)
   934   in (case strip_abs_body t of
   935         Bound _ => true
   936       | t' => is_p 0 t')
   937   end;
   938 
   939 fun needed_vars prop =
   940   Library.foldl (op union)
   941     ([], map (uncurry (insert (op =))) (add_npvars true true [] ([], prop))) union
   942   prop_vars prop;
   943 
   944 fun gen_axm_proof c name prop =
   945   let
   946     val nvs = needed_vars prop;
   947     val args = map (fn (v as Var (ixn, _)) =>
   948         if member (op =) nvs ixn then SOME v else NONE) (vars_of prop) @
   949       map SOME (frees_of prop);
   950   in
   951     proof_combt' (c (name, prop, NONE), args)
   952   end;
   953 
   954 val axm_proof = gen_axm_proof PAxm;
   955 
   956 val dummy = Const (Term.dummy_patternN, dummyT);
   957 
   958 fun oracle_proof name prop =
   959   if ! proofs = 0 then ((name, dummy), Oracle (name, dummy, NONE))
   960   else ((name, prop), gen_axm_proof Oracle name prop);
   961 
   962 val shrink_proof =
   963   let
   964     fun shrink ls lev (prf as Abst (a, T, body)) =
   965           let val (b, is, ch, body') = shrink ls (lev+1) body
   966           in (b, is, ch, if ch then Abst (a, T, body') else prf) end
   967       | shrink ls lev (prf as AbsP (a, t, body)) =
   968           let val (b, is, ch, body') = shrink (lev::ls) lev body
   969           in (b orelse member (op =) is 0, map_filter (fn 0 => NONE | i => SOME (i-1)) is,
   970             ch, if ch then AbsP (a, t, body') else prf)
   971           end
   972       | shrink ls lev prf =
   973           let val (is, ch, _, prf') = shrink' ls lev [] [] prf
   974           in (false, is, ch, prf') end
   975     and shrink' ls lev ts prfs (prf as prf1 %% prf2) =
   976           let
   977             val p as (_, is', ch', prf') = shrink ls lev prf2;
   978             val (is, ch, ts', prf'') = shrink' ls lev ts (p::prfs) prf1
   979           in (is union is', ch orelse ch', ts',
   980               if ch orelse ch' then prf'' %% prf' else prf)
   981           end
   982       | shrink' ls lev ts prfs (prf as prf1 % t) =
   983           let val (is, ch, (ch', t')::ts', prf') = shrink' ls lev (t::ts) prfs prf1
   984           in (is, ch orelse ch', ts',
   985               if ch orelse ch' then prf' % t' else prf) end
   986       | shrink' ls lev ts prfs (prf as PBound i) =
   987           (if exists (fn SOME (Bound j) => lev-j <= nth ls i | _ => true) ts
   988              orelse has_duplicates (op =)
   989                (Library.foldl (fn (js, SOME (Bound j)) => j :: js | (js, _) => js) ([], ts))
   990              orelse exists #1 prfs then [i] else [], false, map (pair false) ts, prf)
   991       | shrink' ls lev ts prfs (prf as Hyp _) = ([], false, map (pair false) ts, prf)
   992       | shrink' ls lev ts prfs (prf as MinProof) = ([], false, map (pair false) ts, prf)
   993       | shrink' ls lev ts prfs (prf as OfClass _) = ([], false, map (pair false) ts, prf)
   994       | shrink' ls lev ts prfs prf =
   995           let
   996             val prop =
   997               (case prf of
   998                 PAxm (_, prop, _) => prop
   999               | Oracle (_, prop, _) => prop
  1000               | Promise (_, prop, _) => prop
  1001               | PThm (_, ((_, prop, _), _)) => prop
  1002               | _ => error "shrink: proof not in normal form");
  1003             val vs = vars_of prop;
  1004             val (ts', ts'') = chop (length vs) ts;
  1005             val insts = Library.take (length ts', map (fst o dest_Var) vs) ~~ ts';
  1006             val nvs = Library.foldl (fn (ixns', (ixn, ixns)) =>
  1007               insert (op =) ixn (case AList.lookup (op =) insts ixn of
  1008                   SOME (SOME t) => if is_proj t then ixns union ixns' else ixns'
  1009                 | _ => ixns union ixns'))
  1010                   (needed prop ts'' prfs, add_npvars false true [] ([], prop));
  1011             val insts' = map
  1012               (fn (ixn, x as SOME _) => if member (op =) nvs ixn then (false, x) else (true, NONE)
  1013                 | (_, x) => (false, x)) insts
  1014           in ([], false, insts' @ map (pair false) ts'', prf) end
  1015     and needed (Const ("==>", _) $ t $ u) ts ((b, _, _, _)::prfs) =
  1016           (if b then map (fst o dest_Var) (vars_of t) else []) union needed u ts prfs
  1017       | needed (Var (ixn, _)) (_::_) _ = [ixn]
  1018       | needed _ _ _ = [];
  1019   in shrink end;
  1020 
  1021 
  1022 (**** Simple first order matching functions for terms and proofs ****)
  1023 
  1024 exception PMatch;
  1025 
  1026 (** see pattern.ML **)
  1027 
  1028 fun flt (i: int) = List.filter (fn n => n < i);
  1029 
  1030 fun fomatch Ts tymatch j =
  1031   let
  1032     fun mtch (instsp as (tyinsts, insts)) = fn
  1033         (Var (ixn, T), t)  =>
  1034           if j>0 andalso not (null (flt j (loose_bnos t)))
  1035           then raise PMatch
  1036           else (tymatch (tyinsts, fn () => (T, fastype_of1 (Ts, t))),
  1037             (ixn, t) :: insts)
  1038       | (Free (a, T), Free (b, U)) =>
  1039           if a=b then (tymatch (tyinsts, K (T, U)), insts) else raise PMatch
  1040       | (Const (a, T), Const (b, U))  =>
  1041           if a=b then (tymatch (tyinsts, K (T, U)), insts) else raise PMatch
  1042       | (f $ t, g $ u) => mtch (mtch instsp (f, g)) (t, u)
  1043       | (Bound i, Bound j) => if i=j then instsp else raise PMatch
  1044       | _ => raise PMatch
  1045   in mtch end;
  1046 
  1047 fun match_proof Ts tymatch =
  1048   let
  1049     fun optmatch _ inst (NONE, _) = inst
  1050       | optmatch _ _ (SOME _, NONE) = raise PMatch
  1051       | optmatch mtch inst (SOME x, SOME y) = mtch inst (x, y)
  1052 
  1053     fun matcht Ts j (pinst, tinst) (t, u) =
  1054       (pinst, fomatch Ts tymatch j tinst (t, Envir.beta_norm u));
  1055     fun matchT (pinst, (tyinsts, insts)) p =
  1056       (pinst, (tymatch (tyinsts, K p), insts));
  1057     fun matchTs inst (Ts, Us) = Library.foldl (uncurry matchT) (inst, Ts ~~ Us);
  1058 
  1059     fun mtch Ts i j (pinst, tinst) (Hyp (Var (ixn, _)), prf) =
  1060           if i = 0 andalso j = 0 then ((ixn, prf) :: pinst, tinst)
  1061           else (case apfst (flt i) (apsnd (flt j)
  1062                   (prf_add_loose_bnos 0 0 prf ([], []))) of
  1063               ([], []) => ((ixn, incr_pboundvars (~i) (~j) prf) :: pinst, tinst)
  1064             | ([], _) => if j = 0 then
  1065                    ((ixn, incr_pboundvars (~i) (~j) prf) :: pinst, tinst)
  1066                  else raise PMatch
  1067             | _ => raise PMatch)
  1068       | mtch Ts i j inst (prf1 % opt1, prf2 % opt2) =
  1069           optmatch (matcht Ts j) (mtch Ts i j inst (prf1, prf2)) (opt1, opt2)
  1070       | mtch Ts i j inst (prf1 %% prf2, prf1' %% prf2') =
  1071           mtch Ts i j (mtch Ts i j inst (prf1, prf1')) (prf2, prf2')
  1072       | mtch Ts i j inst (Abst (_, opT, prf1), Abst (_, opU, prf2)) =
  1073           mtch (the_default dummyT opU :: Ts) i (j+1)
  1074             (optmatch matchT inst (opT, opU)) (prf1, prf2)
  1075       | mtch Ts i j inst (prf1, Abst (_, opU, prf2)) =
  1076           mtch (the_default dummyT opU :: Ts) i (j+1) inst
  1077             (incr_pboundvars 0 1 prf1 %> Bound 0, prf2)
  1078       | mtch Ts i j inst (AbsP (_, opt, prf1), AbsP (_, opu, prf2)) =
  1079           mtch Ts (i+1) j (optmatch (matcht Ts j) inst (opt, opu)) (prf1, prf2)
  1080       | mtch Ts i j inst (prf1, AbsP (_, _, prf2)) =
  1081           mtch Ts (i+1) j inst (incr_pboundvars 1 0 prf1 %% PBound 0, prf2)
  1082       | mtch Ts i j inst (PAxm (s1, _, opTs), PAxm (s2, _, opUs)) =
  1083           if s1 = s2 then optmatch matchTs inst (opTs, opUs)
  1084           else raise PMatch
  1085       | mtch Ts i j inst (OfClass (T1, c1), OfClass (T2, c2)) =
  1086           if c1 = c2 then matchT inst (T1, T2)
  1087           else raise PMatch
  1088       | mtch Ts i j inst (PThm (_, ((name1, prop1, opTs), _)), PThm (_, ((name2, prop2, opUs), _))) =
  1089           if name1 = name2 andalso prop1 = prop2 then
  1090             optmatch matchTs inst (opTs, opUs)
  1091           else raise PMatch
  1092       | mtch _ _ _ inst (PBound i, PBound j) = if i = j then inst else raise PMatch
  1093       | mtch _ _ _ _ _ = raise PMatch
  1094   in mtch Ts 0 0 end;
  1095 
  1096 fun prf_subst (pinst, (tyinsts, insts)) =
  1097   let
  1098     val substT = Envir.subst_type_same tyinsts;
  1099     val substTs = Same.map substT;
  1100 
  1101     fun subst' lev (Var (xi, _)) =
  1102         (case AList.lookup (op =) insts xi of
  1103           NONE => raise Same.SAME
  1104         | SOME u => incr_boundvars lev u)
  1105       | subst' _ (Const (s, T)) = Const (s, substT T)
  1106       | subst' _ (Free (s, T)) = Free (s, substT T)
  1107       | subst' lev (Abs (a, T, body)) =
  1108           (Abs (a, substT T, Same.commit (subst' (lev + 1)) body)
  1109             handle Same.SAME => Abs (a, T, subst' (lev + 1) body))
  1110       | subst' lev (f $ t) =
  1111           (subst' lev f $ Same.commit (subst' lev) t
  1112             handle Same.SAME => f $ subst' lev t)
  1113       | subst' _ _ = raise Same.SAME;
  1114 
  1115     fun subst plev tlev (AbsP (a, t, body)) =
  1116           (AbsP (a, Same.map_option (subst' tlev) t, Same.commit (subst (plev + 1) tlev) body)
  1117             handle Same.SAME => AbsP (a, t, subst (plev + 1) tlev body))
  1118       | subst plev tlev (Abst (a, T, body)) =
  1119           (Abst (a, Same.map_option substT T, Same.commit (subst plev (tlev + 1)) body)
  1120             handle Same.SAME => Abst (a, T, subst plev (tlev + 1) body))
  1121       | subst plev tlev (prf %% prf') =
  1122           (subst plev tlev prf %% Same.commit (subst plev tlev) prf'
  1123             handle Same.SAME => prf %% subst plev tlev prf')
  1124       | subst plev tlev (prf % t) =
  1125           (subst plev tlev prf % Same.commit (Same.map_option (subst' tlev)) t
  1126             handle Same.SAME => prf % Same.map_option (subst' tlev) t)
  1127       | subst plev tlev (Hyp (Var (xi, _))) =
  1128           (case AList.lookup (op =) pinst xi of
  1129             NONE => raise Same.SAME
  1130           | SOME prf' => incr_pboundvars plev tlev prf')
  1131       | subst _ _ (PAxm (id, prop, Ts)) = PAxm (id, prop, Same.map_option substTs Ts)
  1132       | subst _ _ (OfClass (T, c)) = OfClass (substT T, c)
  1133       | subst _ _ (Oracle (id, prop, Ts)) = Oracle (id, prop, Same.map_option substTs Ts)
  1134       | subst _ _ (Promise (i, prop, Ts)) = Promise (i, prop, substTs Ts)
  1135       | subst _ _ (PThm (i, ((id, prop, Ts), body))) =
  1136           PThm (i, ((id, prop, Same.map_option substTs Ts), body))
  1137       | subst _ _ _ = raise Same.SAME;
  1138   in fn t => subst 0 0 t handle Same.SAME => t end;
  1139 
  1140 (*A fast unification filter: true unless the two terms cannot be unified.
  1141   Terms must be NORMAL.  Treats all Vars as distinct. *)
  1142 fun could_unify prf1 prf2 =
  1143   let
  1144     fun matchrands (prf1 %% prf2) (prf1' %% prf2') =
  1145           could_unify prf2 prf2' andalso matchrands prf1 prf1'
  1146       | matchrands (prf % SOME t) (prf' % SOME t') =
  1147           Term.could_unify (t, t') andalso matchrands prf prf'
  1148       | matchrands (prf % _) (prf' % _) = matchrands prf prf'
  1149       | matchrands _ _ = true
  1150 
  1151     fun head_of (prf %% _) = head_of prf
  1152       | head_of (prf % _) = head_of prf
  1153       | head_of prf = prf
  1154 
  1155   in case (head_of prf1, head_of prf2) of
  1156         (_, Hyp (Var _)) => true
  1157       | (Hyp (Var _), _) => true
  1158       | (PAxm (a, _, _), PAxm (b, _, _)) => a = b andalso matchrands prf1 prf2
  1159       | (OfClass (_, c), OfClass (_, d)) => c = d andalso matchrands prf1 prf2
  1160       | (PThm (_, ((a, propa, _), _)), PThm (_, ((b, propb, _), _))) =>
  1161           a = b andalso propa = propb andalso matchrands prf1 prf2
  1162       | (PBound i, PBound j) => i = j andalso matchrands prf1 prf2
  1163       | (AbsP _, _) =>  true   (*because of possible eta equality*)
  1164       | (Abst _, _) =>  true
  1165       | (_, AbsP _) =>  true
  1166       | (_, Abst _) =>  true
  1167       | _ => false
  1168   end;
  1169 
  1170 
  1171 (**** rewriting on proof terms ****)
  1172 
  1173 val skel0 = PBound 0;
  1174 
  1175 fun rewrite_prf tymatch (rules, procs) prf =
  1176   let
  1177     fun rew _ (Abst (_, _, body) % SOME t) = SOME (prf_subst_bounds [t] body, skel0)
  1178       | rew _ (AbsP (_, _, body) %% prf) = SOME (prf_subst_pbounds [prf] body, skel0)
  1179       | rew Ts prf = (case get_first (fn r => r Ts prf) procs of
  1180           SOME prf' => SOME (prf', skel0)
  1181         | NONE => get_first (fn (prf1, prf2) => SOME (prf_subst
  1182             (match_proof Ts tymatch ([], (Vartab.empty, [])) (prf1, prf)) prf2, prf2)
  1183                handle PMatch => NONE) (filter (could_unify prf o fst) rules));
  1184 
  1185     fun rew0 Ts (prf as AbsP (_, _, prf' %% PBound 0)) =
  1186           if prf_loose_Pbvar1 prf' 0 then rew Ts prf
  1187           else
  1188             let val prf'' = incr_pboundvars (~1) 0 prf'
  1189             in SOME (the_default (prf'', skel0) (rew Ts prf'')) end
  1190       | rew0 Ts (prf as Abst (_, _, prf' % SOME (Bound 0))) =
  1191           if prf_loose_bvar1 prf' 0 then rew Ts prf
  1192           else
  1193             let val prf'' = incr_pboundvars 0 (~1) prf'
  1194             in SOME (the_default (prf'', skel0) (rew Ts prf'')) end
  1195       | rew0 Ts prf = rew Ts prf;
  1196 
  1197     fun rew1 _ (Hyp (Var _)) _ = NONE
  1198       | rew1 Ts skel prf = (case rew2 Ts skel prf of
  1199           SOME prf1 => (case rew0 Ts prf1 of
  1200               SOME (prf2, skel') => SOME (the_default prf2 (rew1 Ts skel' prf2))
  1201             | NONE => SOME prf1)
  1202         | NONE => (case rew0 Ts prf of
  1203               SOME (prf1, skel') => SOME (the_default prf1 (rew1 Ts skel' prf1))
  1204             | NONE => NONE))
  1205 
  1206     and rew2 Ts skel (prf % SOME t) = (case prf of
  1207             Abst (_, _, body) =>
  1208               let val prf' = prf_subst_bounds [t] body
  1209               in SOME (the_default prf' (rew2 Ts skel0 prf')) end
  1210           | _ => (case rew1 Ts (case skel of skel' % _ => skel' | _ => skel0) prf of
  1211               SOME prf' => SOME (prf' % SOME t)
  1212             | NONE => NONE))
  1213       | rew2 Ts skel (prf % NONE) = Option.map (fn prf' => prf' % NONE)
  1214           (rew1 Ts (case skel of skel' % _ => skel' | _ => skel0) prf)
  1215       | rew2 Ts skel (prf1 %% prf2) = (case prf1 of
  1216             AbsP (_, _, body) =>
  1217               let val prf' = prf_subst_pbounds [prf2] body
  1218               in SOME (the_default prf' (rew2 Ts skel0 prf')) end
  1219           | _ =>
  1220             let val (skel1, skel2) = (case skel of
  1221                 skel1 %% skel2 => (skel1, skel2)
  1222               | _ => (skel0, skel0))
  1223             in case rew1 Ts skel1 prf1 of
  1224                 SOME prf1' => (case rew1 Ts skel2 prf2 of
  1225                     SOME prf2' => SOME (prf1' %% prf2')
  1226                   | NONE => SOME (prf1' %% prf2))
  1227               | NONE => (case rew1 Ts skel2 prf2 of
  1228                     SOME prf2' => SOME (prf1 %% prf2')
  1229                   | NONE => NONE)
  1230             end)
  1231       | rew2 Ts skel (Abst (s, T, prf)) = (case rew1 (the_default dummyT T :: Ts)
  1232               (case skel of Abst (_, _, skel') => skel' | _ => skel0) prf of
  1233             SOME prf' => SOME (Abst (s, T, prf'))
  1234           | NONE => NONE)
  1235       | rew2 Ts skel (AbsP (s, t, prf)) = (case rew1 Ts
  1236               (case skel of AbsP (_, _, skel') => skel' | _ => skel0) prf of
  1237             SOME prf' => SOME (AbsP (s, t, prf'))
  1238           | NONE => NONE)
  1239       | rew2 _ _ _ = NONE;
  1240 
  1241   in the_default prf (rew1 [] skel0 prf) end;
  1242 
  1243 fun rewrite_proof thy = rewrite_prf (fn (tyenv, f) =>
  1244   Sign.typ_match thy (f ()) tyenv handle Type.TYPE_MATCH => raise PMatch);
  1245 
  1246 fun rewrite_proof_notypes rews = rewrite_prf fst rews;
  1247 
  1248 
  1249 (**** theory data ****)
  1250 
  1251 structure ProofData = TheoryDataFun
  1252 (
  1253   type T = (stamp * (proof * proof)) list * (stamp * (typ list -> proof -> proof option)) list;
  1254 
  1255   val empty = ([], []);
  1256   val copy = I;
  1257   val extend = I;
  1258   fun merge _ ((rules1, procs1), (rules2, procs2)) : T =
  1259     (AList.merge (op =) (K true) (rules1, rules2),
  1260       AList.merge (op =) (K true) (procs1, procs2));
  1261 );
  1262 
  1263 fun get_data thy = let val (rules, procs) = ProofData.get thy in (map #2 rules, map #2 procs) end;
  1264 fun rew_proof thy = rewrite_prf fst (get_data thy);
  1265 
  1266 fun add_prf_rrule r = (ProofData.map o apfst) (cons (stamp (), r));
  1267 fun add_prf_rproc p = (ProofData.map o apsnd) (cons (stamp (), p));
  1268 
  1269 
  1270 (***** promises *****)
  1271 
  1272 fun promise_proof thy i prop =
  1273   let
  1274     val _ = prop |> Term.exists_subterm (fn t =>
  1275       (Term.is_Free t orelse Term.is_Var t) andalso
  1276         error ("promise_proof: illegal variable " ^ Syntax.string_of_term_global thy t));
  1277     val _ = prop |> Term.exists_type (Term.exists_subtype
  1278       (fn TFree (a, _) => error ("promise_proof: illegal type variable " ^ quote a)
  1279         | _ => false));
  1280   in Promise (i, prop, map TVar (Term.add_tvars prop [])) end;
  1281 
  1282 fun fulfill_proof _ _ [] body0 = body0
  1283   | fulfill_proof thy id ps body0 =
  1284       let
  1285         val PBody {oracles = oracles0, thms = thms0, proof = proof0} = body0;
  1286         val bodies = map snd ps;
  1287         val _ = fold_body_thms (fn (i, (name, _, _)) => fn () =>
  1288           if i = id then error ("Cyclic reference to theorem " ^ quote name)
  1289           else ()) bodies ();
  1290         val oracles = fold (fn PBody {oracles, ...} => merge_oracles oracles) bodies oracles0;
  1291         val thms = fold (fn PBody {thms, ...} => merge_thms thms) bodies thms0;
  1292         val proofs = fold (fn (i, PBody {proof, ...}) => Inttab.update (i, proof)) ps Inttab.empty;
  1293 
  1294         fun fill (Promise (i, prop, Ts)) =
  1295             (case Inttab.lookup proofs i of
  1296               NONE => NONE
  1297             | SOME prf => SOME (instantiate (Term.add_tvars prop [] ~~ Ts, []) prf))
  1298           | fill _ = NONE;
  1299         val (rules, procs) = get_data thy;
  1300         val proof = rewrite_prf fst (rules, K fill :: procs) proof0;
  1301       in PBody {oracles = oracles, thms = thms, proof = proof} end;
  1302 
  1303 fun fulfill_proof_future _ _ [] body = Future.value body
  1304   | fulfill_proof_future thy id promises body =
  1305       Future.fork_deps (map snd promises) (fn () =>
  1306         fulfill_proof thy id (map (apsnd Future.join) promises) body);
  1307 
  1308 
  1309 (***** theorems *****)
  1310 
  1311 fun thm_proof thy name hyps prop promises body =
  1312   let
  1313     val PBody {oracles = oracles0, thms = thms0, proof = prf} = body;
  1314     val prop = Logic.list_implies (hyps, prop);
  1315     val nvs = needed_vars prop;
  1316     val args = map (fn (v as Var (ixn, _)) =>
  1317         if member (op =) nvs ixn then SOME v else NONE) (vars_of prop) @
  1318       map SOME (frees_of prop);
  1319 
  1320     val proof0 =
  1321       if ! proofs = 2 then
  1322         #4 (shrink_proof [] 0 (rew_proof thy (fold_rev implies_intr_proof hyps prf)))
  1323       else MinProof;
  1324     val body0 = PBody {oracles = oracles0, thms = thms0, proof = proof0};
  1325 
  1326     fun new_prf () =
  1327       let val id = serial ()
  1328       in (id, name, prop, fulfill_proof_future thy id promises body0) end;
  1329     val (i, name, prop, body') =
  1330       (case strip_combt (fst (strip_combP prf)) of
  1331         (PThm (i, ((old_name, prop', NONE), body')), args') =>
  1332           if (old_name = "" orelse old_name = name) andalso prop = prop' andalso args = args'
  1333           then (i, name, prop, body')
  1334           else new_prf ()
  1335       | _ => new_prf ());
  1336     val head = PThm (i, ((name, prop, NONE), body'));
  1337   in
  1338     ((i, (name, prop, body')), proof_combP (proof_combt' (head, args), map Hyp hyps))
  1339   end;
  1340 
  1341 fun get_name hyps prop prf =
  1342   let val prop = Logic.list_implies (hyps, prop) in
  1343     (case strip_combt (fst (strip_combP prf)) of
  1344       (PThm (_, ((name, prop', _), _)), _) => if prop = prop' then name else ""
  1345     | _ => "")
  1346   end;
  1347 
  1348 end;
  1349 
  1350 structure Basic_Proofterm : BASIC_PROOFTERM = Proofterm;
  1351 open Basic_Proofterm;