src/Tools/Code/code_target.ML
author haftmann
Tue Aug 31 15:08:04 2010 +0200 (2010-08-31)
changeset 38928 0e6f54c9d201
parent 38927 544f4702d621
child 38929 d9ac9dee764d
permissions -rw-r--r--
dropped single_module parameter
     1 (*  Title:      Tools/Code/code_target.ML
     2     Author:     Florian Haftmann, TU Muenchen
     3 
     4 Generic infrastructure for target language data.
     5 *)
     6 
     7 signature CODE_TARGET =
     8 sig
     9   val cert_tyco: theory -> string -> string
    10   val read_tyco: theory -> string -> string
    11 
    12   val export_code_for: theory -> Path.T option -> string -> int option -> string option -> Token.T list
    13     -> Code_Thingol.naming -> Code_Thingol.program -> string list -> unit
    14   val produce_code_for: theory -> string -> int option -> string option -> Token.T list
    15     -> Code_Thingol.naming -> Code_Thingol.program -> string list * string list -> string * string option list
    16   val check_code_for: theory -> string -> bool -> Token.T list
    17     -> Code_Thingol.naming -> Code_Thingol.program -> string list -> unit
    18 
    19   val export_code: theory -> string list
    20     -> (((string * string option) * Path.T option) * Token.T list) list -> unit
    21   val produce_code: theory -> string list -> (Code_Thingol.naming -> string list)
    22     -> string -> int option -> string option -> Token.T list -> string * string option list
    23   val check_code: theory -> string list
    24     -> ((string * bool) * Token.T list) list -> unit
    25 
    26   val shell_command: string (*theory name*) -> string (*export_code expr*) -> unit
    27 
    28   type serializer
    29   type literals = Code_Printer.literals
    30   val add_target: string * { serializer: serializer, literals: literals,
    31     check: { env_var: string, make_destination: Path.T -> Path.T,
    32       make_command: string -> string -> string } } -> theory -> theory
    33   val extend_target: string *
    34       (string * (Code_Thingol.naming -> Code_Thingol.program -> Code_Thingol.program))
    35     -> theory -> theory
    36   val assert_target: theory -> string -> string
    37   val the_literals: theory -> string -> literals
    38   type serialization
    39   val parse_args: 'a parser -> Token.T list -> 'a
    40   val serialization: (int -> Path.T option -> 'a -> unit)
    41     -> (int -> 'a -> string * string option list)
    42     -> 'a -> serialization
    43   val set_default_code_width: int -> theory -> theory
    44 
    45   val allow_abort: string -> theory -> theory
    46   type tyco_syntax = Code_Printer.tyco_syntax
    47   type const_syntax = Code_Printer.const_syntax
    48   val add_class_syntax: string -> class -> string option -> theory -> theory
    49   val add_instance_syntax: string -> class * string -> unit option -> theory -> theory
    50   val add_tyco_syntax: string -> string -> tyco_syntax option -> theory -> theory
    51   val add_const_syntax: string -> string -> const_syntax option -> theory -> theory
    52   val add_reserved: string -> string -> theory -> theory
    53   val add_include: string -> string * (string * string list) option -> theory -> theory
    54 end;
    55 
    56 structure Code_Target : CODE_TARGET =
    57 struct
    58 
    59 open Basic_Code_Thingol;
    60 
    61 type literals = Code_Printer.literals;
    62 type tyco_syntax = Code_Printer.tyco_syntax;
    63 type const_syntax = Code_Printer.const_syntax;
    64 
    65 
    66 (** abstract nonsense **)
    67 
    68 datatype destination = File of Path.T option | String of string list;
    69 type serialization = int -> destination -> (string * string option list) option;
    70 
    71 fun stmt_names_of_destination (String stmt_names) = stmt_names
    72   | stmt_names_of_destination _ = [];
    73 
    74 fun serialization output _ content width (File some_path) = (output width some_path content; NONE)
    75   | serialization _ string content width (String _) = SOME (string width content);
    76 
    77 fun file some_path f = (f (File some_path); ());
    78 fun string stmt_names f = the (f (String stmt_names));
    79 
    80 
    81 (** theory data **)
    82 
    83 datatype symbol_syntax_data = Symbol_Syntax_Data of {
    84   class: string Symtab.table,
    85   instance: unit Symreltab.table,
    86   tyco: Code_Printer.tyco_syntax Symtab.table,
    87   const: Code_Printer.const_syntax Symtab.table
    88 };
    89 
    90 fun make_symbol_syntax_data ((class, instance), (tyco, const)) =
    91   Symbol_Syntax_Data { class = class, instance = instance, tyco = tyco, const = const };
    92 fun map_symbol_syntax_data f (Symbol_Syntax_Data { class, instance, tyco, const }) =
    93   make_symbol_syntax_data (f ((class, instance), (tyco, const)));
    94 fun merge_symbol_syntax_data
    95   (Symbol_Syntax_Data { class = class1, instance = instance1, tyco = tyco1, const = const1 },
    96     Symbol_Syntax_Data { class = class2, instance = instance2, tyco = tyco2, const = const2 }) =
    97   make_symbol_syntax_data (
    98     (Symtab.join (K snd) (class1, class2),
    99        Symreltab.join (K snd) (instance1, instance2)),
   100     (Symtab.join (K snd) (tyco1, tyco2),
   101        Symtab.join (K snd) (const1, const2))
   102   );
   103 
   104 type serializer = Token.T list (*arguments*) -> {
   105     labelled_name: string -> string,
   106     reserved_syms: string list,
   107     includes: (string * Pretty.T) list,
   108     module_alias: string -> string option,
   109     class_syntax: string -> string option,
   110     tyco_syntax: string -> Code_Printer.tyco_syntax option,
   111     const_syntax: string -> Code_Printer.activated_const_syntax option,
   112     program: Code_Thingol.program,
   113     names: string list,
   114     presentation_names: string list }
   115   -> serialization;
   116 
   117 datatype description = Fundamental of { serializer: serializer,
   118       literals: literals,
   119       check: { env_var: string, make_destination: Path.T -> Path.T,
   120         make_command: string -> string -> string } }
   121   | Extension of string *
   122       (Code_Thingol.naming -> Code_Thingol.program -> Code_Thingol.program);
   123 
   124 datatype target = Target of {
   125   serial: serial,
   126   description: description,
   127   reserved: string list,
   128   includes: (Pretty.T * string list) Symtab.table,
   129   module_alias: string Symtab.table,
   130   symbol_syntax: symbol_syntax_data
   131 };
   132 
   133 fun make_target ((serial, description), ((reserved, includes), (module_alias, symbol_syntax))) =
   134   Target { serial = serial, description = description, reserved = reserved, 
   135     includes = includes, module_alias = module_alias, symbol_syntax = symbol_syntax };
   136 fun map_target f ( Target { serial, description, reserved, includes, module_alias, symbol_syntax } ) =
   137   make_target (f ((serial, description), ((reserved, includes), (module_alias, symbol_syntax))));
   138 fun merge_target strict target (Target { serial = serial1, description = description,
   139   reserved = reserved1, includes = includes1,
   140   module_alias = module_alias1, symbol_syntax = symbol_syntax1 },
   141     Target { serial = serial2, description = _,
   142       reserved = reserved2, includes = includes2,
   143       module_alias = module_alias2, symbol_syntax = symbol_syntax2 }) =
   144   if serial1 = serial2 orelse not strict then
   145     make_target ((serial1, description),
   146       ((merge (op =) (reserved1, reserved2), Symtab.join (K snd) (includes1, includes2)),
   147         (Symtab.join (K snd) (module_alias1, module_alias2),
   148           merge_symbol_syntax_data (symbol_syntax1, symbol_syntax2))
   149     ))
   150   else
   151     error ("Incompatible targets: " ^ quote target);
   152 
   153 fun the_description (Target { description, ... }) = description;
   154 fun the_reserved (Target { reserved, ... }) = reserved;
   155 fun the_includes (Target { includes, ... }) = includes;
   156 fun the_module_alias (Target { module_alias , ... }) = module_alias;
   157 fun the_symbol_syntax (Target { symbol_syntax = Symbol_Syntax_Data x, ... }) = x;
   158 
   159 structure Targets = Theory_Data
   160 (
   161   type T = (target Symtab.table * string list) * int;
   162   val empty = ((Symtab.empty, []), 80);
   163   val extend = I;
   164   fun merge (((target1, exc1), width1), ((target2, exc2), width2)) : T =
   165     ((Symtab.join (merge_target true) (target1, target2),
   166       Library.merge (op =) (exc1, exc2)), Int.max (width1, width2));
   167 );
   168 
   169 val abort_allowed = snd o fst o Targets.get;
   170 
   171 fun assert_target thy target = if Symtab.defined ((fst o fst) (Targets.get thy)) target
   172   then target
   173   else error ("Unknown code target language: " ^ quote target);
   174 
   175 fun put_target (target, seri) thy =
   176   let
   177     val lookup_target = Symtab.lookup ((fst o fst) (Targets.get thy));
   178     val _ = case seri
   179      of Extension (super, _) => if is_some (lookup_target super) then ()
   180           else error ("Unknown code target language: " ^ quote super)
   181       | _ => ();
   182     val overwriting = case (Option.map the_description o lookup_target) target
   183      of NONE => false
   184       | SOME (Extension _) => true
   185       | SOME (Fundamental _) => (case seri
   186          of Extension _ => error ("Will not overwrite existing target " ^ quote target)
   187           | _ => true);
   188     val _ = if overwriting
   189       then warning ("Overwriting existing target " ^ quote target)
   190       else (); 
   191   in
   192     thy
   193     |> (Targets.map o apfst o apfst o Symtab.update)
   194           (target, make_target ((serial (), seri), (([], Symtab.empty),
   195             (Symtab.empty, make_symbol_syntax_data ((Symtab.empty, Symreltab.empty),
   196               (Symtab.empty, Symtab.empty))))))
   197   end;
   198 
   199 fun add_target (target, seri) = put_target (target, Fundamental seri);
   200 fun extend_target (target, (super, modify)) =
   201   put_target (target, Extension (super, modify));
   202 
   203 fun map_target_data target f thy =
   204   let
   205     val _ = assert_target thy target;
   206   in
   207     thy
   208     |> (Targets.map o apfst o apfst o Symtab.map_entry target o map_target) f
   209   end;
   210 
   211 fun map_reserved target =
   212   map_target_data target o apsnd o apfst o apfst;
   213 fun map_includes target =
   214   map_target_data target o apsnd o apfst o apsnd;
   215 fun map_module_alias target =
   216   map_target_data target o apsnd o apsnd o apfst;
   217 fun map_symbol_syntax target =
   218   map_target_data target o apsnd o apsnd o apsnd o map_symbol_syntax_data;
   219 
   220 fun set_default_code_width k = (Targets.map o apsnd) (K k);
   221 
   222 
   223 (** serializer usage **)
   224 
   225 (* montage *)
   226 
   227 fun the_fundamental thy =
   228   let
   229     val ((targets, _), _) = Targets.get thy;
   230     fun fundamental target = case Symtab.lookup targets target
   231      of SOME data => (case the_description data
   232          of Fundamental data => data
   233           | Extension (super, _) => fundamental super)
   234       | NONE => error ("Unknown code target language: " ^ quote target);
   235   in fundamental end;
   236 
   237 fun the_literals thy = #literals o the_fundamental thy;
   238 
   239 local
   240 
   241 fun activate_target_for thy target naming program =
   242   let
   243     val ((targets, abortable), default_width) = Targets.get thy;
   244     fun collapse_hierarchy target =
   245       let
   246         val data = case Symtab.lookup targets target
   247          of SOME data => data
   248           | NONE => error ("Unknown code target language: " ^ quote target);
   249       in case the_description data
   250        of Fundamental _ => (I, data)
   251         | Extension (super, modify) => let
   252             val (modify', data') = collapse_hierarchy super
   253           in (modify' #> modify naming, merge_target false target (data', data)) end
   254       end;
   255     val (modify, data) = collapse_hierarchy target;
   256   in (default_width, abortable, data, modify program) end;
   257 
   258 fun activate_syntax lookup_name src_tab = Symtab.empty
   259   |> fold_map (fn thing_identifier => fn tab => case lookup_name thing_identifier
   260        of SOME name => (SOME name,
   261             Symtab.update_new (name, the (Symtab.lookup src_tab thing_identifier)) tab)
   262         | NONE => (NONE, tab)) (Symtab.keys src_tab)
   263   |>> map_filter I;
   264 
   265 fun activate_const_syntax thy literals src_tab naming = (Symtab.empty, naming)
   266   |> fold_map (fn c => fn (tab, naming) =>
   267       case Code_Thingol.lookup_const naming c
   268        of SOME name => let
   269               val (syn, naming') = Code_Printer.activate_const_syntax thy
   270                 literals c (the (Symtab.lookup src_tab c)) naming
   271             in (SOME name, (Symtab.update_new (name, syn) tab, naming')) end
   272         | NONE => (NONE, (tab, naming))) (Symtab.keys src_tab)
   273   |>> map_filter I;
   274 
   275 fun activate_symbol_syntax thy literals naming
   276     class_syntax instance_syntax tyco_syntax const_syntax =
   277   let
   278     val (names_class, class_syntax') =
   279       activate_syntax (Code_Thingol.lookup_class naming) class_syntax;
   280     val names_inst = map_filter (Code_Thingol.lookup_instance naming)
   281       (Symreltab.keys instance_syntax);
   282     val (names_tyco, tyco_syntax') =
   283       activate_syntax (Code_Thingol.lookup_tyco naming) tyco_syntax;
   284     val (names_const, (const_syntax', _)) =
   285       activate_const_syntax thy literals const_syntax naming;
   286   in
   287     (names_class @ names_inst @ names_tyco @ names_const,
   288       (class_syntax', tyco_syntax', const_syntax'))
   289   end;
   290 
   291 fun project_program thy abortable names_hidden names1 program2 =
   292   let
   293     val names2 = subtract (op =) names_hidden names1;
   294     val program3 = Graph.subgraph (not o member (op =) names_hidden) program2;
   295     val names_all = Graph.all_succs program3 names2;
   296     val empty_funs = filter_out (member (op =) abortable)
   297       (Code_Thingol.empty_funs program3);
   298     val _ = if null empty_funs then () else error ("No code equations for "
   299       ^ commas (map (Sign.extern_const thy) empty_funs));
   300   in (names_all, program3) end;
   301 
   302 fun invoke_serializer thy abortable serializer literals reserved abs_includes 
   303     module_alias proto_class_syntax proto_instance_syntax proto_tyco_syntax proto_const_syntax
   304     module_name args naming proto_program (names, presentation_names) =
   305   let
   306     val (names_hidden, (class_syntax, tyco_syntax, const_syntax)) =
   307       activate_symbol_syntax thy literals naming
   308         proto_class_syntax proto_instance_syntax proto_tyco_syntax proto_const_syntax;
   309     val (names_all, program) = project_program thy abortable names_hidden names proto_program;
   310     val includes = abs_includes names_all;
   311   in
   312     serializer args {
   313       labelled_name = Code_Thingol.labelled_name thy proto_program,
   314       reserved_syms = reserved,
   315       includes = includes,
   316       module_alias = if is_some module_name then K module_name else Symtab.lookup module_alias,
   317       class_syntax = Symtab.lookup class_syntax,
   318       tyco_syntax = Symtab.lookup tyco_syntax,
   319       const_syntax = Symtab.lookup const_syntax,
   320       program = program,
   321       names = names,
   322       presentation_names = presentation_names }
   323   end;
   324 
   325 fun mount_serializer thy target some_width raw_module_name args naming proto_program names destination =
   326   let
   327     val (default_width, abortable, data, program) =
   328       activate_target_for thy target naming proto_program;
   329     val serializer = case the_description data
   330      of Fundamental seri => #serializer seri;
   331     val presentation_names = stmt_names_of_destination destination;
   332     val module_name = if null presentation_names
   333       then raw_module_name else SOME "Code";
   334     val reserved = the_reserved data;
   335     fun select_include names_all (name, (content, cs)) =
   336       if null cs then SOME (name, content)
   337       else if exists (fn c => case Code_Thingol.lookup_const naming c
   338        of SOME name => member (op =) names_all name
   339         | NONE => false) cs
   340       then SOME (name, content) else NONE;
   341     fun includes names_all = map_filter (select_include names_all)
   342       ((Symtab.dest o the_includes) data);
   343     val module_alias = the_module_alias data 
   344     val { class, instance, tyco, const } = the_symbol_syntax data;
   345     val literals = the_literals thy target;
   346     val width = the_default default_width some_width;
   347   in
   348     invoke_serializer thy abortable serializer literals reserved
   349       includes module_alias class instance tyco const module_name args
   350         naming program (names, presentation_names) width destination
   351   end;
   352 
   353 in
   354 
   355 fun export_code_for thy some_path target some_width some_module_name args naming program names =
   356   file some_path (mount_serializer thy target some_width some_module_name args naming program names);
   357 
   358 fun produce_code_for thy target some_width some_module_name args naming program (names, selects) =
   359   string selects (mount_serializer thy target some_width some_module_name args naming program names);
   360 
   361 fun check_code_for thy target strict args naming program names_cs =
   362   let
   363     val module_name = "Code_Test";
   364     val { env_var, make_destination, make_command } =
   365       (#check o the_fundamental thy) target;
   366     val env_param = getenv env_var;
   367     fun ext_check env_param p =
   368       let 
   369         val destination = make_destination p;
   370         val _ = file (SOME destination) (mount_serializer thy target (SOME 80)
   371           (SOME module_name) args naming program names_cs);
   372         val cmd = make_command env_param module_name;
   373       in if bash ("cd " ^ File.shell_path p ^ " && " ^ cmd ^ " 2>&1") <> 0
   374         then error ("Code check failed for " ^ target ^ ": " ^ cmd)
   375         else ()
   376       end;
   377   in if env_param = ""
   378     then if strict
   379       then error (env_var ^ " not set; cannot check code for " ^ target)
   380       else warning (env_var ^ " not set; skipped checking code for " ^ target)
   381     else Cache_IO.with_tmp_dir "Code_Test" (ext_check env_param)
   382   end;
   383 
   384 end; (* local *)
   385 
   386 
   387 (* code generation *)
   388 
   389 fun transitivly_non_empty_funs thy naming program =
   390   let
   391     val cs = subtract (op =) (abort_allowed thy) (Code_Thingol.empty_funs program);
   392     val names = map_filter (Code_Thingol.lookup_const naming) cs;
   393   in subtract (op =) (Graph.all_preds program names) (Graph.keys program) end;
   394 
   395 fun read_const_exprs thy cs =
   396   let
   397     val (cs1, cs2) = Code_Thingol.read_const_exprs thy cs;
   398     val (names2, (naming, program)) = Code_Thingol.consts_program thy true cs2;
   399     val names3 = transitivly_non_empty_funs thy naming program;
   400     val cs3 = map_filter (fn (c, name) =>
   401       if member (op =) names3 name then SOME c else NONE) (cs2 ~~ names2);
   402   in union (op =) cs3 cs1 end;
   403 
   404 fun prep_destination "" = NONE
   405   | prep_destination "-" = NONE
   406   | prep_destination s = SOME (Path.explode s);
   407 
   408 fun export_code thy cs seris =
   409   let
   410     val (names_cs, (naming, program)) = Code_Thingol.consts_program thy false cs;
   411     val _ = map (fn (((target, module_name), some_path), args) =>
   412       export_code_for thy some_path target NONE module_name args naming program names_cs) seris;
   413   in () end;
   414 
   415 fun export_code_cmd raw_cs seris thy = export_code thy (read_const_exprs thy raw_cs)
   416   ((map o apfst o apsnd) prep_destination seris);
   417 
   418 fun produce_code thy cs names_stmt target some_width some_module_name args =
   419   let
   420     val (names_cs, (naming, program)) = Code_Thingol.consts_program thy false cs;
   421   in produce_code_for thy target some_width some_module_name args naming program (names_cs, names_stmt naming) end;
   422 
   423 fun check_code thy cs seris =
   424   let
   425     val (names_cs, (naming, program)) = Code_Thingol.consts_program thy false cs;
   426     val _ = map (fn ((target, strict), args) =>
   427       check_code_for thy target strict args naming program names_cs) seris;
   428   in () end;
   429 
   430 fun check_code_cmd raw_cs seris thy = check_code thy (read_const_exprs thy raw_cs) seris;
   431 
   432 
   433 (** serializer configuration **)
   434 
   435 (* data access *)
   436 
   437 fun cert_class thy class =
   438   let
   439     val _ = AxClass.get_info thy class;
   440   in class end;
   441 
   442 fun read_class thy = cert_class thy o Sign.intern_class thy;
   443 
   444 fun cert_tyco thy tyco =
   445   let
   446     val _ = if Sign.declared_tyname thy tyco then ()
   447       else error ("No such type constructor: " ^ quote tyco);
   448   in tyco end;
   449 
   450 fun read_tyco thy = cert_tyco thy o Sign.intern_type thy;
   451 
   452 fun cert_inst thy (class, tyco) =
   453   (cert_class thy class, cert_tyco thy tyco);
   454 
   455 fun read_inst thy (raw_tyco, raw_class) =
   456   (read_class thy raw_class, read_tyco thy raw_tyco);
   457 
   458 fun gen_add_syntax (mapp, upd, del) prep_x prep_syn target raw_x some_raw_syn thy =
   459   let
   460     val x = prep_x thy raw_x;
   461     val change = case some_raw_syn
   462      of SOME raw_syn => upd (x, prep_syn thy x raw_syn)
   463       | NONE => del x;
   464   in (map_symbol_syntax target o mapp) change thy end;
   465 
   466 fun gen_add_class_syntax prep_class =
   467   gen_add_syntax (apfst o apfst, Symtab.update, Symtab.delete_safe) prep_class ((K o K) I);
   468 
   469 fun gen_add_instance_syntax prep_inst =
   470   gen_add_syntax (apfst o apsnd, Symreltab.update, Symreltab.delete_safe) prep_inst ((K o K) I);
   471 
   472 fun gen_add_tyco_syntax prep_tyco =
   473   gen_add_syntax (apsnd o apfst, Symtab.update, Symtab.delete_safe) prep_tyco
   474     (fn thy => fn tyco => fn syn => if fst syn <> Sign.arity_number thy tyco
   475       then error ("Number of arguments mismatch in syntax for type constructor " ^ quote tyco)
   476       else syn);
   477 
   478 fun gen_add_const_syntax prep_const =
   479   gen_add_syntax (apsnd o apsnd, Symtab.update, Symtab.delete_safe) prep_const
   480     (fn thy => fn c => fn syn =>
   481       if Code_Printer.requires_args syn > Code.args_number thy c
   482       then error ("Too many arguments in syntax for constant " ^ quote c)
   483       else syn);
   484 
   485 fun add_reserved target =
   486   let
   487     fun add sym syms = if member (op =) syms sym
   488       then error ("Reserved symbol " ^ quote sym ^ " already declared")
   489       else insert (op =) sym syms
   490   in map_reserved target o add end;
   491 
   492 fun gen_add_include read_const target args thy =
   493   let
   494     fun add (name, SOME (content, raw_cs)) incls =
   495           let
   496             val _ = if Symtab.defined incls name
   497               then warning ("Overwriting existing include " ^ name)
   498               else ();
   499             val cs = map (read_const thy) raw_cs;
   500           in Symtab.update (name, (Code_Printer.str content, cs)) incls end
   501       | add (name, NONE) incls = Symtab.delete name incls;
   502   in map_includes target (add args) thy end;
   503 
   504 val add_include = gen_add_include (K I);
   505 val add_include_cmd = gen_add_include Code.read_const;
   506 
   507 fun add_module_alias target (thyname, modlname) =
   508   let
   509     val xs = Long_Name.explode modlname;
   510     val xs' = map (Name.desymbolize true) xs;
   511   in if xs' = xs
   512     then map_module_alias target (Symtab.update (thyname, modlname))
   513     else error ("Invalid module name: " ^ quote modlname ^ "\n"
   514       ^ "perhaps try " ^ quote (Long_Name.implode xs'))
   515   end;
   516 
   517 fun gen_allow_abort prep_const raw_c thy =
   518   let
   519     val c = prep_const thy raw_c;
   520   in thy |> (Targets.map o apfst o apsnd) (insert (op =) c) end;
   521 
   522 
   523 (* concrete syntax *)
   524 
   525 local
   526 
   527 fun zip_list (x::xs) f g =
   528   f
   529   :|-- (fn y =>
   530     fold_map (fn x => g |-- f >> pair x) xs
   531     :|-- (fn xys => pair ((x, y) :: xys)));
   532 
   533 fun process_multi_syntax parse_thing parse_syntax change =
   534   (Parse.and_list1 parse_thing
   535   :|-- (fn things => Scan.repeat1 (Parse.$$$ "(" |-- Parse.name --
   536         (zip_list things parse_syntax (Parse.$$$ "and")) --| Parse.$$$ ")")))
   537   >> (Toplevel.theory oo fold)
   538     (fn (target, syns) => fold (fn (raw_x, syn) => change target raw_x syn) syns);
   539 
   540 in
   541 
   542 val add_class_syntax = gen_add_class_syntax cert_class;
   543 val add_instance_syntax = gen_add_instance_syntax cert_inst;
   544 val add_tyco_syntax = gen_add_tyco_syntax cert_tyco;
   545 val add_const_syntax = gen_add_const_syntax (K I);
   546 val allow_abort = gen_allow_abort (K I);
   547 val add_reserved = add_reserved;
   548 val add_include = add_include;
   549 
   550 val add_class_syntax_cmd = gen_add_class_syntax read_class;
   551 val add_instance_syntax_cmd = gen_add_instance_syntax read_inst;
   552 val add_tyco_syntax_cmd = gen_add_tyco_syntax read_tyco;
   553 val add_const_syntax_cmd = gen_add_const_syntax Code.read_const;
   554 val allow_abort_cmd = gen_allow_abort Code.read_const;
   555 
   556 fun parse_args f args =
   557   case Scan.read Token.stopper f args
   558    of SOME x => x
   559     | NONE => error "Bad serializer arguments";
   560 
   561 
   562 (** Isar setup **)
   563 
   564 val (inK, module_nameK, fileK, checkingK) = ("in", "module_name", "file", "checking");
   565 
   566 val code_expr_argsP = Scan.optional (Parse.$$$ "(" |-- Args.parse --| Parse.$$$ ")") [];
   567 
   568 val code_exprP =
   569   Scan.repeat1 Parse.term_group :|-- (fn raw_cs =>
   570     ((Parse.$$$ checkingK |-- Scan.repeat (Parse.name
   571       -- ((Parse.$$$ "?" |-- Scan.succeed false) || Scan.succeed true) -- code_expr_argsP))
   572       >> (fn seris => check_code_cmd raw_cs seris)
   573     || Scan.repeat (Parse.$$$ inK |-- Parse.name
   574        -- Scan.option (Parse.$$$ module_nameK |-- Parse.name)
   575        -- Scan.optional (Parse.$$$ fileK |-- Parse.name) ""
   576        -- code_expr_argsP) >> (fn seris => export_code_cmd raw_cs seris)));
   577 
   578 val _ = List.app Keyword.keyword [inK, module_nameK, fileK, checkingK];
   579 
   580 val _ =
   581   Outer_Syntax.command "code_class" "define code syntax for class" Keyword.thy_decl (
   582     process_multi_syntax Parse.xname (Scan.option Parse.string)
   583     add_class_syntax_cmd);
   584 
   585 val _ =
   586   Outer_Syntax.command "code_instance" "define code syntax for instance" Keyword.thy_decl (
   587     process_multi_syntax (Parse.xname --| Parse.$$$ "::" -- Parse.xname)
   588       (Scan.option (Parse.minus >> K ()))
   589     add_instance_syntax_cmd);
   590 
   591 val _ =
   592   Outer_Syntax.command "code_type" "define code syntax for type constructor" Keyword.thy_decl (
   593     process_multi_syntax Parse.xname Code_Printer.parse_tyco_syntax
   594     add_tyco_syntax_cmd);
   595 
   596 val _ =
   597   Outer_Syntax.command "code_const" "define code syntax for constant" Keyword.thy_decl (
   598     process_multi_syntax Parse.term_group Code_Printer.parse_const_syntax
   599     add_const_syntax_cmd);
   600 
   601 val _ =
   602   Outer_Syntax.command "code_reserved" "declare words as reserved for target language"
   603     Keyword.thy_decl (
   604     Parse.name -- Scan.repeat1 Parse.name
   605     >> (fn (target, reserveds) => (Toplevel.theory o fold (add_reserved target)) reserveds)
   606   );
   607 
   608 val _ =
   609   Outer_Syntax.command "code_include" "declare piece of code to be included in generated code"
   610     Keyword.thy_decl (
   611     Parse.name -- Parse.name -- (Parse.text :|-- (fn "-" => Scan.succeed NONE
   612       | s => Scan.optional (Parse.$$$ "attach" |-- Scan.repeat1 Parse.term) [] >> pair s >> SOME))
   613     >> (fn ((target, name), content_consts) =>
   614         (Toplevel.theory o add_include_cmd target) (name, content_consts))
   615   );
   616 
   617 val _ =
   618   Outer_Syntax.command "code_modulename" "alias module to other name" Keyword.thy_decl (
   619     Parse.name -- Scan.repeat1 (Parse.name -- Parse.name)
   620     >> (fn (target, modlnames) => (Toplevel.theory o fold (add_module_alias target)) modlnames)
   621   );
   622 
   623 val _ =
   624   Outer_Syntax.command "code_abort" "permit constant to be implemented as program abort"
   625     Keyword.thy_decl (
   626     Scan.repeat1 Parse.term_group >> (Toplevel.theory o fold allow_abort_cmd)
   627   );
   628 
   629 val _ =
   630   Outer_Syntax.command "export_code" "generate executable code for constants"
   631     Keyword.diag (Parse.!!! code_exprP >> (fn f => Toplevel.keep (f o Toplevel.theory_of)));
   632 
   633 fun shell_command thyname cmd = Toplevel.program (fn _ =>
   634   (use_thy thyname; case Scan.read Token.stopper (Parse.!!! code_exprP)
   635     ((filter Token.is_proper o Outer_Syntax.scan Position.none) cmd)
   636    of SOME f => (writeln "Now generating code..."; f (Thy_Info.get_theory thyname))
   637     | NONE => error ("Bad directive " ^ quote cmd)))
   638   handle Runtime.TOPLEVEL_ERROR => OS.Process.exit OS.Process.failure;
   639 
   640 end; (*local*)
   641 
   642 end; (*struct*)