src/HOL/Set.thy
author wenzelm
Fri Jan 06 16:45:19 2012 +0100 (2012-01-06)
changeset 46137 0477785525be
parent 46128 53e7cc599f58
child 46146 6baea4fca6bd
permissions -rw-r--r--
tuned -- more direct @{type_name set} (NB: binder_tr' retains the original non-syntax type for the bound/free variable);
     1 (*  Author:     Tobias Nipkow, Lawrence C Paulson and Markus Wenzel *)
     2 
     3 header {* Set theory for higher-order logic *}
     4 
     5 theory Set
     6 imports Lattices
     7 begin
     8 
     9 subsection {* Sets as predicates *}
    10 
    11 typedecl 'a set
    12 
    13 axiomatization Collect :: "('a \<Rightarrow> bool) \<Rightarrow> 'a set" -- "comprehension"
    14   and member :: "'a \<Rightarrow> 'a set \<Rightarrow> bool" -- "membership"
    15 where
    16   mem_Collect_eq [iff, code_unfold]: "member a (Collect P) = P a"
    17   and Collect_mem_eq [simp]: "Collect (\<lambda>x. member x A) = A"
    18 
    19 notation
    20   member  ("op :") and
    21   member  ("(_/ : _)" [50, 51] 50)
    22 
    23 abbreviation not_member where
    24   "not_member x A \<equiv> ~ (x : A)" -- "non-membership"
    25 
    26 notation
    27   not_member  ("op ~:") and
    28   not_member  ("(_/ ~: _)" [50, 51] 50)
    29 
    30 notation (xsymbols)
    31   member      ("op \<in>") and
    32   member      ("(_/ \<in> _)" [50, 51] 50) and
    33   not_member  ("op \<notin>") and
    34   not_member  ("(_/ \<notin> _)" [50, 51] 50)
    35 
    36 notation (HTML output)
    37   member      ("op \<in>") and
    38   member      ("(_/ \<in> _)" [50, 51] 50) and
    39   not_member  ("op \<notin>") and
    40   not_member  ("(_/ \<notin> _)" [50, 51] 50)
    41 
    42 
    43 text {* Set comprehensions *}
    44 
    45 syntax
    46   "_Coll" :: "pttrn => bool => 'a set"    ("(1{_./ _})")
    47 translations
    48   "{x. P}" == "CONST Collect (%x. P)"
    49 
    50 syntax
    51   "_Collect" :: "idt => 'a set => bool => 'a set"    ("(1{_ :/ _./ _})")
    52 syntax (xsymbols)
    53   "_Collect" :: "idt => 'a set => bool => 'a set"    ("(1{_ \<in>/ _./ _})")
    54 translations
    55   "{x:A. P}" => "{x. x:A & P}"
    56 
    57 lemma CollectI: "P a \<Longrightarrow> a \<in> {x. P x}"
    58   by simp
    59 
    60 lemma CollectD: "a \<in> {x. P x} \<Longrightarrow> P a"
    61   by simp
    62 
    63 lemma Collect_cong: "(\<And>x. P x = Q x) ==> {x. P x} = {x. Q x}"
    64   by simp
    65 
    66 text {*
    67 Simproc for pulling @{text "x=t"} in @{text "{x. \<dots> & x=t & \<dots>}"}
    68 to the front (and similarly for @{text "t=x"}):
    69 *}
    70 
    71 simproc_setup defined_Collect ("{x. P x & Q x}") = {*
    72   fn _ =>
    73     Quantifier1.rearrange_Collect
    74      (rtac @{thm Collect_cong} 1 THEN
    75       rtac @{thm iffI} 1 THEN
    76       ALLGOALS
    77         (EVERY' [REPEAT_DETERM o etac @{thm conjE}, DEPTH_SOLVE_1 o ares_tac @{thms conjI}]))
    78 *}
    79 
    80 lemmas CollectE = CollectD [elim_format]
    81 
    82 lemma set_eqI:
    83   assumes "\<And>x. x \<in> A \<longleftrightarrow> x \<in> B"
    84   shows "A = B"
    85 proof -
    86   from assms have "{x. x \<in> A} = {x. x \<in> B}" by simp
    87   then show ?thesis by simp
    88 qed
    89 
    90 lemma set_eq_iff [no_atp]:
    91   "A = B \<longleftrightarrow> (\<forall>x. x \<in> A \<longleftrightarrow> x \<in> B)"
    92   by (auto intro:set_eqI)
    93 
    94 text {* Lifting of predicate class instances *}
    95 
    96 instantiation set :: (type) boolean_algebra
    97 begin
    98 
    99 definition less_eq_set where
   100   "less_eq_set A B = less_eq (\<lambda>x. member x A) (\<lambda>x. member x B)"
   101 
   102 definition less_set where
   103   "less_set A B = less (\<lambda>x. member x A) (\<lambda>x. member x B)"
   104 
   105 definition inf_set where
   106   "inf_set A B = Collect (inf (\<lambda>x. member x A) (\<lambda>x. member x B))"
   107 
   108 definition sup_set where
   109   "sup_set A B = Collect (sup (\<lambda>x. member x A) (\<lambda>x. member x B))"
   110 
   111 definition bot_set where
   112   "bot = Collect bot"
   113 
   114 definition top_set where
   115   "top = Collect top"
   116 
   117 definition uminus_set where
   118   "uminus A = Collect (uminus (\<lambda>x. member x A))"
   119 
   120 definition minus_set where
   121   "minus_set A B = Collect (minus (\<lambda>x. member x A) (\<lambda>x. member x B))"
   122 
   123 instance proof
   124 qed (simp_all add: less_eq_set_def less_set_def inf_set_def sup_set_def
   125   bot_set_def top_set_def uminus_set_def minus_set_def
   126   less_le_not_le inf_compl_bot sup_compl_top sup_inf_distrib1 diff_eq
   127   set_eqI fun_eq_iff)
   128 
   129 end
   130 
   131 text {* Set enumerations *}
   132 
   133 abbreviation empty :: "'a set" ("{}") where
   134   "{} \<equiv> bot"
   135 
   136 definition insert :: "'a \<Rightarrow> 'a set \<Rightarrow> 'a set" where
   137   insert_compr: "insert a B = {x. x = a \<or> x \<in> B}"
   138 
   139 syntax
   140   "_Finset" :: "args => 'a set"    ("{(_)}")
   141 translations
   142   "{x, xs}" == "CONST insert x {xs}"
   143   "{x}" == "CONST insert x {}"
   144 
   145 
   146 subsection {* Subsets and bounded quantifiers *}
   147 
   148 abbreviation
   149   subset :: "'a set \<Rightarrow> 'a set \<Rightarrow> bool" where
   150   "subset \<equiv> less"
   151 
   152 abbreviation
   153   subset_eq :: "'a set \<Rightarrow> 'a set \<Rightarrow> bool" where
   154   "subset_eq \<equiv> less_eq"
   155 
   156 notation (output)
   157   subset  ("op <") and
   158   subset  ("(_/ < _)" [50, 51] 50) and
   159   subset_eq  ("op <=") and
   160   subset_eq  ("(_/ <= _)" [50, 51] 50)
   161 
   162 notation (xsymbols)
   163   subset  ("op \<subset>") and
   164   subset  ("(_/ \<subset> _)" [50, 51] 50) and
   165   subset_eq  ("op \<subseteq>") and
   166   subset_eq  ("(_/ \<subseteq> _)" [50, 51] 50)
   167 
   168 notation (HTML output)
   169   subset  ("op \<subset>") and
   170   subset  ("(_/ \<subset> _)" [50, 51] 50) and
   171   subset_eq  ("op \<subseteq>") and
   172   subset_eq  ("(_/ \<subseteq> _)" [50, 51] 50)
   173 
   174 abbreviation (input)
   175   supset :: "'a set \<Rightarrow> 'a set \<Rightarrow> bool" where
   176   "supset \<equiv> greater"
   177 
   178 abbreviation (input)
   179   supset_eq :: "'a set \<Rightarrow> 'a set \<Rightarrow> bool" where
   180   "supset_eq \<equiv> greater_eq"
   181 
   182 notation (xsymbols)
   183   supset  ("op \<supset>") and
   184   supset  ("(_/ \<supset> _)" [50, 51] 50) and
   185   supset_eq  ("op \<supseteq>") and
   186   supset_eq  ("(_/ \<supseteq> _)" [50, 51] 50)
   187 
   188 definition Ball :: "'a set \<Rightarrow> ('a \<Rightarrow> bool) \<Rightarrow> bool" where
   189   "Ball A P \<longleftrightarrow> (\<forall>x. x \<in> A \<longrightarrow> P x)"   -- "bounded universal quantifiers"
   190 
   191 definition Bex :: "'a set \<Rightarrow> ('a \<Rightarrow> bool) \<Rightarrow> bool" where
   192   "Bex A P \<longleftrightarrow> (\<exists>x. x \<in> A \<and> P x)"   -- "bounded existential quantifiers"
   193 
   194 syntax
   195   "_Ball"       :: "pttrn => 'a set => bool => bool"      ("(3ALL _:_./ _)" [0, 0, 10] 10)
   196   "_Bex"        :: "pttrn => 'a set => bool => bool"      ("(3EX _:_./ _)" [0, 0, 10] 10)
   197   "_Bex1"       :: "pttrn => 'a set => bool => bool"      ("(3EX! _:_./ _)" [0, 0, 10] 10)
   198   "_Bleast"     :: "id => 'a set => bool => 'a"           ("(3LEAST _:_./ _)" [0, 0, 10] 10)
   199 
   200 syntax (HOL)
   201   "_Ball"       :: "pttrn => 'a set => bool => bool"      ("(3! _:_./ _)" [0, 0, 10] 10)
   202   "_Bex"        :: "pttrn => 'a set => bool => bool"      ("(3? _:_./ _)" [0, 0, 10] 10)
   203   "_Bex1"       :: "pttrn => 'a set => bool => bool"      ("(3?! _:_./ _)" [0, 0, 10] 10)
   204 
   205 syntax (xsymbols)
   206   "_Ball"       :: "pttrn => 'a set => bool => bool"      ("(3\<forall>_\<in>_./ _)" [0, 0, 10] 10)
   207   "_Bex"        :: "pttrn => 'a set => bool => bool"      ("(3\<exists>_\<in>_./ _)" [0, 0, 10] 10)
   208   "_Bex1"       :: "pttrn => 'a set => bool => bool"      ("(3\<exists>!_\<in>_./ _)" [0, 0, 10] 10)
   209   "_Bleast"     :: "id => 'a set => bool => 'a"           ("(3LEAST_\<in>_./ _)" [0, 0, 10] 10)
   210 
   211 syntax (HTML output)
   212   "_Ball"       :: "pttrn => 'a set => bool => bool"      ("(3\<forall>_\<in>_./ _)" [0, 0, 10] 10)
   213   "_Bex"        :: "pttrn => 'a set => bool => bool"      ("(3\<exists>_\<in>_./ _)" [0, 0, 10] 10)
   214   "_Bex1"       :: "pttrn => 'a set => bool => bool"      ("(3\<exists>!_\<in>_./ _)" [0, 0, 10] 10)
   215 
   216 translations
   217   "ALL x:A. P" == "CONST Ball A (%x. P)"
   218   "EX x:A. P" == "CONST Bex A (%x. P)"
   219   "EX! x:A. P" => "EX! x. x:A & P"
   220   "LEAST x:A. P" => "LEAST x. x:A & P"
   221 
   222 syntax (output)
   223   "_setlessAll" :: "[idt, 'a, bool] => bool"  ("(3ALL _<_./ _)"  [0, 0, 10] 10)
   224   "_setlessEx"  :: "[idt, 'a, bool] => bool"  ("(3EX _<_./ _)"  [0, 0, 10] 10)
   225   "_setleAll"   :: "[idt, 'a, bool] => bool"  ("(3ALL _<=_./ _)" [0, 0, 10] 10)
   226   "_setleEx"    :: "[idt, 'a, bool] => bool"  ("(3EX _<=_./ _)" [0, 0, 10] 10)
   227   "_setleEx1"   :: "[idt, 'a, bool] => bool"  ("(3EX! _<=_./ _)" [0, 0, 10] 10)
   228 
   229 syntax (xsymbols)
   230   "_setlessAll" :: "[idt, 'a, bool] => bool"   ("(3\<forall>_\<subset>_./ _)"  [0, 0, 10] 10)
   231   "_setlessEx"  :: "[idt, 'a, bool] => bool"   ("(3\<exists>_\<subset>_./ _)"  [0, 0, 10] 10)
   232   "_setleAll"   :: "[idt, 'a, bool] => bool"   ("(3\<forall>_\<subseteq>_./ _)" [0, 0, 10] 10)
   233   "_setleEx"    :: "[idt, 'a, bool] => bool"   ("(3\<exists>_\<subseteq>_./ _)" [0, 0, 10] 10)
   234   "_setleEx1"   :: "[idt, 'a, bool] => bool"   ("(3\<exists>!_\<subseteq>_./ _)" [0, 0, 10] 10)
   235 
   236 syntax (HOL output)
   237   "_setlessAll" :: "[idt, 'a, bool] => bool"   ("(3! _<_./ _)"  [0, 0, 10] 10)
   238   "_setlessEx"  :: "[idt, 'a, bool] => bool"   ("(3? _<_./ _)"  [0, 0, 10] 10)
   239   "_setleAll"   :: "[idt, 'a, bool] => bool"   ("(3! _<=_./ _)" [0, 0, 10] 10)
   240   "_setleEx"    :: "[idt, 'a, bool] => bool"   ("(3? _<=_./ _)" [0, 0, 10] 10)
   241   "_setleEx1"   :: "[idt, 'a, bool] => bool"   ("(3?! _<=_./ _)" [0, 0, 10] 10)
   242 
   243 syntax (HTML output)
   244   "_setlessAll" :: "[idt, 'a, bool] => bool"   ("(3\<forall>_\<subset>_./ _)"  [0, 0, 10] 10)
   245   "_setlessEx"  :: "[idt, 'a, bool] => bool"   ("(3\<exists>_\<subset>_./ _)"  [0, 0, 10] 10)
   246   "_setleAll"   :: "[idt, 'a, bool] => bool"   ("(3\<forall>_\<subseteq>_./ _)" [0, 0, 10] 10)
   247   "_setleEx"    :: "[idt, 'a, bool] => bool"   ("(3\<exists>_\<subseteq>_./ _)" [0, 0, 10] 10)
   248   "_setleEx1"   :: "[idt, 'a, bool] => bool"   ("(3\<exists>!_\<subseteq>_./ _)" [0, 0, 10] 10)
   249 
   250 translations
   251  "\<forall>A\<subset>B. P"   =>  "ALL A. A \<subset> B --> P"
   252  "\<exists>A\<subset>B. P"   =>  "EX A. A \<subset> B & P"
   253  "\<forall>A\<subseteq>B. P"   =>  "ALL A. A \<subseteq> B --> P"
   254  "\<exists>A\<subseteq>B. P"   =>  "EX A. A \<subseteq> B & P"
   255  "\<exists>!A\<subseteq>B. P"  =>  "EX! A. A \<subseteq> B & P"
   256 
   257 print_translation {*
   258 let
   259   val All_binder = Mixfix.binder_name @{const_syntax All};
   260   val Ex_binder = Mixfix.binder_name @{const_syntax Ex};
   261   val impl = @{const_syntax HOL.implies};
   262   val conj = @{const_syntax HOL.conj};
   263   val sbset = @{const_syntax subset};
   264   val sbset_eq = @{const_syntax subset_eq};
   265 
   266   val trans =
   267    [((All_binder, impl, sbset), @{syntax_const "_setlessAll"}),
   268     ((All_binder, impl, sbset_eq), @{syntax_const "_setleAll"}),
   269     ((Ex_binder, conj, sbset), @{syntax_const "_setlessEx"}),
   270     ((Ex_binder, conj, sbset_eq), @{syntax_const "_setleEx"})];
   271 
   272   fun mk v v' c n P =
   273     if v = v' andalso not (Term.exists_subterm (fn Free (x, _) => x = v | _ => false) n)
   274     then Syntax.const c $ Syntax_Trans.mark_bound v' $ n $ P else raise Match;
   275 
   276   fun tr' q = (q,
   277         fn [Const (@{syntax_const "_bound"}, _) $ Free (v, Type (@{type_name set}, _)),
   278             Const (c, _) $
   279               (Const (d, _) $ (Const (@{syntax_const "_bound"}, _) $ Free (v', _)) $ n) $ P] =>
   280             (case AList.lookup (op =) trans (q, c, d) of
   281               NONE => raise Match
   282             | SOME l => mk v v' l n P)
   283          | _ => raise Match);
   284 in
   285   [tr' All_binder, tr' Ex_binder]
   286 end
   287 *}
   288 
   289 
   290 text {*
   291   \medskip Translate between @{text "{e | x1...xn. P}"} and @{text
   292   "{u. EX x1..xn. u = e & P}"}; @{text "{y. EX x1..xn. y = e & P}"} is
   293   only translated if @{text "[0..n] subset bvs(e)"}.
   294 *}
   295 
   296 syntax
   297   "_Setcompr" :: "'a => idts => bool => 'a set"    ("(1{_ |/_./ _})")
   298 
   299 parse_translation {*
   300   let
   301     val ex_tr = snd (Syntax_Trans.mk_binder_tr ("EX ", @{const_syntax Ex}));
   302 
   303     fun nvars (Const (@{syntax_const "_idts"}, _) $ _ $ idts) = nvars idts + 1
   304       | nvars _ = 1;
   305 
   306     fun setcompr_tr [e, idts, b] =
   307       let
   308         val eq = Syntax.const @{const_syntax HOL.eq} $ Bound (nvars idts) $ e;
   309         val P = Syntax.const @{const_syntax HOL.conj} $ eq $ b;
   310         val exP = ex_tr [idts, P];
   311       in Syntax.const @{const_syntax Collect} $ absdummy dummyT exP end;
   312 
   313   in [(@{syntax_const "_Setcompr"}, setcompr_tr)] end;
   314 *}
   315 
   316 print_translation {*
   317  [Syntax_Trans.preserve_binder_abs2_tr' @{const_syntax Ball} @{syntax_const "_Ball"},
   318   Syntax_Trans.preserve_binder_abs2_tr' @{const_syntax Bex} @{syntax_const "_Bex"}]
   319 *} -- {* to avoid eta-contraction of body *}
   320 
   321 print_translation {*
   322 let
   323   val ex_tr' = snd (Syntax_Trans.mk_binder_tr' (@{const_syntax Ex}, "DUMMY"));
   324 
   325   fun setcompr_tr' [Abs (abs as (_, _, P))] =
   326     let
   327       fun check (Const (@{const_syntax Ex}, _) $ Abs (_, _, P), n) = check (P, n + 1)
   328         | check (Const (@{const_syntax HOL.conj}, _) $
   329               (Const (@{const_syntax HOL.eq}, _) $ Bound m $ e) $ P, n) =
   330             n > 0 andalso m = n andalso not (loose_bvar1 (P, n)) andalso
   331             subset (op =) (0 upto (n - 1), add_loose_bnos (e, 0, []))
   332         | check _ = false;
   333 
   334         fun tr' (_ $ abs) =
   335           let val _ $ idts $ (_ $ (_ $ _ $ e) $ Q) = ex_tr' [abs]
   336           in Syntax.const @{syntax_const "_Setcompr"} $ e $ idts $ Q end;
   337     in
   338       if check (P, 0) then tr' P
   339       else
   340         let
   341           val (x as _ $ Free(xN, _), t) = Syntax_Trans.atomic_abs_tr' abs;
   342           val M = Syntax.const @{syntax_const "_Coll"} $ x $ t;
   343         in
   344           case t of
   345             Const (@{const_syntax HOL.conj}, _) $
   346               (Const (@{const_syntax Set.member}, _) $
   347                 (Const (@{syntax_const "_bound"}, _) $ Free (yN, _)) $ A) $ P =>
   348             if xN = yN then Syntax.const @{syntax_const "_Collect"} $ x $ A $ P else M
   349           | _ => M
   350         end
   351     end;
   352   in [(@{const_syntax Collect}, setcompr_tr')] end;
   353 *}
   354 
   355 simproc_setup defined_Bex ("EX x:A. P x & Q x") = {*
   356   let
   357     val unfold_bex_tac = unfold_tac @{thms Bex_def};
   358     fun prove_bex_tac ss = unfold_bex_tac ss THEN Quantifier1.prove_one_point_ex_tac;
   359   in fn _ => fn ss => Quantifier1.rearrange_bex (prove_bex_tac ss) ss end
   360 *}
   361 
   362 simproc_setup defined_All ("ALL x:A. P x --> Q x") = {*
   363   let
   364     val unfold_ball_tac = unfold_tac @{thms Ball_def};
   365     fun prove_ball_tac ss = unfold_ball_tac ss THEN Quantifier1.prove_one_point_all_tac;
   366   in fn _ => fn ss => Quantifier1.rearrange_ball (prove_ball_tac ss) ss end
   367 *}
   368 
   369 lemma ballI [intro!]: "(!!x. x:A ==> P x) ==> ALL x:A. P x"
   370   by (simp add: Ball_def)
   371 
   372 lemmas strip = impI allI ballI
   373 
   374 lemma bspec [dest?]: "ALL x:A. P x ==> x:A ==> P x"
   375   by (simp add: Ball_def)
   376 
   377 text {*
   378   Gives better instantiation for bound:
   379 *}
   380 
   381 declaration {* fn _ =>
   382   Classical.map_cs (fn cs => cs addbefore ("bspec", datac @{thm bspec} 1))
   383 *}
   384 
   385 ML {*
   386 structure Simpdata =
   387 struct
   388 
   389 open Simpdata;
   390 
   391 val mksimps_pairs = [(@{const_name Ball}, @{thms bspec})] @ mksimps_pairs;
   392 
   393 end;
   394 
   395 open Simpdata;
   396 *}
   397 
   398 declaration {* fn _ =>
   399   Simplifier.map_ss (Simplifier.set_mksimps (mksimps mksimps_pairs))
   400 *}
   401 
   402 lemma ballE [elim]: "ALL x:A. P x ==> (P x ==> Q) ==> (x ~: A ==> Q) ==> Q"
   403   by (unfold Ball_def) blast
   404 
   405 lemma bexI [intro]: "P x ==> x:A ==> EX x:A. P x"
   406   -- {* Normally the best argument order: @{prop "P x"} constrains the
   407     choice of @{prop "x:A"}. *}
   408   by (unfold Bex_def) blast
   409 
   410 lemma rev_bexI [intro?]: "x:A ==> P x ==> EX x:A. P x"
   411   -- {* The best argument order when there is only one @{prop "x:A"}. *}
   412   by (unfold Bex_def) blast
   413 
   414 lemma bexCI: "(ALL x:A. ~P x ==> P a) ==> a:A ==> EX x:A. P x"
   415   by (unfold Bex_def) blast
   416 
   417 lemma bexE [elim!]: "EX x:A. P x ==> (!!x. x:A ==> P x ==> Q) ==> Q"
   418   by (unfold Bex_def) blast
   419 
   420 lemma ball_triv [simp]: "(ALL x:A. P) = ((EX x. x:A) --> P)"
   421   -- {* Trival rewrite rule. *}
   422   by (simp add: Ball_def)
   423 
   424 lemma bex_triv [simp]: "(EX x:A. P) = ((EX x. x:A) & P)"
   425   -- {* Dual form for existentials. *}
   426   by (simp add: Bex_def)
   427 
   428 lemma bex_triv_one_point1 [simp]: "(EX x:A. x = a) = (a:A)"
   429   by blast
   430 
   431 lemma bex_triv_one_point2 [simp]: "(EX x:A. a = x) = (a:A)"
   432   by blast
   433 
   434 lemma bex_one_point1 [simp]: "(EX x:A. x = a & P x) = (a:A & P a)"
   435   by blast
   436 
   437 lemma bex_one_point2 [simp]: "(EX x:A. a = x & P x) = (a:A & P a)"
   438   by blast
   439 
   440 lemma ball_one_point1 [simp]: "(ALL x:A. x = a --> P x) = (a:A --> P a)"
   441   by blast
   442 
   443 lemma ball_one_point2 [simp]: "(ALL x:A. a = x --> P x) = (a:A --> P a)"
   444   by blast
   445 
   446 lemma ball_conj_distrib:
   447   "(\<forall>x\<in>A. P x \<and> Q x) \<longleftrightarrow> ((\<forall>x\<in>A. P x) \<and> (\<forall>x\<in>A. Q x))"
   448   by blast
   449 
   450 lemma bex_disj_distrib:
   451   "(\<exists>x\<in>A. P x \<or> Q x) \<longleftrightarrow> ((\<exists>x\<in>A. P x) \<or> (\<exists>x\<in>A. Q x))"
   452   by blast
   453 
   454 
   455 text {* Congruence rules *}
   456 
   457 lemma ball_cong:
   458   "A = B ==> (!!x. x:B ==> P x = Q x) ==>
   459     (ALL x:A. P x) = (ALL x:B. Q x)"
   460   by (simp add: Ball_def)
   461 
   462 lemma strong_ball_cong [cong]:
   463   "A = B ==> (!!x. x:B =simp=> P x = Q x) ==>
   464     (ALL x:A. P x) = (ALL x:B. Q x)"
   465   by (simp add: simp_implies_def Ball_def)
   466 
   467 lemma bex_cong:
   468   "A = B ==> (!!x. x:B ==> P x = Q x) ==>
   469     (EX x:A. P x) = (EX x:B. Q x)"
   470   by (simp add: Bex_def cong: conj_cong)
   471 
   472 lemma strong_bex_cong [cong]:
   473   "A = B ==> (!!x. x:B =simp=> P x = Q x) ==>
   474     (EX x:A. P x) = (EX x:B. Q x)"
   475   by (simp add: simp_implies_def Bex_def cong: conj_cong)
   476 
   477 
   478 subsection {* Basic operations *}
   479 
   480 subsubsection {* Subsets *}
   481 
   482 lemma subsetI [intro!]: "(\<And>x. x \<in> A \<Longrightarrow> x \<in> B) \<Longrightarrow> A \<subseteq> B"
   483   by (simp add: less_eq_set_def le_fun_def)
   484 
   485 text {*
   486   \medskip Map the type @{text "'a set => anything"} to just @{typ
   487   'a}; for overloading constants whose first argument has type @{typ
   488   "'a set"}.
   489 *}
   490 
   491 lemma subsetD [elim, intro?]: "A \<subseteq> B ==> c \<in> A ==> c \<in> B"
   492   by (simp add: less_eq_set_def le_fun_def)
   493   -- {* Rule in Modus Ponens style. *}
   494 
   495 lemma rev_subsetD [no_atp,intro?]: "c \<in> A ==> A \<subseteq> B ==> c \<in> B"
   496   -- {* The same, with reversed premises for use with @{text erule} --
   497       cf @{text rev_mp}. *}
   498   by (rule subsetD)
   499 
   500 text {*
   501   \medskip Converts @{prop "A \<subseteq> B"} to @{prop "x \<in> A ==> x \<in> B"}.
   502 *}
   503 
   504 lemma subsetCE [no_atp,elim]: "A \<subseteq> B ==> (c \<notin> A ==> P) ==> (c \<in> B ==> P) ==> P"
   505   -- {* Classical elimination rule. *}
   506   by (auto simp add: less_eq_set_def le_fun_def)
   507 
   508 lemma subset_eq [code, no_atp]: "A \<le> B = (\<forall>x\<in>A. x \<in> B)" by blast
   509 
   510 lemma contra_subsetD [no_atp]: "A \<subseteq> B ==> c \<notin> B ==> c \<notin> A"
   511   by blast
   512 
   513 lemma subset_refl: "A \<subseteq> A"
   514   by (fact order_refl) (* already [iff] *)
   515 
   516 lemma subset_trans: "A \<subseteq> B ==> B \<subseteq> C ==> A \<subseteq> C"
   517   by (fact order_trans)
   518 
   519 lemma set_rev_mp: "x:A ==> A \<subseteq> B ==> x:B"
   520   by (rule subsetD)
   521 
   522 lemma set_mp: "A \<subseteq> B ==> x:A ==> x:B"
   523   by (rule subsetD)
   524 
   525 lemma eq_mem_trans: "a=b ==> b \<in> A ==> a \<in> A"
   526   by simp
   527 
   528 lemmas basic_trans_rules [trans] =
   529   order_trans_rules set_rev_mp set_mp eq_mem_trans
   530 
   531 
   532 subsubsection {* Equality *}
   533 
   534 lemma subset_antisym [intro!]: "A \<subseteq> B ==> B \<subseteq> A ==> A = B"
   535   -- {* Anti-symmetry of the subset relation. *}
   536   by (iprover intro: set_eqI subsetD)
   537 
   538 text {*
   539   \medskip Equality rules from ZF set theory -- are they appropriate
   540   here?
   541 *}
   542 
   543 lemma equalityD1: "A = B ==> A \<subseteq> B"
   544   by simp
   545 
   546 lemma equalityD2: "A = B ==> B \<subseteq> A"
   547   by simp
   548 
   549 text {*
   550   \medskip Be careful when adding this to the claset as @{text
   551   subset_empty} is in the simpset: @{prop "A = {}"} goes to @{prop "{}
   552   \<subseteq> A"} and @{prop "A \<subseteq> {}"} and then back to @{prop "A = {}"}!
   553 *}
   554 
   555 lemma equalityE: "A = B ==> (A \<subseteq> B ==> B \<subseteq> A ==> P) ==> P"
   556   by simp
   557 
   558 lemma equalityCE [elim]:
   559     "A = B ==> (c \<in> A ==> c \<in> B ==> P) ==> (c \<notin> A ==> c \<notin> B ==> P) ==> P"
   560   by blast
   561 
   562 lemma eqset_imp_iff: "A = B ==> (x : A) = (x : B)"
   563   by simp
   564 
   565 lemma eqelem_imp_iff: "x = y ==> (x : A) = (y : A)"
   566   by simp
   567 
   568 
   569 subsubsection {* The empty set *}
   570 
   571 lemma empty_def:
   572   "{} = {x. False}"
   573   by (simp add: bot_set_def bot_fun_def)
   574 
   575 lemma empty_iff [simp]: "(c : {}) = False"
   576   by (simp add: empty_def)
   577 
   578 lemma emptyE [elim!]: "a : {} ==> P"
   579   by simp
   580 
   581 lemma empty_subsetI [iff]: "{} \<subseteq> A"
   582     -- {* One effect is to delete the ASSUMPTION @{prop "{} <= A"} *}
   583   by blast
   584 
   585 lemma equals0I: "(!!y. y \<in> A ==> False) ==> A = {}"
   586   by blast
   587 
   588 lemma equals0D: "A = {} ==> a \<notin> A"
   589     -- {* Use for reasoning about disjointness: @{text "A Int B = {}"} *}
   590   by blast
   591 
   592 lemma ball_empty [simp]: "Ball {} P = True"
   593   by (simp add: Ball_def)
   594 
   595 lemma bex_empty [simp]: "Bex {} P = False"
   596   by (simp add: Bex_def)
   597 
   598 
   599 subsubsection {* The universal set -- UNIV *}
   600 
   601 abbreviation UNIV :: "'a set" where
   602   "UNIV \<equiv> top"
   603 
   604 lemma UNIV_def:
   605   "UNIV = {x. True}"
   606   by (simp add: top_set_def top_fun_def)
   607 
   608 lemma UNIV_I [simp]: "x : UNIV"
   609   by (simp add: UNIV_def)
   610 
   611 declare UNIV_I [intro]  -- {* unsafe makes it less likely to cause problems *}
   612 
   613 lemma UNIV_witness [intro?]: "EX x. x : UNIV"
   614   by simp
   615 
   616 lemma subset_UNIV: "A \<subseteq> UNIV"
   617   by (fact top_greatest) (* already simp *)
   618 
   619 text {*
   620   \medskip Eta-contracting these two rules (to remove @{text P})
   621   causes them to be ignored because of their interaction with
   622   congruence rules.
   623 *}
   624 
   625 lemma ball_UNIV [simp]: "Ball UNIV P = All P"
   626   by (simp add: Ball_def)
   627 
   628 lemma bex_UNIV [simp]: "Bex UNIV P = Ex P"
   629   by (simp add: Bex_def)
   630 
   631 lemma UNIV_eq_I: "(\<And>x. x \<in> A) \<Longrightarrow> UNIV = A"
   632   by auto
   633 
   634 lemma UNIV_not_empty [iff]: "UNIV ~= {}"
   635   by (blast elim: equalityE)
   636 
   637 
   638 subsubsection {* The Powerset operator -- Pow *}
   639 
   640 definition Pow :: "'a set => 'a set set" where
   641   Pow_def: "Pow A = {B. B \<le> A}"
   642 
   643 lemma Pow_iff [iff]: "(A \<in> Pow B) = (A \<subseteq> B)"
   644   by (simp add: Pow_def)
   645 
   646 lemma PowI: "A \<subseteq> B ==> A \<in> Pow B"
   647   by (simp add: Pow_def)
   648 
   649 lemma PowD: "A \<in> Pow B ==> A \<subseteq> B"
   650   by (simp add: Pow_def)
   651 
   652 lemma Pow_bottom: "{} \<in> Pow B"
   653   by simp
   654 
   655 lemma Pow_top: "A \<in> Pow A"
   656   by simp
   657 
   658 lemma Pow_not_empty: "Pow A \<noteq> {}"
   659   using Pow_top by blast
   660 
   661 
   662 subsubsection {* Set complement *}
   663 
   664 lemma Compl_iff [simp]: "(c \<in> -A) = (c \<notin> A)"
   665   by (simp add: fun_Compl_def uminus_set_def)
   666 
   667 lemma ComplI [intro!]: "(c \<in> A ==> False) ==> c \<in> -A"
   668   by (simp add: fun_Compl_def uminus_set_def) blast
   669 
   670 text {*
   671   \medskip This form, with negated conclusion, works well with the
   672   Classical prover.  Negated assumptions behave like formulae on the
   673   right side of the notional turnstile ... *}
   674 
   675 lemma ComplD [dest!]: "c : -A ==> c~:A"
   676   by simp
   677 
   678 lemmas ComplE = ComplD [elim_format]
   679 
   680 lemma Compl_eq: "- A = {x. ~ x : A}"
   681   by blast
   682 
   683 
   684 subsubsection {* Binary intersection *}
   685 
   686 abbreviation inter :: "'a set \<Rightarrow> 'a set \<Rightarrow> 'a set" (infixl "Int" 70) where
   687   "op Int \<equiv> inf"
   688 
   689 notation (xsymbols)
   690   inter  (infixl "\<inter>" 70)
   691 
   692 notation (HTML output)
   693   inter  (infixl "\<inter>" 70)
   694 
   695 lemma Int_def:
   696   "A \<inter> B = {x. x \<in> A \<and> x \<in> B}"
   697   by (simp add: inf_set_def inf_fun_def)
   698 
   699 lemma Int_iff [simp]: "(c : A Int B) = (c:A & c:B)"
   700   by (unfold Int_def) blast
   701 
   702 lemma IntI [intro!]: "c:A ==> c:B ==> c : A Int B"
   703   by simp
   704 
   705 lemma IntD1: "c : A Int B ==> c:A"
   706   by simp
   707 
   708 lemma IntD2: "c : A Int B ==> c:B"
   709   by simp
   710 
   711 lemma IntE [elim!]: "c : A Int B ==> (c:A ==> c:B ==> P) ==> P"
   712   by simp
   713 
   714 lemma mono_Int: "mono f \<Longrightarrow> f (A \<inter> B) \<subseteq> f A \<inter> f B"
   715   by (fact mono_inf)
   716 
   717 
   718 subsubsection {* Binary union *}
   719 
   720 abbreviation union :: "'a set \<Rightarrow> 'a set \<Rightarrow> 'a set" (infixl "Un" 65) where
   721   "union \<equiv> sup"
   722 
   723 notation (xsymbols)
   724   union  (infixl "\<union>" 65)
   725 
   726 notation (HTML output)
   727   union  (infixl "\<union>" 65)
   728 
   729 lemma Un_def:
   730   "A \<union> B = {x. x \<in> A \<or> x \<in> B}"
   731   by (simp add: sup_set_def sup_fun_def)
   732 
   733 lemma Un_iff [simp]: "(c : A Un B) = (c:A | c:B)"
   734   by (unfold Un_def) blast
   735 
   736 lemma UnI1 [elim?]: "c:A ==> c : A Un B"
   737   by simp
   738 
   739 lemma UnI2 [elim?]: "c:B ==> c : A Un B"
   740   by simp
   741 
   742 text {*
   743   \medskip Classical introduction rule: no commitment to @{prop A} vs
   744   @{prop B}.
   745 *}
   746 
   747 lemma UnCI [intro!]: "(c~:B ==> c:A) ==> c : A Un B"
   748   by auto
   749 
   750 lemma UnE [elim!]: "c : A Un B ==> (c:A ==> P) ==> (c:B ==> P) ==> P"
   751   by (unfold Un_def) blast
   752 
   753 lemma insert_def: "insert a B = {x. x = a} \<union> B"
   754   by (simp add: insert_compr Un_def)
   755 
   756 lemma mono_Un: "mono f \<Longrightarrow> f A \<union> f B \<subseteq> f (A \<union> B)"
   757   by (fact mono_sup)
   758 
   759 
   760 subsubsection {* Set difference *}
   761 
   762 lemma Diff_iff [simp]: "(c : A - B) = (c:A & c~:B)"
   763   by (simp add: minus_set_def fun_diff_def)
   764 
   765 lemma DiffI [intro!]: "c : A ==> c ~: B ==> c : A - B"
   766   by simp
   767 
   768 lemma DiffD1: "c : A - B ==> c : A"
   769   by simp
   770 
   771 lemma DiffD2: "c : A - B ==> c : B ==> P"
   772   by simp
   773 
   774 lemma DiffE [elim!]: "c : A - B ==> (c:A ==> c~:B ==> P) ==> P"
   775   by simp
   776 
   777 lemma set_diff_eq: "A - B = {x. x : A & ~ x : B}" by blast
   778 
   779 lemma Compl_eq_Diff_UNIV: "-A = (UNIV - A)"
   780 by blast
   781 
   782 
   783 subsubsection {* Augmenting a set -- @{const insert} *}
   784 
   785 lemma insert_iff [simp]: "(a : insert b A) = (a = b | a:A)"
   786   by (unfold insert_def) blast
   787 
   788 lemma insertI1: "a : insert a B"
   789   by simp
   790 
   791 lemma insertI2: "a : B ==> a : insert b B"
   792   by simp
   793 
   794 lemma insertE [elim!]: "a : insert b A ==> (a = b ==> P) ==> (a:A ==> P) ==> P"
   795   by (unfold insert_def) blast
   796 
   797 lemma insertCI [intro!]: "(a~:B ==> a = b) ==> a: insert b B"
   798   -- {* Classical introduction rule. *}
   799   by auto
   800 
   801 lemma subset_insert_iff: "(A \<subseteq> insert x B) = (if x:A then A - {x} \<subseteq> B else A \<subseteq> B)"
   802   by auto
   803 
   804 lemma set_insert:
   805   assumes "x \<in> A"
   806   obtains B where "A = insert x B" and "x \<notin> B"
   807 proof
   808   from assms show "A = insert x (A - {x})" by blast
   809 next
   810   show "x \<notin> A - {x}" by blast
   811 qed
   812 
   813 lemma insert_ident: "x ~: A ==> x ~: B ==> (insert x A = insert x B) = (A = B)"
   814 by auto
   815 
   816 lemma insert_eq_iff: assumes "a \<notin> A" "b \<notin> B"
   817 shows "insert a A = insert b B \<longleftrightarrow>
   818   (if a=b then A=B else \<exists>C. A = insert b C \<and> b \<notin> C \<and> B = insert a C \<and> a \<notin> C)"
   819   (is "?L \<longleftrightarrow> ?R")
   820 proof
   821   assume ?L
   822   show ?R
   823   proof cases
   824     assume "a=b" with assms `?L` show ?R by (simp add: insert_ident)
   825   next
   826     assume "a\<noteq>b"
   827     let ?C = "A - {b}"
   828     have "A = insert b ?C \<and> b \<notin> ?C \<and> B = insert a ?C \<and> a \<notin> ?C"
   829       using assms `?L` `a\<noteq>b` by auto
   830     thus ?R using `a\<noteq>b` by auto
   831   qed
   832 next
   833   assume ?R thus ?L by (auto split: if_splits)
   834 qed
   835 
   836 subsubsection {* Singletons, using insert *}
   837 
   838 lemma singletonI [intro!,no_atp]: "a : {a}"
   839     -- {* Redundant? But unlike @{text insertCI}, it proves the subgoal immediately! *}
   840   by (rule insertI1)
   841 
   842 lemma singletonD [dest!,no_atp]: "b : {a} ==> b = a"
   843   by blast
   844 
   845 lemmas singletonE = singletonD [elim_format]
   846 
   847 lemma singleton_iff: "(b : {a}) = (b = a)"
   848   by blast
   849 
   850 lemma singleton_inject [dest!]: "{a} = {b} ==> a = b"
   851   by blast
   852 
   853 lemma singleton_insert_inj_eq [iff,no_atp]:
   854      "({b} = insert a A) = (a = b & A \<subseteq> {b})"
   855   by blast
   856 
   857 lemma singleton_insert_inj_eq' [iff,no_atp]:
   858      "(insert a A = {b}) = (a = b & A \<subseteq> {b})"
   859   by blast
   860 
   861 lemma subset_singletonD: "A \<subseteq> {x} ==> A = {} | A = {x}"
   862   by fast
   863 
   864 lemma singleton_conv [simp]: "{x. x = a} = {a}"
   865   by blast
   866 
   867 lemma singleton_conv2 [simp]: "{x. a = x} = {a}"
   868   by blast
   869 
   870 lemma diff_single_insert: "A - {x} \<subseteq> B ==> x \<in> A ==> A \<subseteq> insert x B"
   871   by blast
   872 
   873 lemma doubleton_eq_iff: "({a,b} = {c,d}) = (a=c & b=d | a=d & b=c)"
   874   by (blast elim: equalityE)
   875 
   876 
   877 subsubsection {* Image of a set under a function *}
   878 
   879 text {*
   880   Frequently @{term b} does not have the syntactic form of @{term "f x"}.
   881 *}
   882 
   883 definition image :: "('a => 'b) => 'a set => 'b set" (infixr "`" 90) where
   884   image_def [no_atp]: "f ` A = {y. EX x:A. y = f(x)}"
   885 
   886 abbreviation
   887   range :: "('a => 'b) => 'b set" where -- "of function"
   888   "range f == f ` UNIV"
   889 
   890 lemma image_eqI [simp, intro]: "b = f x ==> x:A ==> b : f`A"
   891   by (unfold image_def) blast
   892 
   893 lemma imageI: "x : A ==> f x : f ` A"
   894   by (rule image_eqI) (rule refl)
   895 
   896 lemma rev_image_eqI: "x:A ==> b = f x ==> b : f`A"
   897   -- {* This version's more effective when we already have the
   898     required @{term x}. *}
   899   by (unfold image_def) blast
   900 
   901 lemma imageE [elim!]:
   902   "b : (%x. f x)`A ==> (!!x. b = f x ==> x:A ==> P) ==> P"
   903   -- {* The eta-expansion gives variable-name preservation. *}
   904   by (unfold image_def) blast
   905 
   906 lemma image_Un: "f`(A Un B) = f`A Un f`B"
   907   by blast
   908 
   909 lemma image_iff: "(z : f`A) = (EX x:A. z = f x)"
   910   by blast
   911 
   912 lemma image_subset_iff [no_atp]: "(f`A \<subseteq> B) = (\<forall>x\<in>A. f x \<in> B)"
   913   -- {* This rewrite rule would confuse users if made default. *}
   914   by blast
   915 
   916 lemma subset_image_iff: "(B \<subseteq> f`A) = (EX AA. AA \<subseteq> A & B = f`AA)"
   917   apply safe
   918    prefer 2 apply fast
   919   apply (rule_tac x = "{a. a : A & f a : B}" in exI, fast)
   920   done
   921 
   922 lemma image_subsetI: "(!!x. x \<in> A ==> f x \<in> B) ==> f`A \<subseteq> B"
   923   -- {* Replaces the three steps @{text subsetI}, @{text imageE},
   924     @{text hypsubst}, but breaks too many existing proofs. *}
   925   by blast
   926 
   927 text {*
   928   \medskip Range of a function -- just a translation for image!
   929 *}
   930 
   931 lemma image_ident [simp]: "(%x. x) ` Y = Y"
   932   by blast
   933 
   934 lemma range_eqI: "b = f x ==> b \<in> range f"
   935   by simp
   936 
   937 lemma rangeI: "f x \<in> range f"
   938   by simp
   939 
   940 lemma rangeE [elim?]: "b \<in> range (\<lambda>x. f x) ==> (!!x. b = f x ==> P) ==> P"
   941   by blast
   942 
   943 subsubsection {* Some rules with @{text "if"} *}
   944 
   945 text{* Elimination of @{text"{x. \<dots> & x=t & \<dots>}"}. *}
   946 
   947 lemma Collect_conv_if: "{x. x=a & P x} = (if P a then {a} else {})"
   948   by auto
   949 
   950 lemma Collect_conv_if2: "{x. a=x & P x} = (if P a then {a} else {})"
   951   by auto
   952 
   953 text {*
   954   Rewrite rules for boolean case-splitting: faster than @{text
   955   "split_if [split]"}.
   956 *}
   957 
   958 lemma split_if_eq1: "((if Q then x else y) = b) = ((Q --> x = b) & (~ Q --> y = b))"
   959   by (rule split_if)
   960 
   961 lemma split_if_eq2: "(a = (if Q then x else y)) = ((Q --> a = x) & (~ Q --> a = y))"
   962   by (rule split_if)
   963 
   964 text {*
   965   Split ifs on either side of the membership relation.  Not for @{text
   966   "[simp]"} -- can cause goals to blow up!
   967 *}
   968 
   969 lemma split_if_mem1: "((if Q then x else y) : b) = ((Q --> x : b) & (~ Q --> y : b))"
   970   by (rule split_if)
   971 
   972 lemma split_if_mem2: "(a : (if Q then x else y)) = ((Q --> a : x) & (~ Q --> a : y))"
   973   by (rule split_if [where P="%S. a : S"])
   974 
   975 lemmas split_ifs = if_bool_eq_conj split_if_eq1 split_if_eq2 split_if_mem1 split_if_mem2
   976 
   977 (*Would like to add these, but the existing code only searches for the
   978   outer-level constant, which in this case is just Set.member; we instead need
   979   to use term-nets to associate patterns with rules.  Also, if a rule fails to
   980   apply, then the formula should be kept.
   981   [("uminus", Compl_iff RS iffD1), ("minus", [Diff_iff RS iffD1]),
   982    ("Int", [IntD1,IntD2]),
   983    ("Collect", [CollectD]), ("Inter", [InterD]), ("INTER", [INT_D])]
   984  *)
   985 
   986 
   987 subsection {* Further operations and lemmas *}
   988 
   989 subsubsection {* The ``proper subset'' relation *}
   990 
   991 lemma psubsetI [intro!,no_atp]: "A \<subseteq> B ==> A \<noteq> B ==> A \<subset> B"
   992   by (unfold less_le) blast
   993 
   994 lemma psubsetE [elim!,no_atp]: 
   995     "[|A \<subset> B;  [|A \<subseteq> B; ~ (B\<subseteq>A)|] ==> R|] ==> R"
   996   by (unfold less_le) blast
   997 
   998 lemma psubset_insert_iff:
   999   "(A \<subset> insert x B) = (if x \<in> B then A \<subset> B else if x \<in> A then A - {x} \<subset> B else A \<subseteq> B)"
  1000   by (auto simp add: less_le subset_insert_iff)
  1001 
  1002 lemma psubset_eq: "(A \<subset> B) = (A \<subseteq> B & A \<noteq> B)"
  1003   by (simp only: less_le)
  1004 
  1005 lemma psubset_imp_subset: "A \<subset> B ==> A \<subseteq> B"
  1006   by (simp add: psubset_eq)
  1007 
  1008 lemma psubset_trans: "[| A \<subset> B; B \<subset> C |] ==> A \<subset> C"
  1009 apply (unfold less_le)
  1010 apply (auto dest: subset_antisym)
  1011 done
  1012 
  1013 lemma psubsetD: "[| A \<subset> B; c \<in> A |] ==> c \<in> B"
  1014 apply (unfold less_le)
  1015 apply (auto dest: subsetD)
  1016 done
  1017 
  1018 lemma psubset_subset_trans: "A \<subset> B ==> B \<subseteq> C ==> A \<subset> C"
  1019   by (auto simp add: psubset_eq)
  1020 
  1021 lemma subset_psubset_trans: "A \<subseteq> B ==> B \<subset> C ==> A \<subset> C"
  1022   by (auto simp add: psubset_eq)
  1023 
  1024 lemma psubset_imp_ex_mem: "A \<subset> B ==> \<exists>b. b \<in> (B - A)"
  1025   by (unfold less_le) blast
  1026 
  1027 lemma atomize_ball:
  1028     "(!!x. x \<in> A ==> P x) == Trueprop (\<forall>x\<in>A. P x)"
  1029   by (simp only: Ball_def atomize_all atomize_imp)
  1030 
  1031 lemmas [symmetric, rulify] = atomize_ball
  1032   and [symmetric, defn] = atomize_ball
  1033 
  1034 lemma image_Pow_mono:
  1035   assumes "f ` A \<le> B"
  1036   shows "(image f) ` (Pow A) \<le> Pow B"
  1037 using assms by blast
  1038 
  1039 lemma image_Pow_surj:
  1040   assumes "f ` A = B"
  1041   shows "(image f) ` (Pow A) = Pow B"
  1042 using assms unfolding Pow_def proof(auto)
  1043   fix Y assume *: "Y \<le> f ` A"
  1044   obtain X where X_def: "X = {x \<in> A. f x \<in> Y}" by blast
  1045   have "f ` X = Y \<and> X \<le> A" unfolding X_def using * by auto
  1046   thus "Y \<in> (image f) ` {X. X \<le> A}" by blast
  1047 qed
  1048 
  1049 subsubsection {* Derived rules involving subsets. *}
  1050 
  1051 text {* @{text insert}. *}
  1052 
  1053 lemma subset_insertI: "B \<subseteq> insert a B"
  1054   by (rule subsetI) (erule insertI2)
  1055 
  1056 lemma subset_insertI2: "A \<subseteq> B \<Longrightarrow> A \<subseteq> insert b B"
  1057   by blast
  1058 
  1059 lemma subset_insert: "x \<notin> A ==> (A \<subseteq> insert x B) = (A \<subseteq> B)"
  1060   by blast
  1061 
  1062 
  1063 text {* \medskip Finite Union -- the least upper bound of two sets. *}
  1064 
  1065 lemma Un_upper1: "A \<subseteq> A \<union> B"
  1066   by (fact sup_ge1)
  1067 
  1068 lemma Un_upper2: "B \<subseteq> A \<union> B"
  1069   by (fact sup_ge2)
  1070 
  1071 lemma Un_least: "A \<subseteq> C ==> B \<subseteq> C ==> A \<union> B \<subseteq> C"
  1072   by (fact sup_least)
  1073 
  1074 
  1075 text {* \medskip Finite Intersection -- the greatest lower bound of two sets. *}
  1076 
  1077 lemma Int_lower1: "A \<inter> B \<subseteq> A"
  1078   by (fact inf_le1)
  1079 
  1080 lemma Int_lower2: "A \<inter> B \<subseteq> B"
  1081   by (fact inf_le2)
  1082 
  1083 lemma Int_greatest: "C \<subseteq> A ==> C \<subseteq> B ==> C \<subseteq> A \<inter> B"
  1084   by (fact inf_greatest)
  1085 
  1086 
  1087 text {* \medskip Set difference. *}
  1088 
  1089 lemma Diff_subset: "A - B \<subseteq> A"
  1090   by blast
  1091 
  1092 lemma Diff_subset_conv: "(A - B \<subseteq> C) = (A \<subseteq> B \<union> C)"
  1093 by blast
  1094 
  1095 
  1096 subsubsection {* Equalities involving union, intersection, inclusion, etc. *}
  1097 
  1098 text {* @{text "{}"}. *}
  1099 
  1100 lemma Collect_const [simp]: "{s. P} = (if P then UNIV else {})"
  1101   -- {* supersedes @{text "Collect_False_empty"} *}
  1102   by auto
  1103 
  1104 lemma subset_empty [simp]: "(A \<subseteq> {}) = (A = {})"
  1105   by (fact bot_unique)
  1106 
  1107 lemma not_psubset_empty [iff]: "\<not> (A < {})"
  1108   by (fact not_less_bot) (* FIXME: already simp *)
  1109 
  1110 lemma Collect_empty_eq [simp]: "(Collect P = {}) = (\<forall>x. \<not> P x)"
  1111 by blast
  1112 
  1113 lemma empty_Collect_eq [simp]: "({} = Collect P) = (\<forall>x. \<not> P x)"
  1114 by blast
  1115 
  1116 lemma Collect_neg_eq: "{x. \<not> P x} = - {x. P x}"
  1117   by blast
  1118 
  1119 lemma Collect_disj_eq: "{x. P x | Q x} = {x. P x} \<union> {x. Q x}"
  1120   by blast
  1121 
  1122 lemma Collect_imp_eq: "{x. P x --> Q x} = -{x. P x} \<union> {x. Q x}"
  1123   by blast
  1124 
  1125 lemma Collect_conj_eq: "{x. P x & Q x} = {x. P x} \<inter> {x. Q x}"
  1126   by blast
  1127 
  1128 
  1129 text {* \medskip @{text insert}. *}
  1130 
  1131 lemma insert_is_Un: "insert a A = {a} Un A"
  1132   -- {* NOT SUITABLE FOR REWRITING since @{text "{a} == insert a {}"} *}
  1133   by blast
  1134 
  1135 lemma insert_not_empty [simp]: "insert a A \<noteq> {}"
  1136   by blast
  1137 
  1138 lemmas empty_not_insert = insert_not_empty [symmetric]
  1139 declare empty_not_insert [simp]
  1140 
  1141 lemma insert_absorb: "a \<in> A ==> insert a A = A"
  1142   -- {* @{text "[simp]"} causes recursive calls when there are nested inserts *}
  1143   -- {* with \emph{quadratic} running time *}
  1144   by blast
  1145 
  1146 lemma insert_absorb2 [simp]: "insert x (insert x A) = insert x A"
  1147   by blast
  1148 
  1149 lemma insert_commute: "insert x (insert y A) = insert y (insert x A)"
  1150   by blast
  1151 
  1152 lemma insert_subset [simp]: "(insert x A \<subseteq> B) = (x \<in> B & A \<subseteq> B)"
  1153   by blast
  1154 
  1155 lemma mk_disjoint_insert: "a \<in> A ==> \<exists>B. A = insert a B & a \<notin> B"
  1156   -- {* use new @{text B} rather than @{text "A - {a}"} to avoid infinite unfolding *}
  1157   apply (rule_tac x = "A - {a}" in exI, blast)
  1158   done
  1159 
  1160 lemma insert_Collect: "insert a (Collect P) = {u. u \<noteq> a --> P u}"
  1161   by auto
  1162 
  1163 lemma insert_inter_insert[simp]: "insert a A \<inter> insert a B = insert a (A \<inter> B)"
  1164   by blast
  1165 
  1166 lemma insert_disjoint [simp,no_atp]:
  1167  "(insert a A \<inter> B = {}) = (a \<notin> B \<and> A \<inter> B = {})"
  1168  "({} = insert a A \<inter> B) = (a \<notin> B \<and> {} = A \<inter> B)"
  1169   by auto
  1170 
  1171 lemma disjoint_insert [simp,no_atp]:
  1172  "(B \<inter> insert a A = {}) = (a \<notin> B \<and> B \<inter> A = {})"
  1173  "({} = A \<inter> insert b B) = (b \<notin> A \<and> {} = A \<inter> B)"
  1174   by auto
  1175 
  1176 text {* \medskip @{text image}. *}
  1177 
  1178 lemma image_empty [simp]: "f`{} = {}"
  1179   by blast
  1180 
  1181 lemma image_insert [simp]: "f ` insert a B = insert (f a) (f`B)"
  1182   by blast
  1183 
  1184 lemma image_constant: "x \<in> A ==> (\<lambda>x. c) ` A = {c}"
  1185   by auto
  1186 
  1187 lemma image_constant_conv: "(%x. c) ` A = (if A = {} then {} else {c})"
  1188 by auto
  1189 
  1190 lemma image_image: "f ` (g ` A) = (\<lambda>x. f (g x)) ` A"
  1191 by blast
  1192 
  1193 lemma insert_image [simp]: "x \<in> A ==> insert (f x) (f`A) = f`A"
  1194 by blast
  1195 
  1196 lemma image_is_empty [iff]: "(f`A = {}) = (A = {})"
  1197 by blast
  1198 
  1199 lemma empty_is_image[iff]: "({} = f ` A) = (A = {})"
  1200 by blast
  1201 
  1202 
  1203 lemma image_Collect [no_atp]: "f ` {x. P x} = {f x | x. P x}"
  1204   -- {* NOT suitable as a default simprule: the RHS isn't simpler than the LHS,
  1205       with its implicit quantifier and conjunction.  Also image enjoys better
  1206       equational properties than does the RHS. *}
  1207   by blast
  1208 
  1209 lemma if_image_distrib [simp]:
  1210   "(\<lambda>x. if P x then f x else g x) ` S
  1211     = (f ` (S \<inter> {x. P x})) \<union> (g ` (S \<inter> {x. \<not> P x}))"
  1212   by (auto simp add: image_def)
  1213 
  1214 lemma image_cong: "M = N ==> (!!x. x \<in> N ==> f x = g x) ==> f`M = g`N"
  1215   by (simp add: image_def)
  1216 
  1217 lemma image_Int_subset: "f`(A Int B) <= f`A Int f`B"
  1218 by blast
  1219 
  1220 lemma image_diff_subset: "f`A - f`B <= f`(A - B)"
  1221 by blast
  1222 
  1223 
  1224 text {* \medskip @{text range}. *}
  1225 
  1226 lemma full_SetCompr_eq [no_atp]: "{u. \<exists>x. u = f x} = range f"
  1227   by auto
  1228 
  1229 lemma range_composition: "range (\<lambda>x. f (g x)) = f`range g"
  1230 by (subst image_image, simp)
  1231 
  1232 
  1233 text {* \medskip @{text Int} *}
  1234 
  1235 lemma Int_absorb: "A \<inter> A = A"
  1236   by (fact inf_idem) (* already simp *)
  1237 
  1238 lemma Int_left_absorb: "A \<inter> (A \<inter> B) = A \<inter> B"
  1239   by (fact inf_left_idem)
  1240 
  1241 lemma Int_commute: "A \<inter> B = B \<inter> A"
  1242   by (fact inf_commute)
  1243 
  1244 lemma Int_left_commute: "A \<inter> (B \<inter> C) = B \<inter> (A \<inter> C)"
  1245   by (fact inf_left_commute)
  1246 
  1247 lemma Int_assoc: "(A \<inter> B) \<inter> C = A \<inter> (B \<inter> C)"
  1248   by (fact inf_assoc)
  1249 
  1250 lemmas Int_ac = Int_assoc Int_left_absorb Int_commute Int_left_commute
  1251   -- {* Intersection is an AC-operator *}
  1252 
  1253 lemma Int_absorb1: "B \<subseteq> A ==> A \<inter> B = B"
  1254   by (fact inf_absorb2)
  1255 
  1256 lemma Int_absorb2: "A \<subseteq> B ==> A \<inter> B = A"
  1257   by (fact inf_absorb1)
  1258 
  1259 lemma Int_empty_left: "{} \<inter> B = {}"
  1260   by (fact inf_bot_left) (* already simp *)
  1261 
  1262 lemma Int_empty_right: "A \<inter> {} = {}"
  1263   by (fact inf_bot_right) (* already simp *)
  1264 
  1265 lemma disjoint_eq_subset_Compl: "(A \<inter> B = {}) = (A \<subseteq> -B)"
  1266   by blast
  1267 
  1268 lemma disjoint_iff_not_equal: "(A \<inter> B = {}) = (\<forall>x\<in>A. \<forall>y\<in>B. x \<noteq> y)"
  1269   by blast
  1270 
  1271 lemma Int_UNIV_left: "UNIV \<inter> B = B"
  1272   by (fact inf_top_left) (* already simp *)
  1273 
  1274 lemma Int_UNIV_right: "A \<inter> UNIV = A"
  1275   by (fact inf_top_right) (* already simp *)
  1276 
  1277 lemma Int_Un_distrib: "A \<inter> (B \<union> C) = (A \<inter> B) \<union> (A \<inter> C)"
  1278   by (fact inf_sup_distrib1)
  1279 
  1280 lemma Int_Un_distrib2: "(B \<union> C) \<inter> A = (B \<inter> A) \<union> (C \<inter> A)"
  1281   by (fact inf_sup_distrib2)
  1282 
  1283 lemma Int_UNIV [simp,no_atp]: "(A \<inter> B = UNIV) = (A = UNIV & B = UNIV)"
  1284   by (fact inf_eq_top_iff) (* already simp *)
  1285 
  1286 lemma Int_subset_iff [no_atp, simp]: "(C \<subseteq> A \<inter> B) = (C \<subseteq> A & C \<subseteq> B)"
  1287   by (fact le_inf_iff)
  1288 
  1289 lemma Int_Collect: "(x \<in> A \<inter> {x. P x}) = (x \<in> A & P x)"
  1290   by blast
  1291 
  1292 
  1293 text {* \medskip @{text Un}. *}
  1294 
  1295 lemma Un_absorb: "A \<union> A = A"
  1296   by (fact sup_idem) (* already simp *)
  1297 
  1298 lemma Un_left_absorb: "A \<union> (A \<union> B) = A \<union> B"
  1299   by (fact sup_left_idem)
  1300 
  1301 lemma Un_commute: "A \<union> B = B \<union> A"
  1302   by (fact sup_commute)
  1303 
  1304 lemma Un_left_commute: "A \<union> (B \<union> C) = B \<union> (A \<union> C)"
  1305   by (fact sup_left_commute)
  1306 
  1307 lemma Un_assoc: "(A \<union> B) \<union> C = A \<union> (B \<union> C)"
  1308   by (fact sup_assoc)
  1309 
  1310 lemmas Un_ac = Un_assoc Un_left_absorb Un_commute Un_left_commute
  1311   -- {* Union is an AC-operator *}
  1312 
  1313 lemma Un_absorb1: "A \<subseteq> B ==> A \<union> B = B"
  1314   by (fact sup_absorb2)
  1315 
  1316 lemma Un_absorb2: "B \<subseteq> A ==> A \<union> B = A"
  1317   by (fact sup_absorb1)
  1318 
  1319 lemma Un_empty_left: "{} \<union> B = B"
  1320   by (fact sup_bot_left) (* already simp *)
  1321 
  1322 lemma Un_empty_right: "A \<union> {} = A"
  1323   by (fact sup_bot_right) (* already simp *)
  1324 
  1325 lemma Un_UNIV_left: "UNIV \<union> B = UNIV"
  1326   by (fact sup_top_left) (* already simp *)
  1327 
  1328 lemma Un_UNIV_right: "A \<union> UNIV = UNIV"
  1329   by (fact sup_top_right) (* already simp *)
  1330 
  1331 lemma Un_insert_left [simp]: "(insert a B) \<union> C = insert a (B \<union> C)"
  1332   by blast
  1333 
  1334 lemma Un_insert_right [simp]: "A \<union> (insert a B) = insert a (A \<union> B)"
  1335   by blast
  1336 
  1337 lemma Int_insert_left:
  1338     "(insert a B) Int C = (if a \<in> C then insert a (B \<inter> C) else B \<inter> C)"
  1339   by auto
  1340 
  1341 lemma Int_insert_left_if0[simp]:
  1342     "a \<notin> C \<Longrightarrow> (insert a B) Int C = B \<inter> C"
  1343   by auto
  1344 
  1345 lemma Int_insert_left_if1[simp]:
  1346     "a \<in> C \<Longrightarrow> (insert a B) Int C = insert a (B Int C)"
  1347   by auto
  1348 
  1349 lemma Int_insert_right:
  1350     "A \<inter> (insert a B) = (if a \<in> A then insert a (A \<inter> B) else A \<inter> B)"
  1351   by auto
  1352 
  1353 lemma Int_insert_right_if0[simp]:
  1354     "a \<notin> A \<Longrightarrow> A Int (insert a B) = A Int B"
  1355   by auto
  1356 
  1357 lemma Int_insert_right_if1[simp]:
  1358     "a \<in> A \<Longrightarrow> A Int (insert a B) = insert a (A Int B)"
  1359   by auto
  1360 
  1361 lemma Un_Int_distrib: "A \<union> (B \<inter> C) = (A \<union> B) \<inter> (A \<union> C)"
  1362   by (fact sup_inf_distrib1)
  1363 
  1364 lemma Un_Int_distrib2: "(B \<inter> C) \<union> A = (B \<union> A) \<inter> (C \<union> A)"
  1365   by (fact sup_inf_distrib2)
  1366 
  1367 lemma Un_Int_crazy:
  1368     "(A \<inter> B) \<union> (B \<inter> C) \<union> (C \<inter> A) = (A \<union> B) \<inter> (B \<union> C) \<inter> (C \<union> A)"
  1369   by blast
  1370 
  1371 lemma subset_Un_eq: "(A \<subseteq> B) = (A \<union> B = B)"
  1372   by (fact le_iff_sup)
  1373 
  1374 lemma Un_empty [iff]: "(A \<union> B = {}) = (A = {} & B = {})"
  1375   by (fact sup_eq_bot_iff) (* FIXME: already simp *)
  1376 
  1377 lemma Un_subset_iff [no_atp, simp]: "(A \<union> B \<subseteq> C) = (A \<subseteq> C & B \<subseteq> C)"
  1378   by (fact le_sup_iff)
  1379 
  1380 lemma Un_Diff_Int: "(A - B) \<union> (A \<inter> B) = A"
  1381   by blast
  1382 
  1383 lemma Diff_Int2: "A \<inter> C - B \<inter> C = A \<inter> C - B"
  1384   by blast
  1385 
  1386 
  1387 text {* \medskip Set complement *}
  1388 
  1389 lemma Compl_disjoint [simp]: "A \<inter> -A = {}"
  1390   by (fact inf_compl_bot)
  1391 
  1392 lemma Compl_disjoint2 [simp]: "-A \<inter> A = {}"
  1393   by (fact compl_inf_bot)
  1394 
  1395 lemma Compl_partition: "A \<union> -A = UNIV"
  1396   by (fact sup_compl_top)
  1397 
  1398 lemma Compl_partition2: "-A \<union> A = UNIV"
  1399   by (fact compl_sup_top)
  1400 
  1401 lemma double_complement: "- (-A) = (A::'a set)"
  1402   by (fact double_compl) (* already simp *)
  1403 
  1404 lemma Compl_Un: "-(A \<union> B) = (-A) \<inter> (-B)"
  1405   by (fact compl_sup) (* already simp *)
  1406 
  1407 lemma Compl_Int: "-(A \<inter> B) = (-A) \<union> (-B)"
  1408   by (fact compl_inf) (* already simp *)
  1409 
  1410 lemma subset_Compl_self_eq: "(A \<subseteq> -A) = (A = {})"
  1411   by blast
  1412 
  1413 lemma Un_Int_assoc_eq: "((A \<inter> B) \<union> C = A \<inter> (B \<union> C)) = (C \<subseteq> A)"
  1414   -- {* Halmos, Naive Set Theory, page 16. *}
  1415   by blast
  1416 
  1417 lemma Compl_UNIV_eq: "-UNIV = {}"
  1418   by (fact compl_top_eq) (* already simp *)
  1419 
  1420 lemma Compl_empty_eq: "-{} = UNIV"
  1421   by (fact compl_bot_eq) (* already simp *)
  1422 
  1423 lemma Compl_subset_Compl_iff [iff]: "(-A \<subseteq> -B) = (B \<subseteq> A)"
  1424   by (fact compl_le_compl_iff) (* FIXME: already simp *)
  1425 
  1426 lemma Compl_eq_Compl_iff [iff]: "(-A = -B) = (A = (B::'a set))"
  1427   by (fact compl_eq_compl_iff) (* FIXME: already simp *)
  1428 
  1429 lemma Compl_insert: "- insert x A = (-A) - {x}"
  1430   by blast
  1431 
  1432 text {* \medskip Bounded quantifiers.
  1433 
  1434   The following are not added to the default simpset because
  1435   (a) they duplicate the body and (b) there are no similar rules for @{text Int}. *}
  1436 
  1437 lemma ball_Un: "(\<forall>x \<in> A \<union> B. P x) = ((\<forall>x\<in>A. P x) & (\<forall>x\<in>B. P x))"
  1438   by blast
  1439 
  1440 lemma bex_Un: "(\<exists>x \<in> A \<union> B. P x) = ((\<exists>x\<in>A. P x) | (\<exists>x\<in>B. P x))"
  1441   by blast
  1442 
  1443 
  1444 text {* \medskip Set difference. *}
  1445 
  1446 lemma Diff_eq: "A - B = A \<inter> (-B)"
  1447   by blast
  1448 
  1449 lemma Diff_eq_empty_iff [simp,no_atp]: "(A - B = {}) = (A \<subseteq> B)"
  1450   by blast
  1451 
  1452 lemma Diff_cancel [simp]: "A - A = {}"
  1453   by blast
  1454 
  1455 lemma Diff_idemp [simp]: "(A - B) - B = A - (B::'a set)"
  1456 by blast
  1457 
  1458 lemma Diff_triv: "A \<inter> B = {} ==> A - B = A"
  1459   by (blast elim: equalityE)
  1460 
  1461 lemma empty_Diff [simp]: "{} - A = {}"
  1462   by blast
  1463 
  1464 lemma Diff_empty [simp]: "A - {} = A"
  1465   by blast
  1466 
  1467 lemma Diff_UNIV [simp]: "A - UNIV = {}"
  1468   by blast
  1469 
  1470 lemma Diff_insert0 [simp,no_atp]: "x \<notin> A ==> A - insert x B = A - B"
  1471   by blast
  1472 
  1473 lemma Diff_insert: "A - insert a B = A - B - {a}"
  1474   -- {* NOT SUITABLE FOR REWRITING since @{text "{a} == insert a 0"} *}
  1475   by blast
  1476 
  1477 lemma Diff_insert2: "A - insert a B = A - {a} - B"
  1478   -- {* NOT SUITABLE FOR REWRITING since @{text "{a} == insert a 0"} *}
  1479   by blast
  1480 
  1481 lemma insert_Diff_if: "insert x A - B = (if x \<in> B then A - B else insert x (A - B))"
  1482   by auto
  1483 
  1484 lemma insert_Diff1 [simp]: "x \<in> B ==> insert x A - B = A - B"
  1485   by blast
  1486 
  1487 lemma insert_Diff_single[simp]: "insert a (A - {a}) = insert a A"
  1488 by blast
  1489 
  1490 lemma insert_Diff: "a \<in> A ==> insert a (A - {a}) = A"
  1491   by blast
  1492 
  1493 lemma Diff_insert_absorb: "x \<notin> A ==> (insert x A) - {x} = A"
  1494   by auto
  1495 
  1496 lemma Diff_disjoint [simp]: "A \<inter> (B - A) = {}"
  1497   by blast
  1498 
  1499 lemma Diff_partition: "A \<subseteq> B ==> A \<union> (B - A) = B"
  1500   by blast
  1501 
  1502 lemma double_diff: "A \<subseteq> B ==> B \<subseteq> C ==> B - (C - A) = A"
  1503   by blast
  1504 
  1505 lemma Un_Diff_cancel [simp]: "A \<union> (B - A) = A \<union> B"
  1506   by blast
  1507 
  1508 lemma Un_Diff_cancel2 [simp]: "(B - A) \<union> A = B \<union> A"
  1509   by blast
  1510 
  1511 lemma Diff_Un: "A - (B \<union> C) = (A - B) \<inter> (A - C)"
  1512   by blast
  1513 
  1514 lemma Diff_Int: "A - (B \<inter> C) = (A - B) \<union> (A - C)"
  1515   by blast
  1516 
  1517 lemma Un_Diff: "(A \<union> B) - C = (A - C) \<union> (B - C)"
  1518   by blast
  1519 
  1520 lemma Int_Diff: "(A \<inter> B) - C = A \<inter> (B - C)"
  1521   by blast
  1522 
  1523 lemma Diff_Int_distrib: "C \<inter> (A - B) = (C \<inter> A) - (C \<inter> B)"
  1524   by blast
  1525 
  1526 lemma Diff_Int_distrib2: "(A - B) \<inter> C = (A \<inter> C) - (B \<inter> C)"
  1527   by blast
  1528 
  1529 lemma Diff_Compl [simp]: "A - (- B) = A \<inter> B"
  1530   by auto
  1531 
  1532 lemma Compl_Diff_eq [simp]: "- (A - B) = -A \<union> B"
  1533   by blast
  1534 
  1535 
  1536 text {* \medskip Quantification over type @{typ bool}. *}
  1537 
  1538 lemma bool_induct: "P True \<Longrightarrow> P False \<Longrightarrow> P x"
  1539   by (cases x) auto
  1540 
  1541 lemma all_bool_eq: "(\<forall>b. P b) \<longleftrightarrow> P True \<and> P False"
  1542   by (auto intro: bool_induct)
  1543 
  1544 lemma bool_contrapos: "P x \<Longrightarrow> \<not> P False \<Longrightarrow> P True"
  1545   by (cases x) auto
  1546 
  1547 lemma ex_bool_eq: "(\<exists>b. P b) \<longleftrightarrow> P True \<or> P False"
  1548   by (auto intro: bool_contrapos)
  1549 
  1550 lemma UNIV_bool [no_atp]: "UNIV = {False, True}"
  1551   by (auto intro: bool_induct)
  1552 
  1553 text {* \medskip @{text Pow} *}
  1554 
  1555 lemma Pow_empty [simp]: "Pow {} = {{}}"
  1556   by (auto simp add: Pow_def)
  1557 
  1558 lemma Pow_insert: "Pow (insert a A) = Pow A \<union> (insert a ` Pow A)"
  1559   by (blast intro: image_eqI [where ?x = "u - {a}", standard])
  1560 
  1561 lemma Pow_Compl: "Pow (- A) = {-B | B. A \<in> Pow B}"
  1562   by (blast intro: exI [where ?x = "- u", standard])
  1563 
  1564 lemma Pow_UNIV [simp]: "Pow UNIV = UNIV"
  1565   by blast
  1566 
  1567 lemma Un_Pow_subset: "Pow A \<union> Pow B \<subseteq> Pow (A \<union> B)"
  1568   by blast
  1569 
  1570 lemma Pow_Int_eq [simp]: "Pow (A \<inter> B) = Pow A \<inter> Pow B"
  1571   by blast
  1572 
  1573 
  1574 text {* \medskip Miscellany. *}
  1575 
  1576 lemma set_eq_subset: "(A = B) = (A \<subseteq> B & B \<subseteq> A)"
  1577   by blast
  1578 
  1579 lemma subset_iff [no_atp]: "(A \<subseteq> B) = (\<forall>t. t \<in> A --> t \<in> B)"
  1580   by blast
  1581 
  1582 lemma subset_iff_psubset_eq: "(A \<subseteq> B) = ((A \<subset> B) | (A = B))"
  1583   by (unfold less_le) blast
  1584 
  1585 lemma all_not_in_conv [simp]: "(\<forall>x. x \<notin> A) = (A = {})"
  1586   by blast
  1587 
  1588 lemma ex_in_conv: "(\<exists>x. x \<in> A) = (A \<noteq> {})"
  1589   by blast
  1590 
  1591 lemma ball_simps [simp, no_atp]:
  1592   "\<And>A P Q. (\<forall>x\<in>A. P x \<or> Q) \<longleftrightarrow> ((\<forall>x\<in>A. P x) \<or> Q)"
  1593   "\<And>A P Q. (\<forall>x\<in>A. P \<or> Q x) \<longleftrightarrow> (P \<or> (\<forall>x\<in>A. Q x))"
  1594   "\<And>A P Q. (\<forall>x\<in>A. P \<longrightarrow> Q x) \<longleftrightarrow> (P \<longrightarrow> (\<forall>x\<in>A. Q x))"
  1595   "\<And>A P Q. (\<forall>x\<in>A. P x \<longrightarrow> Q) \<longleftrightarrow> ((\<exists>x\<in>A. P x) \<longrightarrow> Q)"
  1596   "\<And>P. (\<forall>x\<in>{}. P x) \<longleftrightarrow> True"
  1597   "\<And>P. (\<forall>x\<in>UNIV. P x) \<longleftrightarrow> (\<forall>x. P x)"
  1598   "\<And>a B P. (\<forall>x\<in>insert a B. P x) \<longleftrightarrow> (P a \<and> (\<forall>x\<in>B. P x))"
  1599   "\<And>P Q. (\<forall>x\<in>Collect Q. P x) \<longleftrightarrow> (\<forall>x. Q x \<longrightarrow> P x)"
  1600   "\<And>A P f. (\<forall>x\<in>f`A. P x) \<longleftrightarrow> (\<forall>x\<in>A. P (f x))"
  1601   "\<And>A P. (\<not> (\<forall>x\<in>A. P x)) \<longleftrightarrow> (\<exists>x\<in>A. \<not> P x)"
  1602   by auto
  1603 
  1604 lemma bex_simps [simp, no_atp]:
  1605   "\<And>A P Q. (\<exists>x\<in>A. P x \<and> Q) \<longleftrightarrow> ((\<exists>x\<in>A. P x) \<and> Q)"
  1606   "\<And>A P Q. (\<exists>x\<in>A. P \<and> Q x) \<longleftrightarrow> (P \<and> (\<exists>x\<in>A. Q x))"
  1607   "\<And>P. (\<exists>x\<in>{}. P x) \<longleftrightarrow> False"
  1608   "\<And>P. (\<exists>x\<in>UNIV. P x) \<longleftrightarrow> (\<exists>x. P x)"
  1609   "\<And>a B P. (\<exists>x\<in>insert a B. P x) \<longleftrightarrow> (P a | (\<exists>x\<in>B. P x))"
  1610   "\<And>P Q. (\<exists>x\<in>Collect Q. P x) \<longleftrightarrow> (\<exists>x. Q x \<and> P x)"
  1611   "\<And>A P f. (\<exists>x\<in>f`A. P x) \<longleftrightarrow> (\<exists>x\<in>A. P (f x))"
  1612   "\<And>A P. (\<not>(\<exists>x\<in>A. P x)) \<longleftrightarrow> (\<forall>x\<in>A. \<not> P x)"
  1613   by auto
  1614 
  1615 
  1616 subsubsection {* Monotonicity of various operations *}
  1617 
  1618 lemma image_mono: "A \<subseteq> B ==> f`A \<subseteq> f`B"
  1619   by blast
  1620 
  1621 lemma Pow_mono: "A \<subseteq> B ==> Pow A \<subseteq> Pow B"
  1622   by blast
  1623 
  1624 lemma insert_mono: "C \<subseteq> D ==> insert a C \<subseteq> insert a D"
  1625   by blast
  1626 
  1627 lemma Un_mono: "A \<subseteq> C ==> B \<subseteq> D ==> A \<union> B \<subseteq> C \<union> D"
  1628   by (fact sup_mono)
  1629 
  1630 lemma Int_mono: "A \<subseteq> C ==> B \<subseteq> D ==> A \<inter> B \<subseteq> C \<inter> D"
  1631   by (fact inf_mono)
  1632 
  1633 lemma Diff_mono: "A \<subseteq> C ==> D \<subseteq> B ==> A - B \<subseteq> C - D"
  1634   by blast
  1635 
  1636 lemma Compl_anti_mono: "A \<subseteq> B ==> -B \<subseteq> -A"
  1637   by (fact compl_mono)
  1638 
  1639 text {* \medskip Monotonicity of implications. *}
  1640 
  1641 lemma in_mono: "A \<subseteq> B ==> x \<in> A --> x \<in> B"
  1642   apply (rule impI)
  1643   apply (erule subsetD, assumption)
  1644   done
  1645 
  1646 lemma conj_mono: "P1 --> Q1 ==> P2 --> Q2 ==> (P1 & P2) --> (Q1 & Q2)"
  1647   by iprover
  1648 
  1649 lemma disj_mono: "P1 --> Q1 ==> P2 --> Q2 ==> (P1 | P2) --> (Q1 | Q2)"
  1650   by iprover
  1651 
  1652 lemma imp_mono: "Q1 --> P1 ==> P2 --> Q2 ==> (P1 --> P2) --> (Q1 --> Q2)"
  1653   by iprover
  1654 
  1655 lemma imp_refl: "P --> P" ..
  1656 
  1657 lemma not_mono: "Q --> P ==> ~ P --> ~ Q"
  1658   by iprover
  1659 
  1660 lemma ex_mono: "(!!x. P x --> Q x) ==> (EX x. P x) --> (EX x. Q x)"
  1661   by iprover
  1662 
  1663 lemma all_mono: "(!!x. P x --> Q x) ==> (ALL x. P x) --> (ALL x. Q x)"
  1664   by iprover
  1665 
  1666 lemma Collect_mono: "(!!x. P x --> Q x) ==> Collect P \<subseteq> Collect Q"
  1667   by blast
  1668 
  1669 lemma Int_Collect_mono:
  1670     "A \<subseteq> B ==> (!!x. x \<in> A ==> P x --> Q x) ==> A \<inter> Collect P \<subseteq> B \<inter> Collect Q"
  1671   by blast
  1672 
  1673 lemmas basic_monos =
  1674   subset_refl imp_refl disj_mono conj_mono
  1675   ex_mono Collect_mono in_mono
  1676 
  1677 lemma eq_to_mono: "a = b ==> c = d ==> b --> d ==> a --> c"
  1678   by iprover
  1679 
  1680 
  1681 subsubsection {* Inverse image of a function *}
  1682 
  1683 definition vimage :: "('a => 'b) => 'b set => 'a set" (infixr "-`" 90) where
  1684   "f -` B == {x. f x : B}"
  1685 
  1686 lemma vimage_eq [simp]: "(a : f -` B) = (f a : B)"
  1687   by (unfold vimage_def) blast
  1688 
  1689 lemma vimage_singleton_eq: "(a : f -` {b}) = (f a = b)"
  1690   by simp
  1691 
  1692 lemma vimageI [intro]: "f a = b ==> b:B ==> a : f -` B"
  1693   by (unfold vimage_def) blast
  1694 
  1695 lemma vimageI2: "f a : A ==> a : f -` A"
  1696   by (unfold vimage_def) fast
  1697 
  1698 lemma vimageE [elim!]: "a: f -` B ==> (!!x. f a = x ==> x:B ==> P) ==> P"
  1699   by (unfold vimage_def) blast
  1700 
  1701 lemma vimageD: "a : f -` A ==> f a : A"
  1702   by (unfold vimage_def) fast
  1703 
  1704 lemma vimage_empty [simp]: "f -` {} = {}"
  1705   by blast
  1706 
  1707 lemma vimage_Compl: "f -` (-A) = -(f -` A)"
  1708   by blast
  1709 
  1710 lemma vimage_Un [simp]: "f -` (A Un B) = (f -` A) Un (f -` B)"
  1711   by blast
  1712 
  1713 lemma vimage_Int [simp]: "f -` (A Int B) = (f -` A) Int (f -` B)"
  1714   by fast
  1715 
  1716 lemma vimage_Collect_eq [simp]: "f -` Collect P = {y. P (f y)}"
  1717   by blast
  1718 
  1719 lemma vimage_Collect: "(!!x. P (f x) = Q x) ==> f -` (Collect P) = Collect Q"
  1720   by blast
  1721 
  1722 lemma vimage_insert: "f-`(insert a B) = (f-`{a}) Un (f-`B)"
  1723   -- {* NOT suitable for rewriting because of the recurrence of @{term "{a}"}. *}
  1724   by blast
  1725 
  1726 lemma vimage_Diff: "f -` (A - B) = (f -` A) - (f -` B)"
  1727   by blast
  1728 
  1729 lemma vimage_UNIV [simp]: "f -` UNIV = UNIV"
  1730   by blast
  1731 
  1732 lemma vimage_mono: "A \<subseteq> B ==> f -` A \<subseteq> f -` B"
  1733   -- {* monotonicity *}
  1734   by blast
  1735 
  1736 lemma vimage_image_eq [no_atp]: "f -` (f ` A) = {y. EX x:A. f x = f y}"
  1737 by (blast intro: sym)
  1738 
  1739 lemma image_vimage_subset: "f ` (f -` A) <= A"
  1740 by blast
  1741 
  1742 lemma image_vimage_eq [simp]: "f ` (f -` A) = A Int range f"
  1743 by blast
  1744 
  1745 lemma vimage_const [simp]: "((\<lambda>x. c) -` A) = (if c \<in> A then UNIV else {})"
  1746   by auto
  1747 
  1748 lemma vimage_if [simp]: "((\<lambda>x. if x \<in> B then c else d) -` A) = 
  1749    (if c \<in> A then (if d \<in> A then UNIV else B)
  1750     else if d \<in> A then -B else {})"  
  1751   by (auto simp add: vimage_def) 
  1752 
  1753 lemma vimage_inter_cong:
  1754   "(\<And> w. w \<in> S \<Longrightarrow> f w = g w) \<Longrightarrow> f -` y \<inter> S = g -` y \<inter> S"
  1755   by auto
  1756 
  1757 lemma vimage_ident [simp]: "(%x. x) -` Y = Y"
  1758   by blast
  1759 
  1760 
  1761 subsubsection {* Getting the Contents of a Singleton Set *}
  1762 
  1763 definition the_elem :: "'a set \<Rightarrow> 'a" where
  1764   "the_elem X = (THE x. X = {x})"
  1765 
  1766 lemma the_elem_eq [simp]: "the_elem {x} = x"
  1767   by (simp add: the_elem_def)
  1768 
  1769 
  1770 subsubsection {* Least value operator *}
  1771 
  1772 lemma Least_mono:
  1773   "mono (f::'a::order => 'b::order) ==> EX x:S. ALL y:S. x <= y
  1774     ==> (LEAST y. y : f ` S) = f (LEAST x. x : S)"
  1775     -- {* Courtesy of Stephan Merz *}
  1776   apply clarify
  1777   apply (erule_tac P = "%x. x : S" in LeastI2_order, fast)
  1778   apply (rule LeastI2_order)
  1779   apply (auto elim: monoD intro!: order_antisym)
  1780   done
  1781 
  1782 
  1783 subsubsection {* Monad operation *}
  1784 
  1785 definition bind :: "'a set \<Rightarrow> ('a \<Rightarrow> 'b set) \<Rightarrow> 'b set" where
  1786   "bind A f = {x. \<exists>B \<in> f`A. x \<in> B}"
  1787 
  1788 hide_const (open) bind
  1789 
  1790 lemma bind_bind:
  1791   fixes A :: "'a set"
  1792   shows "Set.bind (Set.bind A B) C = Set.bind A (\<lambda>x. Set.bind (B x) C)"
  1793   by (auto simp add: bind_def)
  1794 
  1795 lemma empty_bind [simp]:
  1796   "Set.bind {} f = {}"
  1797   by (simp add: bind_def)
  1798 
  1799 lemma nonempty_bind_const:
  1800   "A \<noteq> {} \<Longrightarrow> Set.bind A (\<lambda>_. B) = B"
  1801   by (auto simp add: bind_def)
  1802 
  1803 lemma bind_const: "Set.bind A (\<lambda>_. B) = (if A = {} then {} else B)"
  1804   by (auto simp add: bind_def)
  1805 
  1806 
  1807 subsubsection {* Operations for execution *}
  1808 
  1809 definition is_empty :: "'a set \<Rightarrow> bool" where
  1810   [code_abbrev]: "is_empty A \<longleftrightarrow> A = {}"
  1811 
  1812 hide_const (open) is_empty
  1813 
  1814 definition remove :: "'a \<Rightarrow> 'a set \<Rightarrow> 'a set" where
  1815   [code_abbrev]: "remove x A = A - {x}"
  1816 
  1817 hide_const (open) remove
  1818 
  1819 lemma member_remove [simp]:
  1820   "x \<in> Set.remove y A \<longleftrightarrow> x \<in> A \<and> x \<noteq> y"
  1821   by (simp add: remove_def)
  1822 
  1823 definition project :: "('a \<Rightarrow> bool) \<Rightarrow> 'a set \<Rightarrow> 'a set" where
  1824   [code_abbrev]: "project P A = {a \<in> A. P a}"
  1825 
  1826 hide_const (open) project
  1827 
  1828 lemma member_project [simp]:
  1829   "x \<in> Set.project P A \<longleftrightarrow> x \<in> A \<and> P x"
  1830   by (simp add: project_def)
  1831 
  1832 instantiation set :: (equal) equal
  1833 begin
  1834 
  1835 definition
  1836   "HOL.equal A B \<longleftrightarrow> A \<subseteq> B \<and> B \<subseteq> A"
  1837 
  1838 instance proof
  1839 qed (auto simp add: equal_set_def)
  1840 
  1841 end
  1842 
  1843 
  1844 text {* Misc *}
  1845 
  1846 hide_const (open) member not_member
  1847 
  1848 lemmas equalityI = subset_antisym
  1849 
  1850 ML {*
  1851 val Ball_def = @{thm Ball_def}
  1852 val Bex_def = @{thm Bex_def}
  1853 val CollectD = @{thm CollectD}
  1854 val CollectE = @{thm CollectE}
  1855 val CollectI = @{thm CollectI}
  1856 val Collect_conj_eq = @{thm Collect_conj_eq}
  1857 val Collect_mem_eq = @{thm Collect_mem_eq}
  1858 val IntD1 = @{thm IntD1}
  1859 val IntD2 = @{thm IntD2}
  1860 val IntE = @{thm IntE}
  1861 val IntI = @{thm IntI}
  1862 val Int_Collect = @{thm Int_Collect}
  1863 val UNIV_I = @{thm UNIV_I}
  1864 val UNIV_witness = @{thm UNIV_witness}
  1865 val UnE = @{thm UnE}
  1866 val UnI1 = @{thm UnI1}
  1867 val UnI2 = @{thm UnI2}
  1868 val ballE = @{thm ballE}
  1869 val ballI = @{thm ballI}
  1870 val bexCI = @{thm bexCI}
  1871 val bexE = @{thm bexE}
  1872 val bexI = @{thm bexI}
  1873 val bex_triv = @{thm bex_triv}
  1874 val bspec = @{thm bspec}
  1875 val contra_subsetD = @{thm contra_subsetD}
  1876 val equalityCE = @{thm equalityCE}
  1877 val equalityD1 = @{thm equalityD1}
  1878 val equalityD2 = @{thm equalityD2}
  1879 val equalityE = @{thm equalityE}
  1880 val equalityI = @{thm equalityI}
  1881 val imageE = @{thm imageE}
  1882 val imageI = @{thm imageI}
  1883 val image_Un = @{thm image_Un}
  1884 val image_insert = @{thm image_insert}
  1885 val insert_commute = @{thm insert_commute}
  1886 val insert_iff = @{thm insert_iff}
  1887 val mem_Collect_eq = @{thm mem_Collect_eq}
  1888 val rangeE = @{thm rangeE}
  1889 val rangeI = @{thm rangeI}
  1890 val range_eqI = @{thm range_eqI}
  1891 val subsetCE = @{thm subsetCE}
  1892 val subsetD = @{thm subsetD}
  1893 val subsetI = @{thm subsetI}
  1894 val subset_refl = @{thm subset_refl}
  1895 val subset_trans = @{thm subset_trans}
  1896 val vimageD = @{thm vimageD}
  1897 val vimageE = @{thm vimageE}
  1898 val vimageI = @{thm vimageI}
  1899 val vimageI2 = @{thm vimageI2}
  1900 val vimage_Collect = @{thm vimage_Collect}
  1901 val vimage_Int = @{thm vimage_Int}
  1902 val vimage_Un = @{thm vimage_Un}
  1903 *}
  1904 
  1905 end