src/Pure/Syntax/syntax_phases.ML
author wenzelm
Wed Dec 12 23:36:07 2012 +0100 (2012-12-12 ago)
changeset 50499 f496b2b7bafb
parent 50201 c26369c9eda6
child 52143 36ffe23b25f8
permissions -rw-r--r--
rendering of selected dialog_result as active_result_color, depending on dynamic command status in output panel, but not static popups etc.;
     1 (*  Title:      Pure/Syntax/syntax_phases.ML
     2     Author:     Makarius
     3 
     4 Main phases of inner syntax processing, with standard implementations
     5 of parse/unparse operations.
     6 *)
     7 
     8 signature SYNTAX_PHASES =
     9 sig
    10   val decode_sort: term -> sort
    11   val decode_typ: term -> typ
    12   val decode_term: Proof.context ->
    13     Position.report list * term Exn.result -> Position.report list * term Exn.result
    14   val parse_ast_pattern: Proof.context -> string * string -> Ast.ast
    15   val term_of_typ: Proof.context -> typ -> term
    16   val print_checks: Proof.context -> unit
    17   val typ_check: int -> string -> (Proof.context -> typ list -> typ list) ->
    18     Context.generic -> Context.generic
    19   val term_check: int -> string -> (Proof.context -> term list -> term list) ->
    20     Context.generic -> Context.generic
    21   val typ_uncheck: int -> string -> (Proof.context -> typ list -> typ list) ->
    22     Context.generic -> Context.generic
    23   val term_uncheck: int -> string -> (Proof.context -> term list -> term list) ->
    24     Context.generic -> Context.generic
    25   val typ_check': int -> string ->
    26     (typ list -> Proof.context -> (typ list * Proof.context) option) ->
    27     Context.generic -> Context.generic
    28   val term_check': int -> string ->
    29     (term list -> Proof.context -> (term list * Proof.context) option) ->
    30     Context.generic -> Context.generic
    31   val typ_uncheck': int -> string ->
    32     (typ list -> Proof.context -> (typ list * Proof.context) option) ->
    33     Context.generic -> Context.generic
    34   val term_uncheck': int -> string ->
    35     (term list -> Proof.context -> (term list * Proof.context) option) ->
    36     Context.generic -> Context.generic
    37 end
    38 
    39 structure Syntax_Phases: SYNTAX_PHASES =
    40 struct
    41 
    42 (** markup logical entities **)
    43 
    44 fun markup_class ctxt c =
    45   [Name_Space.markup (Type.class_space (Proof_Context.tsig_of ctxt)) c];
    46 
    47 fun markup_type ctxt c =
    48   [Name_Space.markup (Type.type_space (Proof_Context.tsig_of ctxt)) c];
    49 
    50 fun markup_const ctxt c =
    51   [Name_Space.markup (Consts.space_of (Proof_Context.consts_of ctxt)) c];
    52 
    53 fun markup_free ctxt x =
    54   [if can Name.dest_skolem x then Markup.skolem else Markup.free] @
    55   (if Variable.is_body ctxt orelse Variable.is_fixed ctxt x
    56    then [Variable.markup_fixed ctxt x]
    57    else []);
    58 
    59 fun markup_var xi = [Markup.name (Term.string_of_vname xi) Markup.var];
    60 
    61 fun markup_bound def ps (name, id) =
    62   let val entity = Markup.entity Markup.boundN name in
    63     Markup.bound ::
    64       map (fn pos => Markup.properties (Position.entity_properties_of def id pos) entity) ps
    65   end;
    66 
    67 fun markup_entity ctxt c =
    68   (case Syntax.lookup_const (Proof_Context.syn_of ctxt) c of
    69     SOME "" => []
    70   | SOME b => markup_entity ctxt b
    71   | NONE => c |> Lexicon.unmark
    72      {case_class = markup_class ctxt,
    73       case_type = markup_type ctxt,
    74       case_const = markup_const ctxt,
    75       case_fixed = markup_free ctxt,
    76       case_default = K []});
    77 
    78 
    79 
    80 (** decode parse trees **)
    81 
    82 (* decode_sort *)
    83 
    84 fun decode_sort tm =
    85   let
    86     fun err () = raise TERM ("decode_sort: bad encoding of classes", [tm]);
    87 
    88     fun class s = Lexicon.unmark_class s handle Fail _ => err ();
    89 
    90     fun classes (Const (s, _)) = [class s]
    91       | classes (Const ("_classes", _) $ Const (s, _) $ cs) = class s :: classes cs
    92       | classes _ = err ();
    93 
    94     fun sort (Const ("_topsort", _)) = []
    95       | sort (Const ("_sort", _) $ cs) = classes cs
    96       | sort (Const (s, _)) = [class s]
    97       | sort _ = err ();
    98   in sort tm end;
    99 
   100 
   101 (* decode_typ *)
   102 
   103 fun decode_pos (Free (s, _)) =
   104       if is_some (Term_Position.decode s) then SOME s else NONE
   105   | decode_pos _ = NONE;
   106 
   107 fun decode_typ tm =
   108   let
   109     fun err () = raise TERM ("decode_typ: bad encoding of type", [tm]);
   110 
   111     fun typ ps sort tm =
   112       (case tm of
   113         Const ("_tfree", _) $ t => typ ps sort t
   114       | Const ("_tvar", _) $ t => typ ps sort t
   115       | Const ("_ofsort", _) $ t $ s =>
   116           (case decode_pos s of
   117             SOME p => typ (p :: ps) sort t
   118           | NONE =>
   119               if is_none sort then typ ps (SOME (decode_sort s)) t
   120               else err ())
   121       | Const ("_dummy_ofsort", _) $ s => TFree ("'_dummy_", decode_sort s)
   122       | Free (x, _) => TFree (x, ps @ the_default dummyS sort)
   123       | Var (xi, _) => TVar (xi, ps @ the_default dummyS sort)
   124       | _ =>
   125           if null ps andalso is_none sort then
   126             let
   127               val (head, args) = Term.strip_comb tm;
   128               val a =
   129                 (case head of
   130                   Const (c, _) => (Lexicon.unmark_type c handle Fail _ => err ())
   131                 | _ => err ());
   132             in Type (a, map (typ [] NONE) args) end
   133           else err ());
   134   in typ [] NONE tm end;
   135 
   136 
   137 (* parsetree_to_ast *)
   138 
   139 fun parsetree_to_ast ctxt raw trf parsetree =
   140   let
   141     val reports = Unsynchronized.ref ([]: Position.report list);
   142     fun report pos = Position.store_reports reports [pos];
   143 
   144     fun trans a args =
   145       (case trf a of
   146         NONE => Ast.mk_appl (Ast.Constant a) args
   147       | SOME f => f ctxt args);
   148 
   149     fun asts_of_token tok =
   150       if Lexicon.valued_token tok
   151       then [Ast.Variable (Lexicon.str_of_token tok)]
   152       else [];
   153 
   154     fun asts_of_position c tok =
   155       if raw then asts_of_token tok
   156       else
   157         [Ast.Appl [Ast.Constant c, ast_of (Parser.Tip tok),
   158           Ast.Variable (Term_Position.encode (Lexicon.pos_of_token tok))]]
   159 
   160     and asts_of (Parser.Node ("_class_name", [Parser.Tip tok])) =
   161           let
   162             val pos = Lexicon.pos_of_token tok;
   163             val c = Proof_Context.read_class ctxt (Lexicon.str_of_token tok)
   164               handle ERROR msg => error (msg ^ Position.here pos);
   165             val _ = report pos (markup_class ctxt) c;
   166           in [Ast.Constant (Lexicon.mark_class c)] end
   167       | asts_of (Parser.Node ("_type_name", [Parser.Tip tok])) =
   168           let
   169             val pos = Lexicon.pos_of_token tok;
   170             val Type (c, _) =
   171               Proof_Context.read_type_name_proper ctxt false (Lexicon.str_of_token tok)
   172                 handle ERROR msg => error (msg ^ Position.here pos);
   173             val _ = report pos (markup_type ctxt) c;
   174           in [Ast.Constant (Lexicon.mark_type c)] end
   175       | asts_of (Parser.Node ("_position", [Parser.Tip tok])) = asts_of_position "_constrain" tok
   176       | asts_of (Parser.Node ("_position_sort", [Parser.Tip tok])) = asts_of_position "_ofsort" tok
   177       | asts_of (Parser.Node (a, pts)) =
   178           let
   179             val _ = pts |> List.app
   180               (fn Parser.Node _ => () | Parser.Tip tok =>
   181                 if Lexicon.valued_token tok then ()
   182                 else report (Lexicon.pos_of_token tok) (markup_entity ctxt) a);
   183           in [trans a (maps asts_of pts)] end
   184       | asts_of (Parser.Tip tok) = asts_of_token tok
   185 
   186     and ast_of pt =
   187       (case asts_of pt of
   188         [ast] => ast
   189       | asts => raise Ast.AST ("parsetree_to_ast: malformed parsetree", asts));
   190 
   191     val ast = Exn.interruptible_capture ast_of parsetree;
   192   in (! reports, ast) end;
   193 
   194 
   195 (* ast_to_term *)
   196 
   197 fun ast_to_term ctxt trf =
   198   let
   199     fun trans a args =
   200       (case trf a of
   201         NONE => Term.list_comb (Syntax.const a, args)
   202       | SOME f => f ctxt args);
   203 
   204     fun term_of (Ast.Constant a) = trans a []
   205       | term_of (Ast.Variable x) = Lexicon.read_var x
   206       | term_of (Ast.Appl (Ast.Constant a :: (asts as _ :: _))) =
   207           trans a (map term_of asts)
   208       | term_of (Ast.Appl (ast :: (asts as _ :: _))) =
   209           Term.list_comb (term_of ast, map term_of asts)
   210       | term_of (ast as Ast.Appl _) = raise Ast.AST ("ast_to_term: malformed ast", [ast]);
   211   in term_of end;
   212 
   213 
   214 (* decode_term -- transform parse tree into raw term *)
   215 
   216 fun decode_term _ (result as (_: Position.report list, Exn.Exn _)) = result
   217   | decode_term ctxt (reports0, Exn.Res tm) =
   218       let
   219         fun get_const a =
   220           ((true, #1 (Term.dest_Const (Proof_Context.read_const_proper ctxt false a)))
   221             handle ERROR _ => (false, Consts.intern (Proof_Context.consts_of ctxt) a));
   222         val get_free = Proof_Context.intern_skolem ctxt;
   223 
   224         val reports = Unsynchronized.ref reports0;
   225         fun report ps = Position.store_reports reports ps;
   226 
   227         fun decode ps qs bs (Const ("_constrain", _) $ t $ typ) =
   228               (case Term_Position.decode_position typ of
   229                 SOME (p, T) => Type.constraint T (decode (p :: ps) qs bs t)
   230               | NONE => Type.constraint (decode_typ typ) (decode ps qs bs t))
   231           | decode ps qs bs (Const ("_constrainAbs", _) $ t $ typ) =
   232               (case Term_Position.decode_position typ of
   233                 SOME (q, T) => Type.constraint (T --> dummyT) (decode ps (q :: qs) bs t)
   234               | NONE => Type.constraint (decode_typ typ --> dummyT) (decode ps qs bs t))
   235           | decode _ qs bs (Abs (x, T, t)) =
   236               let
   237                 val id = serial ();
   238                 val _ = report qs (markup_bound true qs) (x, id);
   239               in Abs (x, T, decode [] [] ((qs, (x, id)) :: bs) t) end
   240           | decode _ _ bs (t $ u) = decode [] [] bs t $ decode [] [] bs u
   241           | decode ps _ _ (Const (a, T)) =
   242               (case try Lexicon.unmark_fixed a of
   243                 SOME x => (report ps (markup_free ctxt) x; Free (x, T))
   244               | NONE =>
   245                   let
   246                     val c =
   247                       (case try Lexicon.unmark_const a of
   248                         SOME c => c
   249                       | NONE => snd (get_const a));
   250                     val _ = report ps (markup_const ctxt) c;
   251                   in Const (c, T) end)
   252           | decode ps _ _ (Free (a, T)) =
   253               (case (get_free a, get_const a) of
   254                 (SOME x, _) => (report ps (markup_free ctxt) x; Free (x, T))
   255               | (_, (true, c)) => (report ps (markup_const ctxt) c; Const (c, T))
   256               | (_, (false, c)) =>
   257                   if Long_Name.is_qualified c
   258                   then (report ps (markup_const ctxt) c; Const (c, T))
   259                   else (report ps (markup_free ctxt) c; Free (c, T)))
   260           | decode ps _ _ (Var (xi, T)) = (report ps markup_var xi; Var (xi, T))
   261           | decode ps _ bs (t as Bound i) =
   262               (case try (nth bs) i of
   263                 SOME (qs, (x, id)) => (report ps (markup_bound false qs) (x, id); t)
   264               | NONE => t);
   265 
   266         val tm' = Exn.interruptible_capture (fn () => decode [] [] [] tm) ();
   267       in (! reports, tm') end;
   268 
   269 
   270 
   271 (** parse **)
   272 
   273 (* results *)
   274 
   275 fun proper_results results = map_filter (fn (y, Exn.Res x) => SOME (y, x) | _ => NONE) results;
   276 fun failed_results results = map_filter (fn (y, Exn.Exn e) => SOME (y, e) | _ => NONE) results;
   277 
   278 fun report_result ctxt pos ambig_msgs results =
   279   (case (proper_results results, failed_results results) of
   280     ([], (reports, exn) :: _) => (Context_Position.reports ctxt reports; reraise exn)
   281   | ([(reports, x)], _) => (Context_Position.reports ctxt reports; x)
   282   | _ =>
   283       if null ambig_msgs then
   284         error ("Parse error: ambiguous syntax" ^ Position.here pos)
   285       else error (cat_lines ambig_msgs));
   286 
   287 
   288 (* parse raw asts *)
   289 
   290 fun parse_asts ctxt raw root (syms, pos) =
   291   let
   292     val syn = Proof_Context.syn_of ctxt;
   293     val ast_tr = Syntax.parse_ast_translation syn;
   294 
   295     val toks = Syntax.tokenize syn raw syms;
   296     val _ = Context_Position.reports ctxt (map Lexicon.report_of_token toks);
   297 
   298     val pts = Syntax.parse syn root (filter Lexicon.is_proper toks)
   299       handle ERROR msg =>
   300         error (msg ^
   301           implode (map (Markup.markup Markup.report o Lexicon.reported_token_range ctxt) toks));
   302     val len = length pts;
   303 
   304     val limit = Config.get ctxt Syntax.ambiguity_limit;
   305     val ambig_msgs =
   306       if len <= 1 then []
   307       else
   308         [cat_lines
   309           (("Ambiguous input" ^ Position.here (Position.reset_range pos) ^
   310             "\nproduces " ^ string_of_int len ^ " parse trees" ^
   311             (if len <= limit then "" else " (" ^ string_of_int limit ^ " displayed)") ^ ":") ::
   312             map (Pretty.string_of o Parser.pretty_parsetree) (take limit pts))];
   313 
   314   in (ambig_msgs, map (parsetree_to_ast ctxt raw ast_tr) pts) end;
   315 
   316 fun parse_tree ctxt root input =
   317   let
   318     val syn = Proof_Context.syn_of ctxt;
   319     val tr = Syntax.parse_translation syn;
   320     val parse_rules = Syntax.parse_rules syn;
   321     val (ambig_msgs, asts) = parse_asts ctxt false root input;
   322     val results =
   323       (map o apsnd o Exn.maps_result)
   324         (Ast.normalize ctxt parse_rules #> Exn.interruptible_capture (ast_to_term ctxt tr)) asts;
   325   in (ambig_msgs, results) end;
   326 
   327 
   328 (* parse logical entities *)
   329 
   330 fun parse_failed ctxt pos msg kind =
   331   cat_error msg ("Failed to parse " ^ kind ^
   332     Markup.markup Markup.report (Context_Position.reported_text ctxt pos Markup.bad ""));
   333 
   334 fun parse_sort ctxt =
   335   Syntax.parse_token ctxt Term_XML.Decode.sort Markup.sort
   336     (fn (syms, pos) =>
   337       parse_tree ctxt "sort" (syms, pos)
   338       |> uncurry (report_result ctxt pos)
   339       |> decode_sort
   340       |> Type.minimize_sort (Proof_Context.tsig_of ctxt)
   341       handle ERROR msg => parse_failed ctxt pos msg "sort");
   342 
   343 fun parse_typ ctxt =
   344   Syntax.parse_token ctxt Term_XML.Decode.typ Markup.typ
   345     (fn (syms, pos) =>
   346       parse_tree ctxt "type" (syms, pos)
   347       |> uncurry (report_result ctxt pos)
   348       |> decode_typ
   349       handle ERROR msg => parse_failed ctxt pos msg "type");
   350 
   351 fun parse_term is_prop ctxt =
   352   let
   353     val (markup, kind, root, constrain) =
   354       if is_prop
   355       then (Markup.prop, "proposition", "prop", Type.constraint propT)
   356       else (Markup.term, "term", Config.get ctxt Syntax.root, I);
   357     val decode = constrain o Term_XML.Decode.term;
   358   in
   359     Syntax.parse_token ctxt decode markup
   360       (fn (syms, pos) =>
   361         let
   362           val (ambig_msgs, results) = parse_tree ctxt root (syms, pos) ||> map (decode_term ctxt);
   363           val parsed_len = length (proper_results results);
   364 
   365           val ambiguity_warning = Config.get ctxt Syntax.ambiguity_warning;
   366           val limit = Config.get ctxt Syntax.ambiguity_limit;
   367 
   368           (*brute-force disambiguation via type-inference*)
   369           fun check t = (Syntax.check_term ctxt (constrain t); Exn.Res t)
   370             handle exn as ERROR _ => Exn.Exn exn;
   371 
   372           val results' =
   373             if parsed_len > 1 then
   374               (grouped 10 (Par_List.map_name "Syntax_Phases.parse_term") o apsnd o Exn.maps_result)
   375                 check results
   376             else results;
   377           val reports' = fst (hd results');
   378 
   379           val errs = map snd (failed_results results');
   380           val checked = map snd (proper_results results');
   381           val checked_len = length checked;
   382 
   383           val show_term = Syntax.string_of_term (Config.put Printer.show_brackets true ctxt);
   384         in
   385           if checked_len = 0 then
   386             report_result ctxt pos []
   387               [(reports', Exn.Exn (Exn.EXCEPTIONS (map ERROR ambig_msgs @ errs)))]
   388           else if checked_len = 1 then
   389             (if parsed_len > 1 andalso ambiguity_warning then
   390               Context_Position.if_visible ctxt warning
   391                 (cat_lines (ambig_msgs @
   392                   ["Fortunately, only one parse tree is type correct" ^
   393                   Position.here (Position.reset_range pos) ^
   394                   ",\nbut you may still want to disambiguate your grammar or your input."]))
   395              else (); report_result ctxt pos [] results')
   396           else
   397             report_result ctxt pos []
   398               [(reports', Exn.Exn (ERROR (cat_lines (ambig_msgs @
   399                 (("Ambiguous input\n" ^ string_of_int checked_len ^ " terms are type correct" ^
   400                   (if checked_len <= limit then ""
   401                    else " (" ^ string_of_int limit ^ " displayed)") ^ ":") ::
   402                   map show_term (take limit checked))))))]
   403         end handle ERROR msg => parse_failed ctxt pos msg kind)
   404   end;
   405 
   406 
   407 (* parse_ast_pattern *)
   408 
   409 fun parse_ast_pattern ctxt (root, str) =
   410   let
   411     val syn = Proof_Context.syn_of ctxt;
   412 
   413     fun constify (ast as Ast.Constant _) = ast
   414       | constify (ast as Ast.Variable x) =
   415           if is_some (Syntax.lookup_const syn x) orelse Long_Name.is_qualified x
   416           then Ast.Constant x
   417           else ast
   418       | constify (Ast.Appl asts) = Ast.Appl (map constify asts);
   419 
   420     val (syms, pos) = Syntax.read_token str;
   421   in
   422     parse_asts ctxt true root (syms, pos)
   423     |> uncurry (report_result ctxt pos)
   424     |> constify
   425   end;
   426 
   427 
   428 
   429 (** encode parse trees **)
   430 
   431 (* term_of_sort *)
   432 
   433 fun term_of_sort S =
   434   let
   435     val class = Syntax.const o Lexicon.mark_class;
   436 
   437     fun classes [c] = class c
   438       | classes (c :: cs) = Syntax.const "_classes" $ class c $ classes cs;
   439   in
   440     (case S of
   441       [] => Syntax.const "_topsort"
   442     | [c] => class c
   443     | cs => Syntax.const "_sort" $ classes cs)
   444   end;
   445 
   446 
   447 (* term_of_typ *)
   448 
   449 fun term_of_typ ctxt ty =
   450   let
   451     val show_sort_constraint = Printer.show_sort_constraint ctxt;
   452 
   453     fun ofsort t raw_S =
   454       if show_sort_constraint then
   455         let val S = #2 (Term_Position.decode_positionS raw_S)
   456         in if S = dummyS then t else Syntax.const "_ofsort" $ t $ term_of_sort S end
   457       else t;
   458 
   459     fun term_of (Type (a, Ts)) =
   460           Term.list_comb (Syntax.const (Lexicon.mark_type a), map term_of Ts)
   461       | term_of (TFree (x, S)) =
   462           if is_some (Term_Position.decode x) then Syntax.free x
   463           else ofsort (Syntax.const "_tfree" $ Syntax.free x) S
   464       | term_of (TVar (xi, S)) = ofsort (Syntax.const "_tvar" $ Syntax.var xi) S;
   465   in term_of ty end;
   466 
   467 
   468 (* simple_ast_of *)
   469 
   470 fun simple_ast_of ctxt =
   471   let
   472     val tune_var = if Config.get ctxt show_question_marks then I else unprefix "?";
   473     fun ast_of (Const (c, _)) = Ast.Constant c
   474       | ast_of (Free (x, _)) = Ast.Variable x
   475       | ast_of (Var (xi, _)) = Ast.Variable (tune_var (Term.string_of_vname xi))
   476       | ast_of (t as _ $ _) =
   477           let val (f, args) = strip_comb t
   478           in Ast.mk_appl (ast_of f) (map ast_of args) end
   479       | ast_of (Bound i) = Ast.Appl [Ast.Constant "_loose", Ast.Variable ("B." ^ string_of_int i)]
   480       | ast_of (Abs _) = raise Fail "simple_ast_of: Abs";
   481   in ast_of end;
   482 
   483 
   484 (* sort_to_ast and typ_to_ast *)
   485 
   486 fun ast_of_termT ctxt trf tm =
   487   let
   488     val ctxt' = Config.put show_sorts false ctxt;
   489     fun ast_of (t as Const ("_tfree", _) $ Free _) = simple_ast_of ctxt t
   490       | ast_of (t as Const ("_tvar", _) $ Var _) = simple_ast_of ctxt t
   491       | ast_of (Const (a, _)) = trans a []
   492       | ast_of (t as _ $ _) =
   493           (case strip_comb t of
   494             (Const (a, _), args) => trans a args
   495           | (f, args) => Ast.Appl (map ast_of (f :: args)))
   496       | ast_of t = simple_ast_of ctxt t
   497     and trans a args = ast_of (trf a ctxt' dummyT args)
   498       handle Match => Ast.mk_appl (Ast.Constant a) (map ast_of args);
   499   in ast_of tm end;
   500 
   501 fun sort_to_ast ctxt trf S = ast_of_termT ctxt trf (term_of_sort S);
   502 fun typ_to_ast ctxt trf T = ast_of_termT ctxt trf (term_of_typ ctxt T);
   503 
   504 
   505 (* term_to_ast *)
   506 
   507 fun term_to_ast idents is_syntax_const ctxt trf tm =
   508   let
   509     val show_types =
   510       Config.get ctxt show_types orelse Config.get ctxt show_sorts orelse
   511       Config.get ctxt show_all_types;
   512     val show_structs = Config.get ctxt show_structs;
   513     val show_free_types = Config.get ctxt show_free_types;
   514     val show_all_types = Config.get ctxt show_all_types;
   515     val show_markup = Config.get ctxt show_markup;
   516 
   517     val {structs, fixes} = idents;
   518 
   519     fun mark_atoms ((t as Const (c, _)) $ u) =
   520           if member (op =) Syntax.token_markers c
   521           then t $ u else mark_atoms t $ mark_atoms u
   522       | mark_atoms (t $ u) = mark_atoms t $ mark_atoms u
   523       | mark_atoms (Abs (x, T, t)) = Abs (x, T, mark_atoms t)
   524       | mark_atoms (t as Const (c, T)) =
   525           if is_syntax_const c then t
   526           else Const (Lexicon.mark_const c, T)
   527       | mark_atoms (t as Free (x, T)) =
   528           let val i = find_index (fn s => s = x) structs + 1 in
   529             if i = 0 andalso member (op =) fixes x then
   530               Const (Lexicon.mark_fixed x, T)
   531             else if i = 1 andalso not show_structs then
   532               Syntax.const "_struct" $ Syntax.const "_indexdefault"
   533             else Syntax.const "_free" $ t
   534           end
   535       | mark_atoms (t as Var (xi, T)) =
   536           if xi = Syntax_Ext.dddot_indexname then Const ("_DDDOT", T)
   537           else Syntax.const "_var" $ t
   538       | mark_atoms a = a;
   539 
   540     fun prune_typs (t_seen as (Const _, _)) = t_seen
   541       | prune_typs (t as Free (x, ty), seen) =
   542           if ty = dummyT then (t, seen)
   543           else if not show_free_types orelse member (op aconv) seen t then (Syntax.free x, seen)
   544           else (t, t :: seen)
   545       | prune_typs (t as Var (xi, ty), seen) =
   546           if ty = dummyT then (t, seen)
   547           else if not show_free_types orelse member (op aconv) seen t then (Syntax.var xi, seen)
   548           else (t, t :: seen)
   549       | prune_typs (t_seen as (Bound _, _)) = t_seen
   550       | prune_typs (Abs (x, ty, t), seen) =
   551           let val (t', seen') = prune_typs (t, seen);
   552           in (Abs (x, ty, t'), seen') end
   553       | prune_typs (t1 $ t2, seen) =
   554           let
   555             val (t1', seen') = prune_typs (t1, seen);
   556             val (t2', seen'') = prune_typs (t2, seen');
   557           in (t1' $ t2', seen'') end;
   558 
   559     fun ast_of tm =
   560       (case strip_comb tm of
   561         (t as Abs _, ts) => Ast.mk_appl (ast_of (Syntax_Trans.abs_tr' ctxt t)) (map ast_of ts)
   562       | ((c as Const ("_free", _)), Free (x, T) :: ts) =>
   563           Ast.mk_appl (constrain (c $ Syntax.free x) T) (map ast_of ts)
   564       | ((c as Const ("_var", _)), Var (xi, T) :: ts) =>
   565           Ast.mk_appl (constrain (c $ Syntax.var xi) T) (map ast_of ts)
   566       | ((c as Const ("_bound", B)), Free (x, T) :: ts) =>
   567           let
   568             val X =
   569               if show_markup andalso not show_types orelse B <> dummyT then T
   570               else dummyT;
   571           in Ast.mk_appl (constrain (c $ Syntax.free x) X) (map ast_of ts) end
   572       | (Const ("_idtdummy", T), ts) =>
   573           Ast.mk_appl (constrain (Syntax.const "_idtdummy") T) (map ast_of ts)
   574       | (const as Const (c, T), ts) =>
   575           if show_all_types
   576           then Ast.mk_appl (constrain const T) (map ast_of ts)
   577           else trans c T ts
   578       | (t, ts) => Ast.mk_appl (simple_ast_of ctxt t) (map ast_of ts))
   579 
   580     and trans a T args = ast_of (trf a ctxt T args)
   581       handle Match => Ast.mk_appl (Ast.Constant a) (map ast_of args)
   582 
   583     and constrain t T =
   584       if (show_types orelse show_markup) andalso T <> dummyT then
   585         Ast.Appl [Ast.Constant "_constrain", simple_ast_of ctxt t,
   586           ast_of_termT ctxt trf (term_of_typ ctxt T)]
   587       else simple_ast_of ctxt t;
   588   in
   589     tm
   590     |> Syntax_Trans.prop_tr'
   591     |> show_types ? (#1 o prune_typs o rpair [])
   592     |> mark_atoms
   593     |> ast_of
   594   end;
   595 
   596 
   597 
   598 (** unparse **)
   599 
   600 local
   601 
   602 fun free_or_skolem ctxt x =
   603   let
   604     val m =
   605       if Variable.is_fixed ctxt x orelse Syntax.is_pretty_global ctxt
   606       then Markup.fixed x else Markup.intensify;
   607   in
   608     if can Name.dest_skolem x
   609     then ([m, Markup.skolem], Variable.revert_fixed ctxt x)
   610     else ([m, Markup.free], x)
   611   end;
   612 
   613 fun var_or_skolem s =
   614   (case Lexicon.read_variable s of
   615     SOME (x, i) =>
   616       (case try Name.dest_skolem x of
   617         NONE => (Markup.var, s)
   618       | SOME x' => (Markup.skolem, Term.string_of_vname (x', i)))
   619   | NONE => (Markup.var, s));
   620 
   621 val typing_elem = YXML.output_markup_elem Markup.typing;
   622 val sorting_elem = YXML.output_markup_elem Markup.sorting;
   623 
   624 fun unparse_t t_to_ast prt_t markup ctxt t =
   625   let
   626     val show_markup = Config.get ctxt show_markup;
   627     val show_sorts = Config.get ctxt show_sorts;
   628     val show_types =
   629       Config.get ctxt show_types orelse show_sorts orelse
   630       Config.get ctxt show_all_types;
   631 
   632     val syn = Proof_Context.syn_of ctxt;
   633     val prtabs = Syntax.prtabs syn;
   634     val trf = Syntax.print_ast_translation syn;
   635 
   636     fun markup_extern c =
   637       (case Syntax.lookup_const syn c of
   638         SOME "" => ([], c)
   639       | SOME b => markup_extern b
   640       | NONE => c |> Lexicon.unmark
   641          {case_class = fn x => (markup_class ctxt x, Proof_Context.extern_class ctxt x),
   642           case_type = fn x => (markup_type ctxt x, Proof_Context.extern_type ctxt x),
   643           case_const = fn x => (markup_const ctxt x, Proof_Context.extern_const ctxt x),
   644           case_fixed = fn x => free_or_skolem ctxt x,
   645           case_default = fn x => ([], x)});
   646 
   647     fun token_trans "_tfree" x = SOME (Pretty.mark_str (Markup.tfree, x))
   648       | token_trans "_tvar" x = SOME (Pretty.mark_str (Markup.tvar, x))
   649       | token_trans "_free" x = SOME (Pretty.marks_str (free_or_skolem ctxt x))
   650       | token_trans "_bound" x = SOME (Pretty.mark_str (Markup.bound, x))
   651       | token_trans "_loose" x = SOME (Pretty.mark_str (Markup.bad, x))
   652       | token_trans "_var" x = SOME (Pretty.mark_str (var_or_skolem x))
   653       | token_trans "_numeral" x = SOME (Pretty.mark_str (Markup.numeral, x))
   654       | token_trans "_inner_string" x = SOME (Pretty.mark_str (Markup.inner_string, x))
   655       | token_trans _ _ = NONE;
   656 
   657     fun markup_trans a [Ast.Variable x] = token_trans a x
   658       | markup_trans "_constrain" [t, ty] = constrain_trans t ty
   659       | markup_trans "_idtyp" [t, ty] = constrain_trans t ty
   660       | markup_trans "_ofsort" [ty, s] = ofsort_trans ty s
   661       | markup_trans _ _ = NONE
   662 
   663     and constrain_trans t ty =
   664       if show_markup andalso not show_types then
   665         let
   666           val ((bg1, bg2), en) = typing_elem;
   667           val bg = bg1 ^ Pretty.symbolic_output (pretty_typ_ast Markup.empty ty) ^ bg2;
   668         in SOME (Pretty.raw_markup (bg, en) (0, [pretty_ast Markup.empty t])) end
   669       else NONE
   670 
   671     and ofsort_trans ty s =
   672       if show_markup andalso not show_sorts then
   673         let
   674           val ((bg1, bg2), en) = sorting_elem;
   675           val bg = bg1 ^ Pretty.symbolic_output (pretty_typ_ast Markup.empty s) ^ bg2;
   676         in SOME (Pretty.raw_markup (bg, en) (0, [pretty_typ_ast Markup.empty ty])) end
   677       else NONE
   678 
   679     and pretty_typ_ast m ast = ast
   680       |> Printer.pretty_typ_ast ctxt prtabs trf markup_trans markup_extern
   681       |> Pretty.markup m
   682 
   683     and pretty_ast m ast = ast
   684       |> prt_t ctxt prtabs trf markup_trans markup_extern
   685       |> Pretty.markup m;
   686   in
   687     t_to_ast ctxt (Syntax.print_translation syn) t
   688     |> Ast.normalize ctxt (Syntax.print_rules syn)
   689     |> pretty_ast markup
   690   end;
   691 
   692 in
   693 
   694 val unparse_sort = unparse_t sort_to_ast Printer.pretty_typ_ast Markup.sort;
   695 val unparse_typ = unparse_t typ_to_ast Printer.pretty_typ_ast Markup.typ;
   696 
   697 fun unparse_term ctxt =
   698   let
   699     val thy = Proof_Context.theory_of ctxt;
   700     val syn = Proof_Context.syn_of ctxt;
   701     val idents = Local_Syntax.idents_of (Proof_Context.syntax_of ctxt);
   702   in
   703     unparse_t (term_to_ast idents (is_some o Syntax.lookup_const syn))
   704       (Printer.pretty_term_ast (not (Pure_Thy.old_appl_syntax thy)))
   705       Markup.term ctxt
   706   end;
   707 
   708 end;
   709 
   710 
   711 
   712 (** translations **)
   713 
   714 (* type propositions *)
   715 
   716 fun type_prop_tr' ctxt T [Const ("\\<^const>Pure.sort_constraint", _)] =
   717       Syntax.const "_sort_constraint" $ term_of_typ (Config.put show_sorts true ctxt) T
   718   | type_prop_tr' ctxt T [t] =
   719       Syntax.const "_ofclass" $ term_of_typ ctxt T $ t
   720   | type_prop_tr' _ T ts = raise TYPE ("type_prop_tr'", [T], ts);
   721 
   722 
   723 (* type reflection *)
   724 
   725 fun type_tr' ctxt (Type ("itself", [T])) ts =
   726       Term.list_comb (Syntax.const "_TYPE" $ term_of_typ ctxt T, ts)
   727   | type_tr' _ _ _ = raise Match;
   728 
   729 
   730 (* type constraints *)
   731 
   732 fun type_constraint_tr' ctxt (Type ("fun", [T, _])) (t :: ts) =
   733       Term.list_comb (Syntax.const "_constrain" $ t $ term_of_typ ctxt T, ts)
   734   | type_constraint_tr' _ _ _ = raise Match;
   735 
   736 
   737 (* authentic syntax *)
   738 
   739 fun const_ast_tr intern ctxt [Ast.Variable c] =
   740       let
   741         val Const (c', _) = Proof_Context.read_const_proper ctxt false c;
   742         val d = if intern then Lexicon.mark_const c' else c;
   743       in Ast.Constant d end
   744   | const_ast_tr intern ctxt [Ast.Appl [Ast.Constant "_constrain", x, T as Ast.Variable pos]] =
   745       (Ast.Appl [Ast.Constant "_constrain", const_ast_tr intern ctxt [x], T]
   746         handle ERROR msg =>
   747           error (msg ^ Position.here (the_default Position.none (Term_Position.decode pos))))
   748   | const_ast_tr _ _ asts = raise Ast.AST ("const_ast_tr", asts);
   749 
   750 
   751 (* setup translations *)
   752 
   753 val _ = Context.>> (Context.map_theory
   754  (Sign.add_advanced_trfuns
   755   ([("_context_const", const_ast_tr true),
   756     ("_context_xconst", const_ast_tr false)], [], [], []) #>
   757   Sign.add_advanced_trfunsT
   758    [("_type_prop", type_prop_tr'),
   759     ("\\<^const>TYPE", type_tr'),
   760     ("_type_constraint_", type_constraint_tr')]));
   761 
   762 
   763 
   764 (** check/uncheck **)
   765 
   766 (* context-sensitive (un)checking *)
   767 
   768 type key = int * bool;
   769 
   770 structure Checks = Generic_Data
   771 (
   772   type 'a check = 'a list -> Proof.context -> ('a list * Proof.context) option;
   773   type T =
   774     ((key * ((string * typ check) * stamp) list) list *
   775      (key * ((string * term check) * stamp) list) list);
   776   val empty = ([], []);
   777   val extend = I;
   778   fun merge ((typ_checks1, term_checks1), (typ_checks2, term_checks2)) : T =
   779     (AList.join (op =) (K (Library.merge (eq_snd (op =)))) (typ_checks1, typ_checks2),
   780      AList.join (op =) (K (Library.merge (eq_snd (op =)))) (term_checks1, term_checks2));
   781 );
   782 
   783 fun print_checks ctxt =
   784   let
   785     fun split_checks checks =
   786       List.partition (fn ((_, un), _) => not un) checks
   787       |> pairself (map (fn ((i, _), fs) => (i, map (fst o fst) fs))
   788           #> sort (int_ord o pairself fst));
   789     fun pretty_checks kind checks =
   790       checks |> map (fn (i, names) => Pretty.block
   791         [Pretty.str (kind ^ " (stage " ^ signed_string_of_int i ^ "):"),
   792           Pretty.brk 1, Pretty.strs names]);
   793 
   794     val (typs, terms) = Checks.get (Context.Proof ctxt);
   795     val (typ_checks, typ_unchecks) = split_checks typs;
   796     val (term_checks, term_unchecks) = split_checks terms;
   797   in
   798     pretty_checks "typ_checks" typ_checks @
   799     pretty_checks "term_checks" term_checks @
   800     pretty_checks "typ_unchecks" typ_unchecks @
   801     pretty_checks "term_unchecks" term_unchecks
   802   end |> Pretty.chunks |> Pretty.writeln;
   803 
   804 
   805 local
   806 
   807 fun context_check which (key: key) name f =
   808   Checks.map (which (AList.map_default op = (key, []) (cons ((name, f), stamp ()))));
   809 
   810 fun simple_check eq f xs ctxt =
   811   let val xs' = f ctxt xs
   812   in if eq_list eq (xs, xs') then NONE else SOME (xs', ctxt) end;
   813 
   814 in
   815 
   816 fun typ_check' stage = context_check apfst (stage, false);
   817 fun term_check' stage = context_check apsnd (stage, false);
   818 fun typ_uncheck' stage = context_check apfst (stage, true);
   819 fun term_uncheck' stage = context_check apsnd (stage, true);
   820 
   821 fun typ_check key name f = typ_check' key name (simple_check (op =) f);
   822 fun term_check key name f = term_check' key name (simple_check (op aconv) f);
   823 fun typ_uncheck key name f = typ_uncheck' key name (simple_check (op =) f);
   824 fun term_uncheck key name f = term_uncheck' key name (simple_check (op aconv) f);
   825 
   826 end;
   827 
   828 
   829 local
   830 
   831 fun check_stage fs = perhaps_loop (perhaps_apply (map uncurry fs));
   832 fun check_all fs = perhaps_apply (map check_stage fs);
   833 
   834 fun check which uncheck ctxt0 xs0 =
   835   let
   836     val funs = which (Checks.get (Context.Proof ctxt0))
   837       |> map_filter (fn ((i, u), fs) => if uncheck = u then SOME (i, map (snd o fst) fs) else NONE)
   838       |> Library.sort (int_ord o pairself fst) |> map snd
   839       |> not uncheck ? map rev;
   840   in #1 (perhaps (check_all funs) (xs0, ctxt0)) end;
   841 
   842 val apply_typ_check = check fst false;
   843 val apply_term_check = check snd false;
   844 val apply_typ_uncheck = check fst true;
   845 val apply_term_uncheck = check snd true;
   846 
   847 in
   848 
   849 fun check_typs ctxt raw_tys =
   850   let
   851     val (sorting_report, tys) = Proof_Context.prepare_sortsT ctxt raw_tys;
   852     val _ = Context_Position.if_visible ctxt Output.report sorting_report;
   853   in
   854     tys
   855     |> apply_typ_check ctxt
   856     |> Term_Sharing.typs (Proof_Context.theory_of ctxt)
   857   end;
   858 
   859 fun check_terms ctxt raw_ts =
   860   let
   861     val (sorting_report, raw_ts') = Proof_Context.prepare_sorts ctxt raw_ts;
   862     val (ts, ps) = Type_Infer_Context.prepare_positions ctxt raw_ts';
   863 
   864     val tys = map (Logic.mk_type o snd) ps;
   865     val (ts', tys') = ts @ tys
   866       |> apply_term_check ctxt
   867       |> chop (length ts);
   868     val typing_report =
   869       fold2 (fn (pos, _) => fn ty =>
   870         if Position.is_reported pos then
   871           cons (Position.reported_text pos Markup.typing
   872             (Syntax.string_of_typ ctxt (Logic.dest_type ty)))
   873         else I) ps tys' []
   874       |> implode;
   875 
   876     val _ = Context_Position.if_visible ctxt Output.report (sorting_report ^ typing_report);
   877   in Term_Sharing.terms (Proof_Context.theory_of ctxt) ts' end;
   878 
   879 fun check_props ctxt = map (Type.constraint propT) #> check_terms ctxt;
   880 
   881 val uncheck_typs = apply_typ_uncheck;
   882 val uncheck_terms = apply_term_uncheck;
   883 
   884 end;
   885 
   886 
   887 (* standard phases *)
   888 
   889 val _ = Context.>>
   890  (typ_check 0 "standard" Proof_Context.standard_typ_check #>
   891   term_check 0 "standard"
   892     (fn ctxt => Type_Infer_Context.infer_types ctxt #> map (Proof_Context.expand_abbrevs ctxt)) #>
   893   term_check 100 "standard_finish" Proof_Context.standard_term_check_finish #>
   894   term_uncheck 0 "standard" Proof_Context.standard_term_uncheck);
   895 
   896 
   897 
   898 (** install operations **)
   899 
   900 val _ = Syntax.install_operations
   901   {parse_sort = parse_sort,
   902    parse_typ = parse_typ,
   903    parse_term = parse_term false,
   904    parse_prop = parse_term true,
   905    unparse_sort = unparse_sort,
   906    unparse_typ = unparse_typ,
   907    unparse_term = unparse_term,
   908    check_typs = check_typs,
   909    check_terms = check_terms,
   910    check_props = check_props,
   911    uncheck_typs = uncheck_typs,
   912    uncheck_terms = uncheck_terms};
   913 
   914 end;