src/HOL/Library/Euclidean_Space.thy

merged

(* Title:      Library/Euclidean_Space
   Author:     Amine Chaieb, University of Cambridge
*)

header {* (Real) Vectors in Euclidean space, and elementary linear algebra.*}

theory Euclidean_Space
  imports "~~/src/HOL/Decision_Procs/Dense_Linear_Order" Complex_Main 
  Finite_Cartesian_Product Glbs Infinite_Set Numeral_Type
  Inner_Product
  uses ("normarith.ML")
begin

text{* Some common special cases.*}

lemma forall_1: "(\<forall>(i::'a::{order,one}). 1 <= i \<and> i <= 1 --> P i) \<longleftrightarrow> P 1"
  by (metis order_eq_iff)
lemma forall_dimindex_1: "(\<forall>i \<in> {1..dimindex(UNIV:: 1 set)}. P i) \<longleftrightarrow> P 1"
  by (simp add: dimindex_def)

lemma forall_2: "(\<forall>(i::nat). 1 <= i \<and> i <= 2 --> P i) \<longleftrightarrow> P 1 \<and> P 2"
proof-
  have "\<And>i::nat. 1 <= i \<and> i <= 2 \<longleftrightarrow> i = 1 \<or> i = 2" by arith
  thus ?thesis by metis
qed

lemma forall_3: "(\<forall>(i::nat). 1 <= i \<and> i <= 3 --> P i) \<longleftrightarrow> P 1 \<and> P 2 \<and> P 3"
proof-
  have "\<And>i::nat. 1 <= i \<and> i <= 3 \<longleftrightarrow> i = 1 \<or> i = 2 \<or> i = 3" by arith
  thus ?thesis by metis
qed

lemma setsum_singleton[simp]: "setsum f {x} = f x" by simp
lemma setsum_1: "setsum f {(1::'a::{order,one})..1} = f 1" 
  by (simp add: atLeastAtMost_singleton)

lemma setsum_2: "setsum f {1::nat..2} = f 1 + f 2" 
  by (simp add: nat_number  atLeastAtMostSuc_conv add_commute)

lemma setsum_3: "setsum f {1::nat..3} = f 1 + f 2 + f 3" 
  by (simp add: nat_number  atLeastAtMostSuc_conv add_commute)

subsection{* Basic componentwise operations on vectors. *}

instantiation "^" :: (plus,type) plus
begin
definition  vector_add_def : "op + \<equiv> (\<lambda> x y.  (\<chi> i. (x$i) + (y$i)))" 
instance ..
end

instantiation "^" :: (times,type) times
begin
  definition vector_mult_def : "op * \<equiv> (\<lambda> x y.  (\<chi> i. (x$i) * (y$i)))" 
  instance ..
end

instantiation "^" :: (minus,type) minus begin
  definition vector_minus_def : "op - \<equiv> (\<lambda> x y.  (\<chi> i. (x$i) - (y$i)))"
instance ..
end

instantiation "^" :: (uminus,type) uminus begin
  definition vector_uminus_def : "uminus \<equiv> (\<lambda> x.  (\<chi> i. - (x$i)))"
instance ..
end
instantiation "^" :: (zero,type) zero begin
  definition vector_zero_def : "0 \<equiv> (\<chi> i. 0)" 
instance ..
end

instantiation "^" :: (one,type) one begin
  definition vector_one_def : "1 \<equiv> (\<chi> i. 1)" 
instance ..
end

instantiation "^" :: (ord,type) ord
 begin
definition vector_less_eq_def:
  "less_eq (x :: 'a ^'b) y = (ALL i : {1 .. dimindex (UNIV :: 'b set)}.
  x$i <= y$i)"
