src/Tools/Code/code_target.ML
author haftmann
Fri Jul 16 15:55:32 2010 +0200 (2010-07-16)
changeset 37876 48116a1764c5
parent 37844 f26becedaeb1
child 37881 096c8397c989
permissions -rw-r--r--
consolidate const_syntax naming
     1 (*  Title:      Tools/Code/code_target.ML
     2     Author:     Florian Haftmann, TU Muenchen
     3 
     4 Serializer from intermediate language ("Thin-gol") to target languages.
     5 *)
     6 
     7 signature CODE_TARGET =
     8 sig
     9   val cert_tyco: theory -> string -> string
    10   val read_tyco: theory -> string -> string
    11 
    12   type serializer
    13   type literals = Code_Printer.literals
    14   val add_target: string * { serializer: serializer, literals: literals,
    15     check: { env_var: string, make_destination: Path.T -> Path.T,
    16       make_command: string -> Path.T -> string -> string } } -> theory -> theory
    17   val extend_target: string *
    18       (string * (Code_Thingol.naming -> Code_Thingol.program -> Code_Thingol.program))
    19     -> theory -> theory
    20   val assert_target: theory -> string -> string
    21 
    22   type destination
    23   type serialization
    24   val parse_args: 'a parser -> Token.T list -> 'a
    25   val stmt_names_of_destination: destination -> string list
    26   val mk_serialization: string -> (Path.T option -> 'a -> unit)
    27     -> ('a -> string * string option list)
    28     -> 'a -> serialization
    29   val serialize: theory -> string -> int option -> string option -> Token.T list
    30     -> Code_Thingol.naming -> Code_Thingol.program -> string list -> serialization
    31   val serialize_custom: theory -> string * serializer
    32     -> Code_Thingol.naming -> Code_Thingol.program -> string list -> string * string option list
    33   val the_literals: theory -> string -> literals
    34   val export: serialization -> unit
    35   val file: Path.T -> serialization -> unit
    36   val string: string list -> serialization -> string
    37   val code_of: theory -> string -> int option -> string
    38     -> string list -> (Code_Thingol.naming -> string list) -> string
    39   val set_default_code_width: int -> theory -> theory
    40   val shell_command: string (*theory name*) -> string (*export_code expr*) -> unit
    41 
    42   val allow_abort: string -> theory -> theory
    43   type tyco_syntax = Code_Printer.tyco_syntax
    44   type const_syntax = Code_Printer.const_syntax
    45   val add_syntax_class: string -> class -> string option -> theory -> theory
    46   val add_syntax_inst: string -> class * string -> unit option -> theory -> theory
    47   val add_syntax_tyco: string -> string -> tyco_syntax option -> theory -> theory
    48   val add_syntax_const: string -> string -> const_syntax option -> theory -> theory
    49   val add_reserved: string -> string -> theory -> theory
    50   val add_include: string -> string * (string * string list) option -> theory -> theory
    51 end;
    52 
    53 structure Code_Target : CODE_TARGET =
    54 struct
    55 
    56 open Basic_Code_Thingol;
    57 
    58 type literals = Code_Printer.literals;
    59 type tyco_syntax = Code_Printer.tyco_syntax;
    60 type const_syntax = Code_Printer.const_syntax;
    61 
    62 
    63 (** basics **)
    64 
    65 datatype destination = Export | File of Path.T | String of string list;
    66 type serialization = destination -> (string * string option list) option;
    67 
    68 fun export f = (f Export; ());
    69 fun file p f = (f (File p); ());
    70 fun string stmts f = fst (the (f (String stmts)));
    71 
    72 fun stmt_names_of_destination (String stmts) = stmts
    73   | stmt_names_of_destination _ = [];
    74 
    75 fun mk_serialization target output _ code Export = (output NONE code ; NONE)
    76   | mk_serialization target output _ code (File file) = (output (SOME file) code; NONE)
    77   | mk_serialization target _ string code (String _) = SOME (string code);
    78 
    79 
    80 (** theory data **)
    81 
    82 datatype name_syntax_table = NameSyntaxTable of {
    83   class: string Symtab.table,
    84   instance: unit Symreltab.table,
    85   tyco: Code_Printer.tyco_syntax Symtab.table,
    86   const: Code_Printer.const_syntax Symtab.table
    87 };
    88 
    89 fun mk_name_syntax_table ((class, instance), (tyco, const)) =
    90   NameSyntaxTable { class = class, instance = instance, tyco = tyco, const = const };
    91 fun map_name_syntax_table f (NameSyntaxTable { class, instance, tyco, const }) =
    92   mk_name_syntax_table (f ((class, instance), (tyco, const)));
    93 fun merge_name_syntax_table (NameSyntaxTable { class = class1, instance = instance1, tyco = tyco1, const = const1 },
    94     NameSyntaxTable { class = class2, instance = instance2, tyco = tyco2, const = const2 }) =
    95   mk_name_syntax_table (
    96     (Symtab.join (K snd) (class1, class2),
    97        Symreltab.join (K snd) (instance1, instance2)),
    98     (Symtab.join (K snd) (tyco1, tyco2),
    99        Symtab.join (K snd) (const1, const2))
   100   );
   101 
   102 type serializer =
   103   string option                         (*module name*)
   104   -> Token.T list                       (*arguments*)
   105   -> (string -> string)                 (*labelled_name*)
   106   -> string list                        (*reserved symbols*)
   107   -> (string * Pretty.T) list           (*includes*)
   108   -> (string -> string option)          (*module aliasses*)
   109   -> (string -> string option)          (*class syntax*)
   110   -> (string -> Code_Printer.tyco_syntax option)
   111   -> (string -> Code_Printer.activated_const_syntax option)
   112   -> ((Pretty.T -> string) * (Pretty.T -> unit))
   113   -> Code_Thingol.program
   114   -> string list                        (*selected statements*)
   115   -> serialization;
   116 
   117 datatype description = Fundamental of { serializer: serializer, literals: Code_Printer.literals,
   118       check: { env_var: string, make_destination: Path.T -> Path.T,
   119         make_command: string -> Path.T -> string -> string } }
   120   | Extension of string * (Code_Thingol.naming -> Code_Thingol.program -> Code_Thingol.program);
   121 
   122 datatype target = Target of {
   123   serial: serial,
   124   description: description,
   125   reserved: string list,
   126   includes: (Pretty.T * string list) Symtab.table,
   127   name_syntax_table: name_syntax_table,
   128   module_alias: string Symtab.table
   129 };
   130 
   131 fun make_target ((serial, description), ((reserved, includes), (name_syntax_table, module_alias))) =
   132   Target { serial = serial, description = description, reserved = reserved, 
   133     includes = includes, name_syntax_table = name_syntax_table, module_alias = module_alias };
   134 fun map_target f ( Target { serial, description, reserved, includes, name_syntax_table, module_alias } ) =
   135   make_target (f ((serial, description), ((reserved, includes), (name_syntax_table, module_alias))));
   136 fun merge_target strict target (Target { serial = serial1, description = description,
   137   reserved = reserved1, includes = includes1,
   138   name_syntax_table = name_syntax_table1, module_alias = module_alias1 },
   139     Target { serial = serial2, description = _,
   140       reserved = reserved2, includes = includes2,
   141       name_syntax_table = name_syntax_table2, module_alias = module_alias2 }) =
   142   if serial1 = serial2 orelse not strict then
   143     make_target ((serial1, description),
   144       ((merge (op =) (reserved1, reserved2), Symtab.merge (K true) (includes1, includes2)),
   145         (merge_name_syntax_table (name_syntax_table1, name_syntax_table2),
   146           Symtab.join (K fst) (module_alias1, module_alias2))
   147     ))
   148   else
   149     error ("Incompatible targets: " ^ quote target);
   150 
   151 fun the_description (Target { description, ... }) = description;
   152 fun the_reserved (Target { reserved, ... }) = reserved;
   153 fun the_includes (Target { includes, ... }) = includes;
   154 fun the_name_syntax (Target { name_syntax_table = NameSyntaxTable x, ... }) = x;
   155 fun the_module_alias (Target { module_alias , ... }) = module_alias;
   156 
   157 structure Targets = Theory_Data
   158 (
   159   type T = (target Symtab.table * string list) * int;
   160   val empty = ((Symtab.empty, []), 80);
   161   val extend = I;
   162   fun merge (((target1, exc1), width1), ((target2, exc2), width2)) : T =
   163     ((Symtab.join (merge_target true) (target1, target2),
   164       Library.merge (op =) (exc1, exc2)), Int.max (width1, width2));
   165 );
   166 
   167 val abort_allowed = snd o fst o Targets.get;
   168 
   169 fun assert_target thy target = if Symtab.defined ((fst o fst) (Targets.get thy)) target
   170   then target
   171   else error ("Unknown code target language: " ^ quote target);
   172 
   173 fun put_target (target, seri) thy =
   174   let
   175     val lookup_target = Symtab.lookup ((fst o fst) (Targets.get thy));
   176     val _ = case seri
   177      of Extension (super, _) => if is_some (lookup_target super) then ()
   178           else error ("Unknown code target language: " ^ quote super)
   179       | _ => ();
   180     val overwriting = case (Option.map the_description o lookup_target) target
   181      of NONE => false
   182       | SOME (Extension _) => true
   183       | SOME (Fundamental _) => (case seri
   184          of Extension _ => error ("Will not overwrite existing target " ^ quote target)
   185           | _ => true);
   186     val _ = if overwriting
   187       then warning ("Overwriting existing target " ^ quote target)
   188       else (); 
   189   in
   190     thy
   191     |> (Targets.map o apfst o apfst o Symtab.update)
   192           (target, make_target ((serial (), seri), (([], Symtab.empty),
   193             (mk_name_syntax_table ((Symtab.empty, Symreltab.empty), (Symtab.empty, Symtab.empty)),
   194               Symtab.empty))))
   195   end;
   196 
   197 fun add_target (target, seri) = put_target (target, Fundamental seri);
   198 fun extend_target (target, (super, modify)) =
   199   put_target (target, Extension (super, modify));
   200 
   201 fun map_target_data target f thy =
   202   let
   203     val _ = assert_target thy target;
   204   in
   205     thy
   206     |> (Targets.map o apfst o apfst o Symtab.map_entry target o map_target) f
   207   end;
   208 
   209 fun map_reserved target =
   210   map_target_data target o apsnd o apfst o apfst;
   211 fun map_includes target =
   212   map_target_data target o apsnd o apfst o apsnd;
   213 fun map_name_syntax target =
   214   map_target_data target o apsnd o apsnd o apfst o map_name_syntax_table;
   215 fun map_module_alias target =
   216   map_target_data target o apsnd o apsnd o apsnd;
   217 
   218 fun set_default_code_width k = (Targets.map o apsnd) (K k);
   219 
   220 
   221 (** serializer usage **)
   222 
   223 (* montage *)
   224 
   225 fun the_fundamental thy =
   226   let
   227     val ((targets, _), _) = Targets.get thy;
   228     fun fundamental target = case Symtab.lookup targets target
   229      of SOME data => (case the_description data
   230          of Fundamental data => data
   231           | Extension (super, _) => fundamental super)
   232       | NONE => error ("Unknown code target language: " ^ quote target);
   233   in fundamental end;
   234 
   235 fun the_literals thy = #literals o the_fundamental thy;
   236 
   237 local
   238 
   239 fun activate_syntax lookup_name src_tab = Symtab.empty
   240   |> fold_map (fn thing_identifier => fn tab => case lookup_name thing_identifier
   241        of SOME name => (SOME name,
   242             Symtab.update_new (name, the (Symtab.lookup src_tab thing_identifier)) tab)
   243         | NONE => (NONE, tab)) (Symtab.keys src_tab)
   244   |>> map_filter I;
   245 
   246 fun activate_const_syntax thy literals src_tab naming = (Symtab.empty, naming)
   247   |> fold_map (fn thing_identifier => fn (tab, naming) =>
   248       case Code_Thingol.lookup_const naming thing_identifier
   249        of SOME name => let
   250               val (syn, naming') = Code_Printer.activate_const_syntax thy
   251                 literals (the (Symtab.lookup src_tab thing_identifier)) naming
   252             in (SOME name, (Symtab.update_new (name, syn) tab, naming')) end
   253         | NONE => (NONE, (tab, naming))) (Symtab.keys src_tab)
   254   |>> map_filter I;
   255 
   256 fun invoke_serializer thy abortable serializer literals reserved abs_includes 
   257     module_alias class instance tyco const module width args naming program2 names1 =
   258   let
   259     val (names_class, class') =
   260       activate_syntax (Code_Thingol.lookup_class naming) class;
   261     val names_inst = map_filter (Code_Thingol.lookup_instance naming)
   262       (Symreltab.keys instance);
   263     val (names_tyco, tyco') =
   264       activate_syntax (Code_Thingol.lookup_tyco naming) tyco;
   265     val (names_const, (const', _)) =
   266       activate_const_syntax thy literals const naming;
   267     val names_hidden = names_class @ names_inst @ names_tyco @ names_const;
   268     val names2 = subtract (op =) names_hidden names1;
   269     val program3 = Graph.subgraph (not o member (op =) names_hidden) program2;
   270     val names_all = Graph.all_succs program3 names2;
   271     val includes = abs_includes names_all;
   272     val program4 = Graph.subgraph (member (op =) names_all) program3;
   273     val empty_funs = filter_out (member (op =) abortable)
   274       (Code_Thingol.empty_funs program3);
   275     val _ = if null empty_funs then () else error ("No code equations for "
   276       ^ commas (map (Sign.extern_const thy) empty_funs));
   277   in
   278     serializer module args (Code_Thingol.labelled_name thy program2) reserved includes
   279       (Symtab.lookup module_alias) (Symtab.lookup class')
   280       (Symtab.lookup tyco') (Symtab.lookup const')
   281       (Code_Printer.string_of_pretty width, Code_Printer.writeln_pretty width)
   282       program4 names1
   283   end;
   284 
   285 fun mount_serializer thy alt_serializer target some_width module args naming program names =
   286   let
   287     val ((targets, abortable), default_width) = Targets.get thy;
   288     fun collapse_hierarchy target =
   289       let
   290         val data = case Symtab.lookup targets target
   291          of SOME data => data
   292           | NONE => error ("Unknown code target language: " ^ quote target);
   293       in case the_description data
   294        of Fundamental _ => (I, data)
   295         | Extension (super, modify) => let
   296             val (modify', data') = collapse_hierarchy super
   297           in (modify' #> modify naming, merge_target false target (data', data)) end
   298       end;
   299     val (modify, data) = collapse_hierarchy target;
   300     val serializer = the_default (case the_description data
   301      of Fundamental seri => #serializer seri) alt_serializer;
   302     val reserved = the_reserved data;
   303     fun select_include names_all (name, (content, cs)) =
   304       if null cs then SOME (name, content)
   305       else if exists (fn c => case Code_Thingol.lookup_const naming c
   306        of SOME name => member (op =) names_all name
   307         | NONE => false) cs
   308       then SOME (name, content) else NONE;
   309     fun includes names_all = map_filter (select_include names_all)
   310       ((Symtab.dest o the_includes) data);
   311     val module_alias = the_module_alias data;
   312     val { class, instance, tyco, const } = the_name_syntax data;
   313     val literals = the_literals thy target;
   314     val width = the_default default_width some_width;
   315   in
   316     invoke_serializer thy abortable serializer literals reserved
   317       includes module_alias class instance tyco const module width args naming (modify program) names
   318   end;
   319 
   320 in
   321 
   322 fun serialize thy = mount_serializer thy NONE;
   323 
   324 fun check thy names_cs naming program target strict args =
   325   let
   326     val module_name = "Code_Test";
   327     val { env_var, make_destination, make_command } =
   328       (#check o the_fundamental thy) target;
   329     val env_param = getenv env_var;
   330     fun ext_check env_param p =
   331       let 
   332         val destination = make_destination p;
   333         val _ = file destination (serialize thy target (SOME 80)
   334           (SOME module_name) args naming program names_cs);
   335         val cmd = make_command env_param destination module_name;
   336       in if bash ("cd " ^ File.shell_path p ^ " && " ^ cmd ^ " 2>&1") <> 0
   337         then error ("Code check failed for " ^ target ^ ": " ^ cmd)
   338         else ()
   339       end;
   340   in if env_param = ""
   341     then if strict
   342       then error (env_var ^ " not set; cannot check code for " ^ target)
   343       else warning (env_var ^ " not set; skipped checking code for " ^ target)
   344     else Cache_IO.with_tmp_dir "Code_Test" (ext_check env_param)
   345   end;
   346 
   347 fun serialize_custom thy (target_name, seri) naming program names =
   348   mount_serializer thy (SOME seri) target_name NONE NONE [] naming program names (String [])
   349   |> the;
   350 
   351 end; (* local *)
   352 
   353 
   354 (* code presentation *)
   355 
   356 fun code_of thy target some_width module_name cs names_stmt =
   357   let
   358     val (names_cs, (naming, program)) = Code_Thingol.consts_program thy false cs;
   359   in
   360     string (names_stmt naming)
   361       (serialize thy target some_width (SOME module_name) [] naming program names_cs)
   362   end;
   363 
   364 
   365 (* code generation *)
   366 
   367 fun transitivly_non_empty_funs thy naming program =
   368   let
   369     val cs = subtract (op =) (abort_allowed thy) (Code_Thingol.empty_funs program);
   370     val names = map_filter (Code_Thingol.lookup_const naming) cs;
   371   in subtract (op =) (Graph.all_preds program names) (Graph.keys program) end;
   372 
   373 fun read_const_exprs thy cs =
   374   let
   375     val (cs1, cs2) = Code_Thingol.read_const_exprs thy cs;
   376     val (names2, (naming, program)) = Code_Thingol.consts_program thy true cs2;
   377     val names3 = transitivly_non_empty_funs thy naming program;
   378     val cs3 = map_filter (fn (c, name) =>
   379       if member (op =) names3 name then SOME c else NONE) (cs2 ~~ names2);
   380   in union (op =) cs3 cs1 end;
   381 
   382 fun export_code thy cs seris =
   383   let
   384     val (names_cs, (naming, program)) = Code_Thingol.consts_program thy false cs;
   385     fun mk_seri_dest dest = if dest = "" orelse dest = "-" then export
   386       else file (Path.explode dest);
   387     val _ = map (fn (((target, module), dest), args) =>
   388       (mk_seri_dest dest (serialize thy target NONE module args naming program names_cs))) seris;
   389   in () end;
   390 
   391 fun export_code_cmd raw_cs seris thy = export_code thy (read_const_exprs thy raw_cs) seris;
   392 
   393 fun check_code thy cs seris =
   394   let
   395     val (names_cs, (naming, program)) = Code_Thingol.consts_program thy false cs;
   396     val _ = map (fn ((target, strict), args) => check thy names_cs naming program
   397       target strict args) seris;
   398   in () end;
   399 
   400 fun check_code_cmd raw_cs seris thy = check_code thy (read_const_exprs thy raw_cs) seris;
   401 
   402 
   403 (** serializer configuration **)
   404 
   405 (* data access *)
   406 
   407 fun cert_class thy class =
   408   let
   409     val _ = AxClass.get_info thy class;
   410   in class end;
   411 
   412 fun read_class thy = cert_class thy o Sign.intern_class thy;
   413 
   414 fun cert_tyco thy tyco =
   415   let
   416     val _ = if Sign.declared_tyname thy tyco then ()
   417       else error ("No such type constructor: " ^ quote tyco);
   418   in tyco end;
   419 
   420 fun read_tyco thy = cert_tyco thy o Sign.intern_type thy;
   421 
   422 fun cert_inst thy (class, tyco) =
   423   (cert_class thy class, cert_tyco thy tyco);
   424 
   425 fun read_inst thy (raw_tyco, raw_class) =
   426   (read_class thy raw_class, read_tyco thy raw_tyco);
   427 
   428 fun gen_add_syntax (mapp, upd, del) prep_x prep_syn target raw_x some_raw_syn thy =
   429   let
   430     val x = prep_x thy raw_x;
   431     val change = case some_raw_syn
   432      of SOME raw_syn => upd (x, prep_syn thy x raw_syn)
   433       | NONE => del x;
   434   in (map_name_syntax target o mapp) change thy end;
   435 
   436 fun gen_add_syntax_class prep_class =
   437   gen_add_syntax (apfst o apfst, Symtab.update, Symtab.delete_safe) prep_class ((K o K) I);
   438 
   439 fun gen_add_syntax_inst prep_inst =
   440   gen_add_syntax (apfst o apsnd, Symreltab.update, Symreltab.delete_safe) prep_inst ((K o K) I);
   441 
   442 fun gen_add_syntax_tyco prep_tyco =
   443   gen_add_syntax (apsnd o apfst, Symtab.update, Symtab.delete_safe) prep_tyco
   444     (fn thy => fn tyco => fn syn => if fst syn <> Sign.arity_number thy tyco
   445       then error ("Number of arguments mismatch in syntax for type constructor " ^ quote tyco)
   446       else syn);
   447 
   448 fun gen_add_syntax_const prep_const prep_syn =
   449   gen_add_syntax (apsnd o apsnd, Symtab.update, Symtab.delete_safe) prep_const
   450     (fn thy => fn c => fn raw_syn => let val syn = prep_syn raw_syn in
   451       if fst syn > Code.args_number thy c
   452       then error ("Too many arguments in syntax for constant " ^ quote c)
   453       else syn end);
   454 
   455 fun add_reserved target =
   456   let
   457     fun add sym syms = if member (op =) syms sym
   458       then error ("Reserved symbol " ^ quote sym ^ " already declared")
   459       else insert (op =) sym syms
   460   in map_reserved target o add end;
   461 
   462 fun gen_add_include read_const target args thy =
   463   let
   464     fun add (name, SOME (content, raw_cs)) incls =
   465           let
   466             val _ = if Symtab.defined incls name
   467               then warning ("Overwriting existing include " ^ name)
   468               else ();
   469             val cs = map (read_const thy) raw_cs;
   470           in Symtab.update (name, (Code_Printer.str content, cs)) incls end
   471       | add (name, NONE) incls = Symtab.delete name incls;
   472   in map_includes target (add args) thy end;
   473 
   474 val add_include = gen_add_include (K I);
   475 val add_include_cmd = gen_add_include Code.read_const;
   476 
   477 fun add_module_alias target (thyname, modlname) =
   478   let
   479     val xs = Long_Name.explode modlname;
   480     val xs' = map (Name.desymbolize true) xs;
   481   in if xs' = xs
   482     then map_module_alias target (Symtab.update (thyname, modlname))
   483     else error ("Invalid module name: " ^ quote modlname ^ "\n"
   484       ^ "perhaps try " ^ quote (Long_Name.implode xs'))
   485   end;
   486 
   487 fun gen_allow_abort prep_const raw_c thy =
   488   let
   489     val c = prep_const thy raw_c;
   490   in thy |> (Targets.map o apfst o apsnd) (insert (op =) c) end;
   491 
   492 
   493 (* concrete syntax *)
   494 
   495 local
   496 
   497 fun zip_list (x::xs) f g =
   498   f
   499   #-> (fn y =>
   500     fold_map (fn x => g |-- f >> pair x) xs
   501     #-> (fn xys => pair ((x, y) :: xys)));
   502 
   503 fun parse_multi_syntax parse_thing parse_syntax =
   504   Parse.and_list1 parse_thing
   505   #-> (fn things => Scan.repeat1 (Parse.$$$ "(" |-- Parse.name --
   506         (zip_list things parse_syntax (Parse.$$$ "and")) --| Parse.$$$ ")"));
   507 
   508 in
   509 
   510 val add_syntax_class = gen_add_syntax_class cert_class;
   511 val add_syntax_inst = gen_add_syntax_inst cert_inst;
   512 val add_syntax_tyco = gen_add_syntax_tyco cert_tyco;
   513 val add_syntax_const_simple = gen_add_syntax_const (K I) Code_Printer.simple_const_syntax;
   514 val add_syntax_const = gen_add_syntax_const (K I) I;
   515 val allow_abort = gen_allow_abort (K I);
   516 val add_reserved = add_reserved;
   517 val add_include = add_include;
   518 
   519 val add_syntax_class_cmd = gen_add_syntax_class read_class;
   520 val add_syntax_inst_cmd = gen_add_syntax_inst read_inst;
   521 val add_syntax_tyco_cmd = gen_add_syntax_tyco read_tyco;
   522 val add_syntax_const_simple_cmd = gen_add_syntax_const Code.read_const Code_Printer.simple_const_syntax;
   523 val add_syntax_const_cmd = gen_add_syntax_const Code.read_const I;
   524 
   525 val allow_abort_cmd = gen_allow_abort Code.read_const;
   526 
   527 fun parse_args f args =
   528   case Scan.read Token.stopper f args
   529    of SOME x => x
   530     | NONE => error "Bad serializer arguments";
   531 
   532 
   533 (** Isar setup **)
   534 
   535 val (inK, module_nameK, fileK, checkingK) = ("in", "module_name", "file", "checking");
   536 
   537 val code_expr_argsP = Scan.optional (Parse.$$$ "(" |-- Args.parse --| Parse.$$$ ")") [];
   538 
   539 val code_exprP =
   540   Scan.repeat1 Parse.term_group :|-- (fn raw_cs =>
   541     ((Parse.$$$ checkingK |-- Scan.repeat (Parse.name
   542       -- ((Parse.$$$ "?" |-- Scan.succeed false) || Scan.succeed true) -- code_expr_argsP))
   543       >> (fn seris => check_code_cmd raw_cs seris)
   544     || Scan.repeat (Parse.$$$ inK |-- Parse.name
   545        -- Scan.option (Parse.$$$ module_nameK |-- Parse.name)
   546        -- Scan.optional (Parse.$$$ fileK |-- Parse.name) ""
   547        -- code_expr_argsP) >> (fn seris => export_code_cmd raw_cs seris)));
   548 
   549 val _ = List.app Keyword.keyword [inK, module_nameK, fileK, checkingK];
   550 
   551 val _ =
   552   Outer_Syntax.command "code_class" "define code syntax for class" Keyword.thy_decl (
   553     parse_multi_syntax Parse.xname (Scan.option Parse.string)
   554     >> (Toplevel.theory oo fold) (fn (target, syns) =>
   555           fold (fn (raw_class, syn) => add_syntax_class_cmd target raw_class syn) syns)
   556   );
   557 
   558 val _ =
   559   Outer_Syntax.command "code_instance" "define code syntax for instance" Keyword.thy_decl (
   560     parse_multi_syntax (Parse.xname --| Parse.$$$ "::" -- Parse.xname)
   561       (Scan.option (Parse.minus >> K ()))
   562     >> (Toplevel.theory oo fold) (fn (target, syns) =>
   563           fold (fn (raw_inst, add_del) => add_syntax_inst_cmd target raw_inst add_del) syns)
   564   );
   565 
   566 val _ =
   567   Outer_Syntax.command "code_type" "define code syntax for type constructor" Keyword.thy_decl (
   568     parse_multi_syntax Parse.xname (Code_Printer.parse_syntax I)
   569     >> (Toplevel.theory oo fold) (fn (target, syns) =>
   570           fold (fn (raw_tyco, syn) => add_syntax_tyco_cmd target raw_tyco syn) syns)
   571   );
   572 
   573 val _ =
   574   Outer_Syntax.command "code_const" "define code syntax for constant" Keyword.thy_decl (
   575     parse_multi_syntax Parse.term_group (Code_Printer.parse_syntax fst)
   576     >> (Toplevel.theory oo fold) (fn (target, syns) =>
   577       fold (fn (raw_const, syn) => add_syntax_const_simple_cmd target raw_const syn) syns)
   578   );
   579 
   580 val _ =
   581   Outer_Syntax.command "code_reserved" "declare words as reserved for target language"
   582     Keyword.thy_decl (
   583     Parse.name -- Scan.repeat1 Parse.name
   584     >> (fn (target, reserveds) => (Toplevel.theory o fold (add_reserved target)) reserveds)
   585   );
   586 
   587 val _ =
   588   Outer_Syntax.command "code_include" "declare piece of code to be included in generated code"
   589     Keyword.thy_decl (
   590     Parse.name -- Parse.name -- (Parse.text :|-- (fn "-" => Scan.succeed NONE
   591       | s => Scan.optional (Parse.$$$ "attach" |-- Scan.repeat1 Parse.term) [] >> pair s >> SOME))
   592     >> (fn ((target, name), content_consts) =>
   593         (Toplevel.theory o add_include_cmd target) (name, content_consts))
   594   );
   595 
   596 val _ =
   597   Outer_Syntax.command "code_modulename" "alias module to other name" Keyword.thy_decl (
   598     Parse.name -- Scan.repeat1 (Parse.name -- Parse.name)
   599     >> (fn (target, modlnames) => (Toplevel.theory o fold (add_module_alias target)) modlnames)
   600   );
   601 
   602 val _ =
   603   Outer_Syntax.command "code_abort" "permit constant to be implemented as program abort"
   604     Keyword.thy_decl (
   605     Scan.repeat1 Parse.term_group >> (Toplevel.theory o fold allow_abort_cmd)
   606   );
   607 
   608 val _ =
   609   Outer_Syntax.command "export_code" "generate executable code for constants"
   610     Keyword.diag (Parse.!!! code_exprP >> (fn f => Toplevel.keep (f o Toplevel.theory_of)));
   611 
   612 fun shell_command thyname cmd = Toplevel.program (fn _ =>
   613   (use_thy thyname; case Scan.read Token.stopper (Parse.!!! code_exprP)
   614     ((filter Token.is_proper o Outer_Syntax.scan Position.none) cmd)
   615    of SOME f => (writeln "Now generating code..."; f (theory thyname))
   616     | NONE => error ("Bad directive " ^ quote cmd)))
   617   handle Runtime.TOPLEVEL_ERROR => OS.Process.exit OS.Process.failure;
   618 
   619 end; (*local*)
   620 
   621 end; (*struct*)