src/Pure/Isar/proof_context.ML
author haftmann
Thu May 24 08:37:37 2007 +0200 (2007-05-24)
changeset 23086 12320f6e2523
parent 22874 58fcd4f9068a
child 23204 c75e5ace1c53
permissions -rw-r--r--
tuned Pure/General/name_space.ML
     1 (*  Title:      Pure/Isar/proof_context.ML
     2     ID:         $Id$
     3     Author:     Markus Wenzel, TU Muenchen
     4 
     5 The key concept of Isar proof contexts: elevates primitive local
     6 reasoning Gamma |- phi to a structured concept, with generic context
     7 elements.  See also structure Variable and Assumption.
     8 *)
     9 
    10 signature PROOF_CONTEXT =
    11 sig
    12   val theory_of: Proof.context -> theory
    13   val init: theory -> Proof.context
    14   val is_stmt: Proof.context -> bool
    15   val set_stmt: bool -> Proof.context -> Proof.context
    16   val restore_stmt: Proof.context -> Proof.context -> Proof.context
    17   val naming_of: Proof.context -> NameSpace.naming
    18   val full_name: Proof.context -> bstring -> string
    19   val consts_of: Proof.context -> Consts.T
    20   val const_syntax_name: Proof.context -> string -> string
    21   val set_syntax_mode: Syntax.mode -> Proof.context -> Proof.context
    22   val restore_syntax_mode: Proof.context -> Proof.context -> Proof.context
    23   val theorems_of: Proof.context -> thm list NameSpace.table
    24   val fact_index_of: Proof.context -> FactIndex.T
    25   val transfer: theory -> Proof.context -> Proof.context
    26   val theory: (theory -> theory) -> Proof.context -> Proof.context
    27   val theory_result: (theory -> 'a * theory) -> Proof.context -> 'a * Proof.context
    28   val pretty_term: Proof.context -> term -> Pretty.T
    29   val pretty_term_abbrev: Proof.context -> term -> Pretty.T
    30   val pretty_typ: Proof.context -> typ -> Pretty.T
    31   val pretty_sort: Proof.context -> sort -> Pretty.T
    32   val pretty_classrel: Proof.context -> class list -> Pretty.T
    33   val pretty_arity: Proof.context -> arity -> Pretty.T
    34   val pp: Proof.context -> Pretty.pp
    35   val pretty_thm_legacy: thm -> Pretty.T
    36   val pretty_thm: Proof.context -> thm -> Pretty.T
    37   val pretty_thms: Proof.context -> thm list -> Pretty.T
    38   val pretty_fact: Proof.context -> string * thm list -> Pretty.T
    39   val pretty_proof: Proof.context -> Proofterm.proof -> Pretty.T
    40   val pretty_proof_of: Proof.context -> bool -> thm -> Pretty.T
    41   val string_of_typ: Proof.context -> typ -> string
    42   val string_of_term: Proof.context -> term -> string
    43   val string_of_thm: Proof.context -> thm -> string
    44   val read_typ: Proof.context -> string -> typ
    45   val read_typ_syntax: Proof.context -> string -> typ
    46   val read_typ_abbrev: Proof.context -> string -> typ
    47   val cert_typ: Proof.context -> typ -> typ
    48   val cert_typ_syntax: Proof.context -> typ -> typ
    49   val cert_typ_abbrev: Proof.context -> typ -> typ
    50   val get_skolem: Proof.context -> string -> string
    51   val revert_skolem: Proof.context -> string -> string
    52   val revert_skolems: Proof.context -> term -> term
    53   val decode_term: Proof.context -> term -> term
    54   val read_termTs_schematic: Proof.context -> (string -> bool) -> (indexname -> typ option)
    55     -> (indexname -> sort option) -> string list -> (string * typ) list
    56     -> term list * (indexname * typ) list
    57   val read_prop_legacy: Proof.context -> string -> term
    58   val read_term: Proof.context -> string -> term
    59   val read_prop: Proof.context -> string -> term
    60   val read_prop_schematic: Proof.context -> string -> term
    61   val read_termTs: Proof.context -> (string * typ) list -> term list
    62   val read_terms: Proof.context -> string list -> term list
    63   val read_term_pats: typ -> Proof.context -> string list -> term list
    64   val read_prop_pats: Proof.context -> string list -> term list
    65   val read_term_abbrev: Proof.context -> string -> term
    66   val cert_term: Proof.context -> term -> term
    67   val cert_terms: Proof.context -> term list -> term list
    68   val cert_prop: Proof.context -> term -> term
    69   val cert_term_pats: typ -> Proof.context -> term list -> term list
    70   val cert_prop_pats: Proof.context -> term list -> term list
    71   val infer_types: Proof.context -> term list -> term list
    72   val infer_types_pats: Proof.context -> term list -> term list
    73   val infer_type: Proof.context -> string -> typ
    74   val inferred_param: string -> Proof.context -> (string * typ) * Proof.context
    75   val inferred_fixes: Proof.context -> (string * typ) list * Proof.context
    76   val read_tyname: Proof.context -> string -> typ
    77   val read_const: Proof.context -> string -> term
    78   val goal_export: Proof.context -> Proof.context -> thm list -> thm list
    79   val export: Proof.context -> Proof.context -> thm list -> thm list
    80   val export_morphism: Proof.context -> Proof.context -> morphism
    81   val add_binds: (indexname * string option) list -> Proof.context -> Proof.context
    82   val add_binds_i: (indexname * term option) list -> Proof.context -> Proof.context
    83   val auto_bind_goal: term list -> Proof.context -> Proof.context
    84   val auto_bind_facts: term list -> Proof.context -> Proof.context
    85   val match_bind: bool -> (string list * string) list -> Proof.context -> term list * Proof.context
    86   val match_bind_i: bool -> (term list * term) list -> Proof.context -> term list * Proof.context
    87   val read_propp: Proof.context * (string * string list) list list
    88     -> Proof.context * (term * term list) list list
    89   val cert_propp: Proof.context * (term * term list) list list
    90     -> Proof.context * (term * term list) list list
    91   val read_propp_schematic: Proof.context * (string * string list) list list
    92     -> Proof.context * (term * term list) list list
    93   val cert_propp_schematic: Proof.context * (term * term list) list list
    94     -> Proof.context * (term * term list) list list
    95   val bind_propp: Proof.context * (string * string list) list list
    96     -> Proof.context * (term list list * (Proof.context -> Proof.context))
    97   val bind_propp_i: Proof.context * (term * term list) list list
    98     -> Proof.context * (term list list * (Proof.context -> Proof.context))
    99   val bind_propp_schematic: Proof.context * (string * string list) list list
   100     -> Proof.context * (term list list * (Proof.context -> Proof.context))
   101   val bind_propp_schematic_i: Proof.context * (term * term list) list list
   102     -> Proof.context * (term list list * (Proof.context -> Proof.context))
   103   val fact_tac: thm list -> int -> tactic
   104   val some_fact_tac: Proof.context -> int -> tactic
   105   val get_thm: Proof.context -> thmref -> thm
   106   val get_thm_closure: Proof.context -> thmref -> thm
   107   val get_thms: Proof.context -> thmref -> thm list
   108   val get_thms_closure: Proof.context -> thmref -> thm list
   109   val valid_thms: Proof.context -> string * thm list -> bool
   110   val lthms_containing: Proof.context -> FactIndex.spec -> (string * thm list) list
   111   val add_path: string -> Proof.context -> Proof.context
   112   val no_base_names: Proof.context -> Proof.context
   113   val qualified_names: Proof.context -> Proof.context
   114   val sticky_prefix: string -> Proof.context -> Proof.context
   115   val restore_naming: Proof.context -> Proof.context -> Proof.context
   116   val reset_naming: Proof.context -> Proof.context
   117   val hide_thms: bool -> string list -> Proof.context -> Proof.context
   118   val put_thms: string * thm list option -> Proof.context -> Proof.context
   119   val note_thmss: string ->
   120     ((bstring * attribute list) * (thmref * attribute list) list) list ->
   121       Proof.context -> (bstring * thm list) list * Proof.context
   122   val note_thmss_i: string ->
   123     ((bstring * attribute list) * (thm list * attribute list) list) list ->
   124       Proof.context -> (bstring * thm list) list * Proof.context
   125   val read_vars: (string * string option * mixfix) list -> Proof.context ->
   126     (string * typ option * mixfix) list * Proof.context
   127   val cert_vars: (string * typ option * mixfix) list -> Proof.context ->
   128     (string * typ option * mixfix) list * Proof.context
   129   val read_vars_legacy: (string * string option * mixfix) list -> Proof.context ->
   130     (string * typ option * mixfix) list * Proof.context
   131   val cert_vars_legacy: (string * typ option * mixfix) list -> Proof.context ->
   132     (string * typ option * mixfix) list * Proof.context
   133   val add_fixes: (string * string option * mixfix) list ->
   134     Proof.context -> string list * Proof.context
   135   val add_fixes_i: (string * typ option * mixfix) list ->
   136     Proof.context -> string list * Proof.context
   137   val add_fixes_legacy: (string * typ option * mixfix) list ->
   138     Proof.context -> string list * Proof.context
   139   val auto_fixes: Proof.context * (term list list * 'a) -> Proof.context * (term list list * 'a)
   140   val bind_fixes: string list -> Proof.context -> (term -> term) * Proof.context
   141   val add_assms: Assumption.export ->
   142     ((string * attribute list) * (string * string list) list) list ->
   143     Proof.context -> (bstring * thm list) list * Proof.context
   144   val add_assms_i: Assumption.export ->
   145     ((string * attribute list) * (term * term list) list) list ->
   146     Proof.context -> (bstring * thm list) list * Proof.context
   147   val add_cases: bool -> (string * RuleCases.T option) list -> Proof.context -> Proof.context
   148   val apply_case: RuleCases.T -> Proof.context -> (string * term list) list * Proof.context
   149   val get_case: Proof.context -> string -> string option list -> RuleCases.T
   150   val add_notation: Syntax.mode -> (term * mixfix) list ->
   151     Proof.context -> Proof.context
   152   val target_notation: Syntax.mode -> (term * mixfix) list -> morphism ->
   153     Context.generic -> Context.generic
   154   val set_expand_abbrevs: bool -> Proof.context -> Proof.context
   155   val add_abbrev: string -> bstring * term -> Proof.context -> (term * term) * Proof.context
   156   val target_abbrev: Syntax.mode -> (string * mixfix) * term -> morphism ->
   157     Context.generic -> Context.generic
   158   val local_abbrev: string * term -> Proof.context -> (term * term) * Proof.context
   159   val verbose: bool ref
   160   val setmp_verbose: ('a -> 'b) -> 'a -> 'b
   161   val print_syntax: Proof.context -> unit
   162   val print_abbrevs: Proof.context -> unit
   163   val print_binds: Proof.context -> unit
   164   val print_lthms: Proof.context -> unit
   165   val print_cases: Proof.context -> unit
   166   val debug: bool ref
   167   val prems_limit: int ref
   168   val pretty_ctxt: Proof.context -> Pretty.T list
   169   val pretty_context: Proof.context -> Pretty.T list
   170 end;
   171 
   172 structure ProofContext: PROOF_CONTEXT =
   173 struct
   174 
   175 val theory_of = Context.theory_of_proof;
   176 val tsig_of = Sign.tsig_of o theory_of;
   177 
   178 val init = Context.init_proof;
   179 
   180 
   181 
   182 (** Isar proof context information **)
   183 
   184 datatype ctxt =
   185   Ctxt of
   186    {is_stmt: bool,                                (*inner statement mode*)
   187     naming: NameSpace.naming,                     (*local naming conventions*)
   188     syntax: LocalSyntax.T,                        (*local syntax*)
   189     consts: Consts.T * Consts.T,                  (*global/local consts*)
   190     thms: thm list NameSpace.table * FactIndex.T, (*local thms*)
   191     cases: (string * (RuleCases.T * bool)) list}; (*local contexts*)
   192 
   193 fun make_ctxt (is_stmt, naming, syntax, consts, thms, cases) =
   194   Ctxt {is_stmt = is_stmt, naming = naming, syntax = syntax,
   195     consts = consts, thms = thms, cases = cases};
   196 
   197 val local_naming = NameSpace.default_naming |> NameSpace.add_path "local";
   198 
   199 structure ContextData = ProofDataFun
   200 (
   201   type T = ctxt;
   202   fun init thy =
   203     make_ctxt (false, local_naming, LocalSyntax.init thy,
   204       (Sign.consts_of thy, Sign.consts_of thy),
   205       (NameSpace.empty_table, FactIndex.empty), []);
   206 );
   207 
   208 fun rep_context ctxt = ContextData.get ctxt |> (fn Ctxt args => args);
   209 
   210 fun map_context f =
   211   ContextData.map (fn Ctxt {is_stmt, naming, syntax, consts, thms, cases} =>
   212     make_ctxt (f (is_stmt, naming, syntax, consts, thms, cases)));
   213 
   214 fun set_stmt b =
   215   map_context (fn (_, naming, syntax, consts, thms, cases) =>
   216     (b, naming, syntax, consts, thms, cases));
   217 
   218 fun map_naming f =
   219   map_context (fn (is_stmt, naming, syntax, consts, thms, cases) =>
   220     (is_stmt, f naming, syntax, consts, thms, cases));
   221 
   222 fun map_syntax f =
   223   map_context (fn (is_stmt, naming, syntax, consts, thms, cases) =>
   224     (is_stmt, naming, f syntax, consts, thms, cases));
   225 
   226 fun map_consts f =
   227   map_context (fn (is_stmt, naming, syntax, consts, thms, cases) =>
   228     (is_stmt, naming, syntax, f consts, thms, cases));
   229 
   230 fun map_thms f =
   231   map_context (fn (is_stmt, naming, syntax, consts, thms, cases) =>
   232     (is_stmt, naming, syntax, consts, f thms, cases));
   233 
   234 fun map_cases f =
   235   map_context (fn (is_stmt, naming, syntax, consts, thms, cases) =>
   236     (is_stmt, naming, syntax, consts, thms, f cases));
   237 
   238 val is_stmt = #is_stmt o rep_context;
   239 fun restore_stmt ctxt = set_stmt (is_stmt ctxt);
   240 
   241 val naming_of = #naming o rep_context;
   242 val full_name = NameSpace.full o naming_of;
   243 
   244 val syntax_of = #syntax o rep_context;
   245 val syn_of = LocalSyntax.syn_of o syntax_of;
   246 val set_syntax_mode = map_syntax o LocalSyntax.set_mode;
   247 val restore_syntax_mode = map_syntax o LocalSyntax.restore_mode o syntax_of;
   248 
   249 val consts_of = #2 o #consts o rep_context;
   250 val const_syntax_name = Consts.syntax_name o consts_of;
   251 
   252 val thms_of = #thms o rep_context;
   253 val theorems_of = #1 o thms_of;
   254 val fact_index_of = #2 o thms_of;
   255 
   256 val cases_of = #cases o rep_context;
   257 
   258 
   259 (* theory transfer *)
   260 
   261 fun transfer_syntax thy =
   262   map_syntax (LocalSyntax.rebuild thy) #>
   263   map_consts (fn consts as (global_consts, local_consts) =>
   264     let val thy_consts = Sign.consts_of thy in
   265       if Consts.eq_consts (thy_consts, global_consts) then consts
   266       else (thy_consts, Consts.merge (thy_consts, local_consts))
   267     end);
   268 
   269 fun transfer thy = Context.transfer_proof thy #> transfer_syntax thy;
   270 
   271 fun theory f ctxt = transfer (f (theory_of ctxt)) ctxt;
   272 
   273 fun theory_result f ctxt =
   274   let val (res, thy') = f (theory_of ctxt)
   275   in (res, ctxt |> transfer thy') end;
   276 
   277 
   278 
   279 (** pretty printing **)
   280 
   281 local
   282 
   283 fun rewrite_term warn thy rews t =
   284   if can Term.type_of t then Pattern.rewrite_term thy rews [] t
   285   else (if warn then warning "Printing malformed term -- cannot expand abbreviations" else (); t);
   286 
   287 fun pretty_term' abbrevs ctxt t =
   288   let
   289     val thy = theory_of ctxt;
   290     val syntax = syntax_of ctxt;
   291     val consts = consts_of ctxt;
   292     val do_abbrevs = abbrevs andalso not (print_mode_active "no_abbrevs");
   293     val t' = t
   294       |> do_abbrevs ? rewrite_term true thy (Consts.abbrevs_of consts (! print_mode @ [""]))
   295       |> do_abbrevs ? rewrite_term false thy (Consts.abbrevs_of consts [Syntax.internalM])
   296       |> Sign.extern_term (Consts.extern_early consts) thy
   297       |> LocalSyntax.extern_term syntax;
   298   in Sign.pretty_term' ctxt (LocalSyntax.syn_of syntax) (Consts.extern consts) t' end;
   299 
   300 in
   301 
   302 val pretty_term = pretty_term' true;
   303 val pretty_term_abbrev = pretty_term' false;
   304 
   305 end;
   306 
   307 fun pretty_typ ctxt T = Sign.pretty_typ (theory_of ctxt) T;
   308 fun pretty_sort ctxt S = Sign.pretty_sort (theory_of ctxt) S;
   309 fun pretty_classrel ctxt cs = Sign.pretty_classrel (theory_of ctxt) cs;
   310 fun pretty_arity ctxt ar = Sign.pretty_arity (theory_of ctxt) ar;
   311 
   312 fun pp ctxt = Pretty.pp (pretty_term ctxt, pretty_typ ctxt, pretty_sort ctxt,
   313   pretty_classrel ctxt, pretty_arity ctxt);
   314 
   315 fun pretty_thm_legacy th =
   316   let val thy = Thm.theory_of_thm th
   317   in Display.pretty_thm_aux (pp (init thy)) true false [] th end;
   318 
   319 fun pretty_thm ctxt th =
   320   let val asms = map Thm.term_of (Assumption.assms_of ctxt)
   321   in Display.pretty_thm_aux (pp ctxt) false true asms th end;
   322 
   323 fun pretty_thms ctxt [th] = pretty_thm ctxt th
   324   | pretty_thms ctxt ths = Pretty.blk (0, Pretty.fbreaks (map (pretty_thm ctxt) ths));
   325 
   326 fun pretty_fact ctxt ("", ths) = pretty_thms ctxt ths
   327   | pretty_fact ctxt (a, [th]) =
   328       Pretty.block [Pretty.str (a ^ ":"), Pretty.brk 1, pretty_thm ctxt th]
   329   | pretty_fact ctxt (a, ths) =
   330       Pretty.block (Pretty.fbreaks (Pretty.str (a ^ ":") :: map (pretty_thm ctxt) ths));
   331 
   332 fun pretty_proof ctxt prf =
   333   pretty_term_abbrev (ctxt |> transfer_syntax (ProofSyntax.proof_syntax prf (theory_of ctxt)))
   334     (ProofSyntax.term_of_proof prf);
   335 
   336 fun pretty_proof_of ctxt full th =
   337   pretty_proof ctxt (ProofSyntax.proof_of full th);
   338 
   339 val string_of_typ = Pretty.string_of oo pretty_typ;
   340 val string_of_term = Pretty.string_of oo pretty_term;
   341 val string_of_thm = Pretty.string_of oo pretty_thm;
   342 
   343 
   344 
   345 (** prepare types **)
   346 
   347 local
   348 
   349 fun read_typ_aux read ctxt s =
   350   read (syn_of ctxt) ctxt (Variable.def_sort ctxt) s;
   351 
   352 fun cert_typ_aux cert ctxt raw_T =
   353   cert (theory_of ctxt) raw_T handle TYPE (msg, _, _) => error msg;
   354 
   355 in
   356 
   357 val read_typ        = read_typ_aux Sign.read_typ';
   358 val read_typ_syntax = read_typ_aux Sign.read_typ_syntax';
   359 val read_typ_abbrev = read_typ_aux Sign.read_typ_abbrev';
   360 val cert_typ        = cert_typ_aux Sign.certify_typ;
   361 val cert_typ_syntax = cert_typ_aux Sign.certify_typ_syntax;
   362 val cert_typ_abbrev = cert_typ_aux Sign.certify_typ_abbrev;
   363 
   364 end;
   365 
   366 
   367 (* internalize Skolem constants *)
   368 
   369 val lookup_skolem = AList.lookup (op =) o Variable.fixes_of;
   370 fun get_skolem ctxt x = the_default x (lookup_skolem ctxt x);
   371 
   372 fun no_skolem internal x =
   373   if can Name.dest_skolem x then
   374     error ("Illegal reference to internal Skolem constant: " ^ quote x)
   375   else if not internal andalso can Name.dest_internal x then
   376     error ("Illegal reference to internal variable: " ^ quote x)
   377   else x;
   378 
   379 
   380 (* revert Skolem constants -- approximation only! *)
   381 
   382 fun revert_skolem ctxt =
   383   let
   384     val rev_fixes = map Library.swap (Variable.fixes_of ctxt);
   385     val revert = AList.lookup (op =) rev_fixes;
   386   in
   387     fn x =>
   388       (case revert x of
   389         SOME x' => x'
   390       | NONE => perhaps (try Name.dest_skolem) x)
   391    end;
   392 
   393 fun revert_skolems ctxt =
   394   let
   395     val revert = revert_skolem ctxt;
   396     fun reverts (Free (x, T)) = Free (revert x, T)
   397       | reverts (t $ u) = reverts t $ reverts u
   398       | reverts (Abs (x, T, t)) = Abs (x, T, reverts t)
   399       | reverts a = a;
   400   in reverts end
   401 
   402 
   403 
   404 (** prepare terms and propositions **)
   405 
   406 (*
   407   (1) read / certify wrt. theory of context
   408   (2) intern Skolem constants
   409   (3) expand term bindings
   410 *)
   411 
   412 
   413 (* read wrt. theory *)     (*exception ERROR*)
   414 
   415 fun read_def_termTs freeze pp syn ctxt (types, sorts, used) fixed sTs =
   416   Sign.read_def_terms' pp (Sign.is_logtype (theory_of ctxt)) syn (consts_of ctxt) fixed
   417     ctxt (types, sorts) used freeze sTs;
   418 
   419 fun read_def_termT freeze pp syn ctxt defaults fixed sT =
   420   apfst hd (read_def_termTs freeze pp syn ctxt defaults fixed [sT]);
   421 
   422 fun read_term_thy freeze pp syn thy defaults fixed s =
   423   #1 (read_def_termT freeze pp syn thy defaults fixed (s, dummyT));
   424 
   425 fun read_prop_thy freeze pp syn thy defaults fixed s =
   426   #1 (read_def_termT freeze pp syn thy defaults fixed (s, propT));
   427 
   428 fun read_terms_thy freeze pp syn thy defaults fixed =
   429   #1 o read_def_termTs freeze pp syn thy defaults fixed;
   430 
   431 fun read_props_thy freeze pp syn thy defaults fixed =
   432   #1 o read_def_termTs freeze pp syn thy defaults fixed o map (rpair propT);
   433 
   434 
   435 (* local abbreviations *)
   436 
   437 fun certify_consts ctxt =
   438   Consts.certify (pp ctxt) (tsig_of ctxt) (consts_of ctxt);
   439 
   440 fun reject_schematic (Var (xi, _)) =
   441       error ("Unbound schematic variable: " ^ Term.string_of_vname xi)
   442   | reject_schematic (Abs (_, _, t)) = reject_schematic t
   443   | reject_schematic (t $ u) = (reject_schematic t; reject_schematic u)
   444   | reject_schematic _ = ();
   445 
   446 fun expand_binds ctxt schematic =
   447   Variable.expand_binds ctxt #> (if schematic then I else tap reject_schematic);
   448 
   449 
   450 (* schematic type variables *)
   451 
   452 val reject_tvars = (Term.map_types o Term.map_atyps)
   453   (fn TVar (xi, _) => error ("Illegal schematic type variable: " ^ Term.string_of_vname xi)
   454     | T => T);
   455 
   456 
   457 (* dummy patterns *)
   458 
   459 val prepare_dummies =
   460   let val next = ref 1 in
   461     fn t =>
   462       let val (i, u) = Term.replace_dummy_patterns (! next, t)
   463       in next := i; u end
   464   end;
   465 
   466 fun reject_dummies t = Term.no_dummy_patterns t
   467   handle TERM _ => error "Illegal dummy pattern(s) in term";
   468 
   469 
   470 (* decoding raw terms (syntax trees) *)
   471 
   472 fun legacy_intern_skolem ctxt internal def_type x =    (* FIXME cleanup this mess *)
   473   let
   474     val sko = lookup_skolem ctxt x;
   475     val is_const = can (Consts.read_const (consts_of ctxt)) x;
   476     val is_free = is_some sko orelse not is_const;
   477     val is_internal = internal x;
   478     val is_declared = is_some (def_type (x, ~1));
   479     val res =
   480       if is_free andalso not is_internal then (no_skolem false x; sko)
   481       else ((no_skolem false x; ()) handle ERROR msg => legacy_feature msg;
   482         if is_internal andalso is_declared then SOME x else NONE);
   483   in if is_some res then res else if is_declared then SOME x else NONE end;
   484 
   485 fun decode_term ctxt =
   486   let
   487     val thy = theory_of ctxt;
   488     val get_sort = Sign.get_sort thy (Variable.def_sort ctxt);
   489     val map_const = try (#1 o Term.dest_Const o Consts.read_const (consts_of ctxt));
   490     val map_free = legacy_intern_skolem ctxt (K false) (Variable.def_type ctxt false);
   491     val map_type = Sign.intern_tycons thy;
   492     val map_sort = Sign.intern_sort thy;
   493   in Syntax.decode_term get_sort map_const map_free map_type map_sort end;
   494 
   495 
   496 (* read terms *)
   497 
   498 local
   499 
   500 fun append_env e1 e2 x = (case e2 x of NONE => e1 x | some => some);
   501 
   502 fun gen_read' read app pattern schematic
   503     ctxt internal more_types more_sorts more_used s =
   504   let
   505     val types = append_env (Variable.def_type ctxt pattern) more_types;
   506     val sorts = append_env (Variable.def_sort ctxt) more_sorts;
   507     val used = fold Name.declare more_used (Variable.names_of ctxt);
   508   in
   509     (read (pp ctxt) (syn_of ctxt) ctxt (types, sorts, used)
   510         (legacy_intern_skolem ctxt internal types) s
   511       handle TERM (msg, _) => error msg)
   512     |> app (certify_consts ctxt)
   513     |> app (if pattern then I else expand_binds ctxt schematic)
   514     |> app (if pattern orelse schematic then I else reject_tvars)
   515     |> app (if pattern then prepare_dummies else reject_dummies)
   516   end;
   517 
   518 fun gen_read read app pattern schematic ctxt =
   519   gen_read' read app pattern schematic ctxt (K false) (K NONE) (K NONE) [];
   520 
   521 in
   522 
   523 val read_termTs_schematic = gen_read' (read_def_termTs false) (apfst o map) false true;
   524 
   525 fun read_term_pats T ctxt =
   526   #1 o gen_read (read_def_termTs false) (apfst o map) true false ctxt o map (rpair T);
   527 val read_prop_pats = read_term_pats propT;
   528 
   529 fun read_prop_legacy ctxt =
   530   gen_read' (read_prop_thy true) I false false ctxt (K true) (K NONE) (K NONE) [];
   531 
   532 val read_term            = gen_read (read_term_thy true) I false false;
   533 val read_prop            = gen_read (read_prop_thy true) I false false;
   534 val read_prop_schematic  = gen_read (read_prop_thy true) I false true;
   535 val read_termTs          = gen_read (read_terms_thy true) map false false;
   536 fun read_terms ctxt      = read_termTs ctxt o map (rpair dummyT);
   537 fun read_props schematic = gen_read (read_props_thy true) map false schematic;
   538 
   539 end;
   540 
   541 
   542 (* certify terms *)
   543 
   544 local
   545 
   546 fun gen_cert prop pattern schematic ctxt t = t
   547   |> certify_consts ctxt
   548   |> (if pattern then I else expand_binds ctxt schematic)
   549   |> (fn t' => #1 (Sign.certify' false prop (pp ctxt) (consts_of ctxt) (theory_of ctxt) t')
   550     handle TYPE (msg, _, _) => error msg
   551       | TERM (msg, _) => error msg);
   552 
   553 in
   554 
   555 val cert_term = gen_cert false false false;
   556 val cert_terms = map o cert_term;
   557 val cert_prop = gen_cert true false false;
   558 val cert_props = map oo gen_cert true false;
   559 
   560 fun cert_term_pats _ = map o gen_cert false true false;
   561 val cert_prop_pats = map o gen_cert true true false;
   562 
   563 end;
   564 
   565 
   566 (* type inference *)
   567 
   568 local
   569 
   570 fun gen_infer_types pattern ctxt ts =
   571   TypeInfer.infer_types (pp ctxt) (tsig_of ctxt) (try (Consts.the_constraint (consts_of ctxt)))
   572     (Variable.def_type ctxt pattern) (Variable.names_of ctxt) (not pattern) (map (rpair dummyT) ts)
   573   |> #1 |> map #1;
   574 
   575 in
   576 
   577 val infer_types = gen_infer_types false;
   578 val infer_types_pats = gen_infer_types true;
   579 
   580 end;
   581 
   582 
   583 (* inferred types of parameters *)
   584 
   585 fun infer_type ctxt x =
   586   Term.fastype_of (singleton (infer_types ctxt) (Free (x, dummyT)));
   587 
   588 fun inferred_param x ctxt =
   589   let val T = infer_type ctxt x
   590   in ((x, T), ctxt |> Variable.declare_term (Free (x, T))) end;
   591 
   592 fun inferred_fixes ctxt =
   593   fold_map inferred_param (rev (map #2 (Variable.fixes_of ctxt))) ctxt;
   594 
   595 
   596 (* type and constant names *)
   597 
   598 fun read_tyname ctxt c =
   599   if Syntax.is_tid c then
   600     TFree (c, the_default (Sign.defaultS (theory_of ctxt)) (Variable.def_sort ctxt (c, ~1)))
   601   else Sign.read_tyname (theory_of ctxt) c;
   602 
   603 fun read_const ctxt c =
   604   (case lookup_skolem ctxt c of
   605     SOME x => Free (x, infer_type ctxt x)
   606   | NONE => Consts.read_const (consts_of ctxt) c);
   607 
   608 
   609 
   610 (** export results **)
   611 
   612 fun common_export is_goal inner outer =
   613   map (Assumption.export is_goal inner outer) #>
   614   Variable.export inner outer;
   615 
   616 val goal_export = common_export true;
   617 val export = common_export false;
   618 
   619 fun export_morphism inner outer =
   620   Assumption.export_morphism inner outer $>
   621   Variable.export_morphism inner outer;
   622 
   623 
   624 
   625 (** bindings **)
   626 
   627 (* simult_matches *)
   628 
   629 fun simult_matches ctxt (t, pats) =
   630   (case Seq.pull (Unify.matchers (theory_of ctxt) (map (rpair t) pats)) of
   631     NONE => error "Pattern match failed!"
   632   | SOME (env, _) => map (apsnd snd) (Envir.alist_of env));
   633 
   634 
   635 (* add_binds(_i) *)
   636 
   637 local
   638 
   639 fun gen_bind prep (xi as (x, _), raw_t) ctxt =
   640   ctxt |> Variable.add_binds [(xi, Option.map (prep ctxt) raw_t)];
   641 
   642 in
   643 
   644 fun drop_schematic (b as (xi, SOME t)) = if Term.exists_subterm is_Var t then (xi, NONE) else b
   645   | drop_schematic b = b;
   646 
   647 val add_binds = fold (gen_bind read_term);
   648 val add_binds_i = fold (gen_bind cert_term);
   649 
   650 fun auto_bind f ts ctxt = ctxt |> add_binds_i (map drop_schematic (f (theory_of ctxt) ts));
   651 val auto_bind_goal = auto_bind AutoBind.goal;
   652 val auto_bind_facts = auto_bind AutoBind.facts;
   653 
   654 end;
   655 
   656 
   657 (* match_bind(_i) *)
   658 
   659 local
   660 
   661 fun prep_bind prep_pats (raw_pats, t) ctxt =
   662   let
   663     val ctxt' = Variable.declare_term t ctxt;
   664     val pats = prep_pats (Term.fastype_of t) ctxt' raw_pats;
   665     val binds = simult_matches ctxt' (t, pats);
   666   in (binds, ctxt') end;
   667 
   668 fun gen_binds prep_terms prep_pats gen raw_binds ctxt =
   669   let
   670     val ts = prep_terms ctxt (map snd raw_binds);
   671     val (binds, ctxt') =
   672       apfst flat (fold_map (prep_bind prep_pats) (map fst raw_binds ~~ ts) ctxt);
   673     val binds' =
   674       if gen then map #1 binds ~~ Variable.exportT_terms ctxt' ctxt (map #2 binds)
   675       else binds;
   676     val binds'' = map (apsnd SOME) binds';
   677     val ctxt'' =
   678       tap (Variable.warn_extra_tfrees ctxt)
   679        (if gen then
   680           ctxt (*sic!*) |> fold Variable.declare_term (map #2 binds') |> add_binds_i binds''
   681         else ctxt' |> add_binds_i binds'');
   682   in (ts, ctxt'') end;
   683 
   684 in
   685 
   686 val match_bind = gen_binds read_terms read_term_pats;
   687 val match_bind_i = gen_binds cert_terms cert_term_pats;
   688 
   689 end;
   690 
   691 
   692 (* propositions with patterns *)
   693 
   694 local
   695 
   696 fun prep_propp schematic prep_props prep_pats (context, args) =
   697   let
   698     fun prep (_, raw_pats) (ctxt, prop :: props) =
   699           let val ctxt' = Variable.declare_term prop ctxt
   700           in ((prop, prep_pats ctxt' raw_pats), (ctxt', props)) end
   701       | prep _ _ = sys_error "prep_propp";
   702     val (propp, (context', _)) = (fold_map o fold_map) prep args
   703       (context, prep_props schematic context (maps (map fst) args));
   704   in (context', propp) end;
   705 
   706 fun gen_bind_propp prepp (ctxt, raw_args) =
   707   let
   708     val (ctxt', args) = prepp (ctxt, raw_args);
   709     val binds = flat (flat (map (map (simult_matches ctxt')) args));
   710     val propss = map (map #1) args;
   711 
   712     (*generalize result: context evaluated now, binds added later*)
   713     val gen = Variable.exportT_terms ctxt' ctxt;
   714     fun gen_binds c = c |> add_binds_i (map #1 binds ~~ map SOME (gen (map #2 binds)));
   715   in (ctxt' |> add_binds_i (map (apsnd SOME) binds), (propss, gen_binds)) end;
   716 
   717 in
   718 
   719 val read_propp = prep_propp false read_props read_prop_pats;
   720 val cert_propp = prep_propp false cert_props cert_prop_pats;
   721 val read_propp_schematic = prep_propp true read_props read_prop_pats;
   722 val cert_propp_schematic = prep_propp true cert_props cert_prop_pats;
   723 
   724 val bind_propp = gen_bind_propp read_propp;
   725 val bind_propp_i = gen_bind_propp cert_propp;
   726 val bind_propp_schematic = gen_bind_propp read_propp_schematic;
   727 val bind_propp_schematic_i = gen_bind_propp cert_propp_schematic;
   728 
   729 end;
   730 
   731 
   732 
   733 (** theorems **)
   734 
   735 (* fact_tac *)
   736 
   737 fun comp_incr_tac [] _ st = no_tac st
   738   | comp_incr_tac (th :: ths) i st =
   739       (Goal.compose_hhf_tac (Drule.incr_indexes st th) i APPEND comp_incr_tac ths i) st;
   740 
   741 fun fact_tac facts = Goal.norm_hhf_tac THEN' comp_incr_tac facts;
   742 
   743 fun some_fact_tac ctxt = SUBGOAL (fn (goal, i) =>
   744   let
   745     val index = fact_index_of ctxt;
   746     val facts = FactIndex.could_unify index (Term.strip_all_body goal);
   747   in fact_tac facts i end);
   748 
   749 
   750 (* get_thm(s) *)
   751 
   752 fun retrieve_thms _ pick ctxt (Fact s) =
   753       let
   754         val th = Goal.prove ctxt [] [] (read_prop ctxt s) (K (ALLGOALS (some_fact_tac ctxt)))
   755           handle ERROR msg => cat_error msg "Failed to retrieve literal fact.";
   756       in pick "" [th] end
   757   | retrieve_thms from_thy pick ctxt xthmref =
   758       let
   759         val thy = theory_of ctxt;
   760         val (space, tab) = #1 (thms_of ctxt);
   761         val thmref = PureThy.map_name_of_thmref (NameSpace.intern space) xthmref;
   762         val name = PureThy.name_of_thmref thmref;
   763       in
   764         (case Symtab.lookup tab name of
   765           SOME ths => map (Thm.transfer thy) (PureThy.select_thm thmref ths)
   766         | NONE => from_thy thy xthmref) |> pick name
   767       end;
   768 
   769 val get_thm = retrieve_thms PureThy.get_thms PureThy.single_thm;
   770 val get_thm_closure = retrieve_thms PureThy.get_thms_closure PureThy.single_thm;
   771 val get_thms = retrieve_thms PureThy.get_thms (K I);
   772 val get_thms_closure = retrieve_thms PureThy.get_thms_closure (K I);
   773 
   774 
   775 (* valid_thms *)
   776 
   777 fun valid_thms ctxt (name, ths) =
   778   (case try (fn () => get_thms ctxt (Name name)) () of
   779     NONE => false
   780   | SOME ths' => Thm.eq_thms (ths, ths'));
   781 
   782 
   783 (* lthms_containing *)
   784 
   785 fun lthms_containing ctxt spec =
   786   FactIndex.find (fact_index_of ctxt) spec
   787   |> map (fn (name, ths) =>
   788     if valid_thms ctxt (name, ths) then (name, ths)
   789     else (NameSpace.hidden (if name = "" then "unnamed" else name), ths));
   790 
   791 
   792 (* name space operations *)
   793 
   794 val add_path        = map_naming o NameSpace.add_path;
   795 val no_base_names   = map_naming NameSpace.no_base_names;
   796 val qualified_names = map_naming NameSpace.qualified_names;
   797 val sticky_prefix   = map_naming o NameSpace.sticky_prefix;
   798 val restore_naming  = map_naming o K o naming_of;
   799 val reset_naming    = map_naming (K local_naming);
   800 
   801 fun hide_thms fully names = map_thms (fn ((space, tab), index) =>
   802   ((fold (NameSpace.hide fully) names space, tab), index));
   803 
   804 
   805 (* put_thms *)
   806 
   807 fun update_thms _ ("", NONE) ctxt = ctxt
   808   | update_thms opts ("", SOME ths) ctxt = ctxt |> map_thms (fn (facts, index) =>
   809       let
   810         val index' = uncurry FactIndex.add_local opts ("", ths) index;
   811       in (facts, index') end)
   812   | update_thms _ (bname, NONE) ctxt = ctxt |> map_thms (fn ((space, tab), index) =>
   813       let
   814         val name = full_name ctxt bname;
   815         val tab' = Symtab.delete_safe name tab;
   816       in ((space, tab'), index) end)
   817   | update_thms opts (bname, SOME ths) ctxt = ctxt |> map_thms (fn ((space, tab), index) =>
   818       let
   819         val name = full_name ctxt bname;
   820         val space' = NameSpace.declare (naming_of ctxt) name space;
   821         val tab' = Symtab.update (name, ths) tab;
   822         val index' = uncurry FactIndex.add_local opts (name, ths) index;
   823       in ((space', tab'), index') end);
   824 
   825 fun put_thms thms ctxt =
   826   ctxt |> map_naming (K local_naming) |> update_thms (true, false) thms |> restore_naming ctxt;
   827 
   828 
   829 (* note_thmss *)
   830 
   831 local
   832 
   833 fun gen_note_thmss get k = fold_map (fn ((bname, more_attrs), raw_facts) => fn ctxt =>
   834   let
   835     val name = full_name ctxt bname;
   836     val facts = PureThy.name_thmss false name (map (apfst (get ctxt)) raw_facts);
   837     fun app (th, attrs) x =
   838       swap (foldl_map (Thm.proof_attributes (attrs @ more_attrs @ [PureThy.kind k])) (x, th));
   839     val (res, ctxt') = fold_map app facts ctxt;
   840     val thms = PureThy.name_thms false false name (flat res);
   841   in ((bname, thms), ctxt' |> update_thms (is_stmt ctxt, true) (bname, SOME thms)) end);
   842 
   843 in
   844 
   845 fun note_thmss k = gen_note_thmss get_thms k;
   846 fun note_thmss_i k = gen_note_thmss (K I) k;
   847 
   848 end;
   849 
   850 
   851 
   852 (** parameters **)
   853 
   854 (* variables *)
   855 
   856 fun declare_var (x, opt_T, mx) ctxt =
   857   let val T = (case opt_T of SOME T => T | NONE => Syntax.mixfixT mx)
   858   in ((x, T, mx), ctxt |> Variable.declare_constraints (Free (x, T))) end;
   859 
   860 local
   861 
   862 fun prep_vars prep_typ internal legacy =
   863   fold_map (fn (raw_x, raw_T, raw_mx) => fn ctxt =>
   864     let
   865       val (x, mx) = Syntax.const_mixfix raw_x raw_mx;
   866       val _ =
   867         if not legacy andalso not (Syntax.is_identifier (no_skolem internal x)) then
   868           error ("Illegal variable name: " ^ quote x)
   869         else ();
   870 
   871       fun cond_tvars T =
   872         if internal then T
   873         else Type.no_tvars T handle TYPE (msg, _, _) => error msg;
   874       val opt_T = Option.map (cond_tvars o prep_typ ctxt) raw_T;
   875       val var = (x, opt_T, mx);
   876     in (var, ctxt |> declare_var var |> #2) end);
   877 
   878 in
   879 
   880 val read_vars        = prep_vars read_typ false false;
   881 val cert_vars        = prep_vars cert_typ true false;
   882 val read_vars_legacy = prep_vars read_typ true true;
   883 val cert_vars_legacy = prep_vars cert_typ true true;
   884 
   885 end;
   886 
   887 
   888 (* authentic constants *)
   889 
   890 fun const_syntax ctxt (Free (x, T), mx) = SOME (true, (x, T, mx))
   891   | const_syntax ctxt (Const (c, _), mx) =
   892       Option.map (pair false) (try (Consts.syntax (consts_of ctxt)) (c, mx))
   893   | const_syntax _ _ = NONE;
   894 
   895 fun context_const_ast_tr ctxt [Syntax.Variable c] =
   896       let
   897         val consts = consts_of ctxt;
   898         val c' = Consts.intern consts c;
   899         val _ = Consts.the_constraint consts c' handle TYPE (msg, _, _) => error msg;
   900       in Syntax.Constant (Syntax.constN ^ c') end
   901   | context_const_ast_tr _ asts = raise Syntax.AST ("const_ast_tr", asts);
   902 
   903 val _ = Context.add_setup
   904  (Sign.add_syntax
   905    [("_context_const", "id => 'a", Delimfix "CONST _"),
   906     ("_context_const", "longid => 'a", Delimfix "CONST _")] #>
   907   Sign.add_advanced_trfuns ([("_context_const", context_const_ast_tr)], [], [], []));
   908 
   909 
   910 (* notation *)
   911 
   912 fun add_notation mode args ctxt =
   913   ctxt |> map_syntax
   914     (LocalSyntax.add_modesyntax (theory_of ctxt) mode (map_filter (const_syntax ctxt) args));
   915 
   916 fun target_notation mode args phi =
   917   let val args' = filter (fn (t, _) => Term.equiv_types (t, Morphism.term phi t)) args;
   918   in Context.mapping (Sign.add_notation mode args') (add_notation mode args') end;
   919 
   920 
   921 (* abbreviations *)
   922 
   923 val set_expand_abbrevs = map_consts o apsnd o Consts.set_expand;
   924 fun read_term_abbrev ctxt = read_term (set_expand_abbrevs false ctxt);
   925 
   926 fun add_abbrev mode (c, raw_t) ctxt =
   927   let
   928     val t0 = cert_term (ctxt |> set_expand_abbrevs false) raw_t
   929       handle ERROR msg => cat_error msg ("in constant abbreviation " ^ quote c);
   930     val [t] = Variable.exportT_terms (Variable.declare_term t0 ctxt) ctxt [t0];
   931     val ((lhs, rhs), consts') = consts_of ctxt
   932       |> Consts.abbreviate (pp ctxt) (tsig_of ctxt) (naming_of ctxt) mode (c, t);
   933   in
   934     ctxt
   935     |> map_consts (apsnd (K consts'))
   936     |> Variable.declare_term rhs
   937     |> pair (lhs, rhs)
   938   end;
   939 
   940 fun target_abbrev prmode ((c, mx), rhs) phi =
   941   let
   942     val c' = Morphism.name phi c;
   943     val rhs' = Morphism.term phi rhs;
   944     val arg' = (c', rhs');
   945   in
   946     Context.mapping_result
   947       (Sign.add_abbrev Syntax.internalM arg') (add_abbrev Syntax.internalM arg')
   948     #-> (fn (lhs, _) =>
   949       Term.equiv_types (rhs, rhs') ? Morphism.form (target_notation prmode [(lhs, mx)]))
   950   end;
   951 
   952 fun local_abbrev (x, rhs) =
   953   Variable.add_fixes [x] #-> (fn [x'] =>
   954     let
   955       val T = Term.fastype_of rhs;
   956       val lhs = Free (x', T);
   957     in
   958       Variable.declare_term lhs #>
   959       Variable.declare_term rhs #>
   960       Assumption.add_assms (K (K (I, Envir.expand_term_frees [((x', T), rhs)]))) [] #> snd #>
   961       pair (lhs, rhs)
   962     end);
   963 
   964 
   965 (* fixes *)
   966 
   967 local
   968 
   969 fun prep_mixfix (x, T, mx) =
   970   if mx <> NoSyn andalso mx <> Structure andalso
   971       (can Name.dest_internal x orelse can Name.dest_skolem x) then
   972     error ("Illegal mixfix syntax for internal/skolem constant " ^ quote x)
   973   else (true, (x, T, mx));
   974 
   975 fun gen_fixes prep raw_vars ctxt =
   976   let
   977     val (vars, _) = prep raw_vars ctxt;
   978     val (xs', ctxt') = Variable.add_fixes (map #1 vars) ctxt;
   979   in
   980     ctxt'
   981     |> fold_map declare_var (map2 (fn x' => fn (_, T, mx) => (x', T, mx)) xs' vars)
   982     |-> (map_syntax o LocalSyntax.add_syntax (theory_of ctxt) o map prep_mixfix)
   983     |> pair xs'
   984   end;
   985 
   986 in
   987 
   988 val add_fixes = gen_fixes read_vars;
   989 val add_fixes_i = gen_fixes cert_vars;
   990 val add_fixes_legacy = gen_fixes cert_vars_legacy;
   991 
   992 end;
   993 
   994 
   995 (* fixes vs. frees *)
   996 
   997 fun auto_fixes (arg as (ctxt, (propss, x))) =
   998   ((fold o fold) Variable.auto_fixes propss ctxt, (propss, x));
   999 
  1000 fun bind_fixes xs ctxt =
  1001   let
  1002     val (_, ctxt') = ctxt |> add_fixes_i (map (fn x => (x, NONE, NoSyn)) xs);
  1003     fun bind (t as Free (x, T)) =
  1004           if member (op =) xs x then
  1005             (case lookup_skolem ctxt' x of SOME x' => Free (x', T) | NONE => t)
  1006           else t
  1007       | bind (t $ u) = bind t $ bind u
  1008       | bind (Abs (x, T, t)) = Abs (x, T, bind t)
  1009       | bind a = a;
  1010   in (bind, ctxt') end;
  1011 
  1012 
  1013 
  1014 (** assumptions **)
  1015 
  1016 local
  1017 
  1018 fun gen_assms prepp exp args ctxt =
  1019   let
  1020     val cert = Thm.cterm_of (theory_of ctxt);
  1021     val (propss, ctxt1) = swap (prepp (ctxt, map snd args));
  1022     val _ = Variable.warn_extra_tfrees ctxt ctxt1;
  1023     val (premss, ctxt2) = fold_burrow (Assumption.add_assms exp o map cert) propss ctxt1;
  1024   in
  1025     ctxt2
  1026     |> auto_bind_facts (flat propss)
  1027     |> put_thms (AutoBind.premsN, SOME (Assumption.prems_of ctxt2))
  1028     |> note_thmss_i Thm.assumptionK (map fst args ~~ map (map (fn th => ([th], []))) premss)
  1029   end;
  1030 
  1031 in
  1032 
  1033 val add_assms = gen_assms (apsnd #1 o bind_propp);
  1034 val add_assms_i = gen_assms (apsnd #1 o bind_propp_i);
  1035 
  1036 end;
  1037 
  1038 
  1039 
  1040 (** cases **)
  1041 
  1042 local
  1043 
  1044 fun rem_case name = remove (fn (x: string, (y, _)) => x = y) name;
  1045 
  1046 fun add_case _ ("", _) cases = cases
  1047   | add_case _ (name, NONE) cases = rem_case name cases
  1048   | add_case is_proper (name, SOME c) cases = (name, (c, is_proper)) :: rem_case name cases;
  1049 
  1050 fun prep_case name fxs c =
  1051   let
  1052     fun replace (opt_x :: xs) ((y, T) :: ys) = (the_default y opt_x, T) :: replace xs ys
  1053       | replace [] ys = ys
  1054       | replace (_ :: _) [] = error ("Too many parameters for case " ^ quote name);
  1055     val RuleCases.Case {fixes, assumes, binds, cases} = c;
  1056     val fixes' = replace fxs fixes;
  1057     val binds' = map drop_schematic binds;
  1058   in
  1059     if null (fold (Term.add_tvarsT o snd) fixes []) andalso
  1060       null (fold (fold Term.add_vars o snd) assumes []) then
  1061         RuleCases.Case {fixes = fixes', assumes = assumes, binds = binds', cases = cases}
  1062     else error ("Illegal schematic variable(s) in case " ^ quote name)
  1063   end;
  1064 
  1065 fun fix (x, T) ctxt =
  1066   let
  1067     val (bind, ctxt') = bind_fixes [x] ctxt;
  1068     val t = bind (Free (x, T));
  1069   in (t, ctxt' |> Variable.declare_constraints t) end;
  1070 
  1071 in
  1072 
  1073 fun add_cases is_proper = map_cases o fold (add_case is_proper);
  1074 
  1075 fun case_result c ctxt =
  1076   let
  1077     val RuleCases.Case {fixes, ...} = c;
  1078     val (ts, ctxt') = ctxt |> fold_map fix fixes;
  1079     val RuleCases.Case {assumes, binds, cases, ...} = RuleCases.apply ts c;
  1080   in
  1081     ctxt'
  1082     |> add_binds_i (map drop_schematic binds)
  1083     |> add_cases true (map (apsnd SOME) cases)
  1084     |> pair (assumes, (binds, cases))
  1085   end;
  1086 
  1087 val apply_case = apfst fst oo case_result;
  1088 
  1089 fun get_case ctxt name xs =
  1090   (case AList.lookup (op =) (cases_of ctxt) name of
  1091     NONE => error ("Unknown case: " ^ quote name)
  1092   | SOME (c, _) => prep_case name xs c);
  1093 
  1094 end;
  1095 
  1096 
  1097 
  1098 (** print context information **)
  1099 
  1100 val debug = ref false;
  1101 
  1102 val verbose = ref false;
  1103 fun verb f x = if ! verbose then f (x ()) else [];
  1104 
  1105 fun setmp_verbose f x = Library.setmp verbose true f x;
  1106 
  1107 
  1108 (* local syntax *)
  1109 
  1110 val print_syntax = Syntax.print_syntax o syn_of;
  1111 
  1112 
  1113 (* abbreviations *)
  1114 
  1115 fun pretty_abbrevs show_globals ctxt =
  1116   let
  1117     val ((_, globals), (space, consts)) =
  1118       pairself (#constants o Consts.dest) (#consts (rep_context ctxt));
  1119     fun add_abbr (_, (_, NONE)) = I
  1120       | add_abbr (c, (T, SOME (t, _))) =
  1121           if not show_globals andalso Symtab.defined globals c then I
  1122           else cons (c, Logic.mk_equals (Const (c, T), t));
  1123     val abbrevs = NameSpace.extern_table (space, Symtab.make (Symtab.fold add_abbr consts []));
  1124   in
  1125     if null abbrevs andalso not (! verbose) then []
  1126     else [Pretty.big_list "abbreviations:" (map (pretty_term_abbrev ctxt o #2) abbrevs)]
  1127   end;
  1128 
  1129 val print_abbrevs = Pretty.writeln o Pretty.chunks o pretty_abbrevs true;
  1130 
  1131 
  1132 (* term bindings *)
  1133 
  1134 fun pretty_binds ctxt =
  1135   let
  1136     val binds = Variable.binds_of ctxt;
  1137     fun prt_bind (xi, (T, t)) = pretty_term_abbrev ctxt (Logic.mk_equals (Var (xi, T), t));
  1138   in
  1139     if Vartab.is_empty binds andalso not (! verbose) then []
  1140     else [Pretty.big_list "term bindings:" (map prt_bind (Vartab.dest binds))]
  1141   end;
  1142 
  1143 val print_binds = Pretty.writeln o Pretty.chunks o pretty_binds;
  1144 
  1145 
  1146 (* local theorems *)
  1147 
  1148 fun pretty_lthms ctxt =
  1149   let
  1150     val props = FactIndex.props (fact_index_of ctxt);
  1151     val facts =
  1152       (if null props then I else cons ("unnamed", props))
  1153       (NameSpace.extern_table (#1 (thms_of ctxt)));
  1154   in
  1155     if null facts andalso not (! verbose) then []
  1156     else [Pretty.big_list "facts:" (map (pretty_fact ctxt) facts)]
  1157   end;
  1158 
  1159 val print_lthms = Pretty.writeln o Pretty.chunks o pretty_lthms;
  1160 
  1161 
  1162 (* local contexts *)
  1163 
  1164 fun pretty_cases ctxt =
  1165   let
  1166     val prt_term = pretty_term ctxt;
  1167 
  1168     fun prt_let (xi, t) = Pretty.block
  1169       [Pretty.quote (prt_term (Var (xi, Term.fastype_of t))), Pretty.str " =", Pretty.brk 1,
  1170         Pretty.quote (prt_term t)];
  1171 
  1172     fun prt_asm (a, ts) = Pretty.block (Pretty.breaks
  1173       ((if a = "" then [] else [Pretty.str (a ^ ":")]) @ map (Pretty.quote o prt_term) ts));
  1174 
  1175     fun prt_sect _ _ _ [] = []
  1176       | prt_sect s sep prt xs = [Pretty.block (Pretty.breaks (Pretty.str s ::
  1177             flat (Library.separate sep (map (Library.single o prt) xs))))];
  1178 
  1179     fun prt_case (name, (fixes, (asms, (lets, cs)))) = Pretty.block (Pretty.fbreaks
  1180       (Pretty.str (name ^ ":") ::
  1181         prt_sect "fix" [] (Pretty.str o fst) fixes @
  1182         prt_sect "let" [Pretty.str "and"] prt_let
  1183           (map_filter (fn (xi, SOME t) => SOME (xi, t) | _ => NONE) lets) @
  1184         (if forall (null o #2) asms then []
  1185           else prt_sect "assume" [Pretty.str "and"] prt_asm asms) @
  1186         prt_sect "subcases:" [] (Pretty.str o fst) cs));
  1187 
  1188     fun add_case (_, (_, false)) = I
  1189       | add_case (name, (c as RuleCases.Case {fixes, ...}, true)) =
  1190           cons (name, (fixes, #1 (case_result c ctxt)));
  1191     val cases = fold add_case (cases_of ctxt) [];
  1192   in
  1193     if null cases andalso not (! verbose) then []
  1194     else [Pretty.big_list "cases:" (map prt_case cases)]
  1195   end;
  1196 
  1197 val print_cases = Pretty.writeln o Pretty.chunks o pretty_cases;
  1198 
  1199 
  1200 (* core context *)
  1201 
  1202 val prems_limit = ref ~1;
  1203 
  1204 fun pretty_ctxt ctxt =
  1205   if ! prems_limit < 0 andalso not (! debug) then []
  1206   else
  1207     let
  1208       val prt_term = pretty_term ctxt;
  1209 
  1210       (*structures*)
  1211       val structs = LocalSyntax.structs_of (syntax_of ctxt);
  1212       val prt_structs = if null structs then []
  1213         else [Pretty.block (Pretty.str "structures:" :: Pretty.brk 1 ::
  1214           Pretty.commas (map Pretty.str structs))];
  1215 
  1216       (*fixes*)
  1217       fun prt_fix (x, x') =
  1218         if x = x' then Pretty.str x
  1219         else Pretty.block [Pretty.str x, Pretty.str " =", Pretty.brk 1, prt_term (Syntax.free x')];
  1220       val fixes =
  1221         rev (filter_out ((can Name.dest_internal orf member (op =) structs) o #1)
  1222           (Variable.fixes_of ctxt));
  1223       val prt_fixes = if null fixes then []
  1224         else [Pretty.block (Pretty.str "fixed variables:" :: Pretty.brk 1 ::
  1225           Pretty.commas (map prt_fix fixes))];
  1226 
  1227       (*prems*)
  1228       val prems = Assumption.prems_of ctxt;
  1229       val len = length prems;
  1230       val suppressed = len - ! prems_limit;
  1231       val prt_prems = if null prems then []
  1232         else [Pretty.big_list "prems:" ((if suppressed <= 0 then [] else [Pretty.str "..."]) @
  1233           map (pretty_thm ctxt) (Library.drop (suppressed, prems)))];
  1234     in prt_structs @ prt_fixes @ prt_prems end;
  1235 
  1236 
  1237 (* main context *)
  1238 
  1239 fun pretty_context ctxt =
  1240   let
  1241     val prt_term = pretty_term ctxt;
  1242     val prt_typ = pretty_typ ctxt;
  1243     val prt_sort = pretty_sort ctxt;
  1244 
  1245     (*theory*)
  1246     val pretty_thy = Pretty.block
  1247       [Pretty.str "theory:", Pretty.brk 1, Context.pretty_thy (theory_of ctxt)];
  1248 
  1249     (*defaults*)
  1250     fun prt_atom prt prtT (x, X) = Pretty.block
  1251       [prt x, Pretty.str " ::", Pretty.brk 1, prtT X];
  1252 
  1253     fun prt_var (x, ~1) = prt_term (Syntax.free x)
  1254       | prt_var xi = prt_term (Syntax.var xi);
  1255 
  1256     fun prt_varT (x, ~1) = prt_typ (TFree (x, []))
  1257       | prt_varT xi = prt_typ (TVar (xi, []));
  1258 
  1259     val prt_defT = prt_atom prt_var prt_typ;
  1260     val prt_defS = prt_atom prt_varT prt_sort;
  1261 
  1262     val (types, sorts) = Variable.constraints_of ctxt;
  1263   in
  1264     verb single (K pretty_thy) @
  1265     pretty_ctxt ctxt @
  1266     verb (pretty_abbrevs false) (K ctxt) @
  1267     verb pretty_binds (K ctxt) @
  1268     verb pretty_lthms (K ctxt) @
  1269     verb pretty_cases (K ctxt) @
  1270     verb single (fn () => Pretty.big_list "type constraints:" (map prt_defT (Vartab.dest types))) @
  1271     verb single (fn () => Pretty.big_list "default sorts:" (map prt_defS (Vartab.dest sorts)))
  1272   end;
  1273 
  1274 end;