src/HOL/Library/Formal_Power_Series.thy

tuned proofs;

(*  Title:      HOL/Library/Formal_Power_Series.thy
    Author:     Amine Chaieb, University of Cambridge
*)

header{* A formalization of formal power series *}

theory Formal_Power_Series
imports Complex_Main Binomial
begin


subsection {* The type of formal power series*}

typedef (open) 'a fps = "{f :: nat \<Rightarrow> 'a. True}"
  morphisms fps_nth Abs_fps
  by simp

notation fps_nth (infixl "$" 75)

lemma expand_fps_eq: "p = q \<longleftrightarrow> (\<forall>n. p $ n = q $ n)"
  by (simp add: fps_nth_inject [symmetric] fun_eq_iff)

lemma fps_ext: "(\<And>n. p $ n = q $ n) \<Longrightarrow> p = q"
  by (simp add: expand_fps_eq)

lemma fps_nth_Abs_fps [simp]: "Abs_fps f $ n = f n"
  by (simp add: Abs_fps_inverse)

text{* Definition of the basic elements 0 and 1 and the basic operations of addition,
  negation and multiplication *}

instantiation fps :: (zero) zero
begin

definition fps_zero_def:
  "0 = Abs_fps (\<lambda>n. 0)"

instance ..
end

lemma fps_zero_nth [simp]: "0 $ n = 0"
  unfolding fps_zero_def by simp

instantiation fps :: ("{one, zero}") one
begin

definition fps_one_def:
  "1 = Abs_fps (\<lambda>n. if n = 0 then 1 else 0)"

instance ..
end

lemma fps_one_nth [simp]: "1 $ n = (if n = 0 then 1 else 0)"
  unfolding fps_one_def by simp

instantiation fps :: (plus)  plus
begin

definition fps_plus_def:
  "op + = (\<lambda>f g. Abs_fps (\<lambda>n. f $ n + g $ n))"

instance ..
end

lemma fps_add_nth [simp]: "(f + g) $ n = f $ n + g $ n"
  unfolding fps_plus_def by simp

instantiation fps :: (minus) minus
begin

definition fps_minus_def:
  "op - = (\<lambda>f g. Abs_fps (\<lambda>n. f $ n - g $ n))"

instance ..
end

lemma fps_sub_nth [simp]: "(f - g) $ n = f $ n - g $ n"
  unfolding fps_minus_def by simp

instantiation fps :: (uminus) uminus
begin

definition fps_uminus_def:
  "uminus = (\<lambda>f. Abs_fps (\<lambda>n. - (f $ n)))"

instance ..
end

lemma fps_neg_nth [simp]: "(- f) $ n = - (f $ n)"
  unfolding fps_uminus_def by simp

instantiation fps :: ("{comm_monoid_add, times}")  times
begin

definition fps_times_def:
  "op * = (\<lambda>f g. Abs_fps (\<lambda>n. \<Sum>i=0..n. f $ i * g $ (n - i)))"

instance ..
end

lemma fps_mult_nth: "(f * g) $ n = (\<Sum>i=0..n. f$i * g$(n - i))"
  unfolding fps_times_def by simp

declare atLeastAtMost_iff[presburger]
declare Bex_def[presburger]
declare Ball_def[presburger]

lemma mult_delta_left:
  fixes x y :: "'a::mult_zero"
  shows "(if b then x else 0) * y = (if b then x * y else 0)"
  by simp

lemma mult_delta_right:
  fixes x y :: "'a::mult_zero"
  shows "x * (if b then y else 0) = (if b then x * y else 0)"
  by simp

lemma cond_value_iff: "f (if b then x else y) = (if b then f x else f y)"
  by auto
lemma cond_application_beta: "(if b then f else g) x = (if b then f x else g x)"
  by auto

subsection{* Formal power series form a commutative ring with unity, if the range of sequences
  they represent is a commutative ring with unity*}

instance fps :: (semigroup_add) semigroup_add
proof
  fix a b c :: "'a fps" show "a + b + c = a + (b + c)"
    by (simp add: fps_ext add_assoc)
qed

instance fps :: (ab_semigroup_add) ab_semigroup_add
proof
  fix a b :: "'a fps" show "a + b = b + a"
    by (simp add: fps_ext add_commute)
qed

lemma fps_mult_assoc_lemma:
  fixes k :: nat and f :: "nat \<Rightarrow> nat \<Rightarrow> nat \<Rightarrow> 'a::comm_monoid_add"
  shows "(\<Sum>j=0..k. \<Sum>i=0..j. f i (j - i) (n - j)) =
         (\<Sum>j=0..k. \<Sum>i=0..k - j. f j i (n - j - i))"
proof (induct k)
  case 0 show ?case by simp
next
  case (Suc k) thus ?case
    by (simp add: Suc_diff_le setsum_addf add_assoc
             cong: strong_setsum_cong)
qed

instance fps :: (semiring_0) semigroup_mult
proof
  fix a b c :: "'a fps"
  show "(a * b) * c = a * (b * c)"
  proof (rule fps_ext)
    fix n :: nat
    have "(\<Sum>j=0..n. \<Sum>i=0..j. a$i * b$(j - i) * c$(n - j)) =
          (\<Sum>j=0..n. \<Sum>i=0..n - j. a$j * b$i * c$(n - j - i))"
      by (rule fps_mult_assoc_lemma)
    thus "((a * b) * c) $ n = (a * (b * c)) $ n"
      by (simp add: fps_mult_nth setsum_right_distrib
                    setsum_left_distrib mult_assoc)
  qed
qed

lemma fps_mult_commute_lemma:
  fixes n :: nat and f :: "nat \<Rightarrow> nat \<Rightarrow> 'a::comm_monoid_add"
  shows "(\<Sum>i=0..n. f i (n - i)) = (\<Sum>i=0..n. f (n - i) i)"
proof (rule setsum_reindex_cong)
  show "inj_on (\<lambda>i. n - i) {0..n}"
    by (rule inj_onI) simp
  show "{0..n} = (\<lambda>i. n - i) ` {0..n}"
    by (auto, rule_tac x="n - x" in image_eqI, simp_all)
next
  fix i assume "i \<in> {0..n}"
  hence "n - (n - i) = i" by simp
  thus "f (n - i) i = f (n - i) (n - (n - i))" by simp
qed

instance fps :: (comm_semiring_0) ab_semigroup_mult
proof
  fix a b :: "'a fps"
  show "a * b = b * a"
  proof (rule fps_ext)
    fix n :: nat
    have "(\<Sum>i=0..n. a$i * b$(n - i)) = (\<Sum>i=0..n. a$(n - i) * b$i)"
      by (rule fps_mult_commute_lemma)
    thus "(a * b) $ n = (b * a) $ n"
      by (simp add: fps_mult_nth mult_commute)
  qed
qed

instance fps :: (monoid_add) monoid_add
proof
  fix a :: "'a fps" show "0 + a = a "
    by (simp add: fps_ext)
next
  fix a :: "'a fps" show "a + 0 = a "
    by (simp add: fps_ext)
qed

instance fps :: (comm_monoid_add) comm_monoid_add
proof
  fix a :: "'a fps" show "0 + a = a "
    by (simp add: fps_ext)
qed

instance fps :: (semiring_1) monoid_mult
proof
  fix a :: "'a fps" show "1 * a = a"
    by (simp add: fps_ext fps_mult_nth mult_delta_left setsum_delta)
