src/HOL/Transfer.thy
author Christian Sternagel
Thu Aug 30 15:44:03 2012 +0900 (2012-08-30)
changeset 49093 fdc301f592c4
parent 48891 c0eafbd55de3
child 49975 faf4afed009f
permissions -rw-r--r--
forgot to add lemmas
huffman@47325
     1
(*  Title:      HOL/Transfer.thy
huffman@47325
     2
    Author:     Brian Huffman, TU Muenchen
huffman@47325
     3
*)
huffman@47325
     4
huffman@47325
     5
header {* Generic theorem transfer using relations *}
huffman@47325
     6
huffman@47325
     7
theory Transfer
huffman@47325
     8
imports Plain Hilbert_Choice
huffman@47325
     9
begin
huffman@47325
    10
huffman@47325
    11
subsection {* Relator for function space *}
huffman@47325
    12
huffman@47325
    13
definition
huffman@47325
    14
  fun_rel :: "('a \<Rightarrow> 'c \<Rightarrow> bool) \<Rightarrow> ('b \<Rightarrow> 'd \<Rightarrow> bool) \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> ('c \<Rightarrow> 'd) \<Rightarrow> bool" (infixr "===>" 55)
huffman@47325
    15
where
huffman@47325
    16
  "fun_rel A B = (\<lambda>f g. \<forall>x y. A x y \<longrightarrow> B (f x) (g y))"
huffman@47325
    17
huffman@47325
    18
lemma fun_relI [intro]:
huffman@47325
    19
  assumes "\<And>x y. A x y \<Longrightarrow> B (f x) (g y)"
huffman@47325
    20
  shows "(A ===> B) f g"
huffman@47325
    21
  using assms by (simp add: fun_rel_def)
huffman@47325
    22
huffman@47325
    23
lemma fun_relD:
huffman@47325
    24
  assumes "(A ===> B) f g" and "A x y"
huffman@47325
    25
  shows "B (f x) (g y)"
huffman@47325
    26
  using assms by (simp add: fun_rel_def)
huffman@47325
    27
kuncar@47937
    28
lemma fun_relD2:
kuncar@47937
    29
  assumes "(A ===> B) f g" and "A x x"
kuncar@47937
    30
  shows "B (f x) (g x)"
kuncar@47937
    31
  using assms unfolding fun_rel_def by auto
kuncar@47937
    32
huffman@47325
    33
lemma fun_relE:
huffman@47325
    34
  assumes "(A ===> B) f g" and "A x y"
huffman@47325
    35
  obtains "B (f x) (g y)"
huffman@47325
    36
  using assms by (simp add: fun_rel_def)
huffman@47325
    37
huffman@47325
    38
lemma fun_rel_eq:
huffman@47325
    39
  shows "((op =) ===> (op =)) = (op =)"
huffman@47325
    40
  by (auto simp add: fun_eq_iff elim: fun_relE)
huffman@47325
    41
huffman@47325
    42
lemma fun_rel_eq_rel:
huffman@47325
    43
  shows "((op =) ===> R) = (\<lambda>f g. \<forall>x. R (f x) (g x))"
huffman@47325
    44
  by (simp add: fun_rel_def)
huffman@47325
    45
huffman@47325
    46
huffman@47325
    47
subsection {* Transfer method *}
huffman@47325
    48
huffman@47789
    49
text {* Explicit tag for relation membership allows for
huffman@47789
    50
  backward proof methods. *}
huffman@47325
    51
huffman@47325
    52
definition Rel :: "('a \<Rightarrow> 'b \<Rightarrow> bool) \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> bool"
huffman@47325
    53
  where "Rel r \<equiv> r"
huffman@47325
    54
huffman@47325
    55
text {* Handling of meta-logic connectives *}
huffman@47325
    56
huffman@47325
    57
definition transfer_forall where
huffman@47325
    58
  "transfer_forall \<equiv> All"
huffman@47325
    59
huffman@47325
    60
definition transfer_implies where
huffman@47325
    61
  "transfer_implies \<equiv> op \<longrightarrow>"
huffman@47325
    62
huffman@47355
    63
definition transfer_bforall :: "('a \<Rightarrow> bool) \<Rightarrow> ('a \<Rightarrow> bool) \<Rightarrow> bool"
huffman@47355
    64
  where "transfer_bforall \<equiv> (\<lambda>P Q. \<forall>x. P x \<longrightarrow> Q x)"
huffman@47355
    65
huffman@47325
    66
