src/Pure/facts.ML
author wenzelm
Tue Apr 15 18:49:18 2008 +0200 (2008-04-15)
changeset 26664 167d879a89b0
parent 26654 1f711934f221
child 26692 3f48d4f4229f
permissions -rw-r--r--
renamed dest to dest_table, and extern to extern table;
added name space intern/extern;
     1 (*  Title:      Pure/facts.ML
     2     ID:         $Id$
     3     Author:     Makarius
     4 
     5 Environment of named facts, optionally indexed by proposition.
     6 *)
     7 
     8 signature FACTS =
     9 sig
    10   val the_single: string -> thm list -> thm
    11   datatype interval = FromTo of int * int | From of int | Single of int
    12   datatype ref =
    13     Named of (string * Position.T) * interval list option |
    14     Fact of string
    15   val named: string -> ref
    16   val string_of_ref: ref -> string
    17   val name_of_ref: ref -> string
    18   val pos_of_ref: ref -> Position.T
    19   val map_name_of_ref: (string -> string) -> ref -> ref
    20   val select: ref -> thm list -> thm list
    21   val selections: string * thm list -> (ref * thm) list
    22   type T
    23   val empty: T
    24   val space_of: T -> NameSpace.T
    25   val intern: T -> xstring -> string
    26   val extern: T -> string -> xstring
    27   val lookup: Context.generic -> T -> string -> thm list option
    28   val dest_table: T -> (string * thm list) list
    29   val extern_table: T -> (xstring * thm list) list
    30   val props: T -> thm list
    31   val could_unify: T -> term -> thm list
    32   val merge: T * T -> T
    33   val add_global: NameSpace.naming -> string * thm list -> T -> T
    34   val add_local: bool -> NameSpace.naming -> string * thm list -> T -> T
    35   val add_dynamic: NameSpace.naming -> string * (Context.generic -> thm list) -> T -> T
    36   val del: string -> T -> T
    37   val hide: bool -> string -> T -> T
    38 end;
    39 
    40 structure Facts: FACTS =
    41 struct
    42 
    43 (** fact references **)
    44 
    45 fun the_single _ [th] : thm = th
    46   | the_single name _ = error ("Single theorem expected " ^ quote name);
    47 
    48 
    49 (* datatype interval *)
    50 
    51 datatype interval =
    52   FromTo of int * int |
    53   From of int |
    54   Single of int;
    55 
    56 fun string_of_interval (FromTo (i, j)) = string_of_int i ^ "-" ^ string_of_int j
    57   | string_of_interval (From i) = string_of_int i ^ "-"
    58   | string_of_interval (Single i) = string_of_int i;
    59 
    60 fun interval n iv =
    61   let fun err () = raise Fail ("Bad interval specification " ^ string_of_interval iv) in
    62     (case iv of
    63       FromTo (i, j) => if i <= j then i upto j else err ()
    64     | From i => if i <= n then i upto n else err ()
    65     | Single i => [i])
    66   end;
    67 
    68 
    69 (* datatype ref *)
    70 
    71 datatype ref =
    72   Named of (string * Position.T) * interval list option |
    73   Fact of string;
    74 
    75 fun named name = Named ((name, Position.none), NONE);
    76 
    77 fun name_pos_of_ref (Named (name_pos, _)) = name_pos
    78   | name_pos_of_ref (Fact _) = error "Illegal literal fact";
    79 
    80 val name_of_ref = #1 o name_pos_of_ref;
    81 val pos_of_ref = #2 o name_pos_of_ref;
    82 
    83 fun map_name_of_ref f (Named ((name, pos), is)) = Named ((f name, pos), is)
    84   | map_name_of_ref _ r = r;
    85 
    86 fun string_of_ref (Named ((name, _), NONE)) = name
    87   | string_of_ref (Named ((name, _), SOME is)) =
    88       name ^ enclose "(" ")" (commas (map string_of_interval is))
    89   | string_of_ref (Fact _) = error "Illegal literal fact";
    90 
    91 
    92 (* select *)
    93 
    94 fun select (Fact _) ths = ths
    95   | select (Named (_, NONE)) ths = ths
    96   | select (Named ((name, pos), SOME ivs)) ths =
    97       let
    98         val n = length ths;
    99         fun err msg =
   100           error (msg ^ " for " ^ quote name ^ " (length " ^ string_of_int n ^ ")" ^
   101             Position.str_of pos);
   102         fun sel i =
   103           if i < 1 orelse i > n then err ("Bad subscript " ^ string_of_int i)
   104           else nth ths (i - 1);
   105         val is = maps (interval n) ivs handle Fail msg => err msg;
   106       in map sel is end;
   107 
   108 
   109 (* selections *)
   110 
   111 fun selections (name, [th]) = [(Named ((name, Position.none), NONE), th)]
   112   | selections (name, ths) = map2 (fn i => fn th =>
   113       (Named ((name, Position.none), SOME [Single i]), th)) (1 upto length ths) ths;
   114 
   115 
   116 
   117 (** fact environment **)
   118 
   119 (* datatypes *)
   120 
   121 datatype fact = Static of thm list | Dynamic of Context.generic -> thm list;
   122 
   123 datatype T = Facts of
   124  {facts: (fact * serial) NameSpace.table,
   125   props: thm Net.net};
   126 
   127 fun make_facts facts props = Facts {facts = facts, props = props};
   128 val empty = make_facts NameSpace.empty_table Net.empty;
   129 
   130 
   131 (* named facts *)
   132 
   133 fun facts_of (Facts {facts, ...}) = facts;
   134 
   135 val space_of = #1 o facts_of;
   136 val table_of = #2 o facts_of;
   137 
   138 val intern = NameSpace.intern o space_of;
   139 val extern = NameSpace.extern o space_of;
   140 
   141 fun lookup context facts name =
   142   (case Symtab.lookup (table_of facts) name of
   143     NONE => NONE
   144   | SOME (Static ths, _) => SOME ths
   145   | SOME (Dynamic f, _) => SOME (f context));
   146 
   147 fun dest_table facts =
   148   Symtab.fold (fn (name, (Static ths, _)) => cons (name, ths) | _ => I) (table_of facts) [];
   149 
   150 fun extern_table facts =
   151   dest_table facts
   152   |> map (apfst (extern facts))
   153   |> sort_wrt #1;
   154 
   155 
   156 (* indexed props *)
   157 
   158 val prop_ord = Term.term_ord o pairself Thm.full_prop_of;
   159 
   160 fun props (Facts {props, ...}) = sort_distinct prop_ord (Net.content props);
   161 fun could_unify (Facts {props, ...}) = Net.unify_term props;
   162 
   163 
   164 (* merge facts *)
   165 
   166 fun err_dup_fact name = error ("Duplicate fact " ^ quote name);
   167 
   168 fun eq_entry ((Static ths1, _), (Static ths2, _)) = is_equal (list_ord Thm.thm_ord (ths1, ths2))
   169   | eq_entry ((_, id1: serial), (_, id2)) = id1 = id2;
   170 
   171 fun merge (Facts {facts = facts1, props = props1}, Facts {facts = facts2, props = props2}) =
   172   let
   173     val facts' = NameSpace.merge_tables eq_entry (facts1, facts2)
   174       handle Symtab.DUP dup => err_dup_fact dup;
   175     val props' = Net.merge (is_equal o prop_ord) (props1, props2);
   176   in make_facts facts' props' end;
   177 
   178 
   179 (* add static entries *)
   180 
   181 fun add permissive do_props naming (name, ths) (Facts {facts, props}) =
   182   let
   183     val facts' =
   184       if name = "" then facts
   185       else
   186         let
   187           val (space, tab) = facts;
   188           val space' = NameSpace.declare naming name space;
   189           val entry = (name, (Static ths, serial ()));
   190           val tab' = (if permissive then Symtab.update else Symtab.update_new) entry tab
   191             handle Symtab.DUP dup => err_dup_fact dup;
   192         in (space', tab') end;
   193     val props' =
   194       if do_props then fold (fn th => Net.insert_term (K false) (Thm.full_prop_of th, th)) ths props
   195       else props;
   196   in make_facts facts' props' end;
   197 
   198 val add_global = add false false;
   199 val add_local = add true;
   200 
   201 
   202 (* add dynamic entries *)
   203 
   204 fun add_dynamic naming (name, f) (Facts {facts = (space, tab), props}) =
   205   let
   206     val space' = NameSpace.declare naming name space;
   207     val entry = (name, (Dynamic f, serial ()));
   208     val tab' = Symtab.update_new entry tab
   209       handle Symtab.DUP dup => err_dup_fact dup;
   210   in make_facts (space', tab') props end;
   211 
   212 
   213 (* remove entries *)
   214 
   215 fun del name (Facts {facts = (space, tab), props}) =
   216   let
   217     val space' = NameSpace.hide true name space handle ERROR _ => space;
   218     val tab' = Symtab.delete_safe name tab;
   219   in make_facts (space', tab') props end;
   220 
   221 fun hide fully name (Facts {facts = (space, tab), props}) =
   222   make_facts (NameSpace.hide fully name space, tab) props;
   223 
   224 end;