next
  fix a :: "'a fps" show "a * 1 = a"
    by (simp add: fps_ext fps_mult_nth mult_delta_right setsum_delta')
qed

instance fps :: (cancel_semigroup_add) cancel_semigroup_add
proof
  fix a b c :: "'a fps"
  assume "a + b = a + c" then show "b = c"
    by (simp add: expand_fps_eq)
next
  fix a b c :: "'a fps"
  assume "b + a = c + a" then show "b = c"
    by (simp add: expand_fps_eq)
qed

instance fps :: (cancel_ab_semigroup_add) cancel_ab_semigroup_add
proof
  fix a b c :: "'a fps"
  assume "a + b = a + c" then show "b = c"
    by (simp add: expand_fps_eq)
qed

instance fps :: (cancel_comm_monoid_add) cancel_comm_monoid_add ..

instance fps :: (group_add) group_add
proof
  fix a :: "'a fps" show "- a + a = 0"
    by (simp add: fps_ext)
next
  fix a b :: "'a fps" show "a - b = a + - b"
    by (simp add: fps_ext diff_minus)
qed

instance fps :: (ab_group_add) ab_group_add
proof
  fix a :: "'a fps"
  show "- a + a = 0"
    by (simp add: fps_ext)
next
  fix a b :: "'a fps"
  show "a - b = a + - b"
    by (simp add: fps_ext)
qed

instance fps :: (zero_neq_one) zero_neq_one
  by default (simp add: expand_fps_eq)

instance fps :: (semiring_0) semiring
proof
  fix a b c :: "'a fps"
  show "(a + b) * c = a * c + b * c"
    by (simp add: expand_fps_eq fps_mult_nth left_distrib setsum_addf)
next
  fix a b c :: "'a fps"
  show "a * (b + c) = a * b + a * c"
    by (simp add: expand_fps_eq fps_mult_nth right_distrib setsum_addf)
qed

instance fps :: (semiring_0) semiring_0
proof
  fix a:: "'a fps" show "0 * a = 0"
    by (simp add: fps_ext fps_mult_nth)
next
  fix a:: "'a fps" show "a * 0 = 0"
    by (simp add: fps_ext fps_mult_nth)
qed

instance fps :: (semiring_0_cancel) semiring_0_cancel ..

subsection {* Selection of the nth power of the implicit variable in the infinite sum*}

lemma fps_nonzero_nth: "f \<noteq> 0 \<longleftrightarrow> (\<exists> n. f $n \<noteq> 0)"
  by (simp add: expand_fps_eq)

lemma fps_nonzero_nth_minimal:
  "f \<noteq> 0 \<longleftrightarrow> (\<exists>n. f $ n \<noteq> 0 \<and> (\<forall>m<n. f $ m = 0))"
proof
  let ?n = "LEAST n. f $ n \<noteq> 0"
  assume "f \<noteq> 0"
  then have "\<exists>n. f $ n \<noteq> 0"
    by (simp add: fps_nonzero_nth)
  then have "f $ ?n \<noteq> 0"
    by (rule LeastI_ex)
  moreover have "\<forall>m<?n. f $ m = 0"
    by (auto dest: not_less_Least)
  ultimately have "f $ ?n \<noteq> 0 \<and> (\<forall>m<?n. f $ m = 0)" ..
  then show "\<exists>n. f $ n \<noteq> 0 \<and> (\<forall>m<n. f $ m = 0)" ..
next
  assume "\<exists>n. f $ n \<noteq> 0 \<and> (\<forall>m<n. f $ m = 0)"
  then show "f \<noteq> 0" by (auto simp add: expand_fps_eq)
qed

lemma fps_eq_iff: "f = g \<longleftrightarrow> (\<forall>n. f $ n = g $n)"
  by (rule expand_fps_eq)

lemma fps_setsum_nth: "(setsum f S) $ n = setsum (\<lambda>k. (f k) $ n) S"
proof (cases "finite S")
  assume "\<not> finite S" then show ?thesis by simp
next
  assume "finite S"
  then show ?thesis by (induct set: finite) auto
qed

subsection{* Injection of the basic ring elements and multiplication by scalars *}

definition
  "fps_const c = Abs_fps (\<lambda>n. if n = 0 then c else 0)"

lemma fps_nth_fps_const [simp]: "fps_const c $ n = (if n = 0 then c else 0)"
  unfolding fps_const_def by simp

lemma fps_const_0_eq_0 [simp]: "fps_const 0 = 0"
  by (simp add: fps_ext)

lemma fps_const_1_eq_1 [simp]: "fps_const 1 = 1"
  by (simp add: fps_ext)

lemma fps_const_neg [simp]: "- (fps_const (c::'a::ring)) = fps_const (- c)"
  by (simp add: fps_ext)

lemma fps_const_add [simp]: "fps_const (c::'a\<Colon>monoid_add) + fps_const d = fps_const (c + d)"
  by (simp add: fps_ext)
lemma fps_const_sub [simp]: "fps_const (c::'a\<Colon>group_add) - fps_const d = fps_const (c - d)"
  by (simp add: fps_ext)
lemma fps_const_mult[simp]: "fps_const (c::'a\<Colon>ring) * fps_const d = fps_const (c * d)"
  by (simp add: fps_eq_iff fps_mult_nth setsum_0')

lemma fps_const_add_left: "fps_const (c::'a\<Colon>monoid_add) + f =
    Abs_fps (\<lambda>n. if n = 0 then c + f$0 else f$n)"
  by (simp add: fps_ext)

lemma fps_const_add_right: "f + fps_const (c::'a\<Colon>monoid_add) =
    Abs_fps (\<lambda>n. if n = 0 then f$0 + c else f$n)"
  by (simp add: fps_ext)

lemma fps_const_mult_left: "fps_const (c::'a\<Colon>semiring_0) * f = Abs_fps (\<lambda>n. c * f$n)"
  unfolding fps_eq_iff fps_mult_nth
  by (simp add: fps_const_def mult_delta_left setsum_delta)

lemma fps_const_mult_right: "f * fps_const (c::'a\<Colon>semiring_0) = Abs_fps (\<lambda>n. f$n * c)"
  unfolding fps_eq_iff fps_mult_nth
  by (simp add: fps_const_def mult_delta_right setsum_delta')

lemma fps_mult_left_const_nth [simp]: "(fps_const (c::'a::semiring_1) * f)$n = c* f$n"
  by (simp add: fps_mult_nth mult_delta_left setsum_delta)

lemma fps_mult_right_const_nth [simp]: "(f * fps_const (c::'a::semiring_1))$n = f$n * c"
  by (simp add: fps_mult_nth mult_delta_right setsum_delta')

subsection {* Formal power series form an integral domain*}

instance fps :: (ring) ring ..

instance fps :: (ring_1) ring_1
  by (intro_classes, auto simp add: diff_minus left_distrib)

instance fps :: (comm_ring_1) comm_ring_1
  by (intro_classes, auto simp add: diff_minus left_distrib)

instance fps :: (ring_no_zero_divisors) ring_no_zero_divisors
proof
  fix a b :: "'a fps"
  assume a0: "a \<noteq> 0" and b0: "b \<noteq> 0"
  then obtain i j where i: "a$i\<noteq>0" "\<forall>k<i. a$k=0"
    and j: "b$j \<noteq>0" "\<forall>k<j. b$k =0" unfolding fps_nonzero_nth_minimal
    by blast+
  have "(a * b) $ (i+j) = (\<Sum>k=0..i+j. a$k * b$(i+j-k))"
    by (rule fps_mult_nth)
  also have "\<dots> = (a$i * b$(i+j-i)) + (\<Sum>k\<in>{0..i+j}-{i}. a$k * b$(i+j-k))"
    by (rule setsum_diff1') simp_all
  also have "(\<Sum>k\<in>{0..i+j}-{i}. a$k * b$(i+j-k)) = 0"
    proof (rule setsum_0' [rule_format])
      fix k assume "k \<in> {0..i+j} - {i}"
      then have "k < i \<or> i+j-k < j" by auto
      then show "a$k * b$(i+j-k) = 0" using i j by auto
    qed
  also have "a$i * b$(i+j-i) + 0 = a$i * b$j" by simp
  also have "a$i * b$j \<noteq> 0" using i j by simp
  finally have "(a*b) $ (i+j) \<noteq> 0" .
  then show "a*b \<noteq> 0" unfolding fps_nonzero_nth by blast
qed

instance fps :: (ring_1_no_zero_divisors) ring_1_no_zero_divisors ..

instance fps :: (idom) idom ..

lemma numeral_fps_const: "numeral k = fps_const (numeral k)"
  by (induct k) (simp_all only: numeral.simps fps_const_1_eq_1
    fps_const_add [symmetric])

lemma neg_numeral_fps_const: "neg_numeral k = fps_const (neg_numeral k)"
  by (simp only: neg_numeral_def numeral_fps_const fps_const_neg)

subsection{* The eXtractor series X*}

lemma minus_one_power_iff: "(- (1::'a :: {comm_ring_1})) ^ n = (if even n then 1 else - 1)"
  by (induct n) auto

definition "X = Abs_fps (\<lambda>n. if n = 1 then 1 else 0)"
lemma X_mult_nth[simp]: "(X * (f :: ('a::semiring_1) fps)) $n = (if n = 0 then 0 else f $ (n - 1))"
proof-
  {assume n: "n \<noteq> 0"
    have "(X * f) $n = (\<Sum>i = 0..n. X $ i * f $ (n - i))" by (simp add: fps_mult_nth)
    also have "\<dots> = f $ (n - 1)"
      using n by (simp add: X_def mult_delta_left setsum_delta)
  finally have ?thesis using n by simp }
  moreover
  {assume n: "n=0" hence ?thesis by (simp add: fps_mult_nth X_def)}
  ultimately show ?thesis by blast
qed

lemma X_mult_right_nth[simp]:
    "((f :: ('a::comm_semiring_1) fps) * X) $n = (if n = 0 then 0 else f $ (n - 1))"
  by (metis X_mult_nth mult_commute)

lemma X_power_iff: "X^k = Abs_fps (\<lambda>n. if n = k then (1::'a::comm_ring_1) else 0)"
proof(induct k)
  case 0 thus ?case by (simp add: X_def fps_eq_iff)
next
  case (Suc k)
  {fix m
    have "(X^Suc k) $ m = (if m = 0 then (0::'a) else (X^k) $ (m - 1))"
      by (simp add: power_Suc del: One_nat_def)
    then     have "(X^Suc k) $ m = (if m = Suc k then (1::'a) else 0)"
      using Suc.hyps by (auto cong del: if_weak_cong)}
  then show ?case by (simp add: fps_eq_iff)
qed

lemma X_power_mult_nth:
    "(X^k * (f :: ('a::comm_ring_1) fps)) $n = (if n < k then 0 else f $ (n - k))"
  apply (induct k arbitrary: n)
  apply (simp)
  unfolding power_Suc mult_assoc
  apply (case_tac n)
  apply auto
  done

lemma X_power_mult_right_nth:
    "((f :: ('a::comm_ring_1) fps) * X^k) $n = (if n < k then 0 else f $ (n - k))"
  by (metis X_power_mult_nth mult_commute)



  
subsection{* Formal Power series form a metric space *}

definition (in dist) ball_def: "ball x r = {y. dist y x < r}"

instantiation fps :: (comm_ring_1) dist
begin

definition dist_fps_def:
  "dist (a::'a fps) b = (if (\<exists>n. a$n \<noteq> b$n) then inverse (2 ^ The (leastP (\<lambda>n. a$n \<noteq> b$n))) else 0)"

lemma dist_fps_ge0: "dist (a::'a fps) b \<ge> 0"
  by (simp add: dist_fps_def)

lemma dist_fps_sym: "dist (a::'a fps) b = dist b a"
  apply (auto simp add: dist_fps_def)
  apply (rule cong[OF refl, where x="(\<lambda>n\<Colon>nat. a $ n \<noteq> b $ n)"])
  apply (rule ext)
  apply auto
  done

instance ..

end

lemma fps_nonzero_least_unique: assumes a0: "a \<noteq> 0"
  shows "\<exists>! n. leastP (\<lambda>n. a$n \<noteq> 0) n"
proof-
  from fps_nonzero_nth_minimal[of a] a0
  obtain n where n: "a$n \<noteq> 0" "\<forall>m < n. a$m = 0" by blast
  from n have ln: "leastP (\<lambda>n. a$n \<noteq> 0) n" 
    by (auto simp add: leastP_def setge_def not_le[symmetric])
  moreover
  {fix m assume "leastP (\<lambda>n. a$n \<noteq> 0) m"
    then have "m = n" using ln
      apply (auto simp add: leastP_def setge_def)
      apply (erule allE[where x=n])
      apply (erule allE[where x=m])
      by simp}
  ultimately show ?thesis by blast
qed

lemma fps_eq_least_unique:
  assumes ab: "(a::('a::ab_group_add) fps) \<noteq> b"
  shows "\<exists>! n. leastP (\<lambda>n. a$n \<noteq> b$n) n"
  using fps_nonzero_least_unique[of "a - b"] ab
  by auto

instantiation fps :: (comm_ring_1) metric_space
begin

definition open_fps_def: "open (S :: 'a fps set) = (\<forall>a \<in> S. \<exists>r. r >0 \<and> ball a r \<subseteq> S)"

instance
proof
  fix S :: "'a fps set" 
  show "open S = (\<forall>x\<in>S. \<exists>e>0. \<forall>y. dist y x < e \<longrightarrow> y \<in> S)"
    by (auto simp add: open_fps_def ball_def subset_eq)
next
  {
    fix a b :: "'a fps"
    {
      assume ab: "a = b"
      then have "\<not> (\<exists>n. a$n \<noteq> b$n)" by simp
      then have "dist a b = 0" by (simp add: dist_fps_def)
    }
    moreover
    {
      assume d: "dist a b = 0"
      then have "\<forall>n. a$n = b$n" 
        by - (rule ccontr, simp add: dist_fps_def)
      then have "a = b" by (simp add: fps_eq_iff)
    }
    ultimately show "dist a b =0 \<longleftrightarrow> a = b" by blast
  }
  note th = this
  from th have th'[simp]: "\<And>a::'a fps. dist a a = 0" by simp
  fix a b c :: "'a fps"
  {
    assume ab: "a = b" then have d0: "dist a b = 0"  unfolding th .
    then have "dist a b \<le> dist a c + dist b c" 
      using dist_fps_ge0[of a c] dist_fps_ge0[of b c] by simp
  }
  moreover
  {
    assume c: "c = a \<or> c = b"
    then have "dist a b \<le> dist a c + dist b c"
      by (cases "c=a") (simp_all add: th dist_fps_sym)
  }
  moreover
  {assume ab: "a \<noteq> b" and ac: "a \<noteq> c" and bc: "b \<noteq> c"
    let ?P = "\<lambda>a b n. a$n \<noteq> b$n"
    from fps_eq_least_unique[OF ab] fps_eq_least_unique[OF ac] 
      fps_eq_least_unique[OF bc]
    obtain nab nac nbc where nab: "leastP (?P a b) nab" 
      and nac: "leastP (?P a c) nac" 
      and nbc: "leastP (?P b c) nbc" by blast
    from nab have nab': "\<And>m. m < nab \<Longrightarrow> a$m = b$m" "a$nab \<noteq> b$nab"
      by (auto simp add: leastP_def setge_def)
    from nac have nac': "\<And>m. m < nac \<Longrightarrow> a$m = c$m" "a$nac \<noteq> c$nac"
      by (auto simp add: leastP_def setge_def)
    from nbc have nbc': "\<And>m. m < nbc \<Longrightarrow> b$m = c$m" "b$nbc \<noteq> c$nbc"
      by (auto simp add: leastP_def setge_def)

    have th0: "\<And>(a::'a fps) b. a \<noteq> b \<longleftrightarrow> (\<exists>n. a$n \<noteq> b$n)"
      by (simp add: fps_eq_iff)
    from ab ac bc nab nac nbc 
    have dab: "dist a b = inverse (2 ^ nab)" 
      and dac: "dist a c = inverse (2 ^ nac)" 
      and dbc: "dist b c = inverse (2 ^ nbc)"
      unfolding th0
      apply (simp_all add: dist_fps_def)
      apply (erule the1_equality[OF fps_eq_least_unique[OF ab]])
      apply (erule the1_equality[OF fps_eq_least_unique[OF ac]])
      by (erule the1_equality[OF fps_eq_least_unique[OF bc]])
    from ab ac bc have nz: "dist a b \<noteq> 0" "dist a c \<noteq> 0" "dist b c \<noteq> 0"
      unfolding th by simp_all
    from nz have pos: "dist a b > 0" "dist a c > 0" "dist b c > 0"
      using dist_fps_ge0[of a b] dist_fps_ge0[of a c] dist_fps_ge0[of b c] 
      by auto
    have th1: "\<And>n. (2::real)^n >0" by auto
    {assume h: "dist a b > dist a c + dist b c"
      then have gt: "dist a b > dist a c" "dist a b > dist b c"
        using pos by auto
      from gt have gtn: "nab < nbc" "nab < nac"
        unfolding dab dbc dac by (auto simp add: th1)
      from nac'(1)[OF gtn(2)] nbc'(1)[OF gtn(1)]
      have "a$nab = b$nab" by simp
      with nab'(2) have False  by simp}
    then have "dist a b \<le> dist a c + dist b c"
      by (auto simp add: not_le[symmetric]) }
  ultimately show "dist a b \<le> dist a c + dist b c" by blast
qed
  
end

text{* The infinite sums and justification of the notation in textbooks*}

lemma reals_power_lt_ex: assumes xp: "x > 0" and y1: "(y::real) > 1"
  shows "\<exists>k>0. (1/y)^k < x"
proof-
  have yp: "y > 0" using y1 by simp
  from reals_Archimedean2[of "max 0 (- log y x) + 1"]
  obtain k::nat where k: "real k > max 0 (- log y x) + 1" by blast
  from k have kp: "k > 0" by simp
  from k have "real k > - log y x" by simp
  then have "ln y * real k > - ln x" unfolding log_def
    using ln_gt_zero_iff[OF yp] y1
    by (simp add: minus_divide_left field_simps del:minus_divide_left[symmetric])
  then have "ln y * real k + ln x > 0" by simp
  then have "exp (real k * ln y + ln x) > exp 0"
    by (simp add: mult_ac)
  then have "y ^ k * x > 1"
    unfolding exp_zero exp_add exp_real_of_nat_mult
    exp_ln[OF xp] exp_ln[OF yp] by simp
  then have "x > (1/y)^k" using yp 
    by (simp add: field_simps nonzero_power_divide)
  then show ?thesis using kp by blast
qed
lemma X_nth[simp]: "X$n = (if n = 1 then 1 else 0)" by (simp add: X_def)
lemma X_power_nth[simp]: "(X^k) $n = (if n = k then 1 else (0::'a::comm_ring_1))"
  by (simp add: X_power_iff)
 

lemma fps_sum_rep_nth: "(setsum (%i. fps_const(a$i)*X^i) {0..m})$n =
    (if n \<le> m then a$n else (0::'a::comm_ring_1))"
  apply (auto simp add: fps_eq_iff fps_setsum_nth X_power_nth cond_application_beta cond_value_iff
    cong del: if_weak_cong)
  apply (simp add: setsum_delta')
  done
  
lemma fps_notation: 
  "(%n. setsum (%i. fps_const(a$i) * X^i) {0..n}) ----> a" (is "?s ----> a")
proof-
    {fix r:: real
      assume rp: "r > 0"
      have th0: "(2::real) > 1" by simp
      from reals_power_lt_ex[OF rp th0] 
      obtain n0 where n0: "(1/2)^n0 < r" "n0 > 0" by blast
      {fix n::nat
        assume nn0: "n \<ge> n0"
        then have thnn0: "(1/2)^n <= (1/2 :: real)^n0"
          by (auto intro: power_decreasing)
        {assume "?s n = a" then have "dist (?s n) a < r" 
            unfolding dist_eq_0_iff[of "?s n" a, symmetric]
            using rp by (simp del: dist_eq_0_iff)}
        moreover
        {assume neq: "?s n \<noteq> a"
          from fps_eq_least_unique[OF neq] 
          obtain k where k: "leastP (\<lambda>i. ?s n $ i \<noteq> a$i) k" by blast
          have th0: "\<And>(a::'a fps) b. a \<noteq> b \<longleftrightarrow> (\<exists>n. a$n \<noteq> b$n)"
            by (simp add: fps_eq_iff)
          from neq have dth: "dist (?s n) a = (1/2)^k"
            unfolding th0 dist_fps_def
            unfolding the1_equality[OF fps_eq_least_unique[OF neq], OF k]
            by (auto simp add: inverse_eq_divide power_divide)

          from k have kn: "k > n"
            by (simp add: leastP_def setge_def fps_sum_rep_nth split:split_if_asm)
          then have "dist (?s n) a < (1/2)^n" unfolding dth
            by (auto intro: power_strict_decreasing)
          also have "\<dots> <= (1/2)^n0" using nn0
            by (auto intro: power_decreasing)
          also have "\<dots> < r" using n0 by simp
          finally have "dist (?s n) a < r" .}
        ultimately have "dist (?s n) a < r" by blast}
      then have "\<exists>n0. \<forall> n \<ge> n0. dist (?s n) a < r " by blast}
    then show ?thesis  unfolding  LIMSEQ_def by blast
  qed

subsection{* Inverses of formal power series *}

declare setsum_cong[fundef_cong]

instantiation fps :: ("{comm_monoid_add, inverse, times, uminus}") inverse
begin

fun natfun_inverse:: "'a fps \<Rightarrow> nat \<Rightarrow> 'a" where
  "natfun_inverse f 0 = inverse (f$0)"
| "natfun_inverse f n = - inverse (f$0) * setsum (\<lambda>i. f$i * natfun_inverse f (n - i)) {1..n}"

definition fps_inverse_def:
  "inverse f = (if f $ 0 = 0 then 0 else Abs_fps (natfun_inverse f))"

definition fps_divide_def: "divide = (\<lambda>(f::'a fps) g. f * inverse g)"

instance ..

end

lemma fps_inverse_zero[simp]:
  "inverse (0 :: 'a::{comm_monoid_add,inverse, times, uminus} fps) = 0"
  by (simp add: fps_ext fps_inverse_def)

lemma fps_inverse_one[simp]: "inverse (1 :: 'a::{division_ring,zero_neq_one} fps) = 1"
  apply (auto simp add: expand_fps_eq fps_inverse_def)
  by (case_tac n, auto)

lemma inverse_mult_eq_1 [intro]: assumes f0: "f$0 \<noteq> (0::'a::field)"
  shows "inverse f * f = 1"
proof-
  have c: "inverse f * f = f * inverse f" by (simp add: mult_commute)
  from f0 have ifn: "\<And>n. inverse f $ n = natfun_inverse f n"
    by (simp add: fps_inverse_def)
  from f0 have th0: "(inverse f * f) $ 0 = 1"
    by (simp add: fps_mult_nth fps_inverse_def)
  {fix n::nat assume np: "n >0 "
    from np have eq: "{0..n} = {0} \<union> {1 .. n}" by auto
    have d: "{0} \<inter> {1 .. n} = {}" by auto
    from f0 np have th0: "- (inverse f$n) =
      (setsum (\<lambda>i. f$i * natfun_inverse f (n - i)) {1..n}) / (f$0)"
      by (cases n, simp, simp add: divide_inverse fps_inverse_def)
    from th0[symmetric, unfolded nonzero_divide_eq_eq[OF f0]]
    have th1: "setsum (\<lambda>i. f$i * natfun_inverse f (n - i)) {1..n} =
      - (f$0) * (inverse f)$n"
      by (simp add: field_simps)
    have "(f * inverse f) $ n = (\<Sum>i = 0..n. f $i * natfun_inverse f (n - i))"
      unfolding fps_mult_nth ifn ..
    also have "\<dots> = f$0 * natfun_inverse f n
      + (\<Sum>i = 1..n. f$i * natfun_inverse f (n-i))"
      by (simp add: eq)
    also have "\<dots> = 0" unfolding th1 ifn by simp
    finally have "(inverse f * f)$n = 0" unfolding c . }
  with th0 show ?thesis by (simp add: fps_eq_iff)
qed

lemma fps_inverse_0_iff[simp]: "(inverse f)$0 = (0::'a::division_ring) \<longleftrightarrow> f$0 = 0"
  by (simp add: fps_inverse_def nonzero_imp_inverse_nonzero)

lemma fps_inverse_eq_0_iff[simp]: "inverse f = (0:: ('a::field) fps) \<longleftrightarrow> f $0 = 0"
proof-
  {assume "f$0 = 0" hence "inverse f = 0" by (simp add: fps_inverse_def)}
  moreover
  {assume h: "inverse f = 0" and c: "f $0 \<noteq> 0"
    from inverse_mult_eq_1[OF c] h have False by simp}
  ultimately show ?thesis by blast
qed

lemma fps_inverse_idempotent[intro]:
  assumes f0: "f$0 \<noteq> (0::'a::field)"
  shows "inverse (inverse f) = f"
proof-
  from f0 have if0: "inverse f $ 0 \<noteq> 0" by simp
  from inverse_mult_eq_1[OF f0] inverse_mult_eq_1[OF if0]
  have th0: "inverse f * f = inverse f * inverse (inverse f)"   by (simp add: mult_ac)
  then show ?thesis using f0 unfolding mult_cancel_left by simp
qed

lemma fps_inverse_unique:
  assumes f0: "f$0 \<noteq> (0::'a::field)" and fg: "f*g = 1"
  shows "inverse f = g"
proof-
  from inverse_mult_eq_1[OF f0] fg
  have th0: "inverse f * f = g * f" by (simp add: mult_ac)
  then show ?thesis using f0  unfolding mult_cancel_right
    by (auto simp add: expand_fps_eq)
qed

lemma fps_inverse_gp: "inverse (Abs_fps(\<lambda>n. (1::'a::field)))
  = Abs_fps (\<lambda>n. if n= 0 then 1 else if n=1 then - 1 else 0)"
  apply (rule fps_inverse_unique)
  apply simp
  apply (simp add: fps_eq_iff fps_mult_nth)
proof(clarsimp)
  fix n::nat assume n: "n > 0"
  let ?f = "\<lambda>i. if n = i then (1\<Colon>'a) else if n - i = 1 then - 1 else 0"
  let ?g = "\<lambda>i. if i = n then 1 else if i=n - 1 then - 1 else 0"
  let ?h = "\<lambda>i. if i=n - 1 then - 1 else 0"
  have th1: "setsum ?f {0..n} = setsum ?g {0..n}"
    by (rule setsum_cong2) auto
  have th2: "setsum ?g {0..n - 1} = setsum ?h {0..n - 1}"
    using n apply - by (rule setsum_cong2) auto
  have eq: "{0 .. n} = {0.. n - 1} \<union> {n}" by auto
  from n have d: "{0.. n - 1} \<inter> {n} = {}" by auto
  have f: "finite {0.. n - 1}" "finite {n}" by auto
  show "setsum ?f {0..n} = 0"
    unfolding th1
    apply (simp add: setsum_Un_disjoint[OF f d, unfolded eq[symmetric]] del: One_nat_def)
    unfolding th2
    by(simp add: setsum_delta)
qed

subsection{* Formal Derivatives, and the MacLaurin theorem around 0*}

definition "fps_deriv f = Abs_fps (\<lambda>n. of_nat (n + 1) * f $ (n + 1))"

lemma fps_deriv_nth[simp]: "fps_deriv f $ n = of_nat (n +1) * f $ (n+1)"
  by (simp add: fps_deriv_def)

lemma fps_deriv_linear[simp]:
  "fps_deriv (fps_const (a::'a::comm_semiring_1) * f + fps_const b * g) =
    fps_const a * fps_deriv f + fps_const b * fps_deriv g"
  unfolding fps_eq_iff fps_add_nth  fps_const_mult_left fps_deriv_nth by (simp add: field_simps)

lemma fps_deriv_mult[simp]:
  fixes f :: "('a :: comm_ring_1) fps"
  shows "fps_deriv (f * g) = f * fps_deriv g + fps_deriv f * g"
proof-
  let ?D = "fps_deriv"
  {fix n::nat
    let ?Zn = "{0 ..n}"
    let ?Zn1 = "{0 .. n + 1}"
    let ?f = "\<lambda>i. i + 1"
    have fi: "inj_on ?f {0..n}" by (simp add: inj_on_def)
    have eq: "{1.. n+1} = ?f ` {0..n}" by auto
    let ?g = "\<lambda>i. of_nat (i+1) * g $ (i+1) * f $ (n - i) +
        of_nat (i+1)* f $ (i+1) * g $ (n - i)"
    let ?h = "\<lambda>i. of_nat i * g $ i * f $ ((n+1) - i) +
        of_nat i* f $ i * g $ ((n + 1) - i)"
    {fix k assume k: "k \<in> {0..n}"
      have "?h (k + 1) = ?g k" using k by auto}
    note th0 = this
    have eq': "{0..n +1}- {1 .. n+1} = {0}" by auto
    have s0: "setsum (\<lambda>i. of_nat i * f $ i * g $ (n + 1 - i)) ?Zn1 = setsum (\<lambda>i. of_nat (n + 1 - i) * f $ (n + 1 - i) * g $ i) ?Zn1"
      apply (rule setsum_reindex_cong[where f="\<lambda>i. n + 1 - i"])
      apply (simp add: inj_on_def Ball_def)
      apply presburger
      apply (rule set_eqI)
      apply (presburger add: image_iff)
      by simp
    have s1: "setsum (\<lambda>i. f $ i * g $ (n + 1 - i)) ?Zn1 = setsum (\<lambda>i. f $ (n + 1 - i) * g $ i) ?Zn1"
      apply (rule setsum_reindex_cong[where f="\<lambda>i. n + 1 - i"])
      apply (simp add: inj_on_def Ball_def)
      apply presburger
      apply (rule set_eqI)
      apply (presburger add: image_iff)
      by simp
    have "(f * ?D g + ?D f * g)$n = (?D g * f + ?D f * g)$n" by (simp only: mult_commute)
    also have "\<dots> = (\<Sum>i = 0..n. ?g i)"
      by (simp add: fps_mult_nth setsum_addf[symmetric])
    also have "\<dots> = setsum ?h {1..n+1}"
      using th0 setsum_reindex_cong[OF fi eq, of "?g" "?h"] by auto
    also have "\<dots> = setsum ?h {0..n+1}"
      apply (rule setsum_mono_zero_left)
      apply simp
      apply (simp add: subset_eq)
      unfolding eq'
      by simp
    also have "\<dots> = (fps_deriv (f * g)) $ n"
      apply (simp only: fps_deriv_nth fps_mult_nth setsum_addf)
      unfolding s0 s1
      unfolding setsum_addf[symmetric] setsum_right_distrib
      apply (rule setsum_cong2)
      by (auto simp add: of_nat_diff field_simps)
    finally have "(f * ?D g + ?D f * g) $ n = ?D (f*g) $ n" .}
  then show ?thesis unfolding fps_eq_iff by auto
qed

lemma fps_deriv_X[simp]: "fps_deriv X = 1"
  by (simp add: fps_deriv_def X_def fps_eq_iff)

lemma fps_deriv_neg[simp]: "fps_deriv (- (f:: ('a:: comm_ring_1) fps)) = - (fps_deriv f)"
  by (simp add: fps_eq_iff fps_deriv_def)
lemma fps_deriv_add[simp]: "fps_deriv ((f:: ('a::comm_ring_1) fps) + g) = fps_deriv f + fps_deriv g"
  using fps_deriv_linear[of 1 f 1 g] by simp

lemma fps_deriv_sub[simp]: "fps_deriv ((f:: ('a::comm_ring_1) fps) - g) = fps_deriv f - fps_deriv g"
  unfolding diff_minus by simp

lemma fps_deriv_const[simp]: "fps_deriv (fps_const c) = 0"
  by (simp add: fps_ext fps_deriv_def fps_const_def)

lemma fps_deriv_mult_const_left[simp]:
    "fps_deriv (fps_const (c::'a::comm_ring_1) * f) = fps_const c * fps_deriv f"
  by simp

lemma fps_deriv_0[simp]: "fps_deriv 0 = 0"
  by (simp add: fps_deriv_def fps_eq_iff)

lemma fps_deriv_1[simp]: "fps_deriv 1 = 0"
  by (simp add: fps_deriv_def fps_eq_iff )

lemma fps_deriv_mult_const_right[simp]:
    "fps_deriv (f * fps_const (c::'a::comm_ring_1)) = fps_deriv f * fps_const c"
  by simp

lemma fps_deriv_setsum:
  "fps_deriv (setsum f S) = setsum (\<lambda>i. fps_deriv (f i :: ('a::comm_ring_1) fps)) S"
proof-
  { assume "\<not> finite S" hence ?thesis by simp }
  moreover
  {
    assume fS: "finite S"
    have ?thesis  by (induct rule: finite_induct[OF fS]) simp_all
  }
  ultimately show ?thesis by blast
qed

lemma fps_deriv_eq_0_iff[simp]:
  "fps_deriv f = 0 \<longleftrightarrow> (f = fps_const (f$0 :: 'a::{idom,semiring_char_0}))"
proof-
  {assume "f= fps_const (f$0)" hence "fps_deriv f = fps_deriv (fps_const (f$0))" by simp
    hence "fps_deriv f = 0" by simp }
  moreover
  {assume z: "fps_deriv f = 0"
    hence "\<forall>n. (fps_deriv f)$n = 0" by simp
    hence "\<forall>n. f$(n+1) = 0" by (simp del: of_nat_Suc of_nat_add One_nat_def)
    hence "f = fps_const (f$0)"
      apply (clarsimp simp add: fps_eq_iff fps_const_def)
      apply (erule_tac x="n - 1" in allE)
      by simp}
  ultimately show ?thesis by blast
qed

lemma fps_deriv_eq_iff:
  fixes f:: "('a::{idom,semiring_char_0}) fps"
  shows "fps_deriv f = fps_deriv g \<longleftrightarrow> (f = fps_const(f$0 - g$0) + g)"
proof-
  have "fps_deriv f = fps_deriv g \<longleftrightarrow> fps_deriv (f - g) = 0" by simp
  also have "\<dots> \<longleftrightarrow> f - g = fps_const ((f-g)$0)" unfolding fps_deriv_eq_0_iff ..
  finally show ?thesis by (simp add: field_simps)
qed

lemma fps_deriv_eq_iff_ex:
  "(fps_deriv f = fps_deriv g) \<longleftrightarrow> (\<exists>(c::'a::{idom,semiring_char_0}). f = fps_const c + g)"
  apply auto unfolding fps_deriv_eq_iff
  apply blast
  done


fun fps_nth_deriv :: "nat \<Rightarrow> ('a::semiring_1) fps \<Rightarrow> 'a fps"
where
  "fps_nth_deriv 0 f = f"
| "fps_nth_deriv (Suc n) f = fps_nth_deriv n (fps_deriv f)"

lemma fps_nth_deriv_commute: "fps_nth_deriv (Suc n) f = fps_deriv (fps_nth_deriv n f)"
  by (induct n arbitrary: f) auto

lemma fps_nth_deriv_linear[simp]:
  "fps_nth_deriv n (fps_const (a::'a::comm_semiring_1) * f + fps_const b * g) =
    fps_const a * fps_nth_deriv n f + fps_const b * fps_nth_deriv n g"
  by (induct n arbitrary: f g) (auto simp add: fps_nth_deriv_commute)

lemma fps_nth_deriv_neg[simp]:
  "fps_nth_deriv n (- (f:: ('a:: comm_ring_1) fps)) = - (fps_nth_deriv n f)"
  by (induct n arbitrary: f) simp_all

lemma fps_nth_deriv_add[simp]:
  "fps_nth_deriv n ((f:: ('a::comm_ring_1) fps) + g) = fps_nth_deriv n f + fps_nth_deriv n g"
  using fps_nth_deriv_linear[of n 1 f 1 g] by simp

lemma fps_nth_deriv_sub[simp]:
  "fps_nth_deriv n ((f:: ('a::comm_ring_1) fps) - g) = fps_nth_deriv n f - fps_nth_deriv n g"
  unfolding diff_minus fps_nth_deriv_add by simp

lemma fps_nth_deriv_0[simp]: "fps_nth_deriv n 0 = 0"
  by (induct n) simp_all

lemma fps_nth_deriv_1[simp]: "fps_nth_deriv n 1 = (if n = 0 then 1 else 0)"
  by (induct n) simp_all

lemma fps_nth_deriv_const[simp]:
  "fps_nth_deriv n (fps_const c) = (if n = 0 then fps_const c else 0)"
  by (cases n) simp_all

lemma fps_nth_deriv_mult_const_left[simp]:
  "fps_nth_deriv n (fps_const (c::'a::comm_ring_1) * f) = fps_const c * fps_nth_deriv n f"
  using fps_nth_deriv_linear[of n "c" f 0 0 ] by simp

lemma fps_nth_deriv_mult_const_right[simp]:
  "fps_nth_deriv n (f * fps_const (c::'a::comm_ring_1)) = fps_nth_deriv n f * fps_const c"
  using fps_nth_deriv_linear[of n "c" f 0 0] by (simp add: mult_commute)

lemma fps_nth_deriv_setsum:
  "fps_nth_deriv n (setsum f S) = setsum (\<lambda>i. fps_nth_deriv n (f i :: ('a::comm_ring_1) fps)) S"
proof-
  { assume "\<not> finite S" hence ?thesis by simp }
  moreover
  {
    assume fS: "finite S"
    have ?thesis  by (induct rule: finite_induct[OF fS]) simp_all
  }
  ultimately show ?thesis by blast
qed

lemma fps_deriv_maclauren_0:
  "(fps_nth_deriv k (f:: ('a::comm_semiring_1) fps)) $ 0 = of_nat (fact k) * f$(k)"
  by (induct k arbitrary: f) (auto simp add: field_simps of_nat_mult)

subsection {* Powers*}

lemma fps_power_zeroth_eq_one: "a$0 =1 \<Longrightarrow> a^n $ 0 = (1::'a::semiring_1)"
  by (induct n) (auto simp add: expand_fps_eq fps_mult_nth)

lemma fps_power_first_eq: "(a:: 'a::comm_ring_1 fps)$0 =1 \<Longrightarrow> a^n $ 1 = of_nat n * a$1"
proof(induct n)
  case 0 thus ?case by simp
next
  case (Suc n)
  note h = Suc.hyps[OF `a$0 = 1`]
  show ?case unfolding power_Suc fps_mult_nth
    using h `a$0 = 1`  fps_power_zeroth_eq_one[OF `a$0=1`] by (simp add: field_simps)
qed

lemma startsby_one_power:"a $ 0 = (1::'a::comm_ring_1) \<Longrightarrow> a^n $ 0 = 1"
  by (induct n) (auto simp add: fps_mult_nth)

lemma startsby_zero_power:"a $0 = (0::'a::comm_ring_1) \<Longrightarrow> n > 0 \<Longrightarrow> a^n $0 = 0"
  by (induct n) (auto simp add: fps_mult_nth)

lemma startsby_power:"a $0 = (v::'a::{comm_ring_1}) \<Longrightarrow> a^n $0 = v^n"
  by (induct n) (auto simp add: fps_mult_nth power_Suc)

lemma startsby_zero_power_iff[simp]:
  "a^n $0 = (0::'a::{idom}) \<longleftrightarrow> (n \<noteq> 0 \<and> a$0 = 0)"
apply (rule iffI)
apply (induct n)
apply (auto simp add: fps_mult_nth)
apply (rule startsby_zero_power, simp_all)
done

lemma startsby_zero_power_prefix:
  assumes a0: "a $0 = (0::'a::idom)"
  shows "\<forall>n < k. a ^ k $ n = 0"
  using a0
proof(induct k rule: nat_less_induct)
  fix k assume H: "\<forall>m<k. a $0 =  0 \<longrightarrow> (\<forall>n<m. a ^ m $ n = 0)" and a0: "a $0 = (0\<Colon>'a)"
  let ?ths = "\<forall>m<k. a ^ k $ m = 0"
  {assume "k = 0" then have ?ths by simp}
  moreover
  {fix l assume k: "k = Suc l"
    {fix m assume mk: "m < k"
      {assume "m=0" hence "a^k $ m = 0" using startsby_zero_power[of a k] k a0
          by simp}
      moreover
      {assume m0: "m \<noteq> 0"
        have "a ^k $ m = (a^l * a) $m" by (simp add: k power_Suc mult_commute)
        also have "\<dots> = (\<Sum>i = 0..m. a ^ l $ i * a $ (m - i))" by (simp add: fps_mult_nth)
        also have "\<dots> = 0" apply (rule setsum_0')
          apply auto
          apply (case_tac "aa = m")
          using a0
          apply simp
          apply (rule H[rule_format])
          using a0 k mk by auto
        finally have "a^k $ m = 0" .}
    ultimately have "a^k $ m = 0" by blast}
    hence ?ths by blast}
  ultimately show ?ths by (cases k, auto)
qed

lemma startsby_zero_setsum_depends:
  assumes a0: "a $0 = (0::'a::idom)" and kn: "n \<ge> k"
  shows "setsum (\<lambda>i. (a ^ i)$k) {0 .. n} = setsum (\<lambda>i. (a ^ i)$k) {0 .. k}"
  apply (rule setsum_mono_zero_right)
  using kn apply auto
  apply (rule startsby_zero_power_prefix[rule_format, OF a0])
  by arith

lemma startsby_zero_power_nth_same: assumes a0: "a$0 = (0::'a::{idom})"
  shows "a^n $ n = (a$1) ^ n"
proof(induct n)
  case 0 thus ?case by (simp add: power_0)
next
  case (Suc n)
  have "a ^ Suc n $ (Suc n) = (a^n * a)$(Suc n)" by (simp add: field_simps power_Suc)
  also have "\<dots> = setsum (\<lambda>i. a^n$i * a $ (Suc n - i)) {0.. Suc n}" by (simp add: fps_mult_nth)
  also have "\<dots> = setsum (\<lambda>i. a^n$i * a $ (Suc n - i)) {n .. Suc n}"
    apply (rule setsum_mono_zero_right)
    apply simp
    apply clarsimp
    apply clarsimp
    apply (rule startsby_zero_power_prefix[rule_format, OF a0])
    apply arith
    done
  also have "\<dots> = a^n $ n * a$1" using a0 by simp
  finally show ?case using Suc.hyps by (simp add: power_Suc)
qed

lemma fps_inverse_power:
  fixes a :: "('a::{field}) fps"
  shows "inverse (a^n) = inverse a ^ n"
proof-
  {assume a0: "a$0 = 0"
    hence eq: "inverse a = 0" by (simp add: fps_inverse_def)
    {assume "n = 0" hence ?thesis by simp}
    moreover
    {assume n: "n > 0"
      from startsby_zero_power[OF a0 n] eq a0 n have ?thesis
        by (simp add: fps_inverse_def)}
    ultimately have ?thesis by blast}
  moreover
  {assume a0: "a$0 \<noteq> 0"
    have ?thesis
      apply (rule fps_inverse_unique)
      apply (simp add: a0)
      unfolding power_mult_distrib[symmetric]
      apply (rule ssubst[where t = "a * inverse a" and s= 1])
      apply simp_all
      apply (subst mult_commute)
      by (rule inverse_mult_eq_1[OF a0])}
  ultimately show ?thesis by blast
qed

lemma fps_deriv_power:
    "fps_deriv (a ^ n) = fps_const (of_nat n :: 'a:: comm_ring_1) * fps_deriv a * a ^ (n - 1)"
  apply (induct n)
  apply (auto simp add: power_Suc field_simps fps_const_add[symmetric] simp del: fps_const_add)
  apply (case_tac n)
  apply (auto simp add: power_Suc field_simps)
  done

lemma fps_inverse_deriv:
  fixes a:: "('a :: field) fps"
  assumes a0: "a$0 \<noteq> 0"
  shows "fps_deriv (inverse a) = - fps_deriv a * inverse a ^ 2"
proof-
  from inverse_mult_eq_1[OF a0]
  have "fps_deriv (inverse a * a) = 0" by simp
  hence "inverse a * fps_deriv a + fps_deriv (inverse a) * a = 0" by simp
  hence "inverse a * (inverse a * fps_deriv a + fps_deriv (inverse a) * a) = 0"  by simp
  with inverse_mult_eq_1[OF a0]
  have "inverse a ^ 2 * fps_deriv a + fps_deriv (inverse a) = 0"
    unfolding power2_eq_square
    apply (simp add: field_simps)
    by (simp add: mult_assoc[symmetric])
  hence "inverse a ^ 2 * fps_deriv a + fps_deriv (inverse a) - fps_deriv a * inverse a ^ 2 = 0 - fps_deriv a * inverse a ^ 2"
    by simp
  then show "fps_deriv (inverse a) = - fps_deriv a * inverse a ^ 2" by (simp add: field_simps)
qed

lemma fps_inverse_mult:
  fixes a::"('a :: field) fps"
  shows "inverse (a * b) = inverse a * inverse b"
proof-
  {assume a0: "a$0 = 0" hence ab0: "(a*b)$0 = 0" by (simp add: fps_mult_nth)
    from a0 ab0 have th: "inverse a = 0" "inverse (a*b) = 0" by simp_all
    have ?thesis unfolding th by simp}
  moreover
  {assume b0: "b$0 = 0" hence ab0: "(a*b)$0 = 0" by (simp add: fps_mult_nth)
    from b0 ab0 have th: "inverse b = 0" "inverse (a*b) = 0" by simp_all
    have ?thesis unfolding th by simp}
  moreover
  {assume a0: "a$0 \<noteq> 0" and b0: "b$0 \<noteq> 0"
    from a0 b0 have ab0:"(a*b) $ 0 \<noteq> 0" by (simp  add: fps_mult_nth)
    from inverse_mult_eq_1[OF ab0]
    have "inverse (a*b) * (a*b) * inverse a * inverse b = 1 * inverse a * inverse b" by simp
    then have "inverse (a*b) * (inverse a * a) * (inverse b * b) = inverse a * inverse b"
      by (simp add: field_simps)
    then have ?thesis using inverse_mult_eq_1[OF a0] inverse_mult_eq_1[OF b0] by simp}
ultimately show ?thesis by blast
qed

lemma fps_inverse_deriv':
  fixes a:: "('a :: field) fps"
  assumes a0: "a$0 \<noteq> 0"
  shows "fps_deriv (inverse a) = - fps_deriv a / a ^ 2"
  using fps_inverse_deriv[OF a0]
  unfolding power2_eq_square fps_divide_def fps_inverse_mult
  by simp

lemma inverse_mult_eq_1': assumes f0: "f$0 \<noteq> (0::'a::field)"
  shows "f * inverse f= 1"
  by (metis mult_commute inverse_mult_eq_1 f0)

lemma fps_divide_deriv:   fixes a:: "('a :: field) fps"
  assumes a0: "b$0 \<noteq> 0"
  shows "fps_deriv (a / b) = (fps_deriv a * b - a * fps_deriv b) / b ^ 2"
  using fps_inverse_deriv[OF a0]
  by (simp add: fps_divide_def field_simps
    power2_eq_square fps_inverse_mult inverse_mult_eq_1'[OF a0])


lemma fps_inverse_gp': "inverse (Abs_fps(\<lambda>n. (1::'a::field)))
  = 1 - X"
  by (simp add: fps_inverse_gp fps_eq_iff X_def)

lemma fps_nth_deriv_X[simp]: "fps_nth_deriv n X = (if n = 0 then X else if n=1 then 1 else 0)"
  by (cases "n", simp_all)


lemma fps_inverse_X_plus1:
  "inverse (1 + X) = Abs_fps (\<lambda>n. (- (1::'a::{field})) ^ n)" (is "_ = ?r")
proof-
  have eq: "(1 + X) * ?r = 1"
    unfolding minus_one_power_iff
    by (auto simp add: field_simps fps_eq_iff)
  show ?thesis by (auto simp add: eq intro: fps_inverse_unique simp del: minus_one)
qed


subsection{* Integration *}

definition
  fps_integral :: "'a::field_char_0 fps \<Rightarrow> 'a \<Rightarrow> 'a fps" where
  "fps_integral a a0 = Abs_fps (\<lambda>n. if n = 0 then a0 else (a$(n - 1) / of_nat n))"

lemma fps_deriv_fps_integral: "fps_deriv (fps_integral a a0) = a"
  unfolding fps_integral_def fps_deriv_def
  by (simp add: fps_eq_iff del: of_nat_Suc)

lemma fps_integral_linear:
  "fps_integral (fps_const a * f + fps_const b * g) (a*a0 + b*b0) =
    fps_const a * fps_integral f a0 + fps_const b * fps_integral g b0"
  (is "?l = ?r")
proof-
  have "fps_deriv ?l = fps_deriv ?r" by (simp add: fps_deriv_fps_integral)
  moreover have "?l$0 = ?r$0" by (simp add: fps_integral_def)
  ultimately show ?thesis
    unfolding fps_deriv_eq_iff by auto
qed

subsection {* Composition of FPSs *}
definition fps_compose :: "('a::semiring_1) fps \<Rightarrow> 'a fps \<Rightarrow> 'a fps" (infixl "oo" 55) where
  fps_compose_def: "a oo b = Abs_fps (\<lambda>n. setsum (\<lambda>i. a$i * (b^i$n)) {0..n})"

lemma fps_compose_nth: "(a oo b)$n = setsum (\<lambda>i. a$i * (b^i$n)) {0..n}"
  by (simp add: fps_compose_def)

lemma fps_compose_X[simp]: "a oo X = (a :: ('a :: comm_ring_1) fps)"
  by (simp add: fps_ext fps_compose_def mult_delta_right setsum_delta')

lemma fps_const_compose[simp]:
  "fps_const (a::'a::{comm_ring_1}) oo b = fps_const (a)"
  by (simp add: fps_eq_iff fps_compose_nth mult_delta_left setsum_delta)

lemma numeral_compose[simp]: "(numeral k::('a::{comm_ring_1}) fps) oo b = numeral k"
  unfolding numeral_fps_const by simp

lemma neg_numeral_compose[simp]: "(neg_numeral k::('a::{comm_ring_1}) fps) oo b = neg_numeral k"
  unfolding neg_numeral_fps_const by simp

lemma X_fps_compose_startby0[simp]: "a$0 = 0 \<Longrightarrow> X oo a = (a :: ('a :: comm_ring_1) fps)"
  by (simp add: fps_eq_iff fps_compose_def mult_delta_left setsum_delta
                power_Suc not_le)


subsection {* Rules from Herbert Wilf's Generatingfunctionology*}

subsubsection {* Rule 1 *}
  (* {a_{n+k}}_0^infty Corresponds to (f - setsum (\<lambda>i. a_i * x^i))/x^h, for h>0*)

lemma fps_power_mult_eq_shift:
  "X^Suc k * Abs_fps (\<lambda>n. a (n + Suc k)) = Abs_fps a - setsum (\<lambda>i. fps_const (a i :: 'a:: comm_ring_1) * X^i) {0 .. k}" (is "?lhs = ?rhs")
proof-
  {fix n:: nat
    have "?lhs $ n = (if n < Suc k then 0 else a n)"
      unfolding X_power_mult_nth by auto
    also have "\<dots> = ?rhs $ n"
    proof(induct k)
      case 0 thus ?case by (simp add: fps_setsum_nth power_Suc)
    next
      case (Suc k)
      note th = Suc.hyps[symmetric]
      have "(Abs_fps a - setsum (\<lambda>i. fps_const (a i :: 'a) * X^i) {0 .. Suc k})$n = (Abs_fps a - setsum (\<lambda>i. fps_const (a i :: 'a) * X^i) {0 .. k} - fps_const (a (Suc k)) * X^ Suc k) $ n" by (simp add: field_simps)
      also  have "\<dots> = (if n < Suc k then 0 else a n) - (fps_const (a (Suc k)) * X^ Suc k)$n"
        using th
        unfolding fps_sub_nth by simp
      also have "\<dots> = (if n < Suc (Suc k) then 0 else a n)"
        unfolding X_power_mult_right_nth
        apply (auto simp add: not_less fps_const_def)
        apply (rule cong[of a a, OF refl])
        by arith
      finally show ?case by simp
    qed
    finally have "?lhs $ n = ?rhs $ n"  .}
  then show ?thesis by (simp add: fps_eq_iff)
qed

subsubsection{* Rule 2*}

  (* We can not reach the form of Wilf, but still near to it using rewrite rules*)
  (* If f reprents {a_n} and P is a polynomial, then
        P(xD) f represents {P(n) a_n}*)

definition "XD = op * X o fps_deriv"

lemma XD_add[simp]:"XD (a + b) = XD a + XD (b :: ('a::comm_ring_1) fps)"
  by (simp add: XD_def field_simps)

lemma XD_mult_const[simp]:"XD (fps_const (c::'a::comm_ring_1) * a) = fps_const c * XD a"
  by (simp add: XD_def field_simps)

lemma XD_linear[simp]: "XD (fps_const c * a + fps_const d * b) = fps_const c * XD a + fps_const d * XD (b :: ('a::comm_ring_1) fps)"
  by simp