src/HOL/Filter.thy
author paulson <lp15@cam.ac.uk>
Wed Dec 09 17:35:22 2015 +0000 (2015-12-09)
changeset 61810 3c5040d5694a
parent 61806 d2e62ae01cd8
child 61841 4d3527b94f2a
permissions -rw-r--r--
sorted out eventually_mono
     1 (*  Title:      HOL/Filter.thy
     2     Author:     Brian Huffman
     3     Author:     Johannes Hölzl
     4 *)
     5 
     6 section \<open>Filters on predicates\<close>
     7 
     8 theory Filter
     9 imports Set_Interval Lifting_Set
    10 begin
    11 
    12 subsection \<open>Filters\<close>
    13 
    14 text \<open>
    15   This definition also allows non-proper filters.
    16 \<close>
    17 
    18 locale is_filter =
    19   fixes F :: "('a \<Rightarrow> bool) \<Rightarrow> bool"
    20   assumes True: "F (\<lambda>x. True)"
    21   assumes conj: "F (\<lambda>x. P x) \<Longrightarrow> F (\<lambda>x. Q x) \<Longrightarrow> F (\<lambda>x. P x \<and> Q x)"
    22   assumes mono: "\<forall>x. P x \<longrightarrow> Q x \<Longrightarrow> F (\<lambda>x. P x) \<Longrightarrow> F (\<lambda>x. Q x)"
    23 
    24 typedef 'a filter = "{F :: ('a \<Rightarrow> bool) \<Rightarrow> bool. is_filter F}"
    25 proof
    26   show "(\<lambda>x. True) \<in> ?filter" by (auto intro: is_filter.intro)
    27 qed
    28 
    29 lemma is_filter_Rep_filter: "is_filter (Rep_filter F)"
    30   using Rep_filter [of F] by simp
    31 
    32 lemma Abs_filter_inverse':
    33   assumes "is_filter F" shows "Rep_filter (Abs_filter F) = F"
    34   using assms by (simp add: Abs_filter_inverse)
    35 
    36 
    37 subsubsection \<open>Eventually\<close>
    38 
    39 definition eventually :: "('a \<Rightarrow> bool) \<Rightarrow> 'a filter \<Rightarrow> bool"
    40   where "eventually P F \<longleftrightarrow> Rep_filter F P"
    41 
    42 syntax (xsymbols)
    43   "_eventually"  :: "pttrn => 'a filter => bool => bool"      ("(3\<forall>\<^sub>F _ in _./ _)" [0, 0, 10] 10)
    44 
    45 translations
    46   "\<forall>\<^sub>Fx in F. P" == "CONST eventually (\<lambda>x. P) F"
    47 
    48 lemma eventually_Abs_filter:
    49   assumes "is_filter F" shows "eventually P (Abs_filter F) = F P"
    50   unfolding eventually_def using assms by (simp add: Abs_filter_inverse)
    51 
    52 lemma filter_eq_iff:
    53   shows "F = F' \<longleftrightarrow> (\<forall>P. eventually P F = eventually P F')"
    54   unfolding Rep_filter_inject [symmetric] fun_eq_iff eventually_def ..
    55 
    56 lemma eventually_True [simp]: "eventually (\<lambda>x. True) F"
    57   unfolding eventually_def
    58   by (rule is_filter.True [OF is_filter_Rep_filter])
    59 
    60 lemma always_eventually: "\<forall>x. P x \<Longrightarrow> eventually P F"
    61 proof -
    62   assume "\<forall>x. P x" hence "P = (\<lambda>x. True)" by (simp add: ext)
    63   thus "eventually P F" by simp
    64 qed
    65 
    66 lemma eventuallyI: "(\<And>x. P x) \<Longrightarrow> eventually P F"
    67   by (auto intro: always_eventually)
    68 
    69 lemma eventually_mono:
    70   "\<lbrakk>eventually P F; \<And>x. P x \<Longrightarrow> Q x\<rbrakk> \<Longrightarrow> eventually Q F"
    71   unfolding eventually_def
    72   by (blast intro: is_filter.mono [OF is_filter_Rep_filter])
    73 
    74 lemma eventually_conj:
    75   assumes P: "eventually (\<lambda>x. P x) F"
    76   assumes Q: "eventually (\<lambda>x. Q x) F"
    77   shows "eventually (\<lambda>x. P x \<and> Q x) F"
    78   using assms unfolding eventually_def
    79   by (rule is_filter.conj [OF is_filter_Rep_filter])
    80 
    81 lemma eventually_mp:
    82   assumes "eventually (\<lambda>x. P x \<longrightarrow> Q x) F"
    83   assumes "eventually (\<lambda>x. P x) F"
    84   shows "eventually (\<lambda>x. Q x) F"
    85 proof -
    86   have "eventually (\<lambda>x. (P x \<longrightarrow> Q x) \<and> P x) F"
    87     using assms by (rule eventually_conj)
    88   then show ?thesis
    89     by (blast intro: eventually_mono)
    90 qed
    91 
    92 lemma eventually_rev_mp:
    93   assumes "eventually (\<lambda>x. P x) F"
    94   assumes "eventually (\<lambda>x. P x \<longrightarrow> Q x) F"
    95   shows "eventually (\<lambda>x. Q x) F"
    96 using assms(2) assms(1) by (rule eventually_mp)
    97 
    98 lemma eventually_conj_iff:
    99   "eventually (\<lambda>x. P x \<and> Q x) F \<longleftrightarrow> eventually P F \<and> eventually Q F"
   100   by (auto intro: eventually_conj elim: eventually_rev_mp)
   101 
   102 lemma eventually_elim2:
   103   assumes "eventually (\<lambda>i. P i) F"
   104   assumes "eventually (\<lambda>i. Q i) F"
   105   assumes "\<And>i. P i \<Longrightarrow> Q i \<Longrightarrow> R i"
   106   shows "eventually (\<lambda>i. R i) F"
   107   using assms by (auto elim!: eventually_rev_mp)
   108 
   109 lemma eventually_ball_finite_distrib:
   110   "finite A \<Longrightarrow> (eventually (\<lambda>x. \<forall>y\<in>A. P x y) net) \<longleftrightarrow> (\<forall>y\<in>A. eventually (\<lambda>x. P x y) net)"
   111   by (induction A rule: finite_induct) (auto simp: eventually_conj_iff)
   112 
   113 lemma eventually_ball_finite:
   114   "finite A \<Longrightarrow> \<forall>y\<in>A. eventually (\<lambda>x. P x y) net \<Longrightarrow> eventually (\<lambda>x. \<forall>y\<in>A. P x y) net"
   115   by (auto simp: eventually_ball_finite_distrib)
   116 
   117 lemma eventually_all_finite:
   118   fixes P :: "'a \<Rightarrow> 'b::finite \<Rightarrow> bool"
   119   assumes "\<And>y. eventually (\<lambda>x. P x y) net"
   120   shows "eventually (\<lambda>x. \<forall>y. P x y) net"
   121 using eventually_ball_finite [of UNIV P] assms by simp
   122 
   123 lemma eventually_ex: "(\<forall>\<^sub>Fx in F. \<exists>y. P x y) \<longleftrightarrow> (\<exists>Y. \<forall>\<^sub>Fx in F. P x (Y x))"
   124 proof
   125   assume "\<forall>\<^sub>Fx in F. \<exists>y. P x y"
   126   then have "\<forall>\<^sub>Fx in F. P x (SOME y. P x y)"
   127     by (auto intro: someI_ex eventually_mono)
   128   then show "\<exists>Y. \<forall>\<^sub>Fx in F. P x (Y x)"
   129     by auto
   130 qed (auto intro: eventually_mono)
   131 
   132 lemma not_eventually_impI: "eventually P F \<Longrightarrow> \<not> eventually Q F \<Longrightarrow> \<not> eventually (\<lambda>x. P x \<longrightarrow> Q x) F"
   133   by (auto intro: eventually_mp)
   134 
   135 lemma not_eventuallyD: "\<not> eventually P F \<Longrightarrow> \<exists>x. \<not> P x"
   136   by (metis always_eventually)
   137 
   138 lemma eventually_subst:
   139   assumes "eventually (\<lambda>n. P n = Q n) F"
   140   shows "eventually P F = eventually Q F" (is "?L = ?R")
   141 proof -
   142   from assms have "eventually (\<lambda>x. P x \<longrightarrow> Q x) F"
   143       and "eventually (\<lambda>x. Q x \<longrightarrow> P x) F"
   144     by (auto elim: eventually_mono)
   145   then show ?thesis by (auto elim: eventually_elim2)
   146 qed
   147 
   148 subsection \<open> Frequently as dual to eventually \<close>
   149 
   150 definition frequently :: "('a \<Rightarrow> bool) \<Rightarrow> 'a filter \<Rightarrow> bool"
   151   where "frequently P F \<longleftrightarrow> \<not> eventually (\<lambda>x. \<not> P x) F"
   152 
   153 syntax (xsymbols)
   154   "_frequently"  :: "pttrn \<Rightarrow> 'a filter \<Rightarrow> bool \<Rightarrow> bool"      ("(3\<exists>\<^sub>F _ in _./ _)" [0, 0, 10] 10)
   155 
   156 translations
   157   "\<exists>\<^sub>Fx in F. P" == "CONST frequently (\<lambda>x. P) F"
   158 
   159 lemma not_frequently_False [simp]: "\<not> (\<exists>\<^sub>Fx in F. False)"
   160   by (simp add: frequently_def)
   161 
   162 lemma frequently_ex: "\<exists>\<^sub>Fx in F. P x \<Longrightarrow> \<exists>x. P x"
   163   by (auto simp: frequently_def dest: not_eventuallyD)
   164 
   165 lemma frequentlyE: assumes "frequently P F" obtains x where "P x"
   166   using frequently_ex[OF assms] by auto
   167 
   168 lemma frequently_mp:
   169   assumes ev: "\<forall>\<^sub>Fx in F. P x \<longrightarrow> Q x" and P: "\<exists>\<^sub>Fx in F. P x" shows "\<exists>\<^sub>Fx in F. Q x"
   170 proof -
   171   from ev have "eventually (\<lambda>x. \<not> Q x \<longrightarrow> \<not> P x) F"
   172     by (rule eventually_rev_mp) (auto intro!: always_eventually)
   173   from eventually_mp[OF this] P show ?thesis
   174     by (auto simp: frequently_def)
   175 qed
   176 
   177 lemma frequently_rev_mp:
   178   assumes "\<exists>\<^sub>Fx in F. P x"
   179   assumes "\<forall>\<^sub>Fx in F. P x \<longrightarrow> Q x"
   180   shows "\<exists>\<^sub>Fx in F. Q x"
   181 using assms(2) assms(1) by (rule frequently_mp)
   182 
   183 lemma frequently_mono: "(\<forall>x. P x \<longrightarrow> Q x) \<Longrightarrow> frequently P F \<Longrightarrow> frequently Q F"
   184   using frequently_mp[of P Q] by (simp add: always_eventually)
   185 
   186 lemma frequently_elim1: "\<exists>\<^sub>Fx in F. P x \<Longrightarrow> (\<And>i. P i \<Longrightarrow> Q i) \<Longrightarrow> \<exists>\<^sub>Fx in F. Q x"
   187   by (metis frequently_mono)
   188 
   189 lemma frequently_disj_iff: "(\<exists>\<^sub>Fx in F. P x \<or> Q x) \<longleftrightarrow> (\<exists>\<^sub>Fx in F. P x) \<or> (\<exists>\<^sub>Fx in F. Q x)"
   190   by (simp add: frequently_def eventually_conj_iff)
   191 
   192 lemma frequently_disj: "\<exists>\<^sub>Fx in F. P x \<Longrightarrow> \<exists>\<^sub>Fx in F. Q x \<Longrightarrow> \<exists>\<^sub>Fx in F. P x \<or> Q x"
   193   by (simp add: frequently_disj_iff)
   194 
   195 lemma frequently_bex_finite_distrib:
   196   assumes "finite A" shows "(\<exists>\<^sub>Fx in F. \<exists>y\<in>A. P x y) \<longleftrightarrow> (\<exists>y\<in>A. \<exists>\<^sub>Fx in F. P x y)"
   197   using assms by induction (auto simp: frequently_disj_iff)
   198 
   199 lemma frequently_bex_finite: "finite A \<Longrightarrow> \<exists>\<^sub>Fx in F. \<exists>y\<in>A. P x y \<Longrightarrow> \<exists>y\<in>A. \<exists>\<^sub>Fx in F. P x y"
   200   by (simp add: frequently_bex_finite_distrib)
   201 
   202 lemma frequently_all: "(\<exists>\<^sub>Fx in F. \<forall>y. P x y) \<longleftrightarrow> (\<forall>Y. \<exists>\<^sub>Fx in F. P x (Y x))"
   203   using eventually_ex[of "\<lambda>x y. \<not> P x y" F] by (simp add: frequently_def)
   204 
   205 lemma
   206   shows not_eventually: "\<not> eventually P F \<longleftrightarrow> (\<exists>\<^sub>Fx in F. \<not> P x)"
   207     and not_frequently: "\<not> frequently P F \<longleftrightarrow> (\<forall>\<^sub>Fx in F. \<not> P x)"
   208   by (auto simp: frequently_def)
   209 
   210 lemma frequently_imp_iff:
   211   "(\<exists>\<^sub>Fx in F. P x \<longrightarrow> Q x) \<longleftrightarrow> (eventually P F \<longrightarrow> frequently Q F)"
   212   unfolding imp_conv_disj frequently_disj_iff not_eventually[symmetric] ..
   213 
   214 lemma eventually_frequently_const_simps:
   215   "(\<exists>\<^sub>Fx in F. P x \<and> C) \<longleftrightarrow> (\<exists>\<^sub>Fx in F. P x) \<and> C"
   216   "(\<exists>\<^sub>Fx in F. C \<and> P x) \<longleftrightarrow> C \<and> (\<exists>\<^sub>Fx in F. P x)"
   217   "(\<forall>\<^sub>Fx in F. P x \<or> C) \<longleftrightarrow> (\<forall>\<^sub>Fx in F. P x) \<or> C"
   218   "(\<forall>\<^sub>Fx in F. C \<or> P x) \<longleftrightarrow> C \<or> (\<forall>\<^sub>Fx in F. P x)"
   219   "(\<forall>\<^sub>Fx in F. P x \<longrightarrow> C) \<longleftrightarrow> ((\<exists>\<^sub>Fx in F. P x) \<longrightarrow> C)"
   220   "(\<forall>\<^sub>Fx in F. C \<longrightarrow> P x) \<longleftrightarrow> (C \<longrightarrow> (\<forall>\<^sub>Fx in F. P x))"
   221   by (cases C; simp add: not_frequently)+
   222 
   223 lemmas eventually_frequently_simps =
   224   eventually_frequently_const_simps
   225   not_eventually
   226   eventually_conj_iff
   227   eventually_ball_finite_distrib
   228   eventually_ex
   229   not_frequently
   230   frequently_disj_iff
   231   frequently_bex_finite_distrib
   232   frequently_all
   233   frequently_imp_iff
   234 
   235 ML \<open>
   236   fun eventually_elim_tac ctxt facts = SUBGOAL_CASES (fn (goal, i) =>
   237     let
   238       val mp_thms = facts RL @{thms eventually_rev_mp}
   239       val raw_elim_thm =
   240         (@{thm allI} RS @{thm always_eventually})
   241         |> fold (fn thm1 => fn thm2 => thm2 RS thm1) mp_thms
   242         |> fold (fn _ => fn thm => @{thm impI} RS thm) facts
   243       val cases_prop =
   244         Thm.prop_of
   245           (Rule_Cases.internalize_params (raw_elim_thm RS Goal.init (Thm.cterm_of ctxt goal)))
   246       val cases = Rule_Cases.make_common ctxt cases_prop [(("elim", []), [])]
   247     in
   248       CASES cases (resolve_tac ctxt [raw_elim_thm] i)
   249     end)
   250 \<close>
   251 
   252 method_setup eventually_elim = \<open>
   253   Scan.succeed (fn ctxt => METHOD_CASES (HEADGOAL o eventually_elim_tac ctxt))
   254 \<close> "elimination of eventually quantifiers"
   255 
   256 subsubsection \<open>Finer-than relation\<close>
   257 
   258 text \<open>@{term "F \<le> F'"} means that filter @{term F} is finer than
   259 filter @{term F'}.\<close>
   260 
   261 instantiation filter :: (type) complete_lattice
   262 begin
   263 
   264 definition le_filter_def:
   265   "F \<le> F' \<longleftrightarrow> (\<forall>P. eventually P F' \<longrightarrow> eventually P F)"
   266 
   267 definition
   268   "(F :: 'a filter) < F' \<longleftrightarrow> F \<le> F' \<and> \<not> F' \<le> F"
   269 
   270 definition
   271   "top = Abs_filter (\<lambda>P. \<forall>x. P x)"
   272 
   273 definition
   274   "bot = Abs_filter (\<lambda>P. True)"
   275 
   276 definition
   277   "sup F F' = Abs_filter (\<lambda>P. eventually P F \<and> eventually P F')"
   278 
   279 definition
   280   "inf F F' = Abs_filter
   281       (\<lambda>P. \<exists>Q R. eventually Q F \<and> eventually R F' \<and> (\<forall>x. Q x \<and> R x \<longrightarrow> P x))"
   282 
   283 definition
   284   "Sup S = Abs_filter (\<lambda>P. \<forall>F\<in>S. eventually P F)"
   285 
   286 definition
   287   "Inf S = Sup {F::'a filter. \<forall>F'\<in>S. F \<le> F'}"
   288 
   289 lemma eventually_top [simp]: "eventually P top \<longleftrightarrow> (\<forall>x. P x)"
   290   unfolding top_filter_def
   291   by (rule eventually_Abs_filter, rule is_filter.intro, auto)
   292 
   293 lemma eventually_bot [simp]: "eventually P bot"
   294   unfolding bot_filter_def
   295   by (subst eventually_Abs_filter, rule is_filter.intro, auto)
   296 
   297 lemma eventually_sup:
   298   "eventually P (sup F F') \<longleftrightarrow> eventually P F \<and> eventually P F'"
   299   unfolding sup_filter_def
   300   by (rule eventually_Abs_filter, rule is_filter.intro)
   301      (auto elim!: eventually_rev_mp)
   302 
   303 lemma eventually_inf:
   304   "eventually P (inf F F') \<longleftrightarrow>
   305    (\<exists>Q R. eventually Q F \<and> eventually R F' \<and> (\<forall>x. Q x \<and> R x \<longrightarrow> P x))"
   306   unfolding inf_filter_def
   307   apply (rule eventually_Abs_filter, rule is_filter.intro)
   308   apply (fast intro: eventually_True)
   309   apply clarify
   310   apply (intro exI conjI)
   311   apply (erule (1) eventually_conj)
   312   apply (erule (1) eventually_conj)
   313   apply simp
   314   apply auto
   315   done
   316 
   317 lemma eventually_Sup:
   318   "eventually P (Sup S) \<longleftrightarrow> (\<forall>F\<in>S. eventually P F)"
   319   unfolding Sup_filter_def
   320   apply (rule eventually_Abs_filter, rule is_filter.intro)
   321   apply (auto intro: eventually_conj elim!: eventually_rev_mp)
   322   done
   323 
   324 instance proof
   325   fix F F' F'' :: "'a filter" and S :: "'a filter set"
   326   { show "F < F' \<longleftrightarrow> F \<le> F' \<and> \<not> F' \<le> F"
   327     by (rule less_filter_def) }
   328   { show "F \<le> F"
   329     unfolding le_filter_def by simp }
   330   { assume "F \<le> F'" and "F' \<le> F''" thus "F \<le> F''"
   331     unfolding le_filter_def by simp }
   332   { assume "F \<le> F'" and "F' \<le> F" thus "F = F'"
   333     unfolding le_filter_def filter_eq_iff by fast }
   334   { show "inf F F' \<le> F" and "inf F F' \<le> F'"
   335     unfolding le_filter_def eventually_inf by (auto intro: eventually_True) }
   336   { assume "F \<le> F'" and "F \<le> F''" thus "F \<le> inf F' F''"
   337     unfolding le_filter_def eventually_inf
   338     by (auto intro: eventually_mono [OF eventually_conj]) }
   339   { show "F \<le> sup F F'" and "F' \<le> sup F F'"
   340     unfolding le_filter_def eventually_sup by simp_all }
   341   { assume "F \<le> F''" and "F' \<le> F''" thus "sup F F' \<le> F''"
   342     unfolding le_filter_def eventually_sup by simp }
   343   { assume "F'' \<in> S" thus "Inf S \<le> F''"
   344     unfolding le_filter_def Inf_filter_def eventually_Sup Ball_def by simp }
   345   { assume "\<And>F'. F' \<in> S \<Longrightarrow> F \<le> F'" thus "F \<le> Inf S"
   346     unfolding le_filter_def Inf_filter_def eventually_Sup Ball_def by simp }
   347   { assume "F \<in> S" thus "F \<le> Sup S"
   348     unfolding le_filter_def eventually_Sup by simp }
   349   { assume "\<And>F. F \<in> S \<Longrightarrow> F \<le> F'" thus "Sup S \<le> F'"
   350     unfolding le_filter_def eventually_Sup by simp }
   351   { show "Inf {} = (top::'a filter)"
   352     by (auto simp: top_filter_def Inf_filter_def Sup_filter_def)
   353       (metis (full_types) top_filter_def always_eventually eventually_top) }
   354   { show "Sup {} = (bot::'a filter)"
   355     by (auto simp: bot_filter_def Sup_filter_def) }
   356 qed
   357 
   358 end
   359 
   360 lemma filter_leD:
   361   "F \<le> F' \<Longrightarrow> eventually P F' \<Longrightarrow> eventually P F"
   362   unfolding le_filter_def by simp
   363 
   364 lemma filter_leI:
   365   "(\<And>P. eventually P F' \<Longrightarrow> eventually P F) \<Longrightarrow> F \<le> F'"
   366   unfolding le_filter_def by simp
   367 
   368 lemma eventually_False:
   369   "eventually (\<lambda>x. False) F \<longleftrightarrow> F = bot"
   370   unfolding filter_eq_iff by (auto elim: eventually_rev_mp)
   371 
   372 lemma eventually_frequently: "F \<noteq> bot \<Longrightarrow> eventually P F \<Longrightarrow> frequently P F"
   373   using eventually_conj[of P F "\<lambda>x. \<not> P x"]
   374   by (auto simp add: frequently_def eventually_False)
   375 
   376 lemma eventually_const_iff: "eventually (\<lambda>x. P) F \<longleftrightarrow> P \<or> F = bot"
   377   by (cases P) (auto simp: eventually_False)
   378 
   379 lemma eventually_const[simp]: "F \<noteq> bot \<Longrightarrow> eventually (\<lambda>x. P) F \<longleftrightarrow> P"
   380   by (simp add: eventually_const_iff)
   381 
   382 lemma frequently_const_iff: "frequently (\<lambda>x. P) F \<longleftrightarrow> P \<and> F \<noteq> bot"
   383   by (simp add: frequently_def eventually_const_iff)
   384 
   385 lemma frequently_const[simp]: "F \<noteq> bot \<Longrightarrow> frequently (\<lambda>x. P) F \<longleftrightarrow> P"
   386   by (simp add: frequently_const_iff)
   387 
   388 lemma eventually_happens: "eventually P net \<Longrightarrow> net = bot \<or> (\<exists>x. P x)"
   389   by (metis frequentlyE eventually_frequently)
   390 
   391 lemma eventually_happens':
   392   assumes "F \<noteq> bot" "eventually P F"
   393   shows   "\<exists>x. P x"
   394   using assms eventually_frequently frequentlyE by blast
   395 
   396 abbreviation (input) trivial_limit :: "'a filter \<Rightarrow> bool"
   397   where "trivial_limit F \<equiv> F = bot"
   398 
   399 lemma trivial_limit_def: "trivial_limit F \<longleftrightarrow> eventually (\<lambda>x. False) F"
   400   by (rule eventually_False [symmetric])
   401 
   402 lemma False_imp_not_eventually: "(\<forall>x. \<not> P x ) \<Longrightarrow> \<not> trivial_limit net \<Longrightarrow> \<not> eventually (\<lambda>x. P x) net"
   403   by (simp add: eventually_False)
   404 
   405 lemma eventually_Inf: "eventually P (Inf B) \<longleftrightarrow> (\<exists>X\<subseteq>B. finite X \<and> eventually P (Inf X))"
   406 proof -
   407   let ?F = "\<lambda>P. \<exists>X\<subseteq>B. finite X \<and> eventually P (Inf X)"
   408 
   409   { fix P have "eventually P (Abs_filter ?F) \<longleftrightarrow> ?F P"
   410     proof (rule eventually_Abs_filter is_filter.intro)+
   411       show "?F (\<lambda>x. True)"
   412         by (rule exI[of _ "{}"]) (simp add: le_fun_def)
   413     next
   414       fix P Q
   415       assume "?F P" then guess X ..
   416       moreover
   417       assume "?F Q" then guess Y ..
   418       ultimately show "?F (\<lambda>x. P x \<and> Q x)"
   419         by (intro exI[of _ "X \<union> Y"])
   420            (auto simp: Inf_union_distrib eventually_inf)
   421     next
   422       fix P Q
   423       assume "?F P" then guess X ..
   424       moreover assume "\<forall>x. P x \<longrightarrow> Q x"
   425       ultimately show "?F Q"
   426         by (intro exI[of _ X]) (auto elim: eventually_mono)
   427     qed }
   428   note eventually_F = this
   429 
   430   have "Inf B = Abs_filter ?F"
   431   proof (intro antisym Inf_greatest)
   432     show "Inf B \<le> Abs_filter ?F"
   433       by (auto simp: le_filter_def eventually_F dest: Inf_superset_mono)
   434   next
   435     fix F assume "F \<in> B" then show "Abs_filter ?F \<le> F"
   436       by (auto simp add: le_filter_def eventually_F intro!: exI[of _ "{F}"])
   437   qed
   438   then show ?thesis
   439     by (simp add: eventually_F)
   440 qed
   441 
   442 lemma eventually_INF: "eventually P (INF b:B. F b) \<longleftrightarrow> (\<exists>X\<subseteq>B. finite X \<and> eventually P (INF b:X. F b))"
   443   unfolding INF_def[of B] eventually_Inf[of P "F`B"]
   444   by (metis Inf_image_eq finite_imageI image_mono finite_subset_image)
   445 
   446 lemma Inf_filter_not_bot:
   447   fixes B :: "'a filter set"
   448   shows "(\<And>X. X \<subseteq> B \<Longrightarrow> finite X \<Longrightarrow> Inf X \<noteq> bot) \<Longrightarrow> Inf B \<noteq> bot"
   449   unfolding trivial_limit_def eventually_Inf[of _ B]
   450     bot_bool_def [symmetric] bot_fun_def [symmetric] bot_unique by simp
   451 
   452 lemma INF_filter_not_bot:
   453   fixes F :: "'i \<Rightarrow> 'a filter"
   454   shows "(\<And>X. X \<subseteq> B \<Longrightarrow> finite X \<Longrightarrow> (INF b:X. F b) \<noteq> bot) \<Longrightarrow> (INF b:B. F b) \<noteq> bot"
   455   unfolding trivial_limit_def eventually_INF[of _ B]
   456     bot_bool_def [symmetric] bot_fun_def [symmetric] bot_unique by simp
   457 
   458 lemma eventually_Inf_base:
   459   assumes "B \<noteq> {}" and base: "\<And>F G. F \<in> B \<Longrightarrow> G \<in> B \<Longrightarrow> \<exists>x\<in>B. x \<le> inf F G"
   460   shows "eventually P (Inf B) \<longleftrightarrow> (\<exists>b\<in>B. eventually P b)"
   461 proof (subst eventually_Inf, safe)
   462   fix X assume "finite X" "X \<subseteq> B"
   463   then have "\<exists>b\<in>B. \<forall>x\<in>X. b \<le> x"
   464   proof induct
   465     case empty then show ?case
   466       using \<open>B \<noteq> {}\<close> by auto
   467   next
   468     case (insert x X)
   469     then obtain b where "b \<in> B" "\<And>x. x \<in> X \<Longrightarrow> b \<le> x"
   470       by auto
   471     with \<open>insert x X \<subseteq> B\<close> base[of b x] show ?case
   472       by (auto intro: order_trans)
   473   qed
   474   then obtain b where "b \<in> B" "b \<le> Inf X"
   475     by (auto simp: le_Inf_iff)
   476   then show "eventually P (Inf X) \<Longrightarrow> Bex B (eventually P)"
   477     by (intro bexI[of _ b]) (auto simp: le_filter_def)
   478 qed (auto intro!: exI[of _ "{x}" for x])
   479 
   480 lemma eventually_INF_base:
   481   "B \<noteq> {} \<Longrightarrow> (\<And>a b. a \<in> B \<Longrightarrow> b \<in> B \<Longrightarrow> \<exists>x\<in>B. F x \<le> inf (F a) (F b)) \<Longrightarrow>
   482     eventually P (INF b:B. F b) \<longleftrightarrow> (\<exists>b\<in>B. eventually P (F b))"
   483   unfolding INF_def by (subst eventually_Inf_base) auto
   484 
   485 
   486 subsubsection \<open>Map function for filters\<close>
   487 
   488 definition filtermap :: "('a \<Rightarrow> 'b) \<Rightarrow> 'a filter \<Rightarrow> 'b filter"
   489   where "filtermap f F = Abs_filter (\<lambda>P. eventually (\<lambda>x. P (f x)) F)"
   490 
   491 lemma eventually_filtermap:
   492   "eventually P (filtermap f F) = eventually (\<lambda>x. P (f x)) F"
   493   unfolding filtermap_def
   494   apply (rule eventually_Abs_filter)
   495   apply (rule is_filter.intro)
   496   apply (auto elim!: eventually_rev_mp)
   497   done
   498 
   499 lemma filtermap_ident: "filtermap (\<lambda>x. x) F = F"
   500   by (simp add: filter_eq_iff eventually_filtermap)
   501 
   502 lemma filtermap_filtermap:
   503   "filtermap f (filtermap g F) = filtermap (\<lambda>x. f (g x)) F"
   504   by (simp add: filter_eq_iff eventually_filtermap)
   505 
   506 lemma filtermap_mono: "F \<le> F' \<Longrightarrow> filtermap f F \<le> filtermap f F'"
   507   unfolding le_filter_def eventually_filtermap by simp
   508 
   509 lemma filtermap_bot [simp]: "filtermap f bot = bot"
   510   by (simp add: filter_eq_iff eventually_filtermap)
   511 
   512 lemma filtermap_sup: "filtermap f (sup F1 F2) = sup (filtermap f F1) (filtermap f F2)"
   513   by (auto simp: filter_eq_iff eventually_filtermap eventually_sup)
   514 
   515 lemma filtermap_inf: "filtermap f (inf F1 F2) \<le> inf (filtermap f F1) (filtermap f F2)"
   516   by (auto simp: le_filter_def eventually_filtermap eventually_inf)
   517 
   518 lemma filtermap_INF: "filtermap f (INF b:B. F b) \<le> (INF b:B. filtermap f (F b))"
   519 proof -
   520   { fix X :: "'c set" assume "finite X"
   521     then have "filtermap f (INFIMUM X F) \<le> (INF b:X. filtermap f (F b))"
   522     proof induct
   523       case (insert x X)
   524       have "filtermap f (INF a:insert x X. F a) \<le> inf (filtermap f (F x)) (filtermap f (INF a:X. F a))"
   525         by (rule order_trans[OF _ filtermap_inf]) simp
   526       also have "\<dots> \<le> inf (filtermap f (F x)) (INF a:X. filtermap f (F a))"
   527         by (intro inf_mono insert order_refl)
   528       finally show ?case
   529         by simp
   530     qed simp }
   531   then show ?thesis
   532     unfolding le_filter_def eventually_filtermap
   533     by (subst (1 2) eventually_INF) auto
   534 qed
   535 subsubsection \<open>Standard filters\<close>
   536 
   537 definition principal :: "'a set \<Rightarrow> 'a filter" where
   538   "principal S = Abs_filter (\<lambda>P. \<forall>x\<in>S. P x)"
   539 
   540 lemma eventually_principal: "eventually P (principal S) \<longleftrightarrow> (\<forall>x\<in>S. P x)"
   541   unfolding principal_def
   542   by (rule eventually_Abs_filter, rule is_filter.intro) auto
   543 
   544 lemma eventually_inf_principal: "eventually P (inf F (principal s)) \<longleftrightarrow> eventually (\<lambda>x. x \<in> s \<longrightarrow> P x) F"
   545   unfolding eventually_inf eventually_principal by (auto elim: eventually_mono)
   546 
   547 lemma principal_UNIV[simp]: "principal UNIV = top"
   548   by (auto simp: filter_eq_iff eventually_principal)
   549 
   550 lemma principal_empty[simp]: "principal {} = bot"
   551   by (auto simp: filter_eq_iff eventually_principal)
   552 
   553 lemma principal_eq_bot_iff: "principal X = bot \<longleftrightarrow> X = {}"
   554   by (auto simp add: filter_eq_iff eventually_principal)
   555 
   556 lemma principal_le_iff[iff]: "principal A \<le> principal B \<longleftrightarrow> A \<subseteq> B"
   557   by (auto simp: le_filter_def eventually_principal)
   558 
   559 lemma le_principal: "F \<le> principal A \<longleftrightarrow> eventually (\<lambda>x. x \<in> A) F"
   560   unfolding le_filter_def eventually_principal
   561   apply safe
   562   apply (erule_tac x="\<lambda>x. x \<in> A" in allE)
   563   apply (auto elim: eventually_mono)
   564   done
   565 
   566 lemma principal_inject[iff]: "principal A = principal B \<longleftrightarrow> A = B"
   567   unfolding eq_iff by simp
   568 
   569 lemma sup_principal[simp]: "sup (principal A) (principal B) = principal (A \<union> B)"
   570   unfolding filter_eq_iff eventually_sup eventually_principal by auto
   571 
   572 lemma inf_principal[simp]: "inf (principal A) (principal B) = principal (A \<inter> B)"
   573   unfolding filter_eq_iff eventually_inf eventually_principal
   574   by (auto intro: exI[of _ "\<lambda>x. x \<in> A"] exI[of _ "\<lambda>x. x \<in> B"])
   575 
   576 lemma SUP_principal[simp]: "(SUP i : I. principal (A i)) = principal (\<Union>i\<in>I. A i)"
   577   unfolding filter_eq_iff eventually_Sup SUP_def by (auto simp: eventually_principal)
   578 
   579 lemma INF_principal_finite: "finite X \<Longrightarrow> (INF x:X. principal (f x)) = principal (\<Inter>x\<in>X. f x)"
   580   by (induct X rule: finite_induct) auto
   581 
   582 lemma filtermap_principal[simp]: "filtermap f (principal A) = principal (f ` A)"
   583   unfolding filter_eq_iff eventually_filtermap eventually_principal by simp
   584 
   585 subsubsection \<open>Order filters\<close>
   586 
   587 definition at_top :: "('a::order) filter"
   588   where "at_top = (INF k. principal {k ..})"
   589 
   590 lemma at_top_sub: "at_top = (INF k:{c::'a::linorder..}. principal {k ..})"
   591   by (auto intro!: INF_eq max.cobounded1 max.cobounded2 simp: at_top_def)
   592 
   593 lemma eventually_at_top_linorder: "eventually P at_top \<longleftrightarrow> (\<exists>N::'a::linorder. \<forall>n\<ge>N. P n)"
   594   unfolding at_top_def
   595   by (subst eventually_INF_base) (auto simp: eventually_principal intro: max.cobounded1 max.cobounded2)
   596 
   597 lemma eventually_ge_at_top:
   598   "eventually (\<lambda>x. (c::_::linorder) \<le> x) at_top"
   599   unfolding eventually_at_top_linorder by auto
   600 
   601 lemma eventually_at_top_dense: "eventually P at_top \<longleftrightarrow> (\<exists>N::'a::{no_top, linorder}. \<forall>n>N. P n)"
   602 proof -
   603   have "eventually P (INF k. principal {k <..}) \<longleftrightarrow> (\<exists>N::'a. \<forall>n>N. P n)"
   604     by (subst eventually_INF_base) (auto simp: eventually_principal intro: max.cobounded1 max.cobounded2)
   605   also have "(INF k. principal {k::'a <..}) = at_top"
   606     unfolding at_top_def
   607     by (intro INF_eq) (auto intro: less_imp_le simp: Ici_subset_Ioi_iff gt_ex)
   608   finally show ?thesis .
   609 qed
   610 
   611 lemma eventually_at_top_not_equal: "eventually (\<lambda>x::'a::{no_top, linorder}. x \<noteq> c) at_top"
   612   unfolding eventually_at_top_dense by auto
   613 
   614 lemma eventually_gt_at_top: "eventually (\<lambda>x. (c::_::{no_top, linorder}) < x) at_top"
   615   unfolding eventually_at_top_dense by auto
   616 
   617 lemma eventually_all_ge_at_top:
   618   assumes "eventually P (at_top :: ('a :: linorder) filter)"
   619   shows   "eventually (\<lambda>x. \<forall>y\<ge>x. P y) at_top"
   620 proof -
   621   from assms obtain x where "\<And>y. y \<ge> x \<Longrightarrow> P y" by (auto simp: eventually_at_top_linorder)
   622   hence "\<forall>z\<ge>y. P z" if "y \<ge> x" for y using that by simp
   623   thus ?thesis by (auto simp: eventually_at_top_linorder)
   624 qed
   625 
   626 definition at_bot :: "('a::order) filter"
   627   where "at_bot = (INF k. principal {.. k})"
   628 
   629 lemma at_bot_sub: "at_bot = (INF k:{.. c::'a::linorder}. principal {.. k})"
   630   by (auto intro!: INF_eq min.cobounded1 min.cobounded2 simp: at_bot_def)
   631 
   632 lemma eventually_at_bot_linorder:
   633   fixes P :: "'a::linorder \<Rightarrow> bool" shows "eventually P at_bot \<longleftrightarrow> (\<exists>N. \<forall>n\<le>N. P n)"
   634   unfolding at_bot_def
   635   by (subst eventually_INF_base) (auto simp: eventually_principal intro: min.cobounded1 min.cobounded2)
   636 
   637 lemma eventually_le_at_bot:
   638   "eventually (\<lambda>x. x \<le> (c::_::linorder)) at_bot"
   639   unfolding eventually_at_bot_linorder by auto
   640 
   641 lemma eventually_at_bot_dense: "eventually P at_bot \<longleftrightarrow> (\<exists>N::'a::{no_bot, linorder}. \<forall>n<N. P n)"
   642 proof -
   643   have "eventually P (INF k. principal {..< k}) \<longleftrightarrow> (\<exists>N::'a. \<forall>n<N. P n)"
   644     by (subst eventually_INF_base) (auto simp: eventually_principal intro: min.cobounded1 min.cobounded2)
   645   also have "(INF k. principal {..< k::'a}) = at_bot"
   646     unfolding at_bot_def
   647     by (intro INF_eq) (auto intro: less_imp_le simp: Iic_subset_Iio_iff lt_ex)
   648   finally show ?thesis .
   649 qed
   650 
   651 lemma eventually_at_bot_not_equal: "eventually (\<lambda>x::'a::{no_bot, linorder}. x \<noteq> c) at_bot"
   652   unfolding eventually_at_bot_dense by auto
   653 
   654 lemma eventually_gt_at_bot:
   655   "eventually (\<lambda>x. x < (c::_::unbounded_dense_linorder)) at_bot"
   656   unfolding eventually_at_bot_dense by auto
   657 
   658 lemma trivial_limit_at_bot_linorder: "\<not> trivial_limit (at_bot ::('a::linorder) filter)"
   659   unfolding trivial_limit_def
   660   by (metis eventually_at_bot_linorder order_refl)
   661 
   662 lemma trivial_limit_at_top_linorder: "\<not> trivial_limit (at_top ::('a::linorder) filter)"
   663   unfolding trivial_limit_def
   664   by (metis eventually_at_top_linorder order_refl)
   665 
   666 subsection \<open>Sequentially\<close>
   667 
   668 abbreviation sequentially :: "nat filter"
   669   where "sequentially \<equiv> at_top"
   670 
   671 lemma eventually_sequentially:
   672   "eventually P sequentially \<longleftrightarrow> (\<exists>N. \<forall>n\<ge>N. P n)"
   673   by (rule eventually_at_top_linorder)
   674 
   675 lemma sequentially_bot [simp, intro]: "sequentially \<noteq> bot"
   676   unfolding filter_eq_iff eventually_sequentially by auto
   677 
   678 lemmas trivial_limit_sequentially = sequentially_bot
   679 
   680 lemma eventually_False_sequentially [simp]:
   681   "\<not> eventually (\<lambda>n. False) sequentially"
   682   by (simp add: eventually_False)
   683 
   684 lemma le_sequentially:
   685   "F \<le> sequentially \<longleftrightarrow> (\<forall>N. eventually (\<lambda>n. N \<le> n) F)"
   686   by (simp add: at_top_def le_INF_iff le_principal)
   687 
   688 lemma eventually_sequentiallyI [intro?]:
   689   assumes "\<And>x. c \<le> x \<Longrightarrow> P x"
   690   shows "eventually P sequentially"
   691 using assms by (auto simp: eventually_sequentially)
   692 
   693 lemma eventually_sequentially_Suc: "eventually (\<lambda>i. P (Suc i)) sequentially \<longleftrightarrow> eventually P sequentially"
   694   unfolding eventually_sequentially by (metis Suc_le_D Suc_le_mono le_Suc_eq)
   695 
   696 lemma eventually_sequentially_seg: "eventually (\<lambda>n. P (n + k)) sequentially \<longleftrightarrow> eventually P sequentially"
   697   using eventually_sequentially_Suc[of "\<lambda>n. P (n + k)" for k] by (induction k) auto
   698 
   699 subsection \<open> The cofinite filter \<close>
   700 
   701 definition "cofinite = Abs_filter (\<lambda>P. finite {x. \<not> P x})"
   702 
   703 abbreviation Inf_many :: "('a \<Rightarrow> bool) \<Rightarrow> bool"  (binder "INFM " 10) where
   704   "Inf_many P \<equiv> frequently P cofinite"
   705 
   706 abbreviation Alm_all :: "('a \<Rightarrow> bool) \<Rightarrow> bool"  (binder "MOST " 10) where
   707   "Alm_all P \<equiv> eventually P cofinite"
   708 
   709 notation (xsymbols)
   710   Inf_many  (binder "\<exists>\<^sub>\<infinity>" 10) and
   711   Alm_all  (binder "\<forall>\<^sub>\<infinity>" 10)
   712 
   713 lemma eventually_cofinite: "eventually P cofinite \<longleftrightarrow> finite {x. \<not> P x}"
   714   unfolding cofinite_def
   715 proof (rule eventually_Abs_filter, rule is_filter.intro)
   716   fix P Q :: "'a \<Rightarrow> bool" assume "finite {x. \<not> P x}" "finite {x. \<not> Q x}"
   717   from finite_UnI[OF this] show "finite {x. \<not> (P x \<and> Q x)}"
   718     by (rule rev_finite_subset) auto
   719 next
   720   fix P Q :: "'a \<Rightarrow> bool" assume P: "finite {x. \<not> P x}" and *: "\<forall>x. P x \<longrightarrow> Q x"
   721   from * show "finite {x. \<not> Q x}"
   722     by (intro finite_subset[OF _ P]) auto
   723 qed simp
   724 
   725 lemma frequently_cofinite: "frequently P cofinite \<longleftrightarrow> \<not> finite {x. P x}"
   726   by (simp add: frequently_def eventually_cofinite)
   727 
   728 lemma cofinite_bot[simp]: "cofinite = (bot::'a filter) \<longleftrightarrow> finite (UNIV :: 'a set)"
   729   unfolding trivial_limit_def eventually_cofinite by simp
   730 
   731 lemma cofinite_eq_sequentially: "cofinite = sequentially"
   732   unfolding filter_eq_iff eventually_sequentially eventually_cofinite
   733 proof safe
   734   fix P :: "nat \<Rightarrow> bool" assume [simp]: "finite {x. \<not> P x}"
   735   show "\<exists>N. \<forall>n\<ge>N. P n"
   736   proof cases
   737     assume "{x. \<not> P x} \<noteq> {}" then show ?thesis
   738       by (intro exI[of _ "Suc (Max {x. \<not> P x})"]) (auto simp: Suc_le_eq)
   739   qed auto
   740 next
   741   fix P :: "nat \<Rightarrow> bool" and N :: nat assume "\<forall>n\<ge>N. P n"
   742   then have "{x. \<not> P x} \<subseteq> {..< N}"
   743     by (auto simp: not_le)
   744   then show "finite {x. \<not> P x}"
   745     by (blast intro: finite_subset)
   746 qed
   747 
   748 subsection \<open>Limits\<close>
   749 
   750 definition filterlim :: "('a \<Rightarrow> 'b) \<Rightarrow> 'b filter \<Rightarrow> 'a filter \<Rightarrow> bool" where
   751   "filterlim f F2 F1 \<longleftrightarrow> filtermap f F1 \<le> F2"
   752 
   753 syntax
   754   "_LIM" :: "pttrns \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'a \<Rightarrow> bool" ("(3LIM (_)/ (_)./ (_) :> (_))" [1000, 10, 0, 10] 10)
   755 
   756 translations
   757   "LIM x F1. f :> F2"   == "CONST filterlim (%x. f) F2 F1"
   758 
   759 lemma filterlim_iff:
   760   "(LIM x F1. f x :> F2) \<longleftrightarrow> (\<forall>P. eventually P F2 \<longrightarrow> eventually (\<lambda>x. P (f x)) F1)"
   761   unfolding filterlim_def le_filter_def eventually_filtermap ..
   762 
   763 lemma filterlim_compose:
   764   "filterlim g F3 F2 \<Longrightarrow> filterlim f F2 F1 \<Longrightarrow> filterlim (\<lambda>x. g (f x)) F3 F1"
   765   unfolding filterlim_def filtermap_filtermap[symmetric] by (metis filtermap_mono order_trans)
   766 
   767 lemma filterlim_mono:
   768   "filterlim f F2 F1 \<Longrightarrow> F2 \<le> F2' \<Longrightarrow> F1' \<le> F1 \<Longrightarrow> filterlim f F2' F1'"
   769   unfolding filterlim_def by (metis filtermap_mono order_trans)
   770 
   771 lemma filterlim_ident: "LIM x F. x :> F"
   772   by (simp add: filterlim_def filtermap_ident)
   773 
   774 lemma filterlim_cong:
   775   "F1 = F1' \<Longrightarrow> F2 = F2' \<Longrightarrow> eventually (\<lambda>x. f x = g x) F2 \<Longrightarrow> filterlim f F1 F2 = filterlim g F1' F2'"
   776   by (auto simp: filterlim_def le_filter_def eventually_filtermap elim: eventually_elim2)
   777 
   778 lemma filterlim_mono_eventually:
   779   assumes "filterlim f F G" and ord: "F \<le> F'" "G' \<le> G"
   780   assumes eq: "eventually (\<lambda>x. f x = f' x) G'"
   781   shows "filterlim f' F' G'"
   782   apply (rule filterlim_cong[OF refl refl eq, THEN iffD1])
   783   apply (rule filterlim_mono[OF _ ord])
   784   apply fact
   785   done
   786 
   787 lemma filtermap_mono_strong: "inj f \<Longrightarrow> filtermap f F \<le> filtermap f G \<longleftrightarrow> F \<le> G"
   788   apply (auto intro!: filtermap_mono) []
   789   apply (auto simp: le_filter_def eventually_filtermap)
   790   apply (erule_tac x="\<lambda>x. P (inv f x)" in allE)
   791   apply auto
   792   done
   793 
   794 lemma filtermap_eq_strong: "inj f \<Longrightarrow> filtermap f F = filtermap f G \<longleftrightarrow> F = G"
   795   by (simp add: filtermap_mono_strong eq_iff)
   796 
   797 lemma filtermap_fun_inverse:
   798   assumes g: "filterlim g F G"
   799   assumes f: "filterlim f G F"
   800   assumes ev: "eventually (\<lambda>x. f (g x) = x) G"
   801   shows "filtermap f F = G"
   802 proof (rule antisym)
   803   show "filtermap f F \<le> G"
   804     using f unfolding filterlim_def .
   805   have "G = filtermap f (filtermap g G)"
   806     using ev by (auto elim: eventually_elim2 simp: filter_eq_iff eventually_filtermap)
   807   also have "\<dots> \<le> filtermap f F"
   808     using g by (intro filtermap_mono) (simp add: filterlim_def)
   809   finally show "G \<le> filtermap f F" .
   810 qed
   811 
   812 lemma filterlim_principal:
   813   "(LIM x F. f x :> principal S) \<longleftrightarrow> (eventually (\<lambda>x. f x \<in> S) F)"
   814   unfolding filterlim_def eventually_filtermap le_principal ..
   815 
   816 lemma filterlim_inf:
   817   "(LIM x F1. f x :> inf F2 F3) \<longleftrightarrow> ((LIM x F1. f x :> F2) \<and> (LIM x F1. f x :> F3))"
   818   unfolding filterlim_def by simp
   819 
   820 lemma filterlim_INF:
   821   "(LIM x F. f x :> (INF b:B. G b)) \<longleftrightarrow> (\<forall>b\<in>B. LIM x F. f x :> G b)"
   822   unfolding filterlim_def le_INF_iff ..
   823 
   824 lemma filterlim_INF_INF:
   825   "(\<And>m. m \<in> J \<Longrightarrow> \<exists>i\<in>I. filtermap f (F i) \<le> G m) \<Longrightarrow> LIM x (INF i:I. F i). f x :> (INF j:J. G j)"
   826   unfolding filterlim_def by (rule order_trans[OF filtermap_INF INF_mono])
   827 
   828 lemma filterlim_base:
   829   "(\<And>m x. m \<in> J \<Longrightarrow> i m \<in> I) \<Longrightarrow> (\<And>m x. m \<in> J \<Longrightarrow> x \<in> F (i m) \<Longrightarrow> f x \<in> G m) \<Longrightarrow>
   830     LIM x (INF i:I. principal (F i)). f x :> (INF j:J. principal (G j))"
   831   by (force intro!: filterlim_INF_INF simp: image_subset_iff)
   832 
   833 lemma filterlim_base_iff:
   834   assumes "I \<noteq> {}" and chain: "\<And>i j. i \<in> I \<Longrightarrow> j \<in> I \<Longrightarrow> F i \<subseteq> F j \<or> F j \<subseteq> F i"
   835   shows "(LIM x (INF i:I. principal (F i)). f x :> INF j:J. principal (G j)) \<longleftrightarrow>
   836     (\<forall>j\<in>J. \<exists>i\<in>I. \<forall>x\<in>F i. f x \<in> G j)"
   837   unfolding filterlim_INF filterlim_principal
   838 proof (subst eventually_INF_base)
   839   fix i j assume "i \<in> I" "j \<in> I"
   840   with chain[OF this] show "\<exists>x\<in>I. principal (F x) \<le> inf (principal (F i)) (principal (F j))"
   841     by auto
   842 qed (auto simp: eventually_principal \<open>I \<noteq> {}\<close>)
   843 
   844 lemma filterlim_filtermap: "filterlim f F1 (filtermap g F2) = filterlim (\<lambda>x. f (g x)) F1 F2"
   845   unfolding filterlim_def filtermap_filtermap ..
   846 
   847 lemma filterlim_sup:
   848   "filterlim f F F1 \<Longrightarrow> filterlim f F F2 \<Longrightarrow> filterlim f F (sup F1 F2)"
   849   unfolding filterlim_def filtermap_sup by auto
   850 
   851 lemma filterlim_sequentially_Suc:
   852   "(LIM x sequentially. f (Suc x) :> F) \<longleftrightarrow> (LIM x sequentially. f x :> F)"
   853   unfolding filterlim_iff by (subst eventually_sequentially_Suc) simp
   854 
   855 lemma filterlim_Suc: "filterlim Suc sequentially sequentially"
   856   by (simp add: filterlim_iff eventually_sequentially) (metis le_Suc_eq)
   857 
   858 lemma filterlim_If:
   859   "LIM x inf F (principal {x. P x}). f x :> G \<Longrightarrow>
   860     LIM x inf F (principal {x. \<not> P x}). g x :> G \<Longrightarrow>
   861     LIM x F. if P x then f x else g x :> G"
   862   unfolding filterlim_iff eventually_inf_principal by (auto simp: eventually_conj_iff)
   863 
   864 subsection \<open>Limits to @{const at_top} and @{const at_bot}\<close>
   865 
   866 lemma filterlim_at_top:
   867   fixes f :: "'a \<Rightarrow> ('b::linorder)"
   868   shows "(LIM x F. f x :> at_top) \<longleftrightarrow> (\<forall>Z. eventually (\<lambda>x. Z \<le> f x) F)"
   869   by (auto simp: filterlim_iff eventually_at_top_linorder elim!: eventually_mono)
   870 
   871 lemma filterlim_at_top_mono:
   872   "LIM x F. f x :> at_top \<Longrightarrow> eventually (\<lambda>x. f x \<le> (g x::'a::linorder)) F \<Longrightarrow>
   873     LIM x F. g x :> at_top"
   874   by (auto simp: filterlim_at_top elim: eventually_elim2 intro: order_trans)
   875 
   876 lemma filterlim_at_top_dense:
   877   fixes f :: "'a \<Rightarrow> ('b::unbounded_dense_linorder)"
   878   shows "(LIM x F. f x :> at_top) \<longleftrightarrow> (\<forall>Z. eventually (\<lambda>x. Z < f x) F)"
   879   by (metis eventually_mono[of _ F] eventually_gt_at_top order_less_imp_le
   880             filterlim_at_top[of f F] filterlim_iff[of f at_top F])
   881 
   882 lemma filterlim_at_top_ge:
   883   fixes f :: "'a \<Rightarrow> ('b::linorder)" and c :: "'b"
   884   shows "(LIM x F. f x :> at_top) \<longleftrightarrow> (\<forall>Z\<ge>c. eventually (\<lambda>x. Z \<le> f x) F)"
   885   unfolding at_top_sub[of c] filterlim_INF by (auto simp add: filterlim_principal)
   886 
   887 lemma filterlim_at_top_at_top:
   888   fixes f :: "'a::linorder \<Rightarrow> 'b::linorder"
   889   assumes mono: "\<And>x y. Q x \<Longrightarrow> Q y \<Longrightarrow> x \<le> y \<Longrightarrow> f x \<le> f y"
   890   assumes bij: "\<And>x. P x \<Longrightarrow> f (g x) = x" "\<And>x. P x \<Longrightarrow> Q (g x)"
   891   assumes Q: "eventually Q at_top"
   892   assumes P: "eventually P at_top"
   893   shows "filterlim f at_top at_top"
   894 proof -
   895   from P obtain x where x: "\<And>y. x \<le> y \<Longrightarrow> P y"
   896     unfolding eventually_at_top_linorder by auto
   897   show ?thesis
   898   proof (intro filterlim_at_top_ge[THEN iffD2] allI impI)
   899     fix z assume "x \<le> z"
   900     with x have "P z" by auto
   901     have "eventually (\<lambda>x. g z \<le> x) at_top"
   902       by (rule eventually_ge_at_top)
   903     with Q show "eventually (\<lambda>x. z \<le> f x) at_top"
   904       by eventually_elim (metis mono bij \<open>P z\<close>)
   905   qed
   906 qed
   907 
   908 lemma filterlim_at_top_gt:
   909   fixes f :: "'a \<Rightarrow> ('b::unbounded_dense_linorder)" and c :: "'b"
   910   shows "(LIM x F. f x :> at_top) \<longleftrightarrow> (\<forall>Z>c. eventually (\<lambda>x. Z \<le> f x) F)"
   911   by (metis filterlim_at_top order_less_le_trans gt_ex filterlim_at_top_ge)
   912 
   913 lemma filterlim_at_bot:
   914   fixes f :: "'a \<Rightarrow> ('b::linorder)"
   915   shows "(LIM x F. f x :> at_bot) \<longleftrightarrow> (\<forall>Z. eventually (\<lambda>x. f x \<le> Z) F)"
   916   by (auto simp: filterlim_iff eventually_at_bot_linorder elim!: eventually_mono)
   917 
   918 lemma filterlim_at_bot_dense:
   919   fixes f :: "'a \<Rightarrow> ('b::{dense_linorder, no_bot})"
   920   shows "(LIM x F. f x :> at_bot) \<longleftrightarrow> (\<forall>Z. eventually (\<lambda>x. f x < Z) F)"
   921 proof (auto simp add: filterlim_at_bot[of f F])
   922   fix Z :: 'b
   923   from lt_ex [of Z] obtain Z' where 1: "Z' < Z" ..
   924   assume "\<forall>Z. eventually (\<lambda>x. f x \<le> Z) F"
   925   hence "eventually (\<lambda>x. f x \<le> Z') F" by auto
   926   thus "eventually (\<lambda>x. f x < Z) F"
   927     apply (rule eventually_mono)
   928     using 1 by auto
   929   next
   930     fix Z :: 'b
   931     show "\<forall>Z. eventually (\<lambda>x. f x < Z) F \<Longrightarrow> eventually (\<lambda>x. f x \<le> Z) F"
   932       by (drule spec [of _ Z], erule eventually_mono, auto simp add: less_imp_le)
   933 qed
   934 
   935 lemma filterlim_at_bot_le:
   936   fixes f :: "'a \<Rightarrow> ('b::linorder)" and c :: "'b"
   937   shows "(LIM x F. f x :> at_bot) \<longleftrightarrow> (\<forall>Z\<le>c. eventually (\<lambda>x. Z \<ge> f x) F)"
   938   unfolding filterlim_at_bot
   939 proof safe
   940   fix Z assume *: "\<forall>Z\<le>c. eventually (\<lambda>x. Z \<ge> f x) F"
   941   with *[THEN spec, of "min Z c"] show "eventually (\<lambda>x. Z \<ge> f x) F"
   942     by (auto elim!: eventually_mono)
   943 qed simp
   944 
   945 lemma filterlim_at_bot_lt:
   946   fixes f :: "'a \<Rightarrow> ('b::unbounded_dense_linorder)" and c :: "'b"
   947   shows "(LIM x F. f x :> at_bot) \<longleftrightarrow> (\<forall>Z<c. eventually (\<lambda>x. Z \<ge> f x) F)"
   948   by (metis filterlim_at_bot filterlim_at_bot_le lt_ex order_le_less_trans)
   949 
   950 
   951 subsection \<open>Setup @{typ "'a filter"} for lifting and transfer\<close>
   952 
   953 context begin interpretation lifting_syntax .
   954 
   955 definition rel_filter :: "('a \<Rightarrow> 'b \<Rightarrow> bool) \<Rightarrow> 'a filter \<Rightarrow> 'b filter \<Rightarrow> bool"
   956 where "rel_filter R F G = ((R ===> op =) ===> op =) (Rep_filter F) (Rep_filter G)"
   957 
   958 lemma rel_filter_eventually:
   959   "rel_filter R F G \<longleftrightarrow>
   960   ((R ===> op =) ===> op =) (\<lambda>P. eventually P F) (\<lambda>P. eventually P G)"
   961 by(simp add: rel_filter_def eventually_def)
   962 
   963 lemma filtermap_id [simp, id_simps]: "filtermap id = id"
   964 by(simp add: fun_eq_iff id_def filtermap_ident)
   965 
   966 lemma filtermap_id' [simp]: "filtermap (\<lambda>x. x) = (\<lambda>F. F)"
   967 using filtermap_id unfolding id_def .
   968 
   969 lemma Quotient_filter [quot_map]:
   970   assumes Q: "Quotient R Abs Rep T"
   971   shows "Quotient (rel_filter R) (filtermap Abs) (filtermap Rep) (rel_filter T)"
   972 unfolding Quotient_alt_def
   973 proof(intro conjI strip)
   974   from Q have *: "\<And>x y. T x y \<Longrightarrow> Abs x = y"
   975     unfolding Quotient_alt_def by blast
   976 
   977   fix F G
   978   assume "rel_filter T F G"
   979   thus "filtermap Abs F = G" unfolding filter_eq_iff
   980     by(auto simp add: eventually_filtermap rel_filter_eventually * rel_funI del: iffI elim!: rel_funD)
   981 next
   982   from Q have *: "\<And>x. T (Rep x) x" unfolding Quotient_alt_def by blast
   983 
   984   fix F
   985   show "rel_filter T (filtermap Rep F) F"
   986     by(auto elim: rel_funD intro: * intro!: ext arg_cong[where f="\<lambda>P. eventually P F"] rel_funI
   987             del: iffI simp add: eventually_filtermap rel_filter_eventually)
   988 qed(auto simp add: map_fun_def o_def eventually_filtermap filter_eq_iff fun_eq_iff rel_filter_eventually
   989          fun_quotient[OF fun_quotient[OF Q identity_quotient] identity_quotient, unfolded Quotient_alt_def])
   990 
   991 lemma eventually_parametric [transfer_rule]:
   992   "((A ===> op =) ===> rel_filter A ===> op =) eventually eventually"
   993 by(simp add: rel_fun_def rel_filter_eventually)
   994 
   995 lemma frequently_parametric [transfer_rule]:
   996   "((A ===> op =) ===> rel_filter A ===> op =) frequently frequently"
   997   unfolding frequently_def[abs_def] by transfer_prover
   998 
   999 lemma rel_filter_eq [relator_eq]: "rel_filter op = = op ="
  1000 by(auto simp add: rel_filter_eventually rel_fun_eq fun_eq_iff filter_eq_iff)
  1001 
  1002 lemma rel_filter_mono [relator_mono]:
  1003   "A \<le> B \<Longrightarrow> rel_filter A \<le> rel_filter B"
  1004 unfolding rel_filter_eventually[abs_def]
  1005 by(rule le_funI)+(intro fun_mono fun_mono[THEN le_funD, THEN le_funD] order.refl)
  1006 
  1007 lemma rel_filter_conversep [simp]: "rel_filter A\<inverse>\<inverse> = (rel_filter A)\<inverse>\<inverse>"
  1008 apply (simp add: rel_filter_eventually fun_eq_iff rel_fun_def)
  1009 apply (safe; metis)
  1010 done
  1011 
  1012 lemma is_filter_parametric_aux:
  1013   assumes "is_filter F"
  1014   assumes [transfer_rule]: "bi_total A" "bi_unique A"
  1015   and [transfer_rule]: "((A ===> op =) ===> op =) F G"
  1016   shows "is_filter G"
  1017 proof -
  1018   interpret is_filter F by fact
  1019   show ?thesis
  1020   proof
  1021     have "F (\<lambda>_. True) = G (\<lambda>x. True)" by transfer_prover
  1022     thus "G (\<lambda>x. True)" by(simp add: True)
  1023   next
  1024     fix P' Q'
  1025     assume "G P'" "G Q'"
  1026     moreover
  1027     from bi_total_fun[OF \<open>bi_unique A\<close> bi_total_eq, unfolded bi_total_def]
  1028     obtain P Q where [transfer_rule]: "(A ===> op =) P P'" "(A ===> op =) Q Q'" by blast
  1029     have "F P = G P'" "F Q = G Q'" by transfer_prover+
  1030     ultimately have "F (\<lambda>x. P x \<and> Q x)" by(simp add: conj)
  1031     moreover have "F (\<lambda>x. P x \<and> Q x) = G (\<lambda>x. P' x \<and> Q' x)" by transfer_prover
  1032     ultimately show "G (\<lambda>x. P' x \<and> Q' x)" by simp
  1033   next
  1034     fix P' Q'
  1035     assume "\<forall>x. P' x \<longrightarrow> Q' x" "G P'"
  1036     moreover
  1037     from bi_total_fun[OF \<open>bi_unique A\<close> bi_total_eq, unfolded bi_total_def]
  1038     obtain P Q where [transfer_rule]: "(A ===> op =) P P'" "(A ===> op =) Q Q'" by blast
  1039     have "F P = G P'" by transfer_prover
  1040     moreover have "(\<forall>x. P x \<longrightarrow> Q x) \<longleftrightarrow> (\<forall>x. P' x \<longrightarrow> Q' x)" by transfer_prover
  1041     ultimately have "F Q" by(simp add: mono)
  1042     moreover have "F Q = G Q'" by transfer_prover
  1043     ultimately show "G Q'" by simp
  1044   qed
  1045 qed
  1046 
  1047 lemma is_filter_parametric [transfer_rule]:
  1048   "\<lbrakk> bi_total A; bi_unique A \<rbrakk>
  1049   \<Longrightarrow> (((A ===> op =) ===> op =) ===> op =) is_filter is_filter"
  1050 apply(rule rel_funI)
  1051 apply(rule iffI)
  1052  apply(erule (3) is_filter_parametric_aux)
  1053 apply(erule is_filter_parametric_aux[where A="conversep A"])
  1054 apply (simp_all add: rel_fun_def)
  1055 apply metis
  1056 done
  1057 
  1058 lemma left_total_rel_filter [transfer_rule]:
  1059   assumes [transfer_rule]: "bi_total A" "bi_unique A"
  1060   shows "left_total (rel_filter A)"
  1061 proof(rule left_totalI)
  1062   fix F :: "'a filter"
  1063   from bi_total_fun[OF bi_unique_fun[OF \<open>bi_total A\<close> bi_unique_eq] bi_total_eq]
  1064   obtain G where [transfer_rule]: "((A ===> op =) ===> op =) (\<lambda>P. eventually P F) G"
  1065     unfolding  bi_total_def by blast
  1066   moreover have "is_filter (\<lambda>P. eventually P F) \<longleftrightarrow> is_filter G" by transfer_prover
  1067   hence "is_filter G" by(simp add: eventually_def is_filter_Rep_filter)
  1068   ultimately have "rel_filter A F (Abs_filter G)"
  1069     by(simp add: rel_filter_eventually eventually_Abs_filter)
  1070   thus "\<exists>G. rel_filter A F G" ..
  1071 qed
  1072 
  1073 lemma right_total_rel_filter [transfer_rule]:
  1074   "\<lbrakk> bi_total A; bi_unique A \<rbrakk> \<Longrightarrow> right_total (rel_filter A)"
  1075 using left_total_rel_filter[of "A\<inverse>\<inverse>"] by simp
  1076 
  1077 lemma bi_total_rel_filter [transfer_rule]:
  1078   assumes "bi_total A" "bi_unique A"
  1079   shows "bi_total (rel_filter A)"
  1080 unfolding bi_total_alt_def using assms
  1081 by(simp add: left_total_rel_filter right_total_rel_filter)
  1082 
  1083 lemma left_unique_rel_filter [transfer_rule]:
  1084   assumes "left_unique A"
  1085   shows "left_unique (rel_filter A)"
  1086 proof(rule left_uniqueI)
  1087   fix F F' G
  1088   assume [transfer_rule]: "rel_filter A F G" "rel_filter A F' G"
  1089   show "F = F'"
  1090     unfolding filter_eq_iff
  1091   proof
  1092     fix P :: "'a \<Rightarrow> bool"
  1093     obtain P' where [transfer_rule]: "(A ===> op =) P P'"
  1094       using left_total_fun[OF assms left_total_eq] unfolding left_total_def by blast
  1095     have "eventually P F = eventually P' G"
  1096       and "eventually P F' = eventually P' G" by transfer_prover+
  1097     thus "eventually P F = eventually P F'" by simp
  1098   qed
  1099 qed
  1100 
  1101 lemma right_unique_rel_filter [transfer_rule]:
  1102   "right_unique A \<Longrightarrow> right_unique (rel_filter A)"
  1103 using left_unique_rel_filter[of "A\<inverse>\<inverse>"] by simp
  1104 
  1105 lemma bi_unique_rel_filter [transfer_rule]:
  1106   "bi_unique A \<Longrightarrow> bi_unique (rel_filter A)"
  1107 by(simp add: bi_unique_alt_def left_unique_rel_filter right_unique_rel_filter)
  1108 
  1109 lemma top_filter_parametric [transfer_rule]:
  1110   "bi_total A \<Longrightarrow> (rel_filter A) top top"
  1111 by(simp add: rel_filter_eventually All_transfer)
  1112 
  1113 lemma bot_filter_parametric [transfer_rule]: "(rel_filter A) bot bot"
  1114 by(simp add: rel_filter_eventually rel_fun_def)
  1115 
  1116 lemma sup_filter_parametric [transfer_rule]:
  1117   "(rel_filter A ===> rel_filter A ===> rel_filter A) sup sup"
  1118 by(fastforce simp add: rel_filter_eventually[abs_def] eventually_sup dest: rel_funD)
  1119 
  1120 lemma Sup_filter_parametric [transfer_rule]:
  1121   "(rel_set (rel_filter A) ===> rel_filter A) Sup Sup"
  1122 proof(rule rel_funI)
  1123   fix S T
  1124   assume [transfer_rule]: "rel_set (rel_filter A) S T"
  1125   show "rel_filter A (Sup S) (Sup T)"
  1126     by(simp add: rel_filter_eventually eventually_Sup) transfer_prover
  1127 qed
  1128 
  1129 lemma principal_parametric [transfer_rule]:
  1130   "(rel_set A ===> rel_filter A) principal principal"
  1131 proof(rule rel_funI)
  1132   fix S S'
  1133   assume [transfer_rule]: "rel_set A S S'"
  1134   show "rel_filter A (principal S) (principal S')"
  1135     by(simp add: rel_filter_eventually eventually_principal) transfer_prover
  1136 qed
  1137 
  1138 context
  1139   fixes A :: "'a \<Rightarrow> 'b \<Rightarrow> bool"
  1140   assumes [transfer_rule]: "bi_unique A"
  1141 begin
  1142 
  1143 lemma le_filter_parametric [transfer_rule]:
  1144   "(rel_filter A ===> rel_filter A ===> op =) op \<le> op \<le>"
  1145 unfolding le_filter_def[abs_def] by transfer_prover
  1146 
  1147 lemma less_filter_parametric [transfer_rule]:
  1148   "(rel_filter A ===> rel_filter A ===> op =) op < op <"
  1149 unfolding less_filter_def[abs_def] by transfer_prover
  1150 
  1151 context
  1152   assumes [transfer_rule]: "bi_total A"
  1153 begin
  1154 
  1155 lemma Inf_filter_parametric [transfer_rule]:
  1156   "(rel_set (rel_filter A) ===> rel_filter A) Inf Inf"
  1157 unfolding Inf_filter_def[abs_def] by transfer_prover
  1158 
  1159 lemma inf_filter_parametric [transfer_rule]:
  1160   "(rel_filter A ===> rel_filter A ===> rel_filter A) inf inf"
  1161 proof(intro rel_funI)+
  1162   fix F F' G G'
  1163   assume [transfer_rule]: "rel_filter A F F'" "rel_filter A G G'"
  1164   have "rel_filter A (Inf {F, G}) (Inf {F', G'})" by transfer_prover
  1165   thus "rel_filter A (inf F G) (inf F' G')" by simp
  1166 qed
  1167 
  1168 end
  1169 
  1170 end
  1171 
  1172 end
  1173 
  1174 end