src/HOL/Imperative_HOL/Array.thy
author haftmann
Tue Jul 13 15:34:02 2010 +0200 (2010-07-13 ago)
changeset 37802 f2e9c104cebd
parent 37798 0b0570445a2a
child 37803 582d0fbd201e
permissions -rw-r--r--
canonical argument order for length
     1 (*  Title:      HOL/Imperative_HOL/Array.thy
     2     Author:     John Matthews, Galois Connections; Alexander Krauss, Lukas Bulwahn & Florian Haftmann, TU Muenchen
     3 *)
     4 
     5 header {* Monadic arrays *}
     6 
     7 theory Array
     8 imports Heap_Monad
     9 begin
    10 
    11 subsection {* Primitives *}
    12 
    13 definition (*FIXME present :: "heap \<Rightarrow> 'a\<Colon>heap array \<Rightarrow> bool" where*)
    14   array_present :: "'a\<Colon>heap array \<Rightarrow> heap \<Rightarrow> bool" where
    15   "array_present a h \<longleftrightarrow> addr_of_array a < lim h"
    16 
    17 definition (*FIXME get :: "heap \<Rightarrow> 'a\<Colon>heap array \<Rightarrow> 'a list" where*)
    18   get_array :: "'a\<Colon>heap array \<Rightarrow> heap \<Rightarrow> 'a list" where
    19   "get_array a h = map from_nat (arrays h (TYPEREP('a)) (addr_of_array a))"
    20 
    21 definition (*FIXME set*)
    22   set_array :: "'a\<Colon>heap array \<Rightarrow> 'a list \<Rightarrow> heap \<Rightarrow> heap" where
    23   "set_array a x = 
    24   arrays_update (\<lambda>h. h(TYPEREP('a) := ((h(TYPEREP('a))) (addr_of_array a:=map to_nat x))))"
    25 
    26 definition (*FIXME alloc*)
    27   array :: "'a list \<Rightarrow> heap \<Rightarrow> 'a\<Colon>heap array \<times> heap" where
    28   "array xs h = (let
    29      l = lim h;
    30      r = Array l;
    31      h'' = set_array r xs (h\<lparr>lim := l + 1\<rparr>)
    32    in (r, h''))"
    33 
    34 definition length :: "heap \<Rightarrow> 'a\<Colon>heap array \<Rightarrow> nat" where
    35   "length h a = List.length (get_array a h)"
    36   
    37 definition update :: "'a\<Colon>heap array \<Rightarrow> nat \<Rightarrow> 'a \<Rightarrow> heap \<Rightarrow> heap" where
    38   "update a i x h = set_array a ((get_array a h)[i:=x]) h"
    39 
    40 definition (*FIXME noteq*)
    41   noteq_arrs :: "'a\<Colon>heap array \<Rightarrow> 'b\<Colon>heap array \<Rightarrow> bool" (infix "=!!=" 70) where
    42   "r =!!= s \<longleftrightarrow> TYPEREP('a) \<noteq> TYPEREP('b) \<or> addr_of_array r \<noteq> addr_of_array s"
    43 
    44 
    45 subsection {* Monad operations *}
    46 
    47 definition new :: "nat \<Rightarrow> 'a\<Colon>heap \<Rightarrow> 'a array Heap" where
    48   [code del]: "new n x = Heap_Monad.heap (array (replicate n x))"
    49 
    50 definition of_list :: "'a\<Colon>heap list \<Rightarrow> 'a array Heap" where
    51   [code del]: "of_list xs = Heap_Monad.heap (array xs)"
    52 
    53 definition make :: "nat \<Rightarrow> (nat \<Rightarrow> 'a\<Colon>heap) \<Rightarrow> 'a array Heap" where
    54   [code del]: "make n f = Heap_Monad.heap (array (map f [0 ..< n]))"
    55 
    56 definition len :: "'a\<Colon>heap array \<Rightarrow> nat Heap" where
    57   [code del]: "len a = Heap_Monad.tap (\<lambda>h. length h a)"
    58 
    59 definition nth :: "'a\<Colon>heap array \<Rightarrow> nat \<Rightarrow> 'a Heap" where
    60   [code del]: "nth a i = Heap_Monad.guard (\<lambda>h. i < length h a)
    61     (\<lambda>h. (get_array a h ! i, h))"
    62 
    63 definition upd :: "nat \<Rightarrow> 'a \<Rightarrow> 'a\<Colon>heap array \<Rightarrow> 'a\<Colon>heap array Heap" where
    64   [code del]: "upd i x a = Heap_Monad.guard (\<lambda>h. i < length h a)
    65     (\<lambda>h. (a, update a i x h))"
    66 
    67 definition map_entry :: "nat \<Rightarrow> ('a\<Colon>heap \<Rightarrow> 'a) \<Rightarrow> 'a array \<Rightarrow> 'a array Heap" where
    68   [code del]: "map_entry i f a = Heap_Monad.guard (\<lambda>h. i < length h a)
    69     (\<lambda>h. (a, update a i (f (get_array a h ! i)) h))"
    70 
    71 definition swap :: "nat \<Rightarrow> 'a \<Rightarrow> 'a\<Colon>heap array \<Rightarrow> 'a Heap" where
    72   [code del]: "swap i x a = Heap_Monad.guard (\<lambda>h. i < length h a)
    73     (\<lambda>h. (get_array a h ! i, update a i x h))"
    74 
    75 definition freeze :: "'a\<Colon>heap array \<Rightarrow> 'a list Heap" where
    76   [code del]: "freeze a = Heap_Monad.tap (\<lambda>h. get_array a h)"
    77 
    78 
    79 subsection {* Properties *}
    80 
    81 text {* FIXME: Does there exist a "canonical" array axiomatisation in
    82 the literature?  *}
    83 
    84 text {* Primitives *}
    85 
    86 lemma noteq_arrs_sym: "a =!!= b \<Longrightarrow> b =!!= a"
    87   and unequal_arrs [simp]: "a \<noteq> a' \<longleftrightarrow> a =!!= a'"
    88   unfolding noteq_arrs_def by auto
    89 
    90 lemma noteq_arrs_irrefl: "r =!!= r \<Longrightarrow> False"
    91   unfolding noteq_arrs_def by auto
    92 
    93 lemma present_new_arr: "array_present a h \<Longrightarrow> a =!!= fst (array xs h)"
    94   by (simp add: array_present_def noteq_arrs_def array_def Let_def)
    95 
    96 lemma array_get_set_eq [simp]: "get_array r (set_array r x h) = x"
    97   by (simp add: get_array_def set_array_def o_def)
    98 
    99 lemma array_get_set_neq [simp]: "r =!!= s \<Longrightarrow> get_array r (set_array s x h) = get_array r h"
   100   by (simp add: noteq_arrs_def get_array_def set_array_def)
   101 
   102 lemma set_array_same [simp]:
   103   "set_array r x (set_array r y h) = set_array r x h"
   104   by (simp add: set_array_def)
   105 
   106 lemma array_set_set_swap:
   107   "r =!!= r' \<Longrightarrow> set_array r x (set_array r' x' h) = set_array r' x' (set_array r x h)"
   108   by (simp add: Let_def expand_fun_eq noteq_arrs_def set_array_def)
   109 
   110 lemma get_array_update_eq [simp]:
   111   "get_array a (update a i v h) = (get_array a h) [i := v]"
   112   by (simp add: update_def)
   113 
   114 lemma nth_update_array_neq_array [simp]:
   115   "a =!!= b \<Longrightarrow> get_array a (update b j v h) ! i = get_array a h ! i"
   116   by (simp add: update_def noteq_arrs_def)
   117 
   118 lemma get_arry_array_update_elem_neqIndex [simp]:
   119   "i \<noteq> j \<Longrightarrow> get_array a (update a j v h) ! i = get_array a h ! i"
   120   by simp
   121 
   122 lemma length_update [simp]: 
   123   "length (update b i v h) = length h"
   124   by (simp add: update_def length_def set_array_def get_array_def expand_fun_eq)
   125 
   126 lemma update_swap_neqArray:
   127   "a =!!= a' \<Longrightarrow> 
   128   update a i v (update a' i' v' h) 
   129   = update a' i' v' (update a i v h)"
   130 apply (unfold update_def)
   131 apply simp
   132 apply (subst array_set_set_swap, assumption)
   133 apply (subst array_get_set_neq)
   134 apply (erule noteq_arrs_sym)
   135 apply (simp)
   136 done
   137 
   138 lemma update_swap_neqIndex:
   139   "\<lbrakk> i \<noteq> i' \<rbrakk> \<Longrightarrow> update a i v (update a i' v' h) = update a i' v' (update a i v h)"
   140   by (auto simp add: update_def array_set_set_swap list_update_swap)
   141 
   142 lemma get_array_init_array_list:
   143   "get_array (fst (array ls h)) (snd (array ls' h)) = ls'"
   144   by (simp add: Let_def split_def array_def)
   145 
   146 lemma set_array:
   147   "set_array (fst (array ls h))
   148      new_ls (snd (array ls h))
   149        = snd (array new_ls h)"
   150   by (simp add: Let_def split_def array_def)
   151 
   152 lemma array_present_update [simp]: 
   153   "array_present a (update b i v h) = array_present a h"
   154   by (simp add: update_def array_present_def set_array_def get_array_def)
   155 
   156 lemma array_present_array [simp]:
   157   "array_present (fst (array xs h)) (snd (array xs h))"
   158   by (simp add: array_present_def array_def set_array_def Let_def)
   159 
   160 lemma not_array_present_array [simp]:
   161   "\<not> array_present (fst (array xs h)) h"
   162   by (simp add: array_present_def array_def Let_def)
   163 
   164 
   165 text {* Monad operations *}
   166 
   167 lemma execute_new [execute_simps]:
   168   "execute (new n x) h = Some (array (replicate n x) h)"
   169   by (simp add: new_def execute_simps)
   170 
   171 lemma success_newI [success_intros]:
   172   "success (new n x) h"
   173   by (auto intro: success_intros simp add: new_def)
   174 
   175 lemma crel_newI [crel_intros]:
   176   assumes "(a, h') = array (replicate n x) h"
   177   shows "crel (new n x) h h' a"
   178   by (rule crelI) (simp add: assms execute_simps)
   179 
   180 lemma crel_newE [crel_elims]:
   181   assumes "crel (new n x) h h' r"
   182   obtains "r = fst (array (replicate n x) h)" "h' = snd (array (replicate n x) h)" 
   183     "get_array r h' = replicate n x" "array_present r h'" "\<not> array_present r h"
   184   using assms by (rule crelE) (simp add: get_array_init_array_list execute_simps)
   185 
   186 lemma execute_of_list [execute_simps]:
   187   "execute (of_list xs) h = Some (array xs h)"
   188   by (simp add: of_list_def execute_simps)
   189 
   190 lemma success_of_listI [success_intros]:
   191   "success (of_list xs) h"
   192   by (auto intro: success_intros simp add: of_list_def)
   193 
   194 lemma crel_of_listI [crel_intros]:
   195   assumes "(a, h') = array xs h"
   196   shows "crel (of_list xs) h h' a"
   197   by (rule crelI) (simp add: assms execute_simps)
   198 
   199 lemma crel_of_listE [crel_elims]:
   200   assumes "crel (of_list xs) h h' r"
   201   obtains "r = fst (array xs h)" "h' = snd (array xs h)" 
   202     "get_array r h' = xs" "array_present r h'" "\<not> array_present r h"
   203   using assms by (rule crelE) (simp add: get_array_init_array_list execute_simps)
   204 
   205 lemma execute_make [execute_simps]:
   206   "execute (make n f) h = Some (array (map f [0 ..< n]) h)"
   207   by (simp add: make_def execute_simps)
   208 
   209 lemma success_makeI [success_intros]:
   210   "success (make n f) h"
   211   by (auto intro: success_intros simp add: make_def)
   212 
   213 lemma crel_makeI [crel_intros]:
   214   assumes "(a, h') = array (map f [0 ..< n]) h"
   215   shows "crel (make n f) h h' a"
   216   by (rule crelI) (simp add: assms execute_simps)
   217 
   218 lemma crel_makeE [crel_elims]:
   219   assumes "crel (make n f) h h' r"
   220   obtains "r = fst (array (map f [0 ..< n]) h)" "h' = snd (array (map f [0 ..< n]) h)" 
   221     "get_array r h' = map f [0 ..< n]" "array_present r h'" "\<not> array_present r h"
   222   using assms by (rule crelE) (simp add: get_array_init_array_list execute_simps)
   223 
   224 lemma execute_len [execute_simps]:
   225   "execute (len a) h = Some (length h a, h)"
   226   by (simp add: len_def execute_simps)
   227 
   228 lemma success_lenI [success_intros]:
   229   "success (len a) h"
   230   by (auto intro: success_intros simp add: len_def)
   231 
   232 lemma crel_lengthI [crel_intros]:
   233   assumes "h' = h" "r = length h a"
   234   shows "crel (len a) h h' r"
   235   by (rule crelI) (simp add: assms execute_simps)
   236 
   237 lemma crel_lengthE [crel_elims]:
   238   assumes "crel (len a) h h' r"
   239   obtains "r = length h' a" "h' = h" 
   240   using assms by (rule crelE) (simp add: execute_simps)
   241 
   242 lemma execute_nth [execute_simps]:
   243   "i < length h a \<Longrightarrow>
   244     execute (nth a i) h = Some (get_array a h ! i, h)"
   245   "i \<ge> length h a \<Longrightarrow> execute (nth a i) h = None"
   246   by (simp_all add: nth_def execute_simps)
   247 
   248 lemma success_nthI [success_intros]:
   249   "i < length h a \<Longrightarrow> success (nth a i) h"
   250   by (auto intro: success_intros simp add: nth_def)
   251 
   252 lemma crel_nthI [crel_intros]:
   253   assumes "i < length h a" "h' = h" "r = get_array a h ! i"
   254   shows "crel (nth a i) h h' r"
   255   by (rule crelI) (insert assms, simp add: execute_simps)
   256 
   257 lemma crel_nthE [crel_elims]:
   258   assumes "crel (nth a i) h h' r"
   259   obtains "i < length h a" "r = get_array a h ! i" "h' = h"
   260   using assms by (rule crelE)
   261     (erule successE, cases "i < length h a", simp_all add: execute_simps)
   262 
   263 lemma execute_upd [execute_simps]:
   264   "i < length h a \<Longrightarrow>
   265     execute (upd i x a) h = Some (a, update a i x h)"
   266   "i \<ge> length h a \<Longrightarrow> execute (upd i x a) h = None"
   267   by (simp_all add: upd_def execute_simps)
   268 
   269 lemma success_updI [success_intros]:
   270   "i < length h a \<Longrightarrow> success (upd i x a) h"
   271   by (auto intro: success_intros simp add: upd_def)
   272 
   273 lemma crel_updI [crel_intros]:
   274   assumes "i < length h a" "h' = update a i v h"
   275   shows "crel (upd i v a) h h' a"
   276   by (rule crelI) (insert assms, simp add: execute_simps)
   277 
   278 lemma crel_updE [crel_elims]:
   279   assumes "crel (upd i v a) h h' r"
   280   obtains "r = a" "h' = update a i v h" "i < length h a"
   281   using assms by (rule crelE)
   282     (erule successE, cases "i < length h a", simp_all add: execute_simps)
   283 
   284 lemma execute_map_entry [execute_simps]:
   285   "i < length h a \<Longrightarrow>
   286    execute (map_entry i f a) h =
   287       Some (a, update a i (f (get_array a h ! i)) h)"
   288   "i \<ge> length h a \<Longrightarrow> execute (map_entry i f a) h = None"
   289   by (simp_all add: map_entry_def execute_simps)
   290 
   291 lemma success_map_entryI [success_intros]:
   292   "i < length h a \<Longrightarrow> success (map_entry i f a) h"
   293   by (auto intro: success_intros simp add: map_entry_def)
   294 
   295 lemma crel_map_entryI [crel_intros]:
   296   assumes "i < length h a" "h' = update a i (f (get_array a h ! i)) h" "r = a"
   297   shows "crel (map_entry i f a) h h' r"
   298   by (rule crelI) (insert assms, simp add: execute_simps)
   299 
   300 lemma crel_map_entryE [crel_elims]:
   301   assumes "crel (map_entry i f a) h h' r"
   302   obtains "r = a" "h' = update a i (f (get_array a h ! i)) h" "i < length h a"
   303   using assms by (rule crelE)
   304     (erule successE, cases "i < length h a", simp_all add: execute_simps)
   305 
   306 lemma execute_swap [execute_simps]:
   307   "i < length h a \<Longrightarrow>
   308    execute (swap i x a) h =
   309       Some (get_array a h ! i, update a i x h)"
   310   "i \<ge> length h a \<Longrightarrow> execute (swap i x a) h = None"
   311   by (simp_all add: swap_def execute_simps)
   312 
   313 lemma success_swapI [success_intros]:
   314   "i < length h a \<Longrightarrow> success (swap i x a) h"
   315   by (auto intro: success_intros simp add: swap_def)
   316 
   317 lemma crel_swapI [crel_intros]:
   318   assumes "i < length h a" "h' = update a i x h" "r = get_array a h ! i"
   319   shows "crel (swap i x a) h h' r"
   320   by (rule crelI) (insert assms, simp add: execute_simps)
   321 
   322 lemma crel_swapE [crel_elims]:
   323   assumes "crel (swap i x a) h h' r"
   324   obtains "r = get_array a h ! i" "h' = update a i x h" "i < length h a"
   325   using assms by (rule crelE)
   326     (erule successE, cases "i < length h a", simp_all add: execute_simps)
   327 
   328 lemma execute_freeze [execute_simps]:
   329   "execute (freeze a) h = Some (get_array a h, h)"
   330   by (simp add: freeze_def execute_simps)
   331 
   332 lemma success_freezeI [success_intros]:
   333   "success (freeze a) h"
   334   by (auto intro: success_intros simp add: freeze_def)
   335 
   336 lemma crel_freezeI [crel_intros]:
   337   assumes "h' = h" "r = get_array a h"
   338   shows "crel (freeze a) h h' r"
   339   by (rule crelI) (insert assms, simp add: execute_simps)
   340 
   341 lemma crel_freezeE [crel_elims]:
   342   assumes "crel (freeze a) h h' r"
   343   obtains "h' = h" "r = get_array a h"
   344   using assms by (rule crelE) (simp add: execute_simps)
   345 
   346 lemma upd_return:
   347   "upd i x a \<guillemotright> return a = upd i x a"
   348   by (rule Heap_eqI) (simp add: bind_def guard_def upd_def execute_simps)
   349 
   350 lemma array_make:
   351   "new n x = make n (\<lambda>_. x)"
   352   by (rule Heap_eqI) (simp add: map_replicate_trivial execute_simps)
   353 
   354 lemma array_of_list_make:
   355   "of_list xs = make (List.length xs) (\<lambda>n. xs ! n)"
   356   by (rule Heap_eqI) (simp add: map_nth execute_simps)
   357 
   358 hide_const (open) update new of_list make len nth upd map_entry swap freeze
   359 
   360 
   361 subsection {* Code generator setup *}
   362 
   363 subsubsection {* Logical intermediate layer *}
   364 
   365 definition new' where
   366   [code del]: "new' = Array.new o Code_Numeral.nat_of"
   367 
   368 lemma [code]:
   369   "Array.new = new' o Code_Numeral.of_nat"
   370   by (simp add: new'_def o_def)
   371 
   372 definition of_list' where
   373   [code del]: "of_list' i xs = Array.of_list (take (Code_Numeral.nat_of i) xs)"
   374 
   375 lemma [code]:
   376   "Array.of_list xs = of_list' (Code_Numeral.of_nat (List.length xs)) xs"
   377   by (simp add: of_list'_def)
   378 
   379 definition make' where
   380   [code del]: "make' i f = Array.make (Code_Numeral.nat_of i) (f o Code_Numeral.of_nat)"
   381 
   382 lemma [code]:
   383   "Array.make n f = make' (Code_Numeral.of_nat n) (f o Code_Numeral.nat_of)"
   384   by (simp add: make'_def o_def)
   385 
   386 definition len' where
   387   [code del]: "len' a = Array.len a \<guillemotright>= (\<lambda>n. return (Code_Numeral.of_nat n))"
   388 
   389 lemma [code]:
   390   "Array.len a = len' a \<guillemotright>= (\<lambda>i. return (Code_Numeral.nat_of i))"
   391   by (simp add: len'_def)
   392 
   393 definition nth' where
   394   [code del]: "nth' a = Array.nth a o Code_Numeral.nat_of"
   395 
   396 lemma [code]:
   397   "Array.nth a n = nth' a (Code_Numeral.of_nat n)"
   398   by (simp add: nth'_def)
   399 
   400 definition upd' where
   401   [code del]: "upd' a i x = Array.upd (Code_Numeral.nat_of i) x a \<guillemotright> return ()"
   402 
   403 lemma [code]:
   404   "Array.upd i x a = upd' a (Code_Numeral.of_nat i) x \<guillemotright> return a"
   405   by (simp add: upd'_def upd_return)
   406 
   407 lemma [code]:
   408   "Array.map_entry i f a = do {
   409      x \<leftarrow> Array.nth a i;
   410      Array.upd i (f x) a
   411    }"
   412   by (rule Heap_eqI) (simp add: bind_def guard_def map_entry_def execute_simps)
   413 
   414 lemma [code]:
   415   "Array.swap i x a = do {
   416      y \<leftarrow> Array.nth a i;
   417      Array.upd i x a;
   418      return y
   419    }"
   420   by (rule Heap_eqI) (simp add: bind_def guard_def swap_def execute_simps)
   421 
   422 lemma [code]:
   423   "Array.freeze a = do {
   424      n \<leftarrow> Array.len a;
   425      Heap_Monad.fold_map (\<lambda>i. Array.nth a i) [0..<n]
   426    }"
   427 proof (rule Heap_eqI)
   428   fix h
   429   have *: "List.map
   430      (\<lambda>x. fst (the (if x < length h a
   431                     then Some (get_array a h ! x, h) else None)))
   432      [0..<length h a] =
   433        List.map (List.nth (get_array a h)) [0..<length h a]"
   434     by simp
   435   have "execute (Heap_Monad.fold_map (Array.nth a) [0..<length h a]) h =
   436     Some (get_array a h, h)"
   437     apply (subst execute_fold_map_unchanged_heap)
   438     apply (simp_all add: nth_def guard_def *)
   439     apply (simp add: length_def map_nth)
   440     done
   441   then have "execute (do {
   442       n \<leftarrow> Array.len a;
   443       Heap_Monad.fold_map (Array.nth a) [0..<n]
   444     }) h = Some (get_array a h, h)"
   445     by (auto intro: execute_bind_eq_SomeI simp add: execute_simps)
   446   then show "execute (Array.freeze a) h = execute (do {
   447       n \<leftarrow> Array.len a;
   448       Heap_Monad.fold_map (Array.nth a) [0..<n]
   449     }) h" by (simp add: execute_simps)
   450 qed
   451 
   452 hide_const (open) new' of_list' make' len' nth' upd'
   453 
   454 
   455 text {* SML *}
   456 
   457 code_type array (SML "_/ array")
   458 code_const Array (SML "raise/ (Fail/ \"bare Array\")")
   459 code_const Array.new' (SML "(fn/ ()/ =>/ Array.array/ ((_),/ (_)))")
   460 code_const Array.of_list' (SML "(fn/ ()/ =>/ Array.fromList/ _)")
   461 code_const Array.make' (SML "(fn/ ()/ =>/ Array.tabulate/ ((_),/ (_)))")
   462 code_const Array.len' (SML "(fn/ ()/ =>/ Array.length/ _)")
   463 code_const Array.nth' (SML "(fn/ ()/ =>/ Array.sub/ ((_),/ (_)))")
   464 code_const Array.upd' (SML "(fn/ ()/ =>/ Array.update/ ((_),/ (_),/ (_)))")
   465 
   466 code_reserved SML Array
   467 
   468 
   469 text {* OCaml *}
   470 
   471 code_type array (OCaml "_/ array")
   472 code_const Array (OCaml "failwith/ \"bare Array\"")
   473 code_const Array.new' (OCaml "(fun/ ()/ ->/ Array.make/ (Big'_int.int'_of'_big'_int/ _)/ _)")
   474 code_const Array.of_list' (OCaml "(fun/ ()/ ->/ Array.of'_list/ _)")
   475 code_const Array.len' (OCaml "(fun/ ()/ ->/ Big'_int.big'_int'_of'_int/ (Array.length/ _))")
   476 code_const Array.nth' (OCaml "(fun/ ()/ ->/ Array.get/ _/ (Big'_int.int'_of'_big'_int/ _))")
   477 code_const Array.upd' (OCaml "(fun/ ()/ ->/ Array.set/ _/ (Big'_int.int'_of'_big'_int/ _)/ _)")
   478 
   479 code_reserved OCaml Array
   480 
   481 
   482 text {* Haskell *}
   483 
   484 code_type array (Haskell "Heap.STArray/ Heap.RealWorld/ _")
   485 code_const Array (Haskell "error/ \"bare Array\"")
   486 code_const Array.new' (Haskell "Heap.newArray/ (0,/ _)")
   487 code_const Array.of_list' (Haskell "Heap.newListArray/ (0,/ _)")
   488 code_const Array.len' (Haskell "Heap.lengthArray")
   489 code_const Array.nth' (Haskell "Heap.readArray")
   490 code_const Array.upd' (Haskell "Heap.writeArray")
   491 
   492 end