src/Pure/Isar/obtain.ML
author wenzelm
Thu Nov 30 14:17:29 2006 +0100 (2006-11-30)
changeset 21605 4e7307e229b3
parent 21229 9c96c1ec235f
child 21686 4f5f6c685ab4
permissions -rw-r--r--
qualified MetaSimplifier.norm_hhf(_protect);
     1 (*  Title:      Pure/Isar/obtain.ML
     2     ID:         $Id$
     3     Author:     Markus Wenzel, TU Muenchen
     4 
     5 The 'obtain' and 'guess' language elements -- generalized existence at
     6 the level of proof texts: 'obtain' involves a proof that certain
     7 fixes/assumes may be introduced into the present context; 'guess' is
     8 similar, but derives these elements from the course of reasoning!
     9 
    10   <chain_facts>
    11   obtain x where "A x" <proof> ==
    12 
    13   have "!!thesis. (!!x. A x ==> thesis) ==> thesis"
    14   proof succeed
    15     fix thesis
    16     assume that [intro?]: "!!x. A x ==> thesis"
    17     <chain_facts>
    18     show thesis
    19       apply (insert that)
    20       <proof>
    21   qed
    22   fix x assm <<obtain_export>> "A x"
    23 
    24 
    25   <chain_facts>
    26   guess x <proof body> <proof end> ==
    27 
    28   {
    29     fix thesis
    30     <chain_facts> have "PROP ?guess"
    31       apply magic      -- {* turns goal into "thesis ==> #thesis" *}
    32       <proof body>
    33       apply_end magic  -- {* turns final "(!!x. P x ==> thesis) ==> #thesis" into
    34         "#((!!x. A x ==> thesis) ==> thesis)" which is a finished goal state *}
    35       <proof end>
    36   }
    37   fix x assm <<obtain_export>> "A x"
    38 *)
    39 
    40 signature OBTAIN =
    41 sig
    42   val thatN: string
    43   val obtain: string -> (string * string option * mixfix) list ->
    44     ((string * Attrib.src list) * (string * string list) list) list ->
    45     bool -> Proof.state -> Proof.state
    46   val obtain_i: string -> (string * typ option * mixfix) list ->
    47     ((string * attribute list) * (term * term list) list) list ->
    48     bool -> Proof.state -> Proof.state
    49   val result: (Proof.context -> tactic) -> thm list -> Proof.context ->
    50     (cterm list * thm list) * Proof.context
    51   val guess: (string * string option * mixfix) list -> bool -> Proof.state -> Proof.state
    52   val guess_i: (string * typ option * mixfix) list -> bool -> Proof.state -> Proof.state
    53 end;
    54 
    55 structure Obtain: OBTAIN =
    56 struct
    57 
    58 (** obtain_export **)
    59 
    60 (*
    61   [x, A x]
    62      :
    63      B
    64   --------
    65      B
    66 *)
    67 fun obtain_export fix_ctxt rule xs _ As thm =
    68   let
    69     val thy = ProofContext.theory_of fix_ctxt;
    70 
    71     val vs = map (dest_Free o Thm.term_of) xs;
    72     val bads = Term.fold_aterms (fn t as Free v =>
    73       if member (op =) vs v then insert (op aconv) t else I | _ => I) (Thm.prop_of thm) [];
    74     val _ = null bads orelse
    75       error ("Result contains obtained parameters: " ^
    76         space_implode " " (map (ProofContext.string_of_term fix_ctxt) bads));
    77     val _ = ObjectLogic.is_judgment thy (Thm.concl_of thm) orelse
    78       error "Conclusion in obtained context must be object-logic judgment";
    79 
    80     val ((_, [thm']), ctxt') = Variable.import true [thm] fix_ctxt;
    81     val prems = Drule.strip_imp_prems (#prop (Thm.crep_thm thm'));
    82   in
    83     ((Drule.implies_elim_list thm' (map Thm.assume prems)
    84         |> Drule.implies_intr_list (map Drule.norm_hhf_cterm As)
    85         |> Drule.forall_intr_list xs)
    86       COMP rule)
    87     |> Drule.implies_intr_list prems
    88     |> singleton (Variable.export ctxt' fix_ctxt)
    89   end;
    90 
    91 
    92 
    93 (** obtain **)
    94 
    95 fun bind_judgment ctxt name =
    96   let
    97     val (bind, ctxt') = ProofContext.bind_fixes [name] ctxt;
    98     val (t as _ $ Free v) = bind (ObjectLogic.fixed_judgment (ProofContext.theory_of ctxt) name);
    99   in ((v, t), ctxt') end;
   100 
   101 val thatN = "that";
   102 
   103 local
   104 
   105 fun gen_obtain prep_att prep_vars prep_propp
   106     name raw_vars raw_asms int state =
   107   let
   108     val _ = Proof.assert_forward_or_chain state;
   109     val thy = Proof.theory_of state;
   110     val cert = Thm.cterm_of thy;
   111     val ctxt = Proof.context_of state;
   112     val chain_facts = if can Proof.assert_chain state then Proof.the_facts state else [];
   113 
   114     (*obtain vars*)
   115     val (vars, vars_ctxt) = prep_vars raw_vars ctxt;
   116     val (_, fix_ctxt) = vars_ctxt |> ProofContext.add_fixes_i vars;
   117     val xs = map #1 vars;
   118 
   119     (*obtain asms*)
   120     val (asms_ctxt, proppss) = prep_propp (fix_ctxt, map snd raw_asms);
   121     val asm_props = maps (map fst) proppss;
   122     val asms = map fst (Attrib.map_specs (prep_att thy) raw_asms) ~~ proppss;
   123 
   124     val _ = Variable.warn_extra_tfrees fix_ctxt asms_ctxt;
   125 
   126     (*obtain statements*)
   127     val thesisN = Name.variant xs AutoBind.thesisN;
   128     val (thesis_var, thesis) = #1 (bind_judgment fix_ctxt thesisN);
   129 
   130     val asm_frees = fold Term.add_frees asm_props [];
   131     val parms = xs |> map (fn x =>
   132       let val x' = ProofContext.get_skolem fix_ctxt x
   133       in (x', the_default propT (AList.lookup (op =) asm_frees x')) end);
   134 
   135     val that_name = if name = "" then thatN else name;
   136     val that_prop =
   137       Term.list_all_free (parms, Logic.list_implies (asm_props, thesis))
   138       |> Library.curry Logic.list_rename_params xs;
   139     val obtain_prop =
   140       Logic.list_rename_params ([AutoBind.thesisN],
   141         Term.list_all_free ([thesis_var], Logic.mk_implies (that_prop, thesis)));
   142 
   143     fun after_qed _ =
   144       Proof.local_qed (NONE, false)
   145       #> Seq.map (`Proof.the_fact #-> (fn rule =>
   146         Proof.fix_i (map2 (fn x => fn (_, T, mx) => (x, T, mx)) xs vars)
   147         #> Proof.assm_i (obtain_export fix_ctxt rule (map (cert o Free) parms)) asms));
   148   in
   149     state
   150     |> Proof.enter_forward
   151     |> Proof.have_i NONE (K Seq.single) [(("", []), [(obtain_prop, [])])] int
   152     |> Proof.proof (SOME Method.succeed_text) |> Seq.hd
   153     |> Proof.fix_i [(thesisN, NONE, NoSyn)]
   154     |> Proof.assume_i [((that_name, [ContextRules.intro_query NONE]), [(that_prop, [])])]
   155     |> `Proof.the_facts
   156     ||> Proof.chain_facts chain_facts
   157     ||> Proof.show_i NONE after_qed [(("", []), [(thesis, [])])] false
   158     |-> Proof.refine_insert
   159   end;
   160 
   161 in
   162 
   163 val obtain = gen_obtain Attrib.attribute ProofContext.read_vars ProofContext.read_propp;
   164 val obtain_i = gen_obtain (K I) ProofContext.cert_vars ProofContext.cert_propp;
   165 
   166 end;
   167 
   168 
   169 
   170 (** tactical result **)
   171 
   172 fun check_result ctxt thesis th =
   173   (case Thm.prems_of th of
   174     [prem] =>
   175       if Thm.concl_of th aconv thesis andalso
   176         Logic.strip_assums_concl prem aconv thesis then th
   177       else error ("Guessed a different clause:\n" ^ ProofContext.string_of_thm ctxt th)
   178   | [] => error "Goal solved -- nothing guessed."
   179   | _ => error ("Guess split into several cases:\n" ^ ProofContext.string_of_thm ctxt th));
   180 
   181 fun result tac facts ctxt =
   182   let
   183     val thy = ProofContext.theory_of ctxt;
   184     val cert = Thm.cterm_of thy;
   185 
   186     val ((thesis_var, thesis), thesis_ctxt) = bind_judgment ctxt AutoBind.thesisN;
   187     val rule =
   188       (case SINGLE (Method.insert_tac facts 1 THEN tac thesis_ctxt) (Goal.init (cert thesis)) of
   189         NONE => raise THM ("Obtain.result: tactic failed", 0, facts)
   190       | SOME th => check_result ctxt thesis (MetaSimplifier.norm_hhf (Goal.conclude th)));
   191 
   192     val closed_rule = Thm.forall_intr (cert (Free thesis_var)) rule;
   193     val ((_, [rule']), ctxt') = Variable.import false [closed_rule] ctxt;
   194     val obtain_rule = Thm.forall_elim (cert (Logic.varify (Free thesis_var))) rule';
   195     val ((params, stmt), fix_ctxt) = Variable.focus (Thm.cprem_of obtain_rule 1) ctxt';
   196     val (prems, ctxt'') =
   197       Assumption.add_assms (obtain_export fix_ctxt obtain_rule params)
   198         (Drule.strip_imp_prems stmt) fix_ctxt;
   199   in ((params, prems), ctxt'') end;
   200 
   201 
   202 
   203 (** guess **)
   204 
   205 local
   206 
   207 fun unify_params vars thesis_var raw_rule ctxt =
   208   let
   209     val thy = ProofContext.theory_of ctxt;
   210     val certT = Thm.ctyp_of thy;
   211     val cert = Thm.cterm_of thy;
   212     val string_of_typ = ProofContext.string_of_typ ctxt;
   213     val string_of_term = setmp show_types true (ProofContext.string_of_term ctxt);
   214 
   215     fun err msg th = error (msg ^ ":\n" ^ ProofContext.string_of_thm ctxt th);
   216 
   217     val maxidx = fold (Term.maxidx_typ o snd o fst) vars ~1;
   218     val rule = Thm.incr_indexes (maxidx + 1) raw_rule;
   219 
   220     val params = RuleCases.strip_params (Logic.nth_prem (1, Thm.prop_of rule));
   221     val m = length vars;
   222     val n = length params;
   223     val _ = m <= n orelse err "More variables than parameters in obtained rule" rule;
   224 
   225     fun unify ((x, T), (y, U)) (tyenv, max) = Sign.typ_unify thy (T, U) (tyenv, max)
   226       handle Type.TUNIFY =>
   227         err ("Failed to unify variable " ^
   228           string_of_term (Free (x, Envir.norm_type tyenv T)) ^ " against parameter " ^
   229           string_of_term (Syntax.mark_boundT (y, Envir.norm_type tyenv U)) ^ " in") rule;
   230     val (tyenv, _) = fold unify (map #1 vars ~~ Library.take (m, params))
   231       (Vartab.empty, Int.max (maxidx, Thm.maxidx_of rule));
   232     val norm_type = Envir.norm_type tyenv;
   233 
   234     val xs = map (apsnd norm_type o fst) vars;
   235     val ys = map (apsnd norm_type) (Library.drop (m, params));
   236     val ys' = map Name.internal (Name.variant_list (map fst xs) (map fst ys)) ~~ map #2 ys;
   237     val terms = map (Drule.mk_term o cert o Free) (xs @ ys');
   238 
   239     val instT =
   240       fold (Term.add_tvarsT o #2) params []
   241       |> map (TVar #> (fn T => (certT T, certT (norm_type T))));
   242     val closed_rule = rule
   243       |> Thm.forall_intr (cert (Free thesis_var))
   244       |> Thm.instantiate (instT, []);
   245 
   246     val ((_, rule' :: terms'), ctxt') = Variable.import false (closed_rule :: terms) ctxt;
   247     val vars' =
   248       map (dest_Free o Thm.term_of o Drule.dest_term) terms' ~~
   249       (map snd vars @ replicate (length ys) NoSyn);
   250     val rule'' = Thm.forall_elim (cert (Logic.varify (Free thesis_var))) rule';
   251   in ((vars', rule''), ctxt') end;
   252 
   253 fun inferred_type (x, _, mx) ctxt =
   254   let val ((_, T), ctxt') = ProofContext.inferred_param x ctxt
   255   in ((x, T, mx), ctxt') end;
   256 
   257 fun polymorphic ctxt vars =
   258   let val Ts = map Logic.dest_type (Variable.polymorphic ctxt (map (Logic.mk_type o #2) vars))
   259   in map2 (fn (x, _, mx) => fn T => ((x, T), mx)) vars Ts end;
   260 
   261 fun gen_guess prep_vars raw_vars int state =
   262   let
   263     val _ = Proof.assert_forward_or_chain state;
   264     val thy = Proof.theory_of state;
   265     val cert = Thm.cterm_of thy;
   266     val ctxt = Proof.context_of state;
   267     val chain_facts = if can Proof.assert_chain state then Proof.the_facts state else [];
   268 
   269     val (thesis_var, thesis) = #1 (bind_judgment ctxt AutoBind.thesisN);
   270     val vars = ctxt |> prep_vars raw_vars |-> fold_map inferred_type |> fst |> polymorphic ctxt;
   271 
   272     fun guess_context raw_rule state' =
   273       let
   274         val ((parms, rule), ctxt') =
   275           unify_params vars thesis_var raw_rule (Proof.context_of state');
   276         val (bind, _) = ProofContext.bind_fixes (map (#1 o #1) parms) ctxt';
   277         val ts = map (bind o Free o #1) parms;
   278         val ps = map dest_Free ts;
   279         val asms =
   280           Logic.strip_assums_hyp (Logic.nth_prem (1, Thm.prop_of rule))
   281           |> map (fn asm => (Term.betapplys (Term.list_abs (ps, asm), ts), []));
   282         val _ = not (null asms) orelse error "Trivial result -- nothing guessed";
   283       in
   284         state'
   285         |> Proof.map_context (K ctxt')
   286         |> Proof.fix_i (map (fn ((x, T), mx) => (x, SOME T, mx)) parms)
   287         |> `Proof.context_of |-> (fn fix_ctxt =>
   288             Proof.assm_i (obtain_export fix_ctxt rule (map cert ts)) [(("", []), asms)])
   289         |> Proof.add_binds_i AutoBind.no_facts
   290       end;
   291 
   292     val goal = Var (("guess", 0), propT);
   293     fun print_result ctxt' (k, [(s, [_, th])]) =
   294       ProofDisplay.print_results int ctxt' (k, [(s, [th])]);
   295     val before_qed = SOME (Method.primitive_text (Goal.conclude #> MetaSimplifier.norm_hhf #>
   296         (fn th => Goal.protect (Conjunction.intr (Drule.mk_term (Thm.cprop_of th)) th))));
   297     fun after_qed [[_, res]] =
   298       Proof.end_block #> guess_context (check_result ctxt thesis res) #> Seq.single;
   299   in
   300     state
   301     |> Proof.enter_forward
   302     |> Proof.begin_block
   303     |> Proof.fix_i [(AutoBind.thesisN, NONE, NoSyn)]
   304     |> Proof.chain_facts chain_facts
   305     |> Proof.local_goal print_result (K I) (apsnd (rpair I))
   306       "guess" before_qed after_qed [(("", []), [Logic.mk_term goal, goal])]
   307     |> Proof.refine (Method.primitive_text (K (Goal.init (cert thesis)))) |> Seq.hd
   308   end;
   309 
   310 in
   311 
   312 val guess = gen_guess ProofContext.read_vars;
   313 val guess_i = gen_guess ProofContext.cert_vars;
   314 
   315 end;
   316 
   317 end;