src/Pure/goal.ML
author wenzelm
Thu Nov 30 14:17:29 2006 +0100 (2006-11-30)
changeset 21604 1af327306c8e
parent 21579 abd2b4386a63
child 21687 f689f729afab
permissions -rw-r--r--
added norm/close_result (supercede local_standard etc.);
     1 (*  Title:      Pure/goal.ML
     2     ID:         $Id$
     3     Author:     Makarius and Lawrence C Paulson
     4 
     5 Goals in tactical theorem proving.
     6 *)
     7 
     8 signature BASIC_GOAL =
     9 sig
    10   val SELECT_GOAL: tactic -> int -> tactic
    11 end;
    12 
    13 signature GOAL =
    14 sig
    15   include BASIC_GOAL
    16   val init: cterm -> thm
    17   val protect: thm -> thm
    18   val conclude: thm -> thm
    19   val finish: thm -> thm
    20   val norm_result: thm -> thm
    21   val close_result: thm -> thm
    22   val compose_hhf: thm -> int -> thm -> thm Seq.seq
    23   val compose_hhf_tac: thm -> int -> tactic
    24   val comp_hhf: thm -> thm -> thm
    25   val prove_raw: cterm list -> cterm -> (thm list -> tactic) -> thm
    26   val prove_multi: Proof.context -> string list -> term list -> term list ->
    27     ({prems: thm list, context: Proof.context} -> tactic) -> thm list
    28   val prove: Proof.context -> string list -> term list -> term ->
    29     ({prems: thm list, context: Proof.context} -> tactic) -> thm
    30   val prove_global: theory -> string list -> term list -> term -> (thm list -> tactic) -> thm
    31   val extract: int -> int -> thm -> thm Seq.seq
    32   val retrofit: int -> int -> thm -> thm -> thm Seq.seq
    33 end;
    34 
    35 structure Goal: GOAL =
    36 struct
    37 
    38 (** goals **)
    39 
    40 (*
    41   -------- (init)
    42   C ==> #C
    43 *)
    44 val init =
    45   let val A = #1 (Drule.dest_implies (Thm.cprop_of Drule.protectI))
    46   in fn C => Thm.instantiate ([], [(A, C)]) Drule.protectI end;
    47 
    48 (*
    49    C
    50   --- (protect)
    51   #C
    52 *)
    53 fun protect th = th COMP_INCR Drule.protectI;
    54 
    55 (*
    56   A ==> ... ==> #C
    57   ---------------- (conclude)
    58   A ==> ... ==> C
    59 *)
    60 fun conclude th =
    61   (case SINGLE (Thm.compose_no_flatten false (th, Thm.nprems_of th) 1)
    62       (Drule.incr_indexes th Drule.protectD) of
    63     SOME th' => th'
    64   | NONE => raise THM ("Failed to conclude goal", 0, [th]));
    65 
    66 (*
    67   #C
    68   --- (finish)
    69    C
    70 *)
    71 fun finish th =
    72   (case Thm.nprems_of th of
    73     0 => conclude th
    74   | n => raise THM ("Proof failed.\n" ^
    75       Pretty.string_of (Pretty.chunks (Display.pretty_goals n th)) ^
    76       ("\n" ^ string_of_int n ^ " unsolved goal(s)!"), 0, [th]));
    77 
    78 
    79 
    80 (** results **)
    81 
    82 (* normal form *)
    83 
    84 val norm_result =
    85   Drule.flexflex_unique
    86   #> MetaSimplifier.norm_hhf_protect
    87   #> Thm.strip_shyps
    88   #> Drule.zero_var_indexes;
    89 
    90 val close_result =
    91   Thm.compress
    92   #> Drule.close_derivation;
    93 
    94 
    95 (* composition of normal results *)
    96 
    97 fun compose_hhf tha i thb =
    98   Thm.bicompose false (false, Drule.lift_all (Thm.cprem_of thb i) tha, 0) i thb;
    99 
   100 fun compose_hhf_tac th i = PRIMSEQ (compose_hhf th i);
   101 
   102 fun comp_hhf tha thb =
   103   (case Seq.chop 2 (compose_hhf tha 1 thb) of
   104     ([th], _) => th
   105   | ([], _) => raise THM ("comp_hhf: no unifiers", 1, [tha, thb])
   106   | _  => raise THM ("comp_hhf: multiple unifiers", 1, [tha, thb]));
   107 
   108 
   109 
   110 (** tactical theorem proving **)
   111 
   112 (* prove_raw -- no checks, no normalization of result! *)
   113 
   114 fun prove_raw casms cprop tac =
   115   (case SINGLE (tac (map Assumption.assume casms)) (init cprop) of
   116     SOME th => Drule.implies_intr_list casms (finish th)
   117   | NONE => error "Tactic failed.");
   118 
   119 
   120 (* prove_multi *)
   121 
   122 fun prove_multi ctxt xs asms props tac =
   123   let
   124     val thy = ProofContext.theory_of ctxt;
   125     val string_of_term = Sign.string_of_term thy;
   126 
   127     fun err msg = cat_error msg
   128       ("The error(s) above occurred for the goal statement:\n" ^
   129         string_of_term (Logic.list_implies (asms, Logic.mk_conjunction_list props)));
   130 
   131     fun cert_safe t = Thm.cterm_of thy (Envir.beta_norm (Term.no_dummy_patterns t))
   132       handle TERM (msg, _) => err msg | TYPE (msg, _, _) => err msg;
   133     val casms = map cert_safe asms;
   134     val cprops = map cert_safe props;
   135 
   136     val (prems, ctxt') = ctxt
   137       |> Variable.add_fixes_direct xs
   138       |> fold Variable.declare_internal (asms @ props)
   139       |> Assumption.add_assumes casms;
   140 
   141     val goal = init (Conjunction.mk_conjunction_list cprops);
   142     val res =
   143       (case SINGLE (tac {prems = prems, context = ctxt'}) goal of
   144         NONE => err "Tactic failed."
   145       | SOME res => res);
   146     val [results] = Conjunction.elim_precise [length props] (finish res)
   147       handle THM (msg, _, _) => err msg;
   148     val _ = Unify.matches_list thy (map Thm.term_of cprops) (map Thm.prop_of results)
   149       orelse err ("Proved a different theorem: " ^ string_of_term (Thm.prop_of res));
   150   in
   151     results
   152     |> map (Assumption.export false ctxt' ctxt)
   153     |> Variable.export ctxt' ctxt
   154     |> map Drule.zero_var_indexes
   155   end;
   156 
   157 
   158 (* prove *)
   159 
   160 fun prove ctxt xs asms prop tac = hd (prove_multi ctxt xs asms [prop] tac);
   161 
   162 fun prove_global thy xs asms prop tac =
   163   Drule.standard (prove (ProofContext.init thy) xs asms prop (fn {prems, ...} => tac prems));
   164 
   165 
   166 
   167 (** local goal states **)
   168 
   169 fun extract i n st =
   170   (if i < 1 orelse n < 1 orelse i + n - 1 > Thm.nprems_of st then Seq.empty
   171    else if n = 1 then Seq.single (Thm.cprem_of st i)
   172    else Seq.single (foldr1 Conjunction.mk_conjunction (map (Thm.cprem_of st) (i upto i + n - 1))))
   173   |> Seq.map (Thm.adjust_maxidx_cterm ~1 #> init);
   174 
   175 fun retrofit i n st' st =
   176   (if n = 1 then st
   177    else st |> Drule.rotate_prems (i - 1) |> Conjunction.uncurry n |> Drule.rotate_prems (1 - i))
   178   |> Thm.compose_no_flatten false (conclude st', Thm.nprems_of st') i;
   179 
   180 fun SELECT_GOAL tac i st =
   181   if Thm.nprems_of st = 1 andalso i = 1 then tac st
   182   else Seq.lifts (retrofit i 1) (Seq.maps tac (extract i 1 st)) st;
   183 
   184 end;
   185 
   186 structure BasicGoal: BASIC_GOAL = Goal;
   187 open BasicGoal;