src/Pure/Isar/toplevel.ML
author wenzelm
Wed Aug 11 18:11:07 2010 +0200 (2010-08-11 ago)
changeset 38337 f6c1e169f51b
parent 38236 d8c7be27e01d
child 38351 ea1ee55aa41f
permissions -rw-r--r--
removed obsolete Toplevel.enter_proof_body;
     1 (*  Title:      Pure/Isar/toplevel.ML
     2     Author:     Markus Wenzel, TU Muenchen
     3 
     4 Isabelle/Isar toplevel transactions.
     5 *)
     6 
     7 signature TOPLEVEL =
     8 sig
     9   exception UNDEF
    10   type state
    11   val toplevel: state
    12   val is_toplevel: state -> bool
    13   val is_theory: state -> bool
    14   val is_proof: state -> bool
    15   val level: state -> int
    16   val presentation_context_of: state -> Proof.context
    17   val previous_context_of: state -> Proof.context option
    18   val context_of: state -> Proof.context
    19   val generic_theory_of: state -> generic_theory
    20   val theory_of: state -> theory
    21   val proof_of: state -> Proof.state
    22   val proof_position_of: state -> int
    23   val end_theory: Position.T -> state -> theory
    24   val print_state_context: state -> unit
    25   val print_state: bool -> state -> unit
    26   val pretty_abstract: state -> Pretty.T
    27   val quiet: bool Unsynchronized.ref
    28   val debug: bool Unsynchronized.ref
    29   val interact: bool Unsynchronized.ref
    30   val timing: bool Unsynchronized.ref
    31   val profiling: int Unsynchronized.ref
    32   val skip_proofs: bool Unsynchronized.ref
    33   exception TERMINATE
    34   exception TOPLEVEL_ERROR
    35   val program: (unit -> 'a) -> 'a
    36   val thread: bool -> (unit -> unit) -> Thread.thread
    37   type transition
    38   val empty: transition
    39   val init_of: transition -> string option
    40   val name_of: transition -> string
    41   val pos_of: transition -> Position.T
    42   val str_of: transition -> string
    43   val name: string -> transition -> transition
    44   val position: Position.T -> transition -> transition
    45   val interactive: bool -> transition -> transition
    46   val print: transition -> transition
    47   val no_timing: transition -> transition
    48   val init_theory: string -> (unit -> theory) -> transition -> transition
    49   val modify_init: (unit -> theory) -> transition -> transition
    50   val exit: transition -> transition
    51   val keep: (state -> unit) -> transition -> transition
    52   val keep': (bool -> state -> unit) -> transition -> transition
    53   val imperative: (unit -> unit) -> transition -> transition
    54   val ignored: Position.T -> transition
    55   val malformed: Position.T -> string -> transition
    56   val theory: (theory -> theory) -> transition -> transition
    57   val generic_theory: (generic_theory -> generic_theory) -> transition -> transition
    58   val theory': (bool -> theory -> theory) -> transition -> transition
    59   val begin_local_theory: bool -> (theory -> local_theory) -> transition -> transition
    60   val end_local_theory: transition -> transition
    61   val local_theory': xstring option -> (bool -> local_theory -> local_theory) ->
    62     transition -> transition
    63   val local_theory: xstring option -> (local_theory -> local_theory) -> transition -> transition
    64   val present_local_theory: xstring option -> (state -> unit) -> transition -> transition
    65   val local_theory_to_proof': xstring option -> (bool -> local_theory -> Proof.state) ->
    66     transition -> transition
    67   val local_theory_to_proof: xstring option -> (local_theory -> Proof.state) ->
    68     transition -> transition
    69   val theory_to_proof: (theory -> Proof.state) -> transition -> transition
    70   val end_proof: (bool -> Proof.state -> Proof.context) -> transition -> transition
    71   val forget_proof: transition -> transition
    72   val present_proof: (state -> unit) -> transition -> transition
    73   val proofs': (bool -> Proof.state -> Proof.state Seq.seq) -> transition -> transition
    74   val proof': (bool -> Proof.state -> Proof.state) -> transition -> transition
    75   val proofs: (Proof.state -> Proof.state Seq.seq) -> transition -> transition
    76   val proof: (Proof.state -> Proof.state) -> transition -> transition
    77   val actual_proof: (Proof_Node.T -> Proof_Node.T) -> transition -> transition
    78   val skip_proof: (int -> int) -> transition -> transition
    79   val skip_proof_to_theory: (int -> bool) -> transition -> transition
    80   val get_id: transition -> string option
    81   val put_id: string -> transition -> transition
    82   val unknown_theory: transition -> transition
    83   val unknown_proof: transition -> transition
    84   val unknown_context: transition -> transition
    85   val setmp_thread_position: transition -> ('a -> 'b) -> 'a -> 'b
    86   val status: transition -> Markup.T -> unit
    87   val error_msg: transition -> exn * string -> unit
    88   val add_hook: (transition -> state -> state -> unit) -> unit
    89   val transition: bool -> transition -> state -> (state * (exn * string) option) option
    90   val run_command: string -> transition -> state -> state option
    91   val command: transition -> state -> state
    92   val excursion: (transition * transition list) list -> (transition * state) list lazy * theory
    93 end;
    94 
    95 structure Toplevel: TOPLEVEL =
    96 struct
    97 
    98 (** toplevel state **)
    99 
   100 exception UNDEF = Runtime.UNDEF;
   101 
   102 
   103 (* local theory wrappers *)
   104 
   105 val loc_init = Theory_Target.context_cmd;
   106 val loc_exit = Local_Theory.exit_global;
   107 
   108 fun loc_begin loc (Context.Theory thy) = loc_init (the_default "-" loc) thy
   109   | loc_begin NONE (Context.Proof lthy) = lthy
   110   | loc_begin (SOME loc) (Context.Proof lthy) = loc_init loc (loc_exit lthy);
   111 
   112 fun loc_finish _ (Context.Theory _) = Context.Theory o loc_exit
   113   | loc_finish NONE (Context.Proof _) = Context.Proof o Local_Theory.restore
   114   | loc_finish (SOME _) (Context.Proof lthy) = fn lthy' =>
   115       Context.Proof (Local_Theory.reinit (Local_Theory.raw_theory (K (loc_exit lthy')) lthy));
   116 
   117 
   118 (* datatype node *)
   119 
   120 datatype node =
   121   Theory of generic_theory * Proof.context option
   122     (*theory with presentation context*) |
   123   Proof of Proof_Node.T * ((Proof.context -> generic_theory) * generic_theory)
   124     (*proof node, finish, original theory*) |
   125   SkipProof of int * (generic_theory * generic_theory);
   126     (*proof depth, resulting theory, original theory*)
   127 
   128 val theory_node = fn Theory (gthy, _) => SOME gthy | _ => NONE;
   129 val proof_node = fn Proof (prf, _) => SOME prf | _ => NONE;
   130 
   131 fun cases_node f _ (Theory (gthy, _)) = f gthy
   132   | cases_node _ g (Proof (prf, _)) = g (Proof_Node.current prf)
   133   | cases_node f _ (SkipProof (_, (gthy, _))) = f gthy;
   134 
   135 val context_node = cases_node Context.proof_of Proof.context_of;
   136 
   137 
   138 (* datatype state *)
   139 
   140 datatype state = State of node option * node option;  (*current, previous*)
   141 
   142 val toplevel = State (NONE, NONE);
   143 
   144 fun is_toplevel (State (NONE, _)) = true
   145   | is_toplevel _ = false;
   146 
   147 fun level (State (NONE, _)) = 0
   148   | level (State (SOME (Theory _), _)) = 0
   149   | level (State (SOME (Proof (prf, _)), _)) = Proof.level (Proof_Node.current prf)
   150   | level (State (SOME (SkipProof (d, _)), _)) = d + 1;   (*different notion of proof depth!*)
   151 
   152 fun str_of_state (State (NONE, _)) = "at top level"
   153   | str_of_state (State (SOME (Theory (Context.Theory _, _)), _)) = "in theory mode"
   154   | str_of_state (State (SOME (Theory (Context.Proof _, _)), _)) = "in local theory mode"
   155   | str_of_state (State (SOME (Proof _), _)) = "in proof mode"
   156   | str_of_state (State (SOME (SkipProof _), _)) = "in skipped proof mode";
   157 
   158 
   159 (* current node *)
   160 
   161 fun node_of (State (NONE, _)) = raise UNDEF
   162   | node_of (State (SOME node, _)) = node;
   163 
   164 fun is_theory state = not (is_toplevel state) andalso is_some (theory_node (node_of state));
   165 fun is_proof state = not (is_toplevel state) andalso is_some (proof_node (node_of state));
   166 
   167 fun node_case f g state = cases_node f g (node_of state);
   168 
   169 fun presentation_context_of state =
   170   (case try node_of state of
   171     SOME (Theory (_, SOME ctxt)) => ctxt
   172   | SOME node => context_node node
   173   | NONE => raise UNDEF);
   174 
   175 fun previous_context_of (State (_, NONE)) = NONE
   176   | previous_context_of (State (_, SOME prev)) = SOME (context_node prev);
   177 
   178 val context_of = node_case Context.proof_of Proof.context_of;
   179 val generic_theory_of = node_case I (Context.Proof o Proof.context_of);
   180 val theory_of = node_case Context.theory_of Proof.theory_of;
   181 val proof_of = node_case (fn _ => raise UNDEF) I;
   182 
   183 fun proof_position_of state =
   184   (case node_of state of
   185     Proof (prf, _) => Proof_Node.position prf
   186   | _ => raise UNDEF);
   187 
   188 fun end_theory _ (State (NONE, SOME (Theory (Context.Theory thy, _)))) = Theory.end_theory thy
   189   | end_theory pos _ = error ("Unfinished theory at end of input" ^ Position.str_of pos);
   190 
   191 
   192 (* print state *)
   193 
   194 val pretty_context = Local_Theory.pretty o Context.cases (Theory_Target.init NONE) I;
   195 
   196 fun print_state_context state =
   197   (case try node_of state of
   198     NONE => []
   199   | SOME (Theory (gthy, _)) => pretty_context gthy
   200   | SOME (Proof (_, (_, gthy))) => pretty_context gthy
   201   | SOME (SkipProof (_, (gthy, _))) => pretty_context gthy)
   202   |> Pretty.chunks |> Pretty.writeln;
   203 
   204 fun print_state prf_only state =
   205   (case try node_of state of
   206     NONE => []
   207   | SOME (Theory (gthy, _)) => if prf_only then [] else pretty_context gthy
   208   | SOME (Proof (prf, _)) =>
   209       Proof.pretty_state (Proof_Node.position prf) (Proof_Node.current prf)
   210   | SOME (SkipProof (d, _)) => [Pretty.str ("skipped proof: depth " ^ string_of_int d)])
   211   |> Pretty.markup_chunks Markup.state |> Pretty.writeln;
   212 
   213 fun pretty_abstract state = Pretty.str ("<Isar " ^ str_of_state state ^ ">");
   214 
   215 
   216 
   217 (** toplevel transitions **)
   218 
   219 val quiet = Unsynchronized.ref false;
   220 val debug = Output.debugging;
   221 val interact = Unsynchronized.ref false;
   222 val timing = Output.timing;
   223 val profiling = Unsynchronized.ref 0;
   224 val skip_proofs = Unsynchronized.ref false;
   225 
   226 exception TERMINATE = Runtime.TERMINATE;
   227 exception EXCURSION_FAIL = Runtime.EXCURSION_FAIL;
   228 exception TOPLEVEL_ERROR = Runtime.TOPLEVEL_ERROR;
   229 
   230 fun program body =
   231  (body
   232   |> Runtime.controlled_execution
   233   |> Runtime.toplevel_error (Output.error_msg o ML_Compiler.exn_message)) ();
   234 
   235 fun thread interrupts body =
   236   Thread.fork
   237     (((fn () => body () handle Exn.Interrupt => ())
   238         |> Runtime.debugging
   239         |> Runtime.toplevel_error
   240           (fn exn => priority ("## INTERNAL ERROR ##\n" ^ ML_Compiler.exn_message exn))),
   241       Simple_Thread.attributes interrupts);
   242 
   243 
   244 (* node transactions -- maintaining stable checkpoints *)
   245 
   246 exception FAILURE of state * exn;
   247 
   248 local
   249 
   250 fun reset_presentation (Theory (gthy, _)) = Theory (gthy, NONE)
   251   | reset_presentation node = node;
   252 
   253 fun is_draft_theory (Theory (gthy, _)) = Context.is_draft (Context.theory_of gthy)
   254   | is_draft_theory _ = false;
   255 
   256 fun is_stale state = Context.is_stale (theory_of state) handle Runtime.UNDEF => false;
   257 
   258 fun stale_error NONE = SOME (ERROR "Stale theory encountered after successful execution!")
   259   | stale_error some = some;
   260 
   261 fun map_theory f (Theory (gthy, ctxt)) =
   262       Theory (Context.mapping f (Local_Theory.raw_theory f) gthy, ctxt)
   263   | map_theory _ node = node;
   264 
   265 in
   266 
   267 fun apply_transaction f g node =
   268   let
   269     val _ = is_draft_theory node andalso error "Illegal draft theory in toplevel state";
   270     val cont_node = reset_presentation node;
   271     val back_node = map_theory (Theory.checkpoint o Theory.copy) cont_node;
   272     fun state_error e nd = (State (SOME nd, SOME node), e);
   273 
   274     val (result, err) =
   275       cont_node
   276       |> Runtime.controlled_execution f
   277       |> map_theory Theory.checkpoint
   278       |> state_error NONE
   279       handle exn => state_error (SOME exn) cont_node;
   280 
   281     val (result', err') =
   282       if is_stale result then state_error (stale_error err) back_node
   283       else (result, err);
   284   in
   285     (case err' of
   286       NONE => tap g result'
   287     | SOME exn => raise FAILURE (result', exn))
   288   end;
   289 
   290 end;
   291 
   292 
   293 (* primitive transitions *)
   294 
   295 datatype trans =
   296   Init of string * (unit -> theory) |    (*theory name, init*)
   297   Exit |                                 (*formal exit of theory*)
   298   Keep of bool -> state -> unit |        (*peek at state*)
   299   Transaction of (bool -> node -> node) * (state -> unit);  (*node transaction and presentation*)
   300 
   301 local
   302 
   303 fun apply_tr _ (Init (_, f)) (State (NONE, _)) =
   304       State (SOME (Theory (Context.Theory
   305           (Theory.checkpoint (Runtime.controlled_execution f ())), NONE)), NONE)
   306   | apply_tr _ Exit (State (prev as SOME (Theory (Context.Theory _, _)), _)) =
   307       State (NONE, prev)
   308   | apply_tr int (Keep f) state =
   309       Runtime.controlled_execution (fn x => tap (f int) x) state
   310   | apply_tr int (Transaction (f, g)) (State (SOME state, _)) =
   311       apply_transaction (fn x => f int x) g state
   312   | apply_tr _ _ _ = raise UNDEF;
   313 
   314 fun apply_union _ [] state = raise FAILURE (state, UNDEF)
   315   | apply_union int (tr :: trs) state =
   316       apply_union int trs state
   317         handle Runtime.UNDEF => apply_tr int tr state
   318           | FAILURE (alt_state, UNDEF) => apply_tr int tr alt_state
   319           | exn as FAILURE _ => raise exn
   320           | exn => raise FAILURE (state, exn);
   321 
   322 in
   323 
   324 fun apply_trans int trs state = (apply_union int trs state, NONE)
   325   handle FAILURE (alt_state, exn) => (alt_state, SOME exn) | exn => (state, SOME exn);
   326 
   327 end;
   328 
   329 
   330 (* datatype transition *)
   331 
   332 datatype transition = Transition of
   333  {name: string,              (*command name*)
   334   pos: Position.T,           (*source position*)
   335   int_only: bool,            (*interactive-only*)
   336   print: bool,               (*print result state*)
   337   no_timing: bool,           (*suppress timing*)
   338   trans: trans list};        (*primitive transitions (union)*)
   339 
   340 fun make_transition (name, pos, int_only, print, no_timing, trans) =
   341   Transition {name = name, pos = pos, int_only = int_only, print = print, no_timing = no_timing,
   342     trans = trans};
   343 
   344 fun map_transition f (Transition {name, pos, int_only, print, no_timing, trans}) =
   345   make_transition (f (name, pos, int_only, print, no_timing, trans));
   346 
   347 val empty = make_transition ("", Position.none, false, false, false, []);
   348 
   349 
   350 (* diagnostics *)
   351 
   352 fun init_of (Transition {trans = [Init (name, _)], ...}) = SOME name
   353   | init_of _ = NONE;
   354 
   355 fun name_of (Transition {name, ...}) = name;
   356 fun pos_of (Transition {pos, ...}) = pos;
   357 fun str_of tr = quote (name_of tr) ^ Position.str_of (pos_of tr);
   358 
   359 fun command_msg msg tr = msg ^ "command " ^ str_of tr;
   360 fun at_command tr = command_msg "At " tr ^ ".";
   361 
   362 fun type_error tr state =
   363   ERROR (command_msg "Illegal application of " tr ^ " " ^ str_of_state state);
   364 
   365 
   366 (* modify transitions *)
   367 
   368 fun name name = map_transition (fn (_, pos, int_only, print, no_timing, trans) =>
   369   (name, pos, int_only, print, no_timing, trans));
   370 
   371 fun position pos = map_transition (fn (name, _, int_only, print, no_timing, trans) =>
   372   (name, pos, int_only, print, no_timing, trans));
   373 
   374 fun interactive int_only = map_transition (fn (name, pos, _, print, no_timing, trans) =>
   375   (name, pos, int_only, print, no_timing, trans));
   376 
   377 val no_timing = map_transition (fn (name, pos, int_only, print, _, trans) =>
   378   (name, pos, int_only, print, true, trans));
   379 
   380 fun add_trans tr = map_transition (fn (name, pos, int_only, print, no_timing, trans) =>
   381   (name, pos, int_only, print, no_timing, tr :: trans));
   382 
   383 val reset_trans = map_transition (fn (name, pos, int_only, print, no_timing, _) =>
   384   (name, pos, int_only, print, no_timing, []));
   385 
   386 fun set_print print = map_transition (fn (name, pos, int_only, _, no_timing, trans) =>
   387   (name, pos, int_only, print, no_timing, trans));
   388 
   389 val print = set_print true;
   390 
   391 
   392 (* basic transitions *)
   393 
   394 fun init_theory name f = add_trans (Init (name, f));
   395 
   396 fun modify_init f tr =
   397   (case init_of tr of
   398     SOME name => init_theory name f (reset_trans tr)
   399   | NONE => tr);
   400 
   401 val exit = add_trans Exit;
   402 val keep' = add_trans o Keep;
   403 
   404 fun present_transaction f g = add_trans (Transaction (f, g));
   405 fun transaction f = present_transaction f (K ());
   406 
   407 fun keep f = add_trans (Keep (fn _ => f));
   408 fun imperative f = keep (fn _ => f ());
   409 
   410 fun ignored pos = empty |> name "<ignored>" |> position pos |> imperative I;
   411 fun malformed pos msg =
   412   empty |> name "<malformed>" |> position pos |> imperative (fn () => error msg);
   413 
   414 val unknown_theory = imperative (fn () => warning "Unknown theory context");
   415 val unknown_proof = imperative (fn () => warning "Unknown proof context");
   416 val unknown_context = imperative (fn () => warning "Unknown context");
   417 
   418 
   419 (* theory transitions *)
   420 
   421 fun generic_theory f = transaction (fn _ =>
   422   (fn Theory (gthy, _) => Theory (f gthy, NONE)
   423     | _ => raise UNDEF));
   424 
   425 fun theory' f = transaction (fn int =>
   426   (fn Theory (Context.Theory thy, _) =>
   427       let val thy' = thy
   428         |> Sign.new_group
   429         |> Theory.checkpoint
   430         |> f int
   431         |> Sign.reset_group;
   432       in Theory (Context.Theory thy', NONE) end
   433     | _ => raise UNDEF));
   434 
   435 fun theory f = theory' (K f);
   436 
   437 fun begin_local_theory begin f = transaction (fn _ =>
   438   (fn Theory (Context.Theory thy, _) =>
   439         let
   440           val lthy = f thy;
   441           val gthy = if begin then Context.Proof lthy else Context.Theory (loc_exit lthy);
   442         in Theory (gthy, SOME lthy) end
   443     | _ => raise UNDEF));
   444 
   445 val end_local_theory = transaction (fn _ =>
   446   (fn Theory (Context.Proof lthy, _) => Theory (Context.Theory (loc_exit lthy), SOME lthy)
   447     | _ => raise UNDEF));
   448 
   449 local
   450 
   451 fun local_theory_presentation loc f = present_transaction (fn int =>
   452   (fn Theory (gthy, _) =>
   453         let
   454           val finish = loc_finish loc gthy;
   455           val lthy' = loc_begin loc gthy
   456             |> Local_Theory.new_group
   457             |> f int
   458             |> Local_Theory.reset_group;
   459         in Theory (finish lthy', SOME lthy') end
   460     | _ => raise UNDEF));
   461 
   462 in
   463 
   464 fun local_theory' loc f = local_theory_presentation loc f (K ());
   465 fun local_theory loc f = local_theory' loc (K f);
   466 fun present_local_theory loc = local_theory_presentation loc (K I);
   467 
   468 end;
   469 
   470 
   471 (* proof transitions *)
   472 
   473 fun end_proof f = transaction (fn int =>
   474   (fn Proof (prf, (finish, _)) =>
   475         let val state = Proof_Node.current prf in
   476           if can (Proof.assert_bottom true) state then
   477             let
   478               val ctxt' = f int state;
   479               val gthy' = finish ctxt';
   480             in Theory (gthy', SOME ctxt') end
   481           else raise UNDEF
   482         end
   483     | SkipProof (0, (gthy, _)) => Theory (gthy, NONE)
   484     | _ => raise UNDEF));
   485 
   486 local
   487 
   488 fun begin_proof init finish = transaction (fn int =>
   489   (fn Theory (gthy, _) =>
   490     let
   491       val prf = init int gthy;
   492       val skip = ! skip_proofs;
   493       val schematic = Proof.schematic_goal prf;
   494     in
   495       if skip andalso schematic then
   496         warning "Cannot skip proof of schematic goal statement"
   497       else ();
   498       if skip andalso not schematic then
   499         SkipProof (0, (finish gthy (Proof.global_skip_proof int prf), gthy))
   500       else Proof (Proof_Node.init prf, (finish gthy, gthy))
   501     end
   502   | _ => raise UNDEF));
   503 
   504 in
   505 
   506 fun local_theory_to_proof' loc f = begin_proof
   507   (fn int => fn gthy => f int (Local_Theory.new_group (loc_begin loc gthy)))
   508   (fn gthy => loc_finish loc gthy o Local_Theory.reset_group);
   509 
   510 fun local_theory_to_proof loc f = local_theory_to_proof' loc (K f);
   511 
   512 fun theory_to_proof f = begin_proof
   513   (K (fn Context.Theory thy => f (Theory.checkpoint (Sign.new_group thy)) | _ => raise UNDEF))
   514   (K (Context.Theory o Sign.reset_group o ProofContext.theory_of));
   515 
   516 end;
   517 
   518 val forget_proof = transaction (fn _ =>
   519   (fn Proof (_, (_, orig_gthy)) => Theory (orig_gthy, NONE)
   520     | SkipProof (_, (_, orig_gthy)) => Theory (orig_gthy, NONE)
   521     | _ => raise UNDEF));
   522 
   523 val present_proof = present_transaction (fn _ =>
   524   (fn Proof (prf, x) => Proof (Proof_Node.apply I prf, x)
   525     | skip as SkipProof _ => skip
   526     | _ => raise UNDEF));
   527 
   528 fun proofs' f = transaction (fn int =>
   529   (fn Proof (prf, x) => Proof (Proof_Node.applys (f int) prf, x)
   530     | skip as SkipProof _ => skip
   531     | _ => raise UNDEF));
   532 
   533 fun proof' f = proofs' (Seq.single oo f);
   534 val proofs = proofs' o K;
   535 val proof = proof' o K;
   536 
   537 fun actual_proof f = transaction (fn _ =>
   538   (fn Proof (prf, x) => Proof (f prf, x)
   539     | _ => raise UNDEF));
   540 
   541 fun skip_proof f = transaction (fn _ =>
   542   (fn SkipProof (h, x) => SkipProof (f h, x)
   543     | _ => raise UNDEF));
   544 
   545 fun skip_proof_to_theory pred = transaction (fn _ =>
   546   (fn SkipProof (d, (gthy, _)) => if pred d then Theory (gthy, NONE) else raise UNDEF
   547     | _ => raise UNDEF));
   548 
   549 
   550 
   551 (** toplevel transactions **)
   552 
   553 (* identification *)
   554 
   555 fun get_id (Transition {pos, ...}) = Position.get_id pos;
   556 fun put_id id (tr as Transition {pos, ...}) = position (Position.put_id id pos) tr;
   557 
   558 
   559 (* thread position *)
   560 
   561 fun setmp_thread_position (Transition {pos, ...}) f x =
   562   Position.setmp_thread_data pos f x;
   563 
   564 fun status tr m =
   565   setmp_thread_position tr (fn () => Output.status (Markup.markup m "")) ();
   566 
   567 fun async_state (tr as Transition {print, ...}) st =
   568   if print then
   569     ignore
   570       (Future.fork (fn () =>
   571           setmp_thread_position tr (fn () => Future.status (fn () => print_state false st)) ()))
   572   else ();
   573 
   574 fun error_msg tr exn_info =
   575   setmp_thread_position tr (fn () =>
   576     Output.error_msg (ML_Compiler.exn_message (EXCURSION_FAIL exn_info))) ();
   577 
   578 
   579 (* post-transition hooks *)
   580 
   581 local
   582   val hooks = Unsynchronized.ref ([]: (transition -> state -> state -> unit) list);
   583 in
   584 
   585 fun add_hook f = CRITICAL (fn () => Unsynchronized.change hooks (cons f));
   586 fun get_hooks () = ! hooks;
   587 
   588 end;
   589 
   590 
   591 (* apply transitions *)
   592 
   593 local
   594 
   595 fun app int (tr as Transition {trans, print, no_timing, ...}) =
   596   setmp_thread_position tr (fn state =>
   597     let
   598       fun do_timing f x = (warning (command_msg "" tr); timeap f x);
   599       fun do_profiling f x = profile (! profiling) f x;
   600 
   601       val (result, status) =
   602          state |>
   603           (apply_trans int trans
   604             |> (! profiling > 0 andalso not no_timing) ? do_profiling
   605             |> (! profiling > 0 orelse ! timing andalso not no_timing) ? do_timing);
   606 
   607       val _ = if int andalso not (! quiet) andalso print then print_state false result else ();
   608     in (result, Option.map (fn UNDEF => type_error tr state | exn => exn) status) end);
   609 
   610 in
   611 
   612 fun transition int tr st =
   613   let
   614     val hooks = get_hooks ();
   615     fun apply_hooks st' = hooks |> List.app (fn f => (try (fn () => f tr st st') (); ()));
   616 
   617     val ctxt = try context_of st;
   618     val res =
   619       (case app int tr st of
   620         (_, SOME TERMINATE) => NONE
   621       | (st', SOME (EXCURSION_FAIL exn_info)) => SOME (st', SOME exn_info)
   622       | (st', SOME exn) => SOME (st', SOME (Runtime.exn_context ctxt exn, at_command tr))
   623       | (st', NONE) => SOME (st', NONE));
   624     val _ = (case res of SOME (st', NONE) => apply_hooks st' | _ => ());
   625   in res end;
   626 
   627 end;
   628 
   629 
   630 (* managed execution *)
   631 
   632 fun run_command thy_name tr st =
   633   (case
   634       (case init_of tr of
   635         SOME name => Exn.capture (fn () => Thy_Header.consistent_name thy_name name) ()
   636       | NONE => Exn.Result ()) of
   637     Exn.Result () =>
   638       let val int = is_some (init_of tr) in
   639         (case transition int tr st of
   640           SOME (st', NONE) =>
   641             (status tr Markup.finished; if int then () else async_state tr st'; SOME st')
   642         | SOME (_, SOME (exn as Exn.Interrupt, _)) => reraise exn
   643         | SOME (_, SOME exn_info) => (error_msg tr exn_info; status tr Markup.failed; NONE)
   644         | NONE => (error_msg tr (TERMINATE, at_command tr); status tr Markup.failed; NONE))
   645       end
   646   | Exn.Exn exn => (error_msg tr (exn, at_command tr); status tr Markup.failed; NONE));
   647 
   648 
   649 (* nested commands *)
   650 
   651 fun command tr st =
   652   (case transition (! interact) tr st of
   653     SOME (st', NONE) => st'
   654   | SOME (_, SOME exn_info) => raise EXCURSION_FAIL exn_info
   655   | NONE => raise EXCURSION_FAIL (TERMINATE, at_command tr));
   656 
   657 fun command_result tr st =
   658   let val st' = command tr st
   659   in (st', st') end;
   660 
   661 
   662 (* excursion of units, consisting of commands with proof *)
   663 
   664 structure States = Proof_Data
   665 (
   666   type T = state list future option;
   667   fun init _ = NONE;
   668 );
   669 
   670 fun proof_result immediate (tr, proof_trs) st =
   671   let val st' = command tr st in
   672     if immediate orelse
   673       null proof_trs orelse
   674       Keyword.is_schematic_goal (name_of tr) orelse
   675       exists (Keyword.is_qed_global o name_of) proof_trs orelse
   676       not (can proof_of st') orelse
   677       Proof.is_relevant (proof_of st')
   678     then
   679       let val (states, st'') = fold_map command_result proof_trs st'
   680       in (Lazy.value ((tr, st') :: (proof_trs ~~ states)), st'') end
   681     else
   682       let
   683         val (body_trs, end_tr) = split_last proof_trs;
   684         val finish = Context.Theory o ProofContext.theory_of;
   685 
   686         val future_proof = Proof.global_future_proof
   687           (fn prf =>
   688             Future.fork_pri ~1 (fn () =>
   689               let val (states, result_state) =
   690                 (case st' of State (SOME (Proof (_, (_, orig_gthy))), prev)
   691                   => State (SOME (Proof (Proof_Node.init prf, (finish, orig_gthy))), prev))
   692                 |> fold_map command_result body_trs
   693                 ||> command (end_tr |> set_print false);
   694               in (states, presentation_context_of result_state) end))
   695           #> (fn (states, ctxt) => States.put (SOME states) ctxt);
   696 
   697         val st'' = st' |> command (end_tr |> reset_trans |> end_proof (K future_proof));
   698 
   699         val states =
   700           (case States.get (presentation_context_of st'') of
   701             NONE => raise Fail ("No future states for " ^ name_of tr ^ Position.str_of (pos_of tr))
   702           | SOME states => states);
   703         val result = Lazy.lazy
   704           (fn () => (tr, st') :: (body_trs ~~ Future.join states) @ [(end_tr, st'')]);
   705 
   706       in (result, st'') end
   707   end;
   708 
   709 fun excursion input =
   710   let
   711     val end_pos = if null input then error "No input" else pos_of (fst (List.last input));
   712     val immediate = not (Goal.future_enabled ());
   713     val (results, end_state) = fold_map (proof_result immediate) input toplevel;
   714     val thy = end_theory end_pos end_state;
   715   in (Lazy.lazy (fn () => maps Lazy.force results), thy) end;
   716 
   717 end;