lemma transfer_forall_eq: "(\<And>x. P x) \<equiv> Trueprop (transfer_forall (\<lambda>x. P x))"
huffman@47325
    67
  unfolding atomize_all transfer_forall_def ..
huffman@47325
    68
huffman@47325
    69
lemma transfer_implies_eq: "(A \<Longrightarrow> B) \<equiv> Trueprop (transfer_implies A B)"
huffman@47325
    70
  unfolding atomize_imp transfer_implies_def ..
huffman@47325
    71
huffman@47355
    72
lemma transfer_bforall_unfold:
huffman@47355
    73
  "Trueprop (transfer_bforall P (\<lambda>x. Q x)) \<equiv> (\<And>x. P x \<Longrightarrow> Q x)"
huffman@47355
    74
  unfolding transfer_bforall_def atomize_imp atomize_all ..
huffman@47355
    75
huffman@47658
    76
lemma transfer_start: "\<lbrakk>P; Rel (op =) P Q\<rbrakk> \<Longrightarrow> Q"
huffman@47325
    77
  unfolding Rel_def by simp
huffman@47325
    78
huffman@47658
    79
lemma transfer_start': "\<lbrakk>P; Rel (op \<longrightarrow>) P Q\<rbrakk> \<Longrightarrow> Q"
huffman@47325
    80
  unfolding Rel_def by simp
huffman@47325
    81
huffman@47635
    82
lemma transfer_prover_start: "\<lbrakk>x = x'; Rel R x' y\<rbrakk> \<Longrightarrow> Rel R x y"
huffman@47618
    83
  by simp
huffman@47618
    84
huffman@47325
    85
lemma Rel_eq_refl: "Rel (op =) x x"
huffman@47325
    86
  unfolding Rel_def ..
huffman@47325
    87
huffman@47789
    88
lemma Rel_app:
huffman@47523
    89
  assumes "Rel (A ===> B) f g" and "Rel A x y"
huffman@47789
    90
  shows "Rel B (f x) (g y)"
huffman@47789
    91
  using assms unfolding Rel_def fun_rel_def by fast
huffman@47523
    92
huffman@47789
    93
lemma Rel_abs:
huffman@47523
    94
  assumes "\<And>x y. Rel A x y \<Longrightarrow> Rel B (f x) (g y)"
huffman@47789
    95
  shows "Rel (A ===> B) (\<lambda>x. f x) (\<lambda>y. g y)"
huffman@47789
    96
  using assms unfolding Rel_def fun_rel_def by fast
huffman@47523
    97
wenzelm@48891
    98
ML_file "Tools/transfer.ML"
huffman@47325
    99
setup Transfer.setup
huffman@47325
   100
huffman@47503
   101
declare fun_rel_eq [relator_eq]
huffman@47503
   102
huffman@47789
   103
hide_const (open) Rel
huffman@47325
   104
huffman@47325
   105
huffman@47325
   106
subsection {* Predicates on relations, i.e. ``class constraints'' *}
huffman@47325
   107
huffman@47325
   108
definition right_total :: "('a \<Rightarrow> 'b \<Rightarrow> bool) \<Rightarrow> bool"
huffman@47325
   109
  where "right_total R \<longleftrightarrow> (\<forall>y. \<exists>x. R x y)"
huffman@47325
   110
huffman@47325
   111
definition right_unique :: "('a \<Rightarrow> 'b \<Rightarrow> bool) \<Rightarrow> bool"
huffman@47325
   112
  where "right_unique R \<longleftrightarrow> (\<forall>x y z. R x y \<longrightarrow> R x z \<longrightarrow> y = z)"
huffman@47325
   113
huffman@47325
   114
definition bi_total :: "('a \<Rightarrow> 'b \<Rightarrow> bool) \<Rightarrow> bool"
huffman@47325
   115
  where "bi_total R \<longleftrightarrow> (\<forall>x. \<exists>y. R x y) \<and> (\<forall>y. \<exists>x. R x y)"
huffman@47325
   116
huffman@47325
   117
definition bi_unique :: "('a \<Rightarrow> 'b \<Rightarrow> bool) \<Rightarrow> bool"
huffman@47325
   118
  where "bi_unique R \<longleftrightarrow>
huffman@47325
   119
    (\<forall>x y z. R x y \<longrightarrow> R x z \<longrightarrow> y = z) \<and>
huffman@47325
   120
    (\<forall>x y z. R x z \<longrightarrow> R y z \<longrightarrow> x = y)"
huffman@47325
   121
huffman@47325
   122
