src/HOL/Imperative_HOL/Heap_Monad.thy
author wenzelm
Thu Feb 11 22:19:58 2010 +0100 (2010-02-11)
changeset 35113 1a0c129bb2e0
parent 34051 1a82e2e29d67
child 35423 6ef9525a5727
permissions -rw-r--r--
modernized translations;
formal markup of @{syntax_const} and @{const_syntax};
     1 (*  Title:      HOL/Library/Heap_Monad.thy
     2     Author:     John Matthews, Galois Connections; Alexander Krauss, Lukas Bulwahn & Florian Haftmann, TU Muenchen
     3 *)
     4 
     5 header {* A monad with a polymorphic heap *}
     6 
     7 theory Heap_Monad
     8 imports Heap
     9 begin
    10 
    11 subsection {* The monad *}
    12 
    13 subsubsection {* Monad combinators *}
    14 
    15 datatype exception = Exn
    16 
    17 text {* Monadic heap actions either produce values
    18   and transform the heap, or fail *}
    19 datatype 'a Heap = Heap "heap \<Rightarrow> ('a + exception) \<times> heap"
    20 
    21 primrec
    22   execute :: "'a Heap \<Rightarrow> heap \<Rightarrow> ('a + exception) \<times> heap" where
    23   "execute (Heap f) = f"
    24 lemmas [code del] = execute.simps
    25 
    26 lemma Heap_execute [simp]:
    27   "Heap (execute f) = f" by (cases f) simp_all
    28 
    29 lemma Heap_eqI:
    30   "(\<And>h. execute f h = execute g h) \<Longrightarrow> f = g"
    31     by (cases f, cases g) (auto simp: expand_fun_eq)
    32 
    33 lemma Heap_eqI':
    34   "(\<And>h. (\<lambda>x. execute (f x) h) = (\<lambda>y. execute (g y) h)) \<Longrightarrow> f = g"
    35     by (auto simp: expand_fun_eq intro: Heap_eqI)
    36 
    37 lemma Heap_strip: "(\<And>f. PROP P f) \<equiv> (\<And>g. PROP P (Heap g))"
    38 proof
    39   fix g :: "heap \<Rightarrow> ('a + exception) \<times> heap" 
    40   assume "\<And>f. PROP P f"
    41   then show "PROP P (Heap g)" .
    42 next
    43   fix f :: "'a Heap" 
    44   assume assm: "\<And>g. PROP P (Heap g)"
    45   then have "PROP P (Heap (execute f))" .
    46   then show "PROP P f" by simp
    47 qed
    48 
    49 definition
    50   heap :: "(heap \<Rightarrow> 'a \<times> heap) \<Rightarrow> 'a Heap" where
    51   [code del]: "heap f = Heap (\<lambda>h. apfst Inl (f h))"
    52 
    53 lemma execute_heap [simp]:
    54   "execute (heap f) h = apfst Inl (f h)"
    55   by (simp add: heap_def)
    56 
    57 definition
    58   bindM :: "'a Heap \<Rightarrow> ('a \<Rightarrow> 'b Heap) \<Rightarrow> 'b Heap" (infixl ">>=" 54) where
    59   [code del]: "f >>= g = Heap (\<lambda>h. case execute f h of
    60                   (Inl x, h') \<Rightarrow> execute (g x) h'
    61                 | r \<Rightarrow> r)"
    62 
    63 notation
    64   bindM (infixl "\<guillemotright>=" 54)
    65 
    66 abbreviation
    67   chainM :: "'a Heap \<Rightarrow> 'b Heap \<Rightarrow> 'b Heap"  (infixl ">>" 54) where
    68   "f >> g \<equiv> f >>= (\<lambda>_. g)"
    69 
    70 notation
    71   chainM (infixl "\<guillemotright>" 54)
    72 
    73 definition
    74   return :: "'a \<Rightarrow> 'a Heap" where
    75   [code del]: "return x = heap (Pair x)"
    76 
    77 lemma execute_return [simp]:
    78   "execute (return x) h = apfst Inl (x, h)"
    79   by (simp add: return_def)
    80 
    81 definition
    82   raise :: "string \<Rightarrow> 'a Heap" where -- {* the string is just decoration *}
    83   [code del]: "raise s = Heap (Pair (Inr Exn))"
    84 
    85 notation (latex output)
    86   "raise" ("\<^raw:{\textsf{raise}}>")
    87 
    88 lemma execute_raise [simp]:
    89   "execute (raise s) h = (Inr Exn, h)"
    90   by (simp add: raise_def)
    91 
    92 
    93 subsubsection {* do-syntax *}
    94 
    95 text {*
    96   We provide a convenient do-notation for monadic expressions
    97   well-known from Haskell.  @{const Let} is printed
    98   specially in do-expressions.
    99 *}
   100 
   101 nonterminals do_expr
   102 
   103 syntax
   104   "_do" :: "do_expr \<Rightarrow> 'a"
   105     ("(do (_)//done)" [12] 100)
   106   "_bindM" :: "pttrn \<Rightarrow> 'a \<Rightarrow> do_expr \<Rightarrow> do_expr"
   107     ("_ <- _;//_" [1000, 13, 12] 12)
   108   "_chainM" :: "'a \<Rightarrow> do_expr \<Rightarrow> do_expr"
   109     ("_;//_" [13, 12] 12)
   110   "_let" :: "pttrn \<Rightarrow> 'a \<Rightarrow> do_expr \<Rightarrow> do_expr"
   111     ("let _ = _;//_" [1000, 13, 12] 12)
   112   "_nil" :: "'a \<Rightarrow> do_expr"
   113     ("_" [12] 12)
   114 
   115 syntax (xsymbols)
   116   "_bindM" :: "pttrn \<Rightarrow> 'a \<Rightarrow> do_expr \<Rightarrow> do_expr"
   117     ("_ \<leftarrow> _;//_" [1000, 13, 12] 12)
   118 syntax (latex output)
   119   "_do" :: "do_expr \<Rightarrow> 'a"
   120     ("(\<^raw:{\textsf{do}}> (_))" [12] 100)
   121   "_let" :: "pttrn \<Rightarrow> 'a \<Rightarrow> do_expr \<Rightarrow> do_expr"
   122     ("\<^raw:\textsf{let}> _ = _;//_" [1000, 13, 12] 12)
   123 notation (latex output)
   124   "return" ("\<^raw:{\textsf{return}}>")
   125 
   126 translations
   127   "_do f" => "f"
   128   "_bindM x f g" => "f \<guillemotright>= (\<lambda>x. g)"
   129   "_chainM f g" => "f \<guillemotright> g"
   130   "_let x t f" => "CONST Let t (\<lambda>x. f)"
   131   "_nil f" => "f"
   132 
   133 print_translation {*
   134 let
   135   fun dest_abs_eta (Abs (abs as (_, ty, _))) =
   136         let
   137           val (v, t) = Syntax.variant_abs abs;
   138         in (Free (v, ty), t) end
   139     | dest_abs_eta t =
   140         let
   141           val (v, t) = Syntax.variant_abs ("", dummyT, t $ Bound 0);
   142         in (Free (v, dummyT), t) end;
   143   fun unfold_monad (Const (@{const_syntax bindM}, _) $ f $ g) =
   144         let
   145           val (v, g') = dest_abs_eta g;
   146           val vs = fold_aterms (fn Free (v, _) => insert (op =) v | _ => I) v [];
   147           val v_used = fold_aterms
   148             (fn Free (w, _) => (fn s => s orelse member (op =) vs w) | _ => I) g' false;
   149         in if v_used then
   150           Const (@{syntax_const "_bindM"}, dummyT) $ v $ f $ unfold_monad g'
   151         else
   152           Const (@{syntax_const "_chainM"}, dummyT) $ f $ unfold_monad g'
   153         end
   154     | unfold_monad (Const (@{const_syntax chainM}, _) $ f $ g) =
   155         Const (@{syntax_const "_chainM"}, dummyT) $ f $ unfold_monad g
   156     | unfold_monad (Const (@{const_syntax Let}, _) $ f $ g) =
   157         let
   158           val (v, g') = dest_abs_eta g;
   159         in Const (@{syntax_const "_let"}, dummyT) $ v $ f $ unfold_monad g' end
   160     | unfold_monad (Const (@{const_syntax Pair}, _) $ f) =
   161         Const (@{const_syntax return}, dummyT) $ f
   162     | unfold_monad f = f;
   163   fun contains_bindM (Const (@{const_syntax bindM}, _) $ _ $ _) = true
   164     | contains_bindM (Const (@{const_syntax Let}, _) $ _ $ Abs (_, _, t)) =
   165         contains_bindM t;
   166   fun bindM_monad_tr' (f::g::ts) = list_comb
   167     (Const (@{syntax_const "_do"}, dummyT) $
   168       unfold_monad (Const (@{const_syntax bindM}, dummyT) $ f $ g), ts);
   169   fun Let_monad_tr' (f :: (g as Abs (_, _, g')) :: ts) =
   170     if contains_bindM g' then list_comb
   171       (Const (@{syntax_const "_do"}, dummyT) $
   172         unfold_monad (Const (@{const_syntax Let}, dummyT) $ f $ g), ts)
   173     else raise Match;
   174 in
   175  [(@{const_syntax bindM}, bindM_monad_tr'),
   176   (@{const_syntax Let}, Let_monad_tr')]
   177 end;
   178 *}
   179 
   180 
   181 subsection {* Monad properties *}
   182 
   183 subsubsection {* Monad laws *}
   184 
   185 lemma return_bind: "return x \<guillemotright>= f = f x"
   186   by (simp add: bindM_def return_def)
   187 
   188 lemma bind_return: "f \<guillemotright>= return = f"
   189 proof (rule Heap_eqI)
   190   fix h
   191   show "execute (f \<guillemotright>= return) h = execute f h"
   192     by (auto simp add: bindM_def return_def split: sum.splits prod.splits)
   193 qed
   194 
   195 lemma bind_bind: "(f \<guillemotright>= g) \<guillemotright>= h = f \<guillemotright>= (\<lambda>x. g x \<guillemotright>= h)"
   196   by (rule Heap_eqI) (auto simp add: bindM_def split: split: sum.splits prod.splits)
   197 
   198 lemma bind_bind': "f \<guillemotright>= (\<lambda>x. g x \<guillemotright>= h x) = f \<guillemotright>= (\<lambda>x. g x \<guillemotright>= (\<lambda>y. return (x, y))) \<guillemotright>= (\<lambda>(x, y). h x y)"
   199   by (rule Heap_eqI) (auto simp add: bindM_def split: split: sum.splits prod.splits)
   200 
   201 lemma raise_bind: "raise e \<guillemotright>= f = raise e"
   202   by (simp add: raise_def bindM_def)
   203 
   204 
   205 lemmas monad_simp = return_bind bind_return bind_bind raise_bind
   206 
   207 
   208 subsection {* Generic combinators *}
   209 
   210 definition
   211   liftM :: "('a \<Rightarrow> 'b) \<Rightarrow> 'a \<Rightarrow> 'b Heap"
   212 where
   213   "liftM f = return o f"
   214 
   215 definition
   216   compM :: "('a \<Rightarrow> 'b Heap) \<Rightarrow> ('b \<Rightarrow> 'c Heap) \<Rightarrow> 'a \<Rightarrow> 'c Heap" (infixl ">>==" 54)
   217 where
   218   "(f >>== g) = (\<lambda>x. f x \<guillemotright>= g)"
   219 
   220 notation
   221   compM (infixl "\<guillemotright>==" 54)
   222 
   223 lemma liftM_collapse: "liftM f x = return (f x)"
   224   by (simp add: liftM_def)
   225 
   226 lemma liftM_compM: "liftM f \<guillemotright>== g = g o f"
   227   by (auto intro: Heap_eqI' simp add: expand_fun_eq liftM_def compM_def bindM_def)
   228 
   229 lemma compM_return: "f \<guillemotright>== return = f"
   230   by (simp add: compM_def monad_simp)
   231 
   232 lemma compM_compM: "(f \<guillemotright>== g) \<guillemotright>== h = f \<guillemotright>== (g \<guillemotright>== h)"
   233   by (simp add: compM_def monad_simp)
   234 
   235 lemma liftM_bind:
   236   "(\<lambda>x. liftM f x \<guillemotright>= liftM g) = liftM (\<lambda>x. g (f x))"
   237   by (rule Heap_eqI') (simp add: monad_simp liftM_def bindM_def)
   238 
   239 lemma liftM_comp:
   240   "liftM f o g = liftM (f o g)"
   241   by (rule Heap_eqI') (simp add: liftM_def)
   242 
   243 lemmas monad_simp' = monad_simp liftM_compM compM_return
   244   compM_compM liftM_bind liftM_comp
   245 
   246 primrec 
   247   mapM :: "('a \<Rightarrow> 'b Heap) \<Rightarrow> 'a list \<Rightarrow> 'b list Heap"
   248 where
   249   "mapM f [] = return []"
   250   | "mapM f (x#xs) = do y \<leftarrow> f x;
   251                         ys \<leftarrow> mapM f xs;
   252                         return (y # ys)
   253                      done"
   254 
   255 primrec
   256   foldM :: "('a \<Rightarrow> 'b \<Rightarrow> 'b Heap) \<Rightarrow> 'a list \<Rightarrow> 'b \<Rightarrow> 'b Heap"
   257 where
   258   "foldM f [] s = return s"
   259   | "foldM f (x#xs) s = f x s \<guillemotright>= foldM f xs"
   260 
   261 definition
   262   assert :: "('a \<Rightarrow> bool) \<Rightarrow> 'a \<Rightarrow> 'a Heap"
   263 where
   264   "assert P x = (if P x then return x else raise (''assert''))"
   265 
   266 lemma assert_cong [fundef_cong]:
   267   assumes "P = P'"
   268   assumes "\<And>x. P' x \<Longrightarrow> f x = f' x"
   269   shows "(assert P x >>= f) = (assert P' x >>= f')"
   270   using assms by (auto simp add: assert_def return_bind raise_bind)
   271 
   272 subsubsection {* A monadic combinator for simple recursive functions *}
   273  
   274 function (default "\<lambda>(f,g,x,h). (Inr Exn, undefined)") 
   275   mrec 
   276 where
   277   "mrec f g x h = 
   278    (case Heap_Monad.execute (f x) h of
   279      (Inl (Inl r), h') \<Rightarrow> (Inl r, h')
   280    | (Inl (Inr s), h') \<Rightarrow> 
   281           (case mrec f g s h' of
   282              (Inl z, h'') \<Rightarrow> Heap_Monad.execute (g x s z) h''
   283            | (Inr e, h'') \<Rightarrow> (Inr e, h''))
   284    | (Inr e, h') \<Rightarrow> (Inr e, h')
   285    )"
   286 by auto
   287 
   288 lemma graph_implies_dom:
   289 	"mrec_graph x y \<Longrightarrow> mrec_dom x"
   290 apply (induct rule:mrec_graph.induct) 
   291 apply (rule accpI)
   292 apply (erule mrec_rel.cases)
   293 by simp
   294 
   295 lemma f_default: "\<not> mrec_dom (f, g, x, h) \<Longrightarrow> mrec f g x h = (Inr Exn, undefined)"
   296 	unfolding mrec_def 
   297   by (rule fundef_default_value[OF mrec_sumC_def graph_implies_dom, of _ _ "(f, g, x, h)", simplified])
   298 
   299 lemma f_di_reverse: 
   300   assumes "\<not> mrec_dom (f, g, x, h)"
   301   shows "
   302    (case Heap_Monad.execute (f x) h of
   303      (Inl (Inl r), h') \<Rightarrow> mrecalse
   304    | (Inl (Inr s), h') \<Rightarrow> \<not> mrec_dom (f, g, s, h')
   305    | (Inr e, h') \<Rightarrow> mrecalse
   306    )" 
   307 using assms
   308 by (auto split:prod.splits sum.splits)
   309  (erule notE, rule accpI, elim mrec_rel.cases, simp)+
   310 
   311 
   312 lemma mrec_rule:
   313   "mrec f g x h = 
   314    (case Heap_Monad.execute (f x) h of
   315      (Inl (Inl r), h') \<Rightarrow> (Inl r, h')
   316    | (Inl (Inr s), h') \<Rightarrow> 
   317           (case mrec f g s h' of
   318              (Inl z, h'') \<Rightarrow> Heap_Monad.execute (g x s z) h''
   319            | (Inr e, h'') \<Rightarrow> (Inr e, h''))
   320    | (Inr e, h') \<Rightarrow> (Inr e, h')
   321    )"
   322 apply (cases "mrec_dom (f,g,x,h)", simp)
   323 apply (frule f_default)
   324 apply (frule f_di_reverse, simp)
   325 by (auto split: sum.split prod.split simp: f_default)
   326 
   327 
   328 definition
   329   "MREC f g x = Heap (mrec f g x)"
   330 
   331 lemma MREC_rule:
   332   "MREC f g x = 
   333   (do y \<leftarrow> f x;
   334                 (case y of 
   335                 Inl r \<Rightarrow> return r
   336               | Inr s \<Rightarrow> 
   337                 do z \<leftarrow> MREC f g s ;
   338                    g x s z
   339                 done) done)"
   340   unfolding MREC_def
   341   unfolding bindM_def return_def
   342   apply simp
   343   apply (rule ext)
   344   apply (unfold mrec_rule[of f g x])
   345   by (auto split:prod.splits sum.splits)
   346 
   347 hide (open) const heap execute
   348 
   349 
   350 subsection {* Code generator setup *}
   351 
   352 subsubsection {* Logical intermediate layer *}
   353 
   354 definition
   355   Fail :: "String.literal \<Rightarrow> exception"
   356 where
   357   [code del]: "Fail s = Exn"
   358 
   359 definition
   360   raise_exc :: "exception \<Rightarrow> 'a Heap"
   361 where
   362   [code del]: "raise_exc e = raise []"
   363 
   364 lemma raise_raise_exc [code, code_unfold]:
   365   "raise s = raise_exc (Fail (STR s))"
   366   unfolding Fail_def raise_exc_def raise_def ..
   367 
   368 hide (open) const Fail raise_exc
   369 
   370 
   371 subsubsection {* SML and OCaml *}
   372 
   373 code_type Heap (SML "unit/ ->/ _")
   374 code_const Heap (SML "raise/ (Fail/ \"bare Heap\")")
   375 code_const "op \<guillemotright>=" (SML "!(fn/ f'_/ =>/ fn/ ()/ =>/ f'_/ (_/ ())/ ())")
   376 code_const return (SML "!(fn/ ()/ =>/ _)")
   377 code_const "Heap_Monad.Fail" (SML "Fail")
   378 code_const "Heap_Monad.raise_exc" (SML "!(fn/ ()/ =>/ raise/ _)")
   379 
   380 code_type Heap (OCaml "_")
   381 code_const Heap (OCaml "failwith/ \"bare Heap\"")
   382 code_const "op \<guillemotright>=" (OCaml "!(fun/ f'_/ ()/ ->/ f'_/ (_/ ())/ ())")
   383 code_const return (OCaml "!(fun/ ()/ ->/ _)")
   384 code_const "Heap_Monad.Fail" (OCaml "Failure")
   385 code_const "Heap_Monad.raise_exc" (OCaml "!(fun/ ()/ ->/ raise/ _)")
   386 
   387 setup {*
   388 
   389 let
   390 
   391 open Code_Thingol;
   392 
   393 fun imp_program naming =
   394 
   395   let
   396     fun is_const c = case lookup_const naming c
   397      of SOME c' => (fn c'' => c' = c'')
   398       | NONE => K false;
   399     val is_bindM = is_const @{const_name bindM};
   400     val is_return = is_const @{const_name return};
   401     val dummy_name = "";
   402     val dummy_type = ITyVar dummy_name;
   403     val dummy_case_term = IVar NONE;
   404     (*assumption: dummy values are not relevant for serialization*)
   405     val unitt = case lookup_const naming @{const_name Unity}
   406      of SOME unit' => IConst (unit', (([], []), []))
   407       | NONE => error ("Must include " ^ @{const_name Unity} ^ " in generated constants.");
   408     fun dest_abs ((v, ty) `|=> t, _) = ((v, ty), t)
   409       | dest_abs (t, ty) =
   410           let
   411             val vs = fold_varnames cons t [];
   412             val v = Name.variant vs "x";
   413             val ty' = (hd o fst o unfold_fun) ty;
   414           in ((SOME v, ty'), t `$ IVar (SOME v)) end;
   415     fun force (t as IConst (c, _) `$ t') = if is_return c
   416           then t' else t `$ unitt
   417       | force t = t `$ unitt;
   418     fun tr_bind' [(t1, _), (t2, ty2)] =
   419       let
   420         val ((v, ty), t) = dest_abs (t2, ty2);
   421       in ICase (((force t1, ty), [(IVar v, tr_bind'' t)]), dummy_case_term) end
   422     and tr_bind'' t = case unfold_app t
   423          of (IConst (c, (_, ty1 :: ty2 :: _)), [x1, x2]) => if is_bindM c
   424               then tr_bind' [(x1, ty1), (x2, ty2)]
   425               else force t
   426           | _ => force t;
   427     fun imp_monad_bind'' ts = (SOME dummy_name, dummy_type) `|=> ICase (((IVar (SOME dummy_name), dummy_type),
   428       [(unitt, tr_bind' ts)]), dummy_case_term)
   429     and imp_monad_bind' (const as (c, (_, tys))) ts = if is_bindM c then case (ts, tys)
   430        of ([t1, t2], ty1 :: ty2 :: _) => imp_monad_bind'' [(t1, ty1), (t2, ty2)]
   431         | ([t1, t2, t3], ty1 :: ty2 :: _) => imp_monad_bind'' [(t1, ty1), (t2, ty2)] `$ t3
   432         | (ts, _) => imp_monad_bind (eta_expand 2 (const, ts))
   433       else IConst const `$$ map imp_monad_bind ts
   434     and imp_monad_bind (IConst const) = imp_monad_bind' const []
   435       | imp_monad_bind (t as IVar _) = t
   436       | imp_monad_bind (t as _ `$ _) = (case unfold_app t
   437          of (IConst const, ts) => imp_monad_bind' const ts
   438           | (t, ts) => imp_monad_bind t `$$ map imp_monad_bind ts)
   439       | imp_monad_bind (v_ty `|=> t) = v_ty `|=> imp_monad_bind t
   440       | imp_monad_bind (ICase (((t, ty), pats), t0)) = ICase
   441           (((imp_monad_bind t, ty),
   442             (map o pairself) imp_monad_bind pats),
   443               imp_monad_bind t0);
   444 
   445   in (Graph.map_nodes o map_terms_stmt) imp_monad_bind end;
   446 
   447 in
   448 
   449 Code_Target.extend_target ("SML_imp", ("SML", imp_program))
   450 #> Code_Target.extend_target ("OCaml_imp", ("OCaml", imp_program))
   451 
   452 end
   453 
   454 *}
   455 
   456 code_reserved OCaml Failure raise
   457 
   458 
   459 subsubsection {* Haskell *}
   460 
   461 text {* Adaption layer *}
   462 
   463 code_include Haskell "Heap"
   464 {*import qualified Control.Monad;
   465 import qualified Control.Monad.ST;
   466 import qualified Data.STRef;
   467 import qualified Data.Array.ST;
   468 
   469 type RealWorld = Control.Monad.ST.RealWorld;
   470 type ST s a = Control.Monad.ST.ST s a;
   471 type STRef s a = Data.STRef.STRef s a;
   472 type STArray s a = Data.Array.ST.STArray s Int a;
   473 
   474 newSTRef = Data.STRef.newSTRef;
   475 readSTRef = Data.STRef.readSTRef;
   476 writeSTRef = Data.STRef.writeSTRef;
   477 
   478 newArray :: (Int, Int) -> a -> ST s (STArray s a);
   479 newArray = Data.Array.ST.newArray;
   480 
   481 newListArray :: (Int, Int) -> [a] -> ST s (STArray s a);
   482 newListArray = Data.Array.ST.newListArray;
   483 
   484 lengthArray :: STArray s a -> ST s Int;
   485 lengthArray a = Control.Monad.liftM snd (Data.Array.ST.getBounds a);
   486 
   487 readArray :: STArray s a -> Int -> ST s a;
   488 readArray = Data.Array.ST.readArray;
   489 
   490 writeArray :: STArray s a -> Int -> a -> ST s ();
   491 writeArray = Data.Array.ST.writeArray;*}
   492 
   493 code_reserved Haskell Heap
   494 
   495 text {* Monad *}
   496 
   497 code_type Heap (Haskell "Heap.ST/ Heap.RealWorld/ _")
   498 code_const Heap (Haskell "error/ \"bare Heap\"")
   499 code_monad "op \<guillemotright>=" Haskell
   500 code_const return (Haskell "return")
   501 code_const "Heap_Monad.Fail" (Haskell "_")
   502 code_const "Heap_Monad.raise_exc" (Haskell "error")
   503 
   504 end