src/Pure/drule.ML
author wenzelm
Sun Mar 01 23:36:12 2009 +0100 (2009-03-01)
changeset 30190 479806475f3c
parent 29579 cb520b766e00
child 30342 d32daa6aba3c
permissions -rw-r--r--
use long names for old-style fold combinators;
     1 (*  Title:      Pure/drule.ML
     2     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     3 
     4 Derived rules and other operations on theorems.
     5 *)
     6 
     7 infix 0 RS RSN RL RLN MRS MRL OF COMP INCR_COMP COMP_INCR;
     8 
     9 signature BASIC_DRULE =
    10 sig
    11   val mk_implies: cterm * cterm -> cterm
    12   val list_implies: cterm list * cterm -> cterm
    13   val strip_imp_prems: cterm -> cterm list
    14   val strip_imp_concl: cterm -> cterm
    15   val cprems_of: thm -> cterm list
    16   val cterm_fun: (term -> term) -> (cterm -> cterm)
    17   val ctyp_fun: (typ -> typ) -> (ctyp -> ctyp)
    18   val forall_intr_list: cterm list -> thm -> thm
    19   val forall_intr_frees: thm -> thm
    20   val forall_intr_vars: thm -> thm
    21   val forall_elim_list: cterm list -> thm -> thm
    22   val gen_all: thm -> thm
    23   val lift_all: cterm -> thm -> thm
    24   val freeze_thaw: thm -> thm * (thm -> thm)
    25   val freeze_thaw_robust: thm -> thm * (int -> thm -> thm)
    26   val implies_elim_list: thm -> thm list -> thm
    27   val implies_intr_list: cterm list -> thm -> thm
    28   val instantiate: (ctyp * ctyp) list * (cterm * cterm) list -> thm -> thm
    29   val zero_var_indexes_list: thm list -> thm list
    30   val zero_var_indexes: thm -> thm
    31   val implies_intr_hyps: thm -> thm
    32   val standard: thm -> thm
    33   val standard': thm -> thm
    34   val rotate_prems: int -> thm -> thm
    35   val rearrange_prems: int list -> thm -> thm
    36   val RSN: thm * (int * thm) -> thm
    37   val RS: thm * thm -> thm
    38   val RLN: thm list * (int * thm list) -> thm list
    39   val RL: thm list * thm list -> thm list
    40   val MRS: thm list * thm -> thm
    41   val MRL: thm list list * thm list -> thm list
    42   val OF: thm * thm list -> thm
    43   val compose: thm * int * thm -> thm list
    44   val COMP: thm * thm -> thm
    45   val INCR_COMP: thm * thm -> thm
    46   val COMP_INCR: thm * thm -> thm
    47   val cterm_instantiate: (cterm*cterm)list -> thm -> thm
    48   val size_of_thm: thm -> int
    49   val reflexive_thm: thm
    50   val symmetric_thm: thm
    51   val transitive_thm: thm
    52   val symmetric_fun: thm -> thm
    53   val extensional: thm -> thm
    54   val equals_cong: thm
    55   val imp_cong: thm
    56   val swap_prems_eq: thm
    57   val asm_rl: thm
    58   val cut_rl: thm
    59   val revcut_rl: thm
    60   val thin_rl: thm
    61   val triv_forall_equality: thm
    62   val distinct_prems_rl: thm
    63   val swap_prems_rl: thm
    64   val equal_intr_rule: thm
    65   val equal_elim_rule1: thm
    66   val equal_elim_rule2: thm
    67   val instantiate': ctyp option list -> cterm option list -> thm -> thm
    68 end;
    69 
    70 signature DRULE =
    71 sig
    72   include BASIC_DRULE
    73   val generalize: string list * string list -> thm -> thm
    74   val list_comb: cterm * cterm list -> cterm
    75   val strip_comb: cterm -> cterm * cterm list
    76   val strip_type: ctyp -> ctyp list * ctyp
    77   val beta_conv: cterm -> cterm -> cterm
    78   val types_sorts: thm -> (indexname-> typ option) * (indexname-> sort option)
    79   val flexflex_unique: thm -> thm
    80   val store_thm: bstring -> thm -> thm
    81   val store_standard_thm: bstring -> thm -> thm
    82   val store_thm_open: bstring -> thm -> thm
    83   val store_standard_thm_open: bstring -> thm -> thm
    84   val compose_single: thm * int * thm -> thm
    85   val imp_cong_rule: thm -> thm -> thm
    86   val arg_cong_rule: cterm -> thm -> thm
    87   val binop_cong_rule: cterm -> thm -> thm -> thm
    88   val fun_cong_rule: thm -> cterm -> thm
    89   val beta_eta_conversion: cterm -> thm
    90   val eta_long_conversion: cterm -> thm
    91   val eta_contraction_rule: thm -> thm
    92   val norm_hhf_eq: thm
    93   val norm_hhf_eqs: thm list
    94   val is_norm_hhf: term -> bool
    95   val norm_hhf: theory -> term -> term
    96   val norm_hhf_cterm: cterm -> cterm
    97   val protect: cterm -> cterm
    98   val protectI: thm
    99   val protectD: thm
   100   val protect_cong: thm
   101   val implies_intr_protected: cterm list -> thm -> thm
   102   val termI: thm
   103   val mk_term: cterm -> thm
   104   val dest_term: thm -> cterm
   105   val cterm_rule: (thm -> thm) -> cterm -> cterm
   106   val term_rule: theory -> (thm -> thm) -> term -> term
   107   val dummy_thm: thm
   108   val sort_constraintI: thm
   109   val sort_constraint_eq: thm
   110   val sort_triv: theory -> typ * sort -> thm list
   111   val unconstrainTs: thm -> thm
   112   val with_subgoal: int -> (thm -> thm) -> thm -> thm
   113   val comp_no_flatten: thm * int -> int -> thm -> thm
   114   val rename_bvars: (string * string) list -> thm -> thm
   115   val rename_bvars': string option list -> thm -> thm
   116   val incr_type_indexes: int -> thm -> thm
   117   val incr_indexes: thm -> thm -> thm
   118   val incr_indexes2: thm -> thm -> thm -> thm
   119   val remdups_rl: thm
   120   val multi_resolve: thm list -> thm -> thm Seq.seq
   121   val multi_resolves: thm list -> thm list -> thm Seq.seq
   122   val abs_def: thm -> thm
   123 end;
   124 
   125 structure Drule: DRULE =
   126 struct
   127 
   128 
   129 (** some cterm->cterm operations: faster than calling cterm_of! **)
   130 
   131 (* A1==>...An==>B  goes to  [A1,...,An], where B is not an implication *)
   132 fun strip_imp_prems ct =
   133   let val (cA, cB) = Thm.dest_implies ct
   134   in cA :: strip_imp_prems cB end
   135   handle TERM _ => [];
   136 
   137 (* A1==>...An==>B  goes to B, where B is not an implication *)
   138 fun strip_imp_concl ct =
   139   (case Thm.term_of ct of
   140     Const ("==>", _) $ _ $ _ => strip_imp_concl (Thm.dest_arg ct)
   141   | _ => ct);
   142 
   143 (*The premises of a theorem, as a cterm list*)
   144 val cprems_of = strip_imp_prems o cprop_of;
   145 
   146 fun cterm_fun f ct = Thm.cterm_of (Thm.theory_of_cterm ct) (f (Thm.term_of ct));
   147 fun ctyp_fun f cT = Thm.ctyp_of (Thm.theory_of_ctyp cT) (f (Thm.typ_of cT));
   148 
   149 fun certify t = Thm.cterm_of (Context.the_theory (Context.the_thread_data ())) t;
   150 
   151 val implies = certify Logic.implies;
   152 fun mk_implies (A, B) = Thm.capply (Thm.capply implies A) B;
   153 
   154 (*cterm version of list_implies: [A1,...,An], B  goes to [|A1;==>;An|]==>B *)
   155 fun list_implies([], B) = B
   156   | list_implies(A::AS, B) = mk_implies (A, list_implies(AS,B));
   157 
   158 (*cterm version of list_comb: maps  (f, [t1,...,tn])  to  f(t1,...,tn) *)
   159 fun list_comb (f, []) = f
   160   | list_comb (f, t::ts) = list_comb (Thm.capply f t, ts);
   161 
   162 (*cterm version of strip_comb: maps  f(t1,...,tn)  to  (f, [t1,...,tn]) *)
   163 fun strip_comb ct =
   164   let
   165     fun stripc (p as (ct, cts)) =
   166       let val (ct1, ct2) = Thm.dest_comb ct
   167       in stripc (ct1, ct2 :: cts) end handle CTERM _ => p
   168   in stripc (ct, []) end;
   169 
   170 (* cterm version of strip_type: maps  [T1,...,Tn]--->T  to   ([T1,T2,...,Tn], T) *)
   171 fun strip_type cT = (case Thm.typ_of cT of
   172     Type ("fun", _) =>
   173       let
   174         val [cT1, cT2] = Thm.dest_ctyp cT;
   175         val (cTs, cT') = strip_type cT2
   176       in (cT1 :: cTs, cT') end
   177   | _ => ([], cT));
   178 
   179 (*Beta-conversion for cterms, where x is an abstraction. Simply returns the rhs
   180   of the meta-equality returned by the beta_conversion rule.*)
   181 fun beta_conv x y =
   182   Thm.dest_arg (cprop_of (Thm.beta_conversion false (Thm.capply x y)));
   183 
   184 
   185 
   186 (*** Find the type (sort) associated with a (T)Var or (T)Free in a term
   187      Used for establishing default types (of variables) and sorts (of
   188      type variables) when reading another term.
   189      Index -1 indicates that a (T)Free rather than a (T)Var is wanted.
   190 ***)
   191 
   192 fun types_sorts thm =
   193   let
   194     val vars = Thm.fold_terms Term.add_vars thm [];
   195     val frees = Thm.fold_terms Term.add_frees thm [];
   196     val tvars = Thm.fold_terms Term.add_tvars thm [];
   197     val tfrees = Thm.fold_terms Term.add_tfrees thm [];
   198     fun types (a, i) =
   199       if i < 0 then AList.lookup (op =) frees a else AList.lookup (op =) vars (a, i);
   200     fun sorts (a, i) =
   201       if i < 0 then AList.lookup (op =) tfrees a else AList.lookup (op =) tvars (a, i);
   202   in (types, sorts) end;
   203 
   204 
   205 
   206 
   207 (** Standardization of rules **)
   208 
   209 (* type classes and sorts *)
   210 
   211 fun sort_triv thy (T, S) =
   212   let
   213     val certT = Thm.ctyp_of thy;
   214     val cT = certT T;
   215     fun class_triv c =
   216       Thm.class_triv thy c
   217       |> Thm.instantiate ([(certT (TVar ((Name.aT, 0), [c])), cT)], []);
   218   in map class_triv S end;
   219 
   220 fun unconstrainTs th =
   221   fold (Thm.unconstrainT o Thm.ctyp_of (Thm.theory_of_thm th) o TVar)
   222     (Thm.fold_terms Term.add_tvars th []) th;
   223 
   224 (*Generalization over a list of variables*)
   225 val forall_intr_list = fold_rev forall_intr;
   226 
   227 (*Generalization over all suitable Free variables*)
   228 fun forall_intr_frees th =
   229     let
   230       val thy = Thm.theory_of_thm th;
   231       val {prop, hyps, tpairs, ...} = rep_thm th;
   232       val fixed = fold Term.add_frees (Thm.terms_of_tpairs tpairs @ hyps) [];
   233       val frees = Term.fold_aterms (fn Free v =>
   234         if member (op =) fixed v then I else insert (op =) v | _ => I) prop [];
   235     in fold (forall_intr o cterm_of thy o Free) frees th end;
   236 
   237 (*Generalization over Vars -- canonical order*)
   238 fun forall_intr_vars th =
   239   fold forall_intr
   240     (map (Thm.cterm_of (Thm.theory_of_thm th) o Var) (Thm.fold_terms Term.add_vars th [])) th;
   241 
   242 fun outer_params t =
   243   let val vs = Term.strip_all_vars t
   244   in Name.variant_list [] (map (Name.clean o #1) vs) ~~ map #2 vs end;
   245 
   246 (*generalize outermost parameters*)
   247 fun gen_all th =
   248   let
   249     val thy = Thm.theory_of_thm th;
   250     val {prop, maxidx, ...} = Thm.rep_thm th;
   251     val cert = Thm.cterm_of thy;
   252     fun elim (x, T) = Thm.forall_elim (cert (Var ((x, maxidx + 1), T)));
   253   in fold elim (outer_params prop) th end;
   254 
   255 (*lift vars wrt. outermost goal parameters
   256   -- reverses the effect of gen_all modulo higher-order unification*)
   257 fun lift_all goal th =
   258   let
   259     val thy = Theory.merge (Thm.theory_of_cterm goal, Thm.theory_of_thm th);
   260     val cert = Thm.cterm_of thy;
   261     val maxidx = Thm.maxidx_of th;
   262     val ps = outer_params (Thm.term_of goal)
   263       |> map (fn (x, T) => Var ((x, maxidx + 1), Logic.incr_tvar (maxidx + 1) T));
   264     val Ts = map Term.fastype_of ps;
   265     val inst = Thm.fold_terms Term.add_vars th [] |> map (fn (xi, T) =>
   266       (cert (Var (xi, T)), cert (Term.list_comb (Var (xi, Ts ---> T), ps))));
   267   in
   268     th |> Thm.instantiate ([], inst)
   269     |> fold_rev (Thm.forall_intr o cert) ps
   270   end;
   271 
   272 (*direct generalization*)
   273 fun generalize names th = Thm.generalize names (Thm.maxidx_of th + 1) th;
   274 
   275 (*specialization over a list of cterms*)
   276 val forall_elim_list = fold forall_elim;
   277 
   278 (*maps A1,...,An |- B  to  [| A1;...;An |] ==> B*)
   279 val implies_intr_list = fold_rev implies_intr;
   280 
   281 (*maps [| A1;...;An |] ==> B and [A1,...,An]  to  B*)
   282 fun implies_elim_list impth ths = fold Thm.elim_implies ths impth;
   283 
   284 (*Reset Var indexes to zero, renaming to preserve distinctness*)
   285 fun zero_var_indexes_list [] = []
   286   | zero_var_indexes_list ths =
   287       let
   288         val thy = Theory.merge_list (map Thm.theory_of_thm ths);
   289         val certT = Thm.ctyp_of thy and cert = Thm.cterm_of thy;
   290         val (instT, inst) = TermSubst.zero_var_indexes_inst (map Thm.full_prop_of ths);
   291         val cinstT = map (fn (v, T) => (certT (TVar v), certT T)) instT;
   292         val cinst = map (fn (v, t) => (cert (Var v), cert t)) inst;
   293       in map (Thm.adjust_maxidx_thm ~1 o Thm.instantiate (cinstT, cinst)) ths end;
   294 
   295 val zero_var_indexes = singleton zero_var_indexes_list;
   296 
   297 
   298 (** Standard form of object-rule: no hypotheses, flexflex constraints,
   299     Frees, or outer quantifiers; all generality expressed by Vars of index 0.**)
   300 
   301 (*Discharge all hypotheses.*)
   302 fun implies_intr_hyps th =
   303   fold Thm.implies_intr (#hyps (Thm.crep_thm th)) th;
   304 
   305 (*Squash a theorem's flexflex constraints provided it can be done uniquely.
   306   This step can lose information.*)
   307 fun flexflex_unique th =
   308   if null (tpairs_of th) then th else
   309     case distinct Thm.eq_thm (Seq.list_of (flexflex_rule th)) of
   310       [th] => th
   311     | []   => raise THM("flexflex_unique: impossible constraints", 0, [th])
   312     |  _   => raise THM("flexflex_unique: multiple unifiers", 0, [th]);
   313 
   314 
   315 (* legacy standard operations *)
   316 
   317 val standard' =
   318   implies_intr_hyps
   319   #> forall_intr_frees
   320   #> `Thm.maxidx_of
   321   #-> (fn maxidx =>
   322     Thm.forall_elim_vars (maxidx + 1)
   323     #> Thm.strip_shyps
   324     #> zero_var_indexes
   325     #> Thm.varifyT);
   326 
   327 val standard =
   328   flexflex_unique
   329   #> standard'
   330   #> Thm.close_derivation;
   331 
   332 
   333 (*Convert all Vars in a theorem to Frees.  Also return a function for
   334   reversing that operation.  DOES NOT WORK FOR TYPE VARIABLES.
   335   Similar code in type/freeze_thaw*)
   336 
   337 fun freeze_thaw_robust th =
   338  let val fth = Thm.freezeT th
   339      val thy = Thm.theory_of_thm fth
   340      val {prop, tpairs, ...} = rep_thm fth
   341  in
   342    case List.foldr OldTerm.add_term_vars [] (prop :: Thm.terms_of_tpairs tpairs) of
   343        [] => (fth, fn i => fn x => x)   (*No vars: nothing to do!*)
   344      | vars =>
   345          let fun newName (Var(ix,_)) = (ix, gensym (string_of_indexname ix))
   346              val alist = map newName vars
   347              fun mk_inst (Var(v,T)) =
   348                  (cterm_of thy (Var(v,T)),
   349                   cterm_of thy (Free(((the o AList.lookup (op =) alist) v), T)))
   350              val insts = map mk_inst vars
   351              fun thaw i th' = (*i is non-negative increment for Var indexes*)
   352                  th' |> forall_intr_list (map #2 insts)
   353                      |> forall_elim_list (map (Thm.incr_indexes_cterm i o #1) insts)
   354          in  (Thm.instantiate ([],insts) fth, thaw)  end
   355  end;
   356 
   357 (*Basic version of the function above. No option to rename Vars apart in thaw.
   358   The Frees created from Vars have nice names. FIXME: does not check for
   359   clashes with variables in the assumptions, so delete and use freeze_thaw_robust instead?*)
   360 fun freeze_thaw th =
   361  let val fth = Thm.freezeT th
   362      val thy = Thm.theory_of_thm fth
   363      val {prop, tpairs, ...} = rep_thm fth
   364  in
   365    case List.foldr OldTerm.add_term_vars [] (prop :: Thm.terms_of_tpairs tpairs) of
   366        [] => (fth, fn x => x)
   367      | vars =>
   368          let fun newName (Var(ix,_), (pairs,used)) =
   369                    let val v = Name.variant used (string_of_indexname ix)
   370                    in  ((ix,v)::pairs, v::used)  end;
   371              val (alist, _) = List.foldr newName ([], Library.foldr OldTerm.add_term_names
   372                (prop :: Thm.terms_of_tpairs tpairs, [])) vars
   373              fun mk_inst (Var(v,T)) =
   374                  (cterm_of thy (Var(v,T)),
   375                   cterm_of thy (Free(((the o AList.lookup (op =) alist) v), T)))
   376              val insts = map mk_inst vars
   377              fun thaw th' =
   378                  th' |> forall_intr_list (map #2 insts)
   379                      |> forall_elim_list (map #1 insts)
   380          in  (Thm.instantiate ([],insts) fth, thaw)  end
   381  end;
   382 
   383 (*Rotates a rule's premises to the left by k*)
   384 fun rotate_prems 0 = I
   385   | rotate_prems k = permute_prems 0 k;
   386 
   387 fun with_subgoal i f = rotate_prems (i - 1) #> f #> rotate_prems (1 - i);
   388 
   389 (* permute prems, where the i-th position in the argument list (counting from 0)
   390    gives the position within the original thm to be transferred to position i.
   391    Any remaining trailing positions are left unchanged. *)
   392 val rearrange_prems = let
   393   fun rearr new []      thm = thm
   394   |   rearr new (p::ps) thm = rearr (new+1)
   395      (map (fn q => if new<=q andalso q<p then q+1 else q) ps)
   396      (permute_prems (new+1) (new-p) (permute_prems new (p-new) thm))
   397   in rearr 0 end;
   398 
   399 (*Resolution: exactly one resolvent must be produced.*)
   400 fun tha RSN (i,thb) =
   401   case Seq.chop 2 (biresolution false [(false,tha)] i thb) of
   402       ([th],_) => th
   403     | ([],_)   => raise THM("RSN: no unifiers", i, [tha,thb])
   404     |      _   => raise THM("RSN: multiple unifiers", i, [tha,thb]);
   405 
   406 (*resolution: P==>Q, Q==>R gives P==>R. *)
   407 fun tha RS thb = tha RSN (1,thb);
   408 
   409 (*For joining lists of rules*)
   410 fun thas RLN (i,thbs) =
   411   let val resolve = biresolution false (map (pair false) thas) i
   412       fun resb thb = Seq.list_of (resolve thb) handle THM _ => []
   413   in maps resb thbs end;
   414 
   415 fun thas RL thbs = thas RLN (1,thbs);
   416 
   417 (*Resolve a list of rules against bottom_rl from right to left;
   418   makes proof trees*)
   419 fun rls MRS bottom_rl =
   420   let fun rs_aux i [] = bottom_rl
   421         | rs_aux i (rl::rls) = rl RSN (i, rs_aux (i+1) rls)
   422   in  rs_aux 1 rls  end;
   423 
   424 (*As above, but for rule lists*)
   425 fun rlss MRL bottom_rls =
   426   let fun rs_aux i [] = bottom_rls
   427         | rs_aux i (rls::rlss) = rls RLN (i, rs_aux (i+1) rlss)
   428   in  rs_aux 1 rlss  end;
   429 
   430 (*A version of MRS with more appropriate argument order*)
   431 fun bottom_rl OF rls = rls MRS bottom_rl;
   432 
   433 (*compose Q and [...,Qi,Q(i+1),...]==>R to [...,Q(i+1),...]==>R
   434   with no lifting or renaming!  Q may contain ==> or meta-quants
   435   ALWAYS deletes premise i *)
   436 fun compose(tha,i,thb) =
   437     distinct Thm.eq_thm (Seq.list_of (bicompose false (false,tha,0) i thb));
   438 
   439 fun compose_single (tha,i,thb) =
   440   case compose (tha,i,thb) of
   441     [th] => th
   442   | _ => raise THM ("compose: unique result expected", i, [tha,thb]);
   443 
   444 (*compose Q and [Q1,Q2,...,Qk]==>R to [Q2,...,Qk]==>R getting unique result*)
   445 fun tha COMP thb =
   446     case compose(tha,1,thb) of
   447         [th] => th
   448       | _ =>   raise THM("COMP", 1, [tha,thb]);
   449 
   450 
   451 (** theorem equality **)
   452 
   453 (*Useful "distance" function for BEST_FIRST*)
   454 val size_of_thm = size_of_term o Thm.full_prop_of;
   455 
   456 
   457 
   458 (*** Meta-Rewriting Rules ***)
   459 
   460 val read_prop = certify o SimpleSyntax.read_prop;
   461 
   462 fun store_thm name th =
   463   Context.>>> (Context.map_theory_result (PureThy.store_thm (Binding.name name, th)));
   464 
   465 fun store_thm_open name th =
   466   Context.>>> (Context.map_theory_result (PureThy.store_thm_open (Binding.name name, th)));
   467 
   468 fun store_standard_thm name th = store_thm name (standard th);
   469 fun store_standard_thm_open name thm = store_thm_open name (standard' thm);
   470 
   471 val reflexive_thm =
   472   let val cx = certify (Var(("x",0),TVar(("'a",0),[])))
   473   in store_standard_thm_open "reflexive" (Thm.reflexive cx) end;
   474 
   475 val symmetric_thm =
   476   let val xy = read_prop "x::'a == y::'a"
   477   in store_standard_thm_open "symmetric" (Thm.implies_intr xy (Thm.symmetric (Thm.assume xy))) end;
   478 
   479 val transitive_thm =
   480   let val xy = read_prop "x::'a == y::'a"
   481       val yz = read_prop "y::'a == z::'a"
   482       val xythm = Thm.assume xy and yzthm = Thm.assume yz
   483   in store_standard_thm_open "transitive" (Thm.implies_intr yz (Thm.transitive xythm yzthm)) end;
   484 
   485 fun symmetric_fun thm = thm RS symmetric_thm;
   486 
   487 fun extensional eq =
   488   let val eq' =
   489     abstract_rule "x" (Thm.dest_arg (fst (Thm.dest_equals (cprop_of eq)))) eq
   490   in equal_elim (eta_conversion (cprop_of eq')) eq' end;
   491 
   492 val equals_cong =
   493   store_standard_thm_open "equals_cong" (Thm.reflexive (read_prop "x::'a == y::'a"));
   494 
   495 val imp_cong =
   496   let
   497     val ABC = read_prop "A ==> B::prop == C::prop"
   498     val AB = read_prop "A ==> B"
   499     val AC = read_prop "A ==> C"
   500     val A = read_prop "A"
   501   in
   502     store_standard_thm_open "imp_cong" (implies_intr ABC (equal_intr
   503       (implies_intr AB (implies_intr A
   504         (equal_elim (implies_elim (assume ABC) (assume A))
   505           (implies_elim (assume AB) (assume A)))))
   506       (implies_intr AC (implies_intr A
   507         (equal_elim (symmetric (implies_elim (assume ABC) (assume A)))
   508           (implies_elim (assume AC) (assume A)))))))
   509   end;
   510 
   511 val swap_prems_eq =
   512   let
   513     val ABC = read_prop "A ==> B ==> C"
   514     val BAC = read_prop "B ==> A ==> C"
   515     val A = read_prop "A"
   516     val B = read_prop "B"
   517   in
   518     store_standard_thm_open "swap_prems_eq" (equal_intr
   519       (implies_intr ABC (implies_intr B (implies_intr A
   520         (implies_elim (implies_elim (assume ABC) (assume A)) (assume B)))))
   521       (implies_intr BAC (implies_intr A (implies_intr B
   522         (implies_elim (implies_elim (assume BAC) (assume B)) (assume A))))))
   523   end;
   524 
   525 val imp_cong_rule = Thm.combination o Thm.combination (Thm.reflexive implies);
   526 
   527 fun arg_cong_rule ct th = Thm.combination (Thm.reflexive ct) th;    (*AP_TERM in LCF/HOL*)
   528 fun fun_cong_rule th ct = Thm.combination th (Thm.reflexive ct);    (*AP_THM in LCF/HOL*)
   529 fun binop_cong_rule ct th1 th2 = Thm.combination (arg_cong_rule ct th1) th2;
   530 
   531 local
   532   val dest_eq = Thm.dest_equals o cprop_of
   533   val rhs_of = snd o dest_eq
   534 in
   535 fun beta_eta_conversion t =
   536   let val thm = beta_conversion true t
   537   in transitive thm (eta_conversion (rhs_of thm)) end
   538 end;
   539 
   540 fun eta_long_conversion ct = transitive (beta_eta_conversion ct)
   541   (symmetric (beta_eta_conversion (cterm_fun (Pattern.eta_long []) ct)));
   542 
   543 (*Contract all eta-redexes in the theorem, lest they give rise to needless abstractions*)
   544 fun eta_contraction_rule th =
   545   equal_elim (eta_conversion (cprop_of th)) th;
   546 
   547 
   548 (* abs_def *)
   549 
   550 (*
   551    f ?x1 ... ?xn == u
   552   --------------------
   553    f == %x1 ... xn. u
   554 *)
   555 
   556 local
   557 
   558 fun contract_lhs th =
   559   Thm.transitive (Thm.symmetric (beta_eta_conversion
   560     (fst (Thm.dest_equals (cprop_of th))))) th;
   561 
   562 fun var_args ct =
   563   (case try Thm.dest_comb ct of
   564     SOME (f, arg) =>
   565       (case Thm.term_of arg of
   566         Var ((x, _), _) => update (eq_snd (op aconvc)) (x, arg) (var_args f)
   567       | _ => [])
   568   | NONE => []);
   569 
   570 in
   571 
   572 fun abs_def th =
   573   let
   574     val th' = contract_lhs th;
   575     val args = var_args (Thm.lhs_of th');
   576   in contract_lhs (fold (uncurry Thm.abstract_rule) args th') end;
   577 
   578 end;
   579 
   580 
   581 
   582 (*** Some useful meta-theorems ***)
   583 
   584 (*The rule V/V, obtains assumption solving for eresolve_tac*)
   585 val asm_rl = store_standard_thm_open "asm_rl" (Thm.trivial (read_prop "?psi"));
   586 val _ = store_thm_open "_" asm_rl;
   587 
   588 (*Meta-level cut rule: [| V==>W; V |] ==> W *)
   589 val cut_rl =
   590   store_standard_thm_open "cut_rl"
   591     (Thm.trivial (read_prop "?psi ==> ?theta"));
   592 
   593 (*Generalized elim rule for one conclusion; cut_rl with reversed premises:
   594      [| PROP V;  PROP V ==> PROP W |] ==> PROP W *)
   595 val revcut_rl =
   596   let val V = read_prop "V"
   597       and VW = read_prop "V ==> W";
   598   in
   599     store_standard_thm_open "revcut_rl"
   600       (implies_intr V (implies_intr VW (implies_elim (assume VW) (assume V))))
   601   end;
   602 
   603 (*for deleting an unwanted assumption*)
   604 val thin_rl =
   605   let val V = read_prop "V"
   606       and W = read_prop "W";
   607   in store_standard_thm_open "thin_rl" (implies_intr V (implies_intr W (assume W))) end;
   608 
   609 (* (!!x. PROP ?V) == PROP ?V       Allows removal of redundant parameters*)
   610 val triv_forall_equality =
   611   let val V  = read_prop "V"
   612       and QV = read_prop "!!x::'a. V"
   613       and x  = certify (Free ("x", Term.aT []));
   614   in
   615     store_standard_thm_open "triv_forall_equality"
   616       (equal_intr (implies_intr QV (forall_elim x (assume QV)))
   617         (implies_intr V  (forall_intr x (assume V))))
   618   end;
   619 
   620 (* (PROP ?Phi ==> PROP ?Phi ==> PROP ?Psi) ==>
   621    (PROP ?Phi ==> PROP ?Psi)
   622 *)
   623 val distinct_prems_rl =
   624   let
   625     val AAB = read_prop "Phi ==> Phi ==> Psi"
   626     val A = read_prop "Phi";
   627   in
   628     store_standard_thm_open "distinct_prems_rl"
   629       (implies_intr_list [AAB, A] (implies_elim_list (assume AAB) [assume A, assume A]))
   630   end;
   631 
   632 (* (PROP ?PhiA ==> PROP ?PhiB ==> PROP ?Psi) ==>
   633    (PROP ?PhiB ==> PROP ?PhiA ==> PROP ?Psi)
   634    `thm COMP swap_prems_rl' swaps the first two premises of `thm'
   635 *)
   636 val swap_prems_rl =
   637   let val cmajor = read_prop "PhiA ==> PhiB ==> Psi";
   638       val major = assume cmajor;
   639       val cminor1 = read_prop "PhiA";
   640       val minor1 = assume cminor1;
   641       val cminor2 = read_prop "PhiB";
   642       val minor2 = assume cminor2;
   643   in store_standard_thm_open "swap_prems_rl"
   644        (implies_intr cmajor (implies_intr cminor2 (implies_intr cminor1
   645          (implies_elim (implies_elim major minor1) minor2))))
   646   end;
   647 
   648 (* [| PROP ?phi ==> PROP ?psi; PROP ?psi ==> PROP ?phi |]
   649    ==> PROP ?phi == PROP ?psi
   650    Introduction rule for == as a meta-theorem.
   651 *)
   652 val equal_intr_rule =
   653   let val PQ = read_prop "phi ==> psi"
   654       and QP = read_prop "psi ==> phi"
   655   in
   656     store_standard_thm_open "equal_intr_rule"
   657       (implies_intr PQ (implies_intr QP (equal_intr (assume PQ) (assume QP))))
   658   end;
   659 
   660 (* PROP ?phi == PROP ?psi ==> PROP ?phi ==> PROP ?psi *)
   661 val equal_elim_rule1 =
   662   let val eq = read_prop "phi::prop == psi::prop"
   663       and P = read_prop "phi"
   664   in store_standard_thm_open "equal_elim_rule1"
   665     (Thm.equal_elim (assume eq) (assume P) |> implies_intr_list [eq, P])
   666   end;
   667 
   668 (* PROP ?psi == PROP ?phi ==> PROP ?phi ==> PROP ?psi *)
   669 val equal_elim_rule2 =
   670   store_standard_thm_open "equal_elim_rule2" (symmetric_thm RS equal_elim_rule1);
   671 
   672 (* PROP ?phi ==> PROP ?phi ==> PROP ?psi ==> PROP ?psi *)
   673 val remdups_rl =
   674   let val P = read_prop "phi" and Q = read_prop "psi";
   675   in store_standard_thm_open "remdups_rl" (implies_intr_list [P, P, Q] (Thm.assume Q)) end;
   676 
   677 
   678 
   679 (** embedded terms and types **)
   680 
   681 local
   682   val A = certify (Free ("A", propT));
   683   val axiom = Thm.unvarify o Thm.axiom (Context.the_theory (Context.the_thread_data ()));
   684   val prop_def = axiom "Pure.prop_def";
   685   val term_def = axiom "Pure.term_def";
   686   val sort_constraint_def = axiom "Pure.sort_constraint_def";
   687   val C = Thm.lhs_of sort_constraint_def;
   688   val T = Thm.dest_arg C;
   689   val CA = mk_implies (C, A);
   690 in
   691 
   692 (* protect *)
   693 
   694 val protect = Thm.capply (certify Logic.protectC);
   695 
   696 val protectI = store_thm "protectI" (Thm.kind_rule Thm.internalK (standard
   697     (Thm.equal_elim (Thm.symmetric prop_def) (Thm.assume A))));
   698 
   699 val protectD = store_thm "protectD" (Thm.kind_rule Thm.internalK (standard
   700     (Thm.equal_elim prop_def (Thm.assume (protect A)))));
   701 
   702 val protect_cong = store_standard_thm_open "protect_cong" (Thm.reflexive (protect A));
   703 
   704 fun implies_intr_protected asms th =
   705   let val asms' = map protect asms in
   706     implies_elim_list
   707       (implies_intr_list asms th)
   708       (map (fn asm' => Thm.assume asm' RS protectD) asms')
   709     |> implies_intr_list asms'
   710   end;
   711 
   712 
   713 (* term *)
   714 
   715 val termI = store_thm "termI" (Thm.kind_rule Thm.internalK (standard
   716     (Thm.equal_elim (Thm.symmetric term_def) (Thm.forall_intr A (Thm.trivial A)))));
   717 
   718 fun mk_term ct =
   719   let
   720     val thy = Thm.theory_of_cterm ct;
   721     val cert = Thm.cterm_of thy;
   722     val certT = Thm.ctyp_of thy;
   723     val T = Thm.typ_of (Thm.ctyp_of_term ct);
   724     val a = certT (TVar (("'a", 0), []));
   725     val x = cert (Var (("x", 0), T));
   726   in Thm.instantiate ([(a, certT T)], [(x, ct)]) termI end;
   727 
   728 fun dest_term th =
   729   let val cprop = strip_imp_concl (Thm.cprop_of th) in
   730     if can Logic.dest_term (Thm.term_of cprop) then
   731       Thm.dest_arg cprop
   732     else raise THM ("dest_term", 0, [th])
   733   end;
   734 
   735 fun cterm_rule f = dest_term o f o mk_term;
   736 fun term_rule thy f t = Thm.term_of (cterm_rule f (Thm.cterm_of thy t));
   737 
   738 val dummy_thm = mk_term (certify (Term.dummy_pattern propT));
   739 
   740 
   741 (* sort_constraint *)
   742 
   743 val sort_constraintI = store_thm "sort_constraintI" (Thm.kind_rule Thm.internalK (standard
   744   (Thm.equal_elim (Thm.symmetric sort_constraint_def) (mk_term T))));
   745 
   746 val sort_constraint_eq = store_thm "sort_constraint_eq" (Thm.kind_rule Thm.internalK (standard
   747   (Thm.equal_intr
   748     (Thm.implies_intr CA (Thm.implies_elim (Thm.assume CA) (Thm.unvarify sort_constraintI)))
   749     (implies_intr_list [A, C] (Thm.assume A)))));
   750 
   751 end;
   752 
   753 
   754 (* HHF normalization *)
   755 
   756 (* (PROP ?phi ==> (!!x. PROP ?psi(x))) == (!!x. PROP ?phi ==> PROP ?psi(x)) *)
   757 val norm_hhf_eq =
   758   let
   759     val aT = TFree ("'a", []);
   760     val all = Term.all aT;
   761     val x = Free ("x", aT);
   762     val phi = Free ("phi", propT);
   763     val psi = Free ("psi", aT --> propT);
   764 
   765     val cx = certify x;
   766     val cphi = certify phi;
   767     val lhs = certify (Logic.mk_implies (phi, all $ Abs ("x", aT, psi $ Bound 0)));
   768     val rhs = certify (all $ Abs ("x", aT, Logic.mk_implies (phi, psi $ Bound 0)));
   769   in
   770     Thm.equal_intr
   771       (Thm.implies_elim (Thm.assume lhs) (Thm.assume cphi)
   772         |> Thm.forall_elim cx
   773         |> Thm.implies_intr cphi
   774         |> Thm.forall_intr cx
   775         |> Thm.implies_intr lhs)
   776       (Thm.implies_elim
   777           (Thm.assume rhs |> Thm.forall_elim cx) (Thm.assume cphi)
   778         |> Thm.forall_intr cx
   779         |> Thm.implies_intr cphi
   780         |> Thm.implies_intr rhs)
   781     |> store_standard_thm_open "norm_hhf_eq"
   782   end;
   783 
   784 val norm_hhf_prop = Logic.dest_equals (Thm.prop_of norm_hhf_eq);
   785 val norm_hhf_eqs = [norm_hhf_eq, sort_constraint_eq];
   786 
   787 fun is_norm_hhf tm =
   788   let
   789     fun is_norm (Const ("Pure.sort_constraint", _)) = false
   790       | is_norm (Const ("==>", _) $ _ $ (Const ("all", _) $ _)) = false
   791       | is_norm (t $ u) = is_norm t andalso is_norm u
   792       | is_norm (Abs (_, _, t)) = is_norm t
   793       | is_norm _ = true;
   794   in is_norm (Envir.beta_eta_contract tm) end;
   795 
   796 fun norm_hhf thy t =
   797   if is_norm_hhf t then t
   798   else Pattern.rewrite_term thy [norm_hhf_prop] [] t;
   799 
   800 fun norm_hhf_cterm ct =
   801   if is_norm_hhf (Thm.term_of ct) then ct
   802   else cterm_fun (Pattern.rewrite_term (Thm.theory_of_cterm ct) [norm_hhf_prop] []) ct;
   803 
   804 
   805 (* var indexes *)
   806 
   807 (*Increment the indexes of only the type variables*)
   808 fun incr_type_indexes inc th =
   809   let val tvs = OldTerm.term_tvars (prop_of th)
   810       and thy = Thm.theory_of_thm th
   811       fun inc_tvar ((a,i),s) = pairself (ctyp_of thy) (TVar ((a,i),s), TVar ((a,i+inc),s))
   812   in Thm.instantiate (map inc_tvar tvs, []) th end;
   813 
   814 fun incr_indexes th = Thm.incr_indexes (Thm.maxidx_of th + 1);
   815 
   816 fun incr_indexes2 th1 th2 =
   817   Thm.incr_indexes (Int.max (Thm.maxidx_of th1, Thm.maxidx_of th2) + 1);
   818 
   819 fun th1 INCR_COMP th2 = incr_indexes th2 th1 COMP th2;
   820 fun th1 COMP_INCR th2 = th1 COMP incr_indexes th1 th2;
   821 
   822 fun comp_no_flatten (th, n) i rule =
   823   (case distinct Thm.eq_thm (Seq.list_of
   824       (Thm.compose_no_flatten false (th, n) i (incr_indexes th rule))) of
   825     [th'] => th'
   826   | [] => raise THM ("comp_no_flatten", i, [th, rule])
   827   | _ => raise THM ("comp_no_flatten: unique result expected", i, [th, rule]));
   828 
   829 
   830 
   831 (*** Instantiate theorem th, reading instantiations in theory thy ****)
   832 
   833 (*Version that normalizes the result: Thm.instantiate no longer does that*)
   834 fun instantiate instpair th =
   835   Thm.adjust_maxidx_thm ~1 (Thm.instantiate instpair th COMP_INCR asm_rl);
   836 
   837 (*Left-to-right replacements: tpairs = [...,(vi,ti),...].
   838   Instantiates distinct Vars by terms, inferring type instantiations. *)
   839 local
   840   fun add_types ((ct,cu), (thy,tye,maxidx)) =
   841     let
   842         val thyt = Thm.theory_of_cterm ct;
   843         val thyu = Thm.theory_of_cterm cu;
   844         val {t, T, maxidx = maxt, ...} = Thm.rep_cterm ct;
   845         val {t = u, T = U, maxidx = maxu, ...} = Thm.rep_cterm cu;
   846         val maxi = Int.max(maxidx, Int.max(maxt, maxu));
   847         val thy' = Theory.merge(thy, Theory.merge(thyt, thyu))
   848         val (tye',maxi') = Sign.typ_unify thy' (T, U) (tye, maxi)
   849           handle Type.TUNIFY => raise TYPE ("Ill-typed instantiation:\nType\n" ^
   850             Syntax.string_of_typ_global thy' (Envir.norm_type tye T) ^
   851             "\nof variable " ^
   852             Syntax.string_of_term_global thy' (Term.map_types (Envir.norm_type tye) t) ^
   853             "\ncannot be unified with type\n" ^
   854             Syntax.string_of_typ_global thy' (Envir.norm_type tye U) ^ "\nof term " ^
   855             Syntax.string_of_term_global thy' (Term.map_types (Envir.norm_type tye) u),
   856             [T, U], [t, u])
   857     in  (thy', tye', maxi')  end;
   858 in
   859 fun cterm_instantiate [] th = th
   860   | cterm_instantiate ctpairs0 th =
   861   let val (thy,tye,_) = List.foldr add_types (Thm.theory_of_thm th, Vartab.empty, 0) ctpairs0
   862       fun instT(ct,cu) =
   863         let val inst = cterm_of thy o Term.map_types (Envir.norm_type tye) o term_of
   864         in (inst ct, inst cu) end
   865       fun ctyp2 (ixn, (S, T)) = (ctyp_of thy (TVar (ixn, S)), ctyp_of thy (Envir.norm_type tye T))
   866   in  instantiate (map ctyp2 (Vartab.dest tye), map instT ctpairs0) th  end
   867   handle TERM _ =>
   868            raise THM("cterm_instantiate: incompatible theories",0,[th])
   869        | TYPE (msg, _, _) => raise THM(msg, 0, [th])
   870 end;
   871 
   872 
   873 
   874 (** variations on instantiate **)
   875 
   876 (* instantiate by left-to-right occurrence of variables *)
   877 
   878 fun instantiate' cTs cts thm =
   879   let
   880     fun err msg =
   881       raise TYPE ("instantiate': " ^ msg,
   882         map_filter (Option.map Thm.typ_of) cTs,
   883         map_filter (Option.map Thm.term_of) cts);
   884 
   885     fun inst_of (v, ct) =
   886       (Thm.cterm_of (Thm.theory_of_cterm ct) (Var v), ct)
   887         handle TYPE (msg, _, _) => err msg;
   888 
   889     fun tyinst_of (v, cT) =
   890       (Thm.ctyp_of (Thm.theory_of_ctyp cT) (TVar v), cT)
   891         handle TYPE (msg, _, _) => err msg;
   892 
   893     fun zip_vars xs ys =
   894       zip_options xs ys handle Library.UnequalLengths =>
   895         err "more instantiations than variables in thm";
   896 
   897     (*instantiate types first!*)
   898     val thm' =
   899       if forall is_none cTs then thm
   900       else Thm.instantiate
   901         (map tyinst_of (zip_vars (rev (Thm.fold_terms Term.add_tvars thm [])) cTs), []) thm;
   902     val thm'' =
   903       if forall is_none cts then thm'
   904       else Thm.instantiate
   905         ([], map inst_of (zip_vars (rev (Thm.fold_terms Term.add_vars thm' [])) cts)) thm';
   906     in thm'' end;
   907 
   908 
   909 
   910 (** renaming of bound variables **)
   911 
   912 (* replace bound variables x_i in thm by y_i *)
   913 (* where vs = [(x_1, y_1), ..., (x_n, y_n)]  *)
   914 
   915 fun rename_bvars [] thm = thm
   916   | rename_bvars vs thm =
   917       let
   918         val cert = Thm.cterm_of (Thm.theory_of_thm thm);
   919         fun ren (Abs (x, T, t)) = Abs (AList.lookup (op =) vs x |> the_default x, T, ren t)
   920           | ren (t $ u) = ren t $ ren u
   921           | ren t = t;
   922       in equal_elim (reflexive (cert (ren (Thm.prop_of thm)))) thm end;
   923 
   924 
   925 (* renaming in left-to-right order *)
   926 
   927 fun rename_bvars' xs thm =
   928   let
   929     val cert = Thm.cterm_of (Thm.theory_of_thm thm);
   930     val prop = Thm.prop_of thm;
   931     fun rename [] t = ([], t)
   932       | rename (x' :: xs) (Abs (x, T, t)) =
   933           let val (xs', t') = rename xs t
   934           in (xs', Abs (the_default x x', T, t')) end
   935       | rename xs (t $ u) =
   936           let
   937             val (xs', t') = rename xs t;
   938             val (xs'', u') = rename xs' u
   939           in (xs'', t' $ u') end
   940       | rename xs t = (xs, t);
   941   in case rename xs prop of
   942       ([], prop') => equal_elim (reflexive (cert prop')) thm
   943     | _ => error "More names than abstractions in theorem"
   944   end;
   945 
   946 
   947 
   948 (** multi_resolve **)
   949 
   950 local
   951 
   952 fun res th i rule =
   953   Thm.biresolution false [(false, th)] i rule handle THM _ => Seq.empty;
   954 
   955 fun multi_res _ [] rule = Seq.single rule
   956   | multi_res i (th :: ths) rule = Seq.maps (res th i) (multi_res (i + 1) ths rule);
   957 
   958 in
   959 
   960 val multi_resolve = multi_res 1;
   961 fun multi_resolves facts rules = Seq.maps (multi_resolve facts) (Seq.of_list rules);
   962 
   963 end;
   964 
   965 end;
   966 
   967 structure BasicDrule: BASIC_DRULE = Drule;
   968 open BasicDrule;