src/Pure/Isar/method.ML
author kleing
Wed Feb 11 14:48:14 2009 +1100 (2009-02-11)
changeset 29857 2cc976ed8a3c
parent 29301 2b845381ba6a
child 30165 6ee87f67d9cd
child 30240 5b25fee0362c
permissions -rw-r--r--
FindTheorems: add solves feature; tidy up const name subsettin; patch by Timothy Bourke
     1 (*  Title:      Pure/Isar/method.ML
     2     Author:     Markus Wenzel, TU Muenchen
     3 
     4 Isar proof methods.
     5 *)
     6 
     7 signature BASIC_METHOD =
     8 sig
     9   val FINDGOAL: (int -> thm -> 'a Seq.seq) -> thm -> 'a Seq.seq
    10   val HEADGOAL: (int -> thm -> 'a Seq.seq) -> thm -> 'a Seq.seq
    11   type method
    12   val trace_rules: bool ref
    13 end;
    14 
    15 signature METHOD =
    16 sig
    17   include BASIC_METHOD
    18   val apply: Position.T -> (Proof.context -> method) -> Proof.context -> thm list -> cases_tactic
    19   val RAW_METHOD_CASES: (thm list -> cases_tactic) -> method
    20   val RAW_METHOD: (thm list -> tactic) -> method
    21   val METHOD_CASES: (thm list -> cases_tactic) -> method
    22   val METHOD: (thm list -> tactic) -> method
    23   val fail: method
    24   val succeed: method
    25   val insert_tac: thm list -> int -> tactic
    26   val insert: thm list -> method
    27   val insert_facts: method
    28   val SIMPLE_METHOD: tactic -> method
    29   val SIMPLE_METHOD': (int -> tactic) -> method
    30   val SIMPLE_METHOD'': ((int -> tactic) -> tactic) -> (int -> tactic) -> method
    31   val defer: int option -> method
    32   val prefer: int -> method
    33   val cheating: bool -> Proof.context -> method
    34   val intro: thm list -> method
    35   val elim: thm list -> method
    36   val unfold: thm list -> Proof.context -> method
    37   val fold: thm list -> Proof.context -> method
    38   val atomize: bool -> method
    39   val this: method
    40   val fact: thm list -> Proof.context -> method
    41   val assumption_tac: Proof.context -> int -> tactic
    42   val assumption: Proof.context -> method
    43   val close: bool -> Proof.context -> method
    44   val trace: Proof.context -> thm list -> unit
    45   val rule_tac: thm list -> thm list -> int -> tactic
    46   val some_rule_tac: thm list -> Proof.context -> thm list -> int -> tactic
    47   val intros_tac: thm list -> thm list -> tactic
    48   val rule: thm list -> method
    49   val erule: int -> thm list -> method
    50   val drule: int -> thm list -> method
    51   val frule: int -> thm list -> method
    52   val iprover_tac: Proof.context -> int option -> int -> tactic
    53   val set_tactic: (thm list -> tactic) -> Proof.context -> Proof.context
    54   val tactic: string * Position.T -> Proof.context -> method
    55   val raw_tactic: string * Position.T -> Proof.context -> method
    56   type src = Args.src
    57   datatype text =
    58     Basic of (Proof.context -> method) * Position.T |
    59     Source of src |
    60     Source_i of src |
    61     Then of text list |
    62     Orelse of text list |
    63     Try of text |
    64     Repeat1 of text |
    65     SelectGoals of int * text
    66   val primitive_text: (thm -> thm) -> text
    67   val succeed_text: text
    68   val default_text: text
    69   val this_text: text
    70   val done_text: text
    71   val sorry_text: bool -> text
    72   val finish_text: text option * bool -> Position.T -> text
    73   val print_methods: theory -> unit
    74   val intern: theory -> xstring -> string
    75   val defined: theory -> string -> bool
    76   val method: theory -> src -> Proof.context -> method
    77   val method_i: theory -> src -> Proof.context -> method
    78   val add_methods: (bstring * (src -> Proof.context -> method) * string) list
    79     -> theory -> theory
    80   val add_method: bstring * (src -> Proof.context -> method) * string
    81     -> theory -> theory
    82   val method_setup: bstring -> string * Position.T -> string -> theory -> theory
    83   val syntax: (Context.generic * Args.T list -> 'a * (Context.generic * Args.T list))
    84     -> src -> Proof.context -> 'a * Proof.context
    85   val simple_args: (Args.T list -> 'a * Args.T list)
    86     -> ('a -> Proof.context -> method) -> src -> Proof.context -> method
    87   val ctxt_args: (Proof.context -> method) -> src -> Proof.context -> method
    88   val no_args: method -> src -> Proof.context -> method
    89   type modifier
    90   val sectioned_args: (Context.generic * Args.T list -> 'a * (Context.generic * Args.T list)) ->
    91     (Args.T list -> modifier * Args.T list) list ->
    92     ('a -> Proof.context -> 'b) -> src -> Proof.context -> 'b
    93   val bang_sectioned_args:
    94     (Args.T list -> modifier * Args.T list) list ->
    95     (thm list -> Proof.context -> 'a) -> src -> Proof.context -> 'a
    96   val bang_sectioned_args':
    97     (Args.T list -> modifier * Args.T list) list ->
    98     (Context.generic * Args.T list -> 'a * (Context.generic * Args.T list)) ->
    99     ('a -> thm list -> Proof.context -> 'b) -> src -> Proof.context -> 'b
   100   val only_sectioned_args:
   101     (Args.T list -> modifier * Args.T list) list ->
   102     (Proof.context -> 'a) -> src -> Proof.context -> 'a
   103   val thms_ctxt_args: (thm list -> Proof.context -> 'a) -> src ->
   104     Proof.context -> 'a
   105   val thms_args: (thm list -> 'a) -> src -> Proof.context -> 'a
   106   val thm_args: (thm -> 'a) -> src -> Proof.context -> 'a
   107   val goal_args: (Args.T list -> 'a * Args.T list) -> ('a -> int -> tactic)
   108     -> src -> Proof.context -> method
   109   val goal_args': (Context.generic * Args.T list -> 'a * (Context.generic * Args.T list))
   110     -> ('a -> int -> tactic) -> src -> Proof.context -> method
   111   val goal_args_ctxt: (Args.T list -> 'a * Args.T list) ->
   112     (Proof.context -> 'a -> int -> tactic) -> src -> Proof.context -> method
   113   val goal_args_ctxt': (Context.generic * Args.T list -> 'a * (Context.generic * Args.T list)) ->
   114     (Proof.context -> 'a -> int -> tactic) -> src -> Proof.context -> method
   115   val parse: OuterLex.token list -> text * OuterLex.token list
   116 end;
   117 
   118 structure Method: METHOD =
   119 struct
   120 
   121 (** generic tools **)
   122 
   123 (* goal addressing *)
   124 
   125 fun FINDGOAL tac st =
   126   let fun find i n = if i > n then Seq.fail else Seq.APPEND (tac i, find (i + 1) n)
   127   in find 1 (Thm.nprems_of st) st end;
   128 
   129 fun HEADGOAL tac = tac 1;
   130 
   131 
   132 
   133 (** proof methods **)
   134 
   135 (* datatype method *)
   136 
   137 datatype method = Meth of thm list -> cases_tactic;
   138 
   139 fun apply pos meth_fun ctxt facts goal = Position.setmp_thread_data_seq pos
   140   (fn () => let val Meth meth = meth_fun ctxt in meth facts goal end) ();
   141 
   142 val RAW_METHOD_CASES = Meth;
   143 
   144 fun RAW_METHOD tac = RAW_METHOD_CASES (NO_CASES o tac);
   145 
   146 fun METHOD_CASES tac = RAW_METHOD_CASES (fn facts =>
   147   Seq.THEN (ALLGOALS Goal.conjunction_tac, tac facts));
   148 
   149 fun METHOD tac = RAW_METHOD (fn facts => ALLGOALS Goal.conjunction_tac THEN tac facts);
   150 
   151 val fail = METHOD (K no_tac);
   152 val succeed = METHOD (K all_tac);
   153 
   154 
   155 (* insert facts *)
   156 
   157 local
   158 
   159 fun cut_rule_tac rule =
   160   Tactic.rtac (Drule.forall_intr_vars rule COMP_INCR revcut_rl);
   161 
   162 in
   163 
   164 fun insert_tac [] i = all_tac
   165   | insert_tac facts i = EVERY (map (fn th => cut_rule_tac th i) facts);
   166 
   167 val insert_facts = METHOD (ALLGOALS o insert_tac);
   168 fun insert thms = METHOD (fn _ => ALLGOALS (insert_tac thms));
   169 
   170 fun SIMPLE_METHOD tac = METHOD (fn facts => ALLGOALS (insert_tac facts) THEN tac);
   171 fun SIMPLE_METHOD'' quant tac = METHOD (fn facts => quant (insert_tac facts THEN' tac));
   172 val SIMPLE_METHOD' = SIMPLE_METHOD'' HEADGOAL;
   173 
   174 end;
   175 
   176 
   177 (* shuffle subgoals *)
   178 
   179 fun prefer i = METHOD (K (Tactic.defer_tac i THEN PRIMITIVE (Thm.permute_prems 0 ~1)));
   180 fun defer opt_i = METHOD (K (Tactic.defer_tac (the_default 1 opt_i)));
   181 
   182 
   183 (* cheating *)
   184 
   185 fun cheating int ctxt = METHOD (K (setmp quick_and_dirty (int orelse ! quick_and_dirty)
   186     (SkipProof.cheat_tac (ProofContext.theory_of ctxt))));
   187 
   188 
   189 (* unfold intro/elim rules *)
   190 
   191 fun intro ths = SIMPLE_METHOD' (CHANGED_PROP o REPEAT_ALL_NEW (Tactic.match_tac ths));
   192 fun elim ths = SIMPLE_METHOD' (CHANGED_PROP o REPEAT_ALL_NEW (Tactic.ematch_tac ths));
   193 
   194 
   195 (* unfold/fold definitions *)
   196 
   197 fun unfold_meth ths ctxt = SIMPLE_METHOD (CHANGED_PROP (LocalDefs.unfold_tac ctxt ths));
   198 fun fold_meth ths ctxt = SIMPLE_METHOD (CHANGED_PROP (LocalDefs.fold_tac ctxt ths));
   199 
   200 
   201 (* atomize rule statements *)
   202 
   203 fun atomize false = SIMPLE_METHOD' (CHANGED_PROP o ObjectLogic.atomize_prems_tac)
   204   | atomize true = RAW_METHOD (K (HEADGOAL (CHANGED_PROP o ObjectLogic.full_atomize_tac)));
   205 
   206 
   207 (* this -- resolve facts directly *)
   208 
   209 val this = METHOD (EVERY o map (HEADGOAL o Tactic.rtac));
   210 
   211 
   212 (* fact -- composition by facts from context *)
   213 
   214 fun fact [] ctxt = SIMPLE_METHOD' (ProofContext.some_fact_tac ctxt)
   215   | fact rules _ = SIMPLE_METHOD' (ProofContext.fact_tac rules);
   216 
   217 
   218 (* assumption *)
   219 
   220 local
   221 
   222 fun cond_rtac cond rule = SUBGOAL (fn (prop, i) =>
   223   if cond (Logic.strip_assums_concl prop)
   224   then Tactic.rtac rule i else no_tac);
   225 
   226 in
   227 
   228 fun assumption_tac ctxt =
   229   assume_tac APPEND'
   230   Goal.assume_rule_tac ctxt APPEND'
   231   cond_rtac (can Logic.dest_equals) Drule.reflexive_thm APPEND'
   232   cond_rtac (can Logic.dest_term) Drule.termI;
   233 
   234 fun assumption ctxt = METHOD (HEADGOAL o
   235   (fn [] => assumption_tac ctxt
   236     | [fact] => solve_tac [fact]
   237     | _ => K no_tac));
   238 
   239 fun close immed ctxt = METHOD (K
   240   (FILTER Thm.no_prems
   241     ((if immed then ALLGOALS (assumption_tac ctxt) else all_tac) THEN flexflex_tac)));
   242 
   243 end;
   244 
   245 
   246 (* rule etc. -- single-step refinements *)
   247 
   248 val trace_rules = ref false;
   249 
   250 fun trace ctxt rules =
   251   if ! trace_rules andalso not (null rules) then
   252     Pretty.big_list "rules:" (map (ProofContext.pretty_thm ctxt) rules)
   253     |> Pretty.string_of |> tracing
   254   else ();
   255 
   256 local
   257 
   258 fun gen_rule_tac tac rules facts =
   259   (fn i => fn st =>
   260     if null facts then tac rules i st
   261     else Seq.maps (fn rule => (tac o single) rule i st) (Drule.multi_resolves facts rules))
   262   THEN_ALL_NEW Goal.norm_hhf_tac;
   263 
   264 fun gen_arule_tac tac j rules facts =
   265   EVERY' (gen_rule_tac tac rules facts :: replicate j Tactic.assume_tac);
   266 
   267 fun gen_some_rule_tac tac arg_rules ctxt facts = SUBGOAL (fn (goal, i) =>
   268   let
   269     val rules =
   270       if not (null arg_rules) then arg_rules
   271       else flat (ContextRules.find_rules false facts goal ctxt)
   272   in trace ctxt rules; tac rules facts i end);
   273 
   274 fun meth tac x = METHOD (HEADGOAL o tac x);
   275 fun meth' tac x y = METHOD (HEADGOAL o tac x y);
   276 
   277 in
   278 
   279 val rule_tac = gen_rule_tac Tactic.resolve_tac;
   280 val rule = meth rule_tac;
   281 val some_rule_tac = gen_some_rule_tac rule_tac;
   282 val some_rule = meth' some_rule_tac;
   283 
   284 val erule = meth' (gen_arule_tac Tactic.eresolve_tac);
   285 val drule = meth' (gen_arule_tac Tactic.dresolve_tac);
   286 val frule = meth' (gen_arule_tac Tactic.forward_tac);
   287 
   288 end;
   289 
   290 
   291 (* intros_tac -- pervasive search spanned by intro rules *)
   292 
   293 fun intros_tac intros facts =
   294   ALLGOALS (insert_tac facts THEN'
   295       REPEAT_ALL_NEW (resolve_tac intros))
   296     THEN Tactic.distinct_subgoals_tac;
   297 
   298 
   299 (* iprover -- intuitionistic proof search *)
   300 
   301 local
   302 
   303 val remdups_tac = SUBGOAL (fn (g, i) =>
   304   let val prems = Logic.strip_assums_hyp g in
   305     REPEAT_DETERM_N (length prems - length (distinct op aconv prems))
   306     (Tactic.ematch_tac [Drule.remdups_rl] i THEN Tactic.eq_assume_tac i)
   307   end);
   308 
   309 fun REMDUPS tac = tac THEN_ALL_NEW remdups_tac;
   310 
   311 val bires_tac = Tactic.biresolution_from_nets_tac ContextRules.orderlist;
   312 
   313 fun safe_step_tac ctxt =
   314   ContextRules.Swrap ctxt
   315    (eq_assume_tac ORELSE'
   316     bires_tac true (ContextRules.netpair_bang ctxt));
   317 
   318 fun unsafe_step_tac ctxt =
   319   ContextRules.wrap ctxt
   320    (assume_tac APPEND'
   321     bires_tac false (ContextRules.netpair_bang ctxt) APPEND'
   322     bires_tac false (ContextRules.netpair ctxt));
   323 
   324 fun step_tac ctxt i =
   325   REPEAT_DETERM1 (REMDUPS (safe_step_tac ctxt) i) ORELSE
   326   REMDUPS (unsafe_step_tac ctxt) i;
   327 
   328 fun intprover_tac ctxt gs d lim = SUBGOAL (fn (g, i) => if d > lim then no_tac else
   329   let
   330     val ps = Logic.strip_assums_hyp g;
   331     val c = Logic.strip_assums_concl g;
   332   in
   333     if member (fn ((ps1, c1), (ps2, c2)) =>
   334         c1 aconv c2 andalso
   335         length ps1 = length ps2 andalso
   336         gen_eq_set (op aconv) (ps1, ps2)) gs (ps, c) then no_tac
   337     else (step_tac ctxt THEN_ALL_NEW intprover_tac ctxt ((ps, c) :: gs) (d + 1) lim) i
   338   end);
   339 
   340 in
   341 
   342 fun iprover_tac ctxt opt_lim =
   343   SELECT_GOAL (DEEPEN (2, the_default 20 opt_lim) (intprover_tac ctxt [] 0) 4 1);
   344 
   345 end;
   346 
   347 
   348 (* ML tactics *)
   349 
   350 structure TacticData = ProofDataFun
   351 (
   352   type T = thm list -> tactic;
   353   fun init _ = undefined;
   354 );
   355 
   356 val set_tactic = TacticData.put;
   357 
   358 fun ml_tactic (txt, pos) ctxt =
   359   let
   360     val ctxt' = ctxt |> Context.proof_map
   361       (ML_Context.expression pos
   362         "fun tactic (facts: thm list) : tactic"
   363         "Context.map_proof (Method.set_tactic tactic)" txt);
   364   in Context.setmp_thread_data (SOME (Context.Proof ctxt)) (TacticData.get ctxt') end;
   365 
   366 fun tactic txt ctxt = METHOD (ml_tactic txt ctxt);
   367 fun raw_tactic txt ctxt = RAW_METHOD (ml_tactic txt ctxt);
   368 
   369 
   370 
   371 (** method syntax **)
   372 
   373 (* method text *)
   374 
   375 type src = Args.src;
   376 
   377 datatype text =
   378   Basic of (Proof.context -> method) * Position.T |
   379   Source of src |
   380   Source_i of src |
   381   Then of text list |
   382   Orelse of text list |
   383   Try of text |
   384   Repeat1 of text |
   385   SelectGoals of int * text;
   386 
   387 fun primitive_text r = Basic (K (SIMPLE_METHOD (PRIMITIVE r)), Position.none);
   388 val succeed_text = Basic (K succeed, Position.none);
   389 val default_text = Source (Args.src (("default", []), Position.none));
   390 val this_text = Basic (K this, Position.none);
   391 val done_text = Basic (K (SIMPLE_METHOD all_tac), Position.none);
   392 fun sorry_text int = Basic (cheating int, Position.none);
   393 
   394 fun finish_text (NONE, immed) pos = Basic (close immed, pos)
   395   | finish_text (SOME txt, immed) pos = Then [txt, Basic (close immed, pos)];
   396 
   397 
   398 (* method definitions *)
   399 
   400 structure Methods = TheoryDataFun
   401 (
   402   type T = (((src -> Proof.context -> method) * string) * stamp) NameSpace.table;
   403   val empty = NameSpace.empty_table;
   404   val copy = I;
   405   val extend = I;
   406   fun merge _ tables : T = NameSpace.merge_tables (eq_snd (op =)) tables handle Symtab.DUP dup =>
   407     error ("Attempt to merge different versions of method " ^ quote dup);
   408 );
   409 
   410 fun print_methods thy =
   411   let
   412     val meths = Methods.get thy;
   413     fun prt_meth (name, ((_, comment), _)) = Pretty.block
   414       [Pretty.str (name ^ ":"), Pretty.brk 2, Pretty.str comment];
   415   in
   416     [Pretty.big_list "methods:" (map prt_meth (NameSpace.extern_table meths))]
   417     |> Pretty.chunks |> Pretty.writeln
   418   end;
   419 
   420 
   421 (* get methods *)
   422 
   423 val intern = NameSpace.intern o #1 o Methods.get;
   424 val defined = Symtab.defined o #2 o Methods.get;
   425 
   426 fun method_i thy =
   427   let
   428     val meths = #2 (Methods.get thy);
   429     fun meth src =
   430       let val ((name, _), pos) = Args.dest_src src in
   431         (case Symtab.lookup meths name of
   432           NONE => error ("Unknown proof method: " ^ quote name ^ Position.str_of pos)
   433         | SOME ((mth, _), _) => (Position.report (Markup.method name) pos; mth src))
   434       end;
   435   in meth end;
   436 
   437 fun method thy = method_i thy o Args.map_name (NameSpace.intern (#1 (Methods.get thy)));
   438 
   439 
   440 (* add method *)
   441 
   442 fun add_methods raw_meths thy =
   443   let
   444     val new_meths = raw_meths |> map (fn (name, f, comment) =>
   445       (Binding.name name, ((f, comment), stamp ())));
   446 
   447     fun add meths = fold (snd oo NameSpace.bind (Sign.naming_of thy)) new_meths meths
   448       handle Symtab.DUP dup => error ("Duplicate declaration of method " ^ quote dup);
   449   in Methods.map add thy end;
   450 
   451 val add_method = add_methods o Library.single;
   452 
   453 
   454 (* method_setup *)
   455 
   456 fun method_setup name (txt, pos) cmt =
   457   Context.theory_map (ML_Context.expression pos
   458     "val method: bstring * (Method.src -> Proof.context -> Proof.method) * string"
   459     "Context.map_theory (Method.add_method method)"
   460     ("(" ^ quote name ^ ", " ^ txt ^ ", " ^ quote cmt ^ ")"));
   461 
   462 
   463 
   464 (** concrete syntax **)
   465 
   466 structure P = OuterParse;
   467 
   468 
   469 (* basic *)
   470 
   471 fun syntax scan = Args.context_syntax "method" scan;
   472 
   473 fun simple_args scan f src ctxt : method =
   474   fst (syntax (Scan.lift (scan >> (fn x => f x ctxt))) src ctxt);
   475 
   476 fun ctxt_args (f: Proof.context -> method) src ctxt =
   477   fst (syntax (Scan.succeed (f ctxt)) src ctxt);
   478 
   479 fun no_args m = ctxt_args (K m);
   480 
   481 
   482 (* sections *)
   483 
   484 type modifier = (Proof.context -> Proof.context) * attribute;
   485 
   486 local
   487 
   488 fun thms ss = Scan.repeat (Scan.unless (Scan.lift (Scan.first ss)) Attrib.multi_thm) >> flat;
   489 fun app (f, att) (context, ths) = foldl_map att (Context.map_proof f context, ths);
   490 
   491 fun section ss = Scan.depend (fn context => (Scan.first ss -- Scan.pass context (thms ss)) :|--
   492   (fn (m, ths) => Scan.succeed (app m (context, ths))));
   493 
   494 fun sectioned args ss = args -- Scan.repeat (section ss);
   495 
   496 in
   497 
   498 fun sectioned_args args ss f src ctxt =
   499   let val ((x, _), ctxt') = syntax (sectioned args ss) src ctxt
   500   in f x ctxt' end;
   501 
   502 fun bang_sectioned_args ss f = sectioned_args Args.bang_facts ss f;
   503 fun bang_sectioned_args' ss scan f =
   504   sectioned_args (Args.bang_facts -- scan >> swap) ss (uncurry f);
   505 fun only_sectioned_args ss f = sectioned_args (Scan.succeed ()) ss (fn () => f);
   506 
   507 fun thms_ctxt_args f = sectioned_args (thms []) [] f;
   508 fun thms_args f = thms_ctxt_args (K o f);
   509 fun thm_args f = thms_args (fn [thm] => f thm | _ => error "Single theorem expected");
   510 
   511 end;
   512 
   513 
   514 (* iprover syntax *)
   515 
   516 local
   517 
   518 val introN = "intro";
   519 val elimN = "elim";
   520 val destN = "dest";
   521 val ruleN = "rule";
   522 
   523 fun modifier name kind kind' att =
   524   Args.$$$ name |-- (kind >> K NONE || kind' |-- P.nat --| Args.colon >> SOME)
   525     >> (pair (I: Proof.context -> Proof.context) o att);
   526 
   527 val iprover_modifiers =
   528  [modifier destN Args.bang_colon Args.bang ContextRules.dest_bang,
   529   modifier destN Args.colon (Scan.succeed ()) ContextRules.dest,
   530   modifier elimN Args.bang_colon Args.bang ContextRules.elim_bang,
   531   modifier elimN Args.colon (Scan.succeed ()) ContextRules.elim,
   532   modifier introN Args.bang_colon Args.bang ContextRules.intro_bang,
   533   modifier introN Args.colon (Scan.succeed ()) ContextRules.intro,
   534   Args.del -- Args.colon >> K (I, ContextRules.rule_del)];
   535 
   536 in
   537 
   538 val iprover_meth =
   539   bang_sectioned_args' iprover_modifiers (Scan.lift (Scan.option P.nat))
   540     (fn n => fn prems => fn ctxt => METHOD (fn facts =>
   541       HEADGOAL (insert_tac (prems @ facts) THEN'
   542       ObjectLogic.atomize_prems_tac THEN' iprover_tac ctxt n)));
   543 
   544 end;
   545 
   546 
   547 (* tactic syntax *)
   548 
   549 fun nat_thms_args f = uncurry f oo
   550   (fst oo syntax (Scan.lift (Scan.optional (Args.parens P.nat) 0) -- Attrib.thms));
   551 
   552 fun goal_args' args tac src ctxt = fst (syntax (Args.goal_spec HEADGOAL -- args >>
   553   (fn (quant, s) => SIMPLE_METHOD'' quant (tac s))) src ctxt);
   554 
   555 fun goal_args args tac = goal_args' (Scan.lift args) tac;
   556 
   557 fun goal_args_ctxt' args tac src ctxt =
   558   fst (syntax (Args.goal_spec HEADGOAL -- args >>
   559   (fn (quant, s) => SIMPLE_METHOD'' quant (tac ctxt s))) src ctxt);
   560 
   561 fun goal_args_ctxt args tac = goal_args_ctxt' (Scan.lift args) tac;
   562 
   563 
   564 (* outer parser *)
   565 
   566 fun is_symid_meth s =
   567   s <> "|" andalso s <> "?" andalso s <> "+" andalso OuterLex.ident_or_symbolic s;
   568 
   569 local
   570 
   571 fun meth4 x =
   572  (P.position (P.xname >> rpair []) >> (Source o Args.src) ||
   573   P.$$$ "(" |-- P.!!! (meth0 --| P.$$$ ")")) x
   574 and meth3 x =
   575  (meth4 --| P.$$$ "?" >> Try ||
   576   meth4 --| P.$$$ "+" >> Repeat1 ||
   577   meth4 -- (P.$$$ "[" |-- Scan.optional P.nat 1 --| P.$$$ "]") >> (SelectGoals o swap) ||
   578   meth4) x
   579 and meth2 x =
   580  (P.position (P.xname -- Args.parse1 is_symid_meth) >> (Source o Args.src) ||
   581   meth3) x
   582 and meth1 x = (P.enum1 "," meth2 >> (fn [m] => m | ms => Then ms)) x
   583 and meth0 x = (P.enum1 "|" meth1 >> (fn [m] => m | ms => Orelse ms)) x;
   584 
   585 in val parse = meth3 end;
   586 
   587 
   588 (* theory setup *)
   589 
   590 val _ = Context.>> (Context.map_theory
   591   (add_methods
   592    [("fail", no_args fail, "force failure"),
   593     ("succeed", no_args succeed, "succeed"),
   594     ("-", no_args insert_facts, "do nothing (insert current facts only)"),
   595     ("insert", thms_args insert, "insert theorems, ignoring facts (improper)"),
   596     ("intro", thms_args intro, "repeatedly apply introduction rules"),
   597     ("elim", thms_args elim, "repeatedly apply elimination rules"),
   598     ("unfold", thms_ctxt_args unfold_meth, "unfold definitions"),
   599     ("fold", thms_ctxt_args fold_meth, "fold definitions"),
   600     ("atomize", (atomize o fst) oo syntax (Args.mode "full"),
   601       "present local premises as object-level statements"),
   602     ("iprover", iprover_meth, "intuitionistic proof search"),
   603     ("rule", thms_ctxt_args some_rule, "apply some intro/elim rule"),
   604     ("erule", nat_thms_args erule, "apply rule in elimination manner (improper)"),
   605     ("drule", nat_thms_args drule, "apply rule in destruct manner (improper)"),
   606     ("frule", nat_thms_args frule, "apply rule in forward manner (improper)"),
   607     ("this", no_args this, "apply current facts as rules"),
   608     ("fact", thms_ctxt_args fact, "composition by facts from context"),
   609     ("assumption", ctxt_args assumption, "proof by assumption, preferring facts"),
   610     ("rename_tac", goal_args (Scan.repeat1 Args.name) Tactic.rename_tac,
   611       "rename parameters of goal"),
   612     ("rotate_tac", goal_args (Scan.optional P.int 1) Tactic.rotate_tac,
   613       "rotate assumptions of goal"),
   614     ("tactic", simple_args (P.position Args.name) tactic, "ML tactic as proof method"),
   615     ("raw_tactic", simple_args (P.position Args.name) raw_tactic,
   616       "ML tactic as raw proof method")]));
   617 
   618 
   619 (*final declarations of this structure!*)
   620 val unfold = unfold_meth;
   621 val fold = fold_meth;
   622 
   623 end;
   624 
   625 structure BasicMethod: BASIC_METHOD = Method;
   626 open BasicMethod;