lemma right_total_alt_def:
huffman@47325
   123
  "right_total R \<longleftrightarrow> ((R ===> op \<longrightarrow>) ===> op \<longrightarrow>) All All"
huffman@47325
   124
  unfolding right_total_def fun_rel_def
huffman@47325
   125
  apply (rule iffI, fast)
huffman@47325
   126
  apply (rule allI)
huffman@47325
   127
  apply (drule_tac x="\<lambda>x. True" in spec)
huffman@47325
   128
  apply (drule_tac x="\<lambda>y. \<exists>x. R x y" in spec)
huffman@47325
   129
  apply fast
huffman@47325
   130
  done
huffman@47325
   131
huffman@47325
   132
lemma right_unique_alt_def:
huffman@47325
   133
  "right_unique R \<longleftrightarrow> (R ===> R ===> op \<longrightarrow>) (op =) (op =)"
huffman@47325
   134
  unfolding right_unique_def fun_rel_def by auto
huffman@47325
   135
huffman@47325
   136
lemma bi_total_alt_def:
huffman@47325
   137
  "bi_total R \<longleftrightarrow> ((R ===> op =) ===> op =) All All"
huffman@47325
   138
  unfolding bi_total_def fun_rel_def
huffman@47325
   139
  apply (rule iffI, fast)
huffman@47325
   140
  apply safe
huffman@47325
   141
  apply (drule_tac x="\<lambda>x. \<exists>y. R x y" in spec)
huffman@47325
   142
  apply (drule_tac x="\<lambda>y. True" in spec)
huffman@47325
   143
  apply fast
huffman@47325
   144
  apply (drule_tac x="\<lambda>x. True" in spec)
huffman@47325
   145
  apply (drule_tac x="\<lambda>y. \<exists>x. R x y" in spec)
huffman@47325
   146
  apply fast
huffman@47325
   147
  done
huffman@47325
   148
huffman@47325
   149
lemma bi_unique_alt_def:
huffman@47325
   150
  "bi_unique R \<longleftrightarrow> (R ===> R ===> op =) (op =) (op =)"
huffman@47325
   151
  unfolding bi_unique_def fun_rel_def by auto
huffman@47325
   152
huffman@47660
   153
text {* Properties are preserved by relation composition. *}
huffman@47660
   154
huffman@47660
   155
lemma OO_def: "R OO S = (\<lambda>x z. \<exists>y. R x y \<and> S y z)"
huffman@47660
   156
  by auto
huffman@47660
   157
huffman@47660
   158
lemma bi_total_OO: "\<lbrakk>bi_total A; bi_total B\<rbrakk> \<Longrightarrow> bi_total (A OO B)"
huffman@47660
   159
  unfolding bi_total_def OO_def by metis
huffman@47660
   160
huffman@47660
   161
lemma bi_unique_OO: "\<lbrakk>bi_unique A; bi_unique B\<rbrakk> \<Longrightarrow> bi_unique (A OO B)"
huffman@47660
   162
  unfolding bi_unique_def OO_def by metis
huffman@47660
   163
huffman@47660
   164
lemma right_total_OO:
huffman@47660
   165
  "\<lbrakk>right_total A; right_total B\<rbrakk> \<Longrightarrow> right_total (A OO B)"
huffman@47660
   166
  unfolding right_total_def OO_def by metis
huffman@47660
   167
huffman@47660
   168
lemma right_unique_OO:
huffman@47660
   169
  "\<lbrakk>right_unique A; right_unique B\<rbrakk> \<Longrightarrow> right_unique (A OO B)"
huffman@47660
   170
  unfolding right_unique_def OO_def by metis
huffman@47660
   171
huffman@47325
   172
huffman@47325
   173
subsection {* Properties of relators *}
huffman@47325
   174
huffman@47325
   175
lemma right_total_eq [transfer_rule]: "right_total (op =)"
huffman@47325
   176
  unfolding right_total_def by simp
huffman@47325
   177
huffman@47325
   178
lemma right_unique_eq [transfer_rule]: "right_unique (op =)"
huffman@47325
   179
  unfolding right_unique_def by simp
huffman@47325
   180
huffman@47325
   181
lemma bi_total_eq [transfer_rule]: "bi_total (op =)"
huffman@47325
   182
  unfolding bi_total_def by simp
huffman@47325
   183
huffman@47325
   184
lemma bi_unique_eq [transfer_rule]: "bi_unique (op =)"
huffman@47325
   185
  unfolding bi_unique_def by simp
huffman@47325
   186
huffman@47325
   187
