src/Tools/Code/code_target.ML
author haftmann
Mon Aug 30 17:20:33 2010 +0200 (2010-08-30)
changeset 38918 48d62f237944
parent 38917 c7da3cc88135
child 38921 15f8cffdbf5d
permissions -rw-r--r--
tuned
     1 (*  Title:      Tools/Code/code_target.ML
     2     Author:     Florian Haftmann, TU Muenchen
     3 
     4 Generic infrastructure for target language data.
     5 *)
     6 
     7 signature CODE_TARGET =
     8 sig
     9   val cert_tyco: theory -> string -> string
    10   val read_tyco: theory -> string -> string
    11 
    12   val export_code_for: theory -> Path.T option -> string -> int option -> string option -> Token.T list
    13     -> Code_Thingol.naming -> Code_Thingol.program -> string list -> unit
    14   val produce_code_for: theory -> string -> int option -> string option -> Token.T list
    15     -> Code_Thingol.naming -> Code_Thingol.program -> string list * string list -> string * string option list
    16   val check_code_for: theory -> string -> bool -> Token.T list
    17     -> Code_Thingol.naming -> Code_Thingol.program -> string list -> unit
    18 
    19   val export_code: theory -> string list
    20     -> (((string * string option) * Path.T option) * Token.T list) list -> unit
    21   val produce_code: theory -> string list -> (Code_Thingol.naming -> string list)
    22     -> string -> int option -> string option -> Token.T list -> string * string option list
    23   val check_code: theory -> string list
    24     -> ((string * bool) * Token.T list) list -> unit
    25 
    26   val shell_command: string (*theory name*) -> string (*export_code expr*) -> unit
    27 
    28   type serializer
    29   type literals = Code_Printer.literals
    30   val add_target: string * { serializer: serializer, literals: literals,
    31     check: { env_var: string, make_destination: Path.T -> Path.T,
    32       make_command: string -> string -> string } } -> theory -> theory
    33   val extend_target: string *
    34       (string * (Code_Thingol.naming -> Code_Thingol.program -> Code_Thingol.program))
    35     -> theory -> theory
    36   val assert_target: theory -> string -> string
    37   val the_literals: theory -> string -> literals
    38   type serialization
    39   val parse_args: 'a parser -> Token.T list -> 'a
    40   val serialization: (int -> Path.T option -> 'a -> unit)
    41     -> (int -> 'a -> string * string option list)
    42     -> 'a -> int -> serialization
    43   val set_default_code_width: int -> theory -> theory
    44 
    45   (*FIXME drop asap*)
    46   val code_of: theory -> string -> int option -> string
    47     -> string list -> (Code_Thingol.naming -> string list) -> string * string option list
    48   val serialize_custom: theory -> string * serializer -> string option
    49     -> Code_Thingol.naming -> Code_Thingol.program -> string list -> string * string option list
    50 
    51   val allow_abort: string -> theory -> theory
    52   type tyco_syntax = Code_Printer.tyco_syntax
    53   type const_syntax = Code_Printer.const_syntax
    54   val add_syntax_class: string -> class -> string option -> theory -> theory
    55   val add_syntax_inst: string -> class * string -> unit option -> theory -> theory
    56   val add_syntax_tyco: string -> string -> tyco_syntax option -> theory -> theory
    57   val add_syntax_const: string -> string -> const_syntax option -> theory -> theory
    58   val add_reserved: string -> string -> theory -> theory
    59   val add_include: string -> string * (string * string list) option -> theory -> theory
    60 end;
    61 
    62 structure Code_Target : CODE_TARGET =
    63 struct
    64 
    65 open Basic_Code_Thingol;
    66 
    67 type literals = Code_Printer.literals;
    68 type tyco_syntax = Code_Printer.tyco_syntax;
    69 type const_syntax = Code_Printer.const_syntax;
    70 
    71 
    72 (** basics **)
    73 
    74 datatype destination = File of Path.T option | String of string list;
    75 type serialization = destination -> (string * string option list) option;
    76 
    77 fun stmt_names_of_destination (String stmt_names) = stmt_names
    78   | stmt_names_of_destination _ = [];
    79 
    80 fun serialization output _ pretty width (File some_path) = (output width some_path pretty; NONE)
    81   | serialization _ string pretty width (String _) = SOME (string width pretty);
    82 
    83 fun file some_path f = (f (File some_path); ());
    84 fun string stmt_names f = the (f (String stmt_names));
    85 
    86 
    87 (** theory data **)
    88 
    89 datatype name_syntax_table = NameSyntaxTable of {
    90   class: string Symtab.table,
    91   instance: unit Symreltab.table,
    92   tyco: Code_Printer.tyco_syntax Symtab.table,
    93   const: Code_Printer.const_syntax Symtab.table
    94 };
    95 
    96 fun mk_name_syntax_table ((class, instance), (tyco, const)) =
    97   NameSyntaxTable { class = class, instance = instance, tyco = tyco, const = const };
    98 fun map_name_syntax_table f (NameSyntaxTable { class, instance, tyco, const }) =
    99   mk_name_syntax_table (f ((class, instance), (tyco, const)));
   100 fun merge_name_syntax_table
   101   (NameSyntaxTable { class = class1, instance = instance1, tyco = tyco1, const = const1 },
   102     NameSyntaxTable { class = class2, instance = instance2, tyco = tyco2, const = const2 }) =
   103   mk_name_syntax_table (
   104     (Symtab.join (K snd) (class1, class2),
   105        Symreltab.join (K snd) (instance1, instance2)),
   106     (Symtab.join (K snd) (tyco1, tyco2),
   107        Symtab.join (K snd) (const1, const2))
   108   );
   109 
   110 type serializer =
   111   string option                         (*module name*)
   112   -> Token.T list                       (*arguments*)
   113   -> (string -> string)                 (*labelled_name*)
   114   -> string list                        (*reserved symbols*)
   115   -> (string * Pretty.T) list           (*includes*)
   116   -> (string -> string option)          (*module aliasses*)
   117   -> (string -> string option)          (*class syntax*)
   118   -> (string -> Code_Printer.tyco_syntax option)
   119   -> (string -> Code_Printer.activated_const_syntax option)
   120   -> Code_Thingol.program
   121   -> (string list * string list)        (*selected statements*)
   122   -> int
   123   -> serialization;
   124 
   125 datatype description = Fundamental of { serializer: serializer,
   126       literals: literals,
   127       check: { env_var: string, make_destination: Path.T -> Path.T,
   128         make_command: string -> string -> string } }
   129   | Extension of string *
   130       (Code_Thingol.naming -> Code_Thingol.program -> Code_Thingol.program);
   131 
   132 datatype target = Target of {
   133   serial: serial,
   134   description: description,
   135   reserved: string list,
   136   includes: (Pretty.T * string list) Symtab.table,
   137   name_syntax_table: name_syntax_table,
   138   module_alias: string Symtab.table
   139 };
   140 
   141 fun make_target ((serial, description), ((reserved, includes), (name_syntax_table, module_alias))) =
   142   Target { serial = serial, description = description, reserved = reserved, 
   143     includes = includes, name_syntax_table = name_syntax_table, module_alias = module_alias };
   144 fun map_target f ( Target { serial, description, reserved, includes, name_syntax_table, module_alias } ) =
   145   make_target (f ((serial, description), ((reserved, includes), (name_syntax_table, module_alias))));
   146 fun merge_target strict target (Target { serial = serial1, description = description,
   147   reserved = reserved1, includes = includes1,
   148   name_syntax_table = name_syntax_table1, module_alias = module_alias1 },
   149     Target { serial = serial2, description = _,
   150       reserved = reserved2, includes = includes2,
   151       name_syntax_table = name_syntax_table2, module_alias = module_alias2 }) =
   152   if serial1 = serial2 orelse not strict then
   153     make_target ((serial1, description),
   154       ((merge (op =) (reserved1, reserved2), Symtab.join (K snd) (includes1, includes2)),
   155         (merge_name_syntax_table (name_syntax_table1, name_syntax_table2),
   156           Symtab.join (K snd) (module_alias1, module_alias2))
   157     ))
   158   else
   159     error ("Incompatible targets: " ^ quote target);
   160 
   161 fun the_description (Target { description, ... }) = description;
   162 fun the_reserved (Target { reserved, ... }) = reserved;
   163 fun the_includes (Target { includes, ... }) = includes;
   164 fun the_name_syntax (Target { name_syntax_table = NameSyntaxTable x, ... }) = x;
   165 fun the_module_alias (Target { module_alias , ... }) = module_alias;
   166 
   167 structure Targets = Theory_Data
   168 (
   169   type T = (target Symtab.table * string list) * int;
   170   val empty = ((Symtab.empty, []), 80);
   171   val extend = I;
   172   fun merge (((target1, exc1), width1), ((target2, exc2), width2)) : T =
   173     ((Symtab.join (merge_target true) (target1, target2),
   174       Library.merge (op =) (exc1, exc2)), Int.max (width1, width2));
   175 );
   176 
   177 val abort_allowed = snd o fst o Targets.get;
   178 
   179 fun assert_target thy target = if Symtab.defined ((fst o fst) (Targets.get thy)) target
   180   then target
   181   else error ("Unknown code target language: " ^ quote target);
   182 
   183 fun put_target (target, seri) thy =
   184   let
   185     val lookup_target = Symtab.lookup ((fst o fst) (Targets.get thy));
   186     val _ = case seri
   187      of Extension (super, _) => if is_some (lookup_target super) then ()
   188           else error ("Unknown code target language: " ^ quote super)
   189       | _ => ();
   190     val overwriting = case (Option.map the_description o lookup_target) target
   191      of NONE => false
   192       | SOME (Extension _) => true
   193       | SOME (Fundamental _) => (case seri
   194          of Extension _ => error ("Will not overwrite existing target " ^ quote target)
   195           | _ => true);
   196     val _ = if overwriting
   197       then warning ("Overwriting existing target " ^ quote target)
   198       else (); 
   199   in
   200     thy
   201     |> (Targets.map o apfst o apfst o Symtab.update)
   202           (target, make_target ((serial (), seri), (([], Symtab.empty),
   203             (mk_name_syntax_table ((Symtab.empty, Symreltab.empty),
   204               (Symtab.empty, Symtab.empty)), Symtab.empty))))
   205   end;
   206 
   207 fun add_target (target, seri) = put_target (target, Fundamental seri);
   208 fun extend_target (target, (super, modify)) =
   209   put_target (target, Extension (super, modify));
   210 
   211 fun map_target_data target f thy =
   212   let
   213     val _ = assert_target thy target;
   214   in
   215     thy
   216     |> (Targets.map o apfst o apfst o Symtab.map_entry target o map_target) f
   217   end;
   218 
   219 fun map_reserved target =
   220   map_target_data target o apsnd o apfst o apfst;
   221 fun map_includes target =
   222   map_target_data target o apsnd o apfst o apsnd;
   223 fun map_name_syntax target =
   224   map_target_data target o apsnd o apsnd o apfst o map_name_syntax_table;
   225 fun map_module_alias target =
   226   map_target_data target o apsnd o apsnd o apsnd;
   227 
   228 fun set_default_code_width k = (Targets.map o apsnd) (K k);
   229 
   230 
   231 (** serializer usage **)
   232 
   233 (* montage *)
   234 
   235 fun the_fundamental thy =
   236   let
   237     val ((targets, _), _) = Targets.get thy;
   238     fun fundamental target = case Symtab.lookup targets target
   239      of SOME data => (case the_description data
   240          of Fundamental data => data
   241           | Extension (super, _) => fundamental super)
   242       | NONE => error ("Unknown code target language: " ^ quote target);
   243   in fundamental end;
   244 
   245 fun the_literals thy = #literals o the_fundamental thy;
   246 
   247 local
   248 
   249 fun activate_syntax lookup_name src_tab = Symtab.empty
   250   |> fold_map (fn thing_identifier => fn tab => case lookup_name thing_identifier
   251        of SOME name => (SOME name,
   252             Symtab.update_new (name, the (Symtab.lookup src_tab thing_identifier)) tab)
   253         | NONE => (NONE, tab)) (Symtab.keys src_tab)
   254   |>> map_filter I;
   255 
   256 fun activate_const_syntax thy literals src_tab naming = (Symtab.empty, naming)
   257   |> fold_map (fn c => fn (tab, naming) =>
   258       case Code_Thingol.lookup_const naming c
   259        of SOME name => let
   260               val (syn, naming') = Code_Printer.activate_const_syntax thy
   261                 literals c (the (Symtab.lookup src_tab c)) naming
   262             in (SOME name, (Symtab.update_new (name, syn) tab, naming')) end
   263         | NONE => (NONE, (tab, naming))) (Symtab.keys src_tab)
   264   |>> map_filter I;
   265 
   266 fun invoke_serializer thy abortable serializer literals reserved abs_includes 
   267     module_alias class instance tyco const module_name args naming program2 (names1, presentation_names) width =
   268   let
   269     val (names_class, class') =
   270       activate_syntax (Code_Thingol.lookup_class naming) class;
   271     val names_inst = map_filter (Code_Thingol.lookup_instance naming)
   272       (Symreltab.keys instance);
   273     val (names_tyco, tyco') =
   274       activate_syntax (Code_Thingol.lookup_tyco naming) tyco;
   275     val (names_const, (const', _)) =
   276       activate_const_syntax thy literals const naming;
   277     val names_hidden = names_class @ names_inst @ names_tyco @ names_const;
   278     val names2 = subtract (op =) names_hidden names1;
   279     val program3 = Graph.subgraph (not o member (op =) names_hidden) program2;
   280     val names_all = Graph.all_succs program3 names2;
   281     val includes = abs_includes names_all;
   282     val program4 = Graph.subgraph (member (op =) names_all) program3;
   283     val empty_funs = filter_out (member (op =) abortable)
   284       (Code_Thingol.empty_funs program3);
   285     val _ = if null empty_funs then () else error ("No code equations for "
   286       ^ commas (map (Sign.extern_const thy) empty_funs));
   287   in
   288     serializer module_name args (Code_Thingol.labelled_name thy program2) reserved includes
   289       (if is_some module_name then K module_name else Symtab.lookup module_alias)
   290       (Symtab.lookup class') (Symtab.lookup tyco') (Symtab.lookup const')
   291       program4 (names1, presentation_names) width
   292   end;
   293 
   294 fun mount_serializer thy alt_serializer target some_width raw_module_name args naming program names destination =
   295   let
   296     val ((targets, abortable), default_width) = Targets.get thy;
   297     fun collapse_hierarchy target =
   298       let
   299         val data = case Symtab.lookup targets target
   300          of SOME data => data
   301           | NONE => error ("Unknown code target language: " ^ quote target);
   302       in case the_description data
   303        of Fundamental _ => (I, data)
   304         | Extension (super, modify) => let
   305             val (modify', data') = collapse_hierarchy super
   306           in (modify' #> modify naming, merge_target false target (data', data)) end
   307       end;
   308     val (modify, data) = collapse_hierarchy target;
   309     val serializer = the_default (case the_description data
   310      of Fundamental seri => #serializer seri) alt_serializer;
   311     val presentation_names = stmt_names_of_destination destination;
   312     val module_name = if null presentation_names
   313       then raw_module_name else SOME "Code";
   314     val reserved = the_reserved data;
   315     fun select_include names_all (name, (content, cs)) =
   316       if null cs then SOME (name, content)
   317       else if exists (fn c => case Code_Thingol.lookup_const naming c
   318        of SOME name => member (op =) names_all name
   319         | NONE => false) cs
   320       then SOME (name, content) else NONE;
   321     fun includes names_all = map_filter (select_include names_all)
   322       ((Symtab.dest o the_includes) data);
   323     val module_alias = the_module_alias data 
   324     val { class, instance, tyco, const } = the_name_syntax data;
   325     val literals = the_literals thy target;
   326     val width = the_default default_width some_width;
   327   in
   328     invoke_serializer thy abortable serializer literals reserved
   329       includes module_alias class instance tyco const module_name args
   330         naming (modify program) (names, presentation_names) width destination
   331   end;
   332 
   333 in
   334 
   335 fun serialize thy = mount_serializer thy NONE;
   336 
   337 fun export_code_for thy some_path target some_width some_module_name args naming program names =
   338   file some_path (serialize thy target some_width some_module_name args naming program names);
   339 
   340 fun produce_code_for thy target some_width some_module_name args naming program (names, selects) =
   341   string selects (serialize thy target some_width some_module_name args naming program names);
   342 
   343 fun check_code_for thy target strict args naming program names_cs =
   344   let
   345     val module_name = "Code_Test";
   346     val { env_var, make_destination, make_command } =
   347       (#check o the_fundamental thy) target;
   348     val env_param = getenv env_var;
   349     fun ext_check env_param p =
   350       let 
   351         val destination = make_destination p;
   352         val _ = file (SOME destination) (serialize thy target (SOME 80)
   353           (SOME module_name) args naming program names_cs);
   354         val cmd = make_command env_param module_name;
   355       in if bash ("cd " ^ File.shell_path p ^ " && " ^ cmd ^ " 2>&1") <> 0
   356         then error ("Code check failed for " ^ target ^ ": " ^ cmd)
   357         else ()
   358       end;
   359   in if env_param = ""
   360     then if strict
   361       then error (env_var ^ " not set; cannot check code for " ^ target)
   362       else warning (env_var ^ " not set; skipped checking code for " ^ target)
   363     else Cache_IO.with_tmp_dir "Code_Test" (ext_check env_param)
   364   end;
   365 
   366 fun serialize_custom thy (target_name, seri) module_name naming program names =
   367   mount_serializer thy (SOME seri) target_name NONE module_name [] naming program names (String [])
   368   |> the;
   369 
   370 end; (* local *)
   371 
   372 
   373 (* code presentation *)
   374 
   375 fun code_of thy target some_width module_name cs names_stmt =
   376   let
   377     val (names_cs, (naming, program)) = Code_Thingol.consts_program thy false cs;
   378   in
   379     string (names_stmt naming)
   380       (serialize thy target some_width (SOME module_name) [] naming program names_cs)
   381   end;
   382 
   383 
   384 (* code generation *)
   385 
   386 fun transitivly_non_empty_funs thy naming program =
   387   let
   388     val cs = subtract (op =) (abort_allowed thy) (Code_Thingol.empty_funs program);
   389     val names = map_filter (Code_Thingol.lookup_const naming) cs;
   390   in subtract (op =) (Graph.all_preds program names) (Graph.keys program) end;
   391 
   392 fun read_const_exprs thy cs =
   393   let
   394     val (cs1, cs2) = Code_Thingol.read_const_exprs thy cs;
   395     val (names2, (naming, program)) = Code_Thingol.consts_program thy true cs2;
   396     val names3 = transitivly_non_empty_funs thy naming program;
   397     val cs3 = map_filter (fn (c, name) =>
   398       if member (op =) names3 name then SOME c else NONE) (cs2 ~~ names2);
   399   in union (op =) cs3 cs1 end;
   400 
   401 fun prep_destination "" = NONE
   402   | prep_destination "-" = NONE
   403   | prep_destination s = SOME (Path.explode s);
   404 
   405 fun export_code thy cs seris =
   406   let
   407     val (names_cs, (naming, program)) = Code_Thingol.consts_program thy false cs;
   408     val _ = map (fn (((target, module_name), some_path), args) =>
   409       export_code_for thy some_path target NONE module_name args naming program names_cs) seris;
   410   in () end;
   411 
   412 fun export_code_cmd raw_cs seris thy = export_code thy (read_const_exprs thy raw_cs)
   413   ((map o apfst o apsnd) prep_destination seris);
   414 
   415 fun produce_code thy cs names_stmt target some_width some_module_name args =
   416   let
   417     val (names_cs, (naming, program)) = Code_Thingol.consts_program thy false cs;
   418   in produce_code_for thy target some_width some_module_name args naming program (names_cs, names_stmt naming) end;
   419 
   420 fun check_code thy cs seris =
   421   let
   422     val (names_cs, (naming, program)) = Code_Thingol.consts_program thy false cs;
   423     val _ = map (fn ((target, strict), args) =>
   424       check_code_for thy target strict args naming program names_cs) seris;
   425   in () end;
   426 
   427 fun check_code_cmd raw_cs seris thy = check_code thy (read_const_exprs thy raw_cs) seris;
   428 
   429 
   430 (** serializer configuration **)
   431 
   432 (* data access *)
   433 
   434 fun cert_class thy class =
   435   let
   436     val _ = AxClass.get_info thy class;
   437   in class end;
   438 
   439 fun read_class thy = cert_class thy o Sign.intern_class thy;
   440 
   441 fun cert_tyco thy tyco =
   442   let
   443     val _ = if Sign.declared_tyname thy tyco then ()
   444       else error ("No such type constructor: " ^ quote tyco);
   445   in tyco end;
   446 
   447 fun read_tyco thy = cert_tyco thy o Sign.intern_type thy;
   448 
   449 fun cert_inst thy (class, tyco) =
   450   (cert_class thy class, cert_tyco thy tyco);
   451 
   452 fun read_inst thy (raw_tyco, raw_class) =
   453   (read_class thy raw_class, read_tyco thy raw_tyco);
   454 
   455 fun gen_add_syntax (mapp, upd, del) prep_x prep_syn target raw_x some_raw_syn thy =
   456   let
   457     val x = prep_x thy raw_x;
   458     val change = case some_raw_syn
   459      of SOME raw_syn => upd (x, prep_syn thy x raw_syn)
   460       | NONE => del x;
   461   in (map_name_syntax target o mapp) change thy end;
   462 
   463 fun gen_add_syntax_class prep_class =
   464   gen_add_syntax (apfst o apfst, Symtab.update, Symtab.delete_safe) prep_class ((K o K) I);
   465 
   466 fun gen_add_syntax_inst prep_inst =
   467   gen_add_syntax (apfst o apsnd, Symreltab.update, Symreltab.delete_safe) prep_inst ((K o K) I);
   468 
   469 fun gen_add_syntax_tyco prep_tyco =
   470   gen_add_syntax (apsnd o apfst, Symtab.update, Symtab.delete_safe) prep_tyco
   471     (fn thy => fn tyco => fn syn => if fst syn <> Sign.arity_number thy tyco
   472       then error ("Number of arguments mismatch in syntax for type constructor " ^ quote tyco)
   473       else syn);
   474 
   475 fun gen_add_syntax_const prep_const =
   476   gen_add_syntax (apsnd o apsnd, Symtab.update, Symtab.delete_safe) prep_const
   477     (fn thy => fn c => fn syn =>
   478       if Code_Printer.requires_args syn > Code.args_number thy c
   479       then error ("Too many arguments in syntax for constant " ^ quote c)
   480       else syn);
   481 
   482 fun add_reserved target =
   483   let
   484     fun add sym syms = if member (op =) syms sym
   485       then error ("Reserved symbol " ^ quote sym ^ " already declared")
   486       else insert (op =) sym syms
   487   in map_reserved target o add end;
   488 
   489 fun gen_add_include read_const target args thy =
   490   let
   491     fun add (name, SOME (content, raw_cs)) incls =
   492           let
   493             val _ = if Symtab.defined incls name
   494               then warning ("Overwriting existing include " ^ name)
   495               else ();
   496             val cs = map (read_const thy) raw_cs;
   497           in Symtab.update (name, (Code_Printer.str content, cs)) incls end
   498       | add (name, NONE) incls = Symtab.delete name incls;
   499   in map_includes target (add args) thy end;
   500 
   501 val add_include = gen_add_include (K I);
   502 val add_include_cmd = gen_add_include Code.read_const;
   503 
   504 fun add_module_alias target (thyname, modlname) =
   505   let
   506     val xs = Long_Name.explode modlname;
   507     val xs' = map (Name.desymbolize true) xs;
   508   in if xs' = xs
   509     then map_module_alias target (Symtab.update (thyname, modlname))
   510     else error ("Invalid module name: " ^ quote modlname ^ "\n"
   511       ^ "perhaps try " ^ quote (Long_Name.implode xs'))
   512   end;
   513 
   514 fun gen_allow_abort prep_const raw_c thy =
   515   let
   516     val c = prep_const thy raw_c;
   517   in thy |> (Targets.map o apfst o apsnd) (insert (op =) c) end;
   518 
   519 
   520 (* concrete syntax *)
   521 
   522 local
   523 
   524 fun zip_list (x::xs) f g =
   525   f
   526   :|-- (fn y =>
   527     fold_map (fn x => g |-- f >> pair x) xs
   528     :|-- (fn xys => pair ((x, y) :: xys)));
   529 
   530 fun process_multi_syntax parse_thing parse_syntax change =
   531   (Parse.and_list1 parse_thing
   532   :|-- (fn things => Scan.repeat1 (Parse.$$$ "(" |-- Parse.name --
   533         (zip_list things parse_syntax (Parse.$$$ "and")) --| Parse.$$$ ")")))
   534   >> (Toplevel.theory oo fold)
   535     (fn (target, syns) => fold (fn (raw_x, syn) => change target raw_x syn) syns);
   536 
   537 in
   538 
   539 val add_syntax_class = gen_add_syntax_class cert_class;
   540 val add_syntax_inst = gen_add_syntax_inst cert_inst;
   541 val add_syntax_tyco = gen_add_syntax_tyco cert_tyco;
   542 val add_syntax_const = gen_add_syntax_const (K I);
   543 val allow_abort = gen_allow_abort (K I);
   544 val add_reserved = add_reserved;
   545 val add_include = add_include;
   546 
   547 val add_syntax_class_cmd = gen_add_syntax_class read_class;
   548 val add_syntax_inst_cmd = gen_add_syntax_inst read_inst;
   549 val add_syntax_tyco_cmd = gen_add_syntax_tyco read_tyco;
   550 val add_syntax_const_cmd = gen_add_syntax_const Code.read_const;
   551 val allow_abort_cmd = gen_allow_abort Code.read_const;
   552 
   553 fun parse_args f args =
   554   case Scan.read Token.stopper f args
   555    of SOME x => x
   556     | NONE => error "Bad serializer arguments";
   557 
   558 
   559 (** Isar setup **)
   560 
   561 val (inK, module_nameK, fileK, checkingK) = ("in", "module_name", "file", "checking");
   562 
   563 val code_expr_argsP = Scan.optional (Parse.$$$ "(" |-- Args.parse --| Parse.$$$ ")") [];
   564 
   565 val code_exprP =
   566   Scan.repeat1 Parse.term_group :|-- (fn raw_cs =>
   567     ((Parse.$$$ checkingK |-- Scan.repeat (Parse.name
   568       -- ((Parse.$$$ "?" |-- Scan.succeed false) || Scan.succeed true) -- code_expr_argsP))
   569       >> (fn seris => check_code_cmd raw_cs seris)
   570     || Scan.repeat (Parse.$$$ inK |-- Parse.name
   571        -- Scan.option (Parse.$$$ module_nameK |-- Parse.name)
   572        -- Scan.optional (Parse.$$$ fileK |-- Parse.name) ""
   573        -- code_expr_argsP) >> (fn seris => export_code_cmd raw_cs seris)));
   574 
   575 val _ = List.app Keyword.keyword [inK, module_nameK, fileK, checkingK];
   576 
   577 val _ =
   578   Outer_Syntax.command "code_class" "define code syntax for class" Keyword.thy_decl (
   579     process_multi_syntax Parse.xname (Scan.option Parse.string)
   580     add_syntax_class_cmd);
   581 
   582 val _ =
   583   Outer_Syntax.command "code_instance" "define code syntax for instance" Keyword.thy_decl (
   584     process_multi_syntax (Parse.xname --| Parse.$$$ "::" -- Parse.xname)
   585       (Scan.option (Parse.minus >> K ()))
   586     add_syntax_inst_cmd);
   587 
   588 val _ =
   589   Outer_Syntax.command "code_type" "define code syntax for type constructor" Keyword.thy_decl (
   590     process_multi_syntax Parse.xname Code_Printer.parse_tyco_syntax
   591     add_syntax_tyco_cmd);
   592 
   593 val _ =
   594   Outer_Syntax.command "code_const" "define code syntax for constant" Keyword.thy_decl (
   595     process_multi_syntax Parse.term_group Code_Printer.parse_const_syntax
   596     add_syntax_const_cmd);
   597 
   598 val _ =
   599   Outer_Syntax.command "code_reserved" "declare words as reserved for target language"
   600     Keyword.thy_decl (
   601     Parse.name -- Scan.repeat1 Parse.name
   602     >> (fn (target, reserveds) => (Toplevel.theory o fold (add_reserved target)) reserveds)
   603   );
   604 
   605 val _ =
   606   Outer_Syntax.command "code_include" "declare piece of code to be included in generated code"
   607     Keyword.thy_decl (
   608     Parse.name -- Parse.name -- (Parse.text :|-- (fn "-" => Scan.succeed NONE
   609       | s => Scan.optional (Parse.$$$ "attach" |-- Scan.repeat1 Parse.term) [] >> pair s >> SOME))
   610     >> (fn ((target, name), content_consts) =>
   611         (Toplevel.theory o add_include_cmd target) (name, content_consts))
   612   );
   613 
   614 val _ =
   615   Outer_Syntax.command "code_modulename" "alias module to other name" Keyword.thy_decl (
   616     Parse.name -- Scan.repeat1 (Parse.name -- Parse.name)
   617     >> (fn (target, modlnames) => (Toplevel.theory o fold (add_module_alias target)) modlnames)
   618   );
   619 
   620 val _ =
   621   Outer_Syntax.command "code_abort" "permit constant to be implemented as program abort"
   622     Keyword.thy_decl (
   623     Scan.repeat1 Parse.term_group >> (Toplevel.theory o fold allow_abort_cmd)
   624   );
   625 
   626 val _ =
   627   Outer_Syntax.command "export_code" "generate executable code for constants"
   628     Keyword.diag (Parse.!!! code_exprP >> (fn f => Toplevel.keep (f o Toplevel.theory_of)));
   629 
   630 fun shell_command thyname cmd = Toplevel.program (fn _ =>
   631   (use_thy thyname; case Scan.read Token.stopper (Parse.!!! code_exprP)
   632     ((filter Token.is_proper o Outer_Syntax.scan Position.none) cmd)
   633    of SOME f => (writeln "Now generating code..."; f (Thy_Info.get_theory thyname))
   634     | NONE => error ("Bad directive " ^ quote cmd)))
   635   handle Runtime.TOPLEVEL_ERROR => OS.Process.exit OS.Process.failure;
   636 
   637 end; (*local*)
   638 
   639 end; (*struct*)