definition vector_less_def: "less (x :: 'a ^'b) y = (ALL i : {1 ..
  dimindex (UNIV :: 'b set)}. x$i < y$i)"
 
instance by (intro_classes)
end

instantiation "^" :: (scaleR, type) scaleR
begin
definition vector_scaleR_def: "scaleR = (\<lambda> r x.  (\<chi> i. scaleR r (x$i)))" 
instance ..
end

text{* Also the scalar-vector multiplication. *}

definition vector_scalar_mult:: "'a::times \<Rightarrow> 'a ^'n \<Rightarrow> 'a ^ 'n" (infixr "*s" 75)
  where "c *s x = (\<chi> i. c * (x$i))"

text{* Constant Vectors *}

definition "vec x = (\<chi> i. x)"

text{* Dot products. *}

definition dot :: "'a::{comm_monoid_add, times} ^ 'n \<Rightarrow> 'a ^ 'n \<Rightarrow> 'a" (infix "\<bullet>" 70) where
  "x \<bullet> y = setsum (\<lambda>i. x$i * y$i) {1 .. dimindex (UNIV:: 'n set)}"
lemma dot_1[simp]: "(x::'a::{comm_monoid_add, times}^1) \<bullet> y = (x$1) * (y$1)"
  by (simp add: dot_def dimindex_def)

lemma dot_2[simp]: "(x::'a::{comm_monoid_add, times}^2) \<bullet> y = (x$1) * (y$1) + (x$2) * (y$2)"
  by (simp add: dot_def dimindex_def nat_number)

lemma dot_3[simp]: "(x::'a::{comm_monoid_add, times}^3) \<bullet> y = (x$1) * (y$1) + (x$2) * (y$2) + (x$3) * (y$3)"
  by (simp add: dot_def dimindex_def nat_number)

subsection {* A naive proof procedure to lift really trivial arithmetic stuff from the basis of the vector space. *}

lemmas Cart_lambda_beta' = Cart_lambda_beta[rule_format]
method_setup vector = {*
let
  val ss1 = HOL_basic_ss addsimps [@{thm dot_def}, @{thm setsum_addf} RS sym, 
  @{thm setsum_subtractf} RS sym, @{thm setsum_right_distrib}, 
  @{thm setsum_left_distrib}, @{thm setsum_negf} RS sym]
  val ss2 = @{simpset} addsimps 
             [@{thm vector_add_def}, @{thm vector_mult_def},  
              @{thm vector_minus_def}, @{thm vector_uminus_def}, 
              @{thm vector_one_def}, @{thm vector_zero_def}, @{thm vec_def}, 
              @{thm vector_scaleR_def},
              @{thm Cart_lambda_beta'}, @{thm vector_scalar_mult_def}]
 fun vector_arith_tac ths = 
   simp_tac ss1
   THEN' (fn i => rtac @{thm setsum_cong2} i
         ORELSE rtac @{thm setsum_0'} i 
         ORELSE simp_tac (HOL_basic_ss addsimps [@{thm "Cart_eq"}]) i)
   (* THEN' TRY o clarify_tac HOL_cs  THEN' (TRY o rtac @{thm iffI}) *)
   THEN' asm_full_simp_tac (ss2 addsimps ths)
 in
  Method.thms_args (Method.SIMPLE_METHOD' o vector_arith_tac)
end
*} "Lifts trivial vector statements to real arith statements"

lemma vec_0[simp]: "vec 0 = 0" by (vector vector_zero_def)
lemma vec_1[simp]: "vec 1 = 1" by (vector vector_one_def)



text{* Obvious "component-pushing". *}

lemma vec_component: " i \<in> {1 .. dimindex (UNIV :: 'n set)} \<Longrightarrow> (vec x :: 'a ^ 'n)$i = x" 
  by (vector vec_def) 

lemma vector_add_component: 
  fixes x y :: "'a::{plus} ^ 'n"  assumes i: "i \<in> {1 .. dimindex(UNIV:: 'n set)}"
  shows "(x + y)$i = x$i + y$i"
  using i by vector

lemma vector_minus_component: 
  fixes x y :: "'a::{minus} ^ 'n"  assumes i: "i \<in> {1 .. dimindex(UNIV:: 'n set)}"
  shows "(x - y)$i = x$i - y$i"
  using i  by vector

lemma vector_mult_component: 
  fixes x y :: "'a::{times} ^ 'n"  assumes i: "i \<in> {1 .. dimindex(UNIV:: 'n set)}"
  shows "(x * y)$i = x$i * y$i"
  using i by vector

lemma vector_smult_component: 
  fixes y :: "'a::{times} ^ 'n"  assumes i: "i \<in> {1 .. dimindex(UNIV:: 'n set)}"
  shows "(c *s y)$i = c * (y$i)"
  using i by vector

lemma vector_uminus_component: 
  fixes x :: "'a::{uminus} ^ 'n"  assumes i: "i \<in> {1 .. dimindex(UNIV:: 'n set)}"
  shows "(- x)$i = - (x$i)"
  using i by vector

lemma vector_scaleR_component:
  fixes x :: "'a::scaleR ^ 'n"
  assumes i: "i \<in> {1 .. dimindex(UNIV :: 'n set)}"
  shows "(scaleR r x)$i = scaleR r (x$i)"
  using i by vector

lemma cond_component: "(if b then x else y)$i = (if b then x$i else y$i)" by vector

lemmas vector_component =
  vec_component vector_add_component vector_mult_component
  vector_smult_component vector_minus_component vector_uminus_component
  vector_scaleR_component cond_component

subsection {* Some frequently useful arithmetic lemmas over vectors. *}

instance "^" :: (semigroup_add,type) semigroup_add 
  apply (intro_classes) by (vector add_assoc)


instance "^" :: (monoid_add,type) monoid_add 
  apply (intro_classes) by vector+ 

instance "^" :: (group_add,type) group_add 
  apply (intro_classes) by (vector algebra_simps)+ 

instance "^" :: (ab_semigroup_add,type) ab_semigroup_add 
  apply (intro_classes) by (vector add_commute)

instance "^" :: (comm_monoid_add,type) comm_monoid_add
  apply (intro_classes) by vector

instance "^" :: (ab_group_add,type) ab_group_add 
  apply (intro_classes) by vector+

instance "^" :: (cancel_semigroup_add,type) cancel_semigroup_add 
  apply (intro_classes)
  by (vector Cart_eq)+

instance "^" :: (cancel_ab_semigroup_add,type) cancel_ab_semigroup_add
  apply (intro_classes)
  by (vector Cart_eq)

instance "^" :: (real_vector, type) real_vector
  by default (vector scaleR_left_distrib scaleR_right_distrib)+

instance "^" :: (semigroup_mult,type) semigroup_mult 
  apply (intro_classes) by (vector mult_assoc)

instance "^" :: (monoid_mult,type) monoid_mult 
  apply (intro_classes) by vector+

instance "^" :: (ab_semigroup_mult,type) ab_semigroup_mult 
  apply (intro_classes) by (vector mult_commute)

instance "^" :: (ab_semigroup_idem_mult,type) ab_semigroup_idem_mult 
  apply (intro_classes) by (vector mult_idem)

instance "^" :: (comm_monoid_mult,type) comm_monoid_mult 
  apply (intro_classes) by vector

fun vector_power :: "('a::{one,times} ^'n) \<Rightarrow> nat \<Rightarrow> 'a^'n" where
  "vector_power x 0 = 1"
  | "vector_power x (Suc n) = x * vector_power x n"

instantiation "^" :: (recpower,type) recpower 
begin
  definition vec_power_def: "op ^ \<equiv> vector_power"
  instance 
  apply (intro_classes) by (simp_all add: vec_power_def) 
end

instance "^" :: (semiring,type) semiring
  apply (intro_classes) by (vector ring_simps)+

instance "^" :: (semiring_0,type) semiring_0
  apply (intro_classes) by (vector ring_simps)+
instance "^" :: (semiring_1,type) semiring_1
  apply (intro_classes) apply vector using dimindex_ge_1 by auto 
instance "^" :: (comm_semiring,type) comm_semiring
  apply (intro_classes) by (vector ring_simps)+

instance "^" :: (comm_semiring_0,type) comm_semiring_0 by (intro_classes) 
instance "^" :: (cancel_comm_monoid_add, type) cancel_comm_monoid_add ..
instance "^" :: (semiring_0_cancel,type) semiring_0_cancel by (intro_classes) 
instance "^" :: (comm_semiring_0_cancel,type) comm_semiring_0_cancel by (intro_classes) 
instance "^" :: (ring,type) ring by (intro_classes) 
instance "^" :: (semiring_1_cancel,type) semiring_1_cancel by (intro_classes) 
instance "^" :: (comm_semiring_1,type) comm_semiring_1 by (intro_classes)

instance "^" :: (ring_1,type) ring_1 ..

instance "^" :: (real_algebra,type) real_algebra
  apply intro_classes
  apply (simp_all add: vector_scaleR_def ring_simps)
  apply vector
  apply vector
  done

instance "^" :: (real_algebra_1,type) real_algebra_1 ..

lemma of_nat_index: 
  "i\<in>{1 .. dimindex (UNIV :: 'n set)} \<Longrightarrow> (of_nat n :: 'a::semiring_1 ^'n)$i = of_nat n"
  apply (induct n)
  apply vector
  apply vector
  done
lemma zero_index[simp]: 
  "i\<in>{1 .. dimindex (UNIV :: 'n set)} \<Longrightarrow> (0 :: 'a::zero ^'n)$i = 0" by vector

lemma one_index[simp]: 
  "i\<in>{1 .. dimindex (UNIV :: 'n set)} \<Longrightarrow> (1 :: 'a::one ^'n)$i = 1" by vector

lemma one_plus_of_nat_neq_0: "(1::'a::semiring_char_0) + of_nat n \<noteq> 0"
proof-
  have "(1::'a) + of_nat n = 0 \<longleftrightarrow> of_nat 1 + of_nat n = (of_nat 0 :: 'a)" by simp
  also have "\<dots> \<longleftrightarrow> 1 + n = 0" by (simp only: of_nat_add[symmetric] of_nat_eq_iff) 
  finally show ?thesis by simp 
qed

instance "^" :: (semiring_char_0,type) semiring_char_0 
proof (intro_classes) 
  fix m n ::nat
  show "(of_nat m :: 'a^'b) = of_nat n \<longleftrightarrow> m = n"
  proof(induct m arbitrary: n)
    case 0 thus ?case apply vector 
      apply (induct n,auto simp add: ring_simps)
      using dimindex_ge_1 apply auto
      apply vector
      by (auto simp add: of_nat_index one_plus_of_nat_neq_0)
  next
    case (Suc n m)
    thus ?case  apply vector
      apply (induct m, auto simp add: ring_simps of_nat_index zero_index)
      using dimindex_ge_1 apply simp apply blast
      apply (simp add: one_plus_of_nat_neq_0)
      using dimindex_ge_1 apply simp apply blast
      apply (simp add: vector_component one_index of_nat_index)
      apply (simp only: of_nat.simps(2)[where ?'a = 'a, symmetric] of_nat_eq_iff)
      using  dimindex_ge_1 apply simp apply blast
      apply (simp add: vector_component one_index of_nat_index)
      apply (simp only: of_nat.simps(2)[where ?'a = 'a, symmetric] of_nat_eq_iff)
      using dimindex_ge_1 apply simp apply blast
      apply (simp add: vector_component one_index of_nat_index)
      done
  qed
qed

instance "^" :: (comm_ring_1,type) comm_ring_1 by intro_classes
instance "^" :: (ring_char_0,type) ring_char_0 by intro_classes

lemma vector_smult_assoc: "a *s (b *s x) = ((a::'a::semigroup_mult) * b) *s x"  
  by (vector mult_assoc)
lemma vector_sadd_rdistrib: "((a::'a::semiring) + b) *s x = a *s x + b *s x" 
  by (vector ring_simps)
lemma vector_add_ldistrib: "(c::'a::semiring) *s (x + y) = c *s x + c *s y" 
  by (vector ring_simps)
lemma vector_smult_lzero[simp]: "(0::'a::mult_zero) *s x = 0" by vector
lemma vector_smult_lid[simp]: "(1::'a::monoid_mult) *s x = x" by vector
lemma vector_ssub_ldistrib: "(c::'a::ring) *s (x - y) = c *s x - c *s y" 
  by (vector ring_simps)
lemma vector_smult_rneg: "(c::'a::ring) *s -x = -(c *s x)" by vector
lemma vector_smult_lneg: "- (c::'a::ring) *s x = -(c *s x)" by vector
lemma vector_sneg_minus1: "-x = (- (1::'a::ring_1)) *s x" by vector
lemma vector_smult_rzero[simp]: "c *s 0 = (0::'a::mult_zero ^ 'n)" by vector
lemma vector_sub_rdistrib: "((a::'a::ring) - b) *s x = a *s x - b *s x" 
  by (vector ring_simps)

lemma vec_eq[simp]: "(vec m = vec n) \<longleftrightarrow> (m = n)" 
  apply (auto simp add: vec_def Cart_eq vec_component Cart_lambda_beta )
  using dimindex_ge_1 apply auto done

subsection {* Square root of sum of squares *}

definition
  "setL2 f A = sqrt (\<Sum>i\<in>A. (f i)\<twosuperior>)"

lemma setL2_cong:
  "\<lbrakk>A = B; \<And>x. x \<in> B \<Longrightarrow> f x = g x\<rbrakk> \<Longrightarrow> setL2 f A = setL2 g B"
  unfolding setL2_def by simp

lemma strong_setL2_cong:
  "\<lbrakk>A = B; \<And>x. x \<in> B =simp=> f x = g x\<rbrakk> \<Longrightarrow> setL2 f A = setL2 g B"
  unfolding setL2_def simp_implies_def by simp

lemma setL2_infinite [simp]: "\<not> finite A \<Longrightarrow> setL2 f A = 0"
  unfolding setL2_def by simp

lemma setL2_empty [simp]: "setL2 f {} = 0"
  unfolding setL2_def by simp

lemma setL2_insert [simp]:
  "\<lbrakk>finite F; a \<notin> F\<rbrakk> \<Longrightarrow>
    setL2 f (insert a F) = sqrt ((f a)\<twosuperior> + (setL2 f F)\<twosuperior>)"
  unfolding setL2_def by (simp add: setsum_nonneg)

lemma setL2_nonneg [simp]: "0 \<le> setL2 f A"
  unfolding setL2_def by (simp add: setsum_nonneg)

lemma setL2_0': "\<forall>a\<in>A. f a = 0 \<Longrightarrow> setL2 f A = 0"
  unfolding setL2_def by simp

lemma setL2_mono:
  assumes "\<And>i. i \<in> K \<Longrightarrow> f i \<le> g i"
  assumes "\<And>i. i \<in> K \<Longrightarrow> 0 \<le> f i"
  shows "setL2 f K \<le> setL2 g K"
  unfolding setL2_def
  by (simp add: setsum_nonneg setsum_mono power_mono prems)

lemma setL2_right_distrib:
  "0 \<le> r \<Longrightarrow> r * setL2 f A = setL2 (\<lambda>x. r * f x) A"
  unfolding setL2_def
  apply (simp add: power_mult_distrib)
  apply (simp add: setsum_right_distrib [symmetric])
  apply (simp add: real_sqrt_mult setsum_nonneg)
  done

lemma setL2_left_distrib:
  "0 \<le> r \<Longrightarrow> setL2 f A * r = setL2 (\<lambda>x. f x * r) A"
  unfolding setL2_def
  apply (simp add: power_mult_distrib)
  apply (simp add: setsum_left_distrib [symmetric])
  apply (simp add: real_sqrt_mult setsum_nonneg)
  done

lemma setsum_nonneg_eq_0_iff:
  fixes f :: "'a \<Rightarrow> 'b::pordered_ab_group_add"
  shows "\<lbrakk>finite A; \<forall>x\<in>A. 0 \<le> f x\<rbrakk> \<Longrightarrow> setsum f A = 0 \<longleftrightarrow> (\<forall>x\<in>A. f x = 0)"
  apply (induct set: finite, simp)
  apply (simp add: add_nonneg_eq_0_iff setsum_nonneg)
  done

lemma setL2_eq_0_iff: "finite A \<Longrightarrow> setL2 f A = 0 \<longleftrightarrow> (\<forall>x\<in>A. f x = 0)"
  unfolding setL2_def
  by (simp add: setsum_nonneg setsum_nonneg_eq_0_iff)

lemma setL2_triangle_ineq:
  shows "setL2 (\<lambda>i. f i + g i) A \<le> setL2 f A + setL2 g A"
proof (cases "finite A")
  case False
  thus ?thesis by simp
next
  case True
  thus ?thesis
  proof (induct set: finite)
    case empty
    show ?case by simp
  next
    case (insert x F)
    hence "sqrt ((f x + g x)\<twosuperior> + (setL2 (\<lambda>i. f i + g i) F)\<twosuperior>) \<le>
           sqrt ((f x + g x)\<twosuperior> + (setL2 f F + setL2 g F)\<twosuperior>)"
      by (intro real_sqrt_le_mono add_left_mono power_mono insert
                setL2_nonneg add_increasing zero_le_power2)
    also have
      "\<dots> \<le> sqrt ((f x)\<twosuperior> + (setL2 f F)\<twosuperior>) + sqrt ((g x)\<twosuperior> + (setL2 g F)\<twosuperior>)"
      by (rule real_sqrt_sum_squares_triangle_ineq)
    finally show ?case
      using insert by simp
  qed
qed

lemma sqrt_sum_squares_le_sum:
  "\<lbrakk>0 \<le> x; 0 \<le> y\<rbrakk> \<Longrightarrow> sqrt (x\<twosuperior> + y\<twosuperior>) \<le> x + y"
  apply (rule power2_le_imp_le)
  apply (simp add: power2_sum)
  apply (simp add: mult_nonneg_nonneg)
  apply (simp add: add_nonneg_nonneg)
  done

lemma setL2_le_setsum [rule_format]:
  "(\<forall>i\<in>A. 0 \<le> f i) \<longrightarrow> setL2 f A \<le> setsum f A"
  apply (cases "finite A")
  apply (induct set: finite)
  apply simp
  apply clarsimp
  apply (erule order_trans [OF sqrt_sum_squares_le_sum])
  apply simp
  apply simp
  apply simp
  done

lemma sqrt_sum_squares_le_sum_abs: "sqrt (x\<twosuperior> + y\<twosuperior>) \<le> \<bar>x\<bar> + \<bar>y\<bar>"
  apply (rule power2_le_imp_le)
  apply (simp add: power2_sum)
  apply (simp add: mult_nonneg_nonneg)
  apply (simp add: add_nonneg_nonneg)
  done

lemma setL2_le_setsum_abs: "setL2 f A \<le> (\<Sum>i\<in>A. \<bar>f i\<bar>)"
  apply (cases "finite A")
  apply (induct set: finite)
  apply simp
  apply simp
  apply (rule order_trans [OF sqrt_sum_squares_le_sum_abs])
  apply simp
  apply simp
  done

lemma setL2_mult_ineq_lemma:
  fixes a b c d :: real
  shows "2 * (a * c) * (b * d) \<le> a\<twosuperior> * d\<twosuperior> + b\<twosuperior> * c\<twosuperior>"
proof -
  have "0 \<le> (a * d - b * c)\<twosuperior>" by simp
  also have "\<dots> = a\<twosuperior> * d\<twosuperior> + b\<twosuperior> * c\<twosuperior> - 2 * (a * d) * (b * c)"
    by (simp only: power2_diff power_mult_distrib)
  also have "\<dots> = a\<twosuperior> * d\<twosuperior> + b\<twosuperior> * c\<twosuperior> - 2 * (a * c) * (b * d)"
    by simp
  finally show "2 * (a * c) * (b * d) \<le> a\<twosuperior> * d\<twosuperior> + b\<twosuperior> * c\<twosuperior>"
    by simp
qed

lemma setL2_mult_ineq: "(\<Sum>i\<in>A. \<bar>f i\<bar> * \<bar>g i\<bar>) \<le> setL2 f A * setL2 g A"
  apply (cases "finite A")
  apply (induct set: finite)
  apply simp
  apply (rule power2_le_imp_le, simp)
  apply (rule order_trans)
  apply (rule power_mono)
  apply (erule add_left_mono)
  apply (simp add: add_nonneg_nonneg mult_nonneg_nonneg setsum_nonneg)
  apply (simp add: power2_sum)
  apply (simp add: power_mult_distrib)
  apply (simp add: right_distrib left_distrib)
  apply (rule ord_le_eq_trans)
  apply (rule setL2_mult_ineq_lemma)
  apply simp
  apply (intro mult_nonneg_nonneg setL2_nonneg)
  apply simp
  done

lemma member_le_setL2: "\<lbrakk>finite A; i \<in> A\<rbrakk> \<Longrightarrow> f i \<le> setL2 f A"
  apply (rule_tac s="insert i (A - {i})" and t="A" in subst)
  apply fast
  apply (subst setL2_insert)
  apply simp
  apply simp
  apply simp
  done

subsection {* Norms *}

instantiation "^" :: (real_normed_vector, type) real_normed_vector
begin

definition vector_norm_def:
  "norm (x::'a^'b) = setL2 (\<lambda>i. norm (x$i)) {1 .. dimindex (UNIV:: 'b set)}"

definition vector_sgn_def:
  "sgn (x::'a^'b) = scaleR (inverse (norm x)) x"

instance proof
  fix a :: real and x y :: "'a ^ 'b"
  show "0 \<le> norm x"
    unfolding vector_norm_def
    by (rule setL2_nonneg)
  show "norm x = 0 \<longleftrightarrow> x = 0"
    unfolding vector_norm_def
    by (simp add: setL2_eq_0_iff Cart_eq)
  show "norm (x + y) \<le> norm x + norm y"
    unfolding vector_norm_def
    apply (rule order_trans [OF _ setL2_triangle_ineq])
    apply (rule setL2_mono)
    apply (simp add: vector_component norm_triangle_ineq)
    apply simp
    done
  show "norm (scaleR a x) = \<bar>a\<bar> * norm x"
    unfolding vector_norm_def
    by (simp add: vector_component norm_scaleR setL2_right_distrib
             cong: strong_setL2_cong)
  show "sgn x = scaleR (inverse (norm x)) x"
    by (rule vector_sgn_def)
qed

end

subsection {* Inner products *}

instantiation "^" :: (real_inner, type) real_inner
begin

definition vector_inner_def:
  "inner x y = setsum (\<lambda>i. inner (x$i) (y$i)) {1 .. dimindex(UNIV::'b set)}"

instance proof
  fix r :: real and x y z :: "'a ^ 'b"
  show "inner x y = inner y x"
    unfolding vector_inner_def
    by (simp add: inner_commute)
  show "inner (x + y) z = inner x z + inner y z"
    unfolding vector_inner_def
    by (vector inner_left_distrib)
  show "inner (scaleR r x) y = r * inner x y"
    unfolding vector_inner_def
    by (vector inner_scaleR_left)
  show "0 \<le> inner x x"
    unfolding vector_inner_def
    by (simp add: setsum_nonneg)
  show "inner x x = 0 \<longleftrightarrow> x = 0"
    unfolding vector_inner_def
    by (simp add: Cart_eq setsum_nonneg_eq_0_iff)
  show "norm x = sqrt (inner x x)"
    unfolding vector_inner_def vector_norm_def setL2_def
    by (simp add: power2_norm_eq_inner)
qed

end

subsection{* Properties of the dot product.  *}

lemma dot_sym: "(x::'a:: {comm_monoid_add, ab_semigroup_mult} ^ 'n) \<bullet> y = y \<bullet> x" 
  by (vector mult_commute)
lemma dot_ladd: "((x::'a::ring ^ 'n) + y) \<bullet> z = (x \<bullet> z) + (y \<bullet> z)"
  by (vector ring_simps)
lemma dot_radd: "x \<bullet> (y + (z::'a::ring ^ 'n)) = (x \<bullet> y) + (x \<bullet> z)" 
  by (vector ring_simps)
lemma dot_lsub: "((x::'a::ring ^ 'n) - y) \<bullet> z = (x \<bullet> z) - (y \<bullet> z)" 
  by (vector ring_simps)
lemma dot_rsub: "(x::'a::ring ^ 'n) \<bullet> (y - z) = (x \<bullet> y) - (x \<bullet> z)" 
  by (vector ring_simps)
lemma dot_lmult: "(c *s x) \<bullet> y = (c::'a::ring) * (x \<bullet> y)" by (vector ring_simps)
lemma dot_rmult: "x \<bullet> (c *s y) = (c::'a::comm_ring) * (x \<bullet> y)" by (vector ring_simps)
lemma dot_lneg: "(-x) \<bullet> (y::'a::ring ^ 'n) = -(x \<bullet> y)" by vector
lemma dot_rneg: "(x::'a::ring ^ 'n) \<bullet> (-y) = -(x \<bullet> y)" by vector
lemma dot_lzero[simp]: "0 \<bullet> x = (0::'a::{comm_monoid_add, mult_zero})" by vector
lemma dot_rzero[simp]: "x \<bullet> 0 = (0::'a::{comm_monoid_add, mult_zero})" by vector
lemma dot_pos_le[simp]: "(0::'a\<Colon>ordered_ring_strict) <= x \<bullet> x"
  by (simp add: dot_def setsum_nonneg)

lemma setsum_squares_eq_0_iff: assumes fS: "finite F" and fp: "\<forall>x \<in> F. f x \<ge> (0 ::'a::pordered_ab_group_add)" shows "setsum f F = 0 \<longleftrightarrow> (ALL x:F. f x = 0)"
using fS fp setsum_nonneg[OF fp]
proof (induct set: finite)
  case empty thus ?case by simp
next
  case (insert x F)
  from insert.prems have Fx: "f x \<ge> 0" and Fp: "\<forall> a \<in> F. f a \<ge> 0" by simp_all
  from insert.hyps Fp setsum_nonneg[OF Fp]
  have h: "setsum f F = 0 \<longleftrightarrow> (\<forall>a \<in>F. f a = 0)" by metis
  from sum_nonneg_eq_zero_iff[OF Fx  setsum_nonneg[OF Fp]] insert.hyps(1,2)
  show ?case by (simp add: h)
qed

lemma dot_eq_0: "x \<bullet> x = 0 \<longleftrightarrow> (x::'a::{ordered_ring_strict,ring_no_zero_divisors} ^ 'n) = 0"
proof-
  {assume f: "finite (UNIV :: 'n set)"
    let ?S = "{Suc 0 .. card (UNIV :: 'n set)}"
    have fS: "finite ?S" using f by simp
    have fp: "\<forall> i\<in> ?S. x$i * x$i>= 0" by simp
    have ?thesis by (vector dimindex_def f setsum_squares_eq_0_iff[OF fS fp])}
  moreover
  {assume "\<not> finite (UNIV :: 'n set)" then have ?thesis by (vector dimindex_def)}
  ultimately show ?thesis by metis
qed

lemma dot_pos_lt[simp]: "(0 < x \<bullet> x) \<longleftrightarrow> (x::'a::{ordered_ring_strict,ring_no_zero_divisors} ^ 'n) \<noteq> 0" using dot_eq_0[of x] dot_pos_le[of x] 
  by (auto simp add: le_less) 

subsection{* The collapse of the general concepts to dimension one. *}

lemma vector_one: "(x::'a ^1) = (\<chi> i. (x$1))"
  by (vector dimindex_def)

lemma forall_one: "(\<forall>(x::'a ^1). P x) \<longleftrightarrow> (\<forall>x. P(\<chi> i. x))"
  apply auto
  apply (erule_tac x= "x$1" in allE)
  apply (simp only: vector_one[symmetric])
  done

lemma norm_vector_1: "norm (x :: _^1) = norm (x$1)"
  by (simp add: vector_norm_def dimindex_def)

lemma norm_real: "norm(x::real ^ 1) = abs(x$1)" 
  by (simp add: norm_vector_1)

text{* Metric *}

text {* FIXME: generalize to arbitrary @{text real_normed_vector} types *}
definition dist:: "real ^ 'n \<Rightarrow> real ^ 'n \<Rightarrow> real" where 
  "dist x y = norm (x - y)"

lemma dist_real: "dist(x::real ^ 1) y = abs((x$1) - (y$1))"
  using dimindex_ge_1[of "UNIV :: 1 set"]
  by (auto simp add: norm_real dist_def vector_component Cart_lambda_beta[where ?'a = "1"] )

subsection {* A connectedness or intermediate value lemma with several applications. *}

lemma connected_real_lemma:
  fixes f :: "real \<Rightarrow> real ^ 'n"
  assumes ab: "a \<le> b" and fa: "f a \<in> e1" and fb: "f b \<in> e2"
  and dst: "\<And>e x. a <= x \<Longrightarrow> x <= b \<Longrightarrow> 0 < e ==> \<exists>d > 0. \<forall>y. abs(y - x) < d \<longrightarrow> dist(f y) (f x) < e"
  and e1: "\<forall>y \<in> e1. \<exists>e > 0. \<forall>y'. dist y' y < e \<longrightarrow> y' \<in> e1"
  and e2: "\<forall>y \<in> e2. \<exists>e > 0. \<forall>y'. dist y' y < e \<longrightarrow> y' \<in> e2"
  and e12: "~(\<exists>x \<ge> a. x <= b \<and> f x \<in> e1 \<and> f x \<in> e2)"
  shows "\<exists>x \<ge> a. x <= b \<and> f x \<notin> e1 \<and> f x \<notin> e2" (is "\<exists> x. ?P x")
proof-
  let ?S = "{c. \<forall>x \<ge> a. x <= c \<longrightarrow> f x \<in> e1}"
  have Se: " \<exists>x. x \<in> ?S" apply (rule exI[where x=a]) by (auto simp add: fa) 
  have Sub: "\<exists>y. isUb UNIV ?S y" 
    apply (rule exI[where x= b])
    using ab fb e12 by (auto simp add: isUb_def setle_def)  
  from reals_complete[OF Se Sub] obtain l where 
    l: "isLub UNIV ?S l"by blast
  have alb: "a \<le> l" "l \<le> b" using l ab fa fb e12
    apply (auto simp add: isLub_def leastP_def isUb_def setle_def setge_def)    
    by (metis linorder_linear)
  have ale1: "\<forall>z \<ge> a. z < l \<longrightarrow> f z \<in> e1" using l
    apply (auto simp add: isLub_def leastP_def isUb_def setle_def setge_def)
    by (metis linorder_linear not_le)
    have th1: "\<And>z x e d :: real. z <= x + e \<Longrightarrow> e < d ==> z < x \<or> abs(z - x) < d" by arith
    have th2: "\<And>e x:: real. 0 < e ==> ~(x + e <= x)" by arith
    have th3: "\<And>d::real. d > 0 \<Longrightarrow> \<exists>e > 0. e < d" by dlo
    {assume le2: "f l \<in> e2"
      from le2 fa fb e12 alb have la: "l \<noteq> a" by metis
      hence lap: "l - a > 0" using alb by arith
      from e2[rule_format, OF le2] obtain e where 
	e: "e > 0" "\<forall>y. dist y (f l) < e \<longrightarrow> y \<in> e2" by metis
      from dst[OF alb e(1)] obtain d where 
	d: "d > 0" "\<forall>y. \<bar>y - l\<bar> < d \<longrightarrow> dist (f y) (f l) < e" by metis
      have "\<exists>d'. d' < d \<and> d' >0 \<and> l - d' > a" using lap d(1) 
	apply ferrack by arith
      then obtain d' where d': "d' > 0" "d' < d" "l - d' > a" by metis
      from d e have th0: "\<forall>y. \<bar>y - l\<bar> < d \<longrightarrow> f y \<in> e2" by metis
      from th0[rule_format, of "l - d'"] d' have "f (l - d') \<in> e2" by auto
      moreover
      have "f (l - d') \<in> e1" using ale1[rule_format, of "l -d'"] d' by auto
      ultimately have False using e12 alb d' by auto}
    moreover
    {assume le1: "f l \<in> e1"
    from le1 fa fb e12 alb have lb: "l \<noteq> b" by metis
      hence blp: "b - l > 0" using alb by arith
      from e1[rule_format, OF le1] obtain e where 
	e: "e > 0" "\<forall>y. dist y (f l) < e \<longrightarrow> y \<in> e1" by metis
      from dst[OF alb e(1)] obtain d where 
	d: "d > 0" "\<forall>y. \<bar>y - l\<bar> < d \<longrightarrow> dist (f y) (f l) < e" by metis
      have "\<exists>d'. d' < d \<and> d' >0" using d(1) by dlo 
      then obtain d' where d': "d' > 0" "d' < d" by metis
      from d e have th0: "\<forall>y. \<bar>y - l\<bar> < d \<longrightarrow> f y \<in> e1" by auto
      hence "\<forall>y. l \<le> y \<and> y \<le> l + d' \<longrightarrow> f y \<in> e1" using d' by auto
      with ale1 have "\<forall>y. a \<le> y \<and> y \<le> l + d' \<longrightarrow> f y \<in> e1" by auto
      with l d' have False 
	by (auto simp add: isLub_def isUb_def setle_def setge_def leastP_def) }
    ultimately show ?thesis using alb by metis
qed

text{* One immediately useful corollary is the existence of square roots! --- Should help to get rid of all the development of square-root for reals as a special case @{typ "real^1"} *}

lemma square_bound_lemma: "(x::real) < (1 + x) * (1 + x)"
proof-
  have "(x + 1/2)^2 + 3/4 > 0" using zero_le_power2[of "x+1/2"] by arith 
  thus ?thesis by (simp add: ring_simps power2_eq_square)
qed

lemma square_continuous: "0 < (e::real) ==> \<exists>d. 0 < d \<and> (\<forall>y. abs(y - x) < d \<longrightarrow> abs(y * y - x * x) < e)"
  using isCont_power[OF isCont_ident, of 2, unfolded isCont_def LIM_def, rule_format, of e x] apply (auto simp add: power2_eq_square)
  apply (rule_tac x="s" in exI)
  apply auto
  apply (erule_tac x=y in allE)
  apply auto
  done

lemma real_le_lsqrt: "0 <= x \<Longrightarrow> 0 <= y \<Longrightarrow> x <= y^2 ==> sqrt x <= y"
  using real_sqrt_le_iff[of x "y^2"] by simp

lemma real_le_rsqrt: "x^2 \<le> y \<Longrightarrow> x \<le> sqrt y"
  using real_sqrt_le_mono[of "x^2" y] by simp

lemma real_less_rsqrt: "x^2 < y \<Longrightarrow> x < sqrt y"
  using real_sqrt_less_mono[of "x^2" y] by simp

lemma sqrt_even_pow2: assumes n: "even n" 
  shows "sqrt(2 ^ n) = 2 ^ (n div 2)"
proof-
  from n obtain m where m: "n = 2*m" unfolding even_nat_equiv_def2 
    by (auto simp add: nat_number) 
  from m  have "sqrt(2 ^ n) = sqrt ((2 ^ m) ^ 2)"
    by (simp only: power_mult[symmetric] mult_commute)
  then show ?thesis  using m by simp 
qed

lemma real_div_sqrt: "0 <= x ==> x / sqrt(x) = sqrt(x)"
  apply (cases "x = 0", simp_all)
  using sqrt_divide_self_eq[of x]
  apply (simp add: inverse_eq_divide real_sqrt_ge_0_iff field_simps)
  done

text{* Hence derive more interesting properties of the norm. *}

lemma norm_0[simp]: "norm (0::real ^ 'n) = 0"
  by (rule norm_zero)

lemma norm_mul[simp]: "norm(a *s x) = abs(a) * norm x"
  by (simp add: vector_norm_def vector_component setL2_right_distrib
           abs_mult cong: strong_setL2_cong)
lemma norm_eq_0_dot: "(norm x = 0) \<longleftrightarrow> (x \<bullet> x = (0::real))"
  by (simp add: vector_norm_def dot_def setL2_def power2_eq_square)
lemma real_vector_norm_def: "norm x = sqrt (x \<bullet> x)"
  by (simp add: vector_norm_def setL2_def dot_def power2_eq_square)
lemma norm_pow_2: "norm x ^ 2 = x \<bullet> x"
  by (simp add: real_vector_norm_def)
lemma norm_eq_0_imp: "norm x = 0 ==> x = (0::real ^'n)" by (metis norm_eq_zero)
lemma vector_mul_eq_0[simp]: "(a *s x = 0) \<longleftrightarrow> a = (0::'a::idom) \<or> x = 0"
  by vector
lemma vector_mul_lcancel[simp]: "a *s x = a *s y \<longleftrightarrow> a = (0::real) \<or> x = y"
  by (metis eq_iff_diff_eq_0 vector_mul_eq_0 vector_ssub_ldistrib)
lemma vector_mul_rcancel[simp]: "a *s x = b *s x \<longleftrightarrow> (a::real) = b \<or> x = 0"
  by (metis eq_iff_diff_eq_0 vector_mul_eq_0 vector_sub_rdistrib)
lemma vector_mul_lcancel_imp: "a \<noteq> (0::real) ==>  a *s x = a *s y ==> (x = y)"
  by (metis vector_mul_lcancel)
lemma vector_mul_rcancel_imp: "x \<noteq> 0 \<Longrightarrow> (a::real) *s x = b *s x ==> a = b"
  by (metis vector_mul_rcancel)
lemma norm_cauchy_schwarz: "x \<bullet> y <= norm x * norm y"
proof-
  {assume "norm x = 0"
    hence ?thesis by (simp add: dot_lzero dot_rzero)}
  moreover
  {assume "norm y = 0" 
    hence ?thesis by (simp add: dot_lzero dot_rzero)}
  moreover
  {assume h: "norm x \<noteq> 0" "norm y \<noteq> 0"
    let ?z = "norm y *s x - norm x *s y"
    from h have p: "norm x * norm y > 0" by (metis norm_ge_zero le_less zero_compare_simps)
    from dot_pos_le[of ?z]
    have "(norm x * norm y) * (x \<bullet> y) \<le> norm x ^2 * norm y ^2"
      apply (simp add: dot_rsub dot_lsub dot_lmult dot_rmult ring_simps)
      by (simp add: norm_pow_2[symmetric] power2_eq_square dot_sym)
    hence "x\<bullet>y \<le> (norm x ^2 * norm y ^2) / (norm x * norm y)" using p
      by (simp add: field_simps)
    hence ?thesis using h by (simp add: power2_eq_square)}
  ultimately show ?thesis by metis
qed

lemma norm_cauchy_schwarz_abs: "\<bar>x \<bullet> y\<bar> \<le> norm x * norm y"
  using norm_cauchy_schwarz[of x y] norm_cauchy_schwarz[of x "-y"]
  by (simp add: real_abs_def dot_rneg)

lemma norm_triangle_sub: "norm (x::real ^'n) <= norm(y) + norm(x - y)"
  using norm_triangle_ineq[of "y" "x - y"] by (simp add: ring_simps)
lemma norm_triangle_le: "norm(x::real ^'n) + norm y <= e ==> norm(x + y) <= e"
  by (metis order_trans norm_triangle_ineq)
lemma norm_triangle_lt: "norm(x::real ^'n) + norm(y) < e ==> norm(x + y) < e"
  by (metis basic_trans_rules(21) norm_triangle_ineq)

lemma component_le_norm: "i \<in> {1 .. dimindex(UNIV :: 'n set)} ==> \<bar>x$i\<bar> <= norm (x::real ^ 'n)"
  apply (simp add: vector_norm_def)
  apply (rule member_le_setL2, simp_all)
  done

lemma norm_bound_component_le: "norm(x::real ^ 'n) <= e
                ==> \<forall>i \<in> {1 .. dimindex(UNIV:: 'n set)}. \<bar>x$i\<bar> <= e"
  by (metis component_le_norm order_trans)

lemma norm_bound_component_lt: "norm(x::real ^ 'n) < e
                ==> \<forall>i \<in> {1 .. dimindex(UNIV:: 'n set)}. \<bar>x$i\<bar> < e"
  by (metis component_le_norm basic_trans_rules(21))

lemma norm_le_l1: "norm (x:: real ^'n) <= setsum(\<lambda>i. \<bar>x$i\<bar>) {1..dimindex(UNIV::'n set)}"
  by (simp add: vector_norm_def setL2_le_setsum)

lemma real_abs_norm[simp]: "\<bar> norm x\<bar> = norm (x :: real ^'n)" 
  by (rule abs_norm_cancel)
lemma real_abs_sub_norm: "\<bar>norm(x::real ^'n) - norm y\<bar> <= norm(x - y)"
  by (rule norm_triangle_ineq3)
lemma norm_le: "norm(x::real ^ 'n) <= norm(y) \<longleftrightarrow> x \<bullet> x <= y \<bullet> y"
  by (simp add: real_vector_norm_def)
lemma norm_lt: "norm(x::real ^'n) < norm(y) \<longleftrightarrow> x \<bullet> x < y \<bullet> y"
  by (simp add: real_vector_norm_def)
lemma norm_eq: "norm (x::real ^'n) = norm y \<longleftrightarrow> x \<bullet> x = y \<bullet> y"
  by (simp add: order_eq_iff norm_le)
lemma norm_eq_1: "norm(x::real ^ 'n) = 1 \<longleftrightarrow> x \<bullet> x = 1"
  by (simp add: real_vector_norm_def)

text{* Squaring equations and inequalities involving norms.  *}

lemma dot_square_norm: "x \<bullet> x = norm(x)^2"
  by (simp add: real_vector_norm_def  dot_pos_le )

lemma norm_eq_square: "norm(x) = a \<longleftrightarrow> 0 <= a \<and> x \<bullet> x = a^2"
  by (auto simp add: real_vector_norm_def)

lemma real_abs_le_square_iff: "\<bar>x\<bar> \<le> \<bar>y\<bar> \<longleftrightarrow> (x::real)^2 \<le> y^2"
proof-
  have "x^2 \<le> y^2 \<longleftrightarrow> (x -y) * (y + x) \<le> 0" by (simp add: ring_simps power2_eq_square)
  also have "\<dots> \<longleftrightarrow> \<bar>x\<bar> \<le> \<bar>y\<bar>" apply (simp add: zero_compare_simps real_abs_def not_less) by arith
finally show ?thesis ..
qed

lemma norm_le_square: "norm(x) <= a \<longleftrightarrow> 0 <= a \<and> x \<bullet> x <= a^2"
  apply (simp add: dot_square_norm real_abs_le_square_iff[symmetric])
  using norm_ge_zero[of x]
  apply arith
  done

lemma norm_ge_square: "norm(x) >= a \<longleftrightarrow> a <= 0 \<or> x \<bullet> x >= a ^ 2" 
  apply (simp add: dot_square_norm real_abs_le_square_iff[symmetric])
  using norm_ge_zero[of x]
  apply arith
  done

lemma norm_lt_square: "norm(x) < a \<longleftrightarrow> 0 < a \<and> x \<bullet> x < a^2"
  by (metis not_le norm_ge_square)
lemma norm_gt_square: "norm(x) > a \<longleftrightarrow> a < 0 \<or> x \<bullet> x > a^2"
  by (metis norm_le_square not_less)

text{* Dot product in terms of the norm rather than conversely. *}

lemma dot_norm: "x \<bullet> y = (norm(x + y) ^2 - norm x ^ 2 - norm y ^ 2) / 2"
  by (simp add: norm_pow_2 dot_ladd dot_radd dot_sym)

lemma dot_norm_neg: "x \<bullet> y = ((norm x ^ 2 + norm y ^ 2) - norm(x - y) ^ 2) / 2"
  by (simp add: norm_pow_2 dot_ladd dot_radd dot_lsub dot_rsub dot_sym)


text{* Equality of vectors in terms of @{term "op \<bullet>"} products.    *}

lemma vector_eq: "(x:: real ^ 'n) = y \<longleftrightarrow> x \<bullet> x = x \<bullet> y\<and> y \<bullet> y = x \<bullet> x" (is "?lhs \<longleftrightarrow> ?rhs")
proof
  assume "?lhs" then show ?rhs by simp
next
  assume ?rhs
  then have "x \<bullet> x - x \<bullet> y = 0 \<and> x \<bullet> y - y\<bullet> y = 0" by simp
  hence "x \<bullet> (x - y) = 0 \<and> y \<bullet> (x - y) = 0" 
    by (simp add: dot_rsub dot_lsub dot_sym)
  then have "(x - y) \<bullet> (x - y) = 0" by (simp add: ring_simps dot_lsub dot_rsub)
  then show "x = y" by (simp add: dot_eq_0)
qed


subsection{* General linear decision procedure for normed spaces. *}

lemma norm_cmul_rule_thm: "b >= norm(x) ==> \<bar>c\<bar> * b >= norm(c *s x)"
  apply (clarsimp simp add: norm_mul)
  apply (rule mult_mono1)
  apply simp_all
  done

  (* FIXME: Move all these theorems into the ML code using lemma antiquotation *)
lemma norm_add_rule_thm: "b1 >= norm(x1 :: real ^'n) \<Longrightarrow> b2 >= norm(x2) ==> b1 + b2 >= norm(x1 + x2)"
  apply (rule norm_triangle_le) by simp

lemma ge_iff_diff_ge_0: "(a::'a::ordered_ring) \<ge> b == a - b \<ge> 0"
  by (simp add: ring_simps)

lemma pth_1: "(x::real^'n) == 1 *s x" by (simp only: vector_smult_lid)
lemma pth_2: "x - (y::real^'n) == x + -y" by (atomize (full)) simp
lemma pth_3: "(-x::real^'n) == -1 *s x" by vector
lemma pth_4: "0 *s (x::real^'n) == 0" "c *s 0 = (0::real ^ 'n)" by vector+
lemma pth_5: "c *s (d *s x) == (c * d) *s (x::real ^ 'n)" by (atomize (full)) vector
lemma pth_6: "(c::real) *s (x + y) == c *s x + c *s y" by (atomize (full)) (vector ring_simps)
lemma pth_7: "0 + x == (x::real^'n)" "x + 0 == x" by simp_all 
lemma pth_8: "(c::real) *s x + d *s x == (c + d) *s x" by (atomize (full)) (vector ring_simps) 
lemma pth_9: "((c::real) *s x + z) + d *s x == (c + d) *s x + z"
  "c *s x + (d *s x + z) == (c + d) *s x + z"
  "(c *s x + w) + (d *s x + z) == (c + d) *s x + (w + z)" by ((atomize (full)), vector ring_simps)+
lemma pth_a: "(0::real) *s x + y == y" by (atomize (full)) vector
lemma pth_b: "(c::real) *s x + d *s y == c *s x + d *s y" 
  "(c *s x + z) + d *s y == c *s x + (z + d *s y)"
  "c *s x + (d *s y + z) == c *s x + (d *s y + z)"
  "(c *s x + w) + (d *s y + z) == c *s x + (w + (d *s y + z))"
  by ((atomize (full)), vector)+
lemma pth_c: "(c::real) *s x + d *s y == d *s y + c *s x"
  "(c *s x + z) + d *s y == d *s y + (c *s x + z)"
  "c *s x + (d *s y + z) == d *s y + (c *s x + z)"
  "(c *s x + w) + (d *s y + z) == d *s y + ((c *s x + w) + z)" by ((atomize (full)), vector)+
lemma pth_d: "x + (0::real ^'n) == x" by (atomize (full)) vector

lemma norm_imp_pos_and_ge: "norm (x::real ^ 'n) == n \<Longrightarrow> norm x \<ge> 0 \<and> n \<ge> norm x"
  by (atomize) (auto simp add: norm_ge_zero)

lemma real_eq_0_iff_le_ge_0: "(x::real) = 0 == x \<ge> 0 \<and> -x \<ge> 0" by arith

lemma norm_pths: 
  "(x::real ^'n) = y \<longleftrightarrow> norm (x - y) \<le> 0"
  "x \<noteq> y \<longleftrightarrow> \<not> (norm (x - y) \<le> 0)"
  using norm_ge_zero[of "x - y"] by auto

use "normarith.ML"

method_setup norm = {* Method.ctxt_args (Method.SIMPLE_METHOD' o NormArith.norm_arith_tac)
*} "Proves simple linear statements about vector norms"



text{* Hence more metric properties. *}

lemma dist_refl[simp]: "dist x x = 0" by norm

lemma dist_sym: "dist x y = dist y x"by norm

lemma dist_pos_le[simp]: "0 <= dist x y" by norm

lemma dist_triangle: "dist x z <= dist x y + dist y z" by norm

lemma dist_triangle_alt: "dist y z <= dist x y + dist x z" by norm

lemma dist_eq_0[simp]: "dist x y = 0 \<longleftrightarrow> x = y" by norm

lemma dist_pos_lt: "x \<noteq> y ==> 0 < dist x y" by norm 
lemma dist_nz:  "x \<noteq> y \<longleftrightarrow> 0 < dist x y" by norm 

lemma dist_triangle_le: "dist x z + dist y z <= e \<Longrightarrow> dist x y <= e" by norm 

lemma dist_triangle_lt: "dist x z + dist y z < e ==> dist x y < e" by norm 

lemma dist_triangle_half_l: "dist x1 y < e / 2 \<Longrightarrow> dist x2 y < e / 2 ==> dist x1 x2 < e" by norm 

lemma dist_triangle_half_r: "dist y x1 < e / 2 \<Longrightarrow> dist y x2 < e / 2 ==> dist x1 x2 < e" by norm 

lemma dist_triangle_add: "dist (x + y) (x' + y') <= dist x x' + dist y y'"
  by norm 

lemma dist_mul[simp]: "dist (c *s x) (c *s y) = \<bar>c\<bar> * dist x y" 
  unfolding dist_def vector_ssub_ldistrib[symmetric] norm_mul .. 

lemma dist_triangle_add_half: " dist x x' < e / 2 \<Longrightarrow> dist y y' < e / 2 ==> dist(x + y) (x' + y') < e" by norm 

lemma dist_le_0[simp]: "dist x y <= 0 \<longleftrightarrow> x = y" by norm 

lemma setsum_eq: "setsum f S = (\<chi> i. setsum (\<lambda>x. (f x)$i ) S)"
  apply vector
  apply auto
  apply (cases "finite S")
  apply (rule finite_induct[of S])
  apply (auto simp add: vector_component zero_index)
  done

lemma setsum_clauses: 
  shows "setsum f {} = 0"
  and "finite S \<Longrightarrow> setsum f (insert x S) =
                 (if x \<in> S then setsum f S else f x + setsum f S)"
  by (auto simp add: insert_absorb)

lemma setsum_cmul: 
  fixes f:: "'c \<Rightarrow> ('a::semiring_1)^'n"
  shows "setsum (\<lambda>x. c *s f x) S = c *s setsum f S"
  by (simp add: setsum_eq Cart_eq Cart_lambda_beta vector_component setsum_right_distrib)

lemma setsum_component: 
  fixes f:: " 'a \<Rightarrow> ('b::semiring_1) ^'n"
  assumes i: "i \<in> {1 .. dimindex(UNIV:: 'n set)}"
  shows "(setsum f S)$i = setsum (\<lambda>x. (f x)$i) S"
  using i by (simp add: setsum_eq Cart_lambda_beta)

lemma setsum_norm: 
  fixes f :: "'a \<Rightarrow> 'b::real_normed_vector"
  assumes fS: "finite S"
  shows "norm (setsum f S) <= setsum (\<lambda>x. norm(f x)) S"
proof(induct rule: finite_induct[OF fS])
  case 1 thus ?case by simp
next
  case (2 x S)
  from "2.hyps" have "norm (setsum f (insert x S)) \<le> norm (f x) + norm (setsum f S)" by (simp add: norm_triangle_ineq)
  also have "\<dots> \<le> norm (f x) + setsum (\<lambda>x. norm(f x)) S"
    using "2.hyps" by simp
  finally  show ?case  using "2.hyps" by simp
qed

lemma real_setsum_norm: 
  fixes f :: "'a \<Rightarrow> real ^'n"
  assumes fS: "finite S"
  shows "norm (setsum f S) <= setsum (\<lambda>x. norm(f x)) S"
proof(induct rule: finite_induct[OF fS])
  case 1 thus ?case by simp
next
  case (2 x S)
  from "2.hyps" have "norm (setsum f (insert x S)) \<le> norm (f x) + norm (setsum f S)" by (simp add: norm_triangle_ineq)
  also have "\<dots> \<le> norm (f x) + setsum (\<lambda>x. norm(f x)) S"
    using "2.hyps" by simp
  finally  show ?case  using "2.hyps" by simp
qed

lemma setsum_norm_le: 
  fixes f :: "'a \<Rightarrow> 'b::real_normed_vector"
  assumes fS: "finite S"
  and fg: "\<forall>x \<in> S. norm (f x) \<le> g x"
  shows "norm (setsum f S) \<le> setsum g S"
proof-
  from fg have "setsum (\<lambda>x. norm(f x)) S <= setsum g S" 
    by - (rule setsum_mono, simp)
  then show ?thesis using setsum_norm[OF fS, of f] fg
    by arith
qed

lemma real_setsum_norm_le: 
  fixes f :: "'a \<Rightarrow> real ^ 'n"
  assumes fS: "finite S"
  and fg: "\<forall>x \<in> S. norm (f x) \<le> g x"
  shows "norm (setsum f S) \<le> setsum g S"
proof-
  from fg have "setsum (\<lambda>x. norm(f x)) S <= setsum g S" 
    by - (rule setsum_mono, simp)
  then show ?thesis using real_setsum_norm[OF fS, of f] fg
    by arith
qed

lemma setsum_norm_bound:
  fixes f :: "'a \<Rightarrow> 'b::real_normed_vector"
  assumes fS: "finite S"
  and K: "\<forall>x \<in> S. norm (f x) \<le> K"
  shows "norm (setsum f S) \<le> of_nat (card S) * K"
  using setsum_norm_le[OF fS K] setsum_constant[symmetric]
  by simp

lemma real_setsum_norm_bound:
  fixes f :: "'a \<Rightarrow> real ^ 'n"
  assumes fS: "finite S"
  and K: "\<forall>x \<in> S. norm (f x) \<le> K"
  shows "norm (setsum f S) \<le> of_nat (card S) * K"
  using real_setsum_norm_le[OF fS K] setsum_constant[symmetric]
  by simp

lemma setsum_vmul:
  fixes f :: "'a \<Rightarrow> 'b::{real_normed_vector,semiring, mult_zero}"
  assumes fS: "finite S"
  shows "setsum f S *s v = setsum (\<lambda>x. f x *s v) S"
proof(induct rule: finite_induct[OF fS])
  case 1 then show ?case by (simp add: vector_smult_lzero)
next
  case (2 x F)
  from "2.hyps" have "setsum f (insert x F) *s v = (f x + setsum f F) *s v" 
    by simp
  also have "\<dots> = f x *s v + setsum f F *s v" 
    by (simp add: vector_sadd_rdistrib)
  also have "\<dots> = setsum (\<lambda>x. f x *s v) (insert x F)" using "2.hyps" by simp
  finally show ?case .
qed

(* FIXME : Problem thm setsum_vmul[of _ "f:: 'a \<Rightarrow> real ^'n"]  ---
 Get rid of *s and use real_vector instead! Also prove that ^ creates a real_vector !! *)

lemma setsum_add_split: assumes mn: "(m::nat) \<le> n + 1"
  shows "setsum f {m..n + p} = setsum f {m..n} + setsum f {n + 1..n + p}"
proof-
  let ?A = "{m .. n}"
  let ?B = "{n + 1 .. n + p}"
  have eq: "{m .. n+p} = ?A \<union> ?B" using mn by auto 
  have d: "?A \<inter> ?B = {}" by auto
  from setsum_Un_disjoint[of "?A" "?B" f] eq d show ?thesis by auto
qed

lemma setsum_natinterval_left:
  assumes mn: "(m::nat) <= n" 
  shows "setsum f {m..n} = f m + setsum f {m + 1..n}"
proof-
  from mn have "{m .. n} = insert m {m+1 .. n}" by auto
  then show ?thesis by auto
qed

lemma setsum_natinterval_difff: 
  fixes f:: "nat \<Rightarrow> ('a::ab_group_add)"
  shows  "setsum (\<lambda>k. f k - f(k + 1)) {(m::nat) .. n} =
          (if m <= n then f m - f(n + 1) else 0)"
by (induct n, auto simp add: ring_simps not_le le_Suc_eq)

lemmas setsum_restrict_set' = setsum_restrict_set[unfolded Int_def]

lemma setsum_setsum_restrict:
  "finite S \<Longrightarrow> finite T \<Longrightarrow> setsum (\<lambda>x. setsum (\<lambda>y. f x y) {y. y\<in> T \<and> R x y}) S = setsum (\<lambda>y. setsum (\<lambda>x. f x y) {x. x \<in> S \<and> R x y}) T"
  apply (simp add: setsum_restrict_set'[unfolded mem_def] mem_def)
  by (rule setsum_commute)

lemma setsum_image_gen: assumes fS: "finite S"
  shows "setsum g S = setsum (\<lambda>y. setsum g {x. x \<in> S \<and> f x = y}) (f ` S)"
proof-
  {fix x assume "x \<in> S" then have "{y. y\<in> f`S \<and> f x = y} = {f x}" by auto}
  note th0 = this
  have "setsum g S = setsum (\<lambda>x. setsum (\<lambda>y. g x) {y. y\<in> f`S \<and> f x = y}) S" 
    apply (rule setsum_cong2) 
    by (simp add: th0)
  also have "\<dots> = setsum (\<lambda>y. setsum g {x. x \<in> S \<and> f x = y}) (f ` S)"
    apply (rule setsum_setsum_restrict[OF fS])
    by (rule finite_imageI[OF fS])
  finally show ?thesis .
qed

    (* FIXME: Here too need stupid finiteness assumption on T!!! *)
lemma setsum_group:
  assumes fS: "finite S" and fT: "finite T" and fST: "f ` S \<subseteq> T"
  shows "setsum (\<lambda>y. setsum g {x. x\<in> S \<and> f x = y}) T = setsum g S"
  
apply (subst setsum_image_gen[OF fS, of g f])
apply (rule setsum_mono_zero_right[OF fT fST])
by (auto intro: setsum_0')

lemma vsum_norm_allsubsets_bound:
  fixes f:: "'a \<Rightarrow> real ^'n"
  assumes fP: "finite P" and fPs: "\<And>Q. Q \<subseteq> P \<Longrightarrow> norm (setsum f Q) \<le> e" 
  shows "setsum (\<lambda>x. norm (f x)) P \<le> 2 * real (dimindex(UNIV :: 'n set)) *  e"
proof-
  let ?d = "real (dimindex (UNIV ::'n set))"
  let ?nf = "\<lambda>x. norm (f x)"
  let ?U = "{1 .. dimindex (UNIV :: 'n set)}"
  have th0: "setsum (\<lambda>x. setsum (\<lambda>i. \<bar>f x $ i\<bar>) ?U) P = setsum (\<lambda>i. setsum (\<lambda>x. \<bar>f x $ i\<bar>) P) ?U"
    by (rule setsum_commute)
  have th1: "2 * ?d * e = of_nat (card ?U) * (2 * e)" by (simp add: real_of_nat_def)
  have "setsum ?nf P \<le> setsum (\<lambda>x. setsum (\<lambda>i. \<bar>f x $ i\<bar>) ?U) P"
    apply (rule setsum_mono)
    by (rule norm_le_l1)
  also have "\<dots> \<le> 2 * ?d * e"
    unfolding th0 th1
  proof(rule setsum_bounded)
    fix i assume i: "i \<in> ?U"
    let ?Pp = "{x. x\<in> P \<and> f x $ i \<ge> 0}"
    let ?Pn = "{x. x \<in> P \<and> f x $ i < 0}"
    have thp: "P = ?Pp \<union> ?Pn" by auto
    have thp0: "?Pp \<inter> ?Pn ={}" by auto
    have PpP: "?Pp \<subseteq> P" and PnP: "?Pn \<subseteq> P" by blast+
    have Ppe:"setsum (\<lambda>x. \<bar>f x $ i\<bar>) ?Pp \<le> e"
      using i component_le_norm[OF i, of "setsum (\<lambda>x. f x) ?Pp"]  fPs[OF PpP]
      by (auto simp add: setsum_component intro: abs_le_D1)
    have Pne: "setsum (\<lambda>x. \<bar>f x $ i\<bar>) ?Pn \<le> e"
      using i component_le_norm[OF i, of "setsum (\<lambda>x. - f x) ?Pn"]  fPs[OF PnP]
      by (auto simp add: setsum_negf setsum_component vector_component intro: abs_le_D1)
    have "setsum (\<lambda>x. \<bar>f x $ i\<bar>) P = setsum (\<lambda>x. \<bar>f x $ i\<bar>) ?Pp + setsum (\<lambda>x. \<bar>f x $ i\<bar>) ?Pn" 
      apply (subst thp)
      apply (rule setsum_Un_zero) 
      using fP thp0 by auto
    also have "\<dots> \<le> 2*e" using Pne Ppe by arith
    finally show "setsum (\<lambda>x. \<bar>f x $ i\<bar>) P \<le> 2*e" .
  qed
  finally show ?thesis .
qed

lemma dot_lsum: "finite S \<Longrightarrow> setsum f S \<bullet> (y::'a::{comm_ring}^'n) = setsum (\<lambda>x. f x \<bullet> y) S "
  by (induct rule: finite_induct, auto simp add: dot_lzero dot_ladd dot_radd)

lemma dot_rsum: "finite S \<Longrightarrow> (y::'a::{comm_ring}^'n) \<bullet> setsum f S = setsum (\<lambda>x. y \<bullet> f x) S "
  by (induct rule: finite_induct, auto simp add: dot_rzero dot_radd)

subsection{* Basis vectors in coordinate directions. *}


definition "basis k = (\<chi> i. if i = k then 1 else 0)"

lemma delta_mult_idempotent: 
  "(if k=a then 1 else (0::'a::semiring_1)) * (if k=a then 1 else 0) = (if k=a then 1 else 0)" by (cases "k=a", auto)

lemma norm_basis:
  assumes k: "k \<in> {1 .. dimindex (UNIV :: 'n set)}"
  shows "norm (basis k :: real ^'n) = 1"
  using k 
  apply (simp add: basis_def real_vector_norm_def dot_def)
  apply (vector delta_mult_idempotent)
  using setsum_delta[of "{1 .. dimindex (UNIV :: 'n set)}" "k" "\<lambda>k. 1::real"]
  apply auto
  done

lemma norm_basis_1: "norm(basis 1 :: real ^'n) = 1"
  apply (simp add: basis_def real_vector_norm_def dot_def)
  apply (vector delta_mult_idempotent)
  using setsum_delta[of "{1 .. dimindex (UNIV :: 'n set)}" "1" "\<lambda>k. 1::real"] dimindex_nonzero[of "UNIV :: 'n set"]
  apply auto
  done

lemma vector_choose_size: "0 <= c ==> \<exists>(x::real^'n). norm x = c"
  apply (rule exI[where x="c *s basis 1"])
  by (simp only: norm_mul norm_basis_1)

lemma vector_choose_dist: assumes e: "0 <= e" 
  shows "\<exists>(y::real^'n). dist x y = e"
proof-
  from vector_choose_size[OF e] obtain c:: "real ^'n"  where "norm c = e"
    by blast
  then have "dist x (x - c) = e" by (simp add: dist_def)
  then show ?thesis by blast
qed

lemma basis_inj: "inj_on (basis :: nat \<Rightarrow> real ^'n) {1 .. dimindex (UNIV :: 'n set)}"
  by (auto simp add: inj_on_def basis_def Cart_eq Cart_lambda_beta)

lemma basis_component: "i \<in> {1 .. dimindex(UNIV:: 'n set)} ==> (basis k ::('a::semiring_1)^'n)$i = (if k=i then 1 else 0)"
  by (simp add: basis_def Cart_lambda_beta)

lemma cond_value_iff: "f (if b then x else y) = (if b then f x else f y)"
  by auto

lemma basis_expansion:
  "setsum (\<lambda>i. (x$i) *s basis i) {1 .. dimindex (UNIV :: 'n set)} = (x::('a::ring_1) ^'n)" (is "?lhs = ?rhs" is "setsum ?f ?S = _")
  by (auto simp add: Cart_eq basis_component[where ?'n = "'n"] setsum_component vector_component cond_value_iff setsum_delta[of "?S", where ?'b = "'a", simplified] cong del: if_weak_cong)

lemma basis_expansion_unique: 
  "setsum (\<lambda>i. f i *s basis i) {1 .. dimindex (UNIV :: 'n set)} = (x::('a::comm_ring_1) ^'n) \<longleftrightarrow> (\<forall>i\<in>{1 .. dimindex(UNIV:: 'n set)}. f i = x$i)"
  by (simp add: Cart_eq setsum_component vector_component basis_component setsum_delta cond_value_iff cong del: if_weak_cong)

lemma cond_application_beta: "(if b then f else g) x = (if b then f x else g x)"
  by auto

lemma dot_basis:
  assumes i: "i \<in> {1 .. dimindex (UNIV :: 'n set)}"
  shows "basis i \<bullet> x = x$i" "x \<bullet> (basis i :: 'a^'n) = (x$i :: 'a::semiring_1)"
  using i
  by (auto simp add: dot_def basis_def Cart_lambda_beta cond_application_beta  cond_value_iff setsum_delta cong del: if_weak_cong)

lemma basis_eq_0: "basis i = (0::'a::semiring_1^'n) \<longleftrightarrow> i \<notin> {1..dimindex(UNIV ::'n set)}"
  by (auto simp add: Cart_eq basis_component zero_index)

lemma basis_nonzero: 
  assumes k: "k \<in> {1 .. dimindex(UNIV ::'n set)}"
  shows "basis k \<noteq> (0:: 'a::semiring_1 ^'n)"
  using k by (simp add: basis_eq_0)

lemma vector_eq_ldot: "(\<forall>x. x \<bullet> y = x \<bullet> z) \<longleftrightarrow> y = (z::'a::semiring_1^'n)"
  apply (auto simp add: Cart_eq dot_basis)
  apply (erule_tac x="basis i" in allE)
  apply (simp add: dot_basis)
  apply (subgoal_tac "y = z")
  apply simp
  apply vector
  done

lemma vector_eq_rdot: "(\<forall>z. x \<bullet> z = y \<bullet> z) \<longleftrightarrow> x = (y::'a::semiring_1^'n)"
  apply (auto simp add: Cart_eq dot_basis)
  apply (erule_tac x="basis i" in allE)
  apply (simp add: dot_basis)
  apply (subgoal_tac "x = y")
  apply simp
  apply vector
  done

subsection{* Orthogonality. *}

definition "orthogonal x y \<longleftrightarrow> (x \<bullet> y = 0)"

lemma orthogonal_basis:
  assumes i:"i \<in> {1 .. dimindex(UNIV ::'n set)}" 
  shows "orthogonal (basis i :: 'a^'n) x \<longleftrightarrow> x$i = (0::'a::ring_1)"
  using i
  by (auto simp add: orthogonal_def dot_def basis_def Cart_lambda_beta cond_value_iff cond_application_beta setsum_delta cong del: if_weak_cong)

lemma orthogonal_basis_basis:
  assumes i:"i \<in> {1 .. dimindex(UNIV ::'n set)}" 
  and j: "j \<in> {1 .. dimindex(UNIV ::'n set)}" 
  shows "orthogonal (basis i :: 'a::ring_1^'n) (basis j) \<longleftrightarrow> i \<noteq> j" 
  unfolding orthogonal_basis[OF i] basis_component[OF i] by simp

  (* FIXME : Maybe some of these require less than comm_ring, but not all*)
lemma orthogonal_clauses:
  "orthogonal a (0::'a::comm_ring ^'n)"
  "orthogonal a x ==> orthogonal a (c *s x)"
  "orthogonal a x ==> orthogonal a (-x)"
  "orthogonal a x \<Longrightarrow> orthogonal a y ==> orthogonal a (x + y)"
  "orthogonal a x \<Longrightarrow> orthogonal a y ==> orthogonal a (x - y)"
  "orthogonal 0 a"
  "orthogonal x a ==> orthogonal (c *s x) a"
  "orthogonal x a ==> orthogonal (-x) a"
  "orthogonal x a \<Longrightarrow> orthogonal y a ==> orthogonal (x + y) a"
  "orthogonal x a \<Longrightarrow> orthogonal y a ==> orthogonal (x - y) a"
  unfolding orthogonal_def dot_rneg dot_rmult dot_radd dot_rsub
  dot_lzero dot_rzero dot_lneg dot_lmult dot_ladd dot_lsub
  by simp_all

lemma orthogonal_commute: "orthogonal (x::'a::{ab_semigroup_mult,comm_monoid_add} ^'n)y \<longleftrightarrow> orthogonal y x"
  by (simp add: orthogonal_def dot_sym)

subsection{* Explicit vector construction from lists. *}

lemma Cart_lambda_beta_1[simp]: "(Cart_lambda g)$1 = g 1"
  apply (rule Cart_lambda_beta[rule_format])
  using dimindex_ge_1 apply auto done

lemma Cart_lambda_beta_1'[simp]: "(Cart_lambda g)$(Suc 0) = g 1"
  by (simp only: One_nat_def[symmetric] Cart_lambda_beta_1)

definition "vector l = (\<chi> i. if i <= length l then l ! (i - 1) else 0)"

lemma vector_1: "(vector[x]) $1 = x"
  using dimindex_ge_1
  by (auto simp add: vector_def Cart_lambda_beta[rule_format])
lemma dimindex_2[simp]: "2 \<in> {1 .. dimindex (UNIV :: 2 set)}"
  by (auto simp add: dimindex_def)
lemma dimindex_2'[simp]: "2 \<in> {Suc 0 .. dimindex (UNIV :: 2 set)}"
  by (auto simp add: dimindex_def)
lemma dimindex_3[simp]: "2 \<in> {1 .. dimindex (UNIV :: 3 set)}" "3 \<in> {1 .. dimindex (UNIV :: 3 set)}"
  by (auto simp add: dimindex_def)

lemma dimindex_3'[simp]: "2 \<in> {Suc 0 .. dimindex (UNIV :: 3 set)}" "3 \<in> {Suc 0 .. dimindex (UNIV :: 3 set)}"
  by (auto simp add: dimindex_def)

lemma vector_2:
 "(vector[x,y]) $1 = x"
 "(vector[x,y] :: 'a^2)$2 = (y::'a::zero)"
  apply (simp add: vector_def)
  using Cart_lambda_beta[rule_format, OF dimindex_2, of "\<lambda>i. if i \<le> length [x,y] then [x,y] ! (i - 1) else (0::'a)"]
  apply (simp only: vector_def )
  apply auto
  done