(* Title: HOL/Parity.thy
Author: Jeremy Avigad
Author: Jacques D. Fleuriot
*)
header {* Even and Odd for int and nat *}
theory Parity
imports Main
begin
subsection {* Preliminaries about divisibility on @{typ nat} and @{typ int} *}
lemma two_dvd_Suc_Suc_iff [simp]:
"2 dvd Suc (Suc n) \<longleftrightarrow> 2 dvd n"
using dvd_add_triv_right_iff [of 2 n] by simp
lemma two_dvd_Suc_iff:
"2 dvd Suc n \<longleftrightarrow> \<not> 2 dvd n"
by (induct n) auto
lemma two_dvd_diff_iff:
fixes k l :: int
shows "2 dvd k - l \<longleftrightarrow> 2 dvd k + l"
using dvd_add_times_triv_right_iff [of 2 "k - l" l] by (simp add: ac_simps)
lemma two_dvd_abs_add_iff:
fixes k l :: int
shows "2 dvd \<bar>k\<bar> + l \<longleftrightarrow> 2 dvd k + l"
by (cases "k \<ge> 0") (simp_all add: two_dvd_diff_iff ac_simps)
lemma two_dvd_add_abs_iff:
fixes k l :: int
shows "2 dvd k + \<bar>l\<bar> \<longleftrightarrow> 2 dvd k + l"
using two_dvd_abs_add_iff [of l k] by (simp add: ac_simps)
subsection {* Ring structures with parity *}
class semiring_parity = semiring_dvd + semiring_numeral +
assumes two_not_dvd_one [simp]: "\<not> 2 dvd 1"
assumes not_dvd_not_dvd_dvd_add: "\<not> 2 dvd a \<Longrightarrow> \<not> 2 dvd b \<Longrightarrow> 2 dvd a + b"
assumes two_is_prime: "2 dvd a * b \<Longrightarrow> 2 dvd a \<or> 2 dvd b"
begin
lemma two_dvd_plus_one_iff [simp]:
"2 dvd a + 1 \<longleftrightarrow> \<not> 2 dvd a"
by (auto simp add: dvd_add_right_iff intro: not_dvd_not_dvd_dvd_add)
end
instance nat :: semiring_parity
proof
show "\<not> (2 :: nat) dvd 1"
by (rule notI, erule dvdE) simp
next
fix m n :: nat
assume "\<not> 2 dvd m"
moreover assume "\<not> 2 dvd n"
ultimately have *: "2 dvd Suc m \<and> 2 dvd Suc n"
by (simp add: two_dvd_Suc_iff)
then have "2 dvd Suc m + Suc n"
by (blast intro: dvd_add)
also have "Suc m + Suc n = m + n + 2"
by simp
finally show "2 dvd m + n"
using dvd_add_triv_right_iff [of 2 "m + n"] by simp
next
fix m n :: nat
assume *: "2 dvd m * n"
show "2 dvd m \<or> 2 dvd n"
proof (rule disjCI)
assume "\<not> 2 dvd n"
then have "2 dvd Suc n" by (simp add: two_dvd_Suc_iff)
then obtain r where "Suc n = 2 * r" ..
moreover from * obtain s where "m * n = 2 * s" ..
then have "2 * s + m = m * Suc n" by simp
ultimately have " 2 * s + m = 2 * (m * r)" by simp
then have "m = 2 * (m * r - s)" by simp
then show "2 dvd m" ..
qed
qed
class ring_parity = comm_ring_1 + semiring_parity
instance int :: ring_parity
proof
show "\<not> (2 :: int) dvd 1" by (simp add: dvd_int_unfold_dvd_nat)
fix k l :: int
assume "\<not> 2 dvd k"
moreover assume "\<not> 2 dvd l"
ultimately have "2 dvd nat \<bar>k\<bar> + nat \<bar>l\<bar>"
by (auto simp add: dvd_int_unfold_dvd_nat intro: not_dvd_not_dvd_dvd_add)
then have "2 dvd \<bar>k\<bar> + \<bar>l\<bar>"
by (simp add: dvd_int_unfold_dvd_nat nat_add_distrib)
then show "2 dvd k + l"
by (simp add: two_dvd_abs_add_iff two_dvd_add_abs_iff)
qed (simp add: dvd_int_unfold_dvd_nat two_is_prime nat_abs_mult_distrib)
context semiring_div_parity
begin
subclass semiring_parity
proof (unfold_locales, unfold dvd_eq_mod_eq_0 not_mod_2_eq_0_eq_1)
fix a b c
show "(c * a + b) mod a = 0 \<longleftrightarrow> b mod a = 0"
by simp
next
fix a b c
assume "(b + c) mod a = 0"
with mod_add_eq [of b c a]
have "(b mod a + c mod a) mod a = 0"
by simp
moreover assume "b mod a = 0"
ultimately show "c mod a = 0"
by simp
next
show "1 mod 2 = 1"
by (fact one_mod_two_eq_one)
next
fix a b
assume "a mod 2 = 1"
moreover assume "b mod 2 = 1"
ultimately show "(a + b) mod 2 = 0"
using mod_add_eq [of a b 2] by simp
next
fix a b
assume "(a * b) mod 2 = 0"
then have "(a mod 2) * (b mod 2) = 0"
by (cases "a mod 2 = 0") (simp_all add: mod_mult_eq [of a b 2])
then show "a mod 2 = 0 \<or> b mod 2 = 0"
by (rule divisors_zero)
qed
end
subsection {* Dedicated @{text even}/@{text odd} predicate *}
context semiring_parity
begin
definition even :: "'a \<Rightarrow> bool"
where
[algebra]: "even a \<longleftrightarrow> 2 dvd a"
abbreviation odd :: "'a \<Rightarrow> bool"
where
"odd a \<equiv> \<not> even a"
lemma even_times_iff [simp, presburger, algebra]:
"even (a * b) \<longleftrightarrow> even a \<or> even b"
by (auto simp add: even_def dest: two_is_prime)
lemma even_zero [simp]:
"even 0"
by (simp add: even_def)
lemma odd_one [simp]:
"odd 1"
by (simp add: even_def)
lemma even_numeral [simp]:
"even (numeral (Num.Bit0 n))"
proof -
have "even (2 * numeral n)"
unfolding even_times_iff by (simp add: even_def)
then have "even (numeral n + numeral n)"
unfolding mult_2 .
then show ?thesis
unfolding numeral.simps .
qed
lemma odd_numeral [simp]:
"odd (numeral (Num.Bit1 n))"
proof
assume "even (numeral (num.Bit1 n))"
then have "even (numeral n + numeral n + 1)"
unfolding numeral.simps .
then have "even (2 * numeral n + 1)"
unfolding mult_2 .
then have "2 dvd numeral n * 2 + 1"
unfolding even_def by (simp add: ac_simps)
with dvd_add_times_triv_left_iff [of 2 "numeral n" 1]
have "2 dvd 1"
by simp
then show False by simp
qed
end
context semiring_div_parity
begin
lemma even_iff_mod_2_eq_zero [presburger]:
"even a \<longleftrightarrow> a mod 2 = 0"
by (simp add: even_def dvd_eq_mod_eq_0)
lemma even_times_anything:
"even a \<Longrightarrow> even (a * b)"
by (simp add: even_def)
lemma anything_times_even:
"even a \<Longrightarrow> even (b * a)"
by (simp add: even_def)
lemma odd_times_odd:
"odd a \<Longrightarrow> odd b \<Longrightarrow> odd (a * b)"
by (auto simp add: even_iff_mod_2_eq_zero mod_mult_left_eq)
lemma even_product:
"even (a * b) \<longleftrightarrow> even a \<or> even b"
by (fact even_times_iff)
end
lemma even_nat_def [presburger]:
"even x \<longleftrightarrow> even (int x)"
by (auto simp add: even_iff_mod_2_eq_zero int_eq_iff int_mult nat_mult_distrib)
lemma transfer_int_nat_relations:
"even (int x) \<longleftrightarrow> even x"
by (simp add: even_nat_def)
declare transfer_morphism_int_nat[transfer add return:
transfer_int_nat_relations
]
declare even_iff_mod_2_eq_zero [of "- numeral v", simp] for v
subsection {* Behavior under integer arithmetic operations *}
lemma even_plus_even: "even (x::int) ==> even y ==> even (x + y)"
by presburger
lemma even_plus_odd: "even (x::int) ==> odd y ==> odd (x + y)"
by presburger
lemma odd_plus_even: "odd (x::int) ==> even y ==> odd (x + y)"
by presburger
lemma odd_plus_odd: "odd (x::int) ==> odd y ==> even (x + y)" by presburger
lemma even_sum[simp,presburger]:
"even ((x::int) + y) = ((even x & even y) | (odd x & odd y))"
by presburger
lemma even_neg[simp,presburger,algebra]: "even (-(x::int)) = even x"
by presburger
lemma even_difference[simp]:
"even ((x::int) - y) = ((even x & even y) | (odd x & odd y))" by presburger
lemma even_power[simp,presburger]: "even ((x::int)^n) = (even x & n \<noteq> 0)"
by (induct n) auto
lemma odd_pow: "odd x ==> odd((x::int)^n)" by simp
subsection {* Equivalent definitions *}
lemma two_times_even_div_two: "even (x::int) ==> 2 * (x div 2) = x"
by presburger
lemma two_times_odd_div_two_plus_one:
"odd (x::int) ==> 2 * (x div 2) + 1 = x"
by presburger
lemma even_equiv_def: "even (x::int) = (EX y. x = 2 * y)" by presburger
lemma odd_equiv_def: "odd (x::int) = (EX y. x = 2 * y + 1)" by presburger
subsection {* even and odd for nats *}
lemma pos_int_even_equiv_nat_even: "0 \<le> x ==> even x = even (nat x)"
by (simp add: even_nat_def)
lemma even_product_nat:
"even((x::nat) * y) = (even x | even y)"
by (fact even_times_iff)
lemma even_sum_nat[simp,presburger,algebra]:
"even ((x::nat) + y) = ((even x & even y) | (odd x & odd y))"
by presburger
lemma even_difference_nat[simp,presburger,algebra]:
"even ((x::nat) - y) = (x < y | (even x & even y) | (odd x & odd y))"
by presburger
lemma even_Suc[simp,presburger,algebra]: "even (Suc x) = odd x"
by presburger
lemma even_power_nat[simp,presburger,algebra]:
"even ((x::nat)^y) = (even x & 0 < y)"
by (simp add: even_nat_def int_power)
subsection {* Equivalent definitions *}
lemma even_nat_mod_two_eq_zero: "even (x::nat) ==> x mod (Suc (Suc 0)) = 0"
by presburger
lemma odd_nat_mod_two_eq_one: "odd (x::nat) ==> x mod (Suc (Suc 0)) = Suc 0"
by presburger
lemma even_nat_equiv_def: "even (x::nat) = (x mod Suc (Suc 0) = 0)"
by presburger
lemma odd_nat_equiv_def: "odd (x::nat) = (x mod Suc (Suc 0) = Suc 0)"
by presburger
lemma even_nat_div_two_times_two: "even (x::nat) ==>
Suc (Suc 0) * (x div Suc (Suc 0)) = x" by presburger
lemma odd_nat_div_two_times_two_plus_one: "odd (x::nat) ==>
Suc( Suc (Suc 0) * (x div Suc (Suc 0))) = x" by presburger
lemma even_nat_equiv_def2: "even (x::nat) = (EX y. x = Suc (Suc 0) * y)"
by presburger
lemma odd_nat_equiv_def2: "odd (x::nat) = (EX y. x = Suc(Suc (Suc 0) * y))"
by presburger
subsection {* Parity and powers *}
lemma (in comm_ring_1) neg_power_if:
"(- a) ^ n = (if even n then (a ^ n) else - (a ^ n))"
by (induct n) simp_all
lemma (in comm_ring_1)
shows neg_one_even_power [simp]: "even n \<Longrightarrow> (- 1) ^ n = 1"
and neg_one_odd_power [simp]: "odd n \<Longrightarrow> (- 1) ^ n = - 1"
by (simp_all add: neg_power_if)
lemma zero_le_even_power: "even n ==>
0 <= (x::'a::{linordered_ring,monoid_mult}) ^ n"
apply (simp add: even_nat_equiv_def2)
apply (erule exE)
apply (erule ssubst)
apply (subst power_add)
apply (rule zero_le_square)
done
lemma zero_le_odd_power: "odd n ==>
(0 <= (x::'a::{linordered_idom}) ^ n) = (0 <= x)"
apply (auto simp: odd_nat_equiv_def2 power_add zero_le_mult_iff)
apply (metis field_power_not_zero divisors_zero order_antisym_conv zero_le_square)
done
lemma zero_le_power_eq [presburger]: "(0 <= (x::'a::{linordered_idom}) ^ n) =
(even n | (odd n & 0 <= x))"
apply auto
apply (subst zero_le_odd_power [symmetric])
apply assumption+
apply (erule zero_le_even_power)
done
lemma zero_less_power_eq[presburger]: "(0 < (x::'a::{linordered_idom}) ^ n) =
(n = 0 | (even n & x ~= 0) | (odd n & 0 < x))"
unfolding order_less_le zero_le_power_eq by auto
lemma power_less_zero_eq[presburger]: "((x::'a::{linordered_idom}) ^ n < 0) =
(odd n & x < 0)"
apply (subst linorder_not_le [symmetric])+
apply (subst zero_le_power_eq)
apply auto
done
lemma power_le_zero_eq[presburger]: "((x::'a::{linordered_idom}) ^ n <= 0) =
(n ~= 0 & ((odd n & x <= 0) | (even n & x = 0)))"
apply (subst linorder_not_less [symmetric])+
apply (subst zero_less_power_eq)
apply auto
done
lemma power_even_abs: "even n ==>
(abs (x::'a::{linordered_idom}))^n = x^n"
apply (subst power_abs [symmetric])
apply (simp add: zero_le_even_power)
done
lemma power_minus_even [simp]: "even n ==>
(- x)^n = (x^n::'a::{comm_ring_1})"
apply (subst power_minus)
apply simp
done
lemma power_minus_odd [simp]: "odd n ==>
(- x)^n = - (x^n::'a::{comm_ring_1})"
apply (subst power_minus)
apply simp
done
lemma power_mono_even: fixes x y :: "'a :: {linordered_idom}"
assumes "even n" and "\<bar>x\<bar> \<le> \<bar>y\<bar>"
shows "x^n \<le> y^n"
proof -
have "0 \<le> \<bar>x\<bar>" by auto
with `\<bar>x\<bar> \<le> \<bar>y\<bar>`
have "\<bar>x\<bar>^n \<le> \<bar>y\<bar>^n" by (rule power_mono)
thus ?thesis unfolding power_even_abs[OF `even n`] .
qed
lemma odd_pos: "odd (n::nat) \<Longrightarrow> 0 < n" by presburger
lemma power_mono_odd: fixes x y :: "'a :: {linordered_idom}"
assumes "odd n" and "x \<le> y"
shows "x^n \<le> y^n"
proof (cases "y < 0")
case True with `x \<le> y` have "-y \<le> -x" and "0 \<le> -y" by auto
hence "(-y)^n \<le> (-x)^n" by (rule power_mono)
thus ?thesis unfolding power_minus_odd[OF `odd n`] by auto
next
case False
show ?thesis
proof (cases "x < 0")
case True hence "n \<noteq> 0" and "x \<le> 0" using `odd n`[THEN odd_pos] by auto
hence "x^n \<le> 0" unfolding power_le_zero_eq using `odd n` by auto
moreover
from `\<not> y < 0` have "0 \<le> y" by auto
hence "0 \<le> y^n" by auto
ultimately show ?thesis by auto
next
case False hence "0 \<le> x" by auto
with `x \<le> y` show ?thesis using power_mono by auto
qed
qed
subsection {* More Even/Odd Results *}
lemma even_mult_two_ex: "even(n) = (\<exists>m::nat. n = 2*m)" by presburger
lemma odd_Suc_mult_two_ex: "odd(n) = (\<exists>m. n = Suc (2*m))" by presburger
lemma even_add [simp]: "even(m + n::nat) = (even m = even n)" by presburger
lemma odd_add [simp]: "odd(m + n::nat) = (odd m \<noteq> odd n)" by presburger
lemma lemma_even_div2 [simp]: "even (n::nat) ==> (n + 1) div 2 = n div 2" by presburger
lemma lemma_not_even_div2 [simp]: "~even n ==> (n + 1) div 2 = Suc (n div 2)"
by presburger
lemma even_num_iff: "0 < n ==> even n = (~ even(n - 1 :: nat))" by presburger
lemma even_even_mod_4_iff: "even (n::nat) = even (n mod 4)" by presburger
lemma lemma_odd_mod_4_div_2: "n mod 4 = (3::nat) ==> odd((n - 1) div 2)" by presburger
lemma lemma_even_mod_4_div_2: "n mod 4 = (1::nat) ==> even ((n - 1) div 2)"
by presburger
text {* Simplify, when the exponent is a numeral *}
lemmas zero_le_power_eq_numeral [simp] =
zero_le_power_eq [of _ "numeral w"] for w
lemmas zero_less_power_eq_numeral [simp] =
zero_less_power_eq [of _ "numeral w"] for w
lemmas power_le_zero_eq_numeral [simp] =
power_le_zero_eq [of _ "numeral w"] for w
lemmas power_less_zero_eq_numeral [simp] =
power_less_zero_eq [of _ "numeral w"] for w
lemmas zero_less_power_nat_eq_numeral [simp] =
nat_zero_less_power_iff [of _ "numeral w"] for w
lemmas power_eq_0_iff_numeral [simp] =
power_eq_0_iff [of _ "numeral w"] for w
lemmas power_even_abs_numeral [simp] =
power_even_abs [of "numeral w" _] for w
subsection {* An Equivalence for @{term [source] "0 \<le> a^n"} *}
lemma zero_le_power_iff[presburger]:
"(0 \<le> a^n) = (0 \<le> (a::'a::{linordered_idom}) | even n)"
proof cases
assume even: "even n"
then obtain k where "n = 2*k"
by (auto simp add: even_nat_equiv_def2 numeral_2_eq_2)
thus ?thesis by (simp add: zero_le_even_power even)
next
assume odd: "odd n"
then obtain k where "n = Suc(2*k)"
by (auto simp add: odd_nat_equiv_def2 numeral_2_eq_2)
moreover have "a ^ (2 * k) \<le> 0 \<Longrightarrow> a = 0"
by (induct k) (auto simp add: zero_le_mult_iff mult_le_0_iff)
ultimately show ?thesis
by (auto simp add: zero_le_mult_iff zero_le_even_power)
qed
subsection {* Miscellaneous *}
lemma [presburger]:"(x + 1) div 2 = x div 2 \<longleftrightarrow> even (x::int)" by presburger
lemma [presburger]: "(x + 1) div 2 = x div 2 + 1 \<longleftrightarrow> odd (x::int)" by presburger
lemma even_plus_one_div_two: "even (x::int) ==> (x + 1) div 2 = x div 2" by presburger
lemma odd_plus_one_div_two: "odd (x::int) ==> (x + 1) div 2 = x div 2 + 1" by presburger
lemma [presburger]: "(Suc x) div Suc (Suc 0) = x div Suc (Suc 0) \<longleftrightarrow> even x" by presburger
lemma even_nat_plus_one_div_two: "even (x::nat) ==>
(Suc x) div Suc (Suc 0) = x div Suc (Suc 0)" by presburger
lemma odd_nat_plus_one_div_two: "odd (x::nat) ==>
(Suc x) div Suc (Suc 0) = Suc (x div Suc (Suc 0))" by presburger
end