src/Tools/induct.ML
author nipkow
Tue Sep 20 05:47:11 2011 +0200 (2011-09-20)
changeset 45014 0e847655b2d8
parent 44942 a05ab4d803f2
child 45130 563caf031b50
permissions -rw-r--r--
New proof method "induction" that gives induction hypotheses the name IH.
     1 (*  Title:      Tools/induct.ML
     2     Author:     Markus Wenzel, TU Muenchen
     3 
     4 Proof by cases, induction, and coinduction.
     5 *)
     6 
     7 signature INDUCT_ARGS =
     8 sig
     9   val cases_default: thm
    10   val atomize: thm list
    11   val rulify: thm list
    12   val rulify_fallback: thm list
    13   val equal_def: thm
    14   val dest_def: term -> (term * term) option
    15   val trivial_tac: int -> tactic
    16 end;
    17 
    18 signature INDUCT =
    19 sig
    20   (*rule declarations*)
    21   val vars_of: term -> term list
    22   val dest_rules: Proof.context ->
    23     {type_cases: (string * thm) list, pred_cases: (string * thm) list,
    24       type_induct: (string * thm) list, pred_induct: (string * thm) list,
    25       type_coinduct: (string * thm) list, pred_coinduct: (string * thm) list}
    26   val print_rules: Proof.context -> unit
    27   val lookup_casesT: Proof.context -> string -> thm option
    28   val lookup_casesP: Proof.context -> string -> thm option
    29   val lookup_inductT: Proof.context -> string -> thm option
    30   val lookup_inductP: Proof.context -> string -> thm option
    31   val lookup_coinductT: Proof.context -> string -> thm option
    32   val lookup_coinductP: Proof.context -> string -> thm option
    33   val find_casesT: Proof.context -> typ -> thm list
    34   val find_casesP: Proof.context -> term -> thm list
    35   val find_inductT: Proof.context -> typ -> thm list
    36   val find_inductP: Proof.context -> term -> thm list
    37   val find_coinductT: Proof.context -> typ -> thm list
    38   val find_coinductP: Proof.context -> term -> thm list
    39   val cases_type: string -> attribute
    40   val cases_pred: string -> attribute
    41   val cases_del: attribute
    42   val induct_type: string -> attribute
    43   val induct_pred: string -> attribute
    44   val induct_del: attribute
    45   val coinduct_type: string -> attribute
    46   val coinduct_pred: string -> attribute
    47   val coinduct_del: attribute
    48   val map_simpset: (simpset -> simpset) -> Context.generic -> Context.generic
    49   val induct_simp_add: attribute
    50   val induct_simp_del: attribute
    51   val no_simpN: string
    52   val casesN: string
    53   val inductN: string
    54   val coinductN: string
    55   val typeN: string
    56   val predN: string
    57   val setN: string
    58   (*proof methods*)
    59   val fix_tac: Proof.context -> int -> (string * typ) list -> int -> tactic
    60   val add_defs: (binding option * (term * bool)) option list -> Proof.context ->
    61     (term option list * thm list) * Proof.context
    62   val atomize_term: theory -> term -> term
    63   val atomize_cterm: conv
    64   val atomize_tac: int -> tactic
    65   val inner_atomize_tac: int -> tactic
    66   val rulified_term: thm -> theory * term
    67   val rulify_tac: int -> tactic
    68   val simplified_rule: Proof.context -> thm -> thm
    69   val simplify_tac: Proof.context -> int -> tactic
    70   val trivial_tac: int -> tactic
    71   val rotate_tac: int -> int -> int -> tactic
    72   val internalize: int -> thm -> thm
    73   val guess_instance: Proof.context -> thm -> int -> thm -> thm Seq.seq
    74   val cases_tac: Proof.context -> bool -> term option list list -> thm option ->
    75     thm list -> int -> cases_tactic
    76   val get_inductT: Proof.context -> term option list list -> thm list list
    77   type case_data = (((string * string list) * string list) list * int) (* FIXME -> rule_cases.ML *)
    78   val gen_induct_tac: (theory -> case_data * thm -> case_data * thm) ->
    79     Proof.context -> bool -> (binding option * (term * bool)) option list list ->
    80     (string * typ) list list -> term option list -> thm list option ->
    81     thm list -> int -> cases_tactic
    82   val induct_tac: Proof.context -> bool -> (binding option * (term * bool)) option list list ->
    83     (string * typ) list list -> term option list -> thm list option ->
    84     thm list -> int -> cases_tactic
    85   val coinduct_tac: Proof.context -> term option list -> term option list -> thm option ->
    86     thm list -> int -> cases_tactic
    87   val gen_induct_setup: binding ->
    88    (Proof.context -> bool -> (binding option * (term * bool)) option list list ->
    89     (string * typ) list list -> term option list -> thm list option ->
    90     thm list -> int -> cases_tactic) ->
    91    theory -> theory
    92   val setup: theory -> theory
    93 end;
    94 
    95 functor Induct(Induct_Args: INDUCT_ARGS): INDUCT =
    96 struct
    97 
    98 (** variables -- ordered left-to-right, preferring right **)
    99 
   100 fun vars_of tm =
   101   rev (distinct (op =) (Term.fold_aterms (fn (t as Var _) => cons t | _ => I) tm []));
   102 
   103 local
   104 
   105 val mk_var = Net.encode_type o #2 o Term.dest_Var;
   106 
   107 fun concl_var which thm = mk_var (which (vars_of (Thm.concl_of thm))) handle Empty =>
   108   raise THM ("No variables in conclusion of rule", 0, [thm]);
   109 
   110 in
   111 
   112 fun left_var_prem thm = mk_var (hd (vars_of (hd (Thm.prems_of thm)))) handle Empty =>
   113   raise THM ("No variables in major premise of rule", 0, [thm]);
   114 
   115 val left_var_concl = concl_var hd;
   116 val right_var_concl = concl_var List.last;
   117 
   118 end;
   119 
   120 
   121 
   122 (** constraint simplification **)
   123 
   124 (* rearrange parameters and premises to allow application of one-point-rules *)
   125 
   126 fun swap_params_conv ctxt i j cv =
   127   let
   128     fun conv1 0 ctxt = Conv.forall_conv (cv o snd) ctxt
   129       | conv1 k ctxt =
   130           Conv.rewr_conv @{thm swap_params} then_conv
   131           Conv.forall_conv (conv1 (k - 1) o snd) ctxt
   132     fun conv2 0 ctxt = conv1 j ctxt
   133       | conv2 k ctxt = Conv.forall_conv (conv2 (k - 1) o snd) ctxt
   134   in conv2 i ctxt end;
   135 
   136 fun swap_prems_conv 0 = Conv.all_conv
   137   | swap_prems_conv i =
   138       Conv.implies_concl_conv (swap_prems_conv (i - 1)) then_conv
   139       Conv.rewr_conv Drule.swap_prems_eq
   140 
   141 fun drop_judgment ctxt = Object_Logic.drop_judgment (Proof_Context.theory_of ctxt);
   142 
   143 fun find_eq ctxt t =
   144   let
   145     val l = length (Logic.strip_params t);
   146     val Hs = Logic.strip_assums_hyp t;
   147     fun find (i, t) =
   148       (case Induct_Args.dest_def (drop_judgment ctxt t) of
   149         SOME (Bound j, _) => SOME (i, j)
   150       | SOME (_, Bound j) => SOME (i, j)
   151       | _ => NONE);
   152   in
   153     (case get_first find (map_index I Hs) of
   154       NONE => NONE
   155     | SOME (0, 0) => NONE
   156     | SOME (i, j) => SOME (i, l - j - 1, j))
   157   end;
   158 
   159 fun mk_swap_rrule ctxt ct =
   160   (case find_eq ctxt (term_of ct) of
   161     NONE => NONE
   162   | SOME (i, k, j) => SOME (swap_params_conv ctxt k j (K (swap_prems_conv i)) ct));
   163 
   164 val rearrange_eqs_simproc =
   165   Simplifier.simproc_global
   166     (Thm.theory_of_thm Drule.swap_prems_eq) "rearrange_eqs" ["all t"]
   167     (fn thy => fn ss => fn t =>
   168       mk_swap_rrule (Simplifier.the_context ss) (cterm_of thy t));
   169 
   170 
   171 (* rotate k premises to the left by j, skipping over first j premises *)
   172 
   173 fun rotate_conv 0 j 0 = Conv.all_conv
   174   | rotate_conv 0 j k = swap_prems_conv j then_conv rotate_conv 1 j (k - 1)
   175   | rotate_conv i j k = Conv.implies_concl_conv (rotate_conv (i - 1) j k);
   176 
   177 fun rotate_tac j 0 = K all_tac
   178   | rotate_tac j k = SUBGOAL (fn (goal, i) =>
   179       CONVERSION (rotate_conv
   180         j (length (Logic.strip_assums_hyp goal) - j - k) k) i);
   181 
   182 
   183 (* rulify operators around definition *)
   184 
   185 fun rulify_defs_conv ctxt ct =
   186   if exists_subterm (is_some o Induct_Args.dest_def) (term_of ct) andalso
   187     not (is_some (Induct_Args.dest_def (drop_judgment ctxt (term_of ct))))
   188   then
   189     (Conv.forall_conv (rulify_defs_conv o snd) ctxt else_conv
   190      Conv.implies_conv (Conv.try_conv (rulify_defs_conv ctxt))
   191        (Conv.try_conv (rulify_defs_conv ctxt)) else_conv
   192      Conv.first_conv (map Conv.rewr_conv Induct_Args.rulify) then_conv
   193        Conv.try_conv (rulify_defs_conv ctxt)) ct
   194   else Conv.no_conv ct;
   195 
   196 
   197 
   198 (** induct data **)
   199 
   200 (* rules *)
   201 
   202 type rules = (string * thm) Item_Net.T;
   203 
   204 fun init_rules index : rules =
   205   Item_Net.init
   206     (fn ((s1, th1), (s2, th2)) => s1 = s2 andalso Thm.eq_thm_prop (th1, th2))
   207     (single o index);
   208 
   209 fun filter_rules (rs: rules) th =
   210   filter (fn (_, th') => Thm.eq_thm_prop (th, th')) (Item_Net.content rs);
   211 
   212 fun lookup_rule (rs: rules) = AList.lookup (op =) (Item_Net.content rs);
   213 
   214 fun pretty_rules ctxt kind rs =
   215   let val thms = map snd (Item_Net.content rs)
   216   in Pretty.big_list kind (map (Display.pretty_thm ctxt) thms) end;
   217 
   218 
   219 (* context data *)
   220 
   221 structure Data = Generic_Data
   222 (
   223   type T = (rules * rules) * (rules * rules) * (rules * rules) * simpset;
   224   val empty =
   225     ((init_rules (left_var_prem o #2), init_rules (Thm.major_prem_of o #2)),
   226      (init_rules (right_var_concl o #2), init_rules (Thm.major_prem_of o #2)),
   227      (init_rules (left_var_concl o #2), init_rules (Thm.concl_of o #2)),
   228      empty_ss addsimprocs [rearrange_eqs_simproc] addsimps [Drule.norm_hhf_eq]);
   229   val extend = I;
   230   fun merge (((casesT1, casesP1), (inductT1, inductP1), (coinductT1, coinductP1), simpset1),
   231       ((casesT2, casesP2), (inductT2, inductP2), (coinductT2, coinductP2), simpset2)) =
   232     ((Item_Net.merge (casesT1, casesT2), Item_Net.merge (casesP1, casesP2)),
   233      (Item_Net.merge (inductT1, inductT2), Item_Net.merge (inductP1, inductP2)),
   234      (Item_Net.merge (coinductT1, coinductT2), Item_Net.merge (coinductP1, coinductP2)),
   235      merge_ss (simpset1, simpset2));
   236 );
   237 
   238 val get_local = Data.get o Context.Proof;
   239 
   240 fun dest_rules ctxt =
   241   let val ((casesT, casesP), (inductT, inductP), (coinductT, coinductP), _) = get_local ctxt in
   242     {type_cases = Item_Net.content casesT,
   243      pred_cases = Item_Net.content casesP,
   244      type_induct = Item_Net.content inductT,
   245      pred_induct = Item_Net.content inductP,
   246      type_coinduct = Item_Net.content coinductT,
   247      pred_coinduct = Item_Net.content coinductP}
   248   end;
   249 
   250 fun print_rules ctxt =
   251   let val ((casesT, casesP), (inductT, inductP), (coinductT, coinductP), _) = get_local ctxt in
   252    [pretty_rules ctxt "coinduct type:" coinductT,
   253     pretty_rules ctxt "coinduct pred:" coinductP,
   254     pretty_rules ctxt "induct type:" inductT,
   255     pretty_rules ctxt "induct pred:" inductP,
   256     pretty_rules ctxt "cases type:" casesT,
   257     pretty_rules ctxt "cases pred:" casesP]
   258     |> Pretty.chunks |> Pretty.writeln
   259   end;
   260 
   261 val _ =
   262   Outer_Syntax.improper_command "print_induct_rules" "print induction and cases rules"
   263     Keyword.diag (Scan.succeed (Toplevel.no_timing o Toplevel.unknown_context o
   264       Toplevel.keep (print_rules o Toplevel.context_of)));
   265 
   266 
   267 (* access rules *)
   268 
   269 val lookup_casesT = lookup_rule o #1 o #1 o get_local;
   270 val lookup_casesP = lookup_rule o #2 o #1 o get_local;
   271 val lookup_inductT = lookup_rule o #1 o #2 o get_local;
   272 val lookup_inductP = lookup_rule o #2 o #2 o get_local;
   273 val lookup_coinductT = lookup_rule o #1 o #3 o get_local;
   274 val lookup_coinductP = lookup_rule o #2 o #3 o get_local;
   275 
   276 
   277 fun find_rules which how ctxt x =
   278   map snd (Item_Net.retrieve (which (get_local ctxt)) (how x));
   279 
   280 val find_casesT = find_rules (#1 o #1) Net.encode_type;
   281 val find_casesP = find_rules (#2 o #1) I;
   282 val find_inductT = find_rules (#1 o #2) Net.encode_type;
   283 val find_inductP = find_rules (#2 o #2) I;
   284 val find_coinductT = find_rules (#1 o #3) Net.encode_type;
   285 val find_coinductP = find_rules (#2 o #3) I;
   286 
   287 
   288 
   289 (** attributes **)
   290 
   291 local
   292 
   293 fun mk_att f g name arg =
   294   let val (x, thm) = g arg in (Data.map (f (name, thm)) x, thm) end;
   295 
   296 fun del_att which =
   297   Thm.declaration_attribute (fn th => Data.map (which (pairself (fn rs =>
   298     fold Item_Net.remove (filter_rules rs th) rs))));
   299 
   300 fun map1 f (x, y, z, s) = (f x, y, z, s);
   301 fun map2 f (x, y, z, s) = (x, f y, z, s);
   302 fun map3 f (x, y, z, s) = (x, y, f z, s);
   303 fun map4 f (x, y, z, s) = (x, y, z, f s);
   304 
   305 fun add_casesT rule x = map1 (apfst (Item_Net.update rule)) x;
   306 fun add_casesP rule x = map1 (apsnd (Item_Net.update rule)) x;
   307 fun add_inductT rule x = map2 (apfst (Item_Net.update rule)) x;
   308 fun add_inductP rule x = map2 (apsnd (Item_Net.update rule)) x;
   309 fun add_coinductT rule x = map3 (apfst (Item_Net.update rule)) x;
   310 fun add_coinductP rule x = map3 (apsnd (Item_Net.update rule)) x;
   311 
   312 val consumes0 = Rule_Cases.consumes_default 0;
   313 val consumes1 = Rule_Cases.consumes_default 1;
   314 
   315 in
   316 
   317 val cases_type = mk_att add_casesT consumes0;
   318 val cases_pred = mk_att add_casesP consumes1;
   319 val cases_del = del_att map1;
   320 
   321 val induct_type = mk_att add_inductT consumes0;
   322 val induct_pred = mk_att add_inductP consumes1;
   323 val induct_del = del_att map2;
   324 
   325 val coinduct_type = mk_att add_coinductT consumes0;
   326 val coinduct_pred = mk_att add_coinductP consumes1;
   327 val coinduct_del = del_att map3;
   328 
   329 fun map_simpset f = Data.map (map4 f);
   330 
   331 fun induct_simp f =
   332   Thm.declaration_attribute (fn thm => fn context =>
   333       map_simpset
   334         (Simplifier.with_context (Context.proof_of context) (fn ss => f (ss, [thm]))) context);
   335 
   336 val induct_simp_add = induct_simp (op addsimps);
   337 val induct_simp_del = induct_simp (op delsimps);
   338 
   339 end;
   340 
   341 
   342 
   343 (** attribute syntax **)
   344 
   345 val no_simpN = "no_simp";
   346 val casesN = "cases";
   347 val inductN = "induct";
   348 val coinductN = "coinduct";
   349 
   350 val typeN = "type";
   351 val predN = "pred";
   352 val setN = "set";
   353 
   354 local
   355 
   356 fun spec k arg =
   357   Scan.lift (Args.$$$ k -- Args.colon) |-- arg ||
   358   Scan.lift (Args.$$$ k) >> K "";
   359 
   360 fun attrib add_type add_pred del =
   361   spec typeN (Args.type_name false) >> add_type ||
   362   spec predN (Args.const false) >> add_pred ||
   363   spec setN (Args.const false) >> add_pred ||
   364   Scan.lift Args.del >> K del;
   365 
   366 in
   367 
   368 val attrib_setup =
   369   Attrib.setup @{binding cases} (attrib cases_type cases_pred cases_del)
   370     "declaration of cases rule" #>
   371   Attrib.setup @{binding induct} (attrib induct_type induct_pred induct_del)
   372     "declaration of induction rule" #>
   373   Attrib.setup @{binding coinduct} (attrib coinduct_type coinduct_pred coinduct_del)
   374     "declaration of coinduction rule" #>
   375   Attrib.setup @{binding induct_simp} (Attrib.add_del induct_simp_add induct_simp_del)
   376     "declaration of rules for simplifying induction or cases rules";
   377 
   378 end;
   379 
   380 
   381 
   382 (** method utils **)
   383 
   384 (* alignment *)
   385 
   386 fun align_left msg xs ys =
   387   let val m = length xs and n = length ys
   388   in if m < n then error msg else (take n xs ~~ ys) end;
   389 
   390 fun align_right msg xs ys =
   391   let val m = length xs and n = length ys
   392   in if m < n then error msg else (drop (m - n) xs ~~ ys) end;
   393 
   394 
   395 (* prep_inst *)
   396 
   397 fun prep_inst ctxt align tune (tm, ts) =
   398   let
   399     val cert = Thm.cterm_of (Proof_Context.theory_of ctxt);
   400     fun prep_var (x, SOME t) =
   401           let
   402             val cx = cert x;
   403             val xT = #T (Thm.rep_cterm cx);
   404             val ct = cert (tune t);
   405             val tT = #T (Thm.rep_cterm ct);
   406           in
   407             if Type.could_unify (tT, xT) then SOME (cx, ct)
   408             else error (Pretty.string_of (Pretty.block
   409              [Pretty.str "Ill-typed instantiation:", Pretty.fbrk,
   410               Syntax.pretty_term ctxt (Thm.term_of ct), Pretty.str " ::", Pretty.brk 1,
   411               Syntax.pretty_typ ctxt tT]))
   412           end
   413       | prep_var (_, NONE) = NONE;
   414     val xs = vars_of tm;
   415   in
   416     align "Rule has fewer variables than instantiations given" xs ts
   417     |> map_filter prep_var
   418   end;
   419 
   420 
   421 (* trace_rules *)
   422 
   423 fun trace_rules _ kind [] = error ("Unable to figure out " ^ kind ^ " rule")
   424   | trace_rules ctxt _ rules = Method.trace ctxt rules;
   425 
   426 
   427 (* mark equality constraints in cases rule *)
   428 
   429 val equal_def' = Thm.symmetric Induct_Args.equal_def;
   430 
   431 fun mark_constraints n ctxt = Conv.fconv_rule
   432   (Conv.prems_conv (~1) (Conv.params_conv ~1 (K (Conv.prems_conv n
   433      (Raw_Simplifier.rewrite false [equal_def']))) ctxt));
   434 
   435 val unmark_constraints = Conv.fconv_rule
   436   (Raw_Simplifier.rewrite true [Induct_Args.equal_def]);
   437 
   438 
   439 (* simplify *)
   440 
   441 fun simplify_conv' ctxt =
   442   Simplifier.full_rewrite (Simplifier.context ctxt (#4 (get_local ctxt)));
   443 
   444 fun simplify_conv ctxt ct =
   445   if exists_subterm (is_some o Induct_Args.dest_def) (term_of ct) then
   446     (Conv.try_conv (rulify_defs_conv ctxt) then_conv simplify_conv' ctxt) ct
   447   else Conv.all_conv ct;
   448 
   449 fun gen_simplified_rule cv ctxt =
   450   Conv.fconv_rule (Conv.prems_conv ~1 (cv ctxt));
   451 
   452 val simplified_rule' = gen_simplified_rule simplify_conv';
   453 val simplified_rule = gen_simplified_rule simplify_conv;
   454 
   455 fun simplify_tac ctxt = CONVERSION (simplify_conv ctxt);
   456 
   457 val trivial_tac = Induct_Args.trivial_tac;
   458 
   459 
   460 
   461 (** cases method **)
   462 
   463 (*
   464   rule selection scheme:
   465           cases         - default case split
   466     `A t` cases ...     - predicate/set cases
   467           cases t       - type cases
   468     ...   cases ... r   - explicit rule
   469 *)
   470 
   471 local
   472 
   473 fun get_casesT ctxt ((SOME t :: _) :: _) = find_casesT ctxt (Term.fastype_of t)
   474   | get_casesT _ _ = [];
   475 
   476 fun get_casesP ctxt (fact :: _) = find_casesP ctxt (Thm.concl_of fact)
   477   | get_casesP _ _ = [];
   478 
   479 in
   480 
   481 fun cases_tac ctxt simp insts opt_rule facts =
   482   let
   483     val thy = Proof_Context.theory_of ctxt;
   484 
   485     fun inst_rule r =
   486       (if null insts then r
   487        else (align_left "Rule has fewer premises than arguments given" (Thm.prems_of r) insts
   488          |> maps (prep_inst ctxt align_left I)
   489          |> Drule.cterm_instantiate) r) |>
   490       (if simp then mark_constraints (Rule_Cases.get_constraints r) ctxt else I) |>
   491       pair (Rule_Cases.get r);
   492 
   493     val ruleq =
   494       (case opt_rule of
   495         SOME r => Seq.single (inst_rule r)
   496       | NONE =>
   497           (get_casesP ctxt facts @ get_casesT ctxt insts @ [Induct_Args.cases_default])
   498           |> tap (trace_rules ctxt casesN)
   499           |> Seq.of_list |> Seq.maps (Seq.try inst_rule));
   500   in
   501     fn i => fn st =>
   502       ruleq
   503       |> Seq.maps (Rule_Cases.consume [] facts)
   504       |> Seq.maps (fn ((cases, (_, more_facts)), rule) =>
   505         let val rule' =
   506           (if simp then simplified_rule' ctxt #> unmark_constraints else I) rule
   507         in
   508           CASES (Rule_Cases.make_common (thy,
   509               Thm.prop_of (Rule_Cases.internalize_params rule')) cases)
   510             ((Method.insert_tac more_facts THEN' Tactic.rtac rule' THEN_ALL_NEW
   511                 (if simp then TRY o trivial_tac else K all_tac)) i) st
   512         end)
   513   end;
   514 
   515 end;
   516 
   517 
   518 
   519 (** induct method **)
   520 
   521 val conjunction_congs = [@{thm Pure.all_conjunction}, @{thm imp_conjunction}];
   522 
   523 
   524 (* atomize *)
   525 
   526 fun atomize_term thy =
   527   Raw_Simplifier.rewrite_term thy Induct_Args.atomize []
   528   #> Object_Logic.drop_judgment thy;
   529 
   530 val atomize_cterm = Raw_Simplifier.rewrite true Induct_Args.atomize;
   531 
   532 val atomize_tac = Simplifier.rewrite_goal_tac Induct_Args.atomize;
   533 
   534 val inner_atomize_tac =
   535   Simplifier.rewrite_goal_tac (map Thm.symmetric conjunction_congs) THEN' atomize_tac;
   536 
   537 
   538 (* rulify *)
   539 
   540 fun rulify_term thy =
   541   Raw_Simplifier.rewrite_term thy (Induct_Args.rulify @ conjunction_congs) [] #>
   542   Raw_Simplifier.rewrite_term thy Induct_Args.rulify_fallback [];
   543 
   544 fun rulified_term thm =
   545   let
   546     val thy = Thm.theory_of_thm thm;
   547     val rulify = rulify_term thy;
   548     val (As, B) = Logic.strip_horn (Thm.prop_of thm);
   549   in (thy, Logic.list_implies (map rulify As, rulify B)) end;
   550 
   551 val rulify_tac =
   552   Simplifier.rewrite_goal_tac (Induct_Args.rulify @ conjunction_congs) THEN'
   553   Simplifier.rewrite_goal_tac Induct_Args.rulify_fallback THEN'
   554   Goal.conjunction_tac THEN_ALL_NEW
   555   (Simplifier.rewrite_goal_tac [@{thm Pure.conjunction_imp}] THEN' Goal.norm_hhf_tac);
   556 
   557 
   558 (* prepare rule *)
   559 
   560 fun rule_instance ctxt inst rule =
   561   Drule.cterm_instantiate (prep_inst ctxt align_left I (Thm.prop_of rule, inst)) rule;
   562 
   563 fun internalize k th =
   564   th |> Thm.permute_prems 0 k
   565   |> Conv.fconv_rule (Conv.concl_conv (Thm.nprems_of th - k) atomize_cterm);
   566 
   567 
   568 (* guess rule instantiation -- cannot handle pending goal parameters *)
   569 
   570 local
   571 
   572 fun dest_env thy env =
   573   let
   574     val cert = Thm.cterm_of thy;
   575     val certT = Thm.ctyp_of thy;
   576     val pairs = Vartab.dest (Envir.term_env env);
   577     val types = Vartab.dest (Envir.type_env env);
   578     val ts = map (cert o Envir.norm_term env o #2 o #2) pairs;
   579     val xs = map2 (curry (cert o Var)) (map #1 pairs) (map (#T o Thm.rep_cterm) ts);
   580   in (map (fn (xi, (S, T)) => (certT (TVar (xi, S)), certT T)) types, xs ~~ ts) end;
   581 
   582 in
   583 
   584 fun guess_instance ctxt rule i st =
   585   let
   586     val thy = Proof_Context.theory_of ctxt;
   587     val maxidx = Thm.maxidx_of st;
   588     val goal = Thm.term_of (Thm.cprem_of st i);  (*exception Subscript*)
   589     val params = rev (Term.rename_wrt_term goal (Logic.strip_params goal));
   590   in
   591     if not (null params) then
   592       (warning ("Cannot determine rule instantiation due to pending parameter(s): " ^
   593         commas_quote (map (Syntax.string_of_term ctxt o Syntax_Trans.mark_boundT) params));
   594       Seq.single rule)
   595     else
   596       let
   597         val rule' = Thm.incr_indexes (maxidx + 1) rule;
   598         val concl = Logic.strip_assums_concl goal;
   599       in
   600         Unify.smash_unifiers thy [(Thm.concl_of rule', concl)] (Envir.empty (Thm.maxidx_of rule'))
   601         |> Seq.map (fn env => Drule.instantiate_normalize (dest_env thy env) rule')
   602       end
   603   end
   604   handle General.Subscript => Seq.empty;
   605 
   606 end;
   607 
   608 
   609 (* special renaming of rule parameters *)
   610 
   611 fun special_rename_params ctxt [[SOME (Free (z, Type (T, _)))]] [thm] =
   612       let
   613         val x = Name.clean (Variable.revert_fixed ctxt z);
   614         fun index i [] = []
   615           | index i (y :: ys) =
   616               if x = y then x ^ string_of_int i :: index (i + 1) ys
   617               else y :: index i ys;
   618         fun rename_params [] = []
   619           | rename_params ((y, Type (U, _)) :: ys) =
   620               (if U = T then x else y) :: rename_params ys
   621           | rename_params ((y, _) :: ys) = y :: rename_params ys;
   622         fun rename_asm A =
   623           let
   624             val xs = rename_params (Logic.strip_params A);
   625             val xs' =
   626               (case filter (fn x' => x' = x) xs of
   627                 [] => xs | [_] => xs | _ => index 1 xs);
   628           in Logic.list_rename_params (xs', A) end;
   629         fun rename_prop p =
   630           let val (As, C) = Logic.strip_horn p
   631           in Logic.list_implies (map rename_asm As, C) end;
   632         val cp' = cterm_fun rename_prop (Thm.cprop_of thm);
   633         val thm' = Thm.equal_elim (Thm.reflexive cp') thm;
   634       in [Rule_Cases.save thm thm'] end
   635   | special_rename_params _ _ ths = ths;
   636 
   637 
   638 (* fix_tac *)
   639 
   640 local
   641 
   642 fun goal_prefix k ((c as Const ("all", _)) $ Abs (a, T, B)) = c $ Abs (a, T, goal_prefix k B)
   643   | goal_prefix 0 _ = Term.dummy_pattern propT
   644   | goal_prefix k ((c as Const ("==>", _)) $ A $ B) = c $ A $ goal_prefix (k - 1) B
   645   | goal_prefix _ _ = Term.dummy_pattern propT;
   646 
   647 fun goal_params k (Const ("all", _) $ Abs (_, _, B)) = goal_params k B + 1
   648   | goal_params 0 _ = 0
   649   | goal_params k (Const ("==>", _) $ _ $ B) = goal_params (k - 1) B
   650   | goal_params _ _ = 0;
   651 
   652 fun meta_spec_tac ctxt n (x, T) = SUBGOAL (fn (goal, i) =>
   653   let
   654     val thy = Proof_Context.theory_of ctxt;
   655     val cert = Thm.cterm_of thy;
   656 
   657     val v = Free (x, T);
   658     fun spec_rule prfx (xs, body) =
   659       @{thm Pure.meta_spec}
   660       |> Thm.rename_params_rule ([Name.clean (Variable.revert_fixed ctxt x)], 1)
   661       |> Thm.lift_rule (cert prfx)
   662       |> `(Thm.prop_of #> Logic.strip_assums_concl)
   663       |-> (fn pred $ arg =>
   664         Drule.cterm_instantiate
   665           [(cert (Term.head_of pred), cert (Logic.rlist_abs (xs, body))),
   666            (cert (Term.head_of arg), cert (Logic.rlist_abs (xs, v)))]);
   667 
   668     fun goal_concl k xs (Const ("all", _) $ Abs (a, T, B)) = goal_concl k ((a, T) :: xs) B
   669       | goal_concl 0 xs B =
   670           if not (Term.exists_subterm (fn t => t aconv v) B) then NONE
   671           else SOME (xs, absfree (x, T) (Term.incr_boundvars 1 B))
   672       | goal_concl k xs (Const ("==>", _) $ _ $ B) = goal_concl (k - 1) xs B
   673       | goal_concl _ _ _ = NONE;
   674   in
   675     (case goal_concl n [] goal of
   676       SOME concl =>
   677         (compose_tac (false, spec_rule (goal_prefix n goal) concl, 1) THEN' rtac asm_rl) i
   678     | NONE => all_tac)
   679   end);
   680 
   681 fun miniscope_tac p = CONVERSION o
   682   Conv.params_conv p (K (Raw_Simplifier.rewrite true [Thm.symmetric Drule.norm_hhf_eq]));
   683 
   684 in
   685 
   686 fun fix_tac _ _ [] = K all_tac
   687   | fix_tac ctxt n xs = SUBGOAL (fn (goal, i) =>
   688      (EVERY' (map (meta_spec_tac ctxt n) xs) THEN'
   689       (miniscope_tac (goal_params n goal) ctxt)) i);
   690 
   691 end;
   692 
   693 
   694 (* add_defs *)
   695 
   696 fun add_defs def_insts =
   697   let
   698     fun add (SOME (_, (t, true))) ctxt = ((SOME t, []), ctxt)
   699       | add (SOME (SOME x, (t, _))) ctxt =
   700           let val ([(lhs, (_, th))], ctxt') =
   701             Local_Defs.add_defs [((x, NoSyn), (Thm.empty_binding, t))] ctxt
   702           in ((SOME lhs, [th]), ctxt') end
   703       | add (SOME (NONE, (t as Free _, _))) ctxt = ((SOME t, []), ctxt)
   704       | add (SOME (NONE, (t, _))) ctxt =
   705           let
   706             val (s, _) = Name.variant "x" (Variable.names_of ctxt);
   707             val ([(lhs, (_, th))], ctxt') =
   708               Local_Defs.add_defs [((Binding.name s, NoSyn),
   709                 (Thm.empty_binding, t))] ctxt
   710           in ((SOME lhs, [th]), ctxt') end
   711       | add NONE ctxt = ((NONE, []), ctxt);
   712   in fold_map add def_insts #> apfst (split_list #> apsnd flat) end;
   713 
   714 
   715 (* induct_tac *)
   716 
   717 (*
   718   rule selection scheme:
   719     `A x` induct ...     - predicate/set induction
   720           induct x       - type induction
   721     ...   induct ... r   - explicit rule
   722 *)
   723 
   724 fun get_inductT ctxt insts =
   725   fold_rev (map_product cons) (insts |> map
   726       ((fn [] => NONE | ts => List.last ts) #>
   727         (fn NONE => TVar (("'a", 0), []) | SOME t => Term.fastype_of t) #>
   728         find_inductT ctxt)) [[]]
   729   |> filter_out (forall Rule_Cases.is_inner_rule);
   730 
   731 fun get_inductP ctxt (fact :: _) = map single (find_inductP ctxt (Thm.concl_of fact))
   732   | get_inductP _ _ = [];
   733 
   734 type case_data = (((string * string list) * string list) list * int)
   735 
   736 fun gen_induct_tac mod_cases ctxt simp def_insts arbitrary taking opt_rule facts =
   737   let
   738     val thy = Proof_Context.theory_of ctxt;
   739 
   740     val ((insts, defs), defs_ctxt) = fold_map add_defs def_insts ctxt |>> split_list;
   741     val atomized_defs = map (map (Conv.fconv_rule atomize_cterm)) defs;
   742 
   743     fun inst_rule (concls, r) =
   744       (if null insts then `Rule_Cases.get r
   745        else (align_left "Rule has fewer conclusions than arguments given"
   746           (map Logic.strip_imp_concl (Logic.dest_conjunctions (Thm.concl_of r))) insts
   747         |> maps (prep_inst ctxt align_right (atomize_term thy))
   748         |> Drule.cterm_instantiate) r |> pair (Rule_Cases.get r))
   749       |> mod_cases thy
   750       |> (fn ((cases, consumes), th) => (((cases, concls), consumes), th));
   751 
   752     val ruleq =
   753       (case opt_rule of
   754         SOME rs => Seq.single (inst_rule (Rule_Cases.strict_mutual_rule ctxt rs))
   755       | NONE =>
   756           (get_inductP ctxt facts @
   757             map (special_rename_params defs_ctxt insts) (get_inductT ctxt insts))
   758           |> map_filter (Rule_Cases.mutual_rule ctxt)
   759           |> tap (trace_rules ctxt inductN o map #2)
   760           |> Seq.of_list |> Seq.maps (Seq.try inst_rule));
   761 
   762     fun rule_cases ctxt rule cases =
   763       let
   764         val rule' = Rule_Cases.internalize_params rule;
   765         val rule'' = (if simp then simplified_rule ctxt else I) rule';
   766         val nonames = map (fn ((cn,_),cls) => ((cn,[]),cls))
   767         val cases' =
   768           if Thm.eq_thm_prop (rule', rule'') then cases else nonames cases
   769       in Rule_Cases.make_nested (Thm.prop_of rule'') (rulified_term rule'')
   770            cases'
   771       end;
   772   in
   773     (fn i => fn st =>
   774       ruleq
   775       |> Seq.maps (Rule_Cases.consume (flat defs) facts)
   776       |> Seq.maps (fn (((cases, concls), (more_consumes, more_facts)), rule) =>
   777         (PRECISE_CONJUNCTS (length concls) (ALLGOALS (fn j =>
   778           (CONJUNCTS (ALLGOALS
   779             let
   780               val adefs = nth_list atomized_defs (j - 1);
   781               val frees = fold (Term.add_frees o prop_of) adefs [];
   782               val xs = nth_list arbitrary (j - 1);
   783               val k = nth concls (j - 1) + more_consumes
   784             in
   785               Method.insert_tac (more_facts @ adefs) THEN'
   786                 (if simp then
   787                    rotate_tac k (length adefs) THEN'
   788                    fix_tac defs_ctxt k
   789                      (List.partition (member op = frees) xs |> op @)
   790                  else
   791                    fix_tac defs_ctxt k xs)
   792              end)
   793           THEN' inner_atomize_tac) j))
   794         THEN' atomize_tac) i st |> Seq.maps (fn st' =>
   795             guess_instance ctxt (internalize more_consumes rule) i st'
   796             |> Seq.map (rule_instance ctxt (burrow_options (Variable.polymorphic ctxt) taking))
   797             |> Seq.maps (fn rule' =>
   798               CASES (rule_cases ctxt rule' cases)
   799                 (Tactic.rtac rule' i THEN
   800                   PRIMITIVE (singleton (Proof_Context.export defs_ctxt ctxt))) st'))))
   801     THEN_ALL_NEW_CASES
   802       ((if simp then simplify_tac ctxt THEN' (TRY o trivial_tac)
   803         else K all_tac)
   804        THEN_ALL_NEW rulify_tac)
   805   end;
   806 
   807 val induct_tac = gen_induct_tac (K I);
   808 
   809 (** coinduct method **)
   810 
   811 (*
   812   rule selection scheme:
   813     goal "A x" coinduct ...   - predicate/set coinduction
   814                coinduct x     - type coinduction
   815                coinduct ... r - explicit rule
   816 *)
   817 
   818 local
   819 
   820 fun get_coinductT ctxt (SOME t :: _) = find_coinductT ctxt (Term.fastype_of t)
   821   | get_coinductT _ _ = [];
   822 
   823 fun get_coinductP ctxt goal = find_coinductP ctxt (Logic.strip_assums_concl goal);
   824 
   825 fun main_prop_of th =
   826   if Rule_Cases.get_consumes th > 0 then Thm.major_prem_of th else Thm.concl_of th;
   827 
   828 in
   829 
   830 fun coinduct_tac ctxt inst taking opt_rule facts =
   831   let
   832     val thy = Proof_Context.theory_of ctxt;
   833 
   834     fun inst_rule r =
   835       if null inst then `Rule_Cases.get r
   836       else Drule.cterm_instantiate (prep_inst ctxt align_right I (main_prop_of r, inst)) r
   837         |> pair (Rule_Cases.get r);
   838 
   839     fun ruleq goal =
   840       (case opt_rule of
   841         SOME r => Seq.single (inst_rule r)
   842       | NONE =>
   843           (get_coinductP ctxt goal @ get_coinductT ctxt inst)
   844           |> tap (trace_rules ctxt coinductN)
   845           |> Seq.of_list |> Seq.maps (Seq.try inst_rule));
   846   in
   847     SUBGOAL_CASES (fn (goal, i) => fn st =>
   848       ruleq goal
   849       |> Seq.maps (Rule_Cases.consume [] facts)
   850       |> Seq.maps (fn ((cases, (_, more_facts)), rule) =>
   851         guess_instance ctxt rule i st
   852         |> Seq.map (rule_instance ctxt (burrow_options (Variable.polymorphic ctxt) taking))
   853         |> Seq.maps (fn rule' =>
   854           CASES (Rule_Cases.make_common (thy,
   855               Thm.prop_of (Rule_Cases.internalize_params rule')) cases)
   856             (Method.insert_tac more_facts i THEN Tactic.rtac rule' i) st)))
   857   end;
   858 
   859 end;
   860 
   861 
   862 
   863 (** concrete syntax **)
   864 
   865 val arbitraryN = "arbitrary";
   866 val takingN = "taking";
   867 val ruleN = "rule";
   868 
   869 local
   870 
   871 fun single_rule [rule] = rule
   872   | single_rule _ = error "Single rule expected";
   873 
   874 fun named_rule k arg get =
   875   Scan.lift (Args.$$$ k -- Args.colon) |-- Scan.repeat arg :|--
   876     (fn names => Scan.peek (fn context => Scan.succeed (names |> map (fn name =>
   877       (case get (Context.proof_of context) name of SOME x => x
   878       | NONE => error ("No rule for " ^ k ^ " " ^ quote name))))));
   879 
   880 fun rule get_type get_pred =
   881   named_rule typeN (Args.type_name false) get_type ||
   882   named_rule predN (Args.const false) get_pred ||
   883   named_rule setN (Args.const false) get_pred ||
   884   Scan.lift (Args.$$$ ruleN -- Args.colon) |-- Attrib.thms;
   885 
   886 val cases_rule = rule lookup_casesT lookup_casesP >> single_rule;
   887 val induct_rule = rule lookup_inductT lookup_inductP;
   888 val coinduct_rule = rule lookup_coinductT lookup_coinductP >> single_rule;
   889 
   890 val inst = Scan.lift (Args.$$$ "_") >> K NONE || Args.term >> SOME;
   891 
   892 val inst' = Scan.lift (Args.$$$ "_") >> K NONE ||
   893   Args.term >> (SOME o rpair false) ||
   894   Scan.lift (Args.$$$ "(") |-- (Args.term >> (SOME o rpair true)) --|
   895     Scan.lift (Args.$$$ ")");
   896 
   897 val def_inst =
   898   ((Scan.lift (Args.binding --| (Args.$$$ "\<equiv>" || Args.$$$ "==")) >> SOME)
   899       -- (Args.term >> rpair false)) >> SOME ||
   900     inst' >> Option.map (pair NONE);
   901 
   902 val free = Args.context -- Args.term >> (fn (_, Free v) => v | (ctxt, t) =>
   903   error ("Bad free variable: " ^ Syntax.string_of_term ctxt t));
   904 
   905 fun unless_more_args scan = Scan.unless (Scan.lift
   906   ((Args.$$$ arbitraryN || Args.$$$ takingN || Args.$$$ typeN ||
   907     Args.$$$ predN || Args.$$$ setN || Args.$$$ ruleN) -- Args.colon)) scan;
   908 
   909 val arbitrary = Scan.optional (Scan.lift (Args.$$$ arbitraryN -- Args.colon) |--
   910   Parse.and_list1' (Scan.repeat (unless_more_args free))) [];
   911 
   912 val taking = Scan.optional (Scan.lift (Args.$$$ takingN -- Args.colon) |--
   913   Scan.repeat1 (unless_more_args inst)) [];
   914 
   915 in
   916 
   917 val cases_setup =
   918   Method.setup @{binding cases}
   919     (Args.mode no_simpN --
   920       (Parse.and_list' (Scan.repeat (unless_more_args inst)) -- Scan.option cases_rule) >>
   921       (fn (no_simp, (insts, opt_rule)) => fn ctxt =>
   922         METHOD_CASES (fn facts => Seq.DETERM (HEADGOAL
   923           (cases_tac ctxt (not no_simp) insts opt_rule facts)))))
   924     "case analysis on types or predicates/sets";
   925 
   926 fun gen_induct_setup binding itac =
   927   Method.setup binding
   928     (Args.mode no_simpN -- (Parse.and_list' (Scan.repeat (unless_more_args def_inst)) --
   929       (arbitrary -- taking -- Scan.option induct_rule)) >>
   930       (fn (no_simp, (insts, ((arbitrary, taking), opt_rule))) => fn ctxt =>
   931         RAW_METHOD_CASES (fn facts =>
   932           Seq.DETERM
   933             (HEADGOAL (itac ctxt (not no_simp) insts arbitrary taking opt_rule facts)))))
   934     "induction on types or predicates/sets";
   935 
   936 val induct_setup = gen_induct_setup @{binding induct} induct_tac;
   937 
   938 val coinduct_setup =
   939   Method.setup @{binding coinduct}
   940     (Scan.repeat (unless_more_args inst) -- taking -- Scan.option coinduct_rule >>
   941       (fn ((insts, taking), opt_rule) => fn ctxt =>
   942         RAW_METHOD_CASES (fn facts =>
   943           Seq.DETERM (HEADGOAL (coinduct_tac ctxt insts taking opt_rule facts)))))
   944     "coinduction on types or predicates/sets";
   945 
   946 end;
   947 
   948 
   949 
   950 (** theory setup **)
   951 
   952 val setup = attrib_setup #> cases_setup  #> induct_setup #> coinduct_setup;
   953 
   954 end;