src/Pure/Thy/present.ML
author wenzelm
Mon Jul 23 16:45:03 2007 +0200 (2007-07-23)
changeset 23935 2a4e42ec9a54
parent 23899 ab37b1f690c7
child 23944 2ea068548a83
permissions -rw-r--r--
PrintMode.with_modes;
     1 (*  Title:      Pure/Thy/present.ML
     2     ID:         $Id$
     3     Author:     Markus Wenzel and Stefan Berghofer, TU Muenchen
     4 
     5 Theory presentation: HTML, graph files, (PDF)LaTeX documents.
     6 *)
     7 
     8 signature BASIC_PRESENT =
     9 sig
    10   val no_document: ('a -> 'b) -> 'a -> 'b
    11   val section: string -> unit
    12 end;
    13 
    14 signature PRESENT =
    15 sig
    16   include BASIC_PRESENT
    17   val get_info: theory -> {name: string, session: string list, is_local: bool}
    18   val write_graph: {name: string, ID: string, dir: string, unfold: bool,
    19    path: string, parents: string list} list -> Path.T -> unit
    20   val display_graph: {name: string, ID: string, dir: string, unfold: bool,
    21    path: string, parents: string list} list -> unit
    22   val init: bool -> bool -> string -> bool -> string list -> string list ->
    23     string -> (bool * Path.T) option -> Url.T option * bool -> bool -> theory list -> unit
    24   val finish: unit -> unit
    25   val init_theory: string -> unit
    26   val verbatim_source: string -> (unit -> Symbol.symbol list) -> unit
    27   val theory_output: string -> string -> unit
    28   val begin_theory: Path.T -> (Path.T * bool) list -> theory -> theory
    29   val add_hook: (string -> (string * thm list) list -> unit) -> unit
    30   val results: string -> (string * thm list) list -> unit
    31   val theorem: string -> thm -> unit
    32   val theorems: string -> thm list -> unit
    33   val chapter: string -> unit
    34   val subsection: string -> unit
    35   val subsubsection: string -> unit
    36   val drafts: string -> Path.T list -> Path.T
    37 end;
    38 
    39 structure Present: PRESENT =
    40 struct
    41 
    42 
    43 (** paths **)
    44 
    45 val output_path = Path.variable "ISABELLE_BROWSER_INFO";
    46 
    47 val tex_ext = Path.ext "tex";
    48 val tex_path = tex_ext o Path.basic;
    49 val html_ext = Path.ext "html";
    50 val html_path = html_ext o Path.basic;
    51 val index_path = Path.basic "index.html";
    52 val readme_html_path = Path.basic "README.html";
    53 val readme_path = Path.basic "README";
    54 val documentN = "document";
    55 val document_path = Path.basic documentN;
    56 val doc_indexN = "session";
    57 val graph_path = Path.basic "session.graph";
    58 val graph_pdf_path = Path.basic "session_graph.pdf";
    59 val graph_eps_path = Path.basic "session_graph.eps";
    60 
    61 val session_path = Path.basic ".session";
    62 val session_entries_path = Path.explode ".session/entries";
    63 val pre_index_path = Path.explode ".session/pre-index";
    64 
    65 fun mk_rel_path [] ys = Path.make ys
    66   | mk_rel_path xs [] = Path.appends (replicate (length xs) Path.parent)
    67   | mk_rel_path (ps as x :: xs) (qs as y :: ys) = if x = y then mk_rel_path xs ys else
    68       Path.appends (replicate (length ps) Path.parent @ [Path.make qs]);
    69 
    70 fun show_path path = Path.implode (Path.append (File.pwd ()) path);
    71 
    72 
    73 
    74 (** additional theory data **)
    75 
    76 structure BrowserInfoData = TheoryDataFun
    77 (
    78   type T = {name: string, session: string list, is_local: bool};
    79   val empty = {name = "", session = [], is_local = false}: T;
    80   val copy = I;
    81   fun extend _ = empty;
    82   fun merge _ _ = empty;
    83 );
    84 
    85 fun get_info thy =
    86   if member (op =) [Context.ProtoPureN, Context.PureN, Context.CPureN] (Context.theory_name thy)
    87   then {name = Context.PureN, session = [], is_local = false}
    88   else BrowserInfoData.get thy;
    89 
    90 
    91 
    92 (** graphs **)
    93 
    94 type graph_node =
    95   {name: string, ID: string, dir: string, unfold: bool,
    96    path: string, parents: string list};
    97 
    98 fun write_graph gr path =
    99   File.write path (cat_lines (map (fn {name, ID, dir, unfold, path, parents} =>
   100     "\"" ^ name ^ "\" \"" ^ ID ^ "\" \"" ^ dir ^ (if unfold then "\" + \"" else "\" \"") ^
   101     path ^ "\" > " ^ space_implode " " (map Library.quote parents) ^ " ;") gr));
   102 
   103 fun display_graph gr =
   104   let
   105     val _ = writeln "Generating graph ...";
   106     val path = File.tmp_path (Path.explode "tmp.graph");
   107     val _ = write_graph gr path;
   108     val _ = File.isatool ("browser -c " ^ File.shell_path path ^ " &");
   109   in () end;
   110 
   111 
   112 fun ID_of sess s = space_implode "/" (sess @ [s]);
   113 fun ID_of_thy thy = ID_of (#session (get_info thy)) (Context.theory_name thy);
   114 
   115 
   116 (*retrieve graph data from initial collection of theories*)
   117 fun init_graph remote_path curr_sess = map (fn thy =>
   118   let
   119     val name = Context.theory_name thy;
   120     val {name = sess_name, session, is_local} = get_info thy;
   121     val path' = Path.append (Path.make session) (html_path name);
   122   in
   123    {name = name, ID = ID_of session name, dir = sess_name,
   124     path =
   125       if null session then "" else
   126       if is_some remote_path andalso not is_local then
   127         Url.implode (Url.append (the remote_path) (Url.File
   128           (Path.append (Path.make session) (html_path name))))
   129       else Path.implode (Path.append (mk_rel_path curr_sess session) (html_path name)),
   130     unfold = false,
   131     parents = map ID_of_thy (Theory.parents_of thy)}
   132   end);
   133 
   134 fun ins_graph_entry (entry as {ID, ...}) (gr: graph_node list) =
   135   filter_out (fn entry' => #ID entry' = ID) gr @ [entry];
   136 
   137 
   138 
   139 (** global browser info state **)
   140 
   141 (* type theory_info *)
   142 
   143 type theory_info = {tex_source: Buffer.T, html_source: Buffer.T, html: Buffer.T};
   144 
   145 fun make_theory_info (tex_source, html_source, html) =
   146   {tex_source = tex_source, html_source = html_source, html = html}: theory_info;
   147 
   148 val empty_theory_info = make_theory_info (Buffer.empty, Buffer.empty, Buffer.empty);
   149 
   150 fun map_theory_info f {tex_source, html_source, html} =
   151   make_theory_info (f (tex_source, html_source, html));
   152 
   153 
   154 (* type browser_info *)
   155 
   156 type browser_info = {theories: theory_info Symtab.table, files: (Path.T * string) list,
   157   tex_index: Buffer.T, html_index: Buffer.T, graph: graph_node list};
   158 
   159 fun make_browser_info (theories, files, tex_index, html_index, graph) =
   160   {theories = theories, files = files, tex_index = tex_index, html_index = html_index,
   161     graph = graph}: browser_info;
   162 
   163 val empty_browser_info = make_browser_info (Symtab.empty, [], Buffer.empty, Buffer.empty, []);
   164 
   165 fun init_browser_info remote_path curr_sess thys = make_browser_info
   166   (Symtab.empty, [], Buffer.empty, Buffer.empty, init_graph remote_path curr_sess thys);
   167 
   168 fun map_browser_info f {theories, files, tex_index, html_index, graph} =
   169   make_browser_info (f (theories, files, tex_index, html_index, graph));
   170 
   171 
   172 (* state *)
   173 
   174 val browser_info = ref empty_browser_info;
   175 fun change_browser_info f = browser_info := map_browser_info f (! browser_info);
   176 
   177 val suppress_tex_source = ref false;
   178 fun no_document f x = Library.setmp suppress_tex_source true f x;
   179 
   180 fun init_theory_info name info =
   181   change_browser_info (fn (theories, files, tex_index, html_index, graph) =>
   182     (Symtab.update (name, info) theories, files, tex_index, html_index, graph));
   183 
   184 fun change_theory_info name f =
   185   change_browser_info (fn (info as (theories, files, tex_index, html_index, graph)) =>
   186     (case Symtab.lookup theories name of
   187       NONE => (warning ("Browser info: cannot access theory document " ^ quote name); info)
   188     | SOME info => (Symtab.update (name, map_theory_info f info) theories, files,
   189         tex_index, html_index, graph)));
   190 
   191 
   192 fun add_file file =
   193   change_browser_info (fn (theories, files, tex_index, html_index, graph) =>
   194     (theories, file :: files, tex_index, html_index, graph));
   195 
   196 fun add_tex_index txt =
   197   change_browser_info (fn (theories, files, tex_index, html_index, graph) =>
   198     (theories, files, Buffer.add txt tex_index, html_index, graph));
   199 
   200 fun add_html_index txt =
   201   change_browser_info (fn (theories, files, tex_index, html_index, graph) =>
   202     (theories, files, tex_index, Buffer.add txt html_index, graph));
   203 
   204 fun add_graph_entry e =
   205   change_browser_info (fn (theories, files, tex_index, html_index, graph) =>
   206     (theories, files, tex_index, html_index, ins_graph_entry e graph));
   207 
   208 fun add_tex_source name txt =
   209   if ! suppress_tex_source then ()
   210   else change_theory_info name (fn (tex_source, html_source, html) =>
   211     (Buffer.add txt tex_source, html_source, html));
   212 
   213 fun add_html_source name txt = change_theory_info name (fn (tex_source, html_source, html) =>
   214   (tex_source, Buffer.add txt html_source, html));
   215 
   216 fun add_html name txt = change_theory_info name (fn (tex_source, html_source, html) =>
   217   (tex_source, html_source, Buffer.add txt html));
   218 
   219 
   220 
   221 (** global session state **)
   222 
   223 (* session_info *)
   224 
   225 type session_info =
   226   {name: string, parent: string, session: string, path: string list, html_prefix: Path.T,
   227     info: bool, doc_format: string, doc_graph: bool, documents: (string * string) list,
   228     doc_prefix1: (Path.T * Path.T) option, doc_prefix2: (bool * Path.T) option,
   229     remote_path: Url.T option, verbose: bool, readme: Path.T option};
   230 
   231 fun make_session_info
   232   (name, parent, session, path, html_prefix, info, doc_format, doc_graph, documents,
   233     doc_prefix1, doc_prefix2, remote_path, verbose, readme) =
   234   {name = name, parent = parent, session = session, path = path, html_prefix = html_prefix,
   235     info = info, doc_format = doc_format, doc_graph = doc_graph, documents = documents,
   236     doc_prefix1 = doc_prefix1, doc_prefix2 = doc_prefix2, remote_path = remote_path,
   237     verbose = verbose, readme = readme}: session_info;
   238 
   239 
   240 (* state *)
   241 
   242 val session_info = ref (NONE: session_info option);
   243 
   244 fun with_session x f = (case ! session_info of NONE => x | SOME info => f info);
   245 fun with_context f = f (Context.theory_name (ML_Context.the_context ()));
   246 
   247 
   248 
   249 (** document preparation **)
   250 
   251 (* maintain index *)
   252 
   253 val session_entries =
   254   HTML.session_entries o
   255     map (fn name => (Url.File (Path.append (Path.basic name) index_path), name));
   256 
   257 fun get_entries dir =
   258   split_lines (File.read (Path.append dir session_entries_path));
   259 
   260 fun put_entries entries dir =
   261   File.write (Path.append dir session_entries_path) (cat_lines entries);
   262 
   263 
   264 fun create_index dir =
   265   File.read (Path.append dir pre_index_path) ^
   266     session_entries (get_entries dir) ^ HTML.end_index
   267   |> File.write (Path.append dir index_path);
   268 
   269 fun update_index dir name =
   270   (case try get_entries dir of
   271     NONE => warning ("Browser info: cannot access session index of " ^ quote (Path.implode dir))
   272   | SOME es => (put_entries ((remove (op =) name es) @ [name]) dir; create_index dir));
   273 
   274 
   275 (* document versions *)
   276 
   277 fun read_version str =
   278   (case space_explode "=" str of
   279     [name] => (name, "")
   280   | [name, tags] => (name, tags)
   281   | _ => error ("Malformed document version specification: " ^ quote str));
   282 
   283 fun read_versions strs =
   284   rev (distinct (eq_fst (op =)) (rev ((documentN, "") :: map read_version strs)))
   285   |> filter_out (equal "-" o #2);
   286 
   287 
   288 (* init session *)
   289 
   290 fun name_of_session elems = space_implode "/" ("Isabelle" :: elems);
   291 
   292 fun init build info doc doc_graph doc_versions path name doc_prefix2
   293     (remote_path, first_time) verbose thys =
   294   if not build andalso not info andalso doc = "" andalso is_none doc_prefix2 then
   295     (browser_info := empty_browser_info; session_info := NONE)
   296   else
   297     let
   298       val parent_name = name_of_session (Library.take (length path - 1, path));
   299       val session_name = name_of_session path;
   300       val sess_prefix = Path.make path;
   301       val html_prefix = Path.append (Path.expand output_path) sess_prefix;
   302 
   303       val (doc_prefix1, documents) =
   304         if doc = "" then (NONE, [])
   305         else if not (File.exists document_path) then
   306           (if verbose then Output.std_error "Warning: missing document directory\n" else ();
   307             (NONE, []))
   308         else (SOME (Path.append html_prefix document_path, html_prefix),
   309           read_versions doc_versions);
   310 
   311       val parent_index_path = Path.append Path.parent index_path;
   312       val index_up_lnk = if first_time then
   313           Url.append (the remote_path) (Url.File (Path.append sess_prefix parent_index_path))
   314         else Url.File parent_index_path;
   315       val readme =
   316         if File.exists readme_html_path then SOME readme_html_path
   317         else if File.exists readme_path then SOME readme_path
   318         else NONE;
   319 
   320       val docs =
   321         (case readme of NONE => [] | SOME p => [(Url.File p, "README")]) @
   322         map (fn (name, _) => (Url.File (Path.ext doc (Path.basic name)), name)) documents;
   323       val index_text = HTML.begin_index (index_up_lnk, parent_name)
   324         (Url.File index_path, session_name) docs (Url.explode "medium.html");
   325     in
   326       session_info := SOME (make_session_info (name, parent_name, session_name, path, html_prefix,
   327       info, doc, doc_graph, documents, doc_prefix1, doc_prefix2, remote_path, verbose, readme));
   328       browser_info := init_browser_info remote_path path thys;
   329       add_html_index index_text
   330     end;
   331 
   332 
   333 (* isatool wrappers *)
   334 
   335 fun isatool_document verbose format name tags path result_path =
   336   let
   337     val s = "\"$ISATOOL\" document -c -o '" ^ format ^ "' \
   338       \-n '" ^ name ^ "' -t '" ^ tags ^ "' " ^ File.shell_path path ^
   339       " 2>&1" ^ (if verbose then "" else " >/dev/null");
   340     val doc_path = Path.append result_path (Path.ext format (Path.basic name));
   341   in
   342     if verbose then writeln s else ();
   343     system s;
   344     File.exists doc_path orelse
   345       error ("No document: " ^ quote (show_path doc_path));
   346     doc_path
   347   end;
   348 
   349 fun isatool_browser graph =
   350   let
   351     val pdf_path = File.tmp_path graph_pdf_path;
   352     val eps_path = File.tmp_path graph_eps_path;
   353     val gr_path = File.tmp_path graph_path;
   354     val s = "browser -o " ^ File.shell_path pdf_path ^ " " ^ File.shell_path gr_path;
   355   in
   356     write_graph graph gr_path;
   357     if File.isatool s <> 0 orelse not (File.exists eps_path) orelse not (File.exists pdf_path)
   358     then error "Failed to prepare dependency graph"
   359     else
   360       let val pdf = File.read pdf_path and eps = File.read eps_path
   361       in File.rm pdf_path; File.rm eps_path; File.rm gr_path; (pdf, eps) end
   362   end;
   363 
   364 
   365 (* finish session -- output all generated text *)
   366 
   367 fun write_tex src name path =
   368   Buffer.write (Path.append path (tex_path name)) src;
   369 
   370 fun write_tex_index tex_index path =
   371   write_tex (Buffer.add Latex.tex_trailer tex_index) doc_indexN path;
   372 
   373 
   374 fun finish () = with_session () (fn {name, info, html_prefix, doc_format, doc_graph,
   375     documents, doc_prefix1, doc_prefix2, path, verbose, readme, ...} =>
   376   let
   377     val {theories, files, tex_index, html_index, graph} = ! browser_info;
   378     val thys = Symtab.dest theories;
   379     val parent_html_prefix = Path.append html_prefix Path.parent;
   380 
   381     fun finish_tex path (a, {tex_source, ...}: theory_info) = write_tex tex_source a path;
   382     fun finish_html (a, {html, ...}: theory_info) =
   383       Buffer.write (Path.append html_prefix (html_path a)) (Buffer.add HTML.end_theory html);
   384 
   385     val opt_graphs =
   386       if doc_graph andalso (is_some doc_prefix1 orelse is_some doc_prefix2) then
   387         SOME (isatool_browser graph)
   388       else NONE;
   389 
   390     fun prepare_sources cp path =
   391      (File.mkdir path;
   392       if cp then File.copy_dir document_path path else ();
   393       File.isatool ("latex -o sty " ^ File.shell_path (Path.append path (Path.basic "root.tex")));
   394       (case opt_graphs of NONE => () | SOME (pdf, eps) =>
   395         (File.write (Path.append path graph_pdf_path) pdf;
   396           File.write (Path.append path graph_eps_path) eps));
   397       write_tex_index tex_index path;
   398       List.app (finish_tex path) thys);
   399   in
   400     if info then
   401      (File.mkdir (Path.append html_prefix session_path);
   402       Buffer.write (Path.append html_prefix pre_index_path) html_index;
   403       File.write (Path.append html_prefix session_entries_path) "";
   404       create_index html_prefix;
   405       if length path > 1 then update_index parent_html_prefix name else ();
   406       (case readme of NONE => () | SOME path => File.copy path html_prefix);
   407       write_graph graph (Path.append html_prefix graph_path);
   408       File.copy (Path.explode "~~/lib/browser/GraphBrowser.jar") html_prefix;
   409       List.app (fn (a, txt) => File.write (Path.append html_prefix (Path.basic a)) txt)
   410         (HTML.applet_pages name (Url.File index_path, name));
   411       File.copy (Path.explode "~~/lib/html/isabelle.css") html_prefix;
   412       List.app finish_html thys;
   413       List.app (uncurry File.write) files;
   414       if verbose then Output.std_error ("Browser info at " ^ show_path html_prefix ^ "\n") else ())
   415     else ();
   416 
   417     (case doc_prefix2 of NONE => () | SOME (cp, path) =>
   418      (prepare_sources cp path;
   419       if verbose then Output.std_error ("Document sources at " ^ show_path path ^ "\n") else ()));
   420 
   421     (case doc_prefix1 of NONE => () | SOME (path, result_path) =>
   422       documents |> List.app (fn (name, tags) =>
   423        let
   424          val _ = prepare_sources true path;
   425          val doc_path = isatool_document true doc_format name tags path result_path;
   426        in
   427          if verbose then Output.std_error ("Document at " ^ show_path doc_path ^ "\n") else ()
   428        end));
   429 
   430     browser_info := empty_browser_info;
   431     session_info := NONE
   432   end);
   433 
   434 
   435 (* theory elements *)
   436 
   437 fun init_theory name = with_session () (fn _ => init_theory_info name empty_theory_info);
   438 
   439 fun verbatim_source name mk_text =
   440   with_session () (fn _ => add_html_source name (HTML.verbatim_source (mk_text ())));
   441 
   442 fun theory_output name s =
   443   with_session () (fn _ => add_tex_source name (Latex.isabelle_file name s));
   444 
   445 
   446 fun parent_link remote_path curr_session thy =
   447   let
   448     val {name = _, session, is_local} = get_info thy;
   449     val name = Context.theory_name thy;
   450     val link =
   451       if null session then NONE
   452       else SOME
   453        (if is_some remote_path andalso not is_local then
   454          Url.append (the remote_path) (Url.File (Path.append (Path.make session) (html_path name)))
   455         else Url.File (Path.append (mk_rel_path curr_session session) (html_path name)));
   456   in (link, name) end;
   457 
   458 fun begin_theory dir orig_files thy =
   459     with_session thy (fn {name = sess_name, session, path, html_prefix, remote_path, ...} =>
   460   let
   461     val name = Context.theory_name thy;
   462     val parents = Theory.parents_of thy;
   463     val parent_specs = map (parent_link remote_path path) parents;
   464     val ml_path = ThyLoad.ml_path name;
   465     val files = map (apsnd SOME) orig_files @
   466       (if is_some (ThyLoad.check_file dir ml_path) then [(ml_path, NONE)] else []);
   467 
   468     fun prep_file (raw_path, loadit) =
   469       (case ThyLoad.check_ml dir raw_path of
   470         SOME (path, _) =>
   471           let
   472             val base = Path.base path;
   473             val base_html = html_ext base;
   474           in
   475             add_file (Path.append html_prefix base_html,
   476               HTML.ml_file (Url.File base) (File.read path));
   477             (SOME (Url.File base_html), Url.File raw_path, loadit)
   478           end
   479       | NONE =>
   480           (warning ("Browser info: expected to find ML file" ^ quote (Path.implode raw_path));
   481             (NONE, Url.File raw_path, loadit)));
   482 
   483     val files_html = map prep_file files;
   484 
   485     fun prep_html_source (tex_source, html_source, html) =
   486       let
   487         val txt = HTML.begin_theory (Url.File index_path, session)
   488           name parent_specs files_html (Buffer.content html_source)
   489       in (tex_source, Buffer.empty, Buffer.add txt html) end;
   490 
   491     val entry =
   492      {name = name, ID = ID_of path name, dir = sess_name, unfold = true,
   493       path = Path.implode (html_path name),
   494       parents = map ID_of_thy parents};
   495 
   496   in
   497     change_theory_info name prep_html_source;
   498     add_graph_entry entry;
   499     add_html_index (HTML.theory_entry (Url.File (html_path name), name));
   500     add_tex_index (Latex.theory_entry name);
   501     BrowserInfoData.put {name = sess_name, session = path, is_local = is_some remote_path} thy
   502   end);
   503 
   504 
   505 val hooks = ref ([]: (string -> (string * thm list) list -> unit) list);
   506 fun add_hook f = hooks := (f :: ! hooks);
   507 
   508 fun results k xs =
   509  (List.app (fn f => (try (fn () => f k xs) (); ())) (! hooks);
   510   with_session () (fn _ => with_context add_html
   511     (HTML.results (ML_Context.the_local_context ()) k xs)));
   512 
   513 fun theorem a th = results Thm.theoremK [(a, [th])];
   514 fun theorems a ths = results Thm.theoremK [(a, ths)];
   515 fun chapter s = with_session () (fn _ => with_context add_html (HTML.chapter s));
   516 fun section s = with_session () (fn _ => with_context add_html (HTML.section s));
   517 fun subsection s = with_session () (fn _ => with_context add_html (HTML.subsection s));
   518 fun subsubsection s = with_session () (fn _ => with_context add_html (HTML.subsubsection s));
   519 
   520 
   521 
   522 (** draft document output **)
   523 
   524 fun drafts doc_format src_paths =
   525   let
   526     fun prep_draft (tex_index, path) =
   527       let
   528         val base = Path.base path;
   529         val name =
   530           (case Path.implode (#1 (Path.split_ext base)) of "" => gensym "DUMMY" | s => s);
   531       in
   532         if File.exists path then
   533           (Buffer.add (Latex.theory_entry name) tex_index, (name, base, File.read path))
   534         else error ("Bad file: " ^ quote (Path.implode path))
   535       end;
   536     val (tex_index, srcs) = foldl_map prep_draft (Buffer.empty, src_paths);
   537 
   538     val doc_path = File.tmp_path document_path;
   539     val result_path = Path.append doc_path Path.parent;
   540     val _ = File.mkdir doc_path;
   541     val root_path = Path.append doc_path (Path.basic "root.tex");
   542     val _ = File.copy (Path.explode "~~/lib/texinputs/draft.tex") root_path;
   543     val _ = File.isatool ("latex -o sty " ^ File.shell_path root_path);
   544     val _ = File.isatool ("latex -o syms " ^ File.shell_path root_path);
   545 
   546     fun known name =
   547       let val ss = split_lines (File.read (Path.append doc_path (Path.basic name)))
   548       in member (op =) ss end;
   549     val known_syms = known "syms.lst";
   550     val known_ctrls = known "ctrls.lst";
   551 
   552     val _ = srcs |> List.app (fn (name, base, txt) =>
   553       Symbol.explode txt
   554       |> Latex.symbol_source (known_syms, known_ctrls) (Path.implode base)
   555       |> File.write (Path.append doc_path (tex_path name)));
   556     val _ = write_tex_index tex_index doc_path;
   557   in isatool_document false doc_format documentN "" doc_path result_path end;
   558 
   559 
   560 end;
   561 
   562 structure BasicPresent: BASIC_PRESENT = Present;
   563 open BasicPresent;