src/Pure/Isar/theory_target.ML
author wenzelm
Sun Feb 10 20:49:48 2008 +0100 (2008-02-10)
changeset 26054 345e495d3b92
parent 26049 8186c03194ed
child 26132 c927c3ed82c9
permissions -rw-r--r--
tuned spaces;
     1 (*  Title:      Pure/Isar/theory_target.ML
     2     ID:         $Id$
     3     Author:     Makarius
     4 
     5 Common theory/locale/class/instantiation/overloading targets.
     6 *)
     7 
     8 signature THEORY_TARGET =
     9 sig
    10   val peek: local_theory -> {target: string, is_locale: bool,
    11     is_class: bool, instantiation: string list * (string * sort) list * sort,
    12     overloading: (string * (string * typ) * bool) list}
    13   val init: string option -> theory -> local_theory
    14   val begin: string -> Proof.context -> local_theory
    15   val context: xstring -> theory -> local_theory
    16   val instantiation: string list * (string * sort) list * sort -> theory -> local_theory
    17   val overloading: (string * (string * typ) * bool) list -> theory -> local_theory
    18   val overloading_cmd: (string * string * bool) list -> theory -> local_theory
    19 end;
    20 
    21 structure TheoryTarget: THEORY_TARGET =
    22 struct
    23 
    24 (* context data *)
    25 
    26 datatype target = Target of {target: string, is_locale: bool,
    27   is_class: bool, instantiation: string list * (string * sort) list * sort,
    28   overloading: (string * (string * typ) * bool) list};
    29 
    30 fun make_target target is_locale is_class instantiation overloading =
    31   Target {target = target, is_locale = is_locale,
    32     is_class = is_class, instantiation = instantiation, overloading = overloading};
    33 
    34 val global_target = make_target "" false false ([], [], []) [];
    35 
    36 structure Data = ProofDataFun
    37 (
    38   type T = target;
    39   fun init _ = global_target;
    40 );
    41 
    42 val peek = (fn Target args => args) o Data.get;
    43 
    44 
    45 (* pretty *)
    46 
    47 fun pretty_thy ctxt target is_locale is_class =
    48   let
    49     val thy = ProofContext.theory_of ctxt;
    50     val target_name = (if is_class then "class " else "locale ") ^ Locale.extern thy target;
    51     val fixes = map (fn (x, T) => (x, SOME T, NoSyn)) (#1 (ProofContext.inferred_fixes ctxt));
    52     val assumes = map (fn A => (("", []), [(A, [])])) (map Thm.term_of (Assumption.assms_of ctxt));
    53     val elems =
    54       (if null fixes then [] else [Element.Fixes fixes]) @
    55       (if null assumes then [] else [Element.Assumes assumes]);
    56   in
    57     if target = "" then []
    58     else if null elems then [Pretty.str target_name]
    59     else [Pretty.big_list (target_name ^ " =")
    60       (map (Pretty.chunks o Element.pretty_ctxt ctxt) elems)]
    61   end;
    62 
    63 fun pretty (Target {target, is_locale, is_class, instantiation, overloading}) ctxt =
    64   Pretty.block [Pretty.str "theory", Pretty.brk 1,
    65       Pretty.str (Context.theory_name (ProofContext.theory_of ctxt))] ::
    66     (if not (null overloading) then [Overloading.pretty ctxt]
    67      else if not (null (#1 instantiation)) then [Class.pretty_instantiation ctxt]
    68      else pretty_thy ctxt target is_locale is_class);
    69 
    70 
    71 (* target declarations *)
    72 
    73 fun target_decl add (Target {target, ...}) d lthy =
    74   let
    75     val d' = Morphism.transform (LocalTheory.target_morphism lthy) d;
    76     val d0 = Morphism.form d';
    77   in
    78     if target = "" then
    79       lthy
    80       |> LocalTheory.theory (Context.theory_map d0)
    81       |> LocalTheory.target (Context.proof_map d0)
    82     else
    83       lthy
    84       |> LocalTheory.target (add target d')
    85   end;
    86 
    87 val type_syntax = target_decl Locale.add_type_syntax;
    88 val term_syntax = target_decl Locale.add_term_syntax;
    89 val declaration = target_decl Locale.add_declaration;
    90 
    91 fun class_target (Target {target, ...}) f =
    92   LocalTheory.raw_theory f #>
    93   LocalTheory.target (Class.refresh_syntax target);
    94 
    95 
    96 (* notes *)
    97 
    98 fun import_export_proof ctxt (name, raw_th) =
    99   let
   100     val thy = ProofContext.theory_of ctxt;
   101     val thy_ctxt = ProofContext.init thy;
   102     val certT = Thm.ctyp_of thy;
   103     val cert = Thm.cterm_of thy;
   104 
   105     (*export assumes/defines*)
   106     val th = Goal.norm_result raw_th;
   107     val (defs, th') = LocalDefs.export ctxt thy_ctxt th;
   108     val concl_conv = MetaSimplifier.rewrite true defs (Thm.cprop_of th);
   109     val assms = map (MetaSimplifier.rewrite_rule defs o Thm.assume) (Assumption.assms_of ctxt);
   110     val nprems = Thm.nprems_of th' - Thm.nprems_of th;
   111 
   112     (*export fixes*)
   113     val tfrees = map TFree (Thm.fold_terms Term.add_tfrees th' []);
   114     val frees = map Free (Thm.fold_terms Term.add_frees th' []);
   115     val (th'' :: vs) = (th' :: map (Drule.mk_term o cert) (map Logic.mk_type tfrees @ frees))
   116       |> Variable.export ctxt thy_ctxt
   117       |> Drule.zero_var_indexes_list;
   118 
   119     (*thm definition*)
   120     val result = th''
   121       |> PureThy.name_thm true true ""
   122       |> Goal.close_result
   123       |> fold PureThy.tag_rule (Position.properties_of (Position.thread_data ()))
   124       |> PureThy.name_thm true true name;
   125 
   126     (*import fixes*)
   127     val (tvars, vars) =
   128       chop (length tfrees) (map (Thm.term_of o Drule.dest_term) vs)
   129       |>> map Logic.dest_type;
   130 
   131     val instT = map_filter (fn (TVar v, T) => SOME (v, T) | _ => NONE) (tvars ~~ tfrees);
   132     val inst = filter (is_Var o fst) (vars ~~ frees);
   133     val cinstT = map (pairself certT o apfst TVar) instT;
   134     val cinst = map (pairself (cert o Term.map_types (TermSubst.instantiateT instT))) inst;
   135     val result' = Thm.instantiate (cinstT, cinst) result;
   136 
   137     (*import assumes/defines*)
   138     val assm_tac = FIRST' (map (fn assm => Tactic.compose_tac (false, assm, 0)) assms);
   139     val result'' =
   140       (case SINGLE (Seq.INTERVAL assm_tac 1 nprems) result' of
   141         NONE => raise THM ("Failed to re-import result", 0, [result'])
   142       | SOME res => LocalDefs.trans_props ctxt [res, Thm.symmetric concl_conv])
   143       |> Goal.norm_result
   144       |> PureThy.name_thm false false name;
   145 
   146   in (result'', result) end;
   147 
   148 fun note_local kind facts ctxt =
   149   ctxt
   150   |> ProofContext.qualified_names
   151   |> ProofContext.note_thmss_i kind facts
   152   ||> ProofContext.restore_naming ctxt;
   153 
   154 fun notes (Target {target, is_locale, ...}) kind group facts lthy =
   155   let
   156     val thy = ProofContext.theory_of lthy;
   157     val full = LocalTheory.full_name lthy;
   158 
   159     val facts' = facts
   160       |> map (fn (a, bs) => (a, PureThy.burrow_fact (PureThy.name_multi (full (fst a))) bs))
   161       |> PureThy.map_facts (import_export_proof lthy);
   162     val local_facts = PureThy.map_facts #1 facts'
   163       |> Attrib.map_facts (Attrib.attribute_i thy);
   164     val target_facts = PureThy.map_facts #1 facts'
   165       |> is_locale ? Element.facts_map (Element.morph_ctxt (LocalTheory.target_morphism lthy));
   166     val global_facts = PureThy.map_facts #2 facts'
   167       |> Attrib.map_facts (if is_locale then K I else Attrib.attribute_i thy);
   168   in
   169     lthy |> LocalTheory.theory
   170       (Sign.qualified_names
   171         #> PureThy.note_thmss_grouped kind group global_facts #> snd
   172         #> Sign.restore_naming thy)
   173 
   174     |> not is_locale ? LocalTheory.target (note_local kind global_facts #> snd)
   175     |> is_locale ? LocalTheory.target (Locale.add_thmss target kind target_facts)
   176 
   177     |> note_local kind local_facts
   178   end;
   179 
   180 
   181 (* declare_const *)
   182 
   183 fun fork_mixfix (Target {is_locale, is_class, ...}) mx =
   184   if not is_locale then (NoSyn, NoSyn, mx)
   185   else if not is_class then (NoSyn, mx, NoSyn)
   186   else (mx, NoSyn, NoSyn);
   187 
   188 fun locale_const (Target {target, is_class, ...}) (prmode as (mode, _)) pos ((c, mx), rhs) phi =
   189   let
   190     val c' = Morphism.name phi c;
   191     val rhs' = Morphism.term phi rhs;
   192     val legacy_arg = (c', Term.close_schematic_term (Logic.legacy_varify rhs'));
   193     val arg = (c', Term.close_schematic_term rhs');
   194     val similar_body = Type.similar_types (rhs, rhs');
   195     (* FIXME workaround based on educated guess *)
   196     val class_global = c' = NameSpace.qualified (Class.class_prefix target) c;
   197   in
   198     not (is_class andalso (similar_body orelse class_global)) ?
   199       (Context.mapping_result
   200         (Sign.add_abbrev PrintMode.internal pos legacy_arg)
   201         (ProofContext.add_abbrev PrintMode.internal pos arg)
   202       #-> (fn (lhs' as Const (d, _), _) =>
   203           similar_body ?
   204             (Context.mapping (Sign.revert_abbrev mode d) (ProofContext.revert_abbrev mode d) #>
   205              Morphism.form (ProofContext.target_notation true prmode [(lhs', mx)]))))
   206   end;
   207 
   208 fun declare_const (ta as Target {target, is_locale, is_class, ...}) depends ((c, T), mx) lthy =
   209   let
   210     val pos = Position.properties_of (Position.thread_data ());
   211     val xs = filter depends (#1 (ProofContext.inferred_fixes (LocalTheory.target_of lthy)));
   212     val U = map #2 xs ---> T;
   213     val (mx1, mx2, mx3) = fork_mixfix ta mx;
   214     fun syntax_error c = error ("Illegal mixfix syntax for overloaded constant " ^ quote c);
   215     val declare_const =
   216       (case Class.instantiation_param lthy c of
   217         SOME c' =>
   218           if mx3 <> NoSyn then syntax_error c'
   219           else LocalTheory.theory_result (AxClass.declare_overloaded (c', U))
   220             ##> Class.confirm_declaration c
   221         | NONE =>
   222             (case Overloading.operation lthy c of
   223               SOME (c', _) =>
   224                 if mx3 <> NoSyn then syntax_error c'
   225                 else LocalTheory.theory_result (Overloading.declare (c', U))
   226                   ##> Overloading.confirm c
   227             | NONE => LocalTheory.theory_result (Sign.declare_const pos (c, U, mx3))));
   228     val (const, lthy') = lthy |> declare_const;
   229     val t = Term.list_comb (const, map Free xs);
   230   in
   231     lthy'
   232     |> is_locale ? term_syntax ta (locale_const ta Syntax.mode_default pos ((c, mx2), t))
   233     |> is_class ? class_target ta (Class.declare target pos ((c, mx1), t))
   234     |> LocalDefs.add_def ((c, NoSyn), t)
   235   end;
   236 
   237 
   238 (* abbrev *)
   239 
   240 fun abbrev (ta as Target {target, is_locale, is_class, ...}) prmode ((c, mx), t) lthy =
   241   let
   242     val pos = Position.properties_of (Position.thread_data ());
   243     val thy_ctxt = ProofContext.init (ProofContext.theory_of lthy);
   244     val target_ctxt = LocalTheory.target_of lthy;
   245 
   246     val (mx1, mx2, mx3) = fork_mixfix ta mx;
   247     val t' = Assumption.export_term lthy target_ctxt t;
   248     val xs = map Free (rev (Variable.add_fixed target_ctxt t' []));
   249     val u = fold_rev lambda xs t';
   250     val global_rhs =
   251       singleton (Variable.export_terms (Variable.declare_term u target_ctxt) thy_ctxt) u;
   252   in
   253     lthy |>
   254      (if is_locale then
   255         LocalTheory.theory_result (Sign.add_abbrev PrintMode.internal pos (c, global_rhs))
   256         #-> (fn (lhs, _) =>
   257           let val lhs' = Term.list_comb (Logic.unvarify lhs, xs) in
   258             term_syntax ta (locale_const ta prmode pos ((c, mx2), lhs')) #>
   259             is_class ? class_target ta (Class.abbrev target prmode pos ((c, mx1), t'))
   260           end)
   261       else
   262         LocalTheory.theory
   263           (Sign.add_abbrev (#1 prmode) pos (c, global_rhs) #-> (fn (lhs, _) =>
   264            Sign.notation true prmode [(lhs, mx3)])))
   265     |> ProofContext.add_abbrev PrintMode.internal pos (c, t) |> snd
   266     |> LocalDefs.fixed_abbrev ((c, NoSyn), t)
   267   end;
   268 
   269 
   270 (* define *)
   271 
   272 fun define (ta as Target {target, is_locale, is_class, ...})
   273     kind group ((c, mx), ((name, atts), rhs)) lthy =
   274   let
   275     val thy = ProofContext.theory_of lthy;
   276     val thy_ctxt = ProofContext.init thy;
   277 
   278     val name' = Thm.def_name_optional c name;
   279     val (rhs', rhs_conv) =
   280       LocalDefs.export_cterm lthy thy_ctxt (Thm.cterm_of thy rhs) |>> Thm.term_of;
   281     val xs = Variable.add_fixed (LocalTheory.target_of lthy) rhs' [];
   282     val T = Term.fastype_of rhs;
   283 
   284     (*const*)
   285     val ((lhs, local_def), lthy2) = lthy |> declare_const ta (member (op =) xs) ((c, T), mx);
   286     val (_, lhs') = Logic.dest_equals (Thm.prop_of local_def);
   287 
   288     (*def*)
   289     val define_const =
   290       (case Overloading.operation lthy c of
   291         SOME (_, checked) =>
   292           (fn name => fn (Const (c, _), rhs) => Overloading.define checked name (c, rhs))
   293       | NONE =>
   294           if is_none (Class.instantiation_param lthy c)
   295           then (fn name => fn eq => Thm.add_def false false (name, Logic.mk_equals eq))
   296           else (fn name => fn (Const (c, _), rhs) => AxClass.define_overloaded name (c, rhs)));
   297     val (global_def, lthy3) = lthy2
   298       |> LocalTheory.theory_result (define_const name' (lhs', rhs'));
   299     val def = LocalDefs.trans_terms lthy3
   300       [(*c == global.c xs*)     local_def,
   301        (*global.c xs == rhs'*)  global_def,
   302        (*rhs' == rhs*)          Thm.symmetric rhs_conv];
   303 
   304     (*note*)
   305     val ([(res_name, [res])], lthy4) = lthy3
   306       |> notes ta kind group [((name', atts), [([def], [])])];
   307   in ((lhs, (res_name, res)), lthy4) end;
   308 
   309 
   310 (* axioms *)
   311 
   312 fun axioms ta kind group (vars, specs) lthy =
   313   let
   314     val thy_ctxt = ProofContext.init (ProofContext.theory_of lthy);
   315     val expanded_props = map (Assumption.export_term lthy thy_ctxt) (maps snd specs);
   316     val xs = fold Term.add_frees expanded_props [];
   317 
   318     (*consts*)
   319     val (consts, lthy') = fold_map (declare_const ta (member (op =) xs)) vars lthy;
   320     val global_consts = map (Term.dest_Const o Term.head_of o Thm.term_of o Thm.rhs_of o #2) consts;
   321 
   322     (*axioms*)
   323     val hyps = map Thm.term_of (Assumption.assms_of lthy');
   324     fun axiom ((name, atts), props) thy = thy
   325       |> fold_map (Thm.add_axiom hyps) (PureThy.name_multi name props)
   326       |-> (fn ths => pair ((name, atts), [(ths, [])]));
   327   in
   328     lthy'
   329     |> fold Variable.declare_term expanded_props
   330     |> LocalTheory.theory (fold (fn c => Theory.add_deps "" c []) global_consts)
   331     |> LocalTheory.theory_result (fold_map axiom specs)
   332     |-> notes ta kind group
   333     |>> pair (map #1 consts)
   334   end;
   335 
   336 
   337 (* init *)
   338 
   339 local
   340 
   341 fun init_target _ NONE = global_target
   342   | init_target thy (SOME target) =
   343       make_target target true (Class.is_class thy target) ([], [], []) [];
   344 
   345 fun init_ctxt (Target {target, is_locale, is_class, instantiation, overloading}) =
   346   if not (null (#1 instantiation)) then Class.init_instantiation instantiation
   347   else if not (null overloading) then Overloading.init overloading
   348   else if not is_locale then ProofContext.init
   349   else if not is_class then Locale.init target
   350   else Class.init target;
   351 
   352 fun init_lthy (ta as Target {target, instantiation, overloading, ...}) =
   353   Data.put ta #>
   354   LocalTheory.init (NameSpace.base target)
   355    {pretty = pretty ta,
   356     axioms = axioms ta,
   357     abbrev = abbrev ta,
   358     define = define ta,
   359     notes = notes ta,
   360     type_syntax = type_syntax ta,
   361     term_syntax = term_syntax ta,
   362     declaration = declaration ta,
   363     reinit = fn lthy => init_lthy_ctxt ta (ProofContext.theory_of lthy),
   364     exit = LocalTheory.target_of o
   365       (if not (null (#1 instantiation)) then Class.conclude_instantiation
   366        else if not (null overloading) then Overloading.conclude
   367        else I)}
   368 and init_lthy_ctxt ta = init_lthy ta o init_ctxt ta;
   369 
   370 fun gen_overloading prep_const raw_ops thy =
   371   let
   372     val ctxt = ProofContext.init thy;
   373     val ops = raw_ops |> map (fn (name, const, checked) =>
   374       (name, Term.dest_Const (prep_const ctxt const), checked));
   375   in thy |> init_lthy_ctxt (make_target "" false false ([], [], []) ops) end;
   376 
   377 in
   378 
   379 fun init target thy = init_lthy_ctxt (init_target thy target) thy;
   380 fun begin target ctxt = init_lthy (init_target (ProofContext.theory_of ctxt) (SOME target)) ctxt;
   381 
   382 fun context "-" thy = init NONE thy
   383   | context target thy = init (SOME (Locale.intern thy target)) thy;
   384 
   385 fun instantiation arities = init_lthy_ctxt (make_target "" false false arities []);
   386 
   387 val overloading = gen_overloading (fn ctxt => Syntax.check_term ctxt o Const);
   388 val overloading_cmd = gen_overloading Syntax.read_term;
   389 
   390 end;
   391 
   392 end;
   393