src/Tools/Code/code_namespace.ML
author haftmann
Sun Feb 23 10:33:43 2014 +0100 (2014-02-23)
changeset 55679 59244fc1a7ca
parent 55605 b1b363e81c87
child 55680 bc5edc5dbf18
permissions -rw-r--r--
formal markup for public ingredients
     1 (*  Title:      Tools/Code/code_namespace.ML
     2     Author:     Florian Haftmann, TU Muenchen
     3 
     4 Mastering target language namespaces.
     5 *)
     6 
     7 signature CODE_NAMESPACE =
     8 sig
     9   type flat_program
    10   val flat_program: Proof.context
    11     -> { module_prefix: string, module_name: string,
    12     reserved: Name.context, identifiers: Code_Target.identifier_data, empty_nsp: 'a,
    13     namify_stmt: Code_Thingol.stmt -> string -> 'a -> string * 'a,
    14     modify_stmt: Code_Thingol.stmt -> Code_Thingol.stmt option }
    15       -> Code_Thingol.program
    16       -> { deresolver: string -> Code_Symbol.T -> string,
    17            flat_program: flat_program }
    18 
    19   datatype ('a, 'b) node =
    20       Dummy
    21     | Stmt of bool * 'a
    22     | Module of ('b * (string * ('a, 'b) node) Code_Symbol.Graph.T)
    23   type ('a, 'b) hierarchical_program
    24   val hierarchical_program: Proof.context
    25     -> { module_name: string,
    26     reserved: Name.context, identifiers: Code_Target.identifier_data,
    27     empty_nsp: 'c, namify_module: string -> 'c -> string * 'c,
    28     namify_stmt: Code_Thingol.stmt -> string -> 'c -> string * 'c,
    29     cyclic_modules: bool, empty_data: 'b, memorize_data: Code_Symbol.T -> 'b -> 'b,
    30     modify_stmts: (Code_Symbol.T * Code_Thingol.stmt) list -> 'a option list }
    31       -> Code_Thingol.program
    32       -> { deresolver: string list -> Code_Symbol.T -> string,
    33            hierarchical_program: ('a, 'b) hierarchical_program }
    34   val print_hierarchical: { print_module: string list -> string -> 'b -> 'c list -> 'c,
    35     print_stmt: string list -> Code_Symbol.T * (bool * 'a) -> 'c,
    36     lift_markup: (Pretty.T -> Pretty.T) -> 'c -> 'c }
    37       -> ('a, 'b) hierarchical_program -> 'c list
    38 end;
    39 
    40 structure Code_Namespace : CODE_NAMESPACE =
    41 struct
    42 
    43 (** fundamental module name hierarchy **)
    44 
    45 fun module_fragments' { identifiers, reserved } name =
    46   case Code_Symbol.lookup_module_data identifiers name of
    47       SOME (fragments, _) => fragments
    48     | NONE => map (fn fragment => fst (Name.variant fragment reserved)) (Long_Name.explode name);
    49 
    50 fun module_fragments { module_name, identifiers, reserved } =
    51   if module_name = ""
    52   then module_fragments' { identifiers = identifiers, reserved = reserved }
    53   else K (Long_Name.explode module_name);
    54 
    55 fun build_module_namespace ctxt { module_prefix, module_name, identifiers, reserved } program =
    56   let
    57     val module_names = Code_Symbol.Graph.fold (insert (op =) o Code_Symbol.default_prefix ctxt o fst) program [];
    58     val module_fragments' = module_fragments
    59       { module_name = module_name, identifiers = identifiers, reserved = reserved };
    60   in
    61     fold (fn name => Symtab.update (name, Long_Name.explode module_prefix @ module_fragments' name))
    62       module_names Symtab.empty
    63   end;
    64 
    65 fun prep_symbol ctxt { module_namespace, force_module, identifiers } sym =
    66   case Code_Symbol.lookup identifiers sym of
    67       NONE => ((the o Symtab.lookup module_namespace o Code_Symbol.default_prefix ctxt) sym,
    68         Code_Symbol.default_base sym)
    69     | SOME prefix_name => if null force_module then prefix_name
    70         else (force_module, snd prefix_name);
    71 
    72 fun has_priority identifiers = is_some o Code_Symbol.lookup identifiers;
    73 
    74 fun build_proto_program { empty, add_stmt, add_dep } program =
    75   empty
    76   |> Code_Symbol.Graph.fold (fn (sym, (stmt, _)) => add_stmt sym stmt) program
    77   |> Code_Symbol.Graph.fold (fn (sym, (_, (_, syms))) =>
    78       Code_Symbol.Graph.Keys.fold (add_dep sym) syms) program;
    79 
    80 fun prioritize has_priority = uncurry append o List.partition has_priority;
    81 
    82 
    83 (** flat program structure **)
    84 
    85 type flat_program = ((string * (bool * Code_Thingol.stmt) option) Code_Symbol.Graph.T * (string * Code_Symbol.T list) list) Graph.T;
    86 
    87 fun flat_program ctxt { module_prefix, module_name, reserved,
    88     identifiers, empty_nsp, namify_stmt, modify_stmt } program =
    89   let
    90 
    91     (* building module name hierarchy *)
    92     val module_namespace = build_module_namespace ctxt { module_prefix = module_prefix,
    93       module_name = module_name, identifiers = identifiers, reserved = reserved } program;
    94     val prep_sym = prep_symbol ctxt { module_namespace = module_namespace,
    95       force_module = Long_Name.explode module_name, identifiers = identifiers }
    96       #>> Long_Name.implode;
    97     val sym_priority = has_priority identifiers;
    98 
    99     (* distribute statements over hierarchy *)
   100     fun add_stmt sym stmt =
   101       let
   102         val (module_name, base) = prep_sym sym;
   103       in
   104         Graph.default_node (module_name, (Code_Symbol.Graph.empty, []))
   105         #> (Graph.map_node module_name o apfst) (Code_Symbol.Graph.new_node (sym, (base, (true, stmt))))
   106       end;
   107     fun add_dep sym sym' =
   108       let
   109         val (module_name, _) = prep_sym sym;
   110         val (module_name', _) = prep_sym sym';
   111       in if module_name = module_name'
   112         then (Graph.map_node module_name o apfst) (Code_Symbol.Graph.add_edge (sym, sym'))
   113         else (Graph.map_node module_name o apsnd) (AList.map_default (op =) (module_name', []) (insert (op =) sym'))
   114       end;
   115     val proto_program = build_proto_program
   116       { empty = Graph.empty, add_stmt = add_stmt, add_dep = add_dep } program;
   117 
   118     (* name declarations and statement modifications *)
   119     fun declare sym (base, (_, stmt)) (gr, nsp) = 
   120       let
   121         val (base', nsp') = namify_stmt stmt base nsp;
   122         val gr' = (Code_Symbol.Graph.map_node sym o apfst) (K base') gr;
   123       in (gr', nsp') end;
   124     fun declarations gr = (gr, empty_nsp)
   125       |> fold (fn sym => declare sym (Code_Symbol.Graph.get_node gr sym))
   126           (prioritize sym_priority (Code_Symbol.Graph.keys gr))
   127       |> fst
   128       |> (Code_Symbol.Graph.map o K o apsnd)
   129         (fn (export, stmt) => Option.map (pair export) (modify_stmt stmt));
   130     val flat_program = proto_program
   131       |> (Graph.map o K o apfst) declarations;
   132 
   133     (* qualified and unqualified imports, deresolving *)
   134     fun base_deresolver sym = fst (Code_Symbol.Graph.get_node
   135       (fst (Graph.get_node flat_program (fst (prep_sym sym)))) sym);
   136     fun classify_names gr imports =
   137       let
   138         val import_tab = maps
   139           (fn (module_name, syms) => map (rpair module_name) syms) imports;
   140         val imported_syms = map fst import_tab;
   141         val here_syms = Code_Symbol.Graph.keys gr;
   142       in
   143         Code_Symbol.Table.empty
   144         |> fold (fn sym => Code_Symbol.Table.update (sym, base_deresolver sym)) here_syms
   145         |> fold (fn sym => Code_Symbol.Table.update (sym,
   146             Long_Name.append (the (AList.lookup (op =) import_tab sym))
   147               (base_deresolver sym))) imported_syms
   148       end;
   149     val deresolver_tab = Symtab.make (AList.make
   150       (uncurry classify_names o Graph.get_node flat_program)
   151         (Graph.keys flat_program));
   152     fun deresolver "" sym =
   153           Long_Name.append (fst (prep_sym sym)) (base_deresolver sym)
   154       | deresolver module_name sym =
   155           the (Code_Symbol.Table.lookup (the (Symtab.lookup deresolver_tab module_name)) sym)
   156           handle Option.Option => error ("Unknown statement name: "
   157             ^ Code_Symbol.quote ctxt sym);
   158 
   159   in { deresolver = deresolver, flat_program = flat_program } end;
   160 
   161 
   162 (** hierarchical program structure **)
   163 
   164 datatype ('a, 'b) node =
   165     Dummy
   166   | Stmt of bool * 'a
   167   | Module of ('b * (string * ('a, 'b) node) Code_Symbol.Graph.T);
   168 
   169 type ('a, 'b) hierarchical_program = (string * ('a, 'b) node) Code_Symbol.Graph.T;
   170 
   171 fun the_stmt (Stmt (export, stmt)) = (export, stmt);
   172 
   173 fun map_module_content f (Module content) = Module (f content);
   174 
   175 fun map_module [] = I
   176   | map_module (name_fragment :: name_fragments) =
   177       apsnd o Code_Symbol.Graph.map_node (Code_Symbol.Module name_fragment) o apsnd o map_module_content
   178         o map_module name_fragments;
   179 
   180 fun hierarchical_program ctxt { module_name, reserved, identifiers, empty_nsp,
   181       namify_module, namify_stmt, cyclic_modules, empty_data, memorize_data, modify_stmts } program =
   182   let
   183 
   184     (* building module name hierarchy *)
   185     val module_namespace = build_module_namespace ctxt { module_prefix = "",
   186       module_name = module_name, identifiers = identifiers, reserved = reserved } program;
   187     val prep_sym = prep_symbol ctxt { module_namespace = module_namespace,
   188       force_module = Long_Name.explode module_name, identifiers = identifiers }
   189     val sym_priority = has_priority identifiers;
   190 
   191     (* building empty module hierarchy *)
   192     val empty_module = (empty_data, Code_Symbol.Graph.empty);
   193     fun ensure_module name_fragment (data, nodes) =
   194       if can (Code_Symbol.Graph.get_node nodes) (Code_Symbol.Module name_fragment) then (data, nodes)
   195       else (data,
   196         nodes |> Code_Symbol.Graph.new_node (Code_Symbol.Module name_fragment, (name_fragment, Module empty_module)));
   197     fun allocate_module [] = I
   198       | allocate_module (name_fragment :: name_fragments) =
   199           ensure_module name_fragment
   200           #> (apsnd o Code_Symbol.Graph.map_node (Code_Symbol.Module name_fragment) o apsnd o map_module_content o allocate_module) name_fragments;
   201     val empty_program =
   202       empty_module
   203       |> Symtab.fold (fn (_, fragments) => allocate_module fragments) module_namespace
   204       |> Code_Symbol.Graph.fold (allocate_module o these o Option.map fst
   205           o Code_Symbol.lookup identifiers o fst) program;
   206 
   207     (* distribute statements over hierarchy *)
   208     fun add_stmt sym stmt =
   209       let
   210         val (name_fragments, base) = prep_sym sym;
   211       in
   212         (map_module name_fragments o apsnd) (Code_Symbol.Graph.new_node (sym, (base, Stmt (true, stmt))))
   213       end;
   214     fun add_dep sym sym' =
   215       let
   216         val (name_fragments, _) = prep_sym sym;
   217         val (name_fragments', _) = prep_sym sym';
   218         val (name_fragments_common, (diff, diff')) =
   219           chop_prefix (op =) (name_fragments, name_fragments');
   220         val is_module = not (null diff andalso null diff');
   221         val dep = pairself hd (map Code_Symbol.Module diff @ [sym], map Code_Symbol.Module diff' @ [sym']);
   222         val add_edge = if is_module andalso not cyclic_modules
   223           then (fn node => Code_Symbol.Graph.add_edge_acyclic dep node
   224             handle Graph.CYCLES _ => error ("Dependency "
   225               ^ Code_Symbol.quote ctxt sym ^ " -> "
   226               ^ Code_Symbol.quote ctxt sym'
   227               ^ " would result in module dependency cycle"))
   228           else Code_Symbol.Graph.add_edge dep
   229       in (map_module name_fragments_common o apsnd) add_edge end;
   230     val proto_program = build_proto_program
   231       { empty = empty_program, add_stmt = add_stmt, add_dep = add_dep } program;
   232 
   233     (* name declarations, data and statement modifications *)
   234     fun make_declarations nsps (data, nodes) =
   235       let
   236         val (module_fragments, stmt_syms) =
   237           Code_Symbol.Graph.keys nodes
   238           |> List.partition
   239               (fn sym => case Code_Symbol.Graph.get_node nodes sym
   240                 of (_, Module _) => true | _ => false)
   241           |> pairself (prioritize sym_priority)
   242         fun declare namify sym (nsps, nodes) =
   243           let
   244             val (base, node) = Code_Symbol.Graph.get_node nodes sym;
   245             val (base', nsps') = namify node base nsps;
   246             val nodes' = Code_Symbol.Graph.map_node sym (K (base', node)) nodes;
   247           in (nsps', nodes') end;
   248         val (nsps', nodes') = (nsps, nodes)
   249           |> fold (declare (K namify_module)) module_fragments
   250           |> fold (declare (namify_stmt o snd o the_stmt)) stmt_syms;
   251         fun select_syms syms = case filter (member (op =) stmt_syms) syms
   252          of [] => NONE
   253           | syms => SOME syms;
   254         fun select_stmt (sym, (export, SOME stmt)) = SOME (sym, (export, stmt))
   255           | select_stmt _ = NONE;
   256         fun modify_stmts' syms =
   257           let
   258             val (exports, stmts) = map_split (the_stmt o snd o Code_Symbol.Graph.get_node nodes) syms;
   259             val stmts' = modify_stmts (syms ~~ stmts);
   260             val stmts'' = stmts' @ replicate (length syms - length stmts') NONE;
   261           in map_filter select_stmt (syms ~~ (exports ~~ stmts'')) end;
   262         val stmtss' = (maps modify_stmts' o map_filter select_syms o Code_Symbol.Graph.strong_conn) nodes;
   263         val nodes'' = Code_Symbol.Graph.map (fn sym => apsnd (fn Module content => Module (make_declarations nsps' content)
   264             | _ => case AList.lookup (op =) stmtss' sym of SOME stmt => Stmt stmt | _ => Dummy)) nodes';
   265         val data' = fold memorize_data stmt_syms data;
   266       in (data', nodes'') end;
   267     val (_, hierarchical_program) = make_declarations empty_nsp proto_program;
   268 
   269     (* deresolving *)
   270     fun deresolver prefix_fragments sym =
   271       let
   272         val (name_fragments, _) = prep_sym sym;
   273         val (_, (_, remainder)) = chop_prefix (op =) (prefix_fragments, name_fragments);
   274         val nodes = fold (fn name_fragment => fn nodes => case Code_Symbol.Graph.get_node nodes (Code_Symbol.Module name_fragment)
   275          of (_, Module (_, nodes)) => nodes) name_fragments hierarchical_program;
   276         val (base', _) = Code_Symbol.Graph.get_node nodes sym;
   277       in Long_Name.implode (remainder @ [base']) end
   278         handle Code_Symbol.Graph.UNDEF _ => error ("Unknown statement name: "
   279           ^ Code_Symbol.quote ctxt sym);
   280 
   281   in { deresolver = deresolver, hierarchical_program = hierarchical_program } end;
   282 
   283 fun print_hierarchical { print_module, print_stmt, lift_markup } =
   284   let
   285     fun print_node _ (_, Dummy) =
   286           NONE
   287       | print_node prefix_fragments (sym, Stmt stmt) =
   288           SOME (lift_markup (Code_Printer.markup_stmt sym)
   289             (print_stmt prefix_fragments (sym, stmt)))
   290       | print_node prefix_fragments (Code_Symbol.Module name_fragment, Module (data, nodes)) =
   291           let
   292             val prefix_fragments' = prefix_fragments @ [name_fragment]
   293           in
   294             Option.map (print_module prefix_fragments'
   295               name_fragment data) (print_nodes prefix_fragments' nodes)
   296           end
   297     and print_nodes prefix_fragments nodes =
   298       let
   299         val xs = (map_filter (fn sym => print_node prefix_fragments
   300           (sym, snd (Code_Symbol.Graph.get_node nodes sym))) o rev o flat o Code_Symbol.Graph.strong_conn) nodes
   301       in if null xs then NONE else SOME xs end;
   302   in these o print_nodes [] end;
   303 
   304 end;