src/HOL/Library/Product_Vector.thy
author blanchet
Wed Sep 24 15:45:55 2014 +0200 (2014-09-24)
changeset 58425 246985c6b20b
parent 56541 0e3abadbef39
child 58881 b9556a055632
permissions -rw-r--r--
simpler proof
     1 (*  Title:      HOL/Library/Product_Vector.thy
     2     Author:     Brian Huffman
     3 *)
     4 
     5 header {* Cartesian Products as Vector Spaces *}
     6 
     7 theory Product_Vector
     8 imports Inner_Product Product_plus
     9 begin
    10 
    11 subsection {* Product is a real vector space *}
    12 
    13 instantiation prod :: (real_vector, real_vector) real_vector
    14 begin
    15 
    16 definition scaleR_prod_def:
    17   "scaleR r A = (scaleR r (fst A), scaleR r (snd A))"
    18 
    19 lemma fst_scaleR [simp]: "fst (scaleR r A) = scaleR r (fst A)"
    20   unfolding scaleR_prod_def by simp
    21 
    22 lemma snd_scaleR [simp]: "snd (scaleR r A) = scaleR r (snd A)"
    23   unfolding scaleR_prod_def by simp
    24 
    25 lemma scaleR_Pair [simp]: "scaleR r (a, b) = (scaleR r a, scaleR r b)"
    26   unfolding scaleR_prod_def by simp
    27 
    28 instance proof
    29   fix a b :: real and x y :: "'a \<times> 'b"
    30   show "scaleR a (x + y) = scaleR a x + scaleR a y"
    31     by (simp add: prod_eq_iff scaleR_right_distrib)
    32   show "scaleR (a + b) x = scaleR a x + scaleR b x"
    33     by (simp add: prod_eq_iff scaleR_left_distrib)
    34   show "scaleR a (scaleR b x) = scaleR (a * b) x"
    35     by (simp add: prod_eq_iff)
    36   show "scaleR 1 x = x"
    37     by (simp add: prod_eq_iff)
    38 qed
    39 
    40 end
    41 
    42 subsection {* Product is a topological space *}
    43 
    44 instantiation prod :: (topological_space, topological_space) topological_space
    45 begin
    46 
    47 definition open_prod_def[code del]:
    48   "open (S :: ('a \<times> 'b) set) \<longleftrightarrow>
    49     (\<forall>x\<in>S. \<exists>A B. open A \<and> open B \<and> x \<in> A \<times> B \<and> A \<times> B \<subseteq> S)"
    50 
    51 lemma open_prod_elim:
    52   assumes "open S" and "x \<in> S"
    53   obtains A B where "open A" and "open B" and "x \<in> A \<times> B" and "A \<times> B \<subseteq> S"
    54 using assms unfolding open_prod_def by fast
    55 
    56 lemma open_prod_intro:
    57   assumes "\<And>x. x \<in> S \<Longrightarrow> \<exists>A B. open A \<and> open B \<and> x \<in> A \<times> B \<and> A \<times> B \<subseteq> S"
    58   shows "open S"
    59 using assms unfolding open_prod_def by fast
    60 
    61 instance proof
    62   show "open (UNIV :: ('a \<times> 'b) set)"
    63     unfolding open_prod_def by auto
    64 next
    65   fix S T :: "('a \<times> 'b) set"
    66   assume "open S" "open T"
    67   show "open (S \<inter> T)"
    68   proof (rule open_prod_intro)
    69     fix x assume x: "x \<in> S \<inter> T"
    70     from x have "x \<in> S" by simp
    71     obtain Sa Sb where A: "open Sa" "open Sb" "x \<in> Sa \<times> Sb" "Sa \<times> Sb \<subseteq> S"
    72       using `open S` and `x \<in> S` by (rule open_prod_elim)
    73     from x have "x \<in> T" by simp
    74     obtain Ta Tb where B: "open Ta" "open Tb" "x \<in> Ta \<times> Tb" "Ta \<times> Tb \<subseteq> T"
    75       using `open T` and `x \<in> T` by (rule open_prod_elim)
    76     let ?A = "Sa \<inter> Ta" and ?B = "Sb \<inter> Tb"
    77     have "open ?A \<and> open ?B \<and> x \<in> ?A \<times> ?B \<and> ?A \<times> ?B \<subseteq> S \<inter> T"
    78       using A B by (auto simp add: open_Int)
    79     thus "\<exists>A B. open A \<and> open B \<and> x \<in> A \<times> B \<and> A \<times> B \<subseteq> S \<inter> T"
    80       by fast
    81   qed
    82 next
    83   fix K :: "('a \<times> 'b) set set"
    84   assume "\<forall>S\<in>K. open S" thus "open (\<Union>K)"
    85     unfolding open_prod_def by fast
    86 qed
    87 
    88 end
    89 
    90 declare [[code abort: "open::('a::topological_space*'b::topological_space) set \<Rightarrow> bool"]]
    91 
    92 lemma open_Times: "open S \<Longrightarrow> open T \<Longrightarrow> open (S \<times> T)"
    93 unfolding open_prod_def by auto
    94 
    95 lemma fst_vimage_eq_Times: "fst -` S = S \<times> UNIV"
    96 by auto
    97 
    98 lemma snd_vimage_eq_Times: "snd -` S = UNIV \<times> S"
    99 by auto
   100 
   101 lemma open_vimage_fst: "open S \<Longrightarrow> open (fst -` S)"
   102 by (simp add: fst_vimage_eq_Times open_Times)
   103 
   104 lemma open_vimage_snd: "open S \<Longrightarrow> open (snd -` S)"
   105 by (simp add: snd_vimage_eq_Times open_Times)
   106 
   107 lemma closed_vimage_fst: "closed S \<Longrightarrow> closed (fst -` S)"
   108 unfolding closed_open vimage_Compl [symmetric]
   109 by (rule open_vimage_fst)
   110 
   111 lemma closed_vimage_snd: "closed S \<Longrightarrow> closed (snd -` S)"
   112 unfolding closed_open vimage_Compl [symmetric]
   113 by (rule open_vimage_snd)
   114 
   115 lemma closed_Times: "closed S \<Longrightarrow> closed T \<Longrightarrow> closed (S \<times> T)"
   116 proof -
   117   have "S \<times> T = (fst -` S) \<inter> (snd -` T)" by auto
   118   thus "closed S \<Longrightarrow> closed T \<Longrightarrow> closed (S \<times> T)"
   119     by (simp add: closed_vimage_fst closed_vimage_snd closed_Int)
   120 qed
   121 
   122 lemma subset_fst_imageI: "A \<times> B \<subseteq> S \<Longrightarrow> y \<in> B \<Longrightarrow> A \<subseteq> fst ` S"
   123   unfolding image_def subset_eq by force
   124 
   125 lemma subset_snd_imageI: "A \<times> B \<subseteq> S \<Longrightarrow> x \<in> A \<Longrightarrow> B \<subseteq> snd ` S"
   126   unfolding image_def subset_eq by force
   127 
   128 lemma open_image_fst: assumes "open S" shows "open (fst ` S)"
   129 proof (rule openI)
   130   fix x assume "x \<in> fst ` S"
   131   then obtain y where "(x, y) \<in> S" by auto
   132   then obtain A B where "open A" "open B" "x \<in> A" "y \<in> B" "A \<times> B \<subseteq> S"
   133     using `open S` unfolding open_prod_def by auto
   134   from `A \<times> B \<subseteq> S` `y \<in> B` have "A \<subseteq> fst ` S" by (rule subset_fst_imageI)
   135   with `open A` `x \<in> A` have "open A \<and> x \<in> A \<and> A \<subseteq> fst ` S" by simp
   136   then show "\<exists>T. open T \<and> x \<in> T \<and> T \<subseteq> fst ` S" by - (rule exI)
   137 qed
   138 
   139 lemma open_image_snd: assumes "open S" shows "open (snd ` S)"
   140 proof (rule openI)
   141   fix y assume "y \<in> snd ` S"
   142   then obtain x where "(x, y) \<in> S" by auto
   143   then obtain A B where "open A" "open B" "x \<in> A" "y \<in> B" "A \<times> B \<subseteq> S"
   144     using `open S` unfolding open_prod_def by auto
   145   from `A \<times> B \<subseteq> S` `x \<in> A` have "B \<subseteq> snd ` S" by (rule subset_snd_imageI)
   146   with `open B` `y \<in> B` have "open B \<and> y \<in> B \<and> B \<subseteq> snd ` S" by simp
   147   then show "\<exists>T. open T \<and> y \<in> T \<and> T \<subseteq> snd ` S" by - (rule exI)
   148 qed
   149 
   150 subsubsection {* Continuity of operations *}
   151 
   152 lemma tendsto_fst [tendsto_intros]:
   153   assumes "(f ---> a) F"
   154   shows "((\<lambda>x. fst (f x)) ---> fst a) F"
   155 proof (rule topological_tendstoI)
   156   fix S assume "open S" and "fst a \<in> S"
   157   then have "open (fst -` S)" and "a \<in> fst -` S"
   158     by (simp_all add: open_vimage_fst)
   159   with assms have "eventually (\<lambda>x. f x \<in> fst -` S) F"
   160     by (rule topological_tendstoD)
   161   then show "eventually (\<lambda>x. fst (f x) \<in> S) F"
   162     by simp
   163 qed
   164 
   165 lemma tendsto_snd [tendsto_intros]:
   166   assumes "(f ---> a) F"
   167   shows "((\<lambda>x. snd (f x)) ---> snd a) F"
   168 proof (rule topological_tendstoI)
   169   fix S assume "open S" and "snd a \<in> S"
   170   then have "open (snd -` S)" and "a \<in> snd -` S"
   171     by (simp_all add: open_vimage_snd)
   172   with assms have "eventually (\<lambda>x. f x \<in> snd -` S) F"
   173     by (rule topological_tendstoD)
   174   then show "eventually (\<lambda>x. snd (f x) \<in> S) F"
   175     by simp
   176 qed
   177 
   178 lemma tendsto_Pair [tendsto_intros]:
   179   assumes "(f ---> a) F" and "(g ---> b) F"
   180   shows "((\<lambda>x. (f x, g x)) ---> (a, b)) F"
   181 proof (rule topological_tendstoI)
   182   fix S assume "open S" and "(a, b) \<in> S"
   183   then obtain A B where "open A" "open B" "a \<in> A" "b \<in> B" "A \<times> B \<subseteq> S"
   184     unfolding open_prod_def by fast
   185   have "eventually (\<lambda>x. f x \<in> A) F"
   186     using `(f ---> a) F` `open A` `a \<in> A`
   187     by (rule topological_tendstoD)
   188   moreover
   189   have "eventually (\<lambda>x. g x \<in> B) F"
   190     using `(g ---> b) F` `open B` `b \<in> B`
   191     by (rule topological_tendstoD)
   192   ultimately
   193   show "eventually (\<lambda>x. (f x, g x) \<in> S) F"
   194     by (rule eventually_elim2)
   195        (simp add: subsetD [OF `A \<times> B \<subseteq> S`])
   196 qed
   197 
   198 lemma continuous_fst[continuous_intros]: "continuous F f \<Longrightarrow> continuous F (\<lambda>x. fst (f x))"
   199   unfolding continuous_def by (rule tendsto_fst)
   200 
   201 lemma continuous_snd[continuous_intros]: "continuous F f \<Longrightarrow> continuous F (\<lambda>x. snd (f x))"
   202   unfolding continuous_def by (rule tendsto_snd)
   203 
   204 lemma continuous_Pair[continuous_intros]: "continuous F f \<Longrightarrow> continuous F g \<Longrightarrow> continuous F (\<lambda>x. (f x, g x))"
   205   unfolding continuous_def by (rule tendsto_Pair)
   206 
   207 lemma continuous_on_fst[continuous_intros]: "continuous_on s f \<Longrightarrow> continuous_on s (\<lambda>x. fst (f x))"
   208   unfolding continuous_on_def by (auto intro: tendsto_fst)
   209 
   210 lemma continuous_on_snd[continuous_intros]: "continuous_on s f \<Longrightarrow> continuous_on s (\<lambda>x. snd (f x))"
   211   unfolding continuous_on_def by (auto intro: tendsto_snd)
   212 
   213 lemma continuous_on_Pair[continuous_intros]: "continuous_on s f \<Longrightarrow> continuous_on s g \<Longrightarrow> continuous_on s (\<lambda>x. (f x, g x))"
   214   unfolding continuous_on_def by (auto intro: tendsto_Pair)
   215 
   216 lemma isCont_fst [simp]: "isCont f a \<Longrightarrow> isCont (\<lambda>x. fst (f x)) a"
   217   by (fact continuous_fst)
   218 
   219 lemma isCont_snd [simp]: "isCont f a \<Longrightarrow> isCont (\<lambda>x. snd (f x)) a"
   220   by (fact continuous_snd)
   221 
   222 lemma isCont_Pair [simp]: "\<lbrakk>isCont f a; isCont g a\<rbrakk> \<Longrightarrow> isCont (\<lambda>x. (f x, g x)) a"
   223   by (fact continuous_Pair)
   224 
   225 subsubsection {* Separation axioms *}
   226 
   227 lemma mem_Times_iff: "x \<in> A \<times> B \<longleftrightarrow> fst x \<in> A \<and> snd x \<in> B"
   228   by (induct x) simp (* TODO: move elsewhere *)
   229 
   230 instance prod :: (t0_space, t0_space) t0_space
   231 proof
   232   fix x y :: "'a \<times> 'b" assume "x \<noteq> y"
   233   hence "fst x \<noteq> fst y \<or> snd x \<noteq> snd y"
   234     by (simp add: prod_eq_iff)
   235   thus "\<exists>U. open U \<and> (x \<in> U) \<noteq> (y \<in> U)"
   236     by (fast dest: t0_space elim: open_vimage_fst open_vimage_snd)
   237 qed
   238 
   239 instance prod :: (t1_space, t1_space) t1_space
   240 proof
   241   fix x y :: "'a \<times> 'b" assume "x \<noteq> y"
   242   hence "fst x \<noteq> fst y \<or> snd x \<noteq> snd y"
   243     by (simp add: prod_eq_iff)
   244   thus "\<exists>U. open U \<and> x \<in> U \<and> y \<notin> U"
   245     by (fast dest: t1_space elim: open_vimage_fst open_vimage_snd)
   246 qed
   247 
   248 instance prod :: (t2_space, t2_space) t2_space
   249 proof
   250   fix x y :: "'a \<times> 'b" assume "x \<noteq> y"
   251   hence "fst x \<noteq> fst y \<or> snd x \<noteq> snd y"
   252     by (simp add: prod_eq_iff)
   253   thus "\<exists>U V. open U \<and> open V \<and> x \<in> U \<and> y \<in> V \<and> U \<inter> V = {}"
   254     by (fast dest: hausdorff elim: open_vimage_fst open_vimage_snd)
   255 qed
   256 
   257 subsection {* Product is a metric space *}
   258 
   259 instantiation prod :: (metric_space, metric_space) metric_space
   260 begin
   261 
   262 definition dist_prod_def[code del]:
   263   "dist x y = sqrt ((dist (fst x) (fst y))\<^sup>2 + (dist (snd x) (snd y))\<^sup>2)"
   264 
   265 lemma dist_Pair_Pair: "dist (a, b) (c, d) = sqrt ((dist a c)\<^sup>2 + (dist b d)\<^sup>2)"
   266   unfolding dist_prod_def by simp
   267 
   268 lemma dist_fst_le: "dist (fst x) (fst y) \<le> dist x y"
   269   unfolding dist_prod_def by (rule real_sqrt_sum_squares_ge1)
   270 
   271 lemma dist_snd_le: "dist (snd x) (snd y) \<le> dist x y"
   272   unfolding dist_prod_def by (rule real_sqrt_sum_squares_ge2)
   273 
   274 instance proof
   275   fix x y :: "'a \<times> 'b"
   276   show "dist x y = 0 \<longleftrightarrow> x = y"
   277     unfolding dist_prod_def prod_eq_iff by simp
   278 next
   279   fix x y z :: "'a \<times> 'b"
   280   show "dist x y \<le> dist x z + dist y z"
   281     unfolding dist_prod_def
   282     by (intro order_trans [OF _ real_sqrt_sum_squares_triangle_ineq]
   283         real_sqrt_le_mono add_mono power_mono dist_triangle2 zero_le_dist)
   284 next
   285   fix S :: "('a \<times> 'b) set"
   286   show "open S \<longleftrightarrow> (\<forall>x\<in>S. \<exists>e>0. \<forall>y. dist y x < e \<longrightarrow> y \<in> S)"
   287   proof
   288     assume "open S" show "\<forall>x\<in>S. \<exists>e>0. \<forall>y. dist y x < e \<longrightarrow> y \<in> S"
   289     proof
   290       fix x assume "x \<in> S"
   291       obtain A B where "open A" "open B" "x \<in> A \<times> B" "A \<times> B \<subseteq> S"
   292         using `open S` and `x \<in> S` by (rule open_prod_elim)
   293       obtain r where r: "0 < r" "\<forall>y. dist y (fst x) < r \<longrightarrow> y \<in> A"
   294         using `open A` and `x \<in> A \<times> B` unfolding open_dist by auto
   295       obtain s where s: "0 < s" "\<forall>y. dist y (snd x) < s \<longrightarrow> y \<in> B"
   296         using `open B` and `x \<in> A \<times> B` unfolding open_dist by auto
   297       let ?e = "min r s"
   298       have "0 < ?e \<and> (\<forall>y. dist y x < ?e \<longrightarrow> y \<in> S)"
   299       proof (intro allI impI conjI)
   300         show "0 < min r s" by (simp add: r(1) s(1))
   301       next
   302         fix y assume "dist y x < min r s"
   303         hence "dist y x < r" and "dist y x < s"
   304           by simp_all
   305         hence "dist (fst y) (fst x) < r" and "dist (snd y) (snd x) < s"
   306           by (auto intro: le_less_trans dist_fst_le dist_snd_le)
   307         hence "fst y \<in> A" and "snd y \<in> B"
   308           by (simp_all add: r(2) s(2))
   309         hence "y \<in> A \<times> B" by (induct y, simp)
   310         with `A \<times> B \<subseteq> S` show "y \<in> S" ..
   311       qed
   312       thus "\<exists>e>0. \<forall>y. dist y x < e \<longrightarrow> y \<in> S" ..
   313     qed
   314   next
   315     assume *: "\<forall>x\<in>S. \<exists>e>0. \<forall>y. dist y x < e \<longrightarrow> y \<in> S" show "open S"
   316     proof (rule open_prod_intro)
   317       fix x assume "x \<in> S"
   318       then obtain e where "0 < e" and S: "\<forall>y. dist y x < e \<longrightarrow> y \<in> S"
   319         using * by fast
   320       def r \<equiv> "e / sqrt 2" and s \<equiv> "e / sqrt 2"
   321       from `0 < e` have "0 < r" and "0 < s"
   322         unfolding r_def s_def by simp_all
   323       from `0 < e` have "e = sqrt (r\<^sup>2 + s\<^sup>2)"
   324         unfolding r_def s_def by (simp add: power_divide)
   325       def A \<equiv> "{y. dist (fst x) y < r}" and B \<equiv> "{y. dist (snd x) y < s}"
   326       have "open A" and "open B"
   327         unfolding A_def B_def by (simp_all add: open_ball)
   328       moreover have "x \<in> A \<times> B"
   329         unfolding A_def B_def mem_Times_iff
   330         using `0 < r` and `0 < s` by simp
   331       moreover have "A \<times> B \<subseteq> S"
   332       proof (clarify)
   333         fix a b assume "a \<in> A" and "b \<in> B"
   334         hence "dist a (fst x) < r" and "dist b (snd x) < s"
   335           unfolding A_def B_def by (simp_all add: dist_commute)
   336         hence "dist (a, b) x < e"
   337           unfolding dist_prod_def `e = sqrt (r\<^sup>2 + s\<^sup>2)`
   338           by (simp add: add_strict_mono power_strict_mono)
   339         thus "(a, b) \<in> S"
   340           by (simp add: S)
   341       qed
   342       ultimately show "\<exists>A B. open A \<and> open B \<and> x \<in> A \<times> B \<and> A \<times> B \<subseteq> S" by fast
   343     qed
   344   qed
   345 qed
   346 
   347 end
   348 
   349 declare [[code abort: "dist::('a::metric_space*'b::metric_space)\<Rightarrow>('a*'b) \<Rightarrow> real"]]
   350 
   351 lemma Cauchy_fst: "Cauchy X \<Longrightarrow> Cauchy (\<lambda>n. fst (X n))"
   352   unfolding Cauchy_def by (fast elim: le_less_trans [OF dist_fst_le])
   353 
   354 lemma Cauchy_snd: "Cauchy X \<Longrightarrow> Cauchy (\<lambda>n. snd (X n))"
   355   unfolding Cauchy_def by (fast elim: le_less_trans [OF dist_snd_le])
   356 
   357 lemma Cauchy_Pair:
   358   assumes "Cauchy X" and "Cauchy Y"
   359   shows "Cauchy (\<lambda>n. (X n, Y n))"
   360 proof (rule metric_CauchyI)
   361   fix r :: real assume "0 < r"
   362   hence "0 < r / sqrt 2" (is "0 < ?s") by simp
   363   obtain M where M: "\<forall>m\<ge>M. \<forall>n\<ge>M. dist (X m) (X n) < ?s"
   364     using metric_CauchyD [OF `Cauchy X` `0 < ?s`] ..
   365   obtain N where N: "\<forall>m\<ge>N. \<forall>n\<ge>N. dist (Y m) (Y n) < ?s"
   366     using metric_CauchyD [OF `Cauchy Y` `0 < ?s`] ..
   367   have "\<forall>m\<ge>max M N. \<forall>n\<ge>max M N. dist (X m, Y m) (X n, Y n) < r"
   368     using M N by (simp add: real_sqrt_sum_squares_less dist_Pair_Pair)
   369   then show "\<exists>n0. \<forall>m\<ge>n0. \<forall>n\<ge>n0. dist (X m, Y m) (X n, Y n) < r" ..
   370 qed
   371 
   372 subsection {* Product is a complete metric space *}
   373 
   374 instance prod :: (complete_space, complete_space) complete_space
   375 proof
   376   fix X :: "nat \<Rightarrow> 'a \<times> 'b" assume "Cauchy X"
   377   have 1: "(\<lambda>n. fst (X n)) ----> lim (\<lambda>n. fst (X n))"
   378     using Cauchy_fst [OF `Cauchy X`]
   379     by (simp add: Cauchy_convergent_iff convergent_LIMSEQ_iff)
   380   have 2: "(\<lambda>n. snd (X n)) ----> lim (\<lambda>n. snd (X n))"
   381     using Cauchy_snd [OF `Cauchy X`]
   382     by (simp add: Cauchy_convergent_iff convergent_LIMSEQ_iff)
   383   have "X ----> (lim (\<lambda>n. fst (X n)), lim (\<lambda>n. snd (X n)))"
   384     using tendsto_Pair [OF 1 2] by simp
   385   then show "convergent X"
   386     by (rule convergentI)
   387 qed
   388 
   389 subsection {* Product is a normed vector space *}
   390 
   391 instantiation prod :: (real_normed_vector, real_normed_vector) real_normed_vector
   392 begin
   393 
   394 definition norm_prod_def[code del]:
   395   "norm x = sqrt ((norm (fst x))\<^sup>2 + (norm (snd x))\<^sup>2)"
   396 
   397 definition sgn_prod_def:
   398   "sgn (x::'a \<times> 'b) = scaleR (inverse (norm x)) x"
   399 
   400 lemma norm_Pair: "norm (a, b) = sqrt ((norm a)\<^sup>2 + (norm b)\<^sup>2)"
   401   unfolding norm_prod_def by simp
   402 
   403 instance proof
   404   fix r :: real and x y :: "'a \<times> 'b"
   405   show "norm x = 0 \<longleftrightarrow> x = 0"
   406     unfolding norm_prod_def
   407     by (simp add: prod_eq_iff)
   408   show "norm (x + y) \<le> norm x + norm y"
   409     unfolding norm_prod_def
   410     apply (rule order_trans [OF _ real_sqrt_sum_squares_triangle_ineq])
   411     apply (simp add: add_mono power_mono norm_triangle_ineq)
   412     done
   413   show "norm (scaleR r x) = \<bar>r\<bar> * norm x"
   414     unfolding norm_prod_def
   415     apply (simp add: power_mult_distrib)
   416     apply (simp add: distrib_left [symmetric])
   417     apply (simp add: real_sqrt_mult_distrib)
   418     done
   419   show "sgn x = scaleR (inverse (norm x)) x"
   420     by (rule sgn_prod_def)
   421   show "dist x y = norm (x - y)"
   422     unfolding dist_prod_def norm_prod_def
   423     by (simp add: dist_norm)
   424 qed
   425 
   426 end
   427 
   428 declare [[code abort: "norm::('a::real_normed_vector*'b::real_normed_vector) \<Rightarrow> real"]]
   429 
   430 instance prod :: (banach, banach) banach ..
   431 
   432 subsubsection {* Pair operations are linear *}
   433 
   434 lemma bounded_linear_fst: "bounded_linear fst"
   435   using fst_add fst_scaleR
   436   by (rule bounded_linear_intro [where K=1], simp add: norm_prod_def)
   437 
   438 lemma bounded_linear_snd: "bounded_linear snd"
   439   using snd_add snd_scaleR
   440   by (rule bounded_linear_intro [where K=1], simp add: norm_prod_def)
   441 
   442 text {* TODO: move to NthRoot *}
   443 lemma sqrt_add_le_add_sqrt:
   444   assumes x: "0 \<le> x" and y: "0 \<le> y"
   445   shows "sqrt (x + y) \<le> sqrt x + sqrt y"
   446 apply (rule power2_le_imp_le)
   447 apply (simp add: power2_sum x y)
   448 apply (simp add: x y)
   449 done
   450 
   451 lemma bounded_linear_Pair:
   452   assumes f: "bounded_linear f"
   453   assumes g: "bounded_linear g"
   454   shows "bounded_linear (\<lambda>x. (f x, g x))"
   455 proof
   456   interpret f: bounded_linear f by fact
   457   interpret g: bounded_linear g by fact
   458   fix x y and r :: real
   459   show "(f (x + y), g (x + y)) = (f x, g x) + (f y, g y)"
   460     by (simp add: f.add g.add)
   461   show "(f (r *\<^sub>R x), g (r *\<^sub>R x)) = r *\<^sub>R (f x, g x)"
   462     by (simp add: f.scaleR g.scaleR)
   463   obtain Kf where "0 < Kf" and norm_f: "\<And>x. norm (f x) \<le> norm x * Kf"
   464     using f.pos_bounded by fast
   465   obtain Kg where "0 < Kg" and norm_g: "\<And>x. norm (g x) \<le> norm x * Kg"
   466     using g.pos_bounded by fast
   467   have "\<forall>x. norm (f x, g x) \<le> norm x * (Kf + Kg)"
   468     apply (rule allI)
   469     apply (simp add: norm_Pair)
   470     apply (rule order_trans [OF sqrt_add_le_add_sqrt], simp, simp)
   471     apply (simp add: distrib_left)
   472     apply (rule add_mono [OF norm_f norm_g])
   473     done
   474   then show "\<exists>K. \<forall>x. norm (f x, g x) \<le> norm x * K" ..
   475 qed
   476 
   477 subsubsection {* Frechet derivatives involving pairs *}
   478 
   479 lemma has_derivative_Pair [derivative_intros]:
   480   assumes f: "(f has_derivative f') (at x within s)" and g: "(g has_derivative g') (at x within s)"
   481   shows "((\<lambda>x. (f x, g x)) has_derivative (\<lambda>h. (f' h, g' h))) (at x within s)"
   482 proof (rule has_derivativeI_sandwich[of 1])
   483   show "bounded_linear (\<lambda>h. (f' h, g' h))"
   484     using f g by (intro bounded_linear_Pair has_derivative_bounded_linear)
   485   let ?Rf = "\<lambda>y. f y - f x - f' (y - x)"
   486   let ?Rg = "\<lambda>y. g y - g x - g' (y - x)"
   487   let ?R = "\<lambda>y. ((f y, g y) - (f x, g x) - (f' (y - x), g' (y - x)))"
   488 
   489   show "((\<lambda>y. norm (?Rf y) / norm (y - x) + norm (?Rg y) / norm (y - x)) ---> 0) (at x within s)"
   490     using f g by (intro tendsto_add_zero) (auto simp: has_derivative_iff_norm)
   491 
   492   fix y :: 'a assume "y \<noteq> x"
   493   show "norm (?R y) / norm (y - x) \<le> norm (?Rf y) / norm (y - x) + norm (?Rg y) / norm (y - x)"
   494     unfolding add_divide_distrib [symmetric]
   495     by (simp add: norm_Pair divide_right_mono order_trans [OF sqrt_add_le_add_sqrt])
   496 qed simp
   497 
   498 lemmas has_derivative_fst [derivative_intros] = bounded_linear.has_derivative [OF bounded_linear_fst]
   499 lemmas has_derivative_snd [derivative_intros] = bounded_linear.has_derivative [OF bounded_linear_snd]
   500 
   501 lemma has_derivative_split [derivative_intros]:
   502   "((\<lambda>p. f (fst p) (snd p)) has_derivative f') F \<Longrightarrow> ((\<lambda>(a, b). f a b) has_derivative f') F"
   503   unfolding split_beta' .
   504 
   505 subsection {* Product is an inner product space *}
   506 
   507 instantiation prod :: (real_inner, real_inner) real_inner
   508 begin
   509 
   510 definition inner_prod_def:
   511   "inner x y = inner (fst x) (fst y) + inner (snd x) (snd y)"
   512 
   513 lemma inner_Pair [simp]: "inner (a, b) (c, d) = inner a c + inner b d"
   514   unfolding inner_prod_def by simp
   515 
   516 instance proof
   517   fix r :: real
   518   fix x y z :: "'a::real_inner \<times> 'b::real_inner"
   519   show "inner x y = inner y x"
   520     unfolding inner_prod_def
   521     by (simp add: inner_commute)
   522   show "inner (x + y) z = inner x z + inner y z"
   523     unfolding inner_prod_def
   524     by (simp add: inner_add_left)
   525   show "inner (scaleR r x) y = r * inner x y"
   526     unfolding inner_prod_def
   527     by (simp add: distrib_left)
   528   show "0 \<le> inner x x"
   529     unfolding inner_prod_def
   530     by (intro add_nonneg_nonneg inner_ge_zero)
   531   show "inner x x = 0 \<longleftrightarrow> x = 0"
   532     unfolding inner_prod_def prod_eq_iff
   533     by (simp add: add_nonneg_eq_0_iff)
   534   show "norm x = sqrt (inner x x)"
   535     unfolding norm_prod_def inner_prod_def
   536     by (simp add: power2_norm_eq_inner)
   537 qed
   538 
   539 end
   540 
   541 end