lemma right_total_fun [transfer_rule]:
huffman@47325
   188
  "\<lbrakk>right_unique A; right_total B\<rbrakk> \<Longrightarrow> right_total (A ===> B)"
huffman@47325
   189
  unfolding right_total_def fun_rel_def
huffman@47325
   190
  apply (rule allI, rename_tac g)
huffman@47325
   191
  apply (rule_tac x="\<lambda>x. SOME z. B z (g (THE y. A x y))" in exI)
huffman@47325
   192
  apply clarify
huffman@47325
   193
  apply (subgoal_tac "(THE y. A x y) = y", simp)
huffman@47325
   194
  apply (rule someI_ex)
huffman@47325
   195
  apply (simp)
huffman@47325
   196
  apply (rule the_equality)
huffman@47325
   197
  apply assumption
huffman@47325
   198
  apply (simp add: right_unique_def)
huffman@47325
   199
  done
huffman@47325
   200
huffman@47325
   201
lemma right_unique_fun [transfer_rule]:
huffman@47325
   202
  "\<lbrakk>right_total A; right_unique B\<rbrakk> \<Longrightarrow> right_unique (A ===> B)"
huffman@47325
   203
  unfolding right_total_def right_unique_def fun_rel_def
huffman@47325
   204
  by (clarify, rule ext, fast)
huffman@47325
   205
huffman@47325
   206
lemma bi_total_fun [transfer_rule]:
huffman@47325
   207
  "\<lbrakk>bi_unique A; bi_total B\<rbrakk> \<Longrightarrow> bi_total (A ===> B)"
huffman@47325
   208
  unfolding bi_total_def fun_rel_def
huffman@47325
   209
  apply safe
huffman@47325
   210
  apply (rename_tac f)
huffman@47325
   211
  apply (rule_tac x="\<lambda>y. SOME z. B (f (THE x. A x y)) z" in exI)
huffman@47325
   212
  apply clarify
huffman@47325
   213
  apply (subgoal_tac "(THE x. A x y) = x", simp)
huffman@47325
   214
  apply (rule someI_ex)
huffman@47325
   215
  apply (simp)
huffman@47325
   216
  apply (rule the_equality)
huffman@47325
   217
  apply assumption
huffman@47325
   218
  apply (simp add: bi_unique_def)
huffman@47325
   219
  apply (rename_tac g)
huffman@47325
   220
  apply (rule_tac x="\<lambda>x. SOME z. B z (g (THE y. A x y))" in exI)
huffman@47325
   221
  apply clarify
huffman@47325
   222
  apply (subgoal_tac "(THE y. A x y) = y", simp)
huffman@47325
   223
  apply (rule someI_ex)
huffman@47325
   224
  apply (simp)
huffman@47325
   225
  apply (rule the_equality)
huffman@47325
   226
  apply assumption
huffman@47325
   227
  apply (simp add: bi_unique_def)
huffman@47325
   228
  done
huffman@47325
   229
huffman@47325
   230
lemma bi_unique_fun [transfer_rule]:
huffman@47325
   231
  "\<lbrakk>bi_total A; bi_unique B\<rbrakk> \<Longrightarrow> bi_unique (A ===> B)"
huffman@47325
   232
  unfolding bi_total_def bi_unique_def fun_rel_def fun_eq_iff
huffman@47325
   233
  by (safe, metis, fast)
huffman@47325
   234
huffman@47325
   235
huffman@47635
   236
subsection {* Transfer rules *}
huffman@47325
   237
huffman@47684
   238
text {* Transfer rules using implication instead of equality on booleans. *}
huffman@47684
   239
huffman@47684
   240
lemma eq_imp_transfer [transfer_rule]:
huffman@47684
   241
  "right_unique A \<Longrightarrow> (A ===> A ===> op \<longrightarrow>) (op =) (op =)"
huffman@47684
   242
  unfolding right_unique_alt_def .
huffman@47684
   243
huffman@47684
   244
lemma forall_imp_transfer [transfer_rule]:
huffman@47684
   245
  "right_total A \<Longrightarrow> ((A ===> op \<longrightarrow>) ===> op \<longrightarrow>) transfer_forall transfer_forall"
huffman@47684
   246
  unfolding right_total_alt_def transfer_forall_def .
huffman@47684
   247
huffman@47636
   248
lemma eq_transfer [transfer_rule]:
huffman@47325
   249
  assumes "bi_unique A"
huffman@47325
   250
  shows "(A ===> A ===> op =) (op =) (op =)"
huffman@47325
   251
  using assms unfolding bi_unique_def fun_rel_def by auto
huffman@47325
   252
huffman@47636
   253
lemma All_transfer [transfer_rule]:
huffman@47325
   254
  assumes "bi_total A"
huffman@47325
   255
  shows "((A ===> op =) ===> op =) All All"
huffman@47325
   256
  using assms unfolding bi_total_def fun_rel_def by fast
huffman@47325
   257
huffman@47636
   258
lemma Ex_transfer [transfer_rule]:
huffman@47325
   259
  assumes "bi_total A"
huffman@47325
   260
  shows "((A ===> op =) ===> op =) Ex Ex"
huffman@47325
   261
  using assms unfolding bi_total_def fun_rel_def by fast
huffman@47325
   262
huffman@47636
   263
lemma If_transfer [transfer_rule]: "(op = ===> A ===> A ===> A) If If"
huffman@47325
   264
  unfolding fun_rel_def by simp
huffman@47325
   265
huffman@47636
   266
lemma Let_transfer [transfer_rule]: "(A ===> (A ===> B) ===> B) Let Let"
huffman@47612
   267
  unfolding fun_rel_def by simp
huffman@47612
   268
huffman@47636
   269
lemma id_transfer [transfer_rule]: "(A ===> A) id id"
huffman@47625
   270
  unfolding fun_rel_def by simp
huffman@47625
   271
huffman@47636
   272
lemma comp_transfer [transfer_rule]:
huffman@47325
   273
  "((B ===> C) ===> (A ===> B) ===> (A ===> C)) (op \<circ>) (op \<circ>)"
huffman@47325
   274
  unfolding fun_rel_def by simp
huffman@47325
   275
huffman@47636
   276
lemma fun_upd_transfer [transfer_rule]:
huffman@47325
   277
  assumes [transfer_rule]: "bi_unique A"
huffman@47325
   278
  shows "((A ===> B) ===> A ===> B ===> A ===> B) fun_upd fun_upd"
huffman@47635
   279
  unfolding fun_upd_def [abs_def] by transfer_prover
huffman@47325
   280
huffman@47637
   281
lemma nat_case_transfer [transfer_rule]:
huffman@47637
   282
  "(A ===> (op = ===> A) ===> op = ===> A) nat_case nat_case"
huffman@47637
   283
  unfolding fun_rel_def by (simp split: nat.split)
huffman@47627
   284
huffman@47924
   285
lemma nat_rec_transfer [transfer_rule]:
huffman@47924
   286
  "(A ===> (op = ===> A ===> A) ===> op = ===> A) nat_rec nat_rec"
huffman@47924
   287
  unfolding fun_rel_def by (clarsimp, rename_tac n, induct_tac n, simp_all)
huffman@47924
   288
huffman@47924
   289
lemma funpow_transfer [transfer_rule]:
huffman@47924
   290
  "(op = ===> (A ===> A) ===> (A ===> A)) compow compow"
huffman@47924
   291
  unfolding funpow_def by transfer_prover
huffman@47924
   292
huffman@47627
   293
text {* Fallback rule for transferring universal quantifiers over
huffman@47627
   294
  correspondence relations that are not bi-total, and do not have
huffman@47627
   295
  custom transfer rules (e.g. relations between function types). *}
huffman@47627
   296
huffman@47637
   297
lemma Domainp_iff: "Domainp T x \<longleftrightarrow> (\<exists>y. T x y)"
huffman@47637
   298
  by auto
huffman@47637
   299
huffman@47627
   300
lemma Domainp_forall_transfer [transfer_rule]:
huffman@47627
   301
  assumes "right_total A"
huffman@47627
   302
  shows "((A ===> op =) ===> op =)
huffman@47627
   303
    (transfer_bforall (Domainp A)) transfer_forall"
huffman@47627
   304
  using assms unfolding right_total_def
huffman@47627
   305
  unfolding transfer_forall_def transfer_bforall_def fun_rel_def Domainp_iff
huffman@47627
   306
  by metis
huffman@47627
   307
huffman@47627
   308
text {* Preferred rule for transferring universal quantifiers over
huffman@47627
   309
  bi-total correspondence relations (later rules are tried first). *}
huffman@47627
   310
huffman@47636
   311
lemma forall_transfer [transfer_rule]:
huffman@47627
   312
  "bi_total A \<Longrightarrow> ((A ===> op =) ===> op =) transfer_forall transfer_forall"
huffman@47636
   313
  unfolding transfer_forall_def by (rule All_transfer)
huffman@47325
   314
huffman@47325
   315
end