src/Pure/Isar/proof_context.ML
author wenzelm
Sat Jun 21 16:18:51 2008 +0200 (2008-06-21 ago)
changeset 27314 fce7f0c7cf76
parent 27286 2ea20e5fdf16
child 27738 66596d7aa899
permissions -rw-r--r--
added query_type/const/class (meta data);
     1 (*  Title:      Pure/Isar/proof_context.ML
     2     ID:         $Id$
     3     Author:     Markus Wenzel, TU Muenchen
     4 
     5 The key concept of Isar proof contexts: elevates primitive local
     6 reasoning Gamma |- phi to a structured concept, with generic context
     7 elements.  See also structure Variable and Assumption.
     8 *)
     9 
    10 signature PROOF_CONTEXT =
    11 sig
    12   val theory_of: Proof.context -> theory
    13   val init: theory -> Proof.context
    14   type mode
    15   val mode_default: mode
    16   val mode_stmt: mode
    17   val mode_pattern: mode
    18   val mode_schematic: mode
    19   val mode_abbrev: mode
    20   val set_mode: mode -> Proof.context -> Proof.context
    21   val get_mode: Proof.context -> mode
    22   val restore_mode: Proof.context -> Proof.context -> Proof.context
    23   val abbrev_mode: Proof.context -> bool
    24   val set_stmt: bool -> Proof.context -> Proof.context
    25   val naming_of: Proof.context -> NameSpace.naming
    26   val full_name: Proof.context -> bstring -> string
    27   val consts_of: Proof.context -> Consts.T
    28   val const_syntax_name: Proof.context -> string -> string
    29   val the_const_constraint: Proof.context -> string -> typ
    30   val mk_const: Proof.context -> string * typ list -> term
    31   val set_syntax_mode: Syntax.mode -> Proof.context -> Proof.context
    32   val restore_syntax_mode: Proof.context -> Proof.context -> Proof.context
    33   val facts_of: Proof.context -> Facts.T
    34   val transfer_syntax: theory -> Proof.context -> Proof.context
    35   val transfer: theory -> Proof.context -> Proof.context
    36   val theory: (theory -> theory) -> Proof.context -> Proof.context
    37   val theory_result: (theory -> 'a * theory) -> Proof.context -> 'a * Proof.context
    38   val pretty_term_abbrev: Proof.context -> term -> Pretty.T
    39   val pretty_thm_legacy: thm -> Pretty.T
    40   val pretty_thm: Proof.context -> thm -> Pretty.T
    41   val pretty_thms: Proof.context -> thm list -> Pretty.T
    42   val pretty_fact: Proof.context -> string * thm list -> Pretty.T
    43   val string_of_thm: Proof.context -> thm -> string
    44   val read_typ: Proof.context -> string -> typ
    45   val read_typ_syntax: Proof.context -> string -> typ
    46   val read_typ_abbrev: Proof.context -> string -> typ
    47   val cert_typ: Proof.context -> typ -> typ
    48   val cert_typ_syntax: Proof.context -> typ -> typ
    49   val cert_typ_abbrev: Proof.context -> typ -> typ
    50   val get_skolem: Proof.context -> string -> string
    51   val revert_skolem: Proof.context -> string -> string
    52   val infer_type: Proof.context -> string -> typ
    53   val inferred_param: string -> Proof.context -> (string * typ) * Proof.context
    54   val inferred_fixes: Proof.context -> (string * typ) list * Proof.context
    55   val read_tyname: Proof.context -> string -> typ
    56   val read_const_proper: Proof.context -> string -> term
    57   val read_const: Proof.context -> string -> term
    58   val allow_dummies: Proof.context -> Proof.context
    59   val decode_term: Proof.context -> term -> term
    60   val standard_infer_types: Proof.context -> term list -> term list
    61   val read_term_pattern: Proof.context -> string -> term
    62   val read_term_schematic: Proof.context -> string -> term
    63   val read_term_abbrev: Proof.context -> string -> term
    64   val expand_abbrevs: Proof.context -> term -> term
    65   val cert_term: Proof.context -> term -> term
    66   val cert_prop: Proof.context -> term -> term
    67   val goal_export: Proof.context -> Proof.context -> thm list -> thm list
    68   val export: Proof.context -> Proof.context -> thm list -> thm list
    69   val export_morphism: Proof.context -> Proof.context -> morphism
    70   val add_binds: (indexname * string option) list -> Proof.context -> Proof.context
    71   val add_binds_i: (indexname * term option) list -> Proof.context -> Proof.context
    72   val auto_bind_goal: term list -> Proof.context -> Proof.context
    73   val auto_bind_facts: term list -> Proof.context -> Proof.context
    74   val match_bind: bool -> (string list * string) list -> Proof.context -> term list * Proof.context
    75   val match_bind_i: bool -> (term list * term) list -> Proof.context -> term list * Proof.context
    76   val read_propp: Proof.context * (string * string list) list list
    77     -> Proof.context * (term * term list) list list
    78   val cert_propp: Proof.context * (term * term list) list list
    79     -> Proof.context * (term * term list) list list
    80   val read_propp_schematic: Proof.context * (string * string list) list list
    81     -> Proof.context * (term * term list) list list
    82   val cert_propp_schematic: Proof.context * (term * term list) list list
    83     -> Proof.context * (term * term list) list list
    84   val bind_propp: Proof.context * (string * string list) list list
    85     -> Proof.context * (term list list * (Proof.context -> Proof.context))
    86   val bind_propp_i: Proof.context * (term * term list) list list
    87     -> Proof.context * (term list list * (Proof.context -> Proof.context))
    88   val bind_propp_schematic: Proof.context * (string * string list) list list
    89     -> Proof.context * (term list list * (Proof.context -> Proof.context))
    90   val bind_propp_schematic_i: Proof.context * (term * term list) list list
    91     -> Proof.context * (term list list * (Proof.context -> Proof.context))
    92   val fact_tac: thm list -> int -> tactic
    93   val some_fact_tac: Proof.context -> int -> tactic
    94   val get_fact: Proof.context -> Facts.ref -> thm list
    95   val get_fact_single: Proof.context -> Facts.ref -> thm
    96   val get_thms: Proof.context -> xstring -> thm list
    97   val get_thm: Proof.context -> xstring -> thm
    98   val add_path: string -> Proof.context -> Proof.context
    99   val no_base_names: Proof.context -> Proof.context
   100   val qualified_names: Proof.context -> Proof.context
   101   val sticky_prefix: string -> Proof.context -> Proof.context
   102   val restore_naming: Proof.context -> Proof.context -> Proof.context
   103   val reset_naming: Proof.context -> Proof.context
   104   val put_thms: bool -> string * thm list option -> Proof.context -> Proof.context
   105   val note_thmss: string ->
   106     ((bstring * attribute list) * (Facts.ref * attribute list) list) list ->
   107       Proof.context -> (bstring * thm list) list * Proof.context
   108   val note_thmss_i: string ->
   109     ((bstring * attribute list) * (thm list * attribute list) list) list ->
   110       Proof.context -> (bstring * thm list) list * Proof.context
   111   val read_vars: (string * string option * mixfix) list -> Proof.context ->
   112     (string * typ option * mixfix) list * Proof.context
   113   val cert_vars: (string * typ option * mixfix) list -> Proof.context ->
   114     (string * typ option * mixfix) list * Proof.context
   115   val add_fixes: (string * string option * mixfix) list ->
   116     Proof.context -> string list * Proof.context
   117   val add_fixes_i: (string * typ option * mixfix) list ->
   118     Proof.context -> string list * Proof.context
   119   val auto_fixes: Proof.context * (term list list * 'a) -> Proof.context * (term list list * 'a)
   120   val bind_fixes: string list -> Proof.context -> (term -> term) * Proof.context
   121   val add_assms: Assumption.export ->
   122     ((string * attribute list) * (string * string list) list) list ->
   123     Proof.context -> (bstring * thm list) list * Proof.context
   124   val add_assms_i: Assumption.export ->
   125     ((string * attribute list) * (term * term list) list) list ->
   126     Proof.context -> (bstring * thm list) list * Proof.context
   127   val add_cases: bool -> (string * RuleCases.T option) list -> Proof.context -> Proof.context
   128   val apply_case: RuleCases.T -> Proof.context -> (string * term list) list * Proof.context
   129   val get_case: Proof.context -> string -> string option list -> RuleCases.T
   130   val notation: bool -> Syntax.mode -> (term * mixfix) list -> Proof.context -> Proof.context
   131   val target_notation: bool -> Syntax.mode -> (term * mixfix) list -> morphism ->
   132     Context.generic -> Context.generic
   133   val add_const_constraint: string * typ option -> Proof.context -> Proof.context
   134   val add_abbrev: string -> Markup.property list ->
   135     bstring * term -> Proof.context -> (term * term) * Proof.context
   136   val revert_abbrev: string -> string -> Proof.context -> Proof.context
   137   val verbose: bool ref
   138   val setmp_verbose: ('a -> 'b) -> 'a -> 'b
   139   val print_syntax: Proof.context -> unit
   140   val print_abbrevs: Proof.context -> unit
   141   val print_binds: Proof.context -> unit
   142   val print_lthms: Proof.context -> unit
   143   val print_cases: Proof.context -> unit
   144   val debug: bool ref
   145   val prems_limit: int ref
   146   val pretty_ctxt: Proof.context -> Pretty.T list
   147   val pretty_context: Proof.context -> Pretty.T list
   148   val query_type: Proof.context -> string -> Markup.property list
   149   val query_const: Proof.context -> string -> Markup.property list
   150   val query_class: Proof.context -> string -> Markup.property list
   151 end;
   152 
   153 structure ProofContext: PROOF_CONTEXT =
   154 struct
   155 
   156 val theory_of = Context.theory_of_proof;
   157 val init = Context.init_proof;
   158 
   159 
   160 (** inner syntax mode **)
   161 
   162 datatype mode =
   163   Mode of
   164    {stmt: bool,                (*inner statement mode*)
   165     pattern: bool,             (*pattern binding schematic variables*)
   166     schematic: bool,           (*term referencing loose schematic variables*)
   167     abbrev: bool};             (*abbrev mode -- no normalization*)
   168 
   169 fun make_mode (stmt, pattern, schematic, abbrev) =
   170   Mode {stmt = stmt, pattern = pattern, schematic = schematic, abbrev = abbrev};
   171 
   172 val mode_default   = make_mode (false, false, false, false);
   173 val mode_stmt      = make_mode (true, false, false, false);
   174 val mode_pattern   = make_mode (false, true, false, false);
   175 val mode_schematic = make_mode (false, false, true, false);
   176 val mode_abbrev    = make_mode (false, false, false, true);
   177 
   178 
   179 
   180 (** Isar proof context information **)
   181 
   182 datatype ctxt =
   183   Ctxt of
   184    {mode: mode,                                       (*inner syntax mode*)
   185     naming: NameSpace.naming,                         (*local naming conventions*)
   186     syntax: LocalSyntax.T,                            (*local syntax*)
   187     consts: Consts.T * Consts.T,                      (*local/global consts*)
   188     facts: Facts.T,                                   (*local facts*)
   189     cases: (string * (RuleCases.T * bool)) list};     (*named case contexts*)
   190 
   191 fun make_ctxt (mode, naming, syntax, consts, facts, cases) =
   192   Ctxt {mode = mode, naming = naming, syntax = syntax,
   193     consts = consts, facts = facts, cases = cases};
   194 
   195 val local_naming = NameSpace.default_naming |> NameSpace.add_path "local";
   196 
   197 structure ContextData = ProofDataFun
   198 (
   199   type T = ctxt;
   200   fun init thy =
   201     make_ctxt (mode_default, local_naming, LocalSyntax.init thy,
   202       (Sign.consts_of thy, Sign.consts_of thy), Facts.empty, []);
   203 );
   204 
   205 fun rep_context ctxt = ContextData.get ctxt |> (fn Ctxt args => args);
   206 
   207 fun map_context f =
   208   ContextData.map (fn Ctxt {mode, naming, syntax, consts, facts, cases} =>
   209     make_ctxt (f (mode, naming, syntax, consts, facts, cases)));
   210 
   211 fun set_mode mode = map_context (fn (_, naming, syntax, consts, facts, cases) =>
   212   (mode, naming, syntax, consts, facts, cases));
   213 
   214 fun map_mode f =
   215   map_context (fn (Mode {stmt, pattern, schematic, abbrev}, naming, syntax, consts, facts, cases) =>
   216     (make_mode (f (stmt, pattern, schematic, abbrev)), naming, syntax, consts, facts, cases));
   217 
   218 fun map_naming f =
   219   map_context (fn (mode, naming, syntax, consts, facts, cases) =>
   220     (mode, f naming, syntax, consts, facts, cases));
   221 
   222 fun map_syntax f =
   223   map_context (fn (mode, naming, syntax, consts, facts, cases) =>
   224     (mode, naming, f syntax, consts, facts, cases));
   225 
   226 fun map_consts f =
   227   map_context (fn (mode, naming, syntax, consts, facts, cases) =>
   228     (mode, naming, syntax, f consts, facts, cases));
   229 
   230 fun map_facts f =
   231   map_context (fn (mode, naming, syntax, consts, facts, cases) =>
   232     (mode, naming, syntax, consts, f facts, cases));
   233 
   234 fun map_cases f =
   235   map_context (fn (mode, naming, syntax, consts, facts, cases) =>
   236     (mode, naming, syntax, consts, facts, f cases));
   237 
   238 val get_mode = #mode o rep_context;
   239 fun restore_mode ctxt = set_mode (get_mode ctxt);
   240 val abbrev_mode = get_mode #> (fn Mode {abbrev, ...} => abbrev);
   241 
   242 fun set_stmt stmt =
   243   map_mode (fn (_, pattern, schematic, abbrev) => (stmt, pattern, schematic, abbrev));
   244 
   245 val naming_of = #naming o rep_context;
   246 val full_name = NameSpace.full o naming_of;
   247 
   248 val syntax_of = #syntax o rep_context;
   249 val syn_of = LocalSyntax.syn_of o syntax_of;
   250 val set_syntax_mode = map_syntax o LocalSyntax.set_mode;
   251 val restore_syntax_mode = map_syntax o LocalSyntax.restore_mode o syntax_of;
   252 
   253 val consts_of = #1 o #consts o rep_context;
   254 val const_syntax_name = Consts.syntax_name o consts_of;
   255 val the_const_constraint = Consts.the_constraint o consts_of;
   256 
   257 fun mk_const ctxt (c, Ts) = Const (c, Consts.instance (consts_of ctxt) (c, Ts));
   258 
   259 val facts_of = #facts o rep_context;
   260 val cases_of = #cases o rep_context;
   261 
   262 
   263 (* theory transfer *)
   264 
   265 fun transfer_syntax thy =
   266   map_syntax (LocalSyntax.rebuild thy) #>
   267   map_consts (fn consts as (local_consts, global_consts) =>
   268     let val thy_consts = Sign.consts_of thy in
   269       if Consts.eq_consts (thy_consts, global_consts) then consts
   270       else (Consts.merge (local_consts, thy_consts), thy_consts)
   271     end);
   272 
   273 fun transfer thy = Context.transfer_proof thy #> transfer_syntax thy;
   274 
   275 fun theory f ctxt = transfer (f (theory_of ctxt)) ctxt;
   276 
   277 fun theory_result f ctxt =
   278   let val (res, thy') = f (theory_of ctxt)
   279   in (res, ctxt |> transfer thy') end;
   280 
   281 
   282 
   283 (** pretty printing **)
   284 
   285 fun pretty_term_abbrev ctxt = Syntax.pretty_term (set_mode mode_abbrev ctxt);
   286 
   287 fun pretty_thm_legacy th =
   288   let val thy = Thm.theory_of_thm th
   289   in Display.pretty_thm_aux (Syntax.pp_global thy) true false [] th end;
   290 
   291 fun pretty_thm ctxt th =
   292   let val asms = map Thm.term_of (Assumption.assms_of ctxt)
   293   in Display.pretty_thm_aux (Syntax.pp ctxt) false true asms th end;
   294 
   295 fun pretty_thms ctxt [th] = pretty_thm ctxt th
   296   | pretty_thms ctxt ths = Pretty.blk (0, Pretty.fbreaks (map (pretty_thm ctxt) ths));
   297 
   298 fun pretty_fact ctxt ("", ths) = pretty_thms ctxt ths
   299   | pretty_fact ctxt (a, [th]) =
   300       Pretty.block [Pretty.str (a ^ ":"), Pretty.brk 1, pretty_thm ctxt th]
   301   | pretty_fact ctxt (a, ths) =
   302       Pretty.block (Pretty.fbreaks (Pretty.str (a ^ ":") :: map (pretty_thm ctxt) ths));
   303 
   304 val string_of_thm = Pretty.string_of oo pretty_thm;
   305 
   306 
   307 
   308 (** prepare types **)
   309 
   310 (* read_typ *)
   311 
   312 fun read_typ_mode mode ctxt s =
   313   Syntax.read_typ (Type.set_mode mode ctxt) s;
   314 
   315 val read_typ        = read_typ_mode Type.mode_default;
   316 val read_typ_syntax = read_typ_mode Type.mode_syntax;
   317 val read_typ_abbrev = read_typ_mode Type.mode_abbrev;
   318 
   319 
   320 (* cert_typ *)
   321 
   322 fun cert_typ_mode mode ctxt T =
   323   Sign.certify_typ_mode mode (theory_of ctxt) T
   324     handle TYPE (msg, _, _) => error msg;
   325 
   326 val cert_typ        = cert_typ_mode Type.mode_default;
   327 val cert_typ_syntax = cert_typ_mode Type.mode_syntax;
   328 val cert_typ_abbrev = cert_typ_mode Type.mode_abbrev;
   329 
   330 
   331 
   332 (** prepare variables **)
   333 
   334 (* internalize Skolem constants *)
   335 
   336 val lookup_skolem = AList.lookup (op =) o Variable.fixes_of;
   337 fun get_skolem ctxt x = the_default x (lookup_skolem ctxt x);
   338 
   339 fun no_skolem internal x =
   340   if can Name.dest_skolem x then
   341     error ("Illegal reference to internal Skolem constant: " ^ quote x)
   342   else if not internal andalso can Name.dest_internal x then
   343     error ("Illegal reference to internal variable: " ^ quote x)
   344   else x;
   345 
   346 
   347 (* revert Skolem constants -- if possible *)
   348 
   349 fun revert_skolem ctxt x =
   350   (case find_first (fn (_, y) => y = x) (Variable.fixes_of ctxt) of
   351     SOME (x', _) => if lookup_skolem ctxt x' = SOME x then x' else x
   352   | NONE => x);
   353 
   354 
   355 (* default token translations *)
   356 
   357 local
   358 
   359 fun free_or_skolem ctxt x =
   360   (if can Name.dest_skolem x then Pretty.mark Markup.skolem (Pretty.str (revert_skolem ctxt x))
   361    else Pretty.mark Markup.free (Pretty.str x))
   362   |> Pretty.mark
   363     (if Variable.is_fixed ctxt x orelse Syntax.is_pretty_global ctxt then Markup.fixed x
   364      else Markup.hilite);
   365 
   366 fun var_or_skolem _ s =
   367   (case Lexicon.read_variable s of
   368     SOME (x, i) =>
   369       (case try Name.dest_skolem x of
   370         NONE => Pretty.mark Markup.var (Pretty.str s)
   371       | SOME x' => Pretty.mark Markup.skolem
   372           (Pretty.str (setmp show_question_marks true Term.string_of_vname (x', i))))
   373   | NONE => Pretty.mark Markup.var (Pretty.str s));
   374 
   375 fun class_markup _ c =    (* FIXME authentic name *)
   376   Pretty.mark (Markup.classN, []) (Pretty.str c);
   377 
   378 fun plain_markup m _ s = Pretty.mark m (Pretty.str s);
   379 
   380 val token_trans =
   381  Syntax.tokentrans_mode ""
   382   [("class", class_markup),
   383    ("tfree", plain_markup Markup.tfree),
   384    ("tvar", plain_markup Markup.tvar),
   385    ("free", free_or_skolem),
   386    ("bound", plain_markup Markup.bound),
   387    ("var", var_or_skolem),
   388    ("num", plain_markup Markup.num),
   389    ("xnum", plain_markup Markup.xnum),
   390    ("xstr", plain_markup Markup.xstr)];
   391 
   392 in val _ = Context.>> (Context.map_theory (Sign.add_tokentrfuns token_trans)) end;
   393 
   394 
   395 
   396 (** prepare terms and propositions **)
   397 
   398 (* inferred types of parameters *)
   399 
   400 fun infer_type ctxt x =
   401   Term.fastype_of (singleton (Syntax.check_terms (set_mode mode_schematic ctxt))
   402     (Free (x, dummyT)));
   403 
   404 fun inferred_param x ctxt =
   405   let val T = infer_type ctxt x
   406   in ((x, T), ctxt |> Variable.declare_term (Free (x, T))) end;
   407 
   408 fun inferred_fixes ctxt =
   409   fold_map inferred_param (rev (map #2 (Variable.fixes_of ctxt))) ctxt;
   410 
   411 
   412 (* type and constant names *)
   413 
   414 fun read_tyname ctxt c =
   415   if Syntax.is_tid c then
   416     TFree (c, the_default (Sign.defaultS (theory_of ctxt)) (Variable.def_sort ctxt (c, ~1)))
   417   else
   418     let
   419       val thy = theory_of ctxt;
   420       val d = Sign.intern_type thy c;
   421     in Type (d, replicate (Sign.arity_number thy d) dummyT) end;
   422 
   423 fun read_const_proper ctxt c =
   424   (case Variable.lookup_const ctxt c of
   425     SOME d => Const (d, Consts.type_scheme (consts_of ctxt) d handle TYPE (msg, _, _) => error msg)
   426   | NONE => Consts.read_const (consts_of ctxt) c);
   427 
   428 fun read_const ctxt c =
   429   (case (lookup_skolem ctxt c, Variable.is_const ctxt c) of
   430     (SOME x, false) => Free (x, infer_type ctxt x)
   431   | _ => read_const_proper ctxt c);
   432 
   433 
   434 (* read_term *)
   435 
   436 fun read_term_mode mode ctxt = Syntax.read_term (set_mode mode ctxt);
   437 
   438 val read_term_pattern   = read_term_mode mode_pattern;
   439 val read_term_schematic = read_term_mode mode_schematic;
   440 val read_term_abbrev    = read_term_mode mode_abbrev;
   441 
   442 
   443 (* local abbreviations *)
   444 
   445 val tsig_of = Sign.tsig_of o ProofContext.theory_of;
   446 
   447 local
   448 
   449 fun certify_consts ctxt = Consts.certify (Syntax.pp ctxt) (tsig_of ctxt)
   450   (not (abbrev_mode ctxt)) (consts_of ctxt);
   451 
   452 fun reject_schematic (Var (xi, _)) =
   453       error ("Unbound schematic variable: " ^ Term.string_of_vname xi)
   454   | reject_schematic (Abs (_, _, t)) = reject_schematic t
   455   | reject_schematic (t $ u) = (reject_schematic t; reject_schematic u)
   456   | reject_schematic _ = ();
   457 
   458 fun expand_binds ctxt =
   459   let val Mode {pattern, schematic, ...} = get_mode ctxt in
   460     if pattern then I
   461     else Variable.expand_binds ctxt #> (if schematic then I else tap reject_schematic)
   462   end;
   463 
   464 in
   465 
   466 fun expand_abbrevs ctxt = certify_consts ctxt #> expand_binds ctxt;
   467 
   468 end;
   469 
   470 
   471 fun contract_abbrevs ctxt t =
   472   let
   473     val thy = theory_of ctxt;
   474     val consts = consts_of ctxt;
   475     val Mode {abbrev, ...} = get_mode ctxt;
   476   in
   477     if abbrev orelse print_mode_active "no_abbrevs" orelse not (can Term.type_of t) then t
   478     else t |> Pattern.rewrite_term thy (Consts.abbrevs_of consts (print_mode_value () @ [""])) []
   479   end;
   480 
   481 
   482 (* patterns *)
   483 
   484 fun prepare_patternT ctxt =
   485   let val Mode {pattern, schematic, ...} = get_mode ctxt in
   486     if pattern orelse schematic then I
   487     else Term.map_atyps
   488       (fn T as TVar (xi, _) =>
   489             if not (TypeInfer.is_param xi)
   490             then error ("Illegal schematic type variable: " ^ Term.string_of_vname xi)
   491             else T
   492         | T => T)
   493   end;
   494 
   495 
   496 local
   497 
   498 structure AllowDummies = ProofDataFun(type T = bool fun init _ = false);
   499 
   500 fun check_dummies ctxt t =
   501   if AllowDummies.get ctxt then t
   502   else Term.no_dummy_patterns t handle TERM _ => error "Illegal dummy pattern(s) in term";
   503 
   504 fun prepare_dummies ts = #1 (fold_map Term.replace_dummy_patterns ts 1);
   505 
   506 in
   507 
   508 val allow_dummies = AllowDummies.put true;
   509 
   510 fun prepare_patterns ctxt =
   511   let val Mode {pattern, ...} = get_mode ctxt in
   512     TypeInfer.fixate_params (Variable.names_of ctxt) #>
   513     pattern ? Variable.polymorphic ctxt #>
   514     (map o Term.map_types) (prepare_patternT ctxt) #>
   515     (if pattern then prepare_dummies else map (check_dummies ctxt))
   516   end;
   517 
   518 end;
   519 
   520 
   521 (* decoding raw terms (syntax trees) *)
   522 
   523 (* types *)
   524 
   525 fun get_sort thy def_sort raw_env =
   526   let
   527     val tsig = Sign.tsig_of thy;
   528 
   529     fun eq ((xi, S), (xi', S')) =
   530       Term.eq_ix (xi, xi') andalso Type.eq_sort tsig (S, S');
   531     val env = distinct eq raw_env;
   532     val _ = (case duplicates (eq_fst (op =)) env of [] => ()
   533       | dups => error ("Inconsistent sort constraints for type variable(s) "
   534           ^ commas_quote (map (Term.string_of_vname' o fst) dups)));
   535 
   536     fun get xi =
   537       (case (AList.lookup (op =) env xi, def_sort xi) of
   538         (NONE, NONE) => Type.defaultS tsig
   539       | (NONE, SOME S) => S
   540       | (SOME S, NONE) => S
   541       | (SOME S, SOME S') =>
   542           if Type.eq_sort tsig (S, S') then S'
   543           else error ("Sort constraint inconsistent with default for type variable " ^
   544             quote (Term.string_of_vname' xi)));
   545   in get end;
   546 
   547 local
   548 
   549 fun intern_skolem ctxt def_type x =
   550   let
   551     val _ = no_skolem false x;
   552     val sko = lookup_skolem ctxt x;
   553     val is_const = can (read_const_proper ctxt) x orelse NameSpace.is_qualified x;
   554     val is_declared = is_some (def_type (x, ~1));
   555   in
   556     if Variable.is_const ctxt x then NONE
   557     else if is_some sko then sko
   558     else if not is_const orelse is_declared then SOME x
   559     else NONE
   560   end;
   561 
   562 in
   563 
   564 fun term_context ctxt =
   565   let val thy = theory_of ctxt in
   566    {get_sort = get_sort thy (Variable.def_sort ctxt),
   567     map_const = fn a => ((true, #1 (Term.dest_Const (read_const_proper ctxt a)))
   568       handle ERROR _ => (false, Consts.intern (consts_of ctxt) a)),
   569     map_free = intern_skolem ctxt (Variable.def_type ctxt false),
   570     map_type = Sign.intern_tycons thy,
   571     map_sort = Sign.intern_sort thy}
   572   end;
   573 
   574 fun decode_term ctxt =
   575   let val {get_sort, map_const, map_free, map_type, map_sort} = term_context ctxt
   576   in Syntax.decode_term get_sort map_const map_free map_type map_sort end;
   577 
   578 end;
   579 
   580 
   581 (* certify terms *)
   582 
   583 local
   584 
   585 fun gen_cert prop ctxt t =
   586   t
   587   |> expand_abbrevs ctxt
   588   |> (fn t' => #1 (Sign.certify' prop (Syntax.pp ctxt) false (consts_of ctxt) (theory_of ctxt) t')
   589     handle TYPE (msg, _, _) => error msg
   590       | TERM (msg, _) => error msg);
   591 
   592 in
   593 
   594 val cert_term = gen_cert false;
   595 val cert_prop = gen_cert true;
   596 
   597 end;
   598 
   599 
   600 (* type checking/inference *)
   601 
   602 fun standard_infer_types ctxt ts =
   603   let val Mode {pattern, ...} = get_mode ctxt in
   604     TypeInfer.infer_types (Syntax.pp ctxt) (tsig_of ctxt) (Syntax.check_typs ctxt)
   605       (try (Consts.the_constraint (consts_of ctxt))) (Variable.def_type ctxt pattern)
   606       (Variable.names_of ctxt) (Variable.maxidx_of ctxt) ts
   607     handle TYPE (msg, _, _) => error msg
   608   end;
   609 
   610 local
   611 
   612 fun standard_typ_check ctxt =
   613   map (cert_typ_mode (Type.get_mode ctxt) ctxt) #>
   614   map (prepare_patternT ctxt);
   615 
   616 fun standard_term_check ctxt =
   617   standard_infer_types ctxt #>
   618   map (expand_abbrevs ctxt);
   619 
   620 fun standard_term_uncheck ctxt =
   621   map (contract_abbrevs ctxt);
   622 
   623 fun add eq what f = Context.>> (what (fn xs => fn ctxt =>
   624   let val xs' = f ctxt xs in if eq_list eq (xs, xs') then NONE else SOME (xs', ctxt) end));
   625 
   626 in
   627 
   628 val _ = add (op =) (Syntax.add_typ_check 0 "standard") standard_typ_check;
   629 val _ = add (op aconv) (Syntax.add_term_check 0 "standard") standard_term_check;
   630 val _ = add (op aconv) (Syntax.add_term_check 100 "fixate") prepare_patterns;
   631 
   632 val _ = add (op aconv) (Syntax.add_term_uncheck 0 "standard") standard_term_uncheck;
   633 
   634 end;
   635 
   636 
   637 
   638 (** inner syntax operations **)
   639 
   640 local
   641 
   642 fun parse_sort ctxt str =
   643   Syntax.standard_parse_sort ctxt (syn_of ctxt) (Sign.intern_sort (theory_of ctxt)) str;
   644 
   645 fun parse_typ ctxt str =
   646   let
   647     val thy = ProofContext.theory_of ctxt;
   648     val get_sort = get_sort thy (Variable.def_sort ctxt);
   649     val T = Sign.intern_tycons thy
   650       (Syntax.standard_parse_typ ctxt (syn_of ctxt) get_sort (Sign.intern_sort thy) str);
   651   in T end
   652   handle ERROR msg => cat_error msg ("The error(s) above occurred in type " ^ quote str);
   653 
   654 fun parse_term T ctxt str =
   655   let
   656     val thy = theory_of ctxt;
   657     val (T', _) = TypeInfer.paramify_dummies T 0;
   658     fun check t = (Syntax.check_term ctxt (TypeInfer.constrain T' t); NONE)
   659       handle ERROR msg => SOME msg;
   660     val {get_sort, map_const, map_free, map_type, map_sort} = term_context ctxt;
   661     val read = Syntax.standard_parse_term (Syntax.pp ctxt) check get_sort
   662       map_const map_free map_type map_sort ctxt (Sign.is_logtype thy) (syn_of ctxt) T';
   663   in read str end;
   664 
   665 
   666 fun unparse_sort ctxt S =
   667   Syntax.standard_unparse_sort ctxt (syn_of ctxt) (Sign.extern_sort (theory_of ctxt) S);
   668 
   669 fun unparse_typ ctxt T =
   670   Syntax.standard_unparse_typ ctxt (syn_of ctxt) (Sign.extern_typ (theory_of ctxt) T);
   671 
   672 fun unparse_term ctxt t =
   673   let
   674     val thy = theory_of ctxt;
   675     val syntax = syntax_of ctxt;
   676     val consts = consts_of ctxt;
   677   in
   678     t
   679     |> Sign.extern_term (Consts.extern_early consts) thy
   680     |> LocalSyntax.extern_term syntax
   681     |> Syntax.standard_unparse_term (Consts.extern consts) ctxt (LocalSyntax.syn_of syntax)
   682         (not (PureThy.old_appl_syntax thy))
   683   end;
   684 
   685 in
   686 
   687 val _ = Syntax.install_operations
   688   {parse_sort = parse_sort,
   689    parse_typ = parse_typ,
   690    parse_term = parse_term dummyT,
   691    parse_prop = parse_term propT,
   692    unparse_sort = unparse_sort,
   693    unparse_typ = unparse_typ,
   694    unparse_term = unparse_term};
   695 
   696 end;
   697 
   698 
   699 
   700 (** export results **)
   701 
   702 fun common_export is_goal inner outer =
   703   map (Assumption.export is_goal inner outer) #>
   704   Variable.export inner outer;
   705 
   706 val goal_export = common_export true;
   707 val export = common_export false;
   708 
   709 fun export_morphism inner outer =
   710   Assumption.export_morphism inner outer $>
   711   Variable.export_morphism inner outer;
   712 
   713 
   714 
   715 (** bindings **)
   716 
   717 (* simult_matches *)
   718 
   719 fun simult_matches ctxt (t, pats) =
   720   (case Seq.pull (Unify.matchers (theory_of ctxt) (map (rpair t) pats)) of
   721     NONE => error "Pattern match failed!"
   722   | SOME (env, _) => map (apsnd snd) (Envir.alist_of env));
   723 
   724 
   725 (* add_binds(_i) *)
   726 
   727 local
   728 
   729 fun gen_bind prep (xi as (x, _), raw_t) ctxt =
   730   ctxt
   731   |> Variable.add_binds [(xi, Option.map (prep (set_mode mode_default ctxt)) raw_t)];
   732 
   733 in
   734 
   735 fun drop_schematic (b as (xi, SOME t)) = if Term.exists_subterm is_Var t then (xi, NONE) else b
   736   | drop_schematic b = b;
   737 
   738 val add_binds = fold (gen_bind Syntax.read_term);
   739 val add_binds_i = fold (gen_bind cert_term);
   740 
   741 fun auto_bind f ts ctxt = ctxt |> add_binds_i (map drop_schematic (f (theory_of ctxt) ts));
   742 val auto_bind_goal = auto_bind AutoBind.goal;
   743 val auto_bind_facts = auto_bind AutoBind.facts;
   744 
   745 end;
   746 
   747 
   748 (* match_bind(_i) *)
   749 
   750 local
   751 
   752 fun gen_bind prep_terms gen raw_binds ctxt =
   753   let
   754     fun prep_bind (raw_pats, t) ctxt1 =
   755       let
   756         val T = Term.fastype_of t;
   757         val ctxt2 = Variable.declare_term t ctxt1;
   758         val pats = prep_terms (set_mode mode_pattern ctxt2) T raw_pats;
   759         val binds = simult_matches ctxt2 (t, pats);
   760       in (binds, ctxt2) end;
   761 
   762     val ts = prep_terms ctxt dummyT (map snd raw_binds);
   763     val (binds, ctxt') = apfst flat (fold_map prep_bind (map fst raw_binds ~~ ts) ctxt);
   764     val binds' =
   765       if gen then map #1 binds ~~ Variable.exportT_terms ctxt' ctxt (map #2 binds)
   766       else binds;
   767     val binds'' = map (apsnd SOME) binds';
   768     val ctxt'' =
   769       tap (Variable.warn_extra_tfrees ctxt)
   770        (if gen then
   771           ctxt (*sic!*) |> fold Variable.declare_term (map #2 binds') |> add_binds_i binds''
   772         else ctxt' |> add_binds_i binds'');
   773   in (ts, ctxt'') end;
   774 
   775 in
   776 
   777 fun read_terms ctxt T =
   778   map (Syntax.parse_term ctxt #> TypeInfer.constrain T) #> Syntax.check_terms ctxt;
   779 
   780 val match_bind = gen_bind read_terms;
   781 val match_bind_i = gen_bind (fn ctxt => fn _ => map (cert_term ctxt));
   782 
   783 end;
   784 
   785 
   786 (* propositions with patterns *)
   787 
   788 local
   789 
   790 fun prep_propp mode prep_props (context, args) =
   791   let
   792     fun prep (_, raw_pats) (ctxt, prop :: props) =
   793       let val ctxt' = Variable.declare_term prop ctxt
   794       in ((prop, prep_props (set_mode mode_pattern ctxt') raw_pats), (ctxt', props)) end;
   795 
   796     val (propp, (context', _)) = (fold_map o fold_map) prep args
   797       (context, prep_props (set_mode mode context) (maps (map fst) args));
   798   in (context', propp) end;
   799 
   800 fun gen_bind_propp mode parse_prop (ctxt, raw_args) =
   801   let
   802     val (ctxt', args) = prep_propp mode parse_prop (ctxt, raw_args);
   803     val binds = flat (flat (map (map (simult_matches ctxt')) args));
   804     val propss = map (map #1) args;
   805 
   806     (*generalize result: context evaluated now, binds added later*)
   807     val gen = Variable.exportT_terms ctxt' ctxt;
   808     fun gen_binds c = c |> add_binds_i (map #1 binds ~~ map SOME (gen (map #2 binds)));
   809   in (ctxt' |> add_binds_i (map (apsnd SOME) binds), (propss, gen_binds)) end;
   810 
   811 in
   812 
   813 val read_propp           = prep_propp mode_default Syntax.read_props;
   814 val cert_propp           = prep_propp mode_default (map o cert_prop);
   815 val read_propp_schematic = prep_propp mode_schematic Syntax.read_props;
   816 val cert_propp_schematic = prep_propp mode_schematic (map o cert_prop);
   817 
   818 val bind_propp             = gen_bind_propp mode_default Syntax.read_props;
   819 val bind_propp_i           = gen_bind_propp mode_default (map o cert_prop);
   820 val bind_propp_schematic   = gen_bind_propp mode_schematic Syntax.read_props;
   821 val bind_propp_schematic_i = gen_bind_propp mode_schematic (map o cert_prop);
   822 
   823 end;
   824 
   825 
   826 
   827 (** theorems **)
   828 
   829 (* fact_tac *)
   830 
   831 fun comp_incr_tac [] _ st = no_tac st
   832   | comp_incr_tac (th :: ths) i st =
   833       (Goal.compose_hhf_tac (Drule.incr_indexes st th) i APPEND comp_incr_tac ths i) st;
   834 
   835 fun fact_tac facts = Goal.norm_hhf_tac THEN' comp_incr_tac facts;
   836 
   837 fun some_fact_tac ctxt = SUBGOAL (fn (goal, i) =>
   838   fact_tac (Facts.could_unify (facts_of ctxt) (Term.strip_all_body goal)) i);
   839 
   840 
   841 (* get_thm(s) *)
   842 
   843 local
   844 
   845 fun retrieve_thms pick ctxt (Facts.Fact s) =
   846       let
   847         val prop = Syntax.read_prop (set_mode mode_default ctxt) s
   848           |> singleton (Variable.polymorphic ctxt);
   849         val th = Goal.prove ctxt [] [] prop (K (ALLGOALS (some_fact_tac ctxt)))
   850           handle ERROR msg => cat_error msg "Failed to retrieve literal fact.";
   851       in pick "" [th] end
   852   | retrieve_thms pick ctxt xthmref =
   853       let
   854         val thy = theory_of ctxt;
   855         val local_facts = facts_of ctxt;
   856         val thmref = Facts.map_name_of_ref (Facts.intern local_facts) xthmref;
   857         val name = Facts.name_of_ref thmref;
   858         val thms =
   859           if name = "" then [Thm.transfer thy Drule.dummy_thm]
   860           else
   861             (case Facts.lookup (Context.Proof ctxt) local_facts name of
   862               SOME ths => map (Thm.transfer thy) (Facts.select thmref ths)
   863             | NONE => PureThy.get_fact (Context.Proof ctxt) thy xthmref);
   864       in pick name thms end;
   865 
   866 in
   867 
   868 val get_fact = retrieve_thms (K I);
   869 val get_fact_single = retrieve_thms Facts.the_single;
   870 
   871 fun get_thms ctxt = get_fact ctxt o Facts.named;
   872 fun get_thm ctxt = get_fact_single ctxt o Facts.named;
   873 
   874 end;
   875 
   876 
   877 (* name space operations *)
   878 
   879 val add_path        = map_naming o NameSpace.add_path;
   880 val no_base_names   = map_naming NameSpace.no_base_names;
   881 val qualified_names = map_naming NameSpace.qualified_names;
   882 val sticky_prefix   = map_naming o NameSpace.sticky_prefix;
   883 val restore_naming  = map_naming o K o naming_of;
   884 val reset_naming    = map_naming (K local_naming);
   885 
   886 
   887 (* facts *)
   888 
   889 fun update_thms _ (bname, NONE) ctxt = ctxt |> map_facts (Facts.del (full_name ctxt bname))
   890   | update_thms do_props (bname, SOME ths) ctxt = ctxt |> map_facts
   891       (Facts.add_local do_props (naming_of ctxt) (full_name ctxt bname, ths));
   892 
   893 fun put_thms do_props thms ctxt =
   894   ctxt |> map_naming (K local_naming) |> update_thms do_props thms |> restore_naming ctxt;
   895 
   896 local
   897 
   898 fun gen_note_thmss get k = fold_map (fn ((bname, more_attrs), raw_facts) => fn ctxt =>
   899   let
   900     val name = full_name ctxt bname;
   901     val facts = PureThy.name_thmss false name (map (apfst (get ctxt)) raw_facts);
   902     fun app (th, attrs) x =
   903       swap (foldl_map (Thm.proof_attributes (attrs @ more_attrs @ [PureThy.kind k])) (x, th));
   904     val (res, ctxt') = fold_map app facts ctxt;
   905     val thms = PureThy.name_thms false false name (flat res);
   906     val Mode {stmt, ...} = get_mode ctxt;
   907   in ((bname, thms), ctxt' |> update_thms stmt (bname, SOME thms)) end);
   908 
   909 in
   910 
   911 fun note_thmss k = gen_note_thmss get_fact k;
   912 fun note_thmss_i k = gen_note_thmss (K I) k;
   913 
   914 end;
   915 
   916 
   917 
   918 (** parameters **)
   919 
   920 (* variables *)
   921 
   922 fun declare_var (x, opt_T, mx) ctxt =
   923   let val T = (case opt_T of SOME T => T | NONE => Syntax.mixfixT mx)
   924   in ((x, T, mx), ctxt |> Variable.declare_constraints (Free (x, T))) end;
   925 
   926 local
   927 
   928 fun prep_vars prep_typ internal =
   929   fold_map (fn (raw_x, raw_T, raw_mx) => fn ctxt =>
   930     let
   931       val (x, mx) = Syntax.const_mixfix raw_x raw_mx;
   932       val _ = Syntax.is_identifier (no_skolem internal x) orelse
   933         error ("Illegal variable name: " ^ quote x);
   934 
   935       fun cond_tvars T =
   936         if internal then T
   937         else Type.no_tvars T handle TYPE (msg, _, _) => error msg;
   938       val opt_T = Option.map (cond_tvars o cert_typ ctxt o prep_typ ctxt) raw_T;
   939       val var = (x, opt_T, mx);
   940     in (var, ctxt |> declare_var var |> #2) end);
   941 
   942 in
   943 
   944 val read_vars = prep_vars Syntax.parse_typ false;
   945 val cert_vars = prep_vars (K I) true;
   946 
   947 end;
   948 
   949 
   950 (* authentic constants *)
   951 
   952 local
   953 
   954 fun const_ast_tr intern ctxt [Syntax.Variable c] =
   955       let
   956         val Const (c', _) = read_const_proper ctxt c;
   957         val d = if intern then const_syntax_name ctxt c' else c;
   958       in Syntax.Constant d end
   959   | const_ast_tr _ _ asts = raise Syntax.AST ("const_ast_tr", asts);
   960 
   961 in
   962 
   963 val _ = Context.>> (Context.map_theory
   964  (Sign.add_syntax
   965    [("_context_const", "id => 'a", Delimfix "CONST _"),
   966     ("_context_const", "longid => 'a", Delimfix "CONST _"),
   967     ("_context_xconst", "id => 'a", Delimfix "XCONST _"),
   968     ("_context_xconst", "longid => 'a", Delimfix "XCONST _")] #>
   969   Sign.add_advanced_trfuns
   970     ([("_context_const", const_ast_tr true), ("_context_xconst", const_ast_tr false)], [], [], [])));
   971 
   972 end;
   973 
   974 
   975 (* notation *)
   976 
   977 local
   978 
   979 fun const_syntax ctxt (Free (x, T), mx) = SOME (true, (x, T, mx))
   980   | const_syntax ctxt (Const (c, _), mx) =
   981       Option.map (pair false) (try (Consts.syntax (consts_of ctxt)) (c, mx))
   982   | const_syntax _ _ = NONE;
   983 
   984 in
   985 
   986 fun notation add mode args ctxt =
   987   ctxt |> map_syntax
   988     (LocalSyntax.update_modesyntax (theory_of ctxt) add mode (map_filter (const_syntax ctxt) args));
   989 
   990 fun target_notation add mode args phi =
   991   let val args' = filter (fn (t, _) => Type.similar_types (t, Morphism.term phi t)) args;
   992   in Context.mapping (Sign.notation add mode args') (notation add mode args') end;
   993 
   994 end;
   995 
   996 
   997 (* local constants *)
   998 
   999 fun add_const_constraint (c, opt_T) ctxt =
  1000   let
  1001     fun prepT raw_T =
  1002       let val T = cert_typ ctxt raw_T
  1003       in cert_term ctxt (Const (c, T)); T end;
  1004   in ctxt |> (map_consts o apfst) (Consts.constrain (c, Option.map prepT opt_T)) end;
  1005 
  1006 fun add_abbrev mode tags (c, raw_t) ctxt =
  1007   let
  1008     val t0 = cert_term (ctxt |> set_mode mode_abbrev) raw_t
  1009       handle ERROR msg => cat_error msg ("in constant abbreviation " ^ quote c);
  1010     val [t] = Variable.exportT_terms (Variable.declare_term t0 ctxt) ctxt [t0];
  1011     val ((lhs, rhs), consts') = consts_of ctxt
  1012       |> Consts.abbreviate (Syntax.pp ctxt) (tsig_of ctxt) (naming_of ctxt) mode tags (c, t);
  1013   in
  1014     ctxt
  1015     |> (map_consts o apfst) (K consts')
  1016     |> Variable.declare_term rhs
  1017     |> pair (lhs, rhs)
  1018   end;
  1019 
  1020 fun revert_abbrev mode c = (map_consts o apfst) (Consts.revert_abbrev mode c);
  1021 
  1022 
  1023 (* fixes *)
  1024 
  1025 local
  1026 
  1027 fun prep_mixfix (x, T, mx) =
  1028   if mx <> NoSyn andalso mx <> Structure andalso
  1029       (can Name.dest_internal x orelse can Name.dest_skolem x) then
  1030     error ("Illegal mixfix syntax for internal/skolem constant " ^ quote x)
  1031   else (true, (x, T, mx));
  1032 
  1033 fun gen_fixes prep raw_vars ctxt =
  1034   let
  1035     val (vars, _) = prep raw_vars ctxt;
  1036     val (xs', ctxt') = Variable.add_fixes (map #1 vars) ctxt;
  1037   in
  1038     ctxt'
  1039     |> fold_map declare_var (map2 (fn x' => fn (_, T, mx) => (x', T, mx)) xs' vars)
  1040     |-> (map_syntax o LocalSyntax.add_syntax (theory_of ctxt) o map prep_mixfix)
  1041     |> pair xs'
  1042   end;
  1043 
  1044 in
  1045 
  1046 val add_fixes = gen_fixes read_vars;
  1047 val add_fixes_i = gen_fixes cert_vars;
  1048 
  1049 end;
  1050 
  1051 
  1052 (* fixes vs. frees *)
  1053 
  1054 fun auto_fixes (arg as (ctxt, (propss, x))) =
  1055   ((fold o fold) Variable.auto_fixes propss ctxt, (propss, x));
  1056 
  1057 fun bind_fixes xs ctxt =
  1058   let
  1059     val (_, ctxt') = ctxt |> add_fixes_i (map (fn x => (x, NONE, NoSyn)) xs);
  1060     fun bind (t as Free (x, T)) =
  1061           if member (op =) xs x then
  1062             (case lookup_skolem ctxt' x of SOME x' => Free (x', T) | NONE => t)
  1063           else t
  1064       | bind (t $ u) = bind t $ bind u
  1065       | bind (Abs (x, T, t)) = Abs (x, T, bind t)
  1066       | bind a = a;
  1067   in (bind, ctxt') end;
  1068 
  1069 
  1070 
  1071 (** assumptions **)
  1072 
  1073 local
  1074 
  1075 fun gen_assms prepp exp args ctxt =
  1076   let
  1077     val cert = Thm.cterm_of (theory_of ctxt);
  1078     val (propss, ctxt1) = swap (prepp (ctxt, map snd args));
  1079     val _ = Variable.warn_extra_tfrees ctxt ctxt1;
  1080     val (premss, ctxt2) = fold_burrow (Assumption.add_assms exp o map cert) propss ctxt1;
  1081   in
  1082     ctxt2
  1083     |> auto_bind_facts (flat propss)
  1084     |> note_thmss_i Thm.assumptionK (map fst args ~~ map (map (fn th => ([th], []))) premss)
  1085   end;
  1086 
  1087 in
  1088 
  1089 val add_assms = gen_assms (apsnd #1 o bind_propp);
  1090 val add_assms_i = gen_assms (apsnd #1 o bind_propp_i);
  1091 
  1092 end;
  1093 
  1094 
  1095 
  1096 (** cases **)
  1097 
  1098 local
  1099 
  1100 fun rem_case name = remove (fn (x: string, (y, _)) => x = y) name;
  1101 
  1102 fun add_case _ ("", _) cases = cases
  1103   | add_case _ (name, NONE) cases = rem_case name cases
  1104   | add_case is_proper (name, SOME c) cases = (name, (c, is_proper)) :: rem_case name cases;
  1105 
  1106 fun prep_case name fxs c =
  1107   let
  1108     fun replace (opt_x :: xs) ((y, T) :: ys) = (the_default y opt_x, T) :: replace xs ys
  1109       | replace [] ys = ys
  1110       | replace (_ :: _) [] = error ("Too many parameters for case " ^ quote name);
  1111     val RuleCases.Case {fixes, assumes, binds, cases} = c;
  1112     val fixes' = replace fxs fixes;
  1113     val binds' = map drop_schematic binds;
  1114   in
  1115     if null (fold (Term.add_tvarsT o snd) fixes []) andalso
  1116       null (fold (fold Term.add_vars o snd) assumes []) then
  1117         RuleCases.Case {fixes = fixes', assumes = assumes, binds = binds', cases = cases}
  1118     else error ("Illegal schematic variable(s) in case " ^ quote name)
  1119   end;
  1120 
  1121 fun fix (x, T) ctxt =
  1122   let
  1123     val (bind, ctxt') = bind_fixes [x] ctxt;
  1124     val t = bind (Free (x, T));
  1125   in (t, ctxt' |> Variable.declare_constraints t) end;
  1126 
  1127 in
  1128 
  1129 fun add_cases is_proper = map_cases o fold (add_case is_proper);
  1130 
  1131 fun case_result c ctxt =
  1132   let
  1133     val RuleCases.Case {fixes, ...} = c;
  1134     val (ts, ctxt') = ctxt |> fold_map fix fixes;
  1135     val RuleCases.Case {assumes, binds, cases, ...} = RuleCases.apply ts c;
  1136   in
  1137     ctxt'
  1138     |> add_binds_i (map drop_schematic binds)
  1139     |> add_cases true (map (apsnd SOME) cases)
  1140     |> pair (assumes, (binds, cases))
  1141   end;
  1142 
  1143 val apply_case = apfst fst oo case_result;
  1144 
  1145 fun get_case ctxt name xs =
  1146   (case AList.lookup (op =) (cases_of ctxt) name of
  1147     NONE => error ("Unknown case: " ^ quote name)
  1148   | SOME (c, _) => prep_case name xs c);
  1149 
  1150 end;
  1151 
  1152 
  1153 
  1154 (** print context information **)
  1155 
  1156 val debug = ref false;
  1157 
  1158 val verbose = ref false;
  1159 fun verb f x = if ! verbose then f (x ()) else [];
  1160 
  1161 fun setmp_verbose f x = Library.setmp verbose true f x;
  1162 
  1163 
  1164 (* local syntax *)
  1165 
  1166 val print_syntax = Syntax.print_syntax o syn_of;
  1167 
  1168 
  1169 (* abbreviations *)
  1170 
  1171 fun pretty_abbrevs show_globals ctxt =
  1172   let
  1173     val ((space, consts), (_, globals)) =
  1174       pairself (#constants o Consts.dest) (#consts (rep_context ctxt));
  1175     fun add_abbr (_, (_, NONE)) = I
  1176       | add_abbr (c, (T, SOME t)) =
  1177           if not show_globals andalso Symtab.defined globals c then I
  1178           else cons (c, Logic.mk_equals (Const (c, T), t));
  1179     val abbrevs = NameSpace.extern_table (space, Symtab.make (Symtab.fold add_abbr consts []));
  1180   in
  1181     if null abbrevs andalso not (! verbose) then []
  1182     else [Pretty.big_list "abbreviations:" (map (pretty_term_abbrev ctxt o #2) abbrevs)]
  1183   end;
  1184 
  1185 val print_abbrevs = Pretty.writeln o Pretty.chunks o pretty_abbrevs true;
  1186 
  1187 
  1188 (* term bindings *)
  1189 
  1190 fun pretty_binds ctxt =
  1191   let
  1192     val binds = Variable.binds_of ctxt;
  1193     fun prt_bind (xi, (T, t)) = pretty_term_abbrev ctxt (Logic.mk_equals (Var (xi, T), t));
  1194   in
  1195     if Vartab.is_empty binds andalso not (! verbose) then []
  1196     else [Pretty.big_list "term bindings:" (map prt_bind (Vartab.dest binds))]
  1197   end;
  1198 
  1199 val print_binds = Pretty.writeln o Pretty.chunks o pretty_binds;
  1200 
  1201 
  1202 (* local theorems *)
  1203 
  1204 fun pretty_lthms ctxt =
  1205   let
  1206     val local_facts = facts_of ctxt;
  1207     val props = Facts.props local_facts;
  1208     val facts =
  1209       (if null props then [] else [("unnamed", props)]) @
  1210       Facts.extern_static [] local_facts;
  1211   in
  1212     if null facts andalso not (! verbose) then []
  1213     else [Pretty.big_list "facts:" (map (pretty_fact ctxt) facts)]
  1214   end;
  1215 
  1216 val print_lthms = Pretty.writeln o Pretty.chunks o pretty_lthms;
  1217 
  1218 
  1219 (* local contexts *)
  1220 
  1221 local
  1222 
  1223 fun pretty_case (name, (fixes, ((asms, (lets, cs)), ctxt))) =
  1224   let
  1225     val prt_term = Syntax.pretty_term ctxt;
  1226 
  1227     fun prt_let (xi, t) = Pretty.block
  1228       [Pretty.quote (prt_term (Var (xi, Term.fastype_of t))), Pretty.str " =", Pretty.brk 1,
  1229         Pretty.quote (prt_term t)];
  1230 
  1231     fun prt_asm (a, ts) = Pretty.block (Pretty.breaks
  1232       ((if a = "" then [] else [Pretty.str (a ^ ":")]) @ map (Pretty.quote o prt_term) ts));
  1233 
  1234     fun prt_sect _ _ _ [] = []
  1235       | prt_sect s sep prt xs = [Pretty.block (Pretty.breaks (Pretty.str s ::
  1236             flat (Library.separate sep (map (Library.single o prt) xs))))];
  1237   in
  1238     Pretty.block (Pretty.fbreaks
  1239       (Pretty.str (name ^ ":") ::
  1240         prt_sect "fix" [] (Pretty.str o fst) fixes @
  1241         prt_sect "let" [Pretty.str "and"] prt_let
  1242           (map_filter (fn (xi, SOME t) => SOME (xi, t) | _ => NONE) lets) @
  1243         (if forall (null o #2) asms then []
  1244           else prt_sect "assume" [Pretty.str "and"] prt_asm asms) @
  1245         prt_sect "subcases:" [] (Pretty.str o fst) cs))
  1246   end;
  1247 
  1248 in
  1249 
  1250 fun pretty_cases ctxt =
  1251   let
  1252     fun add_case (_, (_, false)) = I
  1253       | add_case (name, (c as RuleCases.Case {fixes, ...}, true)) =
  1254           cons (name, (fixes, case_result c ctxt));
  1255     val cases = fold add_case (cases_of ctxt) [];
  1256   in
  1257     if null cases andalso not (! verbose) then []
  1258     else [Pretty.big_list "cases:" (map pretty_case cases)]
  1259   end;
  1260 
  1261 val print_cases = Pretty.writeln o Pretty.chunks o pretty_cases;
  1262 
  1263 end;
  1264 
  1265 
  1266 (* core context *)
  1267 
  1268 val prems_limit = ref ~1;
  1269 
  1270 fun pretty_ctxt ctxt =
  1271   if ! prems_limit < 0 andalso not (! debug) then []
  1272   else
  1273     let
  1274       val prt_term = Syntax.pretty_term ctxt;
  1275 
  1276       (*structures*)
  1277       val structs = LocalSyntax.structs_of (syntax_of ctxt);
  1278       val prt_structs = if null structs then []
  1279         else [Pretty.block (Pretty.str "structures:" :: Pretty.brk 1 ::
  1280           Pretty.commas (map Pretty.str structs))];
  1281 
  1282       (*fixes*)
  1283       fun prt_fix (x, x') =
  1284         if x = x' then Pretty.str x
  1285         else Pretty.block [Pretty.str x, Pretty.str " =", Pretty.brk 1, prt_term (Syntax.free x')];
  1286       val fixes =
  1287         rev (filter_out ((can Name.dest_internal orf member (op =) structs) o #1)
  1288           (Variable.fixes_of ctxt));
  1289       val prt_fixes = if null fixes then []
  1290         else [Pretty.block (Pretty.str "fixed variables:" :: Pretty.brk 1 ::
  1291           Pretty.commas (map prt_fix fixes))];
  1292 
  1293       (*prems*)
  1294       val prems = Assumption.prems_of ctxt;
  1295       val len = length prems;
  1296       val suppressed = len - ! prems_limit;
  1297       val prt_prems = if null prems then []
  1298         else [Pretty.big_list "prems:" ((if suppressed <= 0 then [] else [Pretty.str "..."]) @
  1299           map (pretty_thm ctxt) (Library.drop (suppressed, prems)))];
  1300     in prt_structs @ prt_fixes @ prt_prems end;
  1301 
  1302 
  1303 (* main context *)
  1304 
  1305 fun pretty_context ctxt =
  1306   let
  1307     val prt_term = Syntax.pretty_term ctxt;
  1308     val prt_typ = Syntax.pretty_typ ctxt;
  1309     val prt_sort = Syntax.pretty_sort ctxt;
  1310 
  1311     (*theory*)
  1312     val pretty_thy = Pretty.block
  1313       [Pretty.str "theory:", Pretty.brk 1, Context.pretty_thy (theory_of ctxt)];
  1314 
  1315     (*defaults*)
  1316     fun prt_atom prt prtT (x, X) = Pretty.block
  1317       [prt x, Pretty.str " ::", Pretty.brk 1, prtT X];
  1318 
  1319     fun prt_var (x, ~1) = prt_term (Syntax.free x)
  1320       | prt_var xi = prt_term (Syntax.var xi);
  1321 
  1322     fun prt_varT (x, ~1) = prt_typ (TFree (x, []))
  1323       | prt_varT xi = prt_typ (TVar (xi, []));
  1324 
  1325     val prt_defT = prt_atom prt_var prt_typ;
  1326     val prt_defS = prt_atom prt_varT prt_sort;
  1327 
  1328     val (types, sorts) = Variable.constraints_of ctxt;
  1329   in
  1330     verb single (K pretty_thy) @
  1331     pretty_ctxt ctxt @
  1332     verb (pretty_abbrevs false) (K ctxt) @
  1333     verb pretty_binds (K ctxt) @
  1334     verb pretty_lthms (K ctxt) @
  1335     verb pretty_cases (K ctxt) @
  1336     verb single (fn () => Pretty.big_list "type constraints:" (map prt_defT (Vartab.dest types))) @
  1337     verb single (fn () => Pretty.big_list "default sorts:" (map prt_defS (Vartab.dest sorts)))
  1338   end;
  1339 
  1340 
  1341 (* query meta data *)
  1342 
  1343 val query_type = Type.the_tags o tsig_of;
  1344 
  1345 fun query_const ctxt name =
  1346   Consts.the_tags (consts_of ctxt) name handle TYPE (msg, _, _) => error msg;
  1347 
  1348 fun query_class ctxt name = query_const ctxt (Logic.const_of_class name);
  1349 
  1350 end;