src/Pure/library.ML
 author wenzelm Wed Aug 06 14:09:50 1997 +0200 (1997-08-06) changeset 3624 36e19fce289e parent 3606 5d7073700fbc child 3645 cfbd814a11f2 permissions -rw-r--r--
1 (*  Title:      Pure/library.ML
2     ID:         \$Id\$
3     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
4     Copyright   1992  University of Cambridge
6 Basic library: functions, options, pairs, booleans, lists, integers,
7 strings, lists as sets, association lists, generic tables, balanced trees,
8 orders, input / output, timing, filenames, misc functions.
9 *)
11 infix |> ~~ \ \\ orelf ins ins_string ins_int orf andf prefix upto downto
12       mem mem_int mem_string union union_int union_string
13       inter inter_int inter_string subset subset_int subset_string subdir_of;
16 structure Library =
17 struct
19 (** functions **)
21 (*handy combinators*)
22 fun curry f x y = f (x, y);
23 fun uncurry f (x, y) = f x y;
24 fun I x = x;
25 fun K x y = x;
27 (*reverse apply*)
28 fun (x |> f) = f x;
30 (*combine two functions forming the union of their domains*)
31 fun (f orelf g) = fn x => f x handle Match => g x;
33 (*application of (infix) operator to its left or right argument*)
34 fun apl (x, f) y = f (x, y);
35 fun apr (f, y) x = f (x, y);
37 (*functional for pairs*)
38 fun pairself f (x, y) = (f x, f y);
40 (*function exponentiation: f(...(f x)...) with n applications of f*)
41 fun funpow n f x =
42   let fun rep (0, x) = x
43         | rep (n, x) = rep (n - 1, f x)
44   in rep (n, x) end;
48 (** stamps **)
50 type stamp = unit ref;
51 val stamp: unit -> stamp = ref;
55 (** options **)
57 datatype 'a option = None | Some of 'a;
59 exception OPTION of string;
61 fun the (Some x) = x
62   | the None = raise OPTION "the";
64 fun if_none None y = y
65   | if_none (Some x) _ = x;
67 fun is_some (Some _) = true
68   | is_some None = false;
70 fun is_none (Some _) = false
71   | is_none None = true;
73 fun apsome f (Some x) = Some (f x)
74   | apsome _ None = None;
78 (** pairs **)
80 fun pair x y = (x, y);
81 fun rpair x y = (y, x);
83 fun fst (x, y) = x;
84 fun snd (x, y) = y;
86 fun eq_fst ((x1, _), (x2, _)) = x1 = x2;
87 fun eq_snd ((_, y1), (_, y2)) = y1 = y2;
89 fun swap (x, y) = (y, x);
91 (*apply the function to a component of a pair*)
92 fun apfst f (x, y) = (f x, y);
93 fun apsnd f (x, y) = (x, f y);
97 (** booleans **)
99 (* equality *)
101 fun equal x y = x = y;
102 fun not_equal x y = x <> y;
105 (* operators for combining predicates *)
107 fun (p orf q) = fn x => p x orelse q x;
109 fun (p andf q) = fn x => p x andalso q x;
111 fun notf p x = not (p x);
114 (* predicates on lists *)
116 fun orl [] = false
117   | orl (x :: xs) = x orelse orl xs;
119 fun andl [] = true
120   | andl (x :: xs) = x andalso andl xs;
122 (*Several object-logics declare theories named List or Option, hiding the
123   eponymous basis library structures.*)
124 structure List_ = List
125 and       Option_ = Option;
127 (*exists pred [x1, ..., xn] ===> pred x1 orelse ... orelse pred xn*)
128 fun exists (pred: 'a -> bool) : 'a list -> bool =
129   let fun boolf [] = false
130         | boolf (x :: xs) = pred x orelse boolf xs
131   in boolf end;
133 (*forall pred [x1, ..., xn] ===> pred x1 andalso ... andalso pred xn*)
134 fun forall (pred: 'a -> bool) : 'a list -> bool =
135   let fun boolf [] = true
136         | boolf (x :: xs) = pred x andalso boolf xs
137   in boolf end;
140 (* flags *)
142 fun set flag = (flag := true; true);
143 fun reset flag = (flag := false; false);
144 fun toggle flag = (flag := not (! flag); ! flag);
146 fun setmp flag value f x =
147   let
148     val orig_value = ! flag;
149     fun return y = (flag := orig_value; y);
150   in
151     flag := value;
152     return (f x handle exn => (return (); raise exn))
153   end;
157 (** lists **)
159 exception LIST of string;
161 fun null [] = true
162   | null (_ :: _) = false;
164 fun hd [] = raise LIST "hd"
165   | hd (x :: _) = x;
167 fun tl [] = raise LIST "tl"
168   | tl (_ :: xs) = xs;
170 fun cons x xs = x :: xs;
173 (* fold *)
175 (*the following versions of fold are designed to fit nicely with infixes*)
177 (*  (op @) (e, [x1, ..., xn])  ===>  ((e @ x1) @ x2) ... @ xn
178     for operators that associate to the left (TAIL RECURSIVE)*)
179 fun foldl (f: 'a * 'b -> 'a) : 'a * 'b list -> 'a =
180   let fun itl (e, [])  = e
181         | itl (e, a::l) = itl (f(e, a), l)
182   in  itl end;
184 (*  (op @) ([x1, ..., xn], e)  ===>   x1 @ (x2 ... @ (xn @ e))
185     for operators that associate to the right (not tail recursive)*)
186 fun foldr f (l, e) =
187   let fun itr [] = e
188         | itr (a::l) = f(a, itr l)
189   in  itr l  end;
191 (*  (op @) [x1, ..., xn]  ===>   x1 @ (x2 ... @ (x[n-1] @ xn))
192     for n > 0, operators that associate to the right (not tail recursive)*)
193 fun foldr1 f l =
194   let fun itr [x] = x                       (* FIXME [] case: elim warn (?) *)
195         | itr (x::l) = f(x, itr l)
196   in  itr l  end;
199 (* basic list functions *)
201 (*length of a list, should unquestionably be a standard function*)
202 local fun length1 (n, [])  = n   (*TAIL RECURSIVE*)
203         | length1 (n, x :: xs) = length1 (n + 1, xs)
204 in  fun length l = length1 (0, l) end;
206 (*take the first n elements from a list*)
207 fun take (n, []) = []
208   | take (n, x :: xs) =
209       if n > 0 then x :: take (n - 1, xs) else [];
211 (*drop the first n elements from a list*)
212 fun drop (n, []) = []
213   | drop (n, x :: xs) =
214       if n > 0 then drop (n - 1, xs) else x :: xs;
216 (*return nth element of a list, where 0 designates the first element;
217   raise EXCEPTION if list too short*)
218 fun nth_elem NL =
219   (case drop NL of
220     [] => raise LIST "nth_elem"
221   | x :: _ => x);
223 (*last element of a list*)
224 fun last_elem [] = raise LIST "last_elem"
225   | last_elem [x] = x
226   | last_elem (_ :: xs) = last_elem xs;
228 (*find the position of an element in a list*)
229 fun find (x, ys) =
230   let fun f (y :: ys, i) = if x = y then i else f (ys, i + 1)
231         | f (_, _) = raise LIST "find"
232   in f (ys, 0) end;
234 (*flatten a list of lists to a list*)
235 fun flat (ls: 'c list list) : 'c list = foldr (op @) (ls, []);
238 (*like Lisp's MAPC -- seq proc [x1, ..., xn] evaluates
239   (proc x1; ...; proc xn) for side effects*)
240 fun seq (proc: 'a -> unit) : 'a list -> unit =
241   let fun seqf [] = ()
242         | seqf (x :: xs) = (proc x; seqf xs)
243   in seqf end;
246 (*separate s [x1, x2, ..., xn]  ===>  [x1, s, x2, s, ..., s, xn]*)
247 fun separate s (x :: (xs as _ :: _)) = x :: s :: separate s xs
248   | separate _ xs = xs;
250 (*make the list [x, x, ..., x] of length n*)
251 fun replicate n (x: 'a) : 'a list =
252   let fun rep (0, xs) = xs
253         | rep (n, xs) = rep (n - 1, x :: xs)
254   in
255     if n < 0 then raise LIST "replicate"
256     else rep (n, [])
257   end;
260 (* filter *)
262 (*copy the list preserving elements that satisfy the predicate*)
263 fun filter (pred: 'a->bool) : 'a list -> 'a list =
264   let fun filt [] = []
265         | filt (x :: xs) = if pred x then x :: filt xs else filt xs
266   in filt end;
268 fun filter_out f = filter (not o f);
271 fun mapfilter (f: 'a -> 'b option) ([]: 'a list) = [] : 'b list
272   | mapfilter f (x :: xs) =
273       (case f x of
274         None => mapfilter f xs
275       | Some y => y :: mapfilter f xs);
278 fun find_first _ [] = None
279   | find_first pred (x :: xs) =
280       if pred x then Some x else find_first pred xs;
283 (* lists of pairs *)
285 fun map2 _ ([], []) = []
286   | map2 f (x :: xs, y :: ys) = (f (x, y) :: map2 f (xs, ys))
287   | map2 _ _ = raise LIST "map2";
289 fun exists2 _ ([], []) = false
290   | exists2 pred (x :: xs, y :: ys) = pred (x, y) orelse exists2 pred (xs, ys)
291   | exists2 _ _ = raise LIST "exists2";
293 fun forall2 _ ([], []) = true
294   | forall2 pred (x :: xs, y :: ys) = pred (x, y) andalso forall2 pred (xs, ys)
295   | forall2 _ _ = raise LIST "forall2";
297 (*combine two lists forming a list of pairs:
298   [x1, ..., xn] ~~ [y1, ..., yn]  ===>  [(x1, y1), ..., (xn, yn)]*)
299 fun [] ~~ [] = []
300   | (x :: xs) ~~ (y :: ys) = (x, y) :: (xs ~~ ys)
301   | _ ~~ _ = raise LIST "~~";
304 (*inverse of ~~; the old 'split':
305   [(x1, y1), ..., (xn, yn)]  ===>  ([x1, ..., xn], [y1, ..., yn])*)
306 fun split_list (l: ('a * 'b) list) = (map #1 l, map #2 l);
309 (* prefixes, suffixes *)
311 fun [] prefix _ = true
312   | (x :: xs) prefix (y :: ys) = x = y andalso (xs prefix ys)
313   | _ prefix _ = false;
315 (* [x1, ..., xi, ..., xn]  --->  ([x1, ..., x(i-1)], [xi, ..., xn])
316    where xi is the first element that does not satisfy the predicate*)
317 fun take_prefix (pred : 'a -> bool)  (xs: 'a list) : 'a list * 'a list =
318   let fun take (rxs, []) = (rev rxs, [])
319         | take (rxs, x :: xs) =
320             if  pred x  then  take(x :: rxs, xs)  else  (rev rxs, x :: xs)
321   in  take([], xs)  end;
323 (* [x1, ..., xi, ..., xn]  --->  ([x1, ..., xi], [x(i+1), ..., xn])
324    where xi is the last element that does not satisfy the predicate*)
325 fun take_suffix _ [] = ([], [])
326   | take_suffix pred (x :: xs) =
327       (case take_suffix pred xs of
328         ([], sffx) => if pred x then ([], x :: sffx) else ([x], sffx)
329       | (prfx, sffx) => (x :: prfx, sffx));
333 (** integers **)
335 fun inc i = (i := ! i + 1; ! i);
336 fun dec i = (i := ! i - 1; ! i);
339 (* lists of integers *)
341 (*make the list [from, from + 1, ..., to]*)
342 fun (from upto to) =
343   if from > to then [] else from :: ((from + 1) upto to);
345 (*make the list [from, from - 1, ..., to]*)
346 fun (from downto to) =
347   if from < to then [] else from :: ((from - 1) downto to);
349 (*predicate: downto0 (is, n) <=> is = [n, n - 1, ..., 0]*)
350 fun downto0 (i :: is, n) = i = n andalso downto0 (is, n - 1)
351   | downto0 ([], n) = n = ~1;
354 (* convert integers to strings *)
356 (*expand the number in the given base;
357   example: radixpand (2, 8) gives [1, 0, 0, 0]*)
358 fun radixpand (base, num) : int list =
359   let
360     fun radix (n, tail) =
361       if n < base then n :: tail
362       else radix (n div base, (n mod base) :: tail)
363   in radix (num, []) end;
365 (*expands a number into a string of characters starting from "zerochar";
366   example: radixstring (2, "0", 8) gives "1000"*)
367 fun radixstring (base, zerochar, num) =
368   let val offset = ord zerochar;
369       fun chrof n = chr (offset + n)
370   in implode (map chrof (radixpand (base, num))) end;
373 val string_of_int = Int.toString;
375 fun string_of_indexname (a,0) = a
376   | string_of_indexname (a,i) = a ^ "_" ^ Int.toString i;
379 (** strings **)
381 fun is_letter ch =
382   ord "A" <= ord ch andalso ord ch <= ord "Z" orelse
383   ord "a" <= ord ch andalso ord ch <= ord "z";
385 fun is_digit ch =
386   ord "0" <= ord ch andalso ord ch <= ord "9";
388 (*letter or _ or prime (')*)
389 fun is_quasi_letter "_" = true
390   | is_quasi_letter "'" = true
391   | is_quasi_letter ch = is_letter ch;
393 (*white space: blanks, tabs, newlines, formfeeds*)
394 val is_blank : string -> bool =
395   fn " " => true | "\t" => true | "\n" => true | "\^L" => true | "\160" => true
396     | _ => false;
398 val is_letdig = is_quasi_letter orf is_digit;
400 (*printable chars*)
401 fun is_printable c = ord c > ord " " andalso ord c <= ord "~";
404 (*lower all chars of string*)
405 val to_lower =
406   let
407     fun lower ch =
408       if ch >= "A" andalso ch <= "Z" then
409         chr (ord ch - ord "A" + ord "a")
410       else ch;
411   in implode o (map lower) o explode end;
414 (*enclose in brackets*)
415 fun enclose lpar rpar str = lpar ^ str ^ rpar;
417 (*simple quoting (does not escape special chars)*)
418 val quote = enclose "\"" "\"";
420 (*space_implode "..." (explode "hello"); gives "h...e...l...l...o"*)
421 fun space_implode a bs = implode (separate a bs);
423 val commas = space_implode ", ";
424 val commas_quote = commas o map quote;
426 (*concatenate messages, one per line, into a string*)
427 val cat_lines = space_implode "\n";
429 (*space_explode "." "h.e..l.lo"; gives ["h", "e", "l", "lo"]*)
430 fun space_explode sep s =
431   let fun divide [] "" = []
432         | divide [] part = [part]
433         | divide (c::s) part =
434             if c = sep then
435               (if part = "" then divide s "" else part :: divide s "")
436             else divide s (part ^ c)
437   in divide (explode s) "" end;
440 (** lists as sets **)
442 (*membership in a list*)
443 fun x mem [] = false
444   | x mem (y :: ys) = x = y orelse x mem ys;
446 (*membership in a list, optimized version for ints*)
447 fun (x:int) mem_int [] = false
448   | x mem_int (y :: ys) = x = y orelse x mem_int ys;
450 (*membership in a list, optimized version for strings*)
451 fun (x:string) mem_string [] = false
452   | x mem_string (y :: ys) = x = y orelse x mem_string ys;
454 (*generalized membership test*)
455 fun gen_mem eq (x, []) = false
456   | gen_mem eq (x, y :: ys) = eq (x, y) orelse gen_mem eq (x, ys);
459 (*insertion into list if not already there*)
460 fun (x ins xs) = if x mem xs then xs else x :: xs;
462 (*insertion into list, optimized version for ints*)
463 fun (x ins_int xs) = if x mem_int xs then xs else x :: xs;
465 (*insertion into list, optimized version for strings*)
466 fun (x ins_string xs) = if x mem_string xs then xs else x :: xs;
468 (*generalized insertion*)
469 fun gen_ins eq (x, xs) = if gen_mem eq (x, xs) then xs else x :: xs;
472 (*union of sets represented as lists: no repetitions*)
473 fun xs union [] = xs
474   | [] union ys = ys
475   | (x :: xs) union ys = xs union (x ins ys);
477 (*union of sets, optimized version for ints*)
478 fun (xs:int list) union_int [] = xs
479   | [] union_int ys = ys
480   | (x :: xs) union_int ys = xs union_int (x ins_int ys);
482 (*union of sets, optimized version for strings*)
483 fun (xs:string list) union_string [] = xs
484   | [] union_string ys = ys
485   | (x :: xs) union_string ys = xs union_string (x ins_string ys);
487 (*generalized union*)
488 fun gen_union eq (xs, []) = xs
489   | gen_union eq ([], ys) = ys
490   | gen_union eq (x :: xs, ys) = gen_union eq (xs, gen_ins eq (x, ys));
493 (*intersection*)
494 fun [] inter ys = []
495   | (x :: xs) inter ys =
496       if x mem ys then x :: (xs inter ys) else xs inter ys;
498 (*intersection, optimized version for ints*)
499 fun ([]:int list) inter_int ys = []
500   | (x :: xs) inter_int ys =
501       if x mem_int ys then x :: (xs inter_int ys) else xs inter_int ys;
503 (*intersection, optimized version for strings *)
504 fun ([]:string list) inter_string ys = []
505   | (x :: xs) inter_string ys =
506       if x mem_string ys then x :: (xs inter_string ys) else xs inter_string ys;
509 (*subset*)
510 fun [] subset ys = true
511   | (x :: xs) subset ys = x mem ys andalso xs subset ys;
513 (*subset, optimized version for ints*)
514 fun ([]:int list) subset_int ys = true
515   | (x :: xs) subset_int ys = x mem_int ys andalso xs subset_int ys;
517 (*subset, optimized version for strings*)
518 fun ([]:string list) subset_string ys = true
519   | (x :: xs) subset_string ys = x mem_string ys andalso xs subset_string ys;
521 (*set equality for strings*)
522 fun eq_set_string ((xs:string list), ys) =
523   xs = ys orelse (xs subset_string ys andalso ys subset_string xs);
525 fun gen_subset eq (xs, ys) = forall (fn x => gen_mem eq (x, ys)) xs;
528 (*removing an element from a list WITHOUT duplicates*)
529 fun (y :: ys) \ x = if x = y then ys else y :: (ys \ x)
530   | [] \ x = [];
532 fun ys \\ xs = foldl (op \) (ys,xs);
534 (*removing an element from a list -- possibly WITH duplicates*)
535 fun gen_rem eq (xs, y) = filter_out (fn x => eq (x, y)) xs;
537 fun gen_rems eq = foldl (gen_rem eq);
540 (*makes a list of the distinct members of the input; preserves order, takes
541   first of equal elements*)
542 fun gen_distinct eq lst =
543   let
544     val memb = gen_mem eq;
546     fun dist (rev_seen, []) = rev rev_seen
547       | dist (rev_seen, x :: xs) =
548           if memb (x, rev_seen) then dist (rev_seen, xs)
549           else dist (x :: rev_seen, xs);
550   in
551     dist ([], lst)
552   end;
554 fun distinct l = gen_distinct (op =) l;
557 (*returns the tail beginning with the first repeated element, or []*)
558 fun findrep [] = []
559   | findrep (x :: xs) = if x mem xs then x :: xs else findrep xs;
562 (*returns a list containing all repeated elements exactly once; preserves
563   order, takes first of equal elements*)
564 fun gen_duplicates eq lst =
565   let
566     val memb = gen_mem eq;
568     fun dups (rev_dups, []) = rev rev_dups
569       | dups (rev_dups, x :: xs) =
570           if memb (x, rev_dups) orelse not (memb (x, xs)) then
571             dups (rev_dups, xs)
572           else dups (x :: rev_dups, xs);
573   in
574     dups ([], lst)
575   end;
577 fun duplicates l = gen_duplicates (op =) l;
581 (** association lists **)
583 (*association list lookup*)
584 fun assoc ([], key) = None
585   | assoc ((keyi, xi) :: pairs, key) =
586       if key = keyi then Some xi else assoc (pairs, key);
588 (*association list lookup, optimized version for ints*)
589 fun assoc_int ([], (key:int)) = None
590   | assoc_int ((keyi, xi) :: pairs, key) =
591       if key = keyi then Some xi else assoc_int (pairs, key);
593 (*association list lookup, optimized version for strings*)
594 fun assoc_string ([], (key:string)) = None
595   | assoc_string ((keyi, xi) :: pairs, key) =
596       if key = keyi then Some xi else assoc_string (pairs, key);
598 (*association list lookup, optimized version for string*ints*)
599 fun assoc_string_int ([], (key:string*int)) = None
600   | assoc_string_int ((keyi, xi) :: pairs, key) =
601       if key = keyi then Some xi else assoc_string_int (pairs, key);
603 fun assocs ps x =
604   (case assoc (ps, x) of
605     None => []
606   | Some ys => ys);
608 (*two-fold association list lookup*)
609 fun assoc2 (aal, (key1, key2)) =
610   (case assoc (aal, key1) of
611     Some al => assoc (al, key2)
612   | None => None);
614 (*generalized association list lookup*)
615 fun gen_assoc eq ([], key) = None
616   | gen_assoc eq ((keyi, xi) :: pairs, key) =
617       if eq (key, keyi) then Some xi else gen_assoc eq (pairs, key);
619 (*association list update*)
620 fun overwrite (al, p as (key, _)) =
621   let fun over ((q as (keyi, _)) :: pairs) =
622             if keyi = key then p :: pairs else q :: (over pairs)
623         | over [] = [p]
624   in over al end;
626 fun gen_overwrite eq (al, p as (key, _)) =
627   let fun over ((q as (keyi, _)) :: pairs) =
628             if eq (keyi, key) then p :: pairs else q :: (over pairs)
629         | over [] = [p]
630   in over al end;
634 (** generic tables **)
636 (*Tables are supposed to be 'efficient' encodings of lists of elements distinct
637   wrt. an equality "eq". The extend and merge operations below are optimized
638   for long-term space efficiency.*)
640 (*append (new) elements to a table*)
641 fun generic_extend _ _ _ tab [] = tab
642   | generic_extend eq dest_tab mk_tab tab1 lst2 =
643       let
644         val lst1 = dest_tab tab1;
645         val new_lst2 = gen_rems eq (lst2, lst1);
646       in
647         if null new_lst2 then tab1
648         else mk_tab (lst1 @ new_lst2)
649       end;
651 (*append (new) elements of 2nd table to 1st table*)
652 fun generic_merge eq dest_tab mk_tab tab1 tab2 =
653   let
654     val lst1 = dest_tab tab1;
655     val lst2 = dest_tab tab2;
656     val new_lst2 = gen_rems eq (lst2, lst1);
657   in
658     if null new_lst2 then tab1
659     else if gen_subset eq (lst1, lst2) then tab2
660     else mk_tab (lst1 @ new_lst2)
661   end;
664 (*lists as tables*)
665 fun extend_list tab = generic_extend (op =) I I tab;
666 fun merge_lists tab = generic_merge (op =) I I tab;
668 fun merge_rev_lists xs [] = xs
669   | merge_rev_lists [] ys = ys
670   | merge_rev_lists xs (y :: ys) =
671       (if y mem xs then I else cons y) (merge_rev_lists xs ys);
675 (** balanced trees **)
677 exception Balance;      (*indicates non-positive argument to balancing fun*)
679 (*balanced folding; avoids deep nesting*)
680 fun fold_bal f [x] = x
681   | fold_bal f [] = raise Balance
682   | fold_bal f xs =
683       let val k = length xs div 2
684       in  f (fold_bal f (take(k, xs)),
685              fold_bal f (drop(k, xs)))
686       end;
688 (*construct something of the form f(...g(...(x)...)) for balanced access*)
689 fun access_bal (f, g, x) n i =
690   let fun acc n i =     (*1<=i<=n*)
691           if n=1 then x else
692           let val n2 = n div 2
693           in  if i<=n2 then f (acc n2 i)
694                        else g (acc (n-n2) (i-n2))
695           end
696   in  if 1<=i andalso i<=n then acc n i else raise Balance  end;
698 (*construct ALL such accesses; could try harder to share recursive calls!*)
699 fun accesses_bal (f, g, x) n =
700   let fun acc n =
701           if n=1 then [x] else
702           let val n2 = n div 2
703               val acc2 = acc n2
704           in  if n-n2=n2 then map f acc2 @ map g acc2
705                          else map f acc2 @ map g (acc (n-n2)) end
706   in  if 1<=n then acc n else raise Balance  end;
710 (** orders **)
712 datatype order = LESS | EQUAL | GREATER;
714 fun intord (i, j: int) =
715   if i < j then LESS
716   else if i = j then EQUAL
717   else GREATER;
719 fun stringord (a, b: string) =
720   if a < b then LESS
721   else if a = b then EQUAL
722   else GREATER;
726 (** input / output and diagnostics **)
728 val cd = OS.FileSys.chDir;
729 val pwd = OS.FileSys.getDir;
732 local
733   fun out s =
734     (TextIO.output (TextIO.stdOut, s); TextIO.flushOut TextIO.stdOut);
736   fun lines cs =
737     (case take_prefix (not_equal "\n") cs of
738       (cs', []) => [implode cs']
739     | (cs', _ :: cs'') => implode cs' :: lines cs'');
741   fun prefix_lines prfx txt =
742     txt |> explode |> lines |> map (fn s => prfx ^ s ^ "\n") |> implode;
743 in
745 (*hooks for output channels: normal, warning, error*)
746 val prs_fn = ref (fn s => out s);
747 val warning_fn = ref (fn s => out (prefix_lines "### " s));
748 val error_fn = ref (fn s => out (prefix_lines "*** " s));
750 end;
752 fun prs s = !prs_fn s;
753 fun writeln s = prs (s ^ "\n");
755 fun warning s = !warning_fn s;
757 (*print error message and abort to top level*)
758 exception ERROR;
759 fun error_msg s = !error_fn s;
760 fun error s = (error_msg s; raise ERROR);
761 fun sys_error msg = (error_msg " !! SYSTEM ERROR !!\n"; error msg);
763 fun assert p msg = if p then () else error msg;
764 fun deny p msg = if p then error msg else ();
766 (*Assert pred for every member of l, generating a message if pred fails*)
767 fun assert_all pred l msg_fn =
768   let fun asl [] = ()
769         | asl (x::xs) = if pred x then asl xs
770                         else error (msg_fn x)
771   in  asl l  end;
774 (* read / write files *)
776 fun read_file name =
777   let
778     val instream  = TextIO.openIn name;
779     val intext = TextIO.inputAll instream;
780   in
781     TextIO.closeIn instream;
782     intext
783   end;
785 fun write_file name txt =
786   let
787     val outstream = TextIO.openOut name;
788   in
789     TextIO.output (outstream, txt);
790     TextIO.closeOut outstream
791   end;
794 (*for the "test" target in IsaMakefiles -- signifies successful termination*)
795 fun maketest msg =
796   (writeln msg; write_file "test" "Test examples ran successfully\n");
799 (*print a list surrounded by the brackets lpar and rpar, with comma separator
800   print nothing for empty list*)
801 fun print_list (lpar, rpar, pre: 'a -> unit) (l : 'a list) =
802   let fun prec x = (prs ","; pre x)
803   in
804     (case l of
805       [] => ()
806     | x::l => (prs lpar; pre x; seq prec l; prs rpar))
807   end;
809 (*print a list of items separated by newlines*)
810 fun print_list_ln (pre: 'a -> unit) : 'a list -> unit =
811   seq (fn x => (pre x; writeln ""));
814 val print_int = prs o string_of_int;
817 (* output to LaTeX / xdvi *)
818 fun latex s =
819   execute ("( cd /tmp ; echo \"" ^ s ^
820     "\" | isa2latex -s > \$\$.tex ; latex \$\$.tex ; xdvi \$\$.dvi ; rm \$\$.* ) > /dev/null &");
823 (** timing **)
825 (*unconditional timing function*)
826 fun timeit x = cond_timeit true x;
828 (*timed application function*)
829 fun timeap f x = timeit (fn () => f x);
831 (*timed "use" function, printing filenames*)
832 fun time_use fname = timeit (fn () =>
833   (writeln ("\n**** Starting " ^ fname ^ " ****"); use fname;
834    writeln ("\n**** Finished " ^ fname ^ " ****")));
836 (*use the file, but exit with error code if errors found.*)
837 fun exit_use fname = use fname handle _ => exit 1;
840 (** filenames and paths **)
842 (*Convert UNIX filename of the form "path/file" to "path/" and "file";
843   if filename contains no slash, then it returns "" and "file"*)
844 val split_filename =
845   (pairself implode) o take_suffix (not_equal "/") o explode;
847 val base_name = #2 o split_filename;
849 (*Merge splitted filename (path and file);
850   if path does not end with one a slash is appended*)
851 fun tack_on "" name = name
852   | tack_on path name =
853       if last_elem (explode path) = "/" then path ^ name
854       else path ^ "/" ^ name;
856 (*Remove the extension of a filename, i.e. the part after the last '.'*)
857 val remove_ext = implode o #1 o take_suffix (not_equal ".") o explode;
859 (*Make relative path to reach an absolute location from a different one*)
860 fun relative_path cur_path dest_path =
861   let (*Remove common beginning of both paths and make relative path*)
862       fun mk_relative [] [] = []
863         | mk_relative [] ds = ds
864         | mk_relative cs [] = map (fn _ => "..") cs
865         | mk_relative (c::cs) (d::ds) =
866             if c = d then mk_relative cs ds
867             else ".." :: map (fn _ => "..") cs @ (d::ds);
868   in if cur_path = "" orelse hd (explode cur_path) <> "/" orelse
869         dest_path = "" orelse hd (explode dest_path) <> "/" then
870        error "Relative or empty path passed to relative_path"
871      else ();
872      space_implode "/" (mk_relative (space_explode "/" cur_path)
873                                     (space_explode "/" dest_path))
874   end;
876 (*Determine if absolute path1 is a subdirectory of absolute path2*)
877 fun path1 subdir_of path2 =
878   if hd (explode path1) <> "/" orelse hd (explode path2) <> "/" then
879     error "Relative or empty path passed to subdir_of"
880   else (space_explode "/" path2) prefix (space_explode "/" path1);
882 fun absolute_path cwd file =
883   let fun rm_points [] result = rev result
884         | rm_points (".."::ds) result = rm_points ds (tl result)
885         | rm_points ("."::ds) result = rm_points ds result
886         | rm_points (d::ds) result = rm_points ds (d::result);
887   in if file = "" then ""
888      else if hd (explode file) = "/" then file
889      else "/" ^ space_implode "/"
890                   (rm_points (space_explode "/" (tack_on cwd file)) [])
891   end;
893 fun file_exists file = (file_info file <> "");
896 (** misc functions **)
898 (*use the keyfun to make a list of (x, key) pairs*)
899 fun make_keylist (keyfun: 'a->'b) : 'a list -> ('a * 'b) list =
900   let fun keypair x = (x, keyfun x)
901   in map keypair end;
903 (*given a list of (x, key) pairs and a searchkey
904   return the list of xs from each pair whose key equals searchkey*)
905 fun keyfilter [] searchkey = []
906   | keyfilter ((x, key) :: pairs) searchkey =
907       if key = searchkey then x :: keyfilter pairs searchkey
908       else keyfilter pairs searchkey;
911 (*Partition list into elements that satisfy predicate and those that don't.
912   Preserves order of elements in both lists.*)
913 fun partition (pred: 'a->bool) (ys: 'a list) : ('a list * 'a list) =
914     let fun part ([], answer) = answer
915           | part (x::xs, (ys, ns)) = if pred(x)
916             then  part (xs, (x::ys, ns))
917             else  part (xs, (ys, x::ns))
918     in  part (rev ys, ([], []))  end;
921 fun partition_eq (eq:'a * 'a -> bool) =
922     let fun part [] = []
923           | part (x::ys) = let val (xs, xs') = partition (apl(x, eq)) ys
924                            in (x::xs)::(part xs') end
925     in part end;
928 (*Partition a list into buckets  [ bi, b(i+1), ..., bj ]
929    putting x in bk if p(k)(x) holds.  Preserve order of elements if possible.*)
930 fun partition_list p i j =
931   let fun part k xs =
932             if k>j then
933               (case xs of [] => []
934                          | _ => raise LIST "partition_list")
935             else
936             let val (ns, rest) = partition (p k) xs;
937             in  ns :: part(k+1)rest  end
938   in  part i end;
941 (* sorting *)
943 (*insertion sort; stable (does not reorder equal elements)
944   'less' is less-than test on type 'a*)
945 fun sort (less: 'a*'a -> bool) =
946   let fun insert (x, []) = [x]
947         | insert (x, y::ys) =
948               if less(y, x) then y :: insert (x, ys) else x::y::ys;
949       fun sort1 [] = []
950         | sort1 (x::xs) = insert (x, sort1 xs)
951   in  sort1  end;
953 (*sort strings*)
954 val sort_strings = sort (op <= : string * string -> bool);
957 (* transitive closure (not Warshall's algorithm) *)
959 fun transitive_closure [] = []
960   | transitive_closure ((x, ys)::ps) =
961       let val qs = transitive_closure ps
962           val zs = foldl (fn (zs, y) => assocs qs y union_string zs) (ys, ys)
963           fun step(u, us) = (u, if x mem_string us then zs union_string us
964                                 else us)
965       in (x, zs) :: map step qs end;
968 (* generating identifiers *)
970 local
971   val a = ord "a" and z = ord "z" and A = ord "A" and Z = ord "Z"
972   and k0 = ord "0" and k9 = ord "9"
974   val seedr = ref 0;
975 in
977 (*Maps 0-63 to A-Z, a-z, 0-9 or _ or ' for generating random identifiers*)
978 fun newid n =
979   let fun char i =
980                if i<26 then chr (A+i)
981           else if i<52 then chr (a+i-26)
982           else if i<62 then chr (k0+i-52)
983           else if i=62 then "_"
984           else  (*i=63*)    "'"
985   in  implode (map char (radixpand (64,n)))  end;
987 (*Freshly generated identifiers with given prefix; MUST start with a letter*)
988 fun gensym pre = pre ^
989                  (#1(newid (!seedr),
990                      seedr := 1+ !seedr))
992 (*Increment a list of letters like a reversed base 26 number.
993   If head is "z", bumps chars in tail.
994   Digits are incremented as if they were integers.
995   "_" and "'" are not changed.
996   For making variants of identifiers.*)
998 fun bump_int_list(c::cs) = if c="9" then "0" :: bump_int_list cs else
999         if k0 <= ord(c) andalso ord(c) < k9 then chr(ord(c)+1) :: cs
1000         else "1" :: c :: cs
1001   | bump_int_list([]) = error("bump_int_list: not an identifier");
1003 fun bump_list([], d) = [d]
1004   | bump_list(["'"], d) = [d, "'"]
1005   | bump_list("z"::cs, _) = "a" :: bump_list(cs, "a")
1006   | bump_list("Z"::cs, _) = "A" :: bump_list(cs, "A")
1007   | bump_list("9"::cs, _) = "0" :: bump_int_list cs
1008   | bump_list(c::cs, _) = let val k = ord(c)
1009         in if (a <= k andalso k < z) orelse (A <= k andalso k < Z) orelse
1010               (k0 <= k andalso k < k9) then chr(k+1) :: cs else
1011            if c="'" orelse c="_" then c :: bump_list(cs, "") else
1012                 error("bump_list: not legal in identifier: " ^
1013                         implode(rev(c::cs)))
1014         end;
1016 end;
1018 fun bump_string s : string = implode (rev (bump_list(rev(explode s), "")));
1021 (* lexical scanning *)
1023 (*scan a list of characters into "words" composed of "letters" (recognized by
1024   is_let) and separated by any number of non-"letters"*)
1025 fun scanwords is_let cs =
1026   let fun scan1 [] = []
1027         | scan1 cs =
1028             let val (lets, rest) = take_prefix is_let cs
1029             in implode lets :: scanwords is_let rest end;
1030   in scan1 (#2 (take_prefix (not o is_let) cs)) end;
1032 end;
1034 (*Variable-branching trees: for proof terms*)
1035 datatype 'a mtree = Join of 'a * 'a mtree list;
1037 open Library;