src/Pure/PIDE/command.ML
author wenzelm
Tue Jul 30 11:44:06 2013 +0200 (2013-07-30 ago)
changeset 52785 ecc7d8de4f94
parent 52784 4ba2e8b9972f
child 52850 9fff9f78240a
permissions -rw-r--r--
tuned;
     1 (*  Title:      Pure/PIDE/command.ML
     2     Author:     Makarius
     3 
     4 Prover command execution: read -- eval -- print.
     5 *)
     6 
     7 signature COMMAND =
     8 sig
     9   val read: (unit -> theory) -> Token.T list -> Toplevel.transition
    10   type eval
    11   val eval_eq: eval * eval -> bool
    12   val eval_running: eval -> bool
    13   val eval_finished: eval -> bool
    14   val eval_result_state: eval -> Toplevel.state
    15   val eval: (unit -> theory) -> Token.T list -> eval -> eval
    16   type print
    17   val print: bool -> string -> eval -> print list -> print list option
    18   type print_fn = Toplevel.transition -> Toplevel.state -> unit
    19   val print_function: string ->
    20     ({command_name: string} ->
    21       {delay: Time.time option, pri: int, persistent: bool, print_fn: print_fn} option) -> unit
    22   val no_print_function: string -> unit
    23   type exec = eval * print list
    24   val no_exec: exec
    25   val exec_ids: exec option -> Document_ID.exec list
    26   val exec: Document_ID.execution -> exec -> unit
    27 end;
    28 
    29 structure Command: COMMAND =
    30 struct
    31 
    32 (** memo results **)
    33 
    34 datatype 'a expr =
    35   Expr of Document_ID.exec * (unit -> 'a) |
    36   Result of 'a Exn.result;
    37 
    38 abstype 'a memo = Memo of 'a expr Synchronized.var
    39 with
    40 
    41 fun memo exec_id e = Memo (Synchronized.var "Command.memo" (Expr (exec_id, e)));
    42 fun memo_value a = Memo (Synchronized.var "Command.memo" (Result (Exn.Res a)));
    43 
    44 fun memo_result (Memo v) =
    45   (case Synchronized.value v of
    46     Expr (exec_id, _) => error ("Unfinished execution result: " ^ Document_ID.print exec_id)
    47   | Result res => Exn.release res);
    48 
    49 fun memo_finished (Memo v) =
    50   (case Synchronized.value v of Expr _ => false | Result _ => true);
    51 
    52 fun memo_exec execution_id (Memo v) =
    53   Synchronized.timed_access v (K (SOME Time.zeroTime))
    54     (fn expr =>
    55       (case expr of
    56         Expr (exec_id, body) =>
    57           uninterruptible (fn restore_attributes => fn () =>
    58             if Execution.running execution_id exec_id then
    59               let
    60                 val res =
    61                   (body
    62                     |> restore_attributes
    63                     |> Future.worker_nest "Command.memo_exec"
    64                     |> Exn.interruptible_capture) ();
    65               in SOME ((), Result res) end
    66             else SOME ((), expr)) ()
    67       | Result _ => SOME ((), expr)))
    68   |> (fn NONE => error "Conflicting command execution" | _ => ());
    69 
    70 fun memo_fork params execution_id (Memo v) =
    71   (case Synchronized.value v of
    72     Result _ => ()
    73   | _ => ignore ((singleton o Future.forks) params (fn () => memo_exec execution_id (Memo v))));
    74 
    75 end;
    76 
    77 
    78 
    79 (** main phases of execution **)
    80 
    81 (* read *)
    82 
    83 fun read init span =
    84   let
    85     val outer_syntax = #2 (Outer_Syntax.get_syntax ());
    86     val command_reports = Outer_Syntax.command_reports outer_syntax;
    87 
    88     val proper_range =
    89       Position.set_range (Token.position_range_of (#1 (take_suffix Token.is_improper span)));
    90     val pos =
    91       (case find_first Token.is_command span of
    92         SOME tok => Token.position_of tok
    93       | NONE => proper_range);
    94 
    95     val (is_malformed, token_reports) = Thy_Syntax.reports_of_tokens span;
    96     val _ = Position.reports_text (token_reports @ maps command_reports span);
    97   in
    98     if is_malformed then Toplevel.malformed pos "Malformed command syntax"
    99     else
   100       (case Outer_Syntax.read_spans outer_syntax span of
   101         [tr] =>
   102           if Keyword.is_control (Toplevel.name_of tr) then
   103             Toplevel.malformed pos "Illegal control command"
   104           else Toplevel.modify_init init tr
   105       | [] => Toplevel.ignored (Position.set_range (Token.position_range_of span))
   106       | _ => Toplevel.malformed proper_range "Exactly one command expected")
   107       handle ERROR msg => Toplevel.malformed proper_range msg
   108   end;
   109 
   110 
   111 (* eval *)
   112 
   113 type eval_state =
   114   {failed: bool, malformed: bool, command: Toplevel.transition, state: Toplevel.state};
   115 val init_eval_state =
   116   {failed = false, malformed = false, command = Toplevel.empty, state = Toplevel.toplevel};
   117 
   118 datatype eval = Eval of {exec_id: Document_ID.exec, eval_process: eval_state memo};
   119 
   120 fun eval_eq (Eval {exec_id, ...}, Eval {exec_id = exec_id', ...}) = exec_id = exec_id';
   121 
   122 fun eval_running (Eval {exec_id, ...}) = Execution.is_running_exec exec_id;
   123 fun eval_finished (Eval {eval_process, ...}) = memo_finished eval_process;
   124 
   125 fun eval_result (Eval {eval_process, ...}) = memo_result eval_process;
   126 val eval_result_state = #state o eval_result;
   127 
   128 local
   129 
   130 fun run int tr st =
   131   if Goal.future_enabled () andalso Keyword.is_diag (Toplevel.name_of tr) then
   132     (Goal.fork_params {name = "Toplevel.diag", pos = Toplevel.pos_of tr, pri = ~1}
   133       (fn () => Toplevel.command_exception int tr st); ([], SOME st))
   134   else Toplevel.command_errors int tr st;
   135 
   136 fun check_cmts span tr st' =
   137   Toplevel.setmp_thread_position tr
   138     (fn () =>
   139       Outer_Syntax.side_comments span |> maps (fn cmt =>
   140         (Thy_Output.check_text (Token.source_position_of cmt) st'; [])
   141           handle exn =>
   142             if Exn.is_interrupt exn then reraise exn
   143             else ML_Compiler.exn_messages_ids exn)) ();
   144 
   145 fun proof_status tr st =
   146   (case try Toplevel.proof_of st of
   147     SOME prf => Toplevel.status tr (Proof.status_markup prf)
   148   | NONE => ());
   149 
   150 fun eval_state span tr ({malformed, state = st, ...}: eval_state) =
   151   if malformed then
   152     {failed = true, malformed = malformed, command = tr, state = Toplevel.toplevel}
   153   else
   154     let
   155       val malformed' = Toplevel.is_malformed tr;
   156       val is_init = Toplevel.is_init tr;
   157       val is_proof = Keyword.is_proof (Toplevel.name_of tr);
   158 
   159       val _ = Multithreading.interrupted ();
   160       val _ = Toplevel.status tr Markup.running;
   161       val (errs1, result) = run (is_init orelse is_proof) (Toplevel.set_print false tr) st;
   162       val errs2 = (case result of NONE => [] | SOME st' => check_cmts span tr st');
   163       val errs = errs1 @ errs2;
   164       val _ = Toplevel.status tr Markup.finished;
   165       val _ = List.app (Future.error_msg (Toplevel.pos_of tr)) errs;
   166     in
   167       (case result of
   168         NONE =>
   169           let
   170             val _ = if null errs then Exn.interrupt () else ();
   171             val _ = Toplevel.status tr Markup.failed;
   172           in {failed = true, malformed = malformed', command = tr, state = st} end
   173       | SOME st' =>
   174           let
   175             val _ = proof_status tr st';
   176           in {failed = false, malformed = malformed', command = tr, state = st'} end)
   177     end;
   178 
   179 in
   180 
   181 fun eval init span eval0 =
   182   let
   183     val exec_id = Document_ID.make ();
   184     fun process () =
   185       let
   186         val tr =
   187           Position.setmp_thread_data (Position.id_only (Document_ID.print exec_id))
   188             (fn () => read init span |> Toplevel.exec_id exec_id) ();
   189       in eval_state span tr (eval_result eval0) end;
   190   in Eval {exec_id = exec_id, eval_process = memo exec_id process} end;
   191 
   192 end;
   193 
   194 
   195 (* print *)
   196 
   197 datatype print = Print of
   198  {name: string, delay: Time.time option, pri: int, persistent: bool,
   199   exec_id: Document_ID.exec, print_process: unit memo};
   200 
   201 type print_fn = Toplevel.transition -> Toplevel.state -> unit;
   202 
   203 type print_function =
   204   {command_name: string} ->
   205     {delay: Time.time option, pri: int, persistent: bool, print_fn: print_fn} option;
   206 
   207 local
   208 
   209 val print_functions =
   210   Synchronized.var "Command.print_functions" ([]: (string * print_function) list);
   211 
   212 fun print_error tr e =
   213   (Toplevel.setmp_thread_position tr o Runtime.controlled_execution) e ()
   214     handle exn =>
   215       if Exn.is_interrupt exn then reraise exn
   216       else List.app (Future.error_msg (Toplevel.pos_of tr)) (ML_Compiler.exn_messages_ids exn);
   217 
   218 fun print_eq (Print {exec_id, ...}, Print {exec_id = exec_id', ...}) = exec_id = exec_id';
   219 
   220 fun print_finished (Print {print_process, ...}) = memo_finished print_process;
   221 
   222 fun print_persistent (Print {persistent, ...}) = persistent;
   223 
   224 in
   225 
   226 fun print command_visible command_name eval old_prints =
   227   let
   228     fun new_print (name, get_pr) =
   229       let
   230         fun make_print strict {delay, pri, persistent, print_fn} =
   231           let
   232             val exec_id = Document_ID.make ();
   233             fun process () =
   234               let
   235                 val {failed, command, state = st', ...} = eval_result eval;
   236                 val tr = Toplevel.exec_id exec_id command;
   237               in
   238                 if failed andalso not strict then ()
   239                 else print_error tr (fn () => print_fn tr st')
   240               end;
   241           in
   242            Print {
   243              name = name, delay = delay, pri = pri, persistent = persistent,
   244              exec_id = exec_id, print_process = memo exec_id process}
   245           end;
   246       in
   247         (case Exn.capture (Runtime.controlled_execution get_pr) {command_name = command_name} of
   248           Exn.Res NONE => NONE
   249         | Exn.Res (SOME pr) => SOME (make_print false pr)
   250         | Exn.Exn exn =>
   251             SOME (make_print true
   252               {delay = NONE, pri = 0, persistent = false, print_fn = fn _ => fn _ => reraise exn}))
   253       end;
   254 
   255     val new_prints =
   256       if command_visible then
   257         rev (Synchronized.value print_functions) |> map_filter (fn pr =>
   258           (case find_first (fn Print {name, ...} => name = fst pr) old_prints of
   259             NONE => new_print pr
   260           | some => some))
   261       else filter (fn print => print_finished print andalso print_persistent print) old_prints;
   262   in
   263     if eq_list print_eq (old_prints, new_prints) then NONE else SOME new_prints
   264   end;
   265 
   266 fun print_function name f =
   267   Synchronized.change print_functions (fn funs =>
   268    (if not (AList.defined (op =) funs name) then ()
   269     else warning ("Redefining command print function: " ^ quote name);
   270     AList.update (op =) (name, f) funs));
   271 
   272 fun no_print_function name =
   273   Synchronized.change print_functions (filter_out (equal name o #1));
   274 
   275 end;
   276 
   277 val _ =
   278   print_function "print_state"
   279     (fn {command_name} =>
   280       SOME {delay = NONE, pri = 1, persistent = true,
   281         print_fn = fn tr => fn st' =>
   282           let
   283             val is_init = Keyword.is_theory_begin command_name;
   284             val is_proof = Keyword.is_proof command_name;
   285             val do_print =
   286               not is_init andalso
   287                 (Toplevel.print_of tr orelse (is_proof andalso Toplevel.is_proof st'));
   288           in if do_print then Toplevel.print_state false st' else () end});
   289 
   290 
   291 (* combined execution *)
   292 
   293 type exec = eval * print list;
   294 val no_exec: exec =
   295   (Eval {exec_id = Document_ID.none, eval_process = memo_value init_eval_state}, []);
   296 
   297 fun exec_ids NONE = []
   298   | exec_ids (SOME (Eval {exec_id, ...}, prints)) =
   299       exec_id :: map (fn Print {exec_id, ...} => exec_id) prints;
   300 
   301 local
   302 
   303 fun run_print execution_id (Print {name, delay, pri, print_process, ...}) =
   304   if Multithreading.enabled () then
   305     let
   306       val group = Future.worker_subgroup ();
   307       fun fork () =
   308         memo_fork {name = name, group = SOME group, deps = [], pri = pri, interrupts = true}
   309           execution_id print_process;
   310     in
   311       (case delay of
   312         NONE => fork ()
   313       | SOME d => ignore (Event_Timer.request (Time.+ (Time.now (), d)) fork))
   314     end
   315   else memo_exec execution_id print_process;
   316 
   317 in
   318 
   319 fun exec execution_id (Eval {eval_process, ...}, prints) =
   320   (memo_exec execution_id eval_process; List.app (run_print execution_id) prints);
   321 
   322 end;
   323 
   324 end;
   325