src/Pure/library.ML
author wenzelm
Fri Aug 03 22:33:03 2007 +0200 (2007-08-03)
changeset 24148 2d4ee876c215
parent 24049 e4adf8175149
child 24593 1547ea587f5a
permissions -rw-r--r--
named some CRITICAL sections;
     1 (*  Title:      Pure/library.ML
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     4     Author:     Markus Wenzel, TU Muenchen
     5 
     6 Basic library: functions, options, pairs, booleans, lists, integers,
     7 strings, lists as sets, orders, current directory, misc.
     8 
     9 See also General/basics.ML for the most fundamental concepts.
    10 *)
    11 
    12 infix 1 |>>>
    13 infix 2 ?
    14 infix 3 o oo ooo oooo
    15 infix 4 ~~ upto downto
    16 infix orf andf \ \\ mem mem_int mem_string union union_int
    17   union_string inter inter_int inter_string subset subset_int subset_string
    18 
    19 signature BASIC_LIBRARY =
    20 sig
    21   (*functions*)
    22   val undefined: 'a -> 'b
    23   val I: 'a -> 'a
    24   val K: 'a -> 'b -> 'a
    25   val flip: ('a -> 'b -> 'c) -> 'b -> 'a -> 'c
    26   val curry: ('a * 'b -> 'c) -> 'a -> 'b -> 'c
    27   val uncurry: ('a -> 'b -> 'c) -> 'a * 'b -> 'c
    28   val |>>> : ('a * 'c) * ('a -> 'b * 'd) -> 'b * ('c * 'd)
    29   val ? : bool * ('a -> 'a) -> 'a -> 'a
    30   val oo: ('a -> 'b) * ('c -> 'd -> 'a) -> 'c -> 'd -> 'b
    31   val ooo: ('a -> 'b) * ('c -> 'd -> 'e -> 'a) -> 'c -> 'd -> 'e -> 'b
    32   val oooo: ('a -> 'b) * ('c -> 'd -> 'e -> 'f -> 'a) -> 'c -> 'd -> 'e -> 'f -> 'b
    33   val funpow: int -> ('a -> 'a) -> 'a -> 'a
    34 
    35   (*errors*)
    36   exception SYS_ERROR of string
    37   val sys_error: string -> 'a
    38   exception ERROR of string
    39   val error: string -> 'a
    40   val cat_error: string -> string -> 'a
    41   val assert_all: ('a -> bool) -> 'a list -> ('a -> string) -> unit
    42 
    43   (*pairs*)
    44   val pair: 'a -> 'b -> 'a * 'b
    45   val rpair: 'a -> 'b -> 'b * 'a
    46   val fst: 'a * 'b -> 'a
    47   val snd: 'a * 'b -> 'b
    48   val eq_fst: ('a * 'c -> bool) -> ('a * 'b) * ('c * 'd) -> bool
    49   val eq_snd: ('b * 'd -> bool) -> ('a * 'b) * ('c * 'd) -> bool
    50   val eq_pair: ('a * 'c -> bool) -> ('b * 'd -> bool) -> ('a * 'b) * ('c * 'd) -> bool
    51   val swap: 'a * 'b -> 'b * 'a
    52   val apfst: ('a -> 'b) -> 'a * 'c -> 'b * 'c
    53   val apsnd: ('a -> 'b) -> 'c * 'a -> 'c * 'b
    54   val pairself: ('a -> 'b) -> 'a * 'a -> 'b * 'b
    55 
    56   (*booleans*)
    57   val equal: ''a -> ''a -> bool
    58   val not_equal: ''a -> ''a -> bool
    59   val orf: ('a -> bool) * ('a -> bool) -> 'a -> bool
    60   val andf: ('a -> bool) * ('a -> bool) -> 'a -> bool
    61   val exists: ('a -> bool) -> 'a list -> bool
    62   val forall: ('a -> bool) -> 'a list -> bool
    63   val set: bool ref -> bool
    64   val reset: bool ref -> bool
    65   val toggle: bool ref -> bool
    66   val change: 'a ref -> ('a -> 'a) -> unit
    67   val setmp_noncritical: 'a ref -> 'a -> ('b -> 'c) -> 'b -> 'c
    68   val setmp: 'a ref -> 'a -> ('b -> 'c) -> 'b -> 'c
    69 
    70   (*lists*)
    71   exception UnequalLengths
    72   val single: 'a -> 'a list
    73   val the_single: 'a list -> 'a
    74   val singleton: ('a list -> 'b list) -> 'a -> 'b
    75   val apply: ('a -> 'a) list -> 'a -> 'a
    76   val foldr1: ('a * 'a -> 'a) -> 'a list -> 'a
    77   val foldl_map: ('a * 'b -> 'a * 'c) -> 'a * 'b list -> 'a * 'c list
    78   val flat: 'a list list -> 'a list
    79   val unflat: 'a list list -> 'b list -> 'b list list
    80   val burrow: ('a list -> 'b list) -> 'a list list -> 'b list list
    81   val fold_burrow: ('a list -> 'c -> 'b list * 'd) -> 'a list list -> 'c -> 'b list list * 'd
    82   val maps: ('a -> 'b list) -> 'a list -> 'b list
    83   val chop: int -> 'a list -> 'a list * 'a list
    84   val dropwhile: ('a -> bool) -> 'a list -> 'a list
    85   val nth: 'a list -> int -> 'a
    86   val nth_map: int -> ('a -> 'a) -> 'a list -> 'a list
    87   val nth_list: 'a list list -> int -> 'a list
    88   val map_index: (int * 'a -> 'b) -> 'a list -> 'b list
    89   val fold_index: (int * 'a -> 'b -> 'b) -> 'a list -> 'b -> 'b
    90   val split_last: 'a list -> 'a list * 'a
    91   val find_index: ('a -> bool) -> 'a list -> int
    92   val find_index_eq: ''a -> ''a list -> int
    93   val find_first: ('a -> bool) -> 'a list -> 'a option
    94   val get_index: ('a -> 'b option) -> 'a list -> (int * 'b) option
    95   val get_first: ('a -> 'b option) -> 'a list -> 'b option
    96   val eq_list: ('a * 'b -> bool) -> 'a list * 'b list -> bool
    97   val map2: ('a -> 'b -> 'c) -> 'a list -> 'b list -> 'c list
    98   val fold2: ('a -> 'b -> 'c -> 'c) -> 'a list -> 'b list -> 'c -> 'c
    99   val zip_options: 'a list -> 'b option list -> ('a * 'b) list
   100   val ~~ : 'a list * 'b list -> ('a * 'b) list
   101   val split_list: ('a * 'b) list -> 'a list * 'b list
   102   val separate: 'a -> 'a list -> 'a list
   103   val replicate: int -> 'a -> 'a list
   104   val multiply: 'a list -> 'a list list -> 'a list list
   105   val product: 'a list -> 'b list -> ('a * 'b) list
   106   val filter: ('a -> bool) -> 'a list -> 'a list
   107   val filter_out: ('a -> bool) -> 'a list -> 'a list
   108   val map_filter: ('a -> 'b option) -> 'a list -> 'b list
   109   val is_prefix: ('a * 'a -> bool) -> 'a list -> 'a list -> bool
   110   val take_prefix: ('a -> bool) -> 'a list -> 'a list * 'a list
   111   val chop_prefix: ('a * 'b -> bool) -> 'a list * 'b list -> 'a list * ('a list * 'b list)
   112   val take_suffix: ('a -> bool) -> 'a list -> 'a list * 'a list
   113   val prefixes1: 'a list -> 'a list list
   114   val prefixes: 'a list -> 'a list list
   115   val suffixes1: 'a list -> 'a list list
   116   val suffixes: 'a list -> 'a list list
   117 
   118   (*integers*)
   119   val inc: int ref -> int
   120   val dec: int ref -> int
   121   val upto: int * int -> int list
   122   val downto: int * int -> int list
   123   val radixpand: int * int -> int list
   124   val radixstring: int * string * int -> string
   125   val string_of_int: int -> string
   126   val signed_string_of_int: int -> string
   127   val string_of_indexname: string * int -> string
   128   val read_intinf: int -> string list -> IntInf.int * string list
   129   val read_int: string list -> int * string list
   130   val oct_char: string -> string
   131 
   132   (*strings*)
   133   val nth_string: string -> int -> string
   134   val fold_string: (string -> 'a -> 'a) -> string -> 'a -> 'a
   135   val exists_string: (string -> bool) -> string -> bool
   136   val forall_string: (string -> bool) -> string -> bool
   137   val enclose: string -> string -> string -> string
   138   val unenclose: string -> string
   139   val quote: string -> string
   140   val space_implode: string -> string list -> string
   141   val commas: string list -> string
   142   val commas_quote: string list -> string
   143   val cat_lines: string list -> string
   144   val space_explode: string -> string -> string list
   145   val split_lines: string -> string list
   146   val prefix_lines: string -> string -> string
   147   val untabify: string list -> string list
   148   val prefix: string -> string -> string
   149   val suffix: string -> string -> string
   150   val unprefix: string -> string -> string
   151   val unsuffix: string -> string -> string
   152   val replicate_string: int -> string -> string
   153   val translate_string: (string -> string) -> string -> string
   154 
   155   (*lists as sets -- see also Pure/General/ord_list.ML*)
   156   val member: ('b * 'a -> bool) -> 'a list -> 'b -> bool
   157   val insert: ('a * 'a -> bool) -> 'a -> 'a list -> 'a list
   158   val remove: ('b * 'a -> bool) -> 'b -> 'a list -> 'a list
   159   val update: ('a * 'a -> bool) -> 'a -> 'a list -> 'a list
   160   val subtract: ('b * 'a -> bool) -> 'b list -> 'a list -> 'a list
   161   val merge: ('a * 'a -> bool) -> 'a list * 'a list -> 'a list
   162   val mem: ''a * ''a list -> bool
   163   val mem_int: int * int list -> bool
   164   val mem_string: string * string list -> bool
   165   val union: ''a list * ''a list -> ''a list
   166   val union_int: int list * int list -> int list
   167   val union_string: string list * string list -> string list
   168   val gen_union: ('a * 'a -> bool) -> 'a list * 'a list -> 'a list
   169   val gen_inter: ('a * 'b -> bool) -> 'a list * 'b list -> 'a list
   170   val inter: ''a list * ''a list -> ''a list
   171   val inter_int: int list * int list -> int list
   172   val inter_string: string list * string list -> string list
   173   val subset: ''a list * ''a list -> bool
   174   val subset_int: int list * int list -> bool
   175   val subset_string: string list * string list -> bool
   176   val eq_set: ''a list * ''a list -> bool
   177   val eq_set_string: string list * string list -> bool
   178   val gen_subset: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   179   val gen_eq_set: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   180   val \ : ''a list * ''a -> ''a list
   181   val \\ : ''a list * ''a list -> ''a list
   182   val distinct: ('a * 'a -> bool) -> 'a list -> 'a list
   183   val duplicates: ('a * 'a -> bool) -> 'a list -> 'a list
   184   val has_duplicates: ('a * 'a -> bool) -> 'a list -> bool
   185 
   186   (*lists as multisets*)
   187   val remove1: ('b * 'a -> bool) -> 'b -> 'a list -> 'a list
   188   val submultiset: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   189 
   190   (*orders*)
   191   val is_equal: order -> bool
   192   val rev_order: order -> order
   193   val make_ord: ('a * 'a -> bool) -> 'a * 'a -> order
   194   val int_ord: int * int -> order
   195   val string_ord: string * string -> order
   196   val fast_string_ord: string * string -> order
   197   val option_ord: ('a * 'b -> order) -> 'a option * 'b option -> order
   198   val prod_ord: ('a * 'b -> order) -> ('c * 'd -> order) -> ('a * 'c) * ('b * 'd) -> order
   199   val dict_ord: ('a * 'b -> order) -> 'a list * 'b list -> order
   200   val list_ord: ('a * 'b -> order) -> 'a list * 'b list -> order
   201   val sort: ('a * 'a -> order) -> 'a list -> 'a list
   202   val sort_distinct: ('a * 'a -> order) -> 'a list -> 'a list
   203   val sort_strings: string list -> string list
   204   val sort_wrt: ('a -> string) -> 'a list -> 'a list
   205 
   206   (*random numbers*)
   207   exception RANDOM
   208   val random: unit -> real
   209   val random_range: int -> int -> int
   210   val one_of: 'a list -> 'a
   211   val frequency: (int * 'a) list -> 'a
   212 
   213   (*misc*)
   214   val divide_and_conquer: ('a -> 'a list * ('b list -> 'b)) -> 'a -> 'b
   215   val partition_eq: ('a * 'a -> bool) -> 'a list -> 'a list list
   216   val partition_list: (int -> 'a -> bool) -> int -> int -> 'a list -> 'a list list
   217   val gensym: string -> string
   218   type stamp
   219   val stamp: unit -> stamp
   220   type serial
   221   val serial: unit -> serial
   222   val serial_string: unit -> string
   223   structure Object: sig type T end
   224 end;
   225 
   226 signature LIBRARY =
   227 sig
   228   include BASIC_LIBRARY
   229   val foldl: ('a * 'b -> 'a) -> 'a * 'b list -> 'a
   230   val foldr: ('a * 'b -> 'b) -> 'a list * 'b -> 'b
   231   val take: int * 'a list -> 'a list
   232   val drop: int * 'a list -> 'a list
   233   val last_elem: 'a list -> 'a
   234 end;
   235 
   236 structure Library: LIBRARY =
   237 struct
   238 
   239 (* functions *)
   240 
   241 fun undefined _ = raise Match;
   242 
   243 fun I x = x;
   244 fun K x = fn _ => x;
   245 fun flip f x y = f y x;
   246 fun curry f x y = f (x, y);
   247 fun uncurry f (x, y) = f x y;
   248 
   249 (*application and structured results -- old version*)
   250 fun (x, y) |>>> f = let val (x', z) = f x in (x', (y, z)) end;
   251 
   252 (*conditional application*)
   253 fun b ? f = fn x => if b then f x else x;
   254 
   255 (*composition with multiple args*)
   256 fun (f oo g) x y = f (g x y);
   257 fun (f ooo g) x y z = f (g x y z);
   258 fun (f oooo g) x y z w = f (g x y z w);
   259 
   260 (*function exponentiation: f(...(f x)...) with n applications of f*)
   261 fun funpow 0 _ x = x
   262   | funpow n f x = funpow (n - 1) f (f x);
   263 
   264 
   265 (* errors *)
   266 
   267 exception SYS_ERROR of string;
   268 fun sys_error msg = raise SYS_ERROR msg;
   269 
   270 exception ERROR of string;
   271 fun error msg = raise ERROR msg;
   272 
   273 fun cat_error "" msg = error msg
   274   | cat_error msg1 msg2 = error (msg1 ^ "\n" ^ msg2);
   275 
   276 fun assert_all pred list msg =
   277   let
   278     fun ass [] = ()
   279       | ass (x :: xs) = if pred x then ass xs else error (msg x);
   280   in ass list end;
   281 
   282 
   283 (* pairs *)
   284 
   285 fun pair x y = (x, y);
   286 fun rpair x y = (y, x);
   287 
   288 fun fst (x, y) = x;
   289 fun snd (x, y) = y;
   290 
   291 fun eq_fst eq ((x1, _), (x2, _)) = eq (x1, x2);
   292 fun eq_snd eq ((_, y1), (_, y2)) = eq (y1, y2);
   293 fun eq_pair eqx eqy ((x1, y1), (x2, y2)) = eqx (x1, x2) andalso eqy (y1, y2);
   294 
   295 fun swap (x, y) = (y, x);
   296 
   297 fun apfst f (x, y) = (f x, y);
   298 fun apsnd f (x, y) = (x, f y);
   299 fun pairself f (x, y) = (f x, f y);
   300 
   301 
   302 (* booleans *)
   303 
   304 (*polymorphic equality*)
   305 fun equal x y = x = y;
   306 fun not_equal x y = x <> y;
   307 
   308 (*combining predicates*)
   309 fun p orf q = fn x => p x orelse q x;
   310 fun p andf q = fn x => p x andalso q x;
   311 
   312 (*exists pred [x1, ..., xn] ===> pred x1 orelse ... orelse pred xn*)
   313 fun exists (pred: 'a -> bool) : 'a list -> bool =
   314   let fun boolf [] = false
   315         | boolf (x :: xs) = pred x orelse boolf xs
   316   in boolf end;
   317 
   318 (*forall pred [x1, ..., xn] ===> pred x1 andalso ... andalso pred xn*)
   319 fun forall (pred: 'a -> bool) : 'a list -> bool =
   320   let fun boolf [] = true
   321         | boolf (x :: xs) = pred x andalso boolf xs
   322   in boolf end;
   323 
   324 
   325 (* flags *)
   326 
   327 fun set flag = (flag := true; true);
   328 fun reset flag = (flag := false; false);
   329 fun toggle flag = (flag := not (! flag); ! flag);
   330 
   331 fun change r f = r := f (! r);
   332 
   333 (*temporarily set flag during execution*)
   334 fun setmp_noncritical flag value f x =
   335   let
   336     val orig_value = ! flag;
   337     val _ = flag := value;
   338     val result = Exn.capture f x;
   339     val _ = flag := orig_value;
   340   in Exn.release result end;
   341 
   342 fun setmp flag value f x = NAMED_CRITICAL "setmp" (fn () => setmp_noncritical flag value f x);
   343 
   344 
   345 
   346 (** lists **)
   347 
   348 exception UnequalLengths;
   349 
   350 fun single x = [x];
   351 
   352 fun the_single [x] = x
   353   | the_single _ = raise Empty;
   354 
   355 fun singleton f x = the_single (f [x]);
   356 
   357 fun apply [] x = x
   358   | apply (f :: fs) x = apply fs (f x);
   359 
   360 
   361 (* fold -- old versions *)
   362 
   363 (*the following versions of fold are designed to fit nicely with infixes*)
   364 
   365 (*  (op @) (e, [x1, ..., xn])  ===>  ((e @ x1) @ x2) ... @ xn
   366     for operators that associate to the left (TAIL RECURSIVE)*)
   367 fun foldl (f: 'a * 'b -> 'a) : 'a * 'b list -> 'a =
   368   let fun itl (e, [])  = e
   369         | itl (e, a::l) = itl (f(e, a), l)
   370   in  itl end;
   371 
   372 (*  (op @) ([x1, ..., xn], e)  ===>   x1 @ (x2 ... @ (xn @ e))
   373     for operators that associate to the right (not tail recursive)*)
   374 fun foldr f (l, e) =
   375   let fun itr [] = e
   376         | itr (a::l) = f(a, itr l)
   377   in  itr l  end;
   378 
   379 (*  (op @) [x1, ..., xn]  ===>   x1 @ (x2 ... @ (x[n-1] @ xn))
   380     for n > 0, operators that associate to the right (not tail recursive)*)
   381 fun foldr1 f [] = raise Empty
   382   | foldr1 f l =
   383       let fun itr [x] = x
   384             | itr (x::l) = f(x, itr l)
   385       in  itr l  end;
   386 
   387 fun foldl_map f =
   388   let
   389     fun fold_aux (x, []) = (x, [])
   390       | fold_aux (x, y :: ys) =
   391           let
   392             val (x', y') = f (x, y);
   393             val (x'', ys') = fold_aux (x', ys);
   394           in (x'', y' :: ys') end;
   395   in fold_aux end;
   396 
   397 
   398 (* basic list functions *)
   399 
   400 fun eq_list eq (list1, list2) =
   401   let
   402     fun eq_lst (x :: xs, y :: ys) = eq (x, y) andalso eq_lst (xs, ys)
   403       | eq_lst _ = true;
   404   in length list1 = length list2 andalso eq_lst (list1, list2) end;
   405 
   406 fun maps f [] = []
   407   | maps f (x :: xs) = f x @ maps f xs;
   408 
   409 fun chop 0 xs = ([], xs)
   410   | chop _ [] = ([], [])
   411   | chop n (x :: xs) = chop (n - 1) xs |>> cons x;
   412 
   413 (*take the first n elements from a list*)
   414 fun take (n, []) = []
   415   | take (n, x :: xs) =
   416       if n > 0 then x :: take (n - 1, xs) else [];
   417 
   418 (*drop the first n elements from a list*)
   419 fun drop (n, []) = []
   420   | drop (n, x :: xs) =
   421       if n > 0 then drop (n - 1, xs) else x :: xs;
   422 
   423 fun dropwhile P [] = []
   424   | dropwhile P (ys as x::xs) = if P x then dropwhile P xs else ys;
   425 
   426 (*return nth element of a list, where 0 designates the first element;
   427   raise Subscript if list too short*)
   428 fun nth xs i = List.nth (xs, i);
   429 
   430 fun nth_list xss i = nth xss i handle Subscript => [];
   431 
   432 fun nth_map 0 f (x :: xs) = f x :: xs
   433   | nth_map n f (x :: xs) = x :: nth_map (n - 1) f xs
   434   | nth_map _ _ [] = raise Subscript;
   435 
   436 fun map_index f =
   437   let
   438     fun mapp _ [] = []
   439       | mapp i (x :: xs) = f (i, x) :: mapp (i+1) xs
   440   in mapp 0 end;
   441 
   442 fun fold_index f =
   443   let
   444     fun fold_aux _ [] y = y
   445       | fold_aux i (x :: xs) y = fold_aux (i+1) xs (f (i, x) y);
   446   in fold_aux 0 end;
   447 
   448 val last_elem = List.last;
   449 
   450 (*rear decomposition*)
   451 fun split_last [] = raise Empty
   452   | split_last [x] = ([], x)
   453   | split_last (x :: xs) = apfst (cons x) (split_last xs);
   454 
   455 (*find the position of an element in a list*)
   456 fun find_index pred =
   457   let fun find _ [] = ~1
   458         | find n (x :: xs) = if pred x then n else find (n + 1) xs;
   459   in find 0 end;
   460 
   461 fun find_index_eq x = find_index (equal x);
   462 
   463 (*find first element satisfying predicate*)
   464 val find_first = List.find;
   465 
   466 (*get first element by lookup function*)
   467 fun get_first _ [] = NONE
   468   | get_first f (x :: xs) =
   469       (case f x of
   470         NONE => get_first f xs
   471       | some => some);
   472 
   473 fun get_index f =
   474   let
   475     fun get _ [] = NONE
   476       | get i (x :: xs) =
   477           case f x
   478            of NONE => get (i + 1) xs
   479             | SOME y => SOME (i, y)
   480   in get 0 end;
   481 
   482 val flat = List.concat;
   483 
   484 fun unflat (xs :: xss) ys =
   485       let val (ps, qs) = chop (length xs) ys
   486       in ps :: unflat xss qs end
   487   | unflat [] [] = []
   488   | unflat _ _ = raise UnequalLengths;
   489 
   490 fun burrow f xss = unflat xss (f (flat xss));
   491 
   492 fun fold_burrow f xss s =
   493   apfst (unflat xss) (f (flat xss) s);
   494 
   495 (*separate s [x1, x2, ..., xn]  ===>  [x1, s, x2, s, ..., s, xn]*)
   496 fun separate s (x :: (xs as _ :: _)) = x :: s :: separate s xs
   497   | separate _ xs = xs;
   498 
   499 (*make the list [x, x, ..., x] of length n*)
   500 fun replicate n (x: 'a) : 'a list =
   501   let fun rep (0, xs) = xs
   502         | rep (n, xs) = rep (n - 1, x :: xs)
   503   in
   504     if n < 0 then raise Subscript
   505     else rep (n, [])
   506   end;
   507 
   508 fun translate_string f = String.translate (f o String.str);
   509 
   510 (*multiply [a, b, c, ...] * [xs, ys, zs, ...]*)
   511 fun multiply [] _ = []
   512   | multiply (x :: xs) yss = map (cons x) yss @ multiply xs yss;
   513 
   514 (*direct product*)
   515 fun product _ [] = []
   516   | product [] _ = []
   517   | product (x :: xs) ys = map (pair x) ys @ product xs ys;
   518 
   519 
   520 (* filter *)
   521 
   522 (*copy the list preserving elements that satisfy the predicate*)
   523 val filter = List.filter;
   524 fun filter_out f = filter (not o f);
   525 val map_filter = List.mapPartial;
   526 
   527 
   528 (* lists of pairs *)
   529 
   530 exception UnequalLengths;
   531 
   532 fun map2 _ [] [] = []
   533   | map2 f (x :: xs) (y :: ys) = f x y :: map2 f xs ys
   534   | map2 _ _ _ = raise UnequalLengths;
   535 
   536 fun fold2 f [] [] z = z
   537   | fold2 f (x :: xs) (y :: ys) z = fold2 f xs ys (f x y z)
   538   | fold2 f _ _ _ = raise UnequalLengths;
   539 
   540 fun zip_options (x :: xs) (SOME y :: ys) = (x, y) :: zip_options xs ys
   541   | zip_options (_ :: xs) (NONE :: ys) = zip_options xs ys
   542   | zip_options _ [] = []
   543   | zip_options [] _ = raise UnequalLengths;
   544 
   545 (*combine two lists forming a list of pairs:
   546   [x1, ..., xn] ~~ [y1, ..., yn]  ===>  [(x1, y1), ..., (xn, yn)]*)
   547 fun [] ~~ [] = []
   548   | (x :: xs) ~~ (y :: ys) = (x, y) :: (xs ~~ ys)
   549   | _ ~~ _ = raise UnequalLengths;
   550 
   551 (*inverse of ~~; the old 'split':
   552   [(x1, y1), ..., (xn, yn)]  ===>  ([x1, ..., xn], [y1, ..., yn])*)
   553 val split_list = ListPair.unzip;
   554 
   555 
   556 (* prefixes, suffixes *)
   557 
   558 fun is_prefix _ [] _ = true
   559   | is_prefix eq (x :: xs) (y :: ys) = eq (x, y) andalso is_prefix eq xs ys
   560   | is_prefix eq _ _ = false;
   561 
   562 (* [x1, ..., xi, ..., xn]  --->  ([x1, ..., x(i-1)], [xi, ..., xn])
   563    where xi is the first element that does not satisfy the predicate*)
   564 fun take_prefix (pred : 'a -> bool)  (xs: 'a list) : 'a list * 'a list =
   565   let fun take (rxs, []) = (rev rxs, [])
   566         | take (rxs, x :: xs) =
   567             if  pred x  then  take(x :: rxs, xs)  else  (rev rxs, x :: xs)
   568   in  take([], xs)  end;
   569 
   570 fun chop_prefix eq ([], ys) = ([], ([], ys))
   571   | chop_prefix eq (xs, []) = ([], (xs, []))
   572   | chop_prefix eq (xs as x :: xs', ys as y :: ys') =
   573       if eq (x, y) then
   574         let val (ps', xys'') = chop_prefix eq (xs', ys')
   575         in (x :: ps', xys'') end
   576       else ([], (xs, ys));
   577 
   578 (* [x1, ..., xi, ..., xn]  --->  ([x1, ..., xi], [x(i+1), ..., xn])
   579    where xi is the last element that does not satisfy the predicate*)
   580 fun take_suffix _ [] = ([], [])
   581   | take_suffix pred (x :: xs) =
   582       (case take_suffix pred xs of
   583         ([], sffx) => if pred x then ([], x :: sffx) else ([x], sffx)
   584       | (prfx, sffx) => (x :: prfx, sffx));
   585 
   586 fun prefixes1 [] = []
   587   | prefixes1 (x :: xs) = map (cons x) ([] :: prefixes1 xs);
   588 
   589 fun prefixes xs = [] :: prefixes1 xs;
   590 
   591 fun suffixes1 xs = map rev (prefixes1 (rev xs));
   592 fun suffixes xs = [] :: suffixes1 xs;
   593 
   594 
   595 
   596 (** integers **)
   597 
   598 fun inc i = (i := ! i + 1; ! i);
   599 fun dec i = (i := ! i - 1; ! i);
   600 
   601 
   602 (* lists of integers *)
   603 
   604 (*make the list [from, from + 1, ..., to]*)
   605 fun (i upto j) =
   606   if i > j then [] else i :: (i + 1 upto j);
   607 
   608 (*make the list [from, from - 1, ..., to]*)
   609 fun (i downto j) =
   610   if i < j then [] else i :: (i - 1 downto j);
   611 
   612 
   613 (* convert integers to strings *)
   614 
   615 (*expand the number in the given base;
   616   example: radixpand (2, 8) gives [1, 0, 0, 0]*)
   617 fun radixpand (base, num) : int list =
   618   let
   619     fun radix (n, tail) =
   620       if n < base then n :: tail
   621       else radix (n div base, (n mod base) :: tail)
   622   in radix (num, []) end;
   623 
   624 (*expands a number into a string of characters starting from "zerochar";
   625   example: radixstring (2, "0", 8) gives "1000"*)
   626 fun radixstring (base, zerochar, num) =
   627   let val offset = ord zerochar;
   628       fun chrof n = chr (offset + n)
   629   in implode (map chrof (radixpand (base, num))) end;
   630 
   631 
   632 val string_of_int = Int.toString;
   633 
   634 fun signed_string_of_int i =
   635   if i < 0 then "-" ^ string_of_int (~ i) else string_of_int i;
   636 
   637 fun string_of_indexname (a, 0) = a
   638   | string_of_indexname (a, i) = a ^ "_" ^ string_of_int i;
   639 
   640 
   641 (* read integers *)
   642 
   643 fun read_intinf radix cs =
   644   let
   645     val zero = ord "0";
   646     val limit = zero + radix;
   647     fun scan (num, []) = (num, [])
   648       | scan (num, c :: cs) =
   649         if zero <= ord c andalso ord c < limit then
   650           scan (IntInf.fromInt radix * num + IntInf.fromInt (ord c - zero), cs)
   651         else (num, c :: cs);
   652   in scan (IntInf.fromInt 0, cs) end;
   653 
   654 fun read_int cs = apfst IntInf.toInt (read_intinf 10 cs);
   655 
   656 fun oct_char s = chr (IntInf.toInt (#1 (read_intinf 8 (explode s))));
   657 
   658 
   659 
   660 (** strings **)
   661 
   662 (* functions tuned for strings, avoiding explode *)
   663 
   664 fun nth_string str i =
   665   (case try String.substring (str, i, 1) of
   666     SOME s => s
   667   | NONE => raise Subscript);
   668 
   669 fun fold_string f str x0 =
   670   let
   671     val n = size str;
   672     fun iter (x, i) =
   673       if i < n then iter (f (String.substring (str, i, 1)) x, i + 1) else x;
   674   in iter (x0, 0) end;
   675 
   676 fun exists_string pred str =
   677   let
   678     val n = size str;
   679     fun ex i = i < n andalso (pred (String.substring (str, i, 1)) orelse ex (i + 1));
   680   in ex 0 end;
   681 
   682 fun forall_string pred = not o exists_string (not o pred);
   683 
   684 (*enclose in brackets*)
   685 fun enclose lpar rpar str = lpar ^ str ^ rpar;
   686 fun unenclose str = String.substring (str, 1, size str - 2);
   687 
   688 (*simple quoting (does not escape special chars)*)
   689 val quote = enclose "\"" "\"";
   690 
   691 (*space_implode "..." (explode "hello") = "h...e...l...l...o"*)
   692 fun space_implode a bs = implode (separate a bs);
   693 
   694 val commas = space_implode ", ";
   695 val commas_quote = commas o map quote;
   696 
   697 (*concatenate messages, one per line, into a string*)
   698 val cat_lines = space_implode "\n";
   699 
   700 (*space_explode "." "h.e..l.lo" = ["h", "e", "", "l", "lo"]*)
   701 fun space_explode _ "" = []
   702   | space_explode sep s = String.fields (fn c => str c = sep) s;
   703 
   704 val split_lines = space_explode "\n";
   705 
   706 fun prefix_lines "" txt = txt
   707   | prefix_lines prfx txt = txt |> split_lines |> map (fn s => prfx ^ s) |> cat_lines;
   708 
   709 fun untabify chs =
   710   let
   711     val tab_width = 8;
   712 
   713     fun untab pos [] ys = rev ys
   714       | untab pos ("\n" :: xs) ys = untab 0 xs ("\n" :: ys)
   715       | untab pos ("\t" :: xs) ys =
   716           let val d = tab_width - (pos mod tab_width)
   717           in untab (pos + d) xs (funpow d (cons " ") ys) end
   718       | untab pos (c :: xs) ys = untab (pos + 1) xs (c :: ys);
   719   in
   720     if not (exists (fn c => c = "\t") chs) then chs
   721     else untab 0 chs []
   722   end;
   723 
   724 fun prefix prfx s = prfx ^ s;
   725 fun suffix sffx s = s ^ sffx;
   726 
   727 fun unprefix prfx s =
   728   if String.isPrefix prfx s then String.substring (s, size prfx, size s - size prfx)
   729   else raise Fail "unprefix";
   730 
   731 fun unsuffix sffx s =
   732   if String.isSuffix sffx s then String.substring (s, 0, size s - size sffx)
   733   else raise Fail "unsuffix";
   734 
   735 fun replicate_string 0 _ = ""
   736   | replicate_string 1 a = a
   737   | replicate_string k a =
   738       if k mod 2 = 0 then replicate_string (k div 2) (a ^ a)
   739       else replicate_string (k div 2) (a ^ a) ^ a;
   740 
   741 
   742 
   743 (** lists as sets -- see also Pure/General/ord_list.ML **)
   744 
   745 (*canonical member, insert, remove*)
   746 fun member eq list x =
   747   let
   748     fun memb [] = false
   749       | memb (y :: ys) = eq (x, y) orelse memb ys;
   750   in memb list end;
   751 
   752 fun insert eq x xs = if member eq xs x then xs else x :: xs;
   753 fun remove eq x xs = if member eq xs x then filter_out (fn y => eq (x, y)) xs else xs;
   754 fun update eq x xs = cons x (remove eq x xs);
   755 
   756 fun subtract eq = fold (remove eq);
   757 
   758 fun merge _ ([], ys) = ys
   759   | merge eq (xs, ys) = fold_rev (insert eq) ys xs;
   760 
   761 (*old-style infixes*)
   762 fun x mem xs = member (op =) xs x;
   763 fun (x: int) mem_int xs = member (op =) xs x;
   764 fun (x: string) mem_string xs = member (op =) xs x;
   765 
   766 
   767 (*union of sets represented as lists: no repetitions*)
   768 fun xs union [] = xs
   769   | [] union ys = ys
   770   | (x :: xs) union ys = xs union (insert (op =) x ys);
   771 
   772 (*union of sets, optimized version for ints*)
   773 fun (xs:int list) union_int [] = xs
   774   | [] union_int ys = ys
   775   | (x :: xs) union_int ys = xs union_int (insert (op =) x ys);
   776 
   777 (*union of sets, optimized version for strings*)
   778 fun (xs:string list) union_string [] = xs
   779   | [] union_string ys = ys
   780   | (x :: xs) union_string ys = xs union_string (insert (op =) x ys);
   781 
   782 (*generalized union*)
   783 fun gen_union eq (xs, []) = xs
   784   | gen_union eq ([], ys) = ys
   785   | gen_union eq (x :: xs, ys) = gen_union eq (xs, insert eq x ys);
   786 
   787 
   788 (*intersection*)
   789 fun [] inter ys = []
   790   | (x :: xs) inter ys =
   791       if x mem ys then x :: (xs inter ys) else xs inter ys;
   792 
   793 (*intersection, optimized version for ints*)
   794 fun ([]:int list) inter_int ys = []
   795   | (x :: xs) inter_int ys =
   796       if x mem_int ys then x :: (xs inter_int ys) else xs inter_int ys;
   797 
   798 (*intersection, optimized version for strings *)
   799 fun ([]:string list) inter_string ys = []
   800   | (x :: xs) inter_string ys =
   801       if x mem_string ys then x :: (xs inter_string ys) else xs inter_string ys;
   802 
   803 (*generalized intersection*)
   804 fun gen_inter eq ([], ys) = []
   805   | gen_inter eq (x::xs, ys) =
   806       if member eq ys x then x :: gen_inter eq (xs, ys)
   807       else gen_inter eq (xs, ys);
   808 
   809 
   810 (*subset*)
   811 fun [] subset ys = true
   812   | (x :: xs) subset ys = x mem ys andalso xs subset ys;
   813 
   814 (*subset, optimized version for ints*)
   815 fun ([]: int list) subset_int ys = true
   816   | (x :: xs) subset_int ys = x mem_int ys andalso xs subset_int ys;
   817 
   818 (*subset, optimized version for strings*)
   819 fun ([]: string list) subset_string ys = true
   820   | (x :: xs) subset_string ys = x mem_string ys andalso xs subset_string ys;
   821 
   822 (*set equality*)
   823 fun eq_set (xs, ys) =
   824   xs = ys orelse (xs subset ys andalso ys subset xs);
   825 
   826 (*set equality for strings*)
   827 fun eq_set_string ((xs: string list), ys) =
   828   xs = ys orelse (xs subset_string ys andalso ys subset_string xs);
   829 
   830 fun gen_subset eq (xs, ys) = forall (member eq ys) xs;
   831 
   832 fun gen_eq_set eq (xs, ys) =
   833   eq_list eq (xs, ys) orelse
   834     (gen_subset eq (xs, ys) andalso gen_subset (eq o swap) (ys, xs));
   835 
   836 
   837 (*removing an element from a list WITHOUT duplicates*)
   838 fun (y :: ys) \ x = if x = y then ys else y :: (ys \ x)
   839   | [] \ x = [];
   840 fun ys \\ xs = foldl (op \) (ys,xs);
   841 
   842 
   843 (*makes a list of the distinct members of the input; preserves order, takes
   844   first of equal elements*)
   845 fun distinct eq lst =
   846   let
   847     fun dist (rev_seen, []) = rev rev_seen
   848       | dist (rev_seen, x :: xs) =
   849           if member eq rev_seen x then dist (rev_seen, xs)
   850           else dist (x :: rev_seen, xs);
   851   in dist ([], lst) end;
   852 
   853 (*returns a list containing all repeated elements exactly once; preserves
   854   order, takes first of equal elements*)
   855 fun duplicates eq lst =
   856   let
   857     fun dups (rev_dups, []) = rev rev_dups
   858       | dups (rev_dups, x :: xs) =
   859           if member eq rev_dups x orelse not (member eq xs x) then
   860             dups (rev_dups, xs)
   861           else dups (x :: rev_dups, xs);
   862   in dups ([], lst) end;
   863 
   864 fun has_duplicates eq =
   865   let
   866     fun dups [] = false
   867       | dups (x :: xs) = member eq xs x orelse dups xs;
   868   in dups end;
   869 
   870 
   871 
   872 (** lists as multisets **)
   873 
   874 fun remove1 _ _ [] = raise Empty
   875   | remove1 eq y (x::xs) = if eq (y, x) then xs else x :: remove1 eq y xs;
   876 
   877 fun submultiset _ ([], _)  = true
   878   | submultiset eq (x :: xs, ys) = member eq ys x andalso submultiset eq (xs, remove1 eq x ys);
   879 
   880 
   881 
   882 (** orders **)
   883 
   884 fun is_equal EQUAL = true
   885   | is_equal _ = false;
   886 
   887 fun rev_order LESS = GREATER
   888   | rev_order EQUAL = EQUAL
   889   | rev_order GREATER = LESS;
   890 
   891 (*assume rel is a linear strict order*)
   892 fun make_ord rel (x, y) =
   893   if rel (x, y) then LESS
   894   else if rel (y, x) then GREATER
   895   else EQUAL;
   896 
   897 val int_ord = Int.compare;
   898 val string_ord = String.compare;
   899 
   900 fun fast_string_ord (s1, s2) =
   901   (case int_ord (size s1, size s2) of EQUAL => string_ord (s1, s2) | ord => ord);
   902 
   903 fun option_ord ord (SOME x, SOME y) = ord (x, y)
   904   | option_ord _ (NONE, NONE) = EQUAL
   905   | option_ord _ (NONE, SOME _) = LESS
   906   | option_ord _ (SOME _, NONE) = GREATER;
   907 
   908 (*lexicographic product*)
   909 fun prod_ord a_ord b_ord ((x, y), (x', y')) =
   910   (case a_ord (x, x') of EQUAL => b_ord (y, y') | ord => ord);
   911 
   912 (*dictionary order -- in general NOT well-founded!*)
   913 fun dict_ord elem_ord (x :: xs, y :: ys) =
   914       (case elem_ord (x, y) of EQUAL => dict_ord elem_ord (xs, ys) | ord => ord)
   915   | dict_ord _ ([], []) = EQUAL
   916   | dict_ord _ ([], _ :: _) = LESS
   917   | dict_ord _ (_ :: _, []) = GREATER;
   918 
   919 (*lexicographic product of lists*)
   920 fun list_ord elem_ord (xs, ys) =
   921   (case int_ord (length xs, length ys) of EQUAL => dict_ord elem_ord (xs, ys) | ord => ord);
   922 
   923 
   924 (* sorting *)
   925 
   926 (*quicksort -- stable, i.e. does not reorder equal elements*)
   927 fun quicksort unique ord =
   928   let
   929     fun qsort [] = []
   930       | qsort (xs as [_]) = xs
   931       | qsort (xs as [x, y]) =
   932           (case ord (x, y) of
   933             LESS => xs
   934           | EQUAL => if unique then [x] else xs
   935           | GREATER => [y, x])
   936       | qsort xs =
   937           let val (lts, eqs, gts) = part (nth xs (length xs div 2)) xs
   938           in qsort lts @ eqs @ qsort gts end
   939     and part _ [] = ([], [], [])
   940       | part pivot (x :: xs) = add (ord (x, pivot)) x (part pivot xs)
   941     and add LESS x (lts, eqs, gts) = (x :: lts, eqs, gts)
   942       | add EQUAL x (lts, [], gts) = (lts, [x], gts)
   943       | add EQUAL x (res as (lts, eqs, gts)) = if unique then res else (lts, x :: eqs, gts)
   944       | add GREATER x (lts, eqs, gts) = (lts, eqs, x :: gts);
   945   in qsort end;
   946 
   947 fun sort ord = quicksort false ord;
   948 fun sort_distinct ord = quicksort true ord;
   949 
   950 val sort_strings = sort string_ord;
   951 fun sort_wrt sel xs = sort (string_ord o pairself sel) xs;
   952 
   953 
   954 
   955 (** random numbers **)
   956 
   957 exception RANDOM;
   958 
   959 fun rmod x y = x - y * Real.realFloor (x / y);
   960 
   961 local
   962   val a = 16807.0;
   963   val m = 2147483647.0;
   964   val random_seed = ref 1.0;
   965 in
   966 
   967 fun random () = CRITICAL (fn () =>
   968   let val r = rmod (a * ! random_seed) m
   969   in (random_seed := r; r) end);
   970 
   971 end;
   972 
   973 fun random_range l h =
   974   if h < l orelse l < 0 then raise RANDOM
   975   else l + Real.floor (rmod (random ()) (real (h - l + 1)));
   976 
   977 fun one_of xs = nth xs (random_range 0 (length xs - 1));
   978 
   979 fun frequency xs =
   980   let
   981     val sum = foldl op + (0, map fst xs);
   982     fun pick n ((k: int, x) :: xs) =
   983       if n <= k then x else pick (n - k) xs
   984   in pick (random_range 1 sum) xs end;
   985 
   986 
   987 
   988 (** misc **)
   989 
   990 fun divide_and_conquer decomp x =
   991   let val (ys, recomb) = decomp x
   992   in recomb (map (divide_and_conquer decomp) ys) end;
   993 
   994 
   995 (*Partition a list into buckets  [ bi, b(i+1), ..., bj ]
   996    putting x in bk if p(k)(x) holds.  Preserve order of elements if possible.*)
   997 fun partition_list p i j =
   998   let fun part k xs =
   999             if k>j then
  1000               (case xs of [] => []
  1001                          | _ => raise Fail "partition_list")
  1002             else
  1003             let val (ns, rest) = List.partition (p k) xs;
  1004             in  ns :: part(k+1)rest  end
  1005   in  part i end;
  1006 
  1007 fun partition_eq (eq:'a * 'a -> bool) =
  1008   let
  1009     fun part [] = []
  1010       | part (x :: ys) =
  1011           let val (xs, xs') = List.partition (fn y => eq (x, y)) ys
  1012           in (x::xs)::(part xs') end
  1013   in part end;
  1014 
  1015 
  1016 
  1017 (* generating identifiers *)
  1018 
  1019 (** Freshly generated identifiers; supplied prefix MUST start with a letter **)
  1020 local
  1021 (*Maps 0-61 to A-Z, a-z, 0-9; exclude _ or ' to avoid clash with internal/unusual indentifiers*)
  1022 fun gensym_char i =
  1023   if i<26 then chr (ord "A" + i)
  1024   else if i<52 then chr (ord "a" + i - 26)
  1025   else chr (ord "0" + i - 52);
  1026 
  1027 val char_vec = Vector.tabulate (62, gensym_char);
  1028 fun newid n = implode (map (fn i => Vector.sub (char_vec, i)) (radixpand (62, n)));
  1029 
  1030 val gensym_seed = ref 0;
  1031 
  1032 in
  1033   fun gensym pre = pre ^ newid (NAMED_CRITICAL "gensym" (fn () => inc gensym_seed));
  1034 end;
  1035 
  1036 
  1037 (* stamps and serial numbers *)
  1038 
  1039 type stamp = unit ref;
  1040 val stamp: unit -> stamp = ref;
  1041 
  1042 type serial = int;
  1043 local val count = ref 0
  1044 in fun serial () = NAMED_CRITICAL "serial" (fn () => inc count) end;
  1045 
  1046 val serial_string = string_of_int o serial;
  1047 
  1048 
  1049 (* generic objects *)
  1050 
  1051 (*note that the builtin exception datatype may be extended by new
  1052   constructors at any time*)
  1053 structure Object = struct type T = exn end;
  1054 
  1055 end;
  1056 
  1057 structure BasicLibrary: BASIC_LIBRARY = Library;
  1058 open BasicLibrary;