src/Tools/Code/code_target.ML
author haftmann
Tue Aug 31 13:08:58 2010 +0200 (2010-08-31)
changeset 38921 15f8cffdbf5d
parent 38918 48d62f237944
child 38923 79d7f2b4cf71
permissions -rw-r--r--
dropped legacy interfaces
     1 (*  Title:      Tools/Code/code_target.ML
     2     Author:     Florian Haftmann, TU Muenchen
     3 
     4 Generic infrastructure for target language data.
     5 *)
     6 
     7 signature CODE_TARGET =
     8 sig
     9   val cert_tyco: theory -> string -> string
    10   val read_tyco: theory -> string -> string
    11 
    12   val export_code_for: theory -> Path.T option -> string -> int option -> string option -> Token.T list
    13     -> Code_Thingol.naming -> Code_Thingol.program -> string list -> unit
    14   val produce_code_for: theory -> string -> int option -> string option -> Token.T list
    15     -> Code_Thingol.naming -> Code_Thingol.program -> string list * string list -> string * string option list
    16   val check_code_for: theory -> string -> bool -> Token.T list
    17     -> Code_Thingol.naming -> Code_Thingol.program -> string list -> unit
    18 
    19   val export_code: theory -> string list
    20     -> (((string * string option) * Path.T option) * Token.T list) list -> unit
    21   val produce_code: theory -> string list -> (Code_Thingol.naming -> string list)
    22     -> string -> int option -> string option -> Token.T list -> string * string option list
    23   val check_code: theory -> string list
    24     -> ((string * bool) * Token.T list) list -> unit
    25 
    26   val shell_command: string (*theory name*) -> string (*export_code expr*) -> unit
    27 
    28   type serializer
    29   type literals = Code_Printer.literals
    30   val add_target: string * { serializer: serializer, literals: literals,
    31     check: { env_var: string, make_destination: Path.T -> Path.T,
    32       make_command: string -> string -> string } } -> theory -> theory
    33   val extend_target: string *
    34       (string * (Code_Thingol.naming -> Code_Thingol.program -> Code_Thingol.program))
    35     -> theory -> theory
    36   val assert_target: theory -> string -> string
    37   val the_literals: theory -> string -> literals
    38   type serialization
    39   val parse_args: 'a parser -> Token.T list -> 'a
    40   val serialization: (int -> Path.T option -> 'a -> unit)
    41     -> (int -> 'a -> string * string option list)
    42     -> 'a -> int -> serialization
    43   val set_default_code_width: int -> theory -> theory
    44 
    45   val allow_abort: string -> theory -> theory
    46   type tyco_syntax = Code_Printer.tyco_syntax
    47   type const_syntax = Code_Printer.const_syntax
    48   val add_syntax_class: string -> class -> string option -> theory -> theory
    49   val add_syntax_inst: string -> class * string -> unit option -> theory -> theory
    50   val add_syntax_tyco: string -> string -> tyco_syntax option -> theory -> theory
    51   val add_syntax_const: string -> string -> const_syntax option -> theory -> theory
    52   val add_reserved: string -> string -> theory -> theory
    53   val add_include: string -> string * (string * string list) option -> theory -> theory
    54 end;
    55 
    56 structure Code_Target : CODE_TARGET =
    57 struct
    58 
    59 open Basic_Code_Thingol;
    60 
    61 type literals = Code_Printer.literals;
    62 type tyco_syntax = Code_Printer.tyco_syntax;
    63 type const_syntax = Code_Printer.const_syntax;
    64 
    65 
    66 (** basics **)
    67 
    68 datatype destination = File of Path.T option | String of string list;
    69 type serialization = destination -> (string * string option list) option;
    70 
    71 fun stmt_names_of_destination (String stmt_names) = stmt_names
    72   | stmt_names_of_destination _ = [];
    73 
    74 fun serialization output _ content width (File some_path) = (output width some_path content; NONE)
    75   | serialization _ string content width (String _) = SOME (string width content);
    76 
    77 fun file some_path f = (f (File some_path); ());
    78 fun string stmt_names f = the (f (String stmt_names));
    79 
    80 
    81 (** theory data **)
    82 
    83 datatype name_syntax_table = NameSyntaxTable of {
    84   class: string Symtab.table,
    85   instance: unit Symreltab.table,
    86   tyco: Code_Printer.tyco_syntax Symtab.table,
    87   const: Code_Printer.const_syntax Symtab.table
    88 };
    89 
    90 fun mk_name_syntax_table ((class, instance), (tyco, const)) =
    91   NameSyntaxTable { class = class, instance = instance, tyco = tyco, const = const };
    92 fun map_name_syntax_table f (NameSyntaxTable { class, instance, tyco, const }) =
    93   mk_name_syntax_table (f ((class, instance), (tyco, const)));
    94 fun merge_name_syntax_table
    95   (NameSyntaxTable { class = class1, instance = instance1, tyco = tyco1, const = const1 },
    96     NameSyntaxTable { class = class2, instance = instance2, tyco = tyco2, const = const2 }) =
    97   mk_name_syntax_table (
    98     (Symtab.join (K snd) (class1, class2),
    99        Symreltab.join (K snd) (instance1, instance2)),
   100     (Symtab.join (K snd) (tyco1, tyco2),
   101        Symtab.join (K snd) (const1, const2))
   102   );
   103 
   104 type serializer =
   105   string option                         (*module name*)
   106   -> Token.T list                       (*arguments*)
   107   -> (string -> string)                 (*labelled_name*)
   108   -> string list                        (*reserved symbols*)
   109   -> (string * Pretty.T) list           (*includes*)
   110   -> (string -> string option)          (*module aliasses*)
   111   -> (string -> string option)          (*class syntax*)
   112   -> (string -> Code_Printer.tyco_syntax option)
   113   -> (string -> Code_Printer.activated_const_syntax option)
   114   -> Code_Thingol.program
   115   -> (string list * string list)        (*selected statements*)
   116   -> int
   117   -> serialization;
   118 
   119 datatype description = Fundamental of { serializer: serializer,
   120       literals: literals,
   121       check: { env_var: string, make_destination: Path.T -> Path.T,
   122         make_command: string -> string -> string } }
   123   | Extension of string *
   124       (Code_Thingol.naming -> Code_Thingol.program -> Code_Thingol.program);
   125 
   126 datatype target = Target of {
   127   serial: serial,
   128   description: description,
   129   reserved: string list,
   130   includes: (Pretty.T * string list) Symtab.table,
   131   name_syntax_table: name_syntax_table,
   132   module_alias: string Symtab.table
   133 };
   134 
   135 fun make_target ((serial, description), ((reserved, includes), (name_syntax_table, module_alias))) =
   136   Target { serial = serial, description = description, reserved = reserved, 
   137     includes = includes, name_syntax_table = name_syntax_table, module_alias = module_alias };
   138 fun map_target f ( Target { serial, description, reserved, includes, name_syntax_table, module_alias } ) =
   139   make_target (f ((serial, description), ((reserved, includes), (name_syntax_table, module_alias))));
   140 fun merge_target strict target (Target { serial = serial1, description = description,
   141   reserved = reserved1, includes = includes1,
   142   name_syntax_table = name_syntax_table1, module_alias = module_alias1 },
   143     Target { serial = serial2, description = _,
   144       reserved = reserved2, includes = includes2,
   145       name_syntax_table = name_syntax_table2, module_alias = module_alias2 }) =
   146   if serial1 = serial2 orelse not strict then
   147     make_target ((serial1, description),
   148       ((merge (op =) (reserved1, reserved2), Symtab.join (K snd) (includes1, includes2)),
   149         (merge_name_syntax_table (name_syntax_table1, name_syntax_table2),
   150           Symtab.join (K snd) (module_alias1, module_alias2))
   151     ))
   152   else
   153     error ("Incompatible targets: " ^ quote target);
   154 
   155 fun the_description (Target { description, ... }) = description;
   156 fun the_reserved (Target { reserved, ... }) = reserved;
   157 fun the_includes (Target { includes, ... }) = includes;
   158 fun the_name_syntax (Target { name_syntax_table = NameSyntaxTable x, ... }) = x;
   159 fun the_module_alias (Target { module_alias , ... }) = module_alias;
   160 
   161 structure Targets = Theory_Data
   162 (
   163   type T = (target Symtab.table * string list) * int;
   164   val empty = ((Symtab.empty, []), 80);
   165   val extend = I;
   166   fun merge (((target1, exc1), width1), ((target2, exc2), width2)) : T =
   167     ((Symtab.join (merge_target true) (target1, target2),
   168       Library.merge (op =) (exc1, exc2)), Int.max (width1, width2));
   169 );
   170 
   171 val abort_allowed = snd o fst o Targets.get;
   172 
   173 fun assert_target thy target = if Symtab.defined ((fst o fst) (Targets.get thy)) target
   174   then target
   175   else error ("Unknown code target language: " ^ quote target);
   176 
   177 fun put_target (target, seri) thy =
   178   let
   179     val lookup_target = Symtab.lookup ((fst o fst) (Targets.get thy));
   180     val _ = case seri
   181      of Extension (super, _) => if is_some (lookup_target super) then ()
   182           else error ("Unknown code target language: " ^ quote super)
   183       | _ => ();
   184     val overwriting = case (Option.map the_description o lookup_target) target
   185      of NONE => false
   186       | SOME (Extension _) => true
   187       | SOME (Fundamental _) => (case seri
   188          of Extension _ => error ("Will not overwrite existing target " ^ quote target)
   189           | _ => true);
   190     val _ = if overwriting
   191       then warning ("Overwriting existing target " ^ quote target)
   192       else (); 
   193   in
   194     thy
   195     |> (Targets.map o apfst o apfst o Symtab.update)
   196           (target, make_target ((serial (), seri), (([], Symtab.empty),
   197             (mk_name_syntax_table ((Symtab.empty, Symreltab.empty),
   198               (Symtab.empty, Symtab.empty)), Symtab.empty))))
   199   end;
   200 
   201 fun add_target (target, seri) = put_target (target, Fundamental seri);
   202 fun extend_target (target, (super, modify)) =
   203   put_target (target, Extension (super, modify));
   204 
   205 fun map_target_data target f thy =
   206   let
   207     val _ = assert_target thy target;
   208   in
   209     thy
   210     |> (Targets.map o apfst o apfst o Symtab.map_entry target o map_target) f
   211   end;
   212 
   213 fun map_reserved target =
   214   map_target_data target o apsnd o apfst o apfst;
   215 fun map_includes target =
   216   map_target_data target o apsnd o apfst o apsnd;
   217 fun map_name_syntax target =
   218   map_target_data target o apsnd o apsnd o apfst o map_name_syntax_table;
   219 fun map_module_alias target =
   220   map_target_data target o apsnd o apsnd o apsnd;
   221 
   222 fun set_default_code_width k = (Targets.map o apsnd) (K k);
   223 
   224 
   225 (** serializer usage **)
   226 
   227 (* montage *)
   228 
   229 fun the_fundamental thy =
   230   let
   231     val ((targets, _), _) = Targets.get thy;
   232     fun fundamental target = case Symtab.lookup targets target
   233      of SOME data => (case the_description data
   234          of Fundamental data => data
   235           | Extension (super, _) => fundamental super)
   236       | NONE => error ("Unknown code target language: " ^ quote target);
   237   in fundamental end;
   238 
   239 fun the_literals thy = #literals o the_fundamental thy;
   240 
   241 local
   242 
   243 fun activate_syntax lookup_name src_tab = Symtab.empty
   244   |> fold_map (fn thing_identifier => fn tab => case lookup_name thing_identifier
   245        of SOME name => (SOME name,
   246             Symtab.update_new (name, the (Symtab.lookup src_tab thing_identifier)) tab)
   247         | NONE => (NONE, tab)) (Symtab.keys src_tab)
   248   |>> map_filter I;
   249 
   250 fun activate_const_syntax thy literals src_tab naming = (Symtab.empty, naming)
   251   |> fold_map (fn c => fn (tab, naming) =>
   252       case Code_Thingol.lookup_const naming c
   253        of SOME name => let
   254               val (syn, naming') = Code_Printer.activate_const_syntax thy
   255                 literals c (the (Symtab.lookup src_tab c)) naming
   256             in (SOME name, (Symtab.update_new (name, syn) tab, naming')) end
   257         | NONE => (NONE, (tab, naming))) (Symtab.keys src_tab)
   258   |>> map_filter I;
   259 
   260 fun invoke_serializer thy abortable serializer literals reserved abs_includes 
   261     module_alias class instance tyco const module_name args naming program2 (names1, presentation_names) width =
   262   let
   263     val (names_class, class') =
   264       activate_syntax (Code_Thingol.lookup_class naming) class;
   265     val names_inst = map_filter (Code_Thingol.lookup_instance naming)
   266       (Symreltab.keys instance);
   267     val (names_tyco, tyco') =
   268       activate_syntax (Code_Thingol.lookup_tyco naming) tyco;
   269     val (names_const, (const', _)) =
   270       activate_const_syntax thy literals const naming;
   271     val names_hidden = names_class @ names_inst @ names_tyco @ names_const;
   272     val names2 = subtract (op =) names_hidden names1;
   273     val program3 = Graph.subgraph (not o member (op =) names_hidden) program2;
   274     val names_all = Graph.all_succs program3 names2;
   275     val includes = abs_includes names_all;
   276     val program4 = Graph.subgraph (member (op =) names_all) program3;
   277     val empty_funs = filter_out (member (op =) abortable)
   278       (Code_Thingol.empty_funs program3);
   279     val _ = if null empty_funs then () else error ("No code equations for "
   280       ^ commas (map (Sign.extern_const thy) empty_funs));
   281   in
   282     serializer module_name args (Code_Thingol.labelled_name thy program2) reserved includes
   283       (if is_some module_name then K module_name else Symtab.lookup module_alias)
   284       (Symtab.lookup class') (Symtab.lookup tyco') (Symtab.lookup const')
   285       program4 (names1, presentation_names) width
   286   end;
   287 
   288 fun mount_serializer thy target some_width raw_module_name args naming program names destination =
   289   let
   290     val ((targets, abortable), default_width) = Targets.get thy;
   291     fun collapse_hierarchy target =
   292       let
   293         val data = case Symtab.lookup targets target
   294          of SOME data => data
   295           | NONE => error ("Unknown code target language: " ^ quote target);
   296       in case the_description data
   297        of Fundamental _ => (I, data)
   298         | Extension (super, modify) => let
   299             val (modify', data') = collapse_hierarchy super
   300           in (modify' #> modify naming, merge_target false target (data', data)) end
   301       end;
   302     val (modify, data) = collapse_hierarchy target;
   303     val serializer = case the_description data
   304     of Fundamental seri => #serializer seri;
   305     val presentation_names = stmt_names_of_destination destination;
   306     val module_name = if null presentation_names
   307       then raw_module_name else SOME "Code";
   308     val reserved = the_reserved data;
   309     fun select_include names_all (name, (content, cs)) =
   310       if null cs then SOME (name, content)
   311       else if exists (fn c => case Code_Thingol.lookup_const naming c
   312        of SOME name => member (op =) names_all name
   313         | NONE => false) cs
   314       then SOME (name, content) else NONE;
   315     fun includes names_all = map_filter (select_include names_all)
   316       ((Symtab.dest o the_includes) data);
   317     val module_alias = the_module_alias data 
   318     val { class, instance, tyco, const } = the_name_syntax data;
   319     val literals = the_literals thy target;
   320     val width = the_default default_width some_width;
   321   in
   322     invoke_serializer thy abortable serializer literals reserved
   323       includes module_alias class instance tyco const module_name args
   324         naming (modify program) (names, presentation_names) width destination
   325   end;
   326 
   327 in
   328 
   329 fun export_code_for thy some_path target some_width some_module_name args naming program names =
   330   file some_path (mount_serializer thy target some_width some_module_name args naming program names);
   331 
   332 fun produce_code_for thy target some_width some_module_name args naming program (names, selects) =
   333   string selects (mount_serializer thy target some_width some_module_name args naming program names);
   334 
   335 fun check_code_for thy target strict args naming program names_cs =
   336   let
   337     val module_name = "Code_Test";
   338     val { env_var, make_destination, make_command } =
   339       (#check o the_fundamental thy) target;
   340     val env_param = getenv env_var;
   341     fun ext_check env_param p =
   342       let 
   343         val destination = make_destination p;
   344         val _ = file (SOME destination) (mount_serializer thy target (SOME 80)
   345           (SOME module_name) args naming program names_cs);
   346         val cmd = make_command env_param module_name;
   347       in if bash ("cd " ^ File.shell_path p ^ " && " ^ cmd ^ " 2>&1") <> 0
   348         then error ("Code check failed for " ^ target ^ ": " ^ cmd)
   349         else ()
   350       end;
   351   in if env_param = ""
   352     then if strict
   353       then error (env_var ^ " not set; cannot check code for " ^ target)
   354       else warning (env_var ^ " not set; skipped checking code for " ^ target)
   355     else Cache_IO.with_tmp_dir "Code_Test" (ext_check env_param)
   356   end;
   357 
   358 end; (* local *)
   359 
   360 
   361 (* code generation *)
   362 
   363 fun transitivly_non_empty_funs thy naming program =
   364   let
   365     val cs = subtract (op =) (abort_allowed thy) (Code_Thingol.empty_funs program);
   366     val names = map_filter (Code_Thingol.lookup_const naming) cs;
   367   in subtract (op =) (Graph.all_preds program names) (Graph.keys program) end;
   368 
   369 fun read_const_exprs thy cs =
   370   let
   371     val (cs1, cs2) = Code_Thingol.read_const_exprs thy cs;
   372     val (names2, (naming, program)) = Code_Thingol.consts_program thy true cs2;
   373     val names3 = transitivly_non_empty_funs thy naming program;
   374     val cs3 = map_filter (fn (c, name) =>
   375       if member (op =) names3 name then SOME c else NONE) (cs2 ~~ names2);
   376   in union (op =) cs3 cs1 end;
   377 
   378 fun prep_destination "" = NONE
   379   | prep_destination "-" = NONE
   380   | prep_destination s = SOME (Path.explode s);
   381 
   382 fun export_code thy cs seris =
   383   let
   384     val (names_cs, (naming, program)) = Code_Thingol.consts_program thy false cs;
   385     val _ = map (fn (((target, module_name), some_path), args) =>
   386       export_code_for thy some_path target NONE module_name args naming program names_cs) seris;
   387   in () end;
   388 
   389 fun export_code_cmd raw_cs seris thy = export_code thy (read_const_exprs thy raw_cs)
   390   ((map o apfst o apsnd) prep_destination seris);
   391 
   392 fun produce_code thy cs names_stmt target some_width some_module_name args =
   393   let
   394     val (names_cs, (naming, program)) = Code_Thingol.consts_program thy false cs;
   395   in produce_code_for thy target some_width some_module_name args naming program (names_cs, names_stmt naming) end;
   396 
   397 fun check_code thy cs seris =
   398   let
   399     val (names_cs, (naming, program)) = Code_Thingol.consts_program thy false cs;
   400     val _ = map (fn ((target, strict), args) =>
   401       check_code_for thy target strict args naming program names_cs) seris;
   402   in () end;
   403 
   404 fun check_code_cmd raw_cs seris thy = check_code thy (read_const_exprs thy raw_cs) seris;
   405 
   406 
   407 (** serializer configuration **)
   408 
   409 (* data access *)
   410 
   411 fun cert_class thy class =
   412   let
   413     val _ = AxClass.get_info thy class;
   414   in class end;
   415 
   416 fun read_class thy = cert_class thy o Sign.intern_class thy;
   417 
   418 fun cert_tyco thy tyco =
   419   let
   420     val _ = if Sign.declared_tyname thy tyco then ()
   421       else error ("No such type constructor: " ^ quote tyco);
   422   in tyco end;
   423 
   424 fun read_tyco thy = cert_tyco thy o Sign.intern_type thy;
   425 
   426 fun cert_inst thy (class, tyco) =
   427   (cert_class thy class, cert_tyco thy tyco);
   428 
   429 fun read_inst thy (raw_tyco, raw_class) =
   430   (read_class thy raw_class, read_tyco thy raw_tyco);
   431 
   432 fun gen_add_syntax (mapp, upd, del) prep_x prep_syn target raw_x some_raw_syn thy =
   433   let
   434     val x = prep_x thy raw_x;
   435     val change = case some_raw_syn
   436      of SOME raw_syn => upd (x, prep_syn thy x raw_syn)
   437       | NONE => del x;
   438   in (map_name_syntax target o mapp) change thy end;
   439 
   440 fun gen_add_syntax_class prep_class =
   441   gen_add_syntax (apfst o apfst, Symtab.update, Symtab.delete_safe) prep_class ((K o K) I);
   442 
   443 fun gen_add_syntax_inst prep_inst =
   444   gen_add_syntax (apfst o apsnd, Symreltab.update, Symreltab.delete_safe) prep_inst ((K o K) I);
   445 
   446 fun gen_add_syntax_tyco prep_tyco =
   447   gen_add_syntax (apsnd o apfst, Symtab.update, Symtab.delete_safe) prep_tyco
   448     (fn thy => fn tyco => fn syn => if fst syn <> Sign.arity_number thy tyco
   449       then error ("Number of arguments mismatch in syntax for type constructor " ^ quote tyco)
   450       else syn);
   451 
   452 fun gen_add_syntax_const prep_const =
   453   gen_add_syntax (apsnd o apsnd, Symtab.update, Symtab.delete_safe) prep_const
   454     (fn thy => fn c => fn syn =>
   455       if Code_Printer.requires_args syn > Code.args_number thy c
   456       then error ("Too many arguments in syntax for constant " ^ quote c)
   457       else syn);
   458 
   459 fun add_reserved target =
   460   let
   461     fun add sym syms = if member (op =) syms sym
   462       then error ("Reserved symbol " ^ quote sym ^ " already declared")
   463       else insert (op =) sym syms
   464   in map_reserved target o add end;
   465 
   466 fun gen_add_include read_const target args thy =
   467   let
   468     fun add (name, SOME (content, raw_cs)) incls =
   469           let
   470             val _ = if Symtab.defined incls name
   471               then warning ("Overwriting existing include " ^ name)
   472               else ();
   473             val cs = map (read_const thy) raw_cs;
   474           in Symtab.update (name, (Code_Printer.str content, cs)) incls end
   475       | add (name, NONE) incls = Symtab.delete name incls;
   476   in map_includes target (add args) thy end;
   477 
   478 val add_include = gen_add_include (K I);
   479 val add_include_cmd = gen_add_include Code.read_const;
   480 
   481 fun add_module_alias target (thyname, modlname) =
   482   let
   483     val xs = Long_Name.explode modlname;
   484     val xs' = map (Name.desymbolize true) xs;
   485   in if xs' = xs
   486     then map_module_alias target (Symtab.update (thyname, modlname))
   487     else error ("Invalid module name: " ^ quote modlname ^ "\n"
   488       ^ "perhaps try " ^ quote (Long_Name.implode xs'))
   489   end;
   490 
   491 fun gen_allow_abort prep_const raw_c thy =
   492   let
   493     val c = prep_const thy raw_c;
   494   in thy |> (Targets.map o apfst o apsnd) (insert (op =) c) end;
   495 
   496 
   497 (* concrete syntax *)
   498 
   499 local
   500 
   501 fun zip_list (x::xs) f g =
   502   f
   503   :|-- (fn y =>
   504     fold_map (fn x => g |-- f >> pair x) xs
   505     :|-- (fn xys => pair ((x, y) :: xys)));
   506 
   507 fun process_multi_syntax parse_thing parse_syntax change =
   508   (Parse.and_list1 parse_thing
   509   :|-- (fn things => Scan.repeat1 (Parse.$$$ "(" |-- Parse.name --
   510         (zip_list things parse_syntax (Parse.$$$ "and")) --| Parse.$$$ ")")))
   511   >> (Toplevel.theory oo fold)
   512     (fn (target, syns) => fold (fn (raw_x, syn) => change target raw_x syn) syns);
   513 
   514 in
   515 
   516 val add_syntax_class = gen_add_syntax_class cert_class;
   517 val add_syntax_inst = gen_add_syntax_inst cert_inst;
   518 val add_syntax_tyco = gen_add_syntax_tyco cert_tyco;
   519 val add_syntax_const = gen_add_syntax_const (K I);
   520 val allow_abort = gen_allow_abort (K I);
   521 val add_reserved = add_reserved;
   522 val add_include = add_include;
   523 
   524 val add_syntax_class_cmd = gen_add_syntax_class read_class;
   525 val add_syntax_inst_cmd = gen_add_syntax_inst read_inst;
   526 val add_syntax_tyco_cmd = gen_add_syntax_tyco read_tyco;
   527 val add_syntax_const_cmd = gen_add_syntax_const Code.read_const;
   528 val allow_abort_cmd = gen_allow_abort Code.read_const;
   529 
   530 fun parse_args f args =
   531   case Scan.read Token.stopper f args
   532    of SOME x => x
   533     | NONE => error "Bad serializer arguments";
   534 
   535 
   536 (** Isar setup **)
   537 
   538 val (inK, module_nameK, fileK, checkingK) = ("in", "module_name", "file", "checking");
   539 
   540 val code_expr_argsP = Scan.optional (Parse.$$$ "(" |-- Args.parse --| Parse.$$$ ")") [];
   541 
   542 val code_exprP =
   543   Scan.repeat1 Parse.term_group :|-- (fn raw_cs =>
   544     ((Parse.$$$ checkingK |-- Scan.repeat (Parse.name
   545       -- ((Parse.$$$ "?" |-- Scan.succeed false) || Scan.succeed true) -- code_expr_argsP))
   546       >> (fn seris => check_code_cmd raw_cs seris)
   547     || Scan.repeat (Parse.$$$ inK |-- Parse.name
   548        -- Scan.option (Parse.$$$ module_nameK |-- Parse.name)
   549        -- Scan.optional (Parse.$$$ fileK |-- Parse.name) ""
   550        -- code_expr_argsP) >> (fn seris => export_code_cmd raw_cs seris)));
   551 
   552 val _ = List.app Keyword.keyword [inK, module_nameK, fileK, checkingK];
   553 
   554 val _ =
   555   Outer_Syntax.command "code_class" "define code syntax for class" Keyword.thy_decl (
   556     process_multi_syntax Parse.xname (Scan.option Parse.string)
   557     add_syntax_class_cmd);
   558 
   559 val _ =
   560   Outer_Syntax.command "code_instance" "define code syntax for instance" Keyword.thy_decl (
   561     process_multi_syntax (Parse.xname --| Parse.$$$ "::" -- Parse.xname)
   562       (Scan.option (Parse.minus >> K ()))
   563     add_syntax_inst_cmd);
   564 
   565 val _ =
   566   Outer_Syntax.command "code_type" "define code syntax for type constructor" Keyword.thy_decl (
   567     process_multi_syntax Parse.xname Code_Printer.parse_tyco_syntax
   568     add_syntax_tyco_cmd);
   569 
   570 val _ =
   571   Outer_Syntax.command "code_const" "define code syntax for constant" Keyword.thy_decl (
   572     process_multi_syntax Parse.term_group Code_Printer.parse_const_syntax
   573     add_syntax_const_cmd);
   574 
   575 val _ =
   576   Outer_Syntax.command "code_reserved" "declare words as reserved for target language"
   577     Keyword.thy_decl (
   578     Parse.name -- Scan.repeat1 Parse.name
   579     >> (fn (target, reserveds) => (Toplevel.theory o fold (add_reserved target)) reserveds)
   580   );
   581 
   582 val _ =
   583   Outer_Syntax.command "code_include" "declare piece of code to be included in generated code"
   584     Keyword.thy_decl (
   585     Parse.name -- Parse.name -- (Parse.text :|-- (fn "-" => Scan.succeed NONE
   586       | s => Scan.optional (Parse.$$$ "attach" |-- Scan.repeat1 Parse.term) [] >> pair s >> SOME))
   587     >> (fn ((target, name), content_consts) =>
   588         (Toplevel.theory o add_include_cmd target) (name, content_consts))
   589   );
   590 
   591 val _ =
   592   Outer_Syntax.command "code_modulename" "alias module to other name" Keyword.thy_decl (
   593     Parse.name -- Scan.repeat1 (Parse.name -- Parse.name)
   594     >> (fn (target, modlnames) => (Toplevel.theory o fold (add_module_alias target)) modlnames)
   595   );
   596 
   597 val _ =
   598   Outer_Syntax.command "code_abort" "permit constant to be implemented as program abort"
   599     Keyword.thy_decl (
   600     Scan.repeat1 Parse.term_group >> (Toplevel.theory o fold allow_abort_cmd)
   601   );
   602 
   603 val _ =
   604   Outer_Syntax.command "export_code" "generate executable code for constants"
   605     Keyword.diag (Parse.!!! code_exprP >> (fn f => Toplevel.keep (f o Toplevel.theory_of)));
   606 
   607 fun shell_command thyname cmd = Toplevel.program (fn _ =>
   608   (use_thy thyname; case Scan.read Token.stopper (Parse.!!! code_exprP)
   609     ((filter Token.is_proper o Outer_Syntax.scan Position.none) cmd)
   610    of SOME f => (writeln "Now generating code..."; f (Thy_Info.get_theory thyname))
   611     | NONE => error ("Bad directive " ^ quote cmd)))
   612   handle Runtime.TOPLEVEL_ERROR => OS.Process.exit OS.Process.failure;
   613 
   614 end; (*local*)
   615 
   616 end; (*struct*)