src/Pure/Thy/context.ML
author wenzelm
Wed, 10 Jun 1998 17:56:57 +0200
changeset 5027 4b1fd9813003
parent 4925 53900a320a87
child 5031 e2280a1eadb2
permissions -rw-r--r--
get_context renamed to the_context; added get_context, set_context;

(*  Title:      Pure/Thy/context.ML
    ID:         $Id$
    Author:     Markus Wenzel, TU Muenchen

Global contexts: session and theory.
*)

signature BASIC_CONTEXT =
sig
  val get_session: unit -> string list
  val add_session: string -> unit
  val reset_session: unit -> unit
  val get_context: unit -> theory option
  val set_context: theory option -> unit
  val the_context: unit -> theory
  val context: theory -> unit
  val reset_context: unit -> unit
  val thm: xstring -> thm
  val thms: xstring -> thm list
  val Goal: string -> thm list
  val Goalw: thm list -> string -> thm list
end;

signature CONTEXT =
sig
  include BASIC_CONTEXT
  val welcome: unit -> string
  val >> : (theory -> theory) -> unit
end;

structure Context: CONTEXT =
struct


(** session **)

val current_session = ref ([]: string list);

fun get_session () = ! current_session;
fun add_session s = current_session := ! current_session @ [s];
fun reset_session () = current_session := [];

fun welcome () =
  "Welcome to Isabelle/" ^
    (case get_session () of [] => "Pure" | ss => space_implode "/" ss) ^
    " (" ^ version ^ ")";



(** theory context **)

local
  val current_theory = ref (None: theory option);
in
  fun get_context () = ! current_theory;
  fun set_context opt_thy = current_theory := opt_thy;
end;

fun the_context () =
  (case get_context () of
    Some thy => thy
  | _ => error "Unknown theory context");

fun context thy = set_context (Some thy);
fun reset_context () = set_context None;


(* map context *)

nonfix >>;
fun >> f = set_context (Some (f (the_context ())));


(* retrieve thms *)

fun thm name = PureThy.get_thm (the_context ()) name;
fun thms name = PureThy.get_thms (the_context ()) name;


(* shortcut goal commands *)

fun Goal s = Goals.goal (the_context ()) s;
fun Goalw thms s = Goals.goalw (the_context ()) thms s;


end;


structure BasicContext: BASIC_CONTEXT = Context;
open BasicContext;