src/Pure/sign.ML
author wenzelm
Wed Dec 12 23:36:07 2012 +0100 (2012-12-12 ago)
changeset 50499 f496b2b7bafb
parent 47008 8b13ebf3eda4
child 52143 36ffe23b25f8
permissions -rw-r--r--
rendering of selected dialog_result as active_result_color, depending on dynamic command status in output panel, but not static popups etc.;
     1 (*  Title:      Pure/sign.ML
     2     Author:     Lawrence C Paulson and Markus Wenzel
     3 
     4 Logical signature content: naming conventions, concrete syntax, type
     5 signature, polymorphic constants.
     6 *)
     7 
     8 signature SIGN =
     9 sig
    10   val syn_of: theory -> Syntax.syntax
    11   val tsig_of: theory -> Type.tsig
    12   val classes_of: theory -> Sorts.algebra
    13   val all_classes: theory -> class list
    14   val super_classes: theory -> class -> class list
    15   val minimize_sort: theory -> sort -> sort
    16   val complete_sort: theory -> sort -> sort
    17   val set_defsort: sort -> theory -> theory
    18   val defaultS: theory -> sort
    19   val subsort: theory -> sort * sort -> bool
    20   val of_sort: theory -> typ * sort -> bool
    21   val inter_sort: theory -> sort * sort -> sort
    22   val witness_sorts: theory -> (typ * sort) list -> sort list -> (typ * sort) list
    23   val is_logtype: theory -> string -> bool
    24   val typ_instance: theory -> typ * typ -> bool
    25   val typ_equiv: theory -> typ * typ -> bool
    26   val typ_match: theory -> typ * typ -> Type.tyenv -> Type.tyenv
    27   val typ_unify: theory -> typ * typ -> Type.tyenv * int -> Type.tyenv * int
    28   val consts_of: theory -> Consts.T
    29   val the_const_constraint: theory -> string -> typ
    30   val const_type: theory -> string -> typ option
    31   val the_const_type: theory -> string -> typ
    32   val declared_tyname: theory -> string -> bool
    33   val declared_const: theory -> string -> bool
    34   val naming_of: theory -> Name_Space.naming
    35   val map_naming: (Name_Space.naming -> Name_Space.naming) -> theory -> theory
    36   val restore_naming: theory -> theory -> theory
    37   val inherit_naming: theory -> Proof.context -> Context.generic
    38   val full_name: theory -> binding -> string
    39   val full_name_path: theory -> string -> binding -> string
    40   val full_bname: theory -> bstring -> string
    41   val full_bname_path: theory -> string -> bstring -> string
    42   val const_monomorphic: theory -> string -> bool
    43   val const_typargs: theory -> string * typ -> typ list
    44   val const_instance: theory -> string * typ list -> typ
    45   val mk_const: theory -> string * typ list -> term
    46   val class_space: theory -> Name_Space.T
    47   val type_space: theory -> Name_Space.T
    48   val const_space: theory -> Name_Space.T
    49   val intern_class: theory -> xstring -> string
    50   val intern_type: theory -> xstring -> string
    51   val intern_const: theory -> xstring -> string
    52   val class_alias: binding -> class -> theory -> theory
    53   val type_alias: binding -> string -> theory -> theory
    54   val const_alias: binding -> string -> theory -> theory
    55   val arity_number: theory -> string -> int
    56   val arity_sorts: theory -> string -> sort -> sort list
    57   val certify_class: theory -> class -> class
    58   val certify_sort: theory -> sort -> sort
    59   val certify_typ: theory -> typ -> typ
    60   val certify_typ_mode: Type.mode -> theory -> typ -> typ
    61   val certify': bool -> Context.pretty -> bool -> Consts.T -> theory -> term -> term * typ * int
    62   val certify_term: theory -> term -> term * typ * int
    63   val cert_term: theory -> term -> term
    64   val cert_prop: theory -> term -> term
    65   val no_frees: Proof.context -> term -> term
    66   val no_vars: Proof.context -> term -> term
    67   val add_type: Proof.context -> binding * int * mixfix -> theory -> theory
    68   val add_types_global: (binding * int * mixfix) list -> theory -> theory
    69   val add_nonterminals: Proof.context -> binding list -> theory -> theory
    70   val add_nonterminals_global: binding list -> theory -> theory
    71   val add_type_abbrev: Proof.context -> binding * string list * typ -> theory -> theory
    72   val add_syntax: (string * string * mixfix) list -> theory -> theory
    73   val add_syntax_i: (string * typ * mixfix) list -> theory -> theory
    74   val add_modesyntax: Syntax.mode -> (string * string * mixfix) list -> theory -> theory
    75   val add_modesyntax_i: Syntax.mode -> (string * typ * mixfix) list -> theory -> theory
    76   val del_modesyntax: Syntax.mode -> (string * string * mixfix) list -> theory -> theory
    77   val del_modesyntax_i: Syntax.mode -> (string * typ * mixfix) list -> theory -> theory
    78   val type_notation: bool -> Syntax.mode -> (typ * mixfix) list -> theory -> theory
    79   val notation: bool -> Syntax.mode -> (term * mixfix) list -> theory -> theory
    80   val declare_const: Proof.context -> (binding * typ) * mixfix -> theory -> term * theory
    81   val declare_const_global: (binding * typ) * mixfix -> theory -> term * theory
    82   val add_consts: (binding * string * mixfix) list -> theory -> theory
    83   val add_consts_i: (binding * typ * mixfix) list -> theory -> theory
    84   val add_abbrev: string -> binding * term -> theory -> (term * term) * theory
    85   val revert_abbrev: string -> string -> theory -> theory
    86   val add_const_constraint: string * typ option -> theory -> theory
    87   val primitive_class: binding * class list -> theory -> theory
    88   val primitive_classrel: class * class -> theory -> theory
    89   val primitive_arity: arity -> theory -> theory
    90   val add_trfuns:
    91     (string * (Ast.ast list -> Ast.ast)) list *
    92     (string * (term list -> term)) list *
    93     (string * (term list -> term)) list *
    94     (string * (Ast.ast list -> Ast.ast)) list -> theory -> theory
    95   val add_trfunsT: (string * (typ -> term list -> term)) list -> theory -> theory
    96   val add_advanced_trfuns:
    97     (string * (Proof.context -> Ast.ast list -> Ast.ast)) list *
    98     (string * (Proof.context -> term list -> term)) list *
    99     (string * (Proof.context -> term list -> term)) list *
   100     (string * (Proof.context -> Ast.ast list -> Ast.ast)) list -> theory -> theory
   101   val add_advanced_trfunsT:
   102     (string * (Proof.context -> typ -> term list -> term)) list -> theory -> theory
   103   val add_trrules: Ast.ast Syntax.trrule list -> theory -> theory
   104   val del_trrules: Ast.ast Syntax.trrule list -> theory -> theory
   105   val new_group: theory -> theory
   106   val reset_group: theory -> theory
   107   val add_path: string -> theory -> theory
   108   val root_path: theory -> theory
   109   val parent_path: theory -> theory
   110   val mandatory_path: string -> theory -> theory
   111   val qualified_path: bool -> binding -> theory -> theory
   112   val local_path: theory -> theory
   113   val hide_class: bool -> string -> theory -> theory
   114   val hide_type: bool -> string -> theory -> theory
   115   val hide_const: bool -> string -> theory -> theory
   116 end
   117 
   118 structure Sign: SIGN =
   119 struct
   120 
   121 (** datatype sign **)
   122 
   123 datatype sign = Sign of
   124  {syn: Syntax.syntax,           (*concrete syntax for terms, types, sorts*)
   125   tsig: Type.tsig,              (*order-sorted signature of types*)
   126   consts: Consts.T};            (*polymorphic constants*)
   127 
   128 fun make_sign (syn, tsig, consts) = Sign {syn = syn, tsig = tsig, consts = consts};
   129 
   130 structure Data = Theory_Data_PP
   131 (
   132   type T = sign;
   133   fun extend (Sign {syn, tsig, consts, ...}) = make_sign (syn, tsig, consts);
   134 
   135   val empty = make_sign (Syntax.empty_syntax, Type.empty_tsig, Consts.empty);
   136 
   137   fun merge pp (sign1, sign2) =
   138     let
   139       val Sign {syn = syn1, tsig = tsig1, consts = consts1} = sign1;
   140       val Sign {syn = syn2, tsig = tsig2, consts = consts2} = sign2;
   141 
   142       val syn = Syntax.merge_syntax (syn1, syn2);
   143       val tsig = Type.merge_tsig pp (tsig1, tsig2);
   144       val consts = Consts.merge (consts1, consts2);
   145     in make_sign (syn, tsig, consts) end;
   146 );
   147 
   148 fun rep_sg thy = Data.get thy |> (fn Sign args => args);
   149 
   150 fun map_sign f = Data.map (fn Sign {syn, tsig, consts} => make_sign (f (syn, tsig, consts)));
   151 
   152 fun map_syn f = map_sign (fn (syn, tsig, consts) => (f syn, tsig, consts));
   153 fun map_tsig f = map_sign (fn (syn, tsig, consts) => (syn, f tsig, consts));
   154 fun map_consts f = map_sign (fn (syn, tsig, consts) => (syn, tsig, f consts));
   155 
   156 
   157 (* syntax *)
   158 
   159 val syn_of = #syn o rep_sg;
   160 
   161 
   162 (* type signature *)
   163 
   164 val tsig_of = #tsig o rep_sg;
   165 
   166 val classes_of = #2 o #classes o Type.rep_tsig o tsig_of;
   167 val all_classes = Sorts.all_classes o classes_of;
   168 val super_classes = Sorts.super_classes o classes_of;
   169 val minimize_sort = Sorts.minimize_sort o classes_of;
   170 val complete_sort = Sorts.complete_sort o classes_of;
   171 
   172 val set_defsort = map_tsig o Type.set_defsort;
   173 val defaultS = Type.defaultS o tsig_of;
   174 val subsort = Type.subsort o tsig_of;
   175 val of_sort = Type.of_sort o tsig_of;
   176 val inter_sort = Type.inter_sort o tsig_of;
   177 val witness_sorts = Type.witness_sorts o tsig_of;
   178 val is_logtype = member (op =) o Type.logical_types o tsig_of;
   179 
   180 val typ_instance = Type.typ_instance o tsig_of;
   181 fun typ_equiv thy (T, U) = typ_instance thy (T, U) andalso typ_instance thy (U, T);
   182 val typ_match = Type.typ_match o tsig_of;
   183 val typ_unify = Type.unify o tsig_of;
   184 
   185 
   186 (* polymorphic constants *)
   187 
   188 val consts_of = #consts o rep_sg;
   189 val the_const_constraint = Consts.the_constraint o consts_of;
   190 val the_const_type = #2 oo (Consts.the_const o consts_of);
   191 val const_type = try o the_const_type;
   192 val const_monomorphic = Consts.is_monomorphic o consts_of;
   193 val const_typargs = Consts.typargs o consts_of;
   194 val const_instance = Consts.instance o consts_of;
   195 
   196 fun mk_const thy (c, Ts) = Const (c, const_instance thy (c, Ts));
   197 
   198 val declared_tyname = Symtab.defined o #2 o #types o Type.rep_tsig o tsig_of;
   199 val declared_const = can o the_const_constraint;
   200 
   201 
   202 (* naming *)
   203 
   204 val naming_of = Name_Space.naming_of o Context.Theory;
   205 val map_naming = Context.theory_map o Name_Space.map_naming;
   206 val restore_naming = map_naming o K o naming_of;
   207 fun inherit_naming thy = Name_Space.map_naming (K (naming_of thy)) o Context.Proof;
   208 
   209 val full_name = Name_Space.full_name o naming_of;
   210 fun full_name_path thy path = Name_Space.full_name (Name_Space.add_path path (naming_of thy));
   211 
   212 fun full_bname thy = Name_Space.full_name (naming_of thy) o Binding.name;
   213 fun full_bname_path thy path = full_name_path thy path o Binding.name;
   214 
   215 
   216 
   217 (** name spaces **)
   218 
   219 val class_space = Type.class_space o tsig_of;
   220 val type_space = Type.type_space o tsig_of;
   221 val const_space = Consts.space_of o consts_of;
   222 
   223 val intern_class = Name_Space.intern o class_space;
   224 val intern_type = Name_Space.intern o type_space;
   225 val intern_const = Name_Space.intern o const_space;
   226 
   227 fun class_alias b c thy = map_tsig (Type.class_alias (naming_of thy) b c) thy;
   228 fun type_alias b c thy = map_tsig (Type.type_alias (naming_of thy) b c) thy;
   229 fun const_alias b c thy = map_consts (Consts.alias (naming_of thy) b c) thy;
   230 
   231 
   232 
   233 (** certify entities **)    (*exception TYPE*)
   234 
   235 (* certify wrt. type signature *)
   236 
   237 val arity_number = Type.arity_number o tsig_of;
   238 fun arity_sorts thy = Type.arity_sorts (Context.pretty_global thy) (tsig_of thy);
   239 
   240 val certify_class = Type.cert_class o tsig_of;
   241 val certify_sort = Type.cert_sort o tsig_of;
   242 val certify_typ = Type.cert_typ o tsig_of;
   243 fun certify_typ_mode mode = Type.cert_typ_mode mode o tsig_of;
   244 
   245 
   246 (* certify term/prop *)
   247 
   248 local
   249 
   250 fun type_check pp tm =
   251   let
   252     fun err_appl bs t T u U =
   253       let
   254         val xs = map Free bs;           (*we do not rename here*)
   255         val t' = subst_bounds (xs, t);
   256         val u' = subst_bounds (xs, u);
   257         val msg = Type.appl_error (Syntax.init_pretty pp) t' T u' U;
   258       in raise TYPE (msg, [T, U], [t', u']) end;
   259 
   260     fun typ_of (_, Const (_, T)) = T
   261       | typ_of (_, Free  (_, T)) = T
   262       | typ_of (_, Var (_, T)) = T
   263       | typ_of (bs, Bound i) = snd (nth bs i handle General.Subscript =>
   264           raise TYPE ("Loose bound variable: B." ^ string_of_int i, [], [Bound i]))
   265       | typ_of (bs, Abs (x, T, body)) = T --> typ_of ((x, T) :: bs, body)
   266       | typ_of (bs, t $ u) =
   267           let val T = typ_of (bs, t) and U = typ_of (bs, u) in
   268             (case T of
   269               Type ("fun", [T1, T2]) =>
   270                 if T1 = U then T2 else err_appl bs t T u U
   271             | _ => err_appl bs t T u U)
   272           end;
   273   in typ_of ([], tm) end;
   274 
   275 fun err msg = raise TYPE (msg, [], []);
   276 
   277 fun check_vars (t $ u) = (check_vars t; check_vars u)
   278   | check_vars (Abs (_, _, t)) = check_vars t
   279   | check_vars (Free (x, _)) =
   280       if Long_Name.is_qualified x then err ("Malformed variable: " ^ quote x) else ()
   281   | check_vars (Var (xi as (_, i), _)) =
   282       if i < 0 then err ("Malformed variable: " ^ quote (Term.string_of_vname xi)) else ()
   283   | check_vars _ = ();
   284 
   285 in
   286 
   287 fun certify' prop pp do_expand consts thy tm =
   288   let
   289     val _ = check_vars tm;
   290     val tm' = Term.map_types (certify_typ thy) tm;
   291     val T = type_check pp tm';
   292     val _ = if prop andalso T <> propT then err "Term not of type prop" else ();
   293     val tm'' = Consts.certify pp (tsig_of thy) do_expand consts tm';
   294   in (if tm = tm'' then tm else tm'', T, Term.maxidx_of_term tm'') end;
   295 
   296 fun certify_term thy = certify' false (Context.pretty_global thy) true (consts_of thy) thy;
   297 fun cert_term_abbrev thy =
   298   #1 o certify' false (Context.pretty_global thy) false (consts_of thy) thy;
   299 val cert_term = #1 oo certify_term;
   300 fun cert_prop thy = #1 o certify' true (Context.pretty_global thy) true (consts_of thy) thy;
   301 
   302 end;
   303 
   304 
   305 (* specifications *)
   306 
   307 fun no_variables kind add addT mk mkT ctxt tm =
   308   (case (add tm [], addT tm []) of
   309     ([], []) => tm
   310   | (frees, tfrees) => error (Pretty.string_of (Pretty.block
   311       (Pretty.str ("Illegal " ^ kind ^ " variable(s) in term:") :: Pretty.brk 1 ::
   312        Pretty.commas
   313         (map (Syntax.pretty_term ctxt o mk) frees @ map (Syntax.pretty_typ ctxt o mkT) tfrees)))));
   314 
   315 val no_frees = no_variables "free" Term.add_frees Term.add_tfrees Free TFree;
   316 val no_vars = no_variables "schematic" Term.add_vars Term.add_tvars Var TVar;
   317 
   318 
   319 
   320 (** signature extension functions **)  (*exception ERROR/TYPE*)
   321 
   322 (* add type constructors *)
   323 
   324 fun add_type ctxt (b, n, mx) thy = thy |> map_sign (fn (syn, tsig, consts) =>
   325   let
   326     val type_syntax = (Lexicon.mark_type (full_name thy b), Mixfix.make_type n, mx);
   327     val syn' = Syntax.update_type_gram true Syntax.mode_default [type_syntax] syn;
   328     val tsig' = Type.add_type (inherit_naming thy ctxt) (b, n) tsig;
   329   in (syn', tsig', consts) end);
   330 
   331 fun add_types_global types thy =
   332   fold (add_type (Syntax.init_pretty_global thy)) types thy;
   333 
   334 
   335 (* add nonterminals *)
   336 
   337 fun add_nonterminals ctxt ns thy = thy |> map_sign (fn (syn, tsig, consts) =>
   338   (syn, fold (Type.add_nonterminal (inherit_naming thy ctxt)) ns tsig, consts));
   339 
   340 fun add_nonterminals_global ns thy =
   341   add_nonterminals (Syntax.init_pretty_global thy) ns thy;
   342 
   343 
   344 (* add type abbreviations *)
   345 
   346 fun add_type_abbrev ctxt abbr thy = thy |> map_sign (fn (syn, tsig, consts) =>
   347   (syn, Type.add_abbrev (inherit_naming thy ctxt) abbr tsig, consts));
   348 
   349 
   350 (* modify syntax *)
   351 
   352 fun gen_syntax change_gram parse_typ mode args thy =
   353   let
   354     val ctxt = Type.set_mode Type.mode_syntax (Proof_Context.init_global thy);
   355     fun prep (c, T, mx) = (c, certify_typ_mode Type.mode_syntax thy (parse_typ ctxt T), mx)
   356       handle ERROR msg => cat_error msg ("in syntax declaration " ^ quote c);
   357   in thy |> map_syn (change_gram (is_logtype thy) mode (map prep args)) end;
   358 
   359 fun gen_add_syntax x = gen_syntax (Syntax.update_const_gram true) x;
   360 
   361 val add_modesyntax = gen_add_syntax Syntax.read_typ;
   362 val add_modesyntax_i = gen_add_syntax (K I);
   363 val add_syntax = add_modesyntax Syntax.mode_default;
   364 val add_syntax_i = add_modesyntax_i Syntax.mode_default;
   365 val del_modesyntax = gen_syntax (Syntax.update_const_gram false) Syntax.read_typ;
   366 val del_modesyntax_i = gen_syntax (Syntax.update_const_gram false) (K I);
   367 
   368 fun type_notation add mode args =
   369   let
   370     fun type_syntax (Type (c, args), mx) =
   371           SOME (Lexicon.mark_type c, Mixfix.make_type (length args), mx)
   372       | type_syntax _ = NONE;
   373   in map_syn (Syntax.update_type_gram add mode (map_filter type_syntax args)) end;
   374 
   375 fun notation add mode args thy =
   376   let
   377     fun const_syntax (Const (c, _), mx) =
   378           (case try (Consts.type_scheme (consts_of thy)) c of
   379             SOME T => SOME (Lexicon.mark_const c, T, mx)
   380           | NONE => NONE)
   381       | const_syntax _ = NONE;
   382   in gen_syntax (Syntax.update_const_gram add) (K I) mode (map_filter const_syntax args) thy end;
   383 
   384 
   385 (* add constants *)
   386 
   387 local
   388 
   389 fun gen_add_consts prep_typ ctxt raw_args thy =
   390   let
   391     val prepT = Type.no_tvars o Term.no_dummyT o certify_typ thy o prep_typ ctxt;
   392     fun prep (b, raw_T, mx) =
   393       let
   394         val c = full_name thy b;
   395         val T = (prepT raw_T handle TYPE (msg, _, _) => error msg) handle ERROR msg =>
   396           cat_error msg ("in declaration of constant " ^ Binding.print b);
   397         val T' = Logic.varifyT_global T;
   398       in ((b, T'), (Lexicon.mark_const c, T', mx), Const (c, T)) end;
   399     val args = map prep raw_args;
   400   in
   401     thy
   402     |> map_consts (fold (Consts.declare (inherit_naming thy ctxt) o #1) args)
   403     |> add_syntax_i (map #2 args)
   404     |> pair (map #3 args)
   405   end;
   406 
   407 in
   408 
   409 fun add_consts args thy =
   410   #2 (gen_add_consts Syntax.read_typ (Proof_Context.init_global thy) args thy);
   411 
   412 fun add_consts_i args thy =
   413   #2 (gen_add_consts (K I) (Proof_Context.init_global thy) args thy);
   414 
   415 fun declare_const ctxt ((b, T), mx) = yield_singleton (gen_add_consts (K I) ctxt) (b, T, mx);
   416 fun declare_const_global arg thy = declare_const (Proof_Context.init_global thy) arg thy;
   417 
   418 end;
   419 
   420 
   421 (* abbreviations *)
   422 
   423 fun add_abbrev mode (b, raw_t) thy =  (* FIXME proper ctxt (?) *)
   424   let
   425     val ctxt = Syntax.init_pretty_global thy;
   426     val prep_tm = no_frees ctxt o Term.no_dummy_patterns o cert_term_abbrev thy;
   427     val t = (prep_tm raw_t handle TYPE (msg, _, _) => error msg | TERM (msg, _) => error msg)
   428       handle ERROR msg => cat_error msg ("in constant abbreviation " ^ Binding.print b);
   429     val (res, consts') = consts_of thy
   430       |> Consts.abbreviate (inherit_naming thy ctxt) (tsig_of thy) mode (b, t);
   431   in (res, thy |> map_consts (K consts')) end;
   432 
   433 fun revert_abbrev mode c = map_consts (Consts.revert_abbrev mode c);
   434 
   435 
   436 (* add constraints *)
   437 
   438 fun add_const_constraint (c, opt_T) thy =
   439   let
   440     fun prepT raw_T =
   441       let val T = Logic.varifyT_global (Type.no_tvars (Term.no_dummyT (certify_typ thy raw_T)))
   442       in cert_term thy (Const (c, T)); T end
   443       handle TYPE (msg, _, _) => error msg;
   444   in thy |> map_consts (Consts.constrain (c, Option.map prepT opt_T)) end;
   445 
   446 
   447 (* primitive classes and arities *)
   448 
   449 fun primitive_class (bclass, classes) thy =
   450   thy
   451   |> map_sign (fn (syn, tsig, consts) =>
   452       let val tsig' = Type.add_class (Context.Theory thy) (bclass, classes) tsig;
   453       in (syn, tsig', consts) end)
   454   |> add_consts_i [(Binding.map_name Logic.const_of_class bclass, Term.a_itselfT --> propT, NoSyn)];
   455 
   456 fun primitive_classrel arg thy =
   457   thy |> map_tsig (Type.add_classrel (Context.pretty_global thy) arg);
   458 
   459 fun primitive_arity arg thy =
   460   thy |> map_tsig (Type.add_arity (Context.pretty_global thy) arg);
   461 
   462 
   463 (* add translation functions *)
   464 
   465 local
   466 
   467 fun mk trs = map Syntax_Ext.mk_trfun trs;
   468 
   469 fun gen_add_trfuns ext non_typed (atrs, trs, tr's, atr's) =
   470   map_syn (ext (mk atrs, mk trs, mk (map (apsnd non_typed) tr's), mk atr's));
   471 
   472 fun gen_add_trfunsT ext tr's = map_syn (ext ([], [], mk tr's, []));
   473 
   474 in
   475 
   476 val add_trfuns = gen_add_trfuns Syntax.update_trfuns Syntax_Trans.non_typed_tr';
   477 val add_trfunsT = gen_add_trfunsT Syntax.update_trfuns;
   478 val add_advanced_trfuns = gen_add_trfuns Syntax.update_advanced_trfuns Syntax_Trans.non_typed_tr'';
   479 val add_advanced_trfunsT = gen_add_trfunsT Syntax.update_advanced_trfuns;
   480 
   481 end;
   482 
   483 
   484 (* translation rules *)
   485 
   486 val add_trrules = map_syn o Syntax.update_trrules;
   487 val del_trrules = map_syn o Syntax.remove_trrules;
   488 
   489 
   490 (* naming *)
   491 
   492 val new_group = map_naming Name_Space.new_group;
   493 val reset_group = map_naming Name_Space.reset_group;
   494 
   495 val add_path = map_naming o Name_Space.add_path;
   496 val root_path = map_naming Name_Space.root_path;
   497 val parent_path = map_naming Name_Space.parent_path;
   498 val mandatory_path = map_naming o Name_Space.mandatory_path;
   499 val qualified_path = map_naming oo Name_Space.qualified_path;
   500 
   501 fun local_path thy = thy |> root_path |> add_path (Context.theory_name thy);
   502 
   503 
   504 (* hide names *)
   505 
   506 val hide_class = map_tsig oo Type.hide_class;
   507 val hide_type = map_tsig oo Type.hide_type;
   508 val hide_const = map_consts oo Consts.hide;
   509 
   510 end;