src/Pure/display.ML
author wenzelm
Sun Apr 13 16:40:02 2008 +0200 (2008-04-13)
changeset 26637 0bfccafc52eb
parent 26626 c6231d64d264
child 26928 ca87aff1ad2d
permissions -rw-r--r--
tsig: removed unnecessary universal witness;
     1 (*  Title:      Pure/display.ML
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     4     Copyright   1993  University of Cambridge
     5 
     6 Printing of theorems, goals, results etc.
     7 *)
     8 
     9 signature BASIC_DISPLAY =
    10 sig
    11   val goals_limit: int ref
    12   val show_hyps: bool ref
    13   val show_tags: bool ref
    14   val string_of_thm: thm -> string
    15   val print_thm: thm -> unit
    16   val print_thms: thm list -> unit
    17   val prth: thm -> thm
    18   val prthq: thm Seq.seq -> thm Seq.seq
    19   val prths: thm list -> thm list
    20   val string_of_ctyp: ctyp -> string
    21   val print_ctyp: ctyp -> unit
    22   val string_of_cterm: cterm -> string
    23   val print_cterm: cterm -> unit
    24   val print_syntax: theory -> unit
    25   val show_consts: bool ref
    26 end;
    27 
    28 signature DISPLAY =
    29 sig
    30   include BASIC_DISPLAY
    31   val pretty_flexpair: Pretty.pp -> term * term -> Pretty.T
    32   val pretty_thm_aux: Pretty.pp -> bool -> bool -> term list -> thm -> Pretty.T
    33   val pretty_thm: thm -> Pretty.T
    34   val pretty_thms: thm list -> Pretty.T
    35   val pretty_thm_sg: theory -> thm -> Pretty.T
    36   val pretty_thms_sg: theory -> thm list -> Pretty.T
    37   val pretty_ctyp: ctyp -> Pretty.T
    38   val pretty_cterm: cterm -> Pretty.T
    39   val pretty_full_theory: bool -> theory -> Pretty.T list
    40   val pretty_goals_aux: Pretty.pp -> Markup.T -> bool * bool -> int -> thm -> Pretty.T list
    41   val pretty_goals: int -> thm -> Pretty.T list
    42   val print_goals: int -> thm -> unit
    43 end;
    44 
    45 structure Display: DISPLAY =
    46 struct
    47 
    48 
    49 (** print thm **)
    50 
    51 val goals_limit = ref 10;       (*max number of goals to print*)
    52 val show_hyps = ref false;      (*false: print meta-hypotheses as dots*)
    53 val show_tags = ref false;      (*false: suppress tags*)
    54 
    55 fun pretty_tag (name, arg) = Pretty.strs [name, Library.quote arg];
    56 val pretty_tags = Pretty.list "[" "]" o map pretty_tag;
    57 
    58 fun pretty_flexpair pp (t, u) = Pretty.block
    59   [Pretty.term pp t, Pretty.str " =?=", Pretty.brk 1, Pretty.term pp u];
    60 
    61 fun pretty_thm_aux pp quote show_hyps' asms raw_th =
    62   let
    63     val th = Thm.strip_shyps raw_th;
    64     val {hyps, tpairs, prop, der = (ora, _), ...} = Thm.rep_thm th;
    65     val xshyps = Thm.extra_shyps th;
    66     val tags = Thm.get_tags th;
    67 
    68     val q = if quote then Pretty.quote else I;
    69     val prt_term = q o Pretty.term pp;
    70 
    71     val hyps' = if ! show_hyps then hyps else subtract (op aconv) asms hyps;
    72     val ora' = ora andalso (! show_hyps orelse not (! quick_and_dirty));
    73     val hlen = length xshyps + length hyps' + length tpairs;
    74     val hsymbs =
    75       if hlen = 0 andalso not ora' then []
    76       else if ! show_hyps orelse show_hyps' then
    77         [Pretty.brk 2, Pretty.list "[" "]"
    78           (map (q o pretty_flexpair pp) tpairs @ map prt_term hyps' @
    79            map (Pretty.sort pp) xshyps @
    80             (if ora' then [Pretty.str "!"] else []))]
    81       else [Pretty.brk 2, Pretty.str ("[" ^ implode (replicate hlen ".") ^
    82         (if ora' then "!" else "") ^ "]")];
    83     val tsymbs =
    84       if null tags orelse not (! show_tags) then []
    85       else [Pretty.brk 1, pretty_tags tags];
    86   in Pretty.block (prt_term prop :: (hsymbs @ tsymbs)) end;
    87 
    88 fun pretty_thm th =
    89   pretty_thm_aux (Sign.pp (Thm.theory_of_thm th)) true false [] th;
    90 
    91 val string_of_thm = Pretty.string_of o pretty_thm;
    92 
    93 fun pretty_thms [th] = pretty_thm th
    94   | pretty_thms ths = Pretty.block (Pretty.fbreaks (map pretty_thm ths));
    95 
    96 val pretty_thm_sg = pretty_thm oo Thm.transfer;
    97 val pretty_thms_sg = pretty_thms oo (map o Thm.transfer);
    98 
    99 
   100 (* top-level commands for printing theorems *)
   101 
   102 val print_thm = Pretty.writeln o pretty_thm;
   103 val print_thms = Pretty.writeln o pretty_thms;
   104 
   105 fun prth th = (print_thm th; th);
   106 fun prthq thq = (Seq.print (K print_thm) 100000 thq; thq);
   107 fun prths ths = (prthq (Seq.of_list ths); ths);
   108 
   109 
   110 (* other printing commands *)
   111 
   112 fun pretty_ctyp cT = Sign.pretty_typ (Thm.theory_of_ctyp cT) (Thm.typ_of cT);
   113 fun string_of_ctyp cT = Sign.string_of_typ (Thm.theory_of_ctyp cT) (Thm.typ_of cT);
   114 val print_ctyp = writeln o string_of_ctyp;
   115 
   116 fun pretty_cterm ct = Sign.pretty_term (Thm.theory_of_cterm ct) (Thm.term_of ct);
   117 fun string_of_cterm ct = Sign.string_of_term (Thm.theory_of_cterm ct) (Thm.term_of ct);
   118 val print_cterm = writeln o string_of_cterm;
   119 
   120 
   121 
   122 (** print theory **)
   123 
   124 val print_syntax = Syntax.print_syntax o Sign.syn_of;
   125 
   126 
   127 (* pretty_full_theory *)
   128 
   129 fun pretty_full_theory verbose thy =
   130   let
   131     val ctxt = ProofContext.init thy;
   132 
   133     fun prt_cls c = Syntax.pretty_sort ctxt [c];
   134     fun prt_sort S = Syntax.pretty_sort ctxt S;
   135     fun prt_arity t (c, (_, Ss)) = Syntax.pretty_arity ctxt (t, Ss, [c]);
   136     fun prt_typ ty = Pretty.quote (Syntax.pretty_typ ctxt ty);
   137     val prt_typ_no_tvars = prt_typ o Logic.unvarifyT;
   138     fun prt_term t = Pretty.quote (Syntax.pretty_term ctxt t);
   139     val prt_term_no_vars = prt_term o Logic.unvarify;
   140     fun prt_const (c, ty) = [Pretty.str c, Pretty.str " ::", Pretty.brk 1, prt_typ_no_tvars ty];
   141     val prt_const' = Defs.pretty_const (Sign.pp thy);
   142 
   143     fun pretty_classrel (c, []) = prt_cls c
   144       | pretty_classrel (c, cs) = Pretty.block
   145           (prt_cls c :: Pretty.str " <" :: Pretty.brk 1 ::
   146             Pretty.commas (map prt_cls cs));
   147 
   148     fun pretty_default S = Pretty.block
   149       [Pretty.str "default sort:", Pretty.brk 1, prt_sort S];
   150 
   151     val tfrees = map (fn v => TFree (v, []));
   152     fun pretty_type syn (t, (Type.LogicalType n, _)) =
   153           if syn then NONE
   154           else SOME (prt_typ (Type (t, tfrees (Name.invents Name.context Name.aT n))))
   155       | pretty_type syn (t, (Type.Abbreviation (vs, U, syn'), _)) =
   156           if syn <> syn' then NONE
   157           else SOME (Pretty.block
   158             [prt_typ (Type (t, tfrees vs)), Pretty.str " =", Pretty.brk 1, prt_typ U])
   159       | pretty_type syn (t, (Type.Nonterminal, _)) =
   160           if not syn then NONE
   161           else SOME (prt_typ (Type (t, [])));
   162 
   163     val pretty_arities = maps (fn (t, ars) => map (prt_arity t) ars);
   164 
   165     fun pretty_abbrev (c, (ty, t)) = Pretty.block
   166       (prt_const (c, ty) @ [Pretty.str " ==", Pretty.brk 1, prt_term_no_vars t]);
   167 
   168     fun pretty_axm (a, t) = Pretty.block [Pretty.str (a ^ ":"), Pretty.brk 1, prt_term_no_vars t];
   169 
   170     fun pretty_finals reds = Pretty.block
   171       (Pretty.str "final:" :: Pretty.brk 1 :: Pretty.commas (map (prt_const' o fst) reds));
   172 
   173     fun pretty_reduct (lhs, rhs) = Pretty.block
   174       ([prt_const' lhs, Pretty.str "  ->", Pretty.brk 2] @
   175         Pretty.commas (map prt_const' (sort_wrt #1 rhs)));
   176 
   177     fun pretty_restrict (const, name) =
   178       Pretty.block ([prt_const' const, Pretty.brk 2, Pretty.str ("(from " ^ quote name ^ ")")]);
   179 
   180     val axioms = (Theory.axiom_space thy, Theory.axiom_table thy);
   181     val oracles = (Theory.oracle_space thy, Theory.oracle_table thy);
   182     val defs = Theory.defs_of thy;
   183     val {restricts, reducts} = Defs.dest defs;
   184     val {naming, syn = _, tsig, consts} = Sign.rep_sg thy;
   185     val {constants, constraints} = Consts.dest consts;
   186     val extern_const = NameSpace.extern (#1 constants);
   187     val {classes, default, types, ...} = Type.rep_tsig tsig;
   188     val (class_space, class_algebra) = classes;
   189     val {classes, arities} = Sorts.rep_algebra class_algebra;
   190 
   191     val clsses = NameSpace.dest_table (class_space, Symtab.make (Graph.dest classes));
   192     val tdecls = NameSpace.dest_table types;
   193     val arties = NameSpace.dest_table (Sign.type_space thy, arities);
   194 
   195     fun prune_const c = not verbose andalso
   196       member (op =) (Consts.the_tags consts c) Markup.property_internal;
   197     val cnsts = NameSpace.extern_table (#1 constants,
   198       Symtab.make (filter_out (prune_const o fst) (Symtab.dest (#2 constants))));
   199 
   200     val log_cnsts = map_filter (fn (c, (ty, NONE)) => SOME (c, ty) | _ => NONE) cnsts;
   201     val abbrevs = map_filter (fn (c, (ty, SOME t)) => SOME (c, (ty, t)) | _ => NONE) cnsts;
   202     val cnstrs = NameSpace.extern_table constraints;
   203 
   204     val axms = NameSpace.extern_table axioms;
   205     val oras = NameSpace.extern_table oracles;
   206 
   207     val (reds0, (reds1, reds2)) = filter_out (prune_const o fst o fst) reducts
   208       |> map (fn (lhs, rhs) =>
   209         (apfst extern_const lhs, map (apfst extern_const) (filter_out (prune_const o fst) rhs)))
   210       |> sort_wrt (#1 o #1)
   211       |> List.partition (null o #2)
   212       ||> List.partition (Defs.plain_args o #2 o #1);
   213     val rests = restricts |> map (apfst (apfst extern_const)) |> sort_wrt (#1 o #1);
   214   in
   215     [Pretty.strs ("names:" :: Context.names_of thy)] @
   216     [Pretty.strs ["name prefix:", NameSpace.path_of naming],
   217       Pretty.big_list "classes:" (map pretty_classrel clsses),
   218       pretty_default default,
   219       Pretty.big_list "syntactic types:" (map_filter (pretty_type true) tdecls),
   220       Pretty.big_list "logical types:" (map_filter (pretty_type false) tdecls),
   221       Pretty.big_list "type arities:" (pretty_arities arties),
   222       Pretty.big_list "logical consts:" (map (Pretty.block o prt_const) log_cnsts),
   223       Pretty.big_list "abbreviations:" (map pretty_abbrev abbrevs),
   224       Pretty.big_list "constraints:" (map (Pretty.block o prt_const) cnstrs),
   225       Pretty.big_list "axioms:" (map pretty_axm axms),
   226       Pretty.strs ("oracles:" :: (map #1 oras)),
   227       Pretty.big_list "definitions:"
   228         [pretty_finals reds0,
   229          Pretty.big_list "non-overloaded:" (map pretty_reduct reds1),
   230          Pretty.big_list "overloaded:" (map pretty_reduct reds2),
   231          Pretty.big_list "pattern restrictions:" (map pretty_restrict rests)]]
   232   end;
   233 
   234 
   235 
   236 (** print_goals **)
   237 
   238 (* print_goals etc. *)
   239 
   240 val show_consts = ref false;  (*true: show consts with types in proof state output*)
   241 
   242 
   243 (*print thm A1,...,An/B in "goal style" -- premises as numbered subgoals*)
   244 
   245 local
   246 
   247 fun ins_entry (x, y) =
   248   AList.default (op =) (x, []) #>
   249   AList.map_entry (op =) x (insert (op =) y);
   250 
   251 val add_consts = Term.fold_aterms
   252   (fn Const (c, T) => ins_entry (T, (c, T))
   253     | _ => I);
   254 
   255 val add_vars = Term.fold_aterms
   256   (fn Free (x, T) => ins_entry (T, (x, ~1))
   257     | Var (xi, T) => ins_entry (T, xi)
   258     | _ => I);
   259 
   260 val add_varsT = Term.fold_atyps
   261   (fn TFree (x, S) => ins_entry (S, (x, ~1))
   262     | TVar (xi, S) => ins_entry (S, xi)
   263     | _ => I);
   264 
   265 fun sort_idxs vs = map (apsnd (sort (prod_ord string_ord int_ord))) vs;
   266 fun sort_cnsts cs = map (apsnd (sort_wrt fst)) cs;
   267 
   268 fun consts_of t = sort_cnsts (add_consts t []);
   269 fun vars_of t = sort_idxs (add_vars t []);
   270 fun varsT_of t = rev (sort_idxs (Term.fold_types add_varsT t []));
   271 
   272 in
   273 
   274 fun pretty_goals_aux pp markup (msg, main) maxgoals state =
   275   let
   276     fun prt_atoms prt prtT (X, xs) = Pretty.block
   277       [Pretty.block (Pretty.commas (map prt xs)), Pretty.str " ::",
   278         Pretty.brk 1, prtT X];
   279 
   280     fun prt_var (x, ~1) = Pretty.term pp (Syntax.free x)
   281       | prt_var xi = Pretty.term pp (Syntax.var xi);
   282 
   283     fun prt_varT (x, ~1) = Pretty.typ pp (TFree (x, []))
   284       | prt_varT xi = Pretty.typ pp (TVar (xi, []));
   285 
   286     val prt_consts = prt_atoms (Pretty.term pp o Const) (Pretty.typ pp);
   287     val prt_vars = prt_atoms prt_var (Pretty.typ pp);
   288     val prt_varsT = prt_atoms prt_varT (Pretty.sort pp);
   289 
   290 
   291     fun pretty_list _ _ [] = []
   292       | pretty_list name prt lst = [Pretty.big_list name (map prt lst)];
   293 
   294     fun pretty_subgoal (n, A) = Pretty.markup markup
   295       [Pretty.str (" " ^ string_of_int n ^ ". "), Pretty.term pp A];
   296     fun pretty_subgoals As = map pretty_subgoal (1 upto length As ~~ As);
   297 
   298     val pretty_ffpairs = pretty_list "flex-flex pairs:" (pretty_flexpair pp);
   299 
   300     val pretty_consts = pretty_list "constants:" prt_consts o consts_of;
   301     val pretty_vars = pretty_list "variables:" prt_vars o vars_of;
   302     val pretty_varsT = pretty_list "type variables:" prt_varsT o varsT_of;
   303 
   304 
   305     val {prop, tpairs, ...} = Thm.rep_thm state;
   306     val (As, B) = Logic.strip_horn prop;
   307     val ngoals = length As;
   308 
   309     fun pretty_gs (types, sorts) =
   310       (if main then [Pretty.term pp B] else []) @
   311        (if ngoals = 0 then [Pretty.str "No subgoals!"]
   312         else if ngoals > maxgoals then
   313           pretty_subgoals (Library.take (maxgoals, As)) @
   314           (if msg then [Pretty.str ("A total of " ^ string_of_int ngoals ^ " subgoals...")]
   315            else [])
   316         else pretty_subgoals As) @
   317       pretty_ffpairs tpairs @
   318       (if ! show_consts then pretty_consts prop else []) @
   319       (if types then pretty_vars prop else []) @
   320       (if sorts then pretty_varsT prop else []);
   321   in
   322     setmp show_no_free_types true
   323       (setmp show_types (! show_types orelse ! show_sorts orelse ! show_all_types)
   324         (setmp show_sorts false pretty_gs))
   325    (! show_types orelse ! show_sorts orelse ! show_all_types, ! show_sorts)
   326   end;
   327 
   328 fun pretty_goals n th =
   329   pretty_goals_aux (Sign.pp (Thm.theory_of_thm th)) Markup.none (true, true) n th;
   330 
   331 val print_goals = (Pretty.writeln o Pretty.chunks) oo pretty_goals;
   332 
   333 end;
   334 
   335 
   336 end;
   337 
   338 structure BasicDisplay: BASIC_DISPLAY = Display;
   339 open BasicDisplay;