src/HOL/Tools/Sledgehammer/sledgehammer_fact.ML
author wenzelm
Mon Nov 26 21:46:04 2012 +0100 (2012-11-26 ago)
changeset 50239 fb579401dc26
parent 50053 fea589c8583e
child 50442 4f6a4d32522c
permissions -rw-r--r--
tuned signature;
tuned;
     1 (*  Title:      HOL/Tools/Sledgehammer/sledgehammer_fact.ML
     2     Author:     Jia Meng, Cambridge University Computer Laboratory and NICTA
     3     Author:     Jasmin Blanchette, TU Muenchen
     4 
     5 Sledgehammer fact handling.
     6 *)
     7 
     8 signature SLEDGEHAMMER_FACT =
     9 sig
    10   type status = ATP_Problem_Generate.status
    11   type stature = ATP_Problem_Generate.stature
    12 
    13   type fact = ((unit -> string) * stature) * thm
    14 
    15   type fact_override =
    16     {add : (Facts.ref * Attrib.src list) list,
    17      del : (Facts.ref * Attrib.src list) list,
    18      only : bool}
    19 
    20   val ignore_no_atp : bool Config.T
    21   val instantiate_inducts : bool Config.T
    22   val no_fact_override : fact_override
    23   val fact_from_ref :
    24     Proof.context -> unit Symtab.table -> thm list -> status Termtab.table
    25     -> Facts.ref * Attrib.src list -> ((string * stature) * thm) list
    26   val backquote_thm : Proof.context -> thm -> string
    27   val clasimpset_rule_table_of : Proof.context -> status Termtab.table
    28   val maybe_instantiate_inducts :
    29     Proof.context -> term list -> term -> (((unit -> string) * 'a) * thm) list
    30     -> (((unit -> string) * 'a) * thm) list
    31   val maybe_filter_no_atps : Proof.context -> ('a * thm) list -> ('a * thm) list
    32   val all_facts :
    33     Proof.context -> bool -> unit Symtab.table -> thm list -> thm list
    34     -> status Termtab.table -> fact list
    35   val nearly_all_facts :
    36     Proof.context -> bool -> fact_override -> unit Symtab.table
    37     -> status Termtab.table -> thm list -> term list -> term -> fact list
    38 end;
    39 
    40 structure Sledgehammer_Fact : SLEDGEHAMMER_FACT =
    41 struct
    42 
    43 open ATP_Problem_Generate
    44 open Metis_Tactic
    45 open Sledgehammer_Util
    46 
    47 type fact = ((unit -> string) * stature) * thm
    48 
    49 type fact_override =
    50   {add : (Facts.ref * Attrib.src list) list,
    51    del : (Facts.ref * Attrib.src list) list,
    52    only : bool}
    53 
    54 (* experimental features *)
    55 val ignore_no_atp =
    56   Attrib.setup_config_bool @{binding sledgehammer_ignore_no_atp} (K false)
    57 val instantiate_inducts =
    58   Attrib.setup_config_bool @{binding sledgehammer_instantiate_inducts} (K false)
    59 
    60 val no_fact_override = {add = [], del = [], only = false}
    61 
    62 fun needs_quoting reserved s =
    63   Symtab.defined reserved s orelse
    64   exists (not o Symbol_Pos.is_identifier) (Long_Name.explode s)
    65 
    66 fun make_name reserved multi j name =
    67   (name |> needs_quoting reserved name ? quote) ^
    68   (if multi then "(" ^ string_of_int j ^ ")" else "")
    69 
    70 fun explode_interval _ (Facts.FromTo (i, j)) = i upto j
    71   | explode_interval max (Facts.From i) = i upto i + max - 1
    72   | explode_interval _ (Facts.Single i) = [i]
    73 
    74 val backquote =
    75   raw_explode #> map (fn "`" => "\\`" | s => s) #> implode #> enclose "`" "`"
    76 
    77 (* unfolding these can yield really huge terms *)
    78 val risky_defs = @{thms Bit0_def Bit1_def}
    79 
    80 fun is_rec_eq lhs = Term.exists_subterm (curry (op =) (head_of lhs))
    81 fun is_rec_def (@{const Trueprop} $ t) = is_rec_def t
    82   | is_rec_def (@{const ==>} $ _ $ t2) = is_rec_def t2
    83   | is_rec_def (Const (@{const_name "=="}, _) $ t1 $ t2) = is_rec_eq t1 t2
    84   | is_rec_def (Const (@{const_name HOL.eq}, _) $ t1 $ t2) = is_rec_eq t1 t2
    85   | is_rec_def _ = false
    86 
    87 fun is_assum assms th = exists (fn ct => prop_of th aconv term_of ct) assms
    88 fun is_chained chained = member Thm.eq_thm_prop chained
    89 
    90 fun scope_of_thm global assms chained th =
    91   if is_chained chained th then Chained
    92   else if global then Global
    93   else if is_assum assms th then Assum
    94   else Local
    95 
    96 val may_be_induction =
    97   exists_subterm (fn Var (_, Type (@{type_name fun}, [_, T])) =>
    98                      body_type T = @{typ bool}
    99                    | _ => false)
   100 
   101 fun status_of_thm css name th =
   102   (* FIXME: use structured name *)
   103   if (String.isSubstring ".induct" name orelse
   104       String.isSubstring ".inducts" name) andalso
   105      may_be_induction (prop_of th) then
   106     Induction
   107   else case Termtab.lookup css (prop_of th) of
   108     SOME status => status
   109   | NONE => General
   110 
   111 fun stature_of_thm global assms chained css name th =
   112   (scope_of_thm global assms chained th, status_of_thm css name th)
   113 
   114 fun fact_from_ref ctxt reserved chained css (xthm as (xref, args)) =
   115   let
   116     val ths = Attrib.eval_thms ctxt [xthm]
   117     val bracket =
   118       map (enclose "[" "]" o Pretty.str_of o Args.pretty_src ctxt) args
   119       |> implode
   120     fun nth_name j =
   121       case xref of
   122         Facts.Fact s => backquote s ^ bracket
   123       | Facts.Named (("", _), _) => "[" ^ bracket ^ "]"
   124       | Facts.Named ((name, _), NONE) =>
   125         make_name reserved (length ths > 1) (j + 1) name ^ bracket
   126       | Facts.Named ((name, _), SOME intervals) =>
   127         make_name reserved true
   128                  (nth (maps (explode_interval (length ths)) intervals) j) name ^
   129         bracket
   130     fun add_nth th (j, rest) =
   131       let val name = nth_name j in
   132         (j + 1, ((name, stature_of_thm false [] chained css name th), th)
   133                 :: rest)
   134       end
   135   in (0, []) |> fold add_nth ths |> snd end
   136 
   137 (* Reject theorems with names like "List.filter.filter_list_def" or
   138   "Accessible_Part.acc.defs", as these are definitions arising from packages. *)
   139 fun is_package_def a =
   140   let val names = Long_Name.explode a in
   141     (length names > 2 andalso not (hd names = "local") andalso
   142      String.isSuffix "_def" a) orelse String.isSuffix "_defs" a
   143   end
   144 
   145 (* FIXME: put other record thms here, or declare as "no_atp" *)
   146 fun multi_base_blacklist ctxt ho_atp =
   147   ["defs", "select_defs", "update_defs", "split", "splits", "split_asm",
   148    "cases", "ext_cases", "eq.simps", "eq.refl", "nchotomy", "case_cong",
   149    "weak_case_cong", "nibble_pair_of_char_simps", "nibble.simps",
   150    "nibble.distinct"]
   151   |> not (ho_atp orelse (Config.get ctxt instantiate_inducts)) ?
   152         append ["induct", "inducts"]
   153   |> map (prefix Long_Name.separator)
   154 
   155 val max_lambda_nesting = 3 (*only applies if not ho_atp*)
   156 
   157 fun term_has_too_many_lambdas max (t1 $ t2) =
   158     exists (term_has_too_many_lambdas max) [t1, t2]
   159   | term_has_too_many_lambdas max (Abs (_, _, t)) =
   160     max = 0 orelse term_has_too_many_lambdas (max - 1) t
   161   | term_has_too_many_lambdas _ _ = false
   162 
   163 (* Don't count nested lambdas at the level of formulas, since they are
   164    quantifiers. *)
   165 fun formula_has_too_many_lambdas Ts (Abs (_, T, t)) =
   166     formula_has_too_many_lambdas (T :: Ts) t
   167   | formula_has_too_many_lambdas Ts t =
   168     if member (op =) [HOLogic.boolT, propT] (fastype_of1 (Ts, t)) then
   169       exists (formula_has_too_many_lambdas Ts) (#2 (strip_comb t))
   170     else
   171       term_has_too_many_lambdas max_lambda_nesting t
   172 
   173 (* The max apply depth of any "metis" call in "Metis_Examples" (on 2007-10-31)
   174    was 11. *)
   175 val max_apply_depth = 15
   176 
   177 fun apply_depth (f $ t) = Int.max (apply_depth f, apply_depth t + 1)
   178   | apply_depth (Abs (_, _, t)) = apply_depth t
   179   | apply_depth _ = 0
   180 
   181 fun is_formula_too_complex ho_atp t =
   182   apply_depth t > max_apply_depth orelse
   183   (not ho_atp andalso formula_has_too_many_lambdas [] t)
   184 
   185 (* FIXME: Ad hoc list *)
   186 val technical_prefixes =
   187   ["ATP", "Code_Evaluation", "DSequence", "Enum", "Lazy_Sequence", "Meson",
   188    "Metis", "Nitpick", "New_DSequence", "New_Random_Sequence", "Quickcheck",
   189    "Quickcheck_Exhaustive", "Quickcheck_Narrowing", "Random_Sequence",
   190    "Sledgehammer", "SMT"]
   191   |> map (suffix Long_Name.separator)
   192 
   193 fun has_technical_prefix s =
   194   exists (fn pref => String.isPrefix pref s) technical_prefixes
   195 val exists_technical_const = exists_Const (has_technical_prefix o fst)
   196 
   197 (* FIXME: make more reliable *)
   198 val exists_low_level_class_const =
   199   exists_Const (fn (s, _) =>
   200      s = @{const_name equal_class.equal} orelse
   201      String.isSubstring (Long_Name.separator ^ "class" ^ Long_Name.separator) s)
   202 
   203 fun is_that_fact th =
   204   String.isSuffix (Long_Name.separator ^ Obtain.thatN) (Thm.get_name_hint th)
   205   andalso exists_subterm (fn Free (s, _) => s = Name.skolem Auto_Bind.thesisN
   206                            | _ => false) (prop_of th)
   207 
   208 fun is_likely_tautology_or_too_meta th =
   209   let
   210     fun is_interesting_subterm (Const (s, _)) =
   211         not (member (op =) atp_widely_irrelevant_consts s)
   212       | is_interesting_subterm (Free _) = true
   213       | is_interesting_subterm _ = false
   214     fun is_boring_bool t =
   215       not (exists_subterm is_interesting_subterm t) orelse
   216       exists_type (exists_subtype (curry (op =) @{typ prop})) t
   217     fun is_boring_prop (@{const Trueprop} $ t) = is_boring_bool t
   218       | is_boring_prop (@{const "==>"} $ t $ u) =
   219         is_boring_prop t andalso is_boring_prop u
   220       | is_boring_prop (Const (@{const_name all}, _) $ (Abs (_, _, t)) $ u) =
   221         is_boring_prop t andalso is_boring_prop u
   222       | is_boring_prop (Const (@{const_name "=="}, _) $ t $ u) =
   223         is_boring_bool t andalso is_boring_bool u
   224       | is_boring_prop _ = true
   225   in
   226     is_boring_prop (prop_of th) andalso not (Thm.eq_thm_prop (@{thm ext}, th))
   227   end
   228 
   229 fun is_theorem_bad_for_atps ho_atp th =
   230   is_likely_tautology_or_too_meta th orelse
   231   let val t = prop_of th in
   232     is_formula_too_complex ho_atp t orelse
   233     exists_type type_has_top_sort t orelse exists_technical_const t orelse
   234     exists_low_level_class_const t orelse is_that_fact th
   235   end
   236 
   237 fun hackish_string_for_term ctxt =
   238   with_vanilla_print_mode (Syntax.string_of_term ctxt) #> simplify_spaces
   239 
   240 (* This is a terrible hack. Free variables are sometimes coded as "M__" when
   241    they are displayed as "M" and we want to avoid clashes with these. But
   242    sometimes it's even worse: "Ma__" encodes "M". So we simply reserve all
   243    prefixes of all free variables. In the worse case scenario, where the fact
   244    won't be resolved correctly, the user can fix it manually, e.g., by giving a
   245    name to the offending fact. *)
   246 fun all_prefixes_of s =
   247   map (fn i => String.extract (s, 0, SOME i)) (1 upto size s - 1)
   248 
   249 fun close_form t =
   250   (t, [] |> Term.add_free_names t |> maps all_prefixes_of)
   251   |> fold (fn ((s, i), T) => fn (t', taken) =>
   252               let val s' = singleton (Name.variant_list taken) s in
   253                 ((if fastype_of t' = HOLogic.boolT then HOLogic.all_const
   254                   else Logic.all_const) T
   255                  $ Abs (s', T, abstract_over (Var ((s, i), T), t')),
   256                  s' :: taken)
   257               end)
   258           (Term.add_vars t [] |> sort_wrt (fst o fst))
   259   |> fst
   260 
   261 fun backquote_term ctxt t =
   262   t |> close_form
   263     |> hackish_string_for_term ctxt
   264     |> backquote
   265 
   266 fun backquote_thm ctxt th = backquote_term ctxt (prop_of th)
   267 
   268 fun clasimpset_rule_table_of ctxt =
   269   let
   270     val thy = Proof_Context.theory_of ctxt
   271     val atomize = HOLogic.mk_Trueprop o Object_Logic.atomize_term thy
   272     fun add stature normalizers get_th =
   273       fold (fn rule =>
   274                let
   275                  val th = rule |> get_th
   276                  val t =
   277                    th |> Thm.maxidx_of th > 0 ? zero_var_indexes |> prop_of
   278                in
   279                  fold (fn normalize => Termtab.update (normalize t, stature))
   280                       (I :: normalizers)
   281                end)
   282     val {safeIs, (* safeEs, *) hazIs, (* hazEs, *) ...} =
   283       ctxt |> claset_of |> Classical.rep_cs
   284     val intros = Item_Net.content safeIs @ Item_Net.content hazIs
   285 (* Add once it is used:
   286     val elims =
   287       Item_Net.content safeEs @ Item_Net.content hazEs
   288       |> map Classical.classical_rule
   289 *)
   290     val simps = ctxt |> simpset_of |> dest_ss |> #simps
   291     val specs = ctxt |> Spec_Rules.get
   292     val (rec_defs, nonrec_defs) =
   293       specs |> filter (curry (op =) Spec_Rules.Equational o fst)
   294             |> maps (snd o snd)
   295             |> filter_out (member Thm.eq_thm_prop risky_defs)
   296             |> List.partition (is_rec_def o prop_of)
   297     val spec_intros =
   298       specs |> filter (member (op =) [Spec_Rules.Inductive,
   299                                       Spec_Rules.Co_Inductive] o fst)
   300             |> maps (snd o snd)
   301   in
   302     Termtab.empty |> add Simp [atomize] snd simps
   303                   |> add Rec_Def [] I rec_defs
   304                   |> add Non_Rec_Def [] I nonrec_defs
   305 (* Add once it is used:
   306                   |> add Elim [] I elims
   307 *)
   308                   |> add Intro [] I intros
   309                   |> add Inductive [] I spec_intros
   310   end
   311 
   312 fun uniquify xs =
   313   Termtab.fold (cons o snd)
   314                (fold (Termtab.update o `(prop_of o snd)) xs Termtab.empty) []
   315 
   316 fun struct_induct_rule_on th =
   317   case Logic.strip_horn (prop_of th) of
   318     (prems, @{const Trueprop}
   319             $ ((p as Var ((p_name, 0), _)) $ (a as Var (_, ind_T)))) =>
   320     if not (is_TVar ind_T) andalso length prems > 1 andalso
   321        exists (exists_subterm (curry (op aconv) p)) prems andalso
   322        not (exists (exists_subterm (curry (op aconv) a)) prems) then
   323       SOME (p_name, ind_T)
   324     else
   325       NONE
   326   | _ => NONE
   327 
   328 fun instantiate_induct_rule ctxt concl_prop p_name ((name, stature), th) ind_x =
   329   let
   330     fun varify_noninducts (t as Free (s, T)) =
   331         if (s, T) = ind_x orelse can dest_funT T then t else Var ((s, 0), T)
   332       | varify_noninducts t = t
   333     val p_inst =
   334       concl_prop |> map_aterms varify_noninducts |> close_form
   335                  |> lambda (Free ind_x)
   336                  |> hackish_string_for_term ctxt
   337   in
   338     ((fn () => name () ^ "[where " ^ p_name ^ " = " ^ quote p_inst ^ "]",
   339       stature), th |> read_instantiate ctxt [((p_name, 0), p_inst)])
   340   end
   341 
   342 fun type_match thy (T1, T2) =
   343   (Sign.typ_match thy (T2, T1) Vartab.empty; true)
   344   handle Type.TYPE_MATCH => false
   345 
   346 fun instantiate_if_induct_rule ctxt stmt stmt_xs (ax as (_, th)) =
   347   case struct_induct_rule_on th of
   348     SOME (p_name, ind_T) =>
   349     let val thy = Proof_Context.theory_of ctxt in
   350       stmt_xs |> filter (fn (_, T) => type_match thy (T, ind_T))
   351               |> map_filter (try (instantiate_induct_rule ctxt stmt p_name ax))
   352     end
   353   | NONE => [ax]
   354 
   355 fun external_frees t =
   356   [] |> Term.add_frees t |> filter_out (can Name.dest_internal o fst)
   357 
   358 fun maybe_instantiate_inducts ctxt hyp_ts concl_t =
   359   if Config.get ctxt instantiate_inducts then
   360     let
   361       val thy = Proof_Context.theory_of ctxt
   362       val ind_stmt =
   363         (hyp_ts |> filter_out (null o external_frees), concl_t)
   364         |> Logic.list_implies |> Object_Logic.atomize_term thy
   365       val ind_stmt_xs = external_frees ind_stmt
   366     in maps (instantiate_if_induct_rule ctxt ind_stmt ind_stmt_xs) end
   367   else
   368     I
   369 
   370 fun maybe_filter_no_atps ctxt =
   371   not (Config.get ctxt ignore_no_atp) ? filter_out (No_ATPs.member ctxt o snd)
   372 
   373 fun all_facts ctxt ho_atp reserved add_ths chained css =
   374   let
   375     val thy = Proof_Context.theory_of ctxt
   376     val global_facts = Global_Theory.facts_of thy
   377     val local_facts = Proof_Context.facts_of ctxt
   378     val named_locals = local_facts |> Facts.dest_static []
   379     val assms = Assumption.all_assms_of ctxt
   380     fun is_good_unnamed_local th =
   381       not (Thm.has_name_hint th) andalso
   382       forall (fn (_, ths) => not (member Thm.eq_thm_prop ths th)) named_locals
   383     val unnamed_locals =
   384       union Thm.eq_thm_prop (Facts.props local_facts) chained
   385       |> filter is_good_unnamed_local |> map (pair "" o single)
   386     val full_space =
   387       Name_Space.merge (Facts.space_of global_facts, Facts.space_of local_facts)
   388     fun add_facts global foldx facts =
   389       foldx (fn (name0, ths) =>
   390         if name0 <> "" andalso
   391            forall (not o member Thm.eq_thm_prop add_ths) ths andalso
   392            (Facts.is_concealed facts name0 orelse
   393             not (can (Proof_Context.get_thms ctxt) name0) orelse
   394             (not (Config.get ctxt ignore_no_atp) andalso
   395              is_package_def name0) orelse
   396             exists (fn s => String.isSuffix s name0)
   397                    (multi_base_blacklist ctxt ho_atp)) then
   398           I
   399         else
   400           let
   401             val multi = length ths > 1
   402             fun check_thms a =
   403               case try (Proof_Context.get_thms ctxt) a of
   404                 NONE => false
   405               | SOME ths' => eq_list Thm.eq_thm_prop (ths, ths')
   406           in
   407             pair 1
   408             #> fold (fn th => fn (j, (multis, unis)) =>
   409                         (j + 1,
   410                          if not (member Thm.eq_thm_prop add_ths th) andalso
   411                             is_theorem_bad_for_atps ho_atp th then
   412                            (multis, unis)
   413                          else
   414                            let
   415                              val new =
   416                                (((fn () =>
   417                                      if name0 = "" then
   418                                        backquote_thm ctxt th
   419                                      else
   420                                        [Facts.extern ctxt facts name0,
   421                                         Name_Space.extern ctxt full_space name0]
   422                                        |> find_first check_thms
   423                                        |> the_default name0
   424                                        |> make_name reserved multi j),
   425                                   stature_of_thm global assms chained css name0
   426                                                  th), th)
   427                            in
   428                              if multi then (new :: multis, unis)
   429                              else (multis, new :: unis)
   430                            end)) ths
   431             #> snd
   432           end)
   433   in
   434     (* The single-name theorems go after the multiple-name ones, so that single
   435        names are preferred when both are available. *)
   436     ([], []) |> add_facts false fold local_facts (unnamed_locals @ named_locals)
   437              |> add_facts true Facts.fold_static global_facts global_facts
   438              |> op @
   439   end
   440 
   441 fun nearly_all_facts ctxt ho_atp {add, del, only} reserved css chained hyp_ts
   442                      concl_t =
   443   if only andalso null add then
   444     []
   445   else
   446     let
   447       val chained =
   448         chained
   449         |> maps (fn th => insert Thm.eq_thm_prop (zero_var_indexes th) [th])
   450     in
   451       (if only then
   452          maps (map (fn ((name, stature), th) => ((K name, stature), th))
   453                o fact_from_ref ctxt reserved chained css) add
   454        else
   455          let val (add, del) = pairself (Attrib.eval_thms ctxt) (add, del) in
   456            all_facts ctxt ho_atp reserved add chained css
   457            |> filter_out (member Thm.eq_thm_prop del o snd)
   458            |> maybe_filter_no_atps ctxt
   459            |> uniquify
   460          end)
   461       |> maybe_instantiate_inducts ctxt hyp_ts concl_t
   462     end
   463 
   464 end;