src/Pure/drule.ML
author wenzelm
Wed Dec 31 00:08:13 2008 +0100 (2008-12-31)
changeset 29265 5b4247055bd7
parent 28713 135317cd34d6
child 29270 0eade173f77e
permissions -rw-r--r--
moved old add_term_vars, add_term_frees etc. to structure OldTerm;
     1 (*  Title:      Pure/drule.ML
     2     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     3 
     4 Derived rules and other operations on theorems.
     5 *)
     6 
     7 infix 0 RS RSN RL RLN MRS MRL OF COMP INCR_COMP COMP_INCR;
     8 
     9 signature BASIC_DRULE =
    10 sig
    11   val mk_implies: cterm * cterm -> cterm
    12   val list_implies: cterm list * cterm -> cterm
    13   val strip_imp_prems: cterm -> cterm list
    14   val strip_imp_concl: cterm -> cterm
    15   val cprems_of: thm -> cterm list
    16   val cterm_fun: (term -> term) -> (cterm -> cterm)
    17   val ctyp_fun: (typ -> typ) -> (ctyp -> ctyp)
    18   val forall_intr_list: cterm list -> thm -> thm
    19   val forall_intr_frees: thm -> thm
    20   val forall_intr_vars: thm -> thm
    21   val forall_elim_list: cterm list -> thm -> thm
    22   val gen_all: thm -> thm
    23   val lift_all: cterm -> thm -> thm
    24   val freeze_thaw: thm -> thm * (thm -> thm)
    25   val freeze_thaw_robust: thm -> thm * (int -> thm -> thm)
    26   val implies_elim_list: thm -> thm list -> thm
    27   val implies_intr_list: cterm list -> thm -> thm
    28   val instantiate: (ctyp * ctyp) list * (cterm * cterm) list -> thm -> thm
    29   val zero_var_indexes_list: thm list -> thm list
    30   val zero_var_indexes: thm -> thm
    31   val implies_intr_hyps: thm -> thm
    32   val standard: thm -> thm
    33   val standard': thm -> thm
    34   val rotate_prems: int -> thm -> thm
    35   val rearrange_prems: int list -> thm -> thm
    36   val RSN: thm * (int * thm) -> thm
    37   val RS: thm * thm -> thm
    38   val RLN: thm list * (int * thm list) -> thm list
    39   val RL: thm list * thm list -> thm list
    40   val MRS: thm list * thm -> thm
    41   val MRL: thm list list * thm list -> thm list
    42   val OF: thm * thm list -> thm
    43   val compose: thm * int * thm -> thm list
    44   val COMP: thm * thm -> thm
    45   val INCR_COMP: thm * thm -> thm
    46   val COMP_INCR: thm * thm -> thm
    47   val cterm_instantiate: (cterm*cterm)list -> thm -> thm
    48   val size_of_thm: thm -> int
    49   val reflexive_thm: thm
    50   val symmetric_thm: thm
    51   val transitive_thm: thm
    52   val symmetric_fun: thm -> thm
    53   val extensional: thm -> thm
    54   val equals_cong: thm
    55   val imp_cong: thm
    56   val swap_prems_eq: thm
    57   val asm_rl: thm
    58   val cut_rl: thm
    59   val revcut_rl: thm
    60   val thin_rl: thm
    61   val triv_forall_equality: thm
    62   val distinct_prems_rl: thm
    63   val swap_prems_rl: thm
    64   val equal_intr_rule: thm
    65   val equal_elim_rule1: thm
    66   val equal_elim_rule2: thm
    67   val instantiate': ctyp option list -> cterm option list -> thm -> thm
    68 end;
    69 
    70 signature DRULE =
    71 sig
    72   include BASIC_DRULE
    73   val generalize: string list * string list -> thm -> thm
    74   val list_comb: cterm * cterm list -> cterm
    75   val strip_comb: cterm -> cterm * cterm list
    76   val strip_type: ctyp -> ctyp list * ctyp
    77   val beta_conv: cterm -> cterm -> cterm
    78   val types_sorts: thm -> (indexname-> typ option) * (indexname-> sort option)
    79   val flexflex_unique: thm -> thm
    80   val store_thm: bstring -> thm -> thm
    81   val store_standard_thm: bstring -> thm -> thm
    82   val store_thm_open: bstring -> thm -> thm
    83   val store_standard_thm_open: bstring -> thm -> thm
    84   val compose_single: thm * int * thm -> thm
    85   val imp_cong_rule: thm -> thm -> thm
    86   val arg_cong_rule: cterm -> thm -> thm
    87   val binop_cong_rule: cterm -> thm -> thm -> thm
    88   val fun_cong_rule: thm -> cterm -> thm
    89   val beta_eta_conversion: cterm -> thm
    90   val eta_long_conversion: cterm -> thm
    91   val eta_contraction_rule: thm -> thm
    92   val norm_hhf_eq: thm
    93   val norm_hhf_eqs: thm list
    94   val is_norm_hhf: term -> bool
    95   val norm_hhf: theory -> term -> term
    96   val norm_hhf_cterm: cterm -> cterm
    97   val protect: cterm -> cterm
    98   val protectI: thm
    99   val protectD: thm
   100   val protect_cong: thm
   101   val implies_intr_protected: cterm list -> thm -> thm
   102   val termI: thm
   103   val mk_term: cterm -> thm
   104   val dest_term: thm -> cterm
   105   val cterm_rule: (thm -> thm) -> cterm -> cterm
   106   val term_rule: theory -> (thm -> thm) -> term -> term
   107   val dummy_thm: thm
   108   val sort_constraintI: thm
   109   val sort_constraint_eq: thm
   110   val sort_triv: theory -> typ * sort -> thm list
   111   val unconstrainTs: thm -> thm
   112   val with_subgoal: int -> (thm -> thm) -> thm -> thm
   113   val rename_bvars: (string * string) list -> thm -> thm
   114   val rename_bvars': string option list -> thm -> thm
   115   val incr_type_indexes: int -> thm -> thm
   116   val incr_indexes: thm -> thm -> thm
   117   val incr_indexes2: thm -> thm -> thm -> thm
   118   val remdups_rl: thm
   119   val multi_resolve: thm list -> thm -> thm Seq.seq
   120   val multi_resolves: thm list -> thm list -> thm Seq.seq
   121   val abs_def: thm -> thm
   122 end;
   123 
   124 structure Drule: DRULE =
   125 struct
   126 
   127 
   128 (** some cterm->cterm operations: faster than calling cterm_of! **)
   129 
   130 (* A1==>...An==>B  goes to  [A1,...,An], where B is not an implication *)
   131 fun strip_imp_prems ct =
   132   let val (cA, cB) = Thm.dest_implies ct
   133   in cA :: strip_imp_prems cB end
   134   handle TERM _ => [];
   135 
   136 (* A1==>...An==>B  goes to B, where B is not an implication *)
   137 fun strip_imp_concl ct =
   138   (case Thm.term_of ct of
   139     Const ("==>", _) $ _ $ _ => strip_imp_concl (Thm.dest_arg ct)
   140   | _ => ct);
   141 
   142 (*The premises of a theorem, as a cterm list*)
   143 val cprems_of = strip_imp_prems o cprop_of;
   144 
   145 fun cterm_fun f ct = Thm.cterm_of (Thm.theory_of_cterm ct) (f (Thm.term_of ct));
   146 fun ctyp_fun f cT = Thm.ctyp_of (Thm.theory_of_ctyp cT) (f (Thm.typ_of cT));
   147 
   148 fun certify t = Thm.cterm_of (Context.the_theory (Context.the_thread_data ())) t;
   149 
   150 val implies = certify Logic.implies;
   151 fun mk_implies (A, B) = Thm.capply (Thm.capply implies A) B;
   152 
   153 (*cterm version of list_implies: [A1,...,An], B  goes to [|A1;==>;An|]==>B *)
   154 fun list_implies([], B) = B
   155   | list_implies(A::AS, B) = mk_implies (A, list_implies(AS,B));
   156 
   157 (*cterm version of list_comb: maps  (f, [t1,...,tn])  to  f(t1,...,tn) *)
   158 fun list_comb (f, []) = f
   159   | list_comb (f, t::ts) = list_comb (Thm.capply f t, ts);
   160 
   161 (*cterm version of strip_comb: maps  f(t1,...,tn)  to  (f, [t1,...,tn]) *)
   162 fun strip_comb ct =
   163   let
   164     fun stripc (p as (ct, cts)) =
   165       let val (ct1, ct2) = Thm.dest_comb ct
   166       in stripc (ct1, ct2 :: cts) end handle CTERM _ => p
   167   in stripc (ct, []) end;
   168 
   169 (* cterm version of strip_type: maps  [T1,...,Tn]--->T  to   ([T1,T2,...,Tn], T) *)
   170 fun strip_type cT = (case Thm.typ_of cT of
   171     Type ("fun", _) =>
   172       let
   173         val [cT1, cT2] = Thm.dest_ctyp cT;
   174         val (cTs, cT') = strip_type cT2
   175       in (cT1 :: cTs, cT') end
   176   | _ => ([], cT));
   177 
   178 (*Beta-conversion for cterms, where x is an abstraction. Simply returns the rhs
   179   of the meta-equality returned by the beta_conversion rule.*)
   180 fun beta_conv x y =
   181   Thm.dest_arg (cprop_of (Thm.beta_conversion false (Thm.capply x y)));
   182 
   183 
   184 
   185 (*** Find the type (sort) associated with a (T)Var or (T)Free in a term
   186      Used for establishing default types (of variables) and sorts (of
   187      type variables) when reading another term.
   188      Index -1 indicates that a (T)Free rather than a (T)Var is wanted.
   189 ***)
   190 
   191 fun types_sorts thm =
   192   let
   193     val vars = Thm.fold_terms Term.add_vars thm [];
   194     val frees = Thm.fold_terms Term.add_frees thm [];
   195     val tvars = Thm.fold_terms Term.add_tvars thm [];
   196     val tfrees = Thm.fold_terms Term.add_tfrees thm [];
   197     fun types (a, i) =
   198       if i < 0 then AList.lookup (op =) frees a else AList.lookup (op =) vars (a, i);
   199     fun sorts (a, i) =
   200       if i < 0 then AList.lookup (op =) tfrees a else AList.lookup (op =) tvars (a, i);
   201   in (types, sorts) end;
   202 
   203 
   204 
   205 
   206 (** Standardization of rules **)
   207 
   208 (* type classes and sorts *)
   209 
   210 fun sort_triv thy (T, S) =
   211   let
   212     val certT = Thm.ctyp_of thy;
   213     val cT = certT T;
   214     fun class_triv c =
   215       Thm.class_triv thy c
   216       |> Thm.instantiate ([(certT (TVar ((Name.aT, 0), [c])), cT)], []);
   217   in map class_triv S end;
   218 
   219 fun unconstrainTs th =
   220   fold (Thm.unconstrainT o Thm.ctyp_of (Thm.theory_of_thm th) o TVar)
   221     (Thm.fold_terms Term.add_tvars th []) th;
   222 
   223 (*Generalization over a list of variables*)
   224 val forall_intr_list = fold_rev forall_intr;
   225 
   226 (*Generalization over all suitable Free variables*)
   227 fun forall_intr_frees th =
   228     let
   229       val thy = Thm.theory_of_thm th;
   230       val {prop, hyps, tpairs, ...} = rep_thm th;
   231       val fixed = fold Term.add_frees (Thm.terms_of_tpairs tpairs @ hyps) [];
   232       val frees = Term.fold_aterms (fn Free v =>
   233         if member (op =) fixed v then I else insert (op =) v | _ => I) prop [];
   234     in fold (forall_intr o cterm_of thy o Free) frees th end;
   235 
   236 (*Generalization over Vars -- canonical order*)
   237 fun forall_intr_vars th =
   238   fold forall_intr
   239     (map (Thm.cterm_of (Thm.theory_of_thm th) o Var) (Thm.fold_terms Term.add_vars th [])) th;
   240 
   241 fun outer_params t =
   242   let val vs = Term.strip_all_vars t
   243   in Name.variant_list [] (map (Name.clean o #1) vs) ~~ map #2 vs end;
   244 
   245 (*generalize outermost parameters*)
   246 fun gen_all th =
   247   let
   248     val thy = Thm.theory_of_thm th;
   249     val {prop, maxidx, ...} = Thm.rep_thm th;
   250     val cert = Thm.cterm_of thy;
   251     fun elim (x, T) = Thm.forall_elim (cert (Var ((x, maxidx + 1), T)));
   252   in fold elim (outer_params prop) th end;
   253 
   254 (*lift vars wrt. outermost goal parameters
   255   -- reverses the effect of gen_all modulo higher-order unification*)
   256 fun lift_all goal th =
   257   let
   258     val thy = Theory.merge (Thm.theory_of_cterm goal, Thm.theory_of_thm th);
   259     val cert = Thm.cterm_of thy;
   260     val maxidx = Thm.maxidx_of th;
   261     val ps = outer_params (Thm.term_of goal)
   262       |> map (fn (x, T) => Var ((x, maxidx + 1), Logic.incr_tvar (maxidx + 1) T));
   263     val Ts = map Term.fastype_of ps;
   264     val inst = Thm.fold_terms Term.add_vars th [] |> map (fn (xi, T) =>
   265       (cert (Var (xi, T)), cert (Term.list_comb (Var (xi, Ts ---> T), ps))));
   266   in
   267     th |> Thm.instantiate ([], inst)
   268     |> fold_rev (Thm.forall_intr o cert) ps
   269   end;
   270 
   271 (*direct generalization*)
   272 fun generalize names th = Thm.generalize names (Thm.maxidx_of th + 1) th;
   273 
   274 (*specialization over a list of cterms*)
   275 val forall_elim_list = fold forall_elim;
   276 
   277 (*maps A1,...,An |- B  to  [| A1;...;An |] ==> B*)
   278 val implies_intr_list = fold_rev implies_intr;
   279 
   280 (*maps [| A1;...;An |] ==> B and [A1,...,An]  to  B*)
   281 fun implies_elim_list impth ths = fold Thm.elim_implies ths impth;
   282 
   283 (*Reset Var indexes to zero, renaming to preserve distinctness*)
   284 fun zero_var_indexes_list [] = []
   285   | zero_var_indexes_list ths =
   286       let
   287         val thy = Theory.merge_list (map Thm.theory_of_thm ths);
   288         val certT = Thm.ctyp_of thy and cert = Thm.cterm_of thy;
   289         val (instT, inst) = TermSubst.zero_var_indexes_inst (map Thm.full_prop_of ths);
   290         val cinstT = map (fn (v, T) => (certT (TVar v), certT T)) instT;
   291         val cinst = map (fn (v, t) => (cert (Var v), cert t)) inst;
   292       in map (Thm.adjust_maxidx_thm ~1 o Thm.instantiate (cinstT, cinst)) ths end;
   293 
   294 val zero_var_indexes = singleton zero_var_indexes_list;
   295 
   296 
   297 (** Standard form of object-rule: no hypotheses, flexflex constraints,
   298     Frees, or outer quantifiers; all generality expressed by Vars of index 0.**)
   299 
   300 (*Discharge all hypotheses.*)
   301 fun implies_intr_hyps th =
   302   fold Thm.implies_intr (#hyps (Thm.crep_thm th)) th;
   303 
   304 (*Squash a theorem's flexflex constraints provided it can be done uniquely.
   305   This step can lose information.*)
   306 fun flexflex_unique th =
   307   if null (tpairs_of th) then th else
   308     case distinct Thm.eq_thm (Seq.list_of (flexflex_rule th)) of
   309       [th] => th
   310     | []   => raise THM("flexflex_unique: impossible constraints", 0, [th])
   311     |  _   => raise THM("flexflex_unique: multiple unifiers", 0, [th]);
   312 
   313 
   314 (* legacy standard operations *)
   315 
   316 val standard' =
   317   implies_intr_hyps
   318   #> forall_intr_frees
   319   #> `Thm.maxidx_of
   320   #-> (fn maxidx =>
   321     Thm.forall_elim_vars (maxidx + 1)
   322     #> Thm.strip_shyps
   323     #> zero_var_indexes
   324     #> Thm.varifyT);
   325 
   326 val standard =
   327   flexflex_unique
   328   #> standard'
   329   #> Thm.close_derivation;
   330 
   331 
   332 (*Convert all Vars in a theorem to Frees.  Also return a function for
   333   reversing that operation.  DOES NOT WORK FOR TYPE VARIABLES.
   334   Similar code in type/freeze_thaw*)
   335 
   336 fun freeze_thaw_robust th =
   337  let val fth = Thm.freezeT th
   338      val thy = Thm.theory_of_thm fth
   339      val {prop, tpairs, ...} = rep_thm fth
   340  in
   341    case List.foldr OldTerm.add_term_vars [] (prop :: Thm.terms_of_tpairs tpairs) of
   342        [] => (fth, fn i => fn x => x)   (*No vars: nothing to do!*)
   343      | vars =>
   344          let fun newName (Var(ix,_)) = (ix, gensym (string_of_indexname ix))
   345              val alist = map newName vars
   346              fun mk_inst (Var(v,T)) =
   347                  (cterm_of thy (Var(v,T)),
   348                   cterm_of thy (Free(((the o AList.lookup (op =) alist) v), T)))
   349              val insts = map mk_inst vars
   350              fun thaw i th' = (*i is non-negative increment for Var indexes*)
   351                  th' |> forall_intr_list (map #2 insts)
   352                      |> forall_elim_list (map (Thm.incr_indexes_cterm i o #1) insts)
   353          in  (Thm.instantiate ([],insts) fth, thaw)  end
   354  end;
   355 
   356 (*Basic version of the function above. No option to rename Vars apart in thaw.
   357   The Frees created from Vars have nice names. FIXME: does not check for
   358   clashes with variables in the assumptions, so delete and use freeze_thaw_robust instead?*)
   359 fun freeze_thaw th =
   360  let val fth = Thm.freezeT th
   361      val thy = Thm.theory_of_thm fth
   362      val {prop, tpairs, ...} = rep_thm fth
   363  in
   364    case List.foldr OldTerm.add_term_vars [] (prop :: Thm.terms_of_tpairs tpairs) of
   365        [] => (fth, fn x => x)
   366      | vars =>
   367          let fun newName (Var(ix,_), (pairs,used)) =
   368                    let val v = Name.variant used (string_of_indexname ix)
   369                    in  ((ix,v)::pairs, v::used)  end;
   370              val (alist, _) = List.foldr newName ([], Library.foldr add_term_names
   371                (prop :: Thm.terms_of_tpairs tpairs, [])) vars
   372              fun mk_inst (Var(v,T)) =
   373                  (cterm_of thy (Var(v,T)),
   374                   cterm_of thy (Free(((the o AList.lookup (op =) alist) v), T)))
   375              val insts = map mk_inst vars
   376              fun thaw th' =
   377                  th' |> forall_intr_list (map #2 insts)
   378                      |> forall_elim_list (map #1 insts)
   379          in  (Thm.instantiate ([],insts) fth, thaw)  end
   380  end;
   381 
   382 (*Rotates a rule's premises to the left by k*)
   383 fun rotate_prems 0 = I
   384   | rotate_prems k = permute_prems 0 k;
   385 
   386 fun with_subgoal i f = rotate_prems (i - 1) #> f #> rotate_prems (1 - i);
   387 
   388 (* permute prems, where the i-th position in the argument list (counting from 0)
   389    gives the position within the original thm to be transferred to position i.
   390    Any remaining trailing positions are left unchanged. *)
   391 val rearrange_prems = let
   392   fun rearr new []      thm = thm
   393   |   rearr new (p::ps) thm = rearr (new+1)
   394      (map (fn q => if new<=q andalso q<p then q+1 else q) ps)
   395      (permute_prems (new+1) (new-p) (permute_prems new (p-new) thm))
   396   in rearr 0 end;
   397 
   398 (*Resolution: exactly one resolvent must be produced.*)
   399 fun tha RSN (i,thb) =
   400   case Seq.chop 2 (biresolution false [(false,tha)] i thb) of
   401       ([th],_) => th
   402     | ([],_)   => raise THM("RSN: no unifiers", i, [tha,thb])
   403     |      _   => raise THM("RSN: multiple unifiers", i, [tha,thb]);
   404 
   405 (*resolution: P==>Q, Q==>R gives P==>R. *)
   406 fun tha RS thb = tha RSN (1,thb);
   407 
   408 (*For joining lists of rules*)
   409 fun thas RLN (i,thbs) =
   410   let val resolve = biresolution false (map (pair false) thas) i
   411       fun resb thb = Seq.list_of (resolve thb) handle THM _ => []
   412   in maps resb thbs end;
   413 
   414 fun thas RL thbs = thas RLN (1,thbs);
   415 
   416 (*Resolve a list of rules against bottom_rl from right to left;
   417   makes proof trees*)
   418 fun rls MRS bottom_rl =
   419   let fun rs_aux i [] = bottom_rl
   420         | rs_aux i (rl::rls) = rl RSN (i, rs_aux (i+1) rls)
   421   in  rs_aux 1 rls  end;
   422 
   423 (*As above, but for rule lists*)
   424 fun rlss MRL bottom_rls =
   425   let fun rs_aux i [] = bottom_rls
   426         | rs_aux i (rls::rlss) = rls RLN (i, rs_aux (i+1) rlss)
   427   in  rs_aux 1 rlss  end;
   428 
   429 (*A version of MRS with more appropriate argument order*)
   430 fun bottom_rl OF rls = rls MRS bottom_rl;
   431 
   432 (*compose Q and [...,Qi,Q(i+1),...]==>R to [...,Q(i+1),...]==>R
   433   with no lifting or renaming!  Q may contain ==> or meta-quants
   434   ALWAYS deletes premise i *)
   435 fun compose(tha,i,thb) =
   436     distinct Thm.eq_thm (Seq.list_of (bicompose false (false,tha,0) i thb));
   437 
   438 fun compose_single (tha,i,thb) =
   439   case compose (tha,i,thb) of
   440     [th] => th
   441   | _ => raise THM ("compose: unique result expected", i, [tha,thb]);
   442 
   443 (*compose Q and [Q1,Q2,...,Qk]==>R to [Q2,...,Qk]==>R getting unique result*)
   444 fun tha COMP thb =
   445     case compose(tha,1,thb) of
   446         [th] => th
   447       | _ =>   raise THM("COMP", 1, [tha,thb]);
   448 
   449 
   450 (** theorem equality **)
   451 
   452 (*Useful "distance" function for BEST_FIRST*)
   453 val size_of_thm = size_of_term o Thm.full_prop_of;
   454 
   455 
   456 
   457 (*** Meta-Rewriting Rules ***)
   458 
   459 val read_prop = certify o SimpleSyntax.read_prop;
   460 
   461 fun store_thm name th =
   462   Context.>>> (Context.map_theory_result (PureThy.store_thm (name, th)));
   463 
   464 fun store_thm_open name th =
   465   Context.>>> (Context.map_theory_result (PureThy.store_thm_open (name, th)));
   466 
   467 fun store_standard_thm name th = store_thm name (standard th);
   468 fun store_standard_thm_open name thm = store_thm_open name (standard' thm);
   469 
   470 val reflexive_thm =
   471   let val cx = certify (Var(("x",0),TVar(("'a",0),[])))
   472   in store_standard_thm_open "reflexive" (Thm.reflexive cx) end;
   473 
   474 val symmetric_thm =
   475   let val xy = read_prop "x::'a == y::'a"
   476   in store_standard_thm_open "symmetric" (Thm.implies_intr xy (Thm.symmetric (Thm.assume xy))) end;
   477 
   478 val transitive_thm =
   479   let val xy = read_prop "x::'a == y::'a"
   480       val yz = read_prop "y::'a == z::'a"
   481       val xythm = Thm.assume xy and yzthm = Thm.assume yz
   482   in store_standard_thm_open "transitive" (Thm.implies_intr yz (Thm.transitive xythm yzthm)) end;
   483 
   484 fun symmetric_fun thm = thm RS symmetric_thm;
   485 
   486 fun extensional eq =
   487   let val eq' =
   488     abstract_rule "x" (Thm.dest_arg (fst (Thm.dest_equals (cprop_of eq)))) eq
   489   in equal_elim (eta_conversion (cprop_of eq')) eq' end;
   490 
   491 val equals_cong =
   492   store_standard_thm_open "equals_cong" (Thm.reflexive (read_prop "x::'a == y::'a"));
   493 
   494 val imp_cong =
   495   let
   496     val ABC = read_prop "A ==> B::prop == C::prop"
   497     val AB = read_prop "A ==> B"
   498     val AC = read_prop "A ==> C"
   499     val A = read_prop "A"
   500   in
   501     store_standard_thm_open "imp_cong" (implies_intr ABC (equal_intr
   502       (implies_intr AB (implies_intr A
   503         (equal_elim (implies_elim (assume ABC) (assume A))
   504           (implies_elim (assume AB) (assume A)))))
   505       (implies_intr AC (implies_intr A
   506         (equal_elim (symmetric (implies_elim (assume ABC) (assume A)))
   507           (implies_elim (assume AC) (assume A)))))))
   508   end;
   509 
   510 val swap_prems_eq =
   511   let
   512     val ABC = read_prop "A ==> B ==> C"
   513     val BAC = read_prop "B ==> A ==> C"
   514     val A = read_prop "A"
   515     val B = read_prop "B"
   516   in
   517     store_standard_thm_open "swap_prems_eq" (equal_intr
   518       (implies_intr ABC (implies_intr B (implies_intr A
   519         (implies_elim (implies_elim (assume ABC) (assume A)) (assume B)))))
   520       (implies_intr BAC (implies_intr A (implies_intr B
   521         (implies_elim (implies_elim (assume BAC) (assume B)) (assume A))))))
   522   end;
   523 
   524 val imp_cong_rule = Thm.combination o Thm.combination (Thm.reflexive implies);
   525 
   526 fun arg_cong_rule ct th = Thm.combination (Thm.reflexive ct) th;    (*AP_TERM in LCF/HOL*)
   527 fun fun_cong_rule th ct = Thm.combination th (Thm.reflexive ct);    (*AP_THM in LCF/HOL*)
   528 fun binop_cong_rule ct th1 th2 = Thm.combination (arg_cong_rule ct th1) th2;
   529 
   530 local
   531   val dest_eq = Thm.dest_equals o cprop_of
   532   val rhs_of = snd o dest_eq
   533 in
   534 fun beta_eta_conversion t =
   535   let val thm = beta_conversion true t
   536   in transitive thm (eta_conversion (rhs_of thm)) end
   537 end;
   538 
   539 fun eta_long_conversion ct = transitive (beta_eta_conversion ct)
   540   (symmetric (beta_eta_conversion (cterm_fun (Pattern.eta_long []) ct)));
   541 
   542 (*Contract all eta-redexes in the theorem, lest they give rise to needless abstractions*)
   543 fun eta_contraction_rule th =
   544   equal_elim (eta_conversion (cprop_of th)) th;
   545 
   546 
   547 (* abs_def *)
   548 
   549 (*
   550    f ?x1 ... ?xn == u
   551   --------------------
   552    f == %x1 ... xn. u
   553 *)
   554 
   555 local
   556 
   557 fun contract_lhs th =
   558   Thm.transitive (Thm.symmetric (beta_eta_conversion
   559     (fst (Thm.dest_equals (cprop_of th))))) th;
   560 
   561 fun var_args ct =
   562   (case try Thm.dest_comb ct of
   563     SOME (f, arg) =>
   564       (case Thm.term_of arg of
   565         Var ((x, _), _) => update (eq_snd (op aconvc)) (x, arg) (var_args f)
   566       | _ => [])
   567   | NONE => []);
   568 
   569 in
   570 
   571 fun abs_def th =
   572   let
   573     val th' = contract_lhs th;
   574     val args = var_args (Thm.lhs_of th');
   575   in contract_lhs (fold (uncurry Thm.abstract_rule) args th') end;
   576 
   577 end;
   578 
   579 
   580 
   581 (*** Some useful meta-theorems ***)
   582 
   583 (*The rule V/V, obtains assumption solving for eresolve_tac*)
   584 val asm_rl = store_standard_thm_open "asm_rl" (Thm.trivial (read_prop "?psi"));
   585 val _ = store_thm_open "_" asm_rl;
   586 
   587 (*Meta-level cut rule: [| V==>W; V |] ==> W *)
   588 val cut_rl =
   589   store_standard_thm_open "cut_rl"
   590     (Thm.trivial (read_prop "?psi ==> ?theta"));
   591 
   592 (*Generalized elim rule for one conclusion; cut_rl with reversed premises:
   593      [| PROP V;  PROP V ==> PROP W |] ==> PROP W *)
   594 val revcut_rl =
   595   let val V = read_prop "V"
   596       and VW = read_prop "V ==> W";
   597   in
   598     store_standard_thm_open "revcut_rl"
   599       (implies_intr V (implies_intr VW (implies_elim (assume VW) (assume V))))
   600   end;
   601 
   602 (*for deleting an unwanted assumption*)
   603 val thin_rl =
   604   let val V = read_prop "V"
   605       and W = read_prop "W";
   606   in store_standard_thm_open "thin_rl" (implies_intr V (implies_intr W (assume W))) end;
   607 
   608 (* (!!x. PROP ?V) == PROP ?V       Allows removal of redundant parameters*)
   609 val triv_forall_equality =
   610   let val V  = read_prop "V"
   611       and QV = read_prop "!!x::'a. V"
   612       and x  = certify (Free ("x", Term.aT []));
   613   in
   614     store_standard_thm_open "triv_forall_equality"
   615       (equal_intr (implies_intr QV (forall_elim x (assume QV)))
   616         (implies_intr V  (forall_intr x (assume V))))
   617   end;
   618 
   619 (* (PROP ?Phi ==> PROP ?Phi ==> PROP ?Psi) ==>
   620    (PROP ?Phi ==> PROP ?Psi)
   621 *)
   622 val distinct_prems_rl =
   623   let
   624     val AAB = read_prop "Phi ==> Phi ==> Psi"
   625     val A = read_prop "Phi";
   626   in
   627     store_standard_thm_open "distinct_prems_rl"
   628       (implies_intr_list [AAB, A] (implies_elim_list (assume AAB) [assume A, assume A]))
   629   end;
   630 
   631 (* (PROP ?PhiA ==> PROP ?PhiB ==> PROP ?Psi) ==>
   632    (PROP ?PhiB ==> PROP ?PhiA ==> PROP ?Psi)
   633    `thm COMP swap_prems_rl' swaps the first two premises of `thm'
   634 *)
   635 val swap_prems_rl =
   636   let val cmajor = read_prop "PhiA ==> PhiB ==> Psi";
   637       val major = assume cmajor;
   638       val cminor1 = read_prop "PhiA";
   639       val minor1 = assume cminor1;
   640       val cminor2 = read_prop "PhiB";
   641       val minor2 = assume cminor2;
   642   in store_standard_thm_open "swap_prems_rl"
   643        (implies_intr cmajor (implies_intr cminor2 (implies_intr cminor1
   644          (implies_elim (implies_elim major minor1) minor2))))
   645   end;
   646 
   647 (* [| PROP ?phi ==> PROP ?psi; PROP ?psi ==> PROP ?phi |]
   648    ==> PROP ?phi == PROP ?psi
   649    Introduction rule for == as a meta-theorem.
   650 *)
   651 val equal_intr_rule =
   652   let val PQ = read_prop "phi ==> psi"
   653       and QP = read_prop "psi ==> phi"
   654   in
   655     store_standard_thm_open "equal_intr_rule"
   656       (implies_intr PQ (implies_intr QP (equal_intr (assume PQ) (assume QP))))
   657   end;
   658 
   659 (* PROP ?phi == PROP ?psi ==> PROP ?phi ==> PROP ?psi *)
   660 val equal_elim_rule1 =
   661   let val eq = read_prop "phi::prop == psi::prop"
   662       and P = read_prop "phi"
   663   in store_standard_thm_open "equal_elim_rule1"
   664     (Thm.equal_elim (assume eq) (assume P) |> implies_intr_list [eq, P])
   665   end;
   666 
   667 (* PROP ?psi == PROP ?phi ==> PROP ?phi ==> PROP ?psi *)
   668 val equal_elim_rule2 =
   669   store_standard_thm_open "equal_elim_rule2" (symmetric_thm RS equal_elim_rule1);
   670 
   671 (* PROP ?phi ==> PROP ?phi ==> PROP ?psi ==> PROP ?psi *)
   672 val remdups_rl =
   673   let val P = read_prop "phi" and Q = read_prop "psi";
   674   in store_standard_thm_open "remdups_rl" (implies_intr_list [P, P, Q] (Thm.assume Q)) end;
   675 
   676 
   677 
   678 (** embedded terms and types **)
   679 
   680 local
   681   val A = certify (Free ("A", propT));
   682   val axiom = Thm.unvarify o Thm.axiom (Context.the_theory (Context.the_thread_data ()));
   683   val prop_def = axiom "Pure.prop_def";
   684   val term_def = axiom "Pure.term_def";
   685   val sort_constraint_def = axiom "Pure.sort_constraint_def";
   686   val C = Thm.lhs_of sort_constraint_def;
   687   val T = Thm.dest_arg C;
   688   val CA = mk_implies (C, A);
   689 in
   690 
   691 (* protect *)
   692 
   693 val protect = Thm.capply (certify Logic.protectC);
   694 
   695 val protectI = store_thm "protectI" (Thm.kind_rule Thm.internalK (standard
   696     (Thm.equal_elim (Thm.symmetric prop_def) (Thm.assume A))));
   697 
   698 val protectD = store_thm "protectD" (Thm.kind_rule Thm.internalK (standard
   699     (Thm.equal_elim prop_def (Thm.assume (protect A)))));
   700 
   701 val protect_cong = store_standard_thm_open "protect_cong" (Thm.reflexive (protect A));
   702 
   703 fun implies_intr_protected asms th =
   704   let val asms' = map protect asms in
   705     implies_elim_list
   706       (implies_intr_list asms th)
   707       (map (fn asm' => Thm.assume asm' RS protectD) asms')
   708     |> implies_intr_list asms'
   709   end;
   710 
   711 
   712 (* term *)
   713 
   714 val termI = store_thm "termI" (Thm.kind_rule Thm.internalK (standard
   715     (Thm.equal_elim (Thm.symmetric term_def) (Thm.forall_intr A (Thm.trivial A)))));
   716 
   717 fun mk_term ct =
   718   let
   719     val thy = Thm.theory_of_cterm ct;
   720     val cert = Thm.cterm_of thy;
   721     val certT = Thm.ctyp_of thy;
   722     val T = Thm.typ_of (Thm.ctyp_of_term ct);
   723     val a = certT (TVar (("'a", 0), []));
   724     val x = cert (Var (("x", 0), T));
   725   in Thm.instantiate ([(a, certT T)], [(x, ct)]) termI end;
   726 
   727 fun dest_term th =
   728   let val cprop = strip_imp_concl (Thm.cprop_of th) in
   729     if can Logic.dest_term (Thm.term_of cprop) then
   730       Thm.dest_arg cprop
   731     else raise THM ("dest_term", 0, [th])
   732   end;
   733 
   734 fun cterm_rule f = dest_term o f o mk_term;
   735 fun term_rule thy f t = Thm.term_of (cterm_rule f (Thm.cterm_of thy t));
   736 
   737 val dummy_thm = mk_term (certify (Term.dummy_pattern propT));
   738 
   739 
   740 (* sort_constraint *)
   741 
   742 val sort_constraintI = store_thm "sort_constraintI" (Thm.kind_rule Thm.internalK (standard
   743   (Thm.equal_elim (Thm.symmetric sort_constraint_def) (mk_term T))));
   744 
   745 val sort_constraint_eq = store_thm "sort_constraint_eq" (Thm.kind_rule Thm.internalK (standard
   746   (Thm.equal_intr
   747     (Thm.implies_intr CA (Thm.implies_elim (Thm.assume CA) (Thm.unvarify sort_constraintI)))
   748     (implies_intr_list [A, C] (Thm.assume A)))));
   749 
   750 end;
   751 
   752 
   753 (* HHF normalization *)
   754 
   755 (* (PROP ?phi ==> (!!x. PROP ?psi(x))) == (!!x. PROP ?phi ==> PROP ?psi(x)) *)
   756 val norm_hhf_eq =
   757   let
   758     val aT = TFree ("'a", []);
   759     val all = Term.all aT;
   760     val x = Free ("x", aT);
   761     val phi = Free ("phi", propT);
   762     val psi = Free ("psi", aT --> propT);
   763 
   764     val cx = certify x;
   765     val cphi = certify phi;
   766     val lhs = certify (Logic.mk_implies (phi, all $ Abs ("x", aT, psi $ Bound 0)));
   767     val rhs = certify (all $ Abs ("x", aT, Logic.mk_implies (phi, psi $ Bound 0)));
   768   in
   769     Thm.equal_intr
   770       (Thm.implies_elim (Thm.assume lhs) (Thm.assume cphi)
   771         |> Thm.forall_elim cx
   772         |> Thm.implies_intr cphi
   773         |> Thm.forall_intr cx
   774         |> Thm.implies_intr lhs)
   775       (Thm.implies_elim
   776           (Thm.assume rhs |> Thm.forall_elim cx) (Thm.assume cphi)
   777         |> Thm.forall_intr cx
   778         |> Thm.implies_intr cphi
   779         |> Thm.implies_intr rhs)
   780     |> store_standard_thm_open "norm_hhf_eq"
   781   end;
   782 
   783 val norm_hhf_prop = Logic.dest_equals (Thm.prop_of norm_hhf_eq);
   784 val norm_hhf_eqs = [norm_hhf_eq, sort_constraint_eq];
   785 
   786 fun is_norm_hhf tm =
   787   let
   788     fun is_norm (Const ("Pure.sort_constraint", _)) = false
   789       | is_norm (Const ("==>", _) $ _ $ (Const ("all", _) $ _)) = false
   790       | is_norm (t $ u) = is_norm t andalso is_norm u
   791       | is_norm (Abs (_, _, t)) = is_norm t
   792       | is_norm _ = true;
   793   in is_norm (Envir.beta_eta_contract tm) end;
   794 
   795 fun norm_hhf thy t =
   796   if is_norm_hhf t then t
   797   else Pattern.rewrite_term thy [norm_hhf_prop] [] t;
   798 
   799 fun norm_hhf_cterm ct =
   800   if is_norm_hhf (Thm.term_of ct) then ct
   801   else cterm_fun (Pattern.rewrite_term (Thm.theory_of_cterm ct) [norm_hhf_prop] []) ct;
   802 
   803 
   804 (* var indexes *)
   805 
   806 (*Increment the indexes of only the type variables*)
   807 fun incr_type_indexes inc th =
   808   let val tvs = term_tvars (prop_of th)
   809       and thy = theory_of_thm th
   810       fun inc_tvar ((a,i),s) = pairself (ctyp_of thy) (TVar ((a,i),s), TVar ((a,i+inc),s))
   811   in Thm.instantiate (map inc_tvar tvs, []) th end;
   812 
   813 fun incr_indexes th = Thm.incr_indexes (Thm.maxidx_of th + 1);
   814 
   815 fun incr_indexes2 th1 th2 =
   816   Thm.incr_indexes (Int.max (Thm.maxidx_of th1, Thm.maxidx_of th2) + 1);
   817 
   818 fun th1 INCR_COMP th2 = incr_indexes th2 th1 COMP th2;
   819 fun th1 COMP_INCR th2 = th1 COMP incr_indexes th1 th2;
   820 
   821 
   822 (*** Instantiate theorem th, reading instantiations in theory thy ****)
   823 
   824 (*Version that normalizes the result: Thm.instantiate no longer does that*)
   825 fun instantiate instpair th =
   826   Thm.adjust_maxidx_thm ~1 (Thm.instantiate instpair th COMP_INCR asm_rl);
   827 
   828 (*Left-to-right replacements: tpairs = [...,(vi,ti),...].
   829   Instantiates distinct Vars by terms, inferring type instantiations. *)
   830 local
   831   fun add_types ((ct,cu), (thy,tye,maxidx)) =
   832     let
   833         val thyt = Thm.theory_of_cterm ct;
   834         val thyu = Thm.theory_of_cterm cu;
   835         val {t, T, maxidx = maxt, ...} = Thm.rep_cterm ct;
   836         val {t = u, T = U, maxidx = maxu, ...} = Thm.rep_cterm cu;
   837         val maxi = Int.max(maxidx, Int.max(maxt, maxu));
   838         val thy' = Theory.merge(thy, Theory.merge(thyt, thyu))
   839         val (tye',maxi') = Sign.typ_unify thy' (T, U) (tye, maxi)
   840           handle Type.TUNIFY => raise TYPE ("Ill-typed instantiation:\nType\n" ^
   841             Syntax.string_of_typ_global thy' (Envir.norm_type tye T) ^
   842             "\nof variable " ^
   843             Syntax.string_of_term_global thy' (Term.map_types (Envir.norm_type tye) t) ^
   844             "\ncannot be unified with type\n" ^
   845             Syntax.string_of_typ_global thy' (Envir.norm_type tye U) ^ "\nof term " ^
   846             Syntax.string_of_term_global thy' (Term.map_types (Envir.norm_type tye) u),
   847             [T, U], [t, u])
   848     in  (thy', tye', maxi')  end;
   849 in
   850 fun cterm_instantiate [] th = th
   851   | cterm_instantiate ctpairs0 th =
   852   let val (thy,tye,_) = List.foldr add_types (Thm.theory_of_thm th, Vartab.empty, 0) ctpairs0
   853       fun instT(ct,cu) =
   854         let val inst = cterm_of thy o Term.map_types (Envir.norm_type tye) o term_of
   855         in (inst ct, inst cu) end
   856       fun ctyp2 (ixn, (S, T)) = (ctyp_of thy (TVar (ixn, S)), ctyp_of thy (Envir.norm_type tye T))
   857   in  instantiate (map ctyp2 (Vartab.dest tye), map instT ctpairs0) th  end
   858   handle TERM _ =>
   859            raise THM("cterm_instantiate: incompatible theories",0,[th])
   860        | TYPE (msg, _, _) => raise THM(msg, 0, [th])
   861 end;
   862 
   863 
   864 
   865 (** variations on instantiate **)
   866 
   867 (* instantiate by left-to-right occurrence of variables *)
   868 
   869 fun instantiate' cTs cts thm =
   870   let
   871     fun err msg =
   872       raise TYPE ("instantiate': " ^ msg,
   873         map_filter (Option.map Thm.typ_of) cTs,
   874         map_filter (Option.map Thm.term_of) cts);
   875 
   876     fun inst_of (v, ct) =
   877       (Thm.cterm_of (Thm.theory_of_cterm ct) (Var v), ct)
   878         handle TYPE (msg, _, _) => err msg;
   879 
   880     fun tyinst_of (v, cT) =
   881       (Thm.ctyp_of (Thm.theory_of_ctyp cT) (TVar v), cT)
   882         handle TYPE (msg, _, _) => err msg;
   883 
   884     fun zip_vars xs ys =
   885       zip_options xs ys handle Library.UnequalLengths =>
   886         err "more instantiations than variables in thm";
   887 
   888     (*instantiate types first!*)
   889     val thm' =
   890       if forall is_none cTs then thm
   891       else Thm.instantiate
   892         (map tyinst_of (zip_vars (rev (Thm.fold_terms Term.add_tvars thm [])) cTs), []) thm;
   893     val thm'' =
   894       if forall is_none cts then thm'
   895       else Thm.instantiate
   896         ([], map inst_of (zip_vars (rev (Thm.fold_terms Term.add_vars thm' [])) cts)) thm';
   897     in thm'' end;
   898 
   899 
   900 
   901 (** renaming of bound variables **)
   902 
   903 (* replace bound variables x_i in thm by y_i *)
   904 (* where vs = [(x_1, y_1), ..., (x_n, y_n)]  *)
   905 
   906 fun rename_bvars [] thm = thm
   907   | rename_bvars vs thm =
   908       let
   909         val cert = Thm.cterm_of (Thm.theory_of_thm thm);
   910         fun ren (Abs (x, T, t)) = Abs (AList.lookup (op =) vs x |> the_default x, T, ren t)
   911           | ren (t $ u) = ren t $ ren u
   912           | ren t = t;
   913       in equal_elim (reflexive (cert (ren (Thm.prop_of thm)))) thm end;
   914 
   915 
   916 (* renaming in left-to-right order *)
   917 
   918 fun rename_bvars' xs thm =
   919   let
   920     val cert = Thm.cterm_of (Thm.theory_of_thm thm);
   921     val prop = Thm.prop_of thm;
   922     fun rename [] t = ([], t)
   923       | rename (x' :: xs) (Abs (x, T, t)) =
   924           let val (xs', t') = rename xs t
   925           in (xs', Abs (the_default x x', T, t')) end
   926       | rename xs (t $ u) =
   927           let
   928             val (xs', t') = rename xs t;
   929             val (xs'', u') = rename xs' u
   930           in (xs'', t' $ u') end
   931       | rename xs t = (xs, t);
   932   in case rename xs prop of
   933       ([], prop') => equal_elim (reflexive (cert prop')) thm
   934     | _ => error "More names than abstractions in theorem"
   935   end;
   936 
   937 
   938 
   939 (** multi_resolve **)
   940 
   941 local
   942 
   943 fun res th i rule =
   944   Thm.biresolution false [(false, th)] i rule handle THM _ => Seq.empty;
   945 
   946 fun multi_res _ [] rule = Seq.single rule
   947   | multi_res i (th :: ths) rule = Seq.maps (res th i) (multi_res (i + 1) ths rule);
   948 
   949 in
   950 
   951 val multi_resolve = multi_res 1;
   952 fun multi_resolves facts rules = Seq.maps (multi_resolve facts) (Seq.of_list rules);
   953 
   954 end;
   955 
   956 end;
   957 
   958 structure BasicDrule: BASIC_DRULE = Drule;
   959 open BasicDrule;