src/Pure/library.ML
author wenzelm
Mon Nov 18 17:28:19 1996 +0100 (1996-11-18)
changeset 2196 1b36ebc70487
parent 2182 29e56f003599
child 2243 3ebeaaacfbd1
permissions -rw-r--r--
added is_printable: string -> bool;
     1 (*  Title:      Pure/library.ML
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     4     Copyright   1992  University of Cambridge
     5 
     6 Basic library: functions, options, pairs, booleans, lists, integers,
     7 strings, lists as sets, association lists, generic tables, balanced trees,
     8 input / output, timing, filenames, misc functions.
     9 *)
    10 
    11 infix |> ~~ \ \\ orelf ins ins_string ins_int orf andf prefix upto downto
    12       mem mem_int mem_string union union_int union_string  
    13       inter inter_int inter_string subset subset_int subset_string subdir_of;
    14 
    15 
    16 structure Library =
    17 struct
    18 
    19 (** functions **)
    20 
    21 (*handy combinators*)
    22 fun curry f x y = f (x, y);
    23 fun uncurry f (x, y) = f x y;
    24 fun I x = x;
    25 fun K x y = x;
    26 
    27 (*reverse apply*)
    28 fun (x |> f) = f x;
    29 
    30 (*combine two functions forming the union of their domains*)
    31 fun (f orelf g) = fn x => f x handle Match => g x;
    32 
    33 (*application of (infix) operator to its left or right argument*)
    34 fun apl (x, f) y = f (x, y);
    35 fun apr (f, y) x = f (x, y);
    36 
    37 (*functional for pairs*)
    38 fun pairself f (x, y) = (f x, f y);
    39 
    40 (*function exponentiation: f(...(f x)...) with n applications of f*)
    41 fun funpow n f x =
    42   let fun rep (0, x) = x
    43         | rep (n, x) = rep (n - 1, f x)
    44   in rep (n, x) end;
    45 
    46 
    47 
    48 (** options **)
    49 
    50 datatype 'a option = None | Some of 'a;
    51 
    52 exception OPTION of string;
    53 
    54 fun the (Some x) = x
    55   | the None = raise OPTION "the";
    56 
    57 fun if_none None y = y
    58   | if_none (Some x) _ = x;
    59 
    60 fun is_some (Some _) = true
    61   | is_some None = false;
    62 
    63 fun is_none (Some _) = false
    64   | is_none None = true;
    65 
    66 fun apsome f (Some x) = Some (f x)
    67   | apsome _ None = None;
    68 
    69 
    70 
    71 (** pairs **)
    72 
    73 fun pair x y = (x, y);
    74 fun rpair x y = (y, x);
    75 
    76 fun fst (x, y) = x;
    77 fun snd (x, y) = y;
    78 
    79 fun eq_fst ((x1, _), (x2, _)) = x1 = x2;
    80 fun eq_snd ((_, y1), (_, y2)) = y1 = y2;
    81 
    82 fun swap (x, y) = (y, x);
    83 
    84 (*apply the function to a component of a pair*)
    85 fun apfst f (x, y) = (f x, y);
    86 fun apsnd f (x, y) = (x, f y);
    87 
    88 
    89 
    90 (** booleans **)
    91 
    92 (* equality *)
    93 
    94 fun equal x y = x = y;
    95 fun not_equal x y = x <> y;
    96 
    97 
    98 (* operators for combining predicates *)
    99 
   100 fun (p orf q) = fn x => p x orelse q x;
   101 
   102 fun (p andf q) = fn x => p x andalso q x;
   103 
   104 fun notf p x = not (p x);
   105 
   106 
   107 (* predicates on lists *)
   108 
   109 fun orl [] = false
   110   | orl (x :: xs) = x orelse orl xs;
   111 
   112 fun andl [] = true
   113   | andl (x :: xs) = x andalso andl xs;
   114 
   115 (*exists pred [x1, ..., xn] ===> pred x1 orelse ... orelse pred xn*)
   116 fun exists (pred: 'a -> bool) : 'a list -> bool =
   117   let fun boolf [] = false
   118         | boolf (x :: xs) = pred x orelse boolf xs
   119   in boolf end;
   120 
   121 (*forall pred [x1, ..., xn] ===> pred x1 andalso ... andalso pred xn*)
   122 fun forall (pred: 'a -> bool) : 'a list -> bool =
   123   let fun boolf [] = true
   124         | boolf (x :: xs) = pred x andalso boolf xs
   125   in boolf end;
   126 
   127 
   128 (* flags *)
   129 
   130 fun set flag = (flag := true; true);
   131 fun reset flag = (flag := false; false);
   132 fun toggle flag = (flag := not (! flag); ! flag);
   133 
   134 
   135 
   136 (** lists **)
   137 
   138 exception LIST of string;
   139 
   140 fun null [] = true
   141   | null (_ :: _) = false;
   142 
   143 fun hd [] = raise LIST "hd"
   144   | hd (x :: _) = x;
   145 
   146 fun tl [] = raise LIST "tl"
   147   | tl (_ :: xs) = xs;
   148 
   149 fun cons x xs = x :: xs;
   150 
   151 
   152 (* fold *)
   153 
   154 (*the following versions of fold are designed to fit nicely with infixes*)
   155 
   156 (*  (op @) (e, [x1, ..., xn])  ===>  ((e @ x1) @ x2) ... @ xn
   157     for operators that associate to the left (TAIL RECURSIVE)*)
   158 fun foldl (f: 'a * 'b -> 'a) : 'a * 'b list -> 'a =
   159   let fun itl (e, [])  = e
   160         | itl (e, a::l) = itl (f(e, a), l)
   161   in  itl end;
   162 
   163 (*  (op @) ([x1, ..., xn], e)  ===>   x1 @ (x2 ... @ (xn @ e))
   164     for operators that associate to the right (not tail recursive)*)
   165 fun foldr f (l, e) =
   166   let fun itr [] = e
   167         | itr (a::l) = f(a, itr l)
   168   in  itr l  end;
   169 
   170 (*  (op @) [x1, ..., xn]  ===>   x1 @ (x2 ... @ (x[n-1] @ xn))
   171     for n > 0, operators that associate to the right (not tail recursive)*)
   172 fun foldr1 f l =
   173   let fun itr [x] = x                       (* FIXME [] case: elim warn (?) *)
   174         | itr (x::l) = f(x, itr l)
   175   in  itr l  end;
   176 
   177 
   178 (* basic list functions *)
   179 
   180 (*length of a list, should unquestionably be a standard function*)
   181 local fun length1 (n, [])  = n   (*TAIL RECURSIVE*)
   182         | length1 (n, x :: xs) = length1 (n + 1, xs)
   183 in  fun length l = length1 (0, l) end;
   184 
   185 (*take the first n elements from a list*)
   186 fun take (n, []) = []
   187   | take (n, x :: xs) =
   188       if n > 0 then x :: take (n - 1, xs) else [];
   189 
   190 (*drop the first n elements from a list*)
   191 fun drop (n, []) = []
   192   | drop (n, x :: xs) =
   193       if n > 0 then drop (n - 1, xs) else x :: xs;
   194 
   195 (*return nth element of a list, where 0 designates the first element;
   196   raise EXCEPTION if list too short*)
   197 fun nth_elem NL =
   198   (case drop NL of
   199     [] => raise LIST "nth_elem"
   200   | x :: _ => x);
   201 
   202 (*last element of a list*)
   203 fun last_elem [] = raise LIST "last_elem"
   204   | last_elem [x] = x
   205   | last_elem (_ :: xs) = last_elem xs;
   206 
   207 (*find the position of an element in a list*)
   208 fun find (x, ys) =
   209   let fun f (y :: ys, i) = if x = y then i else f (ys, i + 1)
   210         | f (_, _) = raise LIST "find"
   211   in f (ys, 0) end;
   212 
   213 (*flatten a list of lists to a list*)
   214 fun flat (ls: 'c list list) : 'c list = foldr (op @) (ls, []);
   215 
   216 
   217 (*like Lisp's MAPC -- seq proc [x1, ..., xn] evaluates
   218   (proc x1; ...; proc xn) for side effects*)
   219 fun seq (proc: 'a -> unit) : 'a list -> unit =
   220   let fun seqf [] = ()
   221         | seqf (x :: xs) = (proc x; seqf xs)
   222   in seqf end;
   223 
   224 
   225 (*separate s [x1, x2, ..., xn]  ===>  [x1, s, x2, s, ..., s, xn]*)
   226 fun separate s (x :: (xs as _ :: _)) = x :: s :: separate s xs
   227   | separate _ xs = xs;
   228 
   229 (*make the list [x, x, ..., x] of length n*)
   230 fun replicate n (x: 'a) : 'a list =
   231   let fun rep (0, xs) = xs
   232         | rep (n, xs) = rep (n - 1, x :: xs)
   233   in
   234     if n < 0 then raise LIST "replicate"
   235     else rep (n, [])
   236   end;
   237 
   238 
   239 (* filter *)
   240 
   241 (*copy the list preserving elements that satisfy the predicate*)
   242 fun filter (pred: 'a->bool) : 'a list -> 'a list =
   243   let fun filt [] = []
   244         | filt (x :: xs) = if pred x then x :: filt xs else filt xs
   245   in filt end;
   246 
   247 fun filter_out f = filter (not o f);
   248 
   249 
   250 fun mapfilter (f: 'a -> 'b option) ([]: 'a list) = [] : 'b list
   251   | mapfilter f (x :: xs) =
   252       (case f x of
   253         None => mapfilter f xs
   254       | Some y => y :: mapfilter f xs);
   255 
   256 
   257 fun find_first _ [] = None
   258   | find_first pred (x :: xs) =
   259       if pred x then Some x else find_first pred xs;
   260 
   261 
   262 (* lists of pairs *)
   263 
   264 fun map2 _ ([], []) = []
   265   | map2 f (x :: xs, y :: ys) = (f (x, y) :: map2 f (xs, ys))
   266   | map2 _ _ = raise LIST "map2";
   267 
   268 fun exists2 _ ([], []) = false
   269   | exists2 pred (x :: xs, y :: ys) = pred (x, y) orelse exists2 pred (xs, ys)
   270   | exists2 _ _ = raise LIST "exists2";
   271 
   272 fun forall2 _ ([], []) = true
   273   | forall2 pred (x :: xs, y :: ys) = pred (x, y) andalso forall2 pred (xs, ys)
   274   | forall2 _ _ = raise LIST "forall2";
   275 
   276 (*combine two lists forming a list of pairs:
   277   [x1, ..., xn] ~~ [y1, ..., yn]  ===>  [(x1, y1), ..., (xn, yn)]*)
   278 fun [] ~~ [] = []
   279   | (x :: xs) ~~ (y :: ys) = (x, y) :: (xs ~~ ys)
   280   | _ ~~ _ = raise LIST "~~";
   281 
   282 
   283 (*inverse of ~~; the old 'split':
   284   [(x1, y1), ..., (xn, yn)]  ===>  ([x1, ..., xn], [y1, ..., yn])*)
   285 fun split_list (l: ('a * 'b) list) = (map #1 l, map #2 l);
   286 
   287 
   288 (* prefixes, suffixes *)
   289 
   290 fun [] prefix _ = true
   291   | (x :: xs) prefix (y :: ys) = x = y andalso (xs prefix ys)
   292   | _ prefix _ = false;
   293 
   294 (* [x1, ..., xi, ..., xn]  --->  ([x1, ..., x(i-1)], [xi, ..., xn])
   295    where xi is the first element that does not satisfy the predicate*)
   296 fun take_prefix (pred : 'a -> bool)  (xs: 'a list) : 'a list * 'a list =
   297   let fun take (rxs, []) = (rev rxs, [])
   298         | take (rxs, x :: xs) =
   299             if  pred x  then  take(x :: rxs, xs)  else  (rev rxs, x :: xs)
   300   in  take([], xs)  end;
   301 
   302 (* [x1, ..., xi, ..., xn]  --->  ([x1, ..., xi], [x(i+1), ..., xn])
   303    where xi is the last element that does not satisfy the predicate*)
   304 fun take_suffix _ [] = ([], [])
   305   | take_suffix pred (x :: xs) =
   306       (case take_suffix pred xs of
   307         ([], sffx) => if pred x then ([], x :: sffx) else ([x], sffx)
   308       | (prfx, sffx) => (x :: prfx, sffx));
   309 
   310 
   311 
   312 (** integers **)
   313 
   314 fun inc i = i := ! i + 1;
   315 fun dec i = i := ! i - 1;
   316 
   317 
   318 (* lists of integers *)
   319 
   320 (*make the list [from, from + 1, ..., to]*)
   321 fun (from upto to) =
   322   if from > to then [] else from :: ((from + 1) upto to);
   323 
   324 (*make the list [from, from - 1, ..., to]*)
   325 fun (from downto to) =
   326   if from < to then [] else from :: ((from - 1) downto to);
   327 
   328 (*predicate: downto0 (is, n) <=> is = [n, n - 1, ..., 0]*)
   329 fun downto0 (i :: is, n) = i = n andalso downto0 (is, n - 1)
   330   | downto0 ([], n) = n = ~1;
   331 
   332 
   333 (* convert integers to strings *)
   334 
   335 (*expand the number in the given base;
   336   example: radixpand (2, 8) gives [1, 0, 0, 0]*)
   337 fun radixpand (base, num) : int list =
   338   let
   339     fun radix (n, tail) =
   340       if n < base then n :: tail
   341       else radix (n div base, (n mod base) :: tail)
   342   in radix (num, []) end;
   343 
   344 (*expands a number into a string of characters starting from "zerochar";
   345   example: radixstring (2, "0", 8) gives "1000"*)
   346 fun radixstring (base, zerochar, num) =
   347   let val offset = ord zerochar;
   348       fun chrof n = chr (offset + n)
   349   in implode (map chrof (radixpand (base, num))) end;
   350 
   351 
   352 fun string_of_int n =
   353   if n < 0 then "~" ^ radixstring (10, "0", ~n) else radixstring (10, "0", n);
   354 
   355 
   356 
   357 (** strings **)
   358 
   359 fun is_letter ch =
   360   ord "A" <= ord ch andalso ord ch <= ord "Z" orelse
   361   ord "a" <= ord ch andalso ord ch <= ord "z";
   362 
   363 fun is_digit ch =
   364   ord "0" <= ord ch andalso ord ch <= ord "9";
   365 
   366 (*letter or _ or prime (')*)
   367 fun is_quasi_letter "_" = true
   368   | is_quasi_letter "'" = true
   369   | is_quasi_letter ch = is_letter ch;
   370 
   371 (*white space: blanks, tabs, newlines, formfeeds*)
   372 val is_blank : string -> bool =
   373   fn " " => true | "\t" => true | "\n" => true | "\^L" => true | _ => false;
   374 
   375 val is_letdig = is_quasi_letter orf is_digit;
   376 
   377 (*printable chars*)
   378 fun is_printable c = ord c > ord " " andalso ord c <= ord "~";
   379 
   380 
   381 (*lower all chars of string*)
   382 val to_lower =
   383   let
   384     fun lower ch =
   385       if ch >= "A" andalso ch <= "Z" then
   386         chr (ord ch - ord "A" + ord "a")
   387       else ch;
   388   in implode o (map lower) o explode end;
   389 
   390 
   391 (*enclose in brackets*)
   392 fun enclose lpar rpar str = lpar ^ str ^ rpar;
   393 
   394 (*simple quoting (does not escape special chars)*)
   395 val quote = enclose "\"" "\"";
   396 
   397 (*space_implode "..." (explode "hello"); gives "h...e...l...l...o"*)
   398 fun space_implode a bs = implode (separate a bs);
   399 
   400 val commas = space_implode ", ";
   401 val commas_quote = commas o map quote;
   402 
   403 (*concatenate messages, one per line, into a string*)
   404 val cat_lines = space_implode "\n";
   405 
   406 (*space_explode "." "h.e..l.lo"; gives ["h", "e", "l", "lo"]*)
   407 fun space_explode sep s =
   408   let fun divide [] "" = []
   409         | divide [] part = [part]
   410         | divide (c::s) part =
   411             if c = sep then
   412               (if part = "" then divide s "" else part :: divide s "")
   413             else divide s (part ^ c)
   414   in divide (explode s) "" end;
   415 
   416 
   417 (** lists as sets **)
   418 
   419 (*membership in a list*)
   420 fun x mem [] = false
   421   | x mem (y :: ys) = x = y orelse x mem ys;
   422 
   423 (*membership in a list, optimized version for ints*)
   424 fun (x:int) mem_int [] = false
   425   | x mem_int (y :: ys) = x = y orelse x mem_int ys;
   426 
   427 (*membership in a list, optimized version for strings*)
   428 fun (x:string) mem_string [] = false
   429   | x mem_string (y :: ys) = x = y orelse x mem_string ys;
   430 
   431 (*generalized membership test*)
   432 fun gen_mem eq (x, []) = false
   433   | gen_mem eq (x, y :: ys) = eq (x, y) orelse gen_mem eq (x, ys);
   434 
   435 
   436 (*insertion into list if not already there*)
   437 fun (x ins xs) = if x mem xs then xs else x :: xs;
   438 
   439 (*insertion into list, optimized version for ints*)
   440 fun (x ins_int xs) = if x mem_int xs then xs else x :: xs;
   441 
   442 (*insertion into list, optimized version for strings*)
   443 fun (x ins_string xs) = if x mem_string xs then xs else x :: xs;
   444 
   445 (*generalized insertion*)
   446 fun gen_ins eq (x, xs) = if gen_mem eq (x, xs) then xs else x :: xs;
   447 
   448 
   449 (*union of sets represented as lists: no repetitions*)
   450 fun xs union [] = xs
   451   | [] union ys = ys
   452   | (x :: xs) union ys = xs union (x ins ys);
   453 
   454 (*union of sets, optimized version for ints*)
   455 fun (xs:int list) union_int [] = xs
   456   | [] union_int ys = ys
   457   | (x :: xs) union_int ys = xs union_int (x ins_int ys);
   458 
   459 (*union of sets, optimized version for strings*)
   460 fun (xs:string list) union_string [] = xs
   461   | [] union_string ys = ys
   462   | (x :: xs) union_string ys = xs union_string (x ins_string ys);
   463 
   464 (*generalized union*)
   465 fun gen_union eq (xs, []) = xs
   466   | gen_union eq ([], ys) = ys
   467   | gen_union eq (x :: xs, ys) = gen_union eq (xs, gen_ins eq (x, ys));
   468 
   469 
   470 (*intersection*)
   471 fun [] inter ys = []
   472   | (x :: xs) inter ys =
   473       if x mem ys then x :: (xs inter ys) else xs inter ys;
   474 
   475 (*intersection, optimized version for ints*)
   476 fun ([]:int list) inter_int ys = []
   477   | (x :: xs) inter_int ys =
   478       if x mem_int ys then x :: (xs inter_int ys) else xs inter_int ys;
   479 
   480 (*intersection, optimized version for strings *)
   481 fun ([]:string list) inter_string ys = []
   482   | (x :: xs) inter_string ys =
   483       if x mem_string ys then x :: (xs inter_string ys) else xs inter_string ys;
   484 
   485 
   486 (*subset*)
   487 fun [] subset ys = true
   488   | (x :: xs) subset ys = x mem ys andalso xs subset ys;
   489 
   490 (*subset, optimized version for ints*)
   491 fun ([]:int list) subset_int ys = true
   492   | (x :: xs) subset_int ys = x mem_int ys andalso xs subset_int ys;
   493 
   494 (*subset, optimized version for strings*)
   495 fun ([]:string list) subset_string ys = true
   496   | (x :: xs) subset_string ys = x mem_string ys andalso xs subset_string ys;
   497 
   498 (*set equality for strings*)
   499 fun eq_set_string ((xs:string list), ys) =
   500   xs = ys orelse (xs subset_string ys andalso ys subset_string xs);
   501 
   502 fun gen_subset eq (xs, ys) = forall (fn x => gen_mem eq (x, ys)) xs;
   503 
   504 
   505 (*removing an element from a list WITHOUT duplicates*)
   506 fun (y :: ys) \ x = if x = y then ys else y :: (ys \ x)
   507   | [] \ x = [];
   508 
   509 val op \\ = foldl (op \);
   510 
   511 (*removing an element from a list -- possibly WITH duplicates*)
   512 fun gen_rem eq (xs, y) = filter_out (fn x => eq (x, y)) xs;
   513 
   514 val gen_rems = foldl o gen_rem;
   515 
   516 
   517 (*makes a list of the distinct members of the input; preserves order, takes
   518   first of equal elements*)
   519 fun gen_distinct eq lst =
   520   let
   521     val memb = gen_mem eq;
   522 
   523     fun dist (rev_seen, []) = rev rev_seen
   524       | dist (rev_seen, x :: xs) =
   525           if memb (x, rev_seen) then dist (rev_seen, xs)
   526           else dist (x :: rev_seen, xs);
   527   in
   528     dist ([], lst)
   529   end;
   530 
   531 val distinct = gen_distinct (op =);
   532 
   533 
   534 (*returns the tail beginning with the first repeated element, or []*)
   535 fun findrep [] = []
   536   | findrep (x :: xs) = if x mem xs then x :: xs else findrep xs;
   537 
   538 
   539 (*returns a list containing all repeated elements exactly once; preserves
   540   order, takes first of equal elements*)
   541 fun gen_duplicates eq lst =
   542   let
   543     val memb = gen_mem eq;
   544 
   545     fun dups (rev_dups, []) = rev rev_dups
   546       | dups (rev_dups, x :: xs) =
   547           if memb (x, rev_dups) orelse not (memb (x, xs)) then
   548             dups (rev_dups, xs)
   549           else dups (x :: rev_dups, xs);
   550   in
   551     dups ([], lst)
   552   end;
   553 
   554 val duplicates = gen_duplicates (op =);
   555 
   556 
   557 
   558 (** association lists **)
   559 
   560 (*association list lookup*)
   561 fun assoc ([], key) = None
   562   | assoc ((keyi, xi) :: pairs, key) =
   563       if key = keyi then Some xi else assoc (pairs, key);
   564 
   565 (*association list lookup, optimized version for ints*)
   566 fun assoc_int ([], (key:int)) = None
   567   | assoc_int ((keyi, xi) :: pairs, key) =
   568       if key = keyi then Some xi else assoc_int (pairs, key);
   569 
   570 (*association list lookup, optimized version for strings*)
   571 fun assoc_string ([], (key:string)) = None
   572   | assoc_string ((keyi, xi) :: pairs, key) =
   573       if key = keyi then Some xi else assoc_string (pairs, key);
   574 
   575 (*association list lookup, optimized version for string*ints*)
   576 fun assoc_string_int ([], (key:string*int)) = None
   577   | assoc_string_int ((keyi, xi) :: pairs, key) =
   578       if key = keyi then Some xi else assoc_string_int (pairs, key);
   579 
   580 fun assocs ps x =
   581   (case assoc (ps, x) of
   582     None => []
   583   | Some ys => ys);
   584 
   585 (*two-fold association list lookup*)
   586 fun assoc2 (aal, (key1, key2)) =
   587   (case assoc (aal, key1) of
   588     Some al => assoc (al, key2)
   589   | None => None);
   590 
   591 (*generalized association list lookup*)
   592 fun gen_assoc eq ([], key) = None
   593   | gen_assoc eq ((keyi, xi) :: pairs, key) =
   594       if eq (key, keyi) then Some xi else gen_assoc eq (pairs, key);
   595 
   596 (*association list update*)
   597 fun overwrite (al, p as (key, _)) =
   598   let fun over ((q as (keyi, _)) :: pairs) =
   599             if keyi = key then p :: pairs else q :: (over pairs)
   600         | over [] = [p]
   601   in over al end;
   602 
   603 
   604 
   605 (** generic tables **)
   606 
   607 (*Tables are supposed to be 'efficient' encodings of lists of elements distinct
   608   wrt. an equality "eq". The extend and merge operations below are optimized
   609   for long-term space efficiency.*)
   610 
   611 (*append (new) elements to a table*)
   612 fun generic_extend _ _ _ tab [] = tab
   613   | generic_extend eq dest_tab mk_tab tab1 lst2 =
   614       let
   615         val lst1 = dest_tab tab1;
   616         val new_lst2 = gen_rems eq (lst2, lst1);
   617       in
   618         if null new_lst2 then tab1
   619         else mk_tab (lst1 @ new_lst2)
   620       end;
   621 
   622 (*append (new) elements of 2nd table to 1st table*)
   623 fun generic_merge eq dest_tab mk_tab tab1 tab2 =
   624   let
   625     val lst1 = dest_tab tab1;
   626     val lst2 = dest_tab tab2;
   627     val new_lst2 = gen_rems eq (lst2, lst1);
   628   in
   629     if null new_lst2 then tab1
   630     else if gen_subset eq (lst1, lst2) then tab2
   631     else mk_tab (lst1 @ new_lst2)
   632   end;
   633 
   634 
   635 (*lists as tables*)
   636 val extend_list = generic_extend (op =) I I;
   637 val merge_lists = generic_merge (op =) I I;
   638 
   639 fun merge_rev_lists xs [] = xs
   640   | merge_rev_lists [] ys = ys
   641   | merge_rev_lists xs (y :: ys) =
   642       (if y mem xs then I else cons y) (merge_rev_lists xs ys);
   643 
   644 
   645 
   646 (** balanced trees **)
   647 
   648 exception Balance;      (*indicates non-positive argument to balancing fun*)
   649 
   650 (*balanced folding; avoids deep nesting*)
   651 fun fold_bal f [x] = x
   652   | fold_bal f [] = raise Balance
   653   | fold_bal f xs =
   654       let val k = length xs div 2
   655       in  f (fold_bal f (take(k, xs)),
   656              fold_bal f (drop(k, xs)))
   657       end;
   658 
   659 (*construct something of the form f(...g(...(x)...)) for balanced access*)
   660 fun access_bal (f, g, x) n i =
   661   let fun acc n i =     (*1<=i<=n*)
   662           if n=1 then x else
   663           let val n2 = n div 2
   664           in  if i<=n2 then f (acc n2 i)
   665                        else g (acc (n-n2) (i-n2))
   666           end
   667   in  if 1<=i andalso i<=n then acc n i else raise Balance  end;
   668 
   669 (*construct ALL such accesses; could try harder to share recursive calls!*)
   670 fun accesses_bal (f, g, x) n =
   671   let fun acc n =
   672           if n=1 then [x] else
   673           let val n2 = n div 2
   674               val acc2 = acc n2
   675           in  if n-n2=n2 then map f acc2 @ map g acc2
   676                          else map f acc2 @ map g (acc (n-n2)) end
   677   in  if 1<=n then acc n else raise Balance  end;
   678 
   679 
   680 
   681 (** input / output **)
   682 
   683 val prs_fn = ref(fn s => output (std_out, s));
   684 
   685 fun prs s = !prs_fn s;
   686 fun writeln s = prs (s ^ "\n");
   687 
   688 (* output to LaTeX / xdvi *)
   689 fun latex s = 
   690 	execute ( "( cd /tmp ; echo \"" ^ s ^
   691 	"\" | isa2latex -s > $$.tex ; latex $$.tex ; xdvi $$.dvi ; rm $$.* ) > /dev/null &" ) ;
   692 
   693 (*print warning*)
   694 val warning_fn = ref(fn s => output (std_out, s ^ "\n"));
   695 fun warning s = !warning_fn ("Warning: " ^ s);
   696 
   697 (*print error message and abort to top level*)
   698 
   699 val error_fn = ref(fn s => output (std_out, s ^ "\n"));
   700 
   701 exception ERROR;
   702 fun error msg = (!error_fn msg; raise ERROR);
   703 fun sys_error msg = (!error_fn "*** SYSTEM ERROR ***"; error msg);
   704 
   705 fun assert p msg = if p then () else error msg;
   706 fun deny p msg = if p then error msg else ();
   707 
   708 (*Assert pred for every member of l, generating a message if pred fails*)
   709 fun assert_all pred l msg_fn = 
   710   let fun asl [] = ()
   711 	| asl (x::xs) = if pred x then asl xs
   712 	                else error (msg_fn x)
   713   in  asl l  end;
   714 
   715 (*for the "test" target in Makefiles -- signifies successful termination*)
   716 fun maketest msg =
   717   (writeln msg; 
   718    let val os = open_out "test" 
   719    in  output (os, "Test examples ran successfully\n");
   720        close_out os
   721    end);
   722 
   723 
   724 (*print a list surrounded by the brackets lpar and rpar, with comma separator
   725   print nothing for empty list*)
   726 fun print_list (lpar, rpar, pre: 'a -> unit) (l : 'a list) =
   727   let fun prec x = (prs ","; pre x)
   728   in
   729     (case l of
   730       [] => ()
   731     | x::l => (prs lpar; pre x; seq prec l; prs rpar))
   732   end;
   733 
   734 (*print a list of items separated by newlines*)
   735 fun print_list_ln (pre: 'a -> unit) : 'a list -> unit =
   736   seq (fn x => (pre x; writeln ""));
   737 
   738 
   739 val print_int = prs o string_of_int;
   740 
   741 
   742 
   743 (** timing **)
   744 
   745 (*unconditional timing function*)
   746 val timeit = cond_timeit true;
   747 
   748 (*timed application function*)
   749 fun timeap f x = timeit (fn () => f x);
   750 
   751 (*timed "use" function, printing filenames*)
   752 fun time_use fname = timeit (fn () =>
   753   (writeln ("\n**** Starting " ^ fname ^ " ****"); use fname;
   754    writeln ("\n**** Finished " ^ fname ^ " ****")));
   755 
   756 (*For Makefiles: use the file, but exit with error code if errors found.*)
   757 fun exit_use fname = use fname handle _ => exit 1;
   758 
   759 
   760 (** filenames and paths **)
   761 
   762 (*Convert UNIX filename of the form "path/file" to "path/" and "file";
   763   if filename contains no slash, then it returns "" and "file"*)
   764 val split_filename =
   765   (pairself implode) o take_suffix (not_equal "/") o explode;
   766 
   767 val base_name = #2 o split_filename;
   768 
   769 (*Merge splitted filename (path and file);
   770   if path does not end with one a slash is appended*)
   771 fun tack_on "" name = name
   772   | tack_on path name =
   773       if last_elem (explode path) = "/" then path ^ name
   774       else path ^ "/" ^ name;
   775 
   776 (*Remove the extension of a filename, i.e. the part after the last '.'*)
   777 val remove_ext = implode o #1 o take_suffix (not_equal ".") o explode;
   778 
   779 (*Make relative path to reach an absolute location from a different one*)
   780 fun relative_path cur_path dest_path =
   781   let (*Remove common beginning of both paths and make relative path*)
   782       fun mk_relative [] [] = []
   783         | mk_relative [] ds = ds
   784         | mk_relative cs [] = map (fn _ => "..") cs
   785         | mk_relative (c::cs) (d::ds) =
   786             if c = d then mk_relative cs ds
   787             else ".." :: map (fn _ => "..") cs @ (d::ds);
   788   in if cur_path = "" orelse hd (explode cur_path) <> "/" orelse
   789         dest_path = "" orelse hd (explode dest_path) <> "/" then
   790        error "Relative or empty path passed to relative_path"
   791      else ();
   792      space_implode "/" (mk_relative (space_explode "/" cur_path)
   793                                     (space_explode "/" dest_path))
   794   end;
   795 
   796 (*Determine if absolute path1 is a subdirectory of absolute path2*)
   797 fun path1 subdir_of path2 =
   798   if hd (explode path1) <> "/" orelse hd (explode path2) <> "/" then
   799     error "Relative or empty path passed to subdir_of"
   800   else (space_explode "/" path2) prefix (space_explode "/" path1);
   801 
   802 fun absolute_path cwd file =
   803   let fun rm_points [] result = rev result
   804         | rm_points (".."::ds) result = rm_points ds (tl result)
   805         | rm_points ("."::ds) result = rm_points ds result
   806         | rm_points (d::ds) result = rm_points ds (d::result);
   807   in if file = "" then ""
   808      else if hd (explode file) = "/" then file
   809      else "/" ^ space_implode "/"
   810                   (rm_points (space_explode "/" (tack_on cwd file)) [])
   811   end;
   812 
   813 
   814 (** misc functions **)
   815 
   816 (*use the keyfun to make a list of (x, key) pairs*)
   817 fun make_keylist (keyfun: 'a->'b) : 'a list -> ('a * 'b) list =
   818   let fun keypair x = (x, keyfun x)
   819   in map keypair end;
   820 
   821 (*given a list of (x, key) pairs and a searchkey
   822   return the list of xs from each pair whose key equals searchkey*)
   823 fun keyfilter [] searchkey = []
   824   | keyfilter ((x, key) :: pairs) searchkey =
   825       if key = searchkey then x :: keyfilter pairs searchkey
   826       else keyfilter pairs searchkey;
   827 
   828 
   829 (*Partition list into elements that satisfy predicate and those that don't.
   830   Preserves order of elements in both lists.*)
   831 fun partition (pred: 'a->bool) (ys: 'a list) : ('a list * 'a list) =
   832     let fun part ([], answer) = answer
   833           | part (x::xs, (ys, ns)) = if pred(x)
   834             then  part (xs, (x::ys, ns))
   835             else  part (xs, (ys, x::ns))
   836     in  part (rev ys, ([], []))  end;
   837 
   838 
   839 fun partition_eq (eq:'a * 'a -> bool) =
   840     let fun part [] = []
   841           | part (x::ys) = let val (xs, xs') = partition (apl(x, eq)) ys
   842                            in (x::xs)::(part xs') end
   843     in part end;
   844 
   845 
   846 (*Partition a list into buckets  [ bi, b(i+1), ..., bj ]
   847    putting x in bk if p(k)(x) holds.  Preserve order of elements if possible.*)
   848 fun partition_list p i j =
   849   let fun part k xs =
   850             if k>j then
   851               (case xs of [] => []
   852                          | _ => raise LIST "partition_list")
   853             else
   854             let val (ns, rest) = partition (p k) xs;
   855             in  ns :: part(k+1)rest  end
   856   in  part i end;
   857 
   858 
   859 (* sorting *)
   860 
   861 (*insertion sort; stable (does not reorder equal elements)
   862   'less' is less-than test on type 'a*)
   863 fun sort (less: 'a*'a -> bool) =
   864   let fun insert (x, []) = [x]
   865         | insert (x, y::ys) =
   866               if less(y, x) then y :: insert (x, ys) else x::y::ys;
   867       fun sort1 [] = []
   868         | sort1 (x::xs) = insert (x, sort1 xs)
   869   in  sort1  end;
   870 
   871 (*sort strings*)
   872 val sort_strings = sort (op <= : string * string -> bool);
   873 
   874 
   875 (* transitive closure (not Warshall's algorithm) *)
   876 
   877 fun transitive_closure [] = []
   878   | transitive_closure ((x, ys)::ps) =
   879       let val qs = transitive_closure ps
   880           val zs = foldl (fn (zs, y) => assocs qs y union_string zs) (ys, ys)
   881           fun step(u, us) = (u, if x mem_string us then zs union_string us 
   882 				else us)
   883       in (x, zs) :: map step qs end;
   884 
   885 
   886 (** Recommended by Stephen K. Park and Keith W. Miller, 
   887       Random number generators: good ones are hard to find,
   888       CACM 31 (1988), 1192-1201. 
   889     Real number version for systems with 46-bit mantissae
   890     Computes  (a*seed) mod m ;  should be applied to integers only! **)
   891 local val a = 16807.0  and  m = 2147483647.0  (* 2^31 - 1 *)
   892 in  fun nextrandom seed =
   893           let val t = a*seed
   894           in  t - m * real(floor(t/m))  end
   895 end;
   896 
   897 (* generating identifiers *)
   898 
   899 local
   900   val a = ord "a" and z = ord "z" and A = ord "A" and Z = ord "Z"
   901   and k0 = ord "0" and k9 = ord "9"
   902 
   903   val seedr = ref 10000.0;
   904 in
   905 
   906 (*Maps 0-63 to A-Z, a-z, 0-9 or _ or ' for generating random identifiers*)
   907 fun newid n = 
   908   let fun char i =
   909                if i<26 then chr (A+i)
   910           else if i<52 then chr (a+i-26)
   911           else if i<62 then chr (k0+i-52)
   912           else if i=62 then "_"
   913           else  (*i=63*)    "'"
   914   in  implode (map char (radixpand (64,n)))  end;
   915 
   916 (*Randomly generated identifiers with given prefix; MUST start with a letter
   917     [division by two avoids overflow for ML systems whose maxint is 2^30 - 1 *)
   918 fun gensym pre = pre ^ 
   919                  (#1(newid (floor (!seedr/2.0)), 
   920 		     seedr := nextrandom (!seedr)))
   921 
   922 (*Increment a list of letters like a reversed base 26 number.
   923   If head is "z", bumps chars in tail.
   924   Digits are incremented as if they were integers.
   925   "_" and "'" are not changed.
   926   For making variants of identifiers.*)
   927 
   928 fun bump_int_list(c::cs) = if c="9" then "0" :: bump_int_list cs else
   929         if k0 <= ord(c) andalso ord(c) < k9 then chr(ord(c)+1) :: cs
   930         else "1" :: c :: cs
   931   | bump_int_list([]) = error("bump_int_list: not an identifier");
   932 
   933 fun bump_list([], d) = [d]
   934   | bump_list(["'"], d) = [d, "'"]
   935   | bump_list("z"::cs, _) = "a" :: bump_list(cs, "a")
   936   | bump_list("Z"::cs, _) = "A" :: bump_list(cs, "A")
   937   | bump_list("9"::cs, _) = "0" :: bump_int_list cs
   938   | bump_list(c::cs, _) = let val k = ord(c)
   939         in if (a <= k andalso k < z) orelse (A <= k andalso k < Z) orelse
   940               (k0 <= k andalso k < k9) then chr(k+1) :: cs else
   941            if c="'" orelse c="_" then c :: bump_list(cs, "") else
   942                 error("bump_list: not legal in identifier: " ^
   943                         implode(rev(c::cs)))
   944         end;
   945 
   946 end;
   947 
   948 fun bump_string s : string = implode (rev (bump_list(rev(explode s), "")));
   949 
   950 
   951 (* lexical scanning *)
   952 
   953 (*scan a list of characters into "words" composed of "letters" (recognized by
   954   is_let) and separated by any number of non-"letters"*)
   955 fun scanwords is_let cs =
   956   let fun scan1 [] = []
   957         | scan1 cs =
   958             let val (lets, rest) = take_prefix is_let cs
   959             in implode lets :: scanwords is_let rest end;
   960   in scan1 (#2 (take_prefix (not o is_let) cs)) end;
   961 
   962 end;
   963 
   964 (*Variable-branching trees: for proof terms*)
   965 datatype 'a mtree = Join of 'a * 'a mtree list;
   966 
   967 open Library;