1 (* Title: HOL/Isar_examples/MutilatedCheckerboard.thy |
|
2 ID: $Id$ |
|
3 Author: Markus Wenzel, TU Muenchen (Isar document) |
|
4 Lawrence C Paulson, Cambridge University Computer Laboratory (original scripts) |
|
5 *) |
|
6 |
|
7 header {* The Mutilated Checker Board Problem *} |
|
8 |
|
9 theory MutilatedCheckerboard imports Main begin |
|
10 |
|
11 text {* |
|
12 The Mutilated Checker Board Problem, formalized inductively. See |
|
13 \cite{paulson-mutilated-board} and |
|
14 \url{http://isabelle.in.tum.de/library/HOL/Induct/Mutil.html} for the |
|
15 original tactic script version. |
|
16 *} |
|
17 |
|
18 subsection {* Tilings *} |
|
19 |
|
20 inductive_set |
|
21 tiling :: "'a set set => 'a set set" |
|
22 for A :: "'a set set" |
|
23 where |
|
24 empty: "{} : tiling A" |
|
25 | Un: "a : A ==> t : tiling A ==> a <= - t ==> a Un t : tiling A" |
|
26 |
|
27 |
|
28 text "The union of two disjoint tilings is a tiling." |
|
29 |
|
30 lemma tiling_Un: |
|
31 assumes "t : tiling A" and "u : tiling A" and "t Int u = {}" |
|
32 shows "t Un u : tiling A" |
|
33 proof - |
|
34 let ?T = "tiling A" |
|
35 from `t : ?T` and `t Int u = {}` |
|
36 show "t Un u : ?T" |
|
37 proof (induct t) |
|
38 case empty |
|
39 with `u : ?T` show "{} Un u : ?T" by simp |
|
40 next |
|
41 case (Un a t) |
|
42 show "(a Un t) Un u : ?T" |
|
43 proof - |
|
44 have "a Un (t Un u) : ?T" |
|
45 using `a : A` |
|
46 proof (rule tiling.Un) |
|
47 from `(a Un t) Int u = {}` have "t Int u = {}" by blast |
|
48 then show "t Un u: ?T" by (rule Un) |
|
49 from `a <= - t` and `(a Un t) Int u = {}` |
|
50 show "a <= - (t Un u)" by blast |
|
51 qed |
|
52 also have "a Un (t Un u) = (a Un t) Un u" |
|
53 by (simp only: Un_assoc) |
|
54 finally show ?thesis . |
|
55 qed |
|
56 qed |
|
57 qed |
|
58 |
|
59 |
|
60 subsection {* Basic properties of ``below'' *} |
|
61 |
|
62 constdefs |
|
63 below :: "nat => nat set" |
|
64 "below n == {i. i < n}" |
|
65 |
|
66 lemma below_less_iff [iff]: "(i: below k) = (i < k)" |
|
67 by (simp add: below_def) |
|
68 |
|
69 lemma below_0: "below 0 = {}" |
|
70 by (simp add: below_def) |
|
71 |
|
72 lemma Sigma_Suc1: |
|
73 "m = n + 1 ==> below m <*> B = ({n} <*> B) Un (below n <*> B)" |
|
74 by (simp add: below_def less_Suc_eq) blast |
|
75 |
|
76 lemma Sigma_Suc2: |
|
77 "m = n + 2 ==> A <*> below m = |
|
78 (A <*> {n}) Un (A <*> {n + 1}) Un (A <*> below n)" |
|
79 by (auto simp add: below_def) |
|
80 |
|
81 lemmas Sigma_Suc = Sigma_Suc1 Sigma_Suc2 |
|
82 |
|
83 |
|
84 subsection {* Basic properties of ``evnodd'' *} |
|
85 |
|
86 constdefs |
|
87 evnodd :: "(nat * nat) set => nat => (nat * nat) set" |
|
88 "evnodd A b == A Int {(i, j). (i + j) mod 2 = b}" |
|
89 |
|
90 lemma evnodd_iff: |
|
91 "(i, j): evnodd A b = ((i, j): A & (i + j) mod 2 = b)" |
|
92 by (simp add: evnodd_def) |
|
93 |
|
94 lemma evnodd_subset: "evnodd A b <= A" |
|
95 by (unfold evnodd_def, rule Int_lower1) |
|
96 |
|
97 lemma evnoddD: "x : evnodd A b ==> x : A" |
|
98 by (rule subsetD, rule evnodd_subset) |
|
99 |
|
100 lemma evnodd_finite: "finite A ==> finite (evnodd A b)" |
|
101 by (rule finite_subset, rule evnodd_subset) |
|
102 |
|
103 lemma evnodd_Un: "evnodd (A Un B) b = evnodd A b Un evnodd B b" |
|
104 by (unfold evnodd_def) blast |
|
105 |
|
106 lemma evnodd_Diff: "evnodd (A - B) b = evnodd A b - evnodd B b" |
|
107 by (unfold evnodd_def) blast |
|
108 |
|
109 lemma evnodd_empty: "evnodd {} b = {}" |
|
110 by (simp add: evnodd_def) |
|
111 |
|
112 lemma evnodd_insert: "evnodd (insert (i, j) C) b = |
|
113 (if (i + j) mod 2 = b |
|
114 then insert (i, j) (evnodd C b) else evnodd C b)" |
|
115 by (simp add: evnodd_def) blast |
|
116 |
|
117 |
|
118 subsection {* Dominoes *} |
|
119 |
|
120 inductive_set |
|
121 domino :: "(nat * nat) set set" |
|
122 where |
|
123 horiz: "{(i, j), (i, j + 1)} : domino" |
|
124 | vertl: "{(i, j), (i + 1, j)} : domino" |
|
125 |
|
126 lemma dominoes_tile_row: |
|
127 "{i} <*> below (2 * n) : tiling domino" |
|
128 (is "?B n : ?T") |
|
129 proof (induct n) |
|
130 case 0 |
|
131 show ?case by (simp add: below_0 tiling.empty) |
|
132 next |
|
133 case (Suc n) |
|
134 let ?a = "{i} <*> {2 * n + 1} Un {i} <*> {2 * n}" |
|
135 have "?B (Suc n) = ?a Un ?B n" |
|
136 by (auto simp add: Sigma_Suc Un_assoc) |
|
137 moreover have "... : ?T" |
|
138 proof (rule tiling.Un) |
|
139 have "{(i, 2 * n), (i, 2 * n + 1)} : domino" |
|
140 by (rule domino.horiz) |
|
141 also have "{(i, 2 * n), (i, 2 * n + 1)} = ?a" by blast |
|
142 finally show "... : domino" . |
|
143 show "?B n : ?T" by (rule Suc) |
|
144 show "?a <= - ?B n" by blast |
|
145 qed |
|
146 ultimately show ?case by simp |
|
147 qed |
|
148 |
|
149 lemma dominoes_tile_matrix: |
|
150 "below m <*> below (2 * n) : tiling domino" |
|
151 (is "?B m : ?T") |
|
152 proof (induct m) |
|
153 case 0 |
|
154 show ?case by (simp add: below_0 tiling.empty) |
|
155 next |
|
156 case (Suc m) |
|
157 let ?t = "{m} <*> below (2 * n)" |
|
158 have "?B (Suc m) = ?t Un ?B m" by (simp add: Sigma_Suc) |
|
159 moreover have "... : ?T" |
|
160 proof (rule tiling_Un) |
|
161 show "?t : ?T" by (rule dominoes_tile_row) |
|
162 show "?B m : ?T" by (rule Suc) |
|
163 show "?t Int ?B m = {}" by blast |
|
164 qed |
|
165 ultimately show ?case by simp |
|
166 qed |
|
167 |
|
168 lemma domino_singleton: |
|
169 assumes d: "d : domino" and "b < 2" |
|
170 shows "EX i j. evnodd d b = {(i, j)}" (is "?P d") |
|
171 using d |
|
172 proof induct |
|
173 from `b < 2` have b_cases: "b = 0 | b = 1" by arith |
|
174 fix i j |
|
175 note [simp] = evnodd_empty evnodd_insert mod_Suc |
|
176 from b_cases show "?P {(i, j), (i, j + 1)}" by rule auto |
|
177 from b_cases show "?P {(i, j), (i + 1, j)}" by rule auto |
|
178 qed |
|
179 |
|
180 lemma domino_finite: |
|
181 assumes d: "d: domino" |
|
182 shows "finite d" |
|
183 using d |
|
184 proof induct |
|
185 fix i j :: nat |
|
186 show "finite {(i, j), (i, j + 1)}" by (intro finite.intros) |
|
187 show "finite {(i, j), (i + 1, j)}" by (intro finite.intros) |
|
188 qed |
|
189 |
|
190 |
|
191 subsection {* Tilings of dominoes *} |
|
192 |
|
193 lemma tiling_domino_finite: |
|
194 assumes t: "t : tiling domino" (is "t : ?T") |
|
195 shows "finite t" (is "?F t") |
|
196 using t |
|
197 proof induct |
|
198 show "?F {}" by (rule finite.emptyI) |
|
199 fix a t assume "?F t" |
|
200 assume "a : domino" then have "?F a" by (rule domino_finite) |
|
201 from this and `?F t` show "?F (a Un t)" by (rule finite_UnI) |
|
202 qed |
|
203 |
|
204 lemma tiling_domino_01: |
|
205 assumes t: "t : tiling domino" (is "t : ?T") |
|
206 shows "card (evnodd t 0) = card (evnodd t 1)" |
|
207 using t |
|
208 proof induct |
|
209 case empty |
|
210 show ?case by (simp add: evnodd_def) |
|
211 next |
|
212 case (Un a t) |
|
213 let ?e = evnodd |
|
214 note hyp = `card (?e t 0) = card (?e t 1)` |
|
215 and at = `a <= - t` |
|
216 have card_suc: |
|
217 "!!b. b < 2 ==> card (?e (a Un t) b) = Suc (card (?e t b))" |
|
218 proof - |
|
219 fix b :: nat assume "b < 2" |
|
220 have "?e (a Un t) b = ?e a b Un ?e t b" by (rule evnodd_Un) |
|
221 also obtain i j where e: "?e a b = {(i, j)}" |
|
222 proof - |
|
223 from `a \<in> domino` and `b < 2` |
|
224 have "EX i j. ?e a b = {(i, j)}" by (rule domino_singleton) |
|
225 then show ?thesis by (blast intro: that) |
|
226 qed |
|
227 moreover have "... Un ?e t b = insert (i, j) (?e t b)" by simp |
|
228 moreover have "card ... = Suc (card (?e t b))" |
|
229 proof (rule card_insert_disjoint) |
|
230 from `t \<in> tiling domino` have "finite t" |
|
231 by (rule tiling_domino_finite) |
|
232 then show "finite (?e t b)" |
|
233 by (rule evnodd_finite) |
|
234 from e have "(i, j) : ?e a b" by simp |
|
235 with at show "(i, j) ~: ?e t b" by (blast dest: evnoddD) |
|
236 qed |
|
237 ultimately show "?thesis b" by simp |
|
238 qed |
|
239 then have "card (?e (a Un t) 0) = Suc (card (?e t 0))" by simp |
|
240 also from hyp have "card (?e t 0) = card (?e t 1)" . |
|
241 also from card_suc have "Suc ... = card (?e (a Un t) 1)" |
|
242 by simp |
|
243 finally show ?case . |
|
244 qed |
|
245 |
|
246 |
|
247 subsection {* Main theorem *} |
|
248 |
|
249 constdefs |
|
250 mutilated_board :: "nat => nat => (nat * nat) set" |
|
251 "mutilated_board m n == |
|
252 below (2 * (m + 1)) <*> below (2 * (n + 1)) |
|
253 - {(0, 0)} - {(2 * m + 1, 2 * n + 1)}" |
|
254 |
|
255 theorem mutil_not_tiling: "mutilated_board m n ~: tiling domino" |
|
256 proof (unfold mutilated_board_def) |
|
257 let ?T = "tiling domino" |
|
258 let ?t = "below (2 * (m + 1)) <*> below (2 * (n + 1))" |
|
259 let ?t' = "?t - {(0, 0)}" |
|
260 let ?t'' = "?t' - {(2 * m + 1, 2 * n + 1)}" |
|
261 |
|
262 show "?t'' ~: ?T" |
|
263 proof |
|
264 have t: "?t : ?T" by (rule dominoes_tile_matrix) |
|
265 assume t'': "?t'' : ?T" |
|
266 |
|
267 let ?e = evnodd |
|
268 have fin: "finite (?e ?t 0)" |
|
269 by (rule evnodd_finite, rule tiling_domino_finite, rule t) |
|
270 |
|
271 note [simp] = evnodd_iff evnodd_empty evnodd_insert evnodd_Diff |
|
272 have "card (?e ?t'' 0) < card (?e ?t' 0)" |
|
273 proof - |
|
274 have "card (?e ?t' 0 - {(2 * m + 1, 2 * n + 1)}) |
|
275 < card (?e ?t' 0)" |
|
276 proof (rule card_Diff1_less) |
|
277 from _ fin show "finite (?e ?t' 0)" |
|
278 by (rule finite_subset) auto |
|
279 show "(2 * m + 1, 2 * n + 1) : ?e ?t' 0" by simp |
|
280 qed |
|
281 then show ?thesis by simp |
|
282 qed |
|
283 also have "... < card (?e ?t 0)" |
|
284 proof - |
|
285 have "(0, 0) : ?e ?t 0" by simp |
|
286 with fin have "card (?e ?t 0 - {(0, 0)}) < card (?e ?t 0)" |
|
287 by (rule card_Diff1_less) |
|
288 then show ?thesis by simp |
|
289 qed |
|
290 also from t have "... = card (?e ?t 1)" |
|
291 by (rule tiling_domino_01) |
|
292 also have "?e ?t 1 = ?e ?t'' 1" by simp |
|
293 also from t'' have "card ... = card (?e ?t'' 0)" |
|
294 by (rule tiling_domino_01 [symmetric]) |
|
295 finally have "... < ..." . then show False .. |
|
296 qed |
|
297 qed |
|
298 |
|
299 end |
|