src/HOL/Product_Type.thy
author wenzelm
Sun Nov 02 18:21:45 2014 +0100 (2014-11-02)
changeset 58889 5b7a9633cfa8
parent 58839 ccda99401bc8
child 58916 229765cc3414
permissions -rw-r--r--
modernized header uniformly as section;
     1 (*  Title:      HOL/Product_Type.thy
     2     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     3     Copyright   1992  University of Cambridge
     4 *)
     5 
     6 section {* Cartesian products *}
     7 
     8 theory Product_Type
     9 imports Typedef Inductive Fun
    10 keywords "inductive_set" "coinductive_set" :: thy_decl
    11 begin
    12 
    13 subsection {* @{typ bool} is a datatype *}
    14 
    15 free_constructors case_bool for True | False
    16   by auto
    17 
    18 text {* Avoid name clashes by prefixing the output of @{text old_rep_datatype} with @{text old}. *}
    19 
    20 setup {* Sign.mandatory_path "old" *}
    21 
    22 old_rep_datatype True False by (auto intro: bool_induct)
    23 
    24 setup {* Sign.parent_path *}
    25 
    26 text {* But erase the prefix for properties that are not generated by @{text free_constructors}. *}
    27 
    28 setup {* Sign.mandatory_path "bool" *}
    29 
    30 lemmas induct = old.bool.induct
    31 lemmas inducts = old.bool.inducts
    32 lemmas rec = old.bool.rec
    33 lemmas simps = bool.distinct bool.case bool.rec
    34 
    35 setup {* Sign.parent_path *}
    36 
    37 declare case_split [cases type: bool]
    38   -- "prefer plain propositional version"
    39 
    40 lemma
    41   shows [code]: "HOL.equal False P \<longleftrightarrow> \<not> P"
    42     and [code]: "HOL.equal True P \<longleftrightarrow> P" 
    43     and [code]: "HOL.equal P False \<longleftrightarrow> \<not> P"
    44     and [code]: "HOL.equal P True \<longleftrightarrow> P"
    45     and [code nbe]: "HOL.equal P P \<longleftrightarrow> True"
    46   by (simp_all add: equal)
    47 
    48 lemma If_case_cert:
    49   assumes "CASE \<equiv> (\<lambda>b. If b f g)"
    50   shows "(CASE True \<equiv> f) &&& (CASE False \<equiv> g)"
    51   using assms by simp_all
    52 
    53 setup {* Code.add_case @{thm If_case_cert} *}
    54 
    55 code_printing
    56   constant "HOL.equal :: bool \<Rightarrow> bool \<Rightarrow> bool" \<rightharpoonup> (Haskell) infix 4 "=="
    57 | class_instance "bool" :: "equal" \<rightharpoonup> (Haskell) -
    58 
    59 
    60 subsection {* The @{text unit} type *}
    61 
    62 typedef unit = "{True}"
    63   by auto
    64 
    65 definition Unity :: unit  ("'(')")
    66   where "() = Abs_unit True"
    67 
    68 lemma unit_eq [no_atp]: "u = ()"
    69   by (induct u) (simp add: Unity_def)
    70 
    71 text {*
    72   Simplification procedure for @{thm [source] unit_eq}.  Cannot use
    73   this rule directly --- it loops!
    74 *}
    75 
    76 simproc_setup unit_eq ("x::unit") = {*
    77   fn _ => fn _ => fn ct =>
    78     if HOLogic.is_unit (term_of ct) then NONE
    79     else SOME (mk_meta_eq @{thm unit_eq})
    80 *}
    81 
    82 free_constructors case_unit for "()"
    83   by auto
    84 
    85 text {* Avoid name clashes by prefixing the output of @{text old_rep_datatype} with @{text old}. *}
    86 
    87 setup {* Sign.mandatory_path "old" *}
    88 
    89 old_rep_datatype "()" by simp
    90 
    91 setup {* Sign.parent_path *}
    92 
    93 text {* But erase the prefix for properties that are not generated by @{text free_constructors}. *}
    94 
    95 setup {* Sign.mandatory_path "unit" *}
    96 
    97 lemmas induct = old.unit.induct
    98 lemmas inducts = old.unit.inducts
    99 lemmas rec = old.unit.rec
   100 lemmas simps = unit.case unit.rec
   101 
   102 setup {* Sign.parent_path *}
   103 
   104 lemma unit_all_eq1: "(!!x::unit. PROP P x) == PROP P ()"
   105   by simp
   106 
   107 lemma unit_all_eq2: "(!!x::unit. PROP P) == PROP P"
   108   by (rule triv_forall_equality)
   109 
   110 text {*
   111   This rewrite counters the effect of simproc @{text unit_eq} on @{term
   112   [source] "%u::unit. f u"}, replacing it by @{term [source]
   113   f} rather than by @{term [source] "%u. f ()"}.
   114 *}
   115 
   116 lemma unit_abs_eta_conv [simp]: "(%u::unit. f ()) = f"
   117   by (rule ext) simp
   118 
   119 lemma UNIV_unit:
   120   "UNIV = {()}" by auto
   121 
   122 instantiation unit :: default
   123 begin
   124 
   125 definition "default = ()"
   126 
   127 instance ..
   128 
   129 end
   130 
   131 instantiation unit :: "{complete_boolean_algebra, complete_linorder, wellorder}"
   132 begin
   133 
   134 definition less_eq_unit :: "unit \<Rightarrow> unit \<Rightarrow> bool"
   135 where
   136   "(_::unit) \<le> _ \<longleftrightarrow> True"
   137 
   138 lemma less_eq_unit [iff]:
   139   "(u::unit) \<le> v"
   140   by (simp add: less_eq_unit_def)
   141 
   142 definition less_unit :: "unit \<Rightarrow> unit \<Rightarrow> bool"
   143 where
   144   "(_::unit) < _ \<longleftrightarrow> False"
   145 
   146 lemma less_unit [iff]:
   147   "\<not> (u::unit) < v"
   148   by (simp_all add: less_eq_unit_def less_unit_def)
   149 
   150 definition bot_unit :: unit
   151 where
   152   [code_unfold]: "\<bottom> = ()"
   153 
   154 definition top_unit :: unit
   155 where
   156   [code_unfold]: "\<top> = ()"
   157 
   158 definition inf_unit :: "unit \<Rightarrow> unit \<Rightarrow> unit"
   159 where
   160   [simp]: "_ \<sqinter> _ = ()"
   161 
   162 definition sup_unit :: "unit \<Rightarrow> unit \<Rightarrow> unit"
   163 where
   164   [simp]: "_ \<squnion> _ = ()"
   165 
   166 definition Inf_unit :: "unit set \<Rightarrow> unit"
   167 where
   168   [simp]: "\<Sqinter>_ = ()"
   169 
   170 definition Sup_unit :: "unit set \<Rightarrow> unit"
   171 where
   172   [simp]: "\<Squnion>_ = ()"
   173 
   174 definition uminus_unit :: "unit \<Rightarrow> unit"
   175 where
   176   [simp]: "- _ = ()"
   177 
   178 declare less_eq_unit_def [abs_def, code_unfold]
   179   less_unit_def [abs_def, code_unfold]
   180   inf_unit_def [abs_def, code_unfold]
   181   sup_unit_def [abs_def, code_unfold]
   182   Inf_unit_def [abs_def, code_unfold]
   183   Sup_unit_def [abs_def, code_unfold]
   184   uminus_unit_def [abs_def, code_unfold]
   185 
   186 instance
   187   by intro_classes auto
   188 
   189 end
   190 
   191 lemma [code]:
   192   "HOL.equal (u\<Colon>unit) v \<longleftrightarrow> True" unfolding equal unit_eq [of u] unit_eq [of v] by rule+
   193 
   194 code_printing
   195   type_constructor unit \<rightharpoonup>
   196     (SML) "unit"
   197     and (OCaml) "unit"
   198     and (Haskell) "()"
   199     and (Scala) "Unit"
   200 | constant Unity \<rightharpoonup>
   201     (SML) "()"
   202     and (OCaml) "()"
   203     and (Haskell) "()"
   204     and (Scala) "()"
   205 | class_instance unit :: equal \<rightharpoonup>
   206     (Haskell) -
   207 | constant "HOL.equal :: unit \<Rightarrow> unit \<Rightarrow> bool" \<rightharpoonup>
   208     (Haskell) infix 4 "=="
   209 
   210 code_reserved SML
   211   unit
   212 
   213 code_reserved OCaml
   214   unit
   215 
   216 code_reserved Scala
   217   Unit
   218 
   219 
   220 subsection {* The product type *}
   221 
   222 subsubsection {* Type definition *}
   223 
   224 definition Pair_Rep :: "'a \<Rightarrow> 'b \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> bool" where
   225   "Pair_Rep a b = (\<lambda>x y. x = a \<and> y = b)"
   226 
   227 definition "prod = {f. \<exists>a b. f = Pair_Rep (a\<Colon>'a) (b\<Colon>'b)}"
   228 
   229 typedef ('a, 'b) prod (infixr "*" 20) = "prod :: ('a \<Rightarrow> 'b \<Rightarrow> bool) set"
   230   unfolding prod_def by auto
   231 
   232 type_notation (xsymbols)
   233   "prod"  ("(_ \<times>/ _)" [21, 20] 20)
   234 type_notation (HTML output)
   235   "prod"  ("(_ \<times>/ _)" [21, 20] 20)
   236 
   237 definition Pair :: "'a \<Rightarrow> 'b \<Rightarrow> 'a \<times> 'b" where
   238   "Pair a b = Abs_prod (Pair_Rep a b)"
   239 
   240 lemma prod_cases: "(\<And>a b. P (Pair a b)) \<Longrightarrow> P p"
   241   by (cases p) (auto simp add: prod_def Pair_def Pair_Rep_def)
   242 
   243 free_constructors case_prod for Pair fst snd
   244 proof -
   245   fix P :: bool and p :: "'a \<times> 'b"
   246   show "(\<And>x1 x2. p = Pair x1 x2 \<Longrightarrow> P) \<Longrightarrow> P"
   247     by (cases p) (auto simp add: prod_def Pair_def Pair_Rep_def)
   248 next
   249   fix a c :: 'a and b d :: 'b
   250   have "Pair_Rep a b = Pair_Rep c d \<longleftrightarrow> a = c \<and> b = d"
   251     by (auto simp add: Pair_Rep_def fun_eq_iff)
   252   moreover have "Pair_Rep a b \<in> prod" and "Pair_Rep c d \<in> prod"
   253     by (auto simp add: prod_def)
   254   ultimately show "Pair a b = Pair c d \<longleftrightarrow> a = c \<and> b = d"
   255     by (simp add: Pair_def Abs_prod_inject)
   256 qed
   257 
   258 text {* Avoid name clashes by prefixing the output of @{text old_rep_datatype} with @{text old}. *}
   259 
   260 setup {* Sign.mandatory_path "old" *}
   261 
   262 old_rep_datatype Pair
   263 by (erule prod_cases) (rule prod.inject)
   264 
   265 setup {* Sign.parent_path *}
   266 
   267 text {* But erase the prefix for properties that are not generated by @{text free_constructors}. *}
   268 
   269 setup {* Sign.mandatory_path "prod" *}
   270 
   271 declare
   272   old.prod.inject[iff del]
   273 
   274 lemmas induct = old.prod.induct
   275 lemmas inducts = old.prod.inducts
   276 lemmas rec = old.prod.rec
   277 lemmas simps = prod.inject prod.case prod.rec
   278 
   279 setup {* Sign.parent_path *}
   280 
   281 declare prod.case [nitpick_simp del]
   282 declare prod.case_cong_weak [cong del]
   283 
   284 
   285 subsubsection {* Tuple syntax *}
   286 
   287 abbreviation (input) split :: "('a \<Rightarrow> 'b \<Rightarrow> 'c) \<Rightarrow> 'a \<times> 'b \<Rightarrow> 'c" where
   288   "split \<equiv> case_prod"
   289 
   290 text {*
   291   Patterns -- extends pre-defined type @{typ pttrn} used in
   292   abstractions.
   293 *}
   294 
   295 nonterminal tuple_args and patterns
   296 
   297 syntax
   298   "_tuple"      :: "'a => tuple_args => 'a * 'b"        ("(1'(_,/ _'))")
   299   "_tuple_arg"  :: "'a => tuple_args"                   ("_")
   300   "_tuple_args" :: "'a => tuple_args => tuple_args"     ("_,/ _")
   301   "_pattern"    :: "[pttrn, patterns] => pttrn"         ("'(_,/ _')")
   302   ""            :: "pttrn => patterns"                  ("_")
   303   "_patterns"   :: "[pttrn, patterns] => patterns"      ("_,/ _")
   304 
   305 translations
   306   "(x, y)" == "CONST Pair x y"
   307   "_pattern x y" => "CONST Pair x y"
   308   "_patterns x y" => "CONST Pair x y"
   309   "_tuple x (_tuple_args y z)" == "_tuple x (_tuple_arg (_tuple y z))"
   310   "%(x, y, zs). b" == "CONST case_prod (%x (y, zs). b)"
   311   "%(x, y). b" == "CONST case_prod (%x y. b)"
   312   "_abs (CONST Pair x y) t" => "%(x, y). t"
   313   -- {* The last rule accommodates tuples in `case C ... (x,y) ... => ...'
   314      The (x,y) is parsed as `Pair x y' because it is logic, not pttrn *}
   315 
   316 (*reconstruct pattern from (nested) splits, avoiding eta-contraction of body;
   317   works best with enclosing "let", if "let" does not avoid eta-contraction*)
   318 print_translation {*
   319   let
   320     fun split_tr' [Abs (x, T, t as (Abs abs))] =
   321           (* split (%x y. t) => %(x,y) t *)
   322           let
   323             val (y, t') = Syntax_Trans.atomic_abs_tr' abs;
   324             val (x', t'') = Syntax_Trans.atomic_abs_tr' (x, T, t');
   325           in
   326             Syntax.const @{syntax_const "_abs"} $
   327               (Syntax.const @{syntax_const "_pattern"} $ x' $ y) $ t''
   328           end
   329       | split_tr' [Abs (x, T, (s as Const (@{const_syntax case_prod}, _) $ t))] =
   330           (* split (%x. (split (%y z. t))) => %(x,y,z). t *)
   331           let
   332             val Const (@{syntax_const "_abs"}, _) $
   333               (Const (@{syntax_const "_pattern"}, _) $ y $ z) $ t' = split_tr' [t];
   334             val (x', t'') = Syntax_Trans.atomic_abs_tr' (x, T, t');
   335           in
   336             Syntax.const @{syntax_const "_abs"} $
   337               (Syntax.const @{syntax_const "_pattern"} $ x' $
   338                 (Syntax.const @{syntax_const "_patterns"} $ y $ z)) $ t''
   339           end
   340       | split_tr' [Const (@{const_syntax case_prod}, _) $ t] =
   341           (* split (split (%x y z. t)) => %((x, y), z). t *)
   342           split_tr' [(split_tr' [t])] (* inner split_tr' creates next pattern *)
   343       | split_tr' [Const (@{syntax_const "_abs"}, _) $ x_y $ Abs abs] =
   344           (* split (%pttrn z. t) => %(pttrn,z). t *)
   345           let val (z, t) = Syntax_Trans.atomic_abs_tr' abs in
   346             Syntax.const @{syntax_const "_abs"} $
   347               (Syntax.const @{syntax_const "_pattern"} $ x_y $ z) $ t
   348           end
   349       | split_tr' _ = raise Match;
   350   in [(@{const_syntax case_prod}, K split_tr')] end
   351 *}
   352 
   353 (* print "split f" as "\<lambda>(x,y). f x y" and "split (\<lambda>x. f x)" as "\<lambda>(x,y). f x y" *) 
   354 typed_print_translation {*
   355   let
   356     fun split_guess_names_tr' T [Abs (x, _, Abs _)] = raise Match
   357       | split_guess_names_tr' T [Abs (x, xT, t)] =
   358           (case (head_of t) of
   359             Const (@{const_syntax case_prod}, _) => raise Match
   360           | _ =>
   361             let 
   362               val (_ :: yT :: _) = binder_types (domain_type T) handle Bind => raise Match;
   363               val (y, t') = Syntax_Trans.atomic_abs_tr' ("y", yT, incr_boundvars 1 t $ Bound 0);
   364               val (x', t'') = Syntax_Trans.atomic_abs_tr' (x, xT, t');
   365             in
   366               Syntax.const @{syntax_const "_abs"} $
   367                 (Syntax.const @{syntax_const "_pattern"} $ x' $ y) $ t''
   368             end)
   369       | split_guess_names_tr' T [t] =
   370           (case head_of t of
   371             Const (@{const_syntax case_prod}, _) => raise Match
   372           | _ =>
   373             let
   374               val (xT :: yT :: _) = binder_types (domain_type T) handle Bind => raise Match;
   375               val (y, t') =
   376                 Syntax_Trans.atomic_abs_tr' ("y", yT, incr_boundvars 2 t $ Bound 1 $ Bound 0);
   377               val (x', t'') = Syntax_Trans.atomic_abs_tr' ("x", xT, t');
   378             in
   379               Syntax.const @{syntax_const "_abs"} $
   380                 (Syntax.const @{syntax_const "_pattern"} $ x' $ y) $ t''
   381             end)
   382       | split_guess_names_tr' _ _ = raise Match;
   383   in [(@{const_syntax case_prod}, K split_guess_names_tr')] end
   384 *}
   385 
   386 
   387 subsubsection {* Code generator setup *}
   388 
   389 code_printing
   390   type_constructor prod \<rightharpoonup>
   391     (SML) infix 2 "*"
   392     and (OCaml) infix 2 "*"
   393     and (Haskell) "!((_),/ (_))"
   394     and (Scala) "((_),/ (_))"
   395 | constant Pair \<rightharpoonup>
   396     (SML) "!((_),/ (_))"
   397     and (OCaml) "!((_),/ (_))"
   398     and (Haskell) "!((_),/ (_))"
   399     and (Scala) "!((_),/ (_))"
   400 | class_instance  prod :: equal \<rightharpoonup>
   401     (Haskell) -
   402 | constant "HOL.equal :: 'a \<times> 'b \<Rightarrow> 'a \<times> 'b \<Rightarrow> bool" \<rightharpoonup>
   403     (Haskell) infix 4 "=="
   404 
   405 
   406 subsubsection {* Fundamental operations and properties *}
   407 
   408 lemma Pair_inject:
   409   assumes "(a, b) = (a', b')"
   410     and "a = a' ==> b = b' ==> R"
   411   shows R
   412   using assms by simp
   413 
   414 lemma surj_pair [simp]: "EX x y. p = (x, y)"
   415   by (cases p) simp
   416 
   417 code_printing
   418   constant fst \<rightharpoonup> (Haskell) "fst"
   419 | constant snd \<rightharpoonup> (Haskell) "snd"
   420 
   421 lemma case_prod_unfold [nitpick_unfold]: "case_prod = (%c p. c (fst p) (snd p))"
   422   by (simp add: fun_eq_iff split: prod.split)
   423 
   424 lemma fst_eqD: "fst (x, y) = a ==> x = a"
   425   by simp
   426 
   427 lemma snd_eqD: "snd (x, y) = a ==> y = a"
   428   by simp
   429 
   430 lemmas surjective_pairing = prod.collapse [symmetric]
   431 
   432 lemma prod_eq_iff: "s = t \<longleftrightarrow> fst s = fst t \<and> snd s = snd t"
   433   by (cases s, cases t) simp
   434 
   435 lemma prod_eqI [intro?]: "fst p = fst q \<Longrightarrow> snd p = snd q \<Longrightarrow> p = q"
   436   by (simp add: prod_eq_iff)
   437 
   438 lemma split_conv [simp, code]: "split f (a, b) = f a b"
   439   by (fact prod.case)
   440 
   441 lemma splitI: "f a b \<Longrightarrow> split f (a, b)"
   442   by (rule split_conv [THEN iffD2])
   443 
   444 lemma splitD: "split f (a, b) \<Longrightarrow> f a b"
   445   by (rule split_conv [THEN iffD1])
   446 
   447 lemma split_Pair [simp]: "(\<lambda>(x, y). (x, y)) = id"
   448   by (simp add: fun_eq_iff split: prod.split)
   449 
   450 lemma split_eta: "(\<lambda>(x, y). f (x, y)) = f"
   451   -- {* Subsumes the old @{text split_Pair} when @{term f} is the identity function. *}
   452   by (simp add: fun_eq_iff split: prod.split)
   453 
   454 lemma split_comp: "split (f \<circ> g) x = f (g (fst x)) (snd x)"
   455   by (cases x) simp
   456 
   457 lemma split_twice: "split f (split g p) = split (\<lambda>x y. split f (g x y)) p"
   458   by (cases p) simp
   459 
   460 lemma The_split: "The (split P) = (THE xy. P (fst xy) (snd xy))"
   461   by (simp add: case_prod_unfold)
   462 
   463 lemmas split_weak_cong = prod.case_cong_weak
   464   -- {* Prevents simplification of @{term c}: much faster *}
   465 
   466 lemma cond_split_eta: "(!!x y. f x y = g (x, y)) ==> (%(x, y). f x y) = g"
   467   by (simp add: split_eta)
   468 
   469 lemma split_paired_all [no_atp]: "(!!x. PROP P x) == (!!a b. PROP P (a, b))"
   470 proof
   471   fix a b
   472   assume "!!x. PROP P x"
   473   then show "PROP P (a, b)" .
   474 next
   475   fix x
   476   assume "!!a b. PROP P (a, b)"
   477   from `PROP P (fst x, snd x)` show "PROP P x" by simp
   478 qed
   479 
   480 lemma case_prod_distrib: "f (case x of (x, y) \<Rightarrow> g x y) = (case x of (x, y) \<Rightarrow> f (g x y))"
   481   by (cases x) simp
   482 
   483 text {*
   484   The rule @{thm [source] split_paired_all} does not work with the
   485   Simplifier because it also affects premises in congrence rules,
   486   where this can lead to premises of the form @{text "!!a b. ... =
   487   ?P(a, b)"} which cannot be solved by reflexivity.
   488 *}
   489 
   490 lemmas split_tupled_all = split_paired_all unit_all_eq2
   491 
   492 ML {*
   493   (* replace parameters of product type by individual component parameters *)
   494   local (* filtering with exists_paired_all is an essential optimization *)
   495     fun exists_paired_all (Const (@{const_name Pure.all}, _) $ Abs (_, T, t)) =
   496           can HOLogic.dest_prodT T orelse exists_paired_all t
   497       | exists_paired_all (t $ u) = exists_paired_all t orelse exists_paired_all u
   498       | exists_paired_all (Abs (_, _, t)) = exists_paired_all t
   499       | exists_paired_all _ = false;
   500     val ss =
   501       simpset_of
   502        (put_simpset HOL_basic_ss @{context}
   503         addsimps [@{thm split_paired_all}, @{thm unit_all_eq2}, @{thm unit_abs_eta_conv}]
   504         addsimprocs [@{simproc unit_eq}]);
   505   in
   506     fun split_all_tac ctxt = SUBGOAL (fn (t, i) =>
   507       if exists_paired_all t then safe_full_simp_tac (put_simpset ss ctxt) i else no_tac);
   508 
   509     fun unsafe_split_all_tac ctxt = SUBGOAL (fn (t, i) =>
   510       if exists_paired_all t then full_simp_tac (put_simpset ss ctxt) i else no_tac);
   511 
   512     fun split_all ctxt th =
   513       if exists_paired_all (Thm.prop_of th)
   514       then full_simplify (put_simpset ss ctxt) th else th;
   515   end;
   516 *}
   517 
   518 setup {* map_theory_claset (fn ctxt => ctxt addSbefore ("split_all_tac", split_all_tac)) *}
   519 
   520 lemma split_paired_All [simp, no_atp]: "(ALL x. P x) = (ALL a b. P (a, b))"
   521   -- {* @{text "[iff]"} is not a good idea because it makes @{text blast} loop *}
   522   by fast
   523 
   524 lemma split_paired_Ex [simp, no_atp]: "(EX x. P x) = (EX a b. P (a, b))"
   525   by fast
   526 
   527 lemma split_paired_The [no_atp]: "(THE x. P x) = (THE (a, b). P (a, b))"
   528   -- {* Can't be added to simpset: loops! *}
   529   by (simp add: split_eta)
   530 
   531 text {*
   532   Simplification procedure for @{thm [source] cond_split_eta}.  Using
   533   @{thm [source] split_eta} as a rewrite rule is not general enough,
   534   and using @{thm [source] cond_split_eta} directly would render some
   535   existing proofs very inefficient; similarly for @{text
   536   split_beta}.
   537 *}
   538 
   539 ML {*
   540 local
   541   val cond_split_eta_ss =
   542     simpset_of (put_simpset HOL_basic_ss @{context} addsimps @{thms cond_split_eta});
   543   fun Pair_pat k 0 (Bound m) = (m = k)
   544     | Pair_pat k i (Const (@{const_name Pair},  _) $ Bound m $ t) =
   545         i > 0 andalso m = k + i andalso Pair_pat k (i - 1) t
   546     | Pair_pat _ _ _ = false;
   547   fun no_args k i (Abs (_, _, t)) = no_args (k + 1) i t
   548     | no_args k i (t $ u) = no_args k i t andalso no_args k i u
   549     | no_args k i (Bound m) = m < k orelse m > k + i
   550     | no_args _ _ _ = true;
   551   fun split_pat tp i (Abs  (_, _, t)) = if tp 0 i t then SOME (i, t) else NONE
   552     | split_pat tp i (Const (@{const_name case_prod}, _) $ Abs (_, _, t)) = split_pat tp (i + 1) t
   553     | split_pat tp i _ = NONE;
   554   fun metaeq ctxt lhs rhs = mk_meta_eq (Goal.prove ctxt [] []
   555         (HOLogic.mk_Trueprop (HOLogic.mk_eq (lhs, rhs)))
   556         (K (simp_tac (put_simpset cond_split_eta_ss ctxt) 1)));
   557 
   558   fun beta_term_pat k i (Abs (_, _, t)) = beta_term_pat (k + 1) i t
   559     | beta_term_pat k i (t $ u) =
   560         Pair_pat k i (t $ u) orelse (beta_term_pat k i t andalso beta_term_pat k i u)
   561     | beta_term_pat k i t = no_args k i t;
   562   fun eta_term_pat k i (f $ arg) = no_args k i f andalso Pair_pat k i arg
   563     | eta_term_pat _ _ _ = false;
   564   fun subst arg k i (Abs (x, T, t)) = Abs (x, T, subst arg (k+1) i t)
   565     | subst arg k i (t $ u) =
   566         if Pair_pat k i (t $ u) then incr_boundvars k arg
   567         else (subst arg k i t $ subst arg k i u)
   568     | subst arg k i t = t;
   569 in
   570   fun beta_proc ctxt (s as Const (@{const_name case_prod}, _) $ Abs (_, _, t) $ arg) =
   571         (case split_pat beta_term_pat 1 t of
   572           SOME (i, f) => SOME (metaeq ctxt s (subst arg 0 i f))
   573         | NONE => NONE)
   574     | beta_proc _ _ = NONE;
   575   fun eta_proc ctxt (s as Const (@{const_name case_prod}, _) $ Abs (_, _, t)) =
   576         (case split_pat eta_term_pat 1 t of
   577           SOME (_, ft) => SOME (metaeq ctxt s (let val f $ _ = ft in f end))
   578         | NONE => NONE)
   579     | eta_proc _ _ = NONE;
   580 end;
   581 *}
   582 simproc_setup split_beta ("split f z") = {* fn _ => fn ctxt => fn ct => beta_proc ctxt (term_of ct) *}
   583 simproc_setup split_eta ("split f") = {* fn _ => fn ctxt => fn ct => eta_proc ctxt (term_of ct) *}
   584 
   585 lemmas split_beta [mono] = prod.case_eq_if
   586 
   587 lemma split_beta': "(\<lambda>(x,y). f x y) = (\<lambda>x. f (fst x) (snd x))"
   588   by (auto simp: fun_eq_iff)
   589 
   590 lemmas split_split [no_atp] = prod.split
   591   -- {* For use with @{text split} and the Simplifier. *}
   592 
   593 text {*
   594   @{thm [source] split_split} could be declared as @{text "[split]"}
   595   done after the Splitter has been speeded up significantly;
   596   precompute the constants involved and don't do anything unless the
   597   current goal contains one of those constants.
   598 *}
   599 
   600 lemmas split_split_asm [no_atp] = prod.split_asm
   601 
   602 text {*
   603   \medskip @{term split} used as a logical connective or set former.
   604 
   605   \medskip These rules are for use with @{text blast}; could instead
   606   call @{text simp} using @{thm [source] prod.split} as rewrite. *}
   607 
   608 lemma splitI2: "!!p. [| !!a b. p = (a, b) ==> c a b |] ==> split c p"
   609   apply (simp only: split_tupled_all)
   610   apply (simp (no_asm_simp))
   611   done
   612 
   613 lemma splitI2': "!!p. [| !!a b. (a, b) = p ==> c a b x |] ==> split c p x"
   614   apply (simp only: split_tupled_all)
   615   apply (simp (no_asm_simp))
   616   done
   617 
   618 lemma splitE: "split c p ==> (!!x y. p = (x, y) ==> c x y ==> Q) ==> Q"
   619   by (induct p) auto
   620 
   621 lemma splitE': "split c p z ==> (!!x y. p = (x, y) ==> c x y z ==> Q) ==> Q"
   622   by (induct p) auto
   623 
   624 lemma splitE2:
   625   "[| Q (split P z);  !!x y. [|z = (x, y); Q (P x y)|] ==> R |] ==> R"
   626 proof -
   627   assume q: "Q (split P z)"
   628   assume r: "!!x y. [|z = (x, y); Q (P x y)|] ==> R"
   629   show R
   630     apply (rule r surjective_pairing)+
   631     apply (rule split_beta [THEN subst], rule q)
   632     done
   633 qed
   634 
   635 lemma splitD': "split R (a,b) c ==> R a b c"
   636   by simp
   637 
   638 lemma mem_splitI: "z: c a b ==> z: split c (a, b)"
   639   by simp
   640 
   641 lemma mem_splitI2: "!!p. [| !!a b. p = (a, b) ==> z: c a b |] ==> z: split c p"
   642 by (simp only: split_tupled_all, simp)
   643 
   644 lemma mem_splitE:
   645   assumes "z \<in> split c p"
   646   obtains x y where "p = (x, y)" and "z \<in> c x y"
   647   using assms by (rule splitE2)
   648 
   649 declare mem_splitI2 [intro!] mem_splitI [intro!] splitI2' [intro!] splitI2 [intro!] splitI [intro!]
   650 declare mem_splitE [elim!] splitE' [elim!] splitE [elim!]
   651 
   652 ML {*
   653 local (* filtering with exists_p_split is an essential optimization *)
   654   fun exists_p_split (Const (@{const_name case_prod},_) $ _ $ (Const (@{const_name Pair},_)$_$_)) = true
   655     | exists_p_split (t $ u) = exists_p_split t orelse exists_p_split u
   656     | exists_p_split (Abs (_, _, t)) = exists_p_split t
   657     | exists_p_split _ = false;
   658 in
   659 fun split_conv_tac ctxt = SUBGOAL (fn (t, i) =>
   660   if exists_p_split t
   661   then safe_full_simp_tac (put_simpset HOL_basic_ss ctxt addsimps @{thms split_conv}) i
   662   else no_tac);
   663 end;
   664 *}
   665 
   666 (* This prevents applications of splitE for already splitted arguments leading
   667    to quite time-consuming computations (in particular for nested tuples) *)
   668 setup {* map_theory_claset (fn ctxt => ctxt addSbefore ("split_conv_tac", split_conv_tac)) *}
   669 
   670 lemma split_eta_SetCompr [simp, no_atp]: "(%u. EX x y. u = (x, y) & P (x, y)) = P"
   671   by (rule ext) fast
   672 
   673 lemma split_eta_SetCompr2 [simp, no_atp]: "(%u. EX x y. u = (x, y) & P x y) = split P"
   674   by (rule ext) fast
   675 
   676 lemma split_part [simp]: "(%(a,b). P & Q a b) = (%ab. P & split Q ab)"
   677   -- {* Allows simplifications of nested splits in case of independent predicates. *}
   678   by (rule ext) blast
   679 
   680 (* Do NOT make this a simp rule as it
   681    a) only helps in special situations
   682    b) can lead to nontermination in the presence of split_def
   683 *)
   684 lemma split_comp_eq: 
   685   fixes f :: "'a => 'b => 'c" and g :: "'d => 'a"
   686   shows "(%u. f (g (fst u)) (snd u)) = (split (%x. f (g x)))"
   687   by (rule ext) auto
   688 
   689 lemma pair_imageI [intro]: "(a, b) : A ==> f a b : (%(a, b). f a b) ` A"
   690   apply (rule_tac x = "(a, b)" in image_eqI)
   691    apply auto
   692   done
   693 
   694 lemma The_split_eq [simp]: "(THE (x',y'). x = x' & y = y') = (x, y)"
   695   by blast
   696 
   697 (*
   698 the following  would be slightly more general,
   699 but cannot be used as rewrite rule:
   700 ### Cannot add premise as rewrite rule because it contains (type) unknowns:
   701 ### ?y = .x
   702 Goal "[| P y; !!x. P x ==> x = y |] ==> (@(x',y). x = x' & P y) = (x,y)"
   703 by (rtac some_equality 1)
   704 by ( Simp_tac 1)
   705 by (split_all_tac 1)
   706 by (Asm_full_simp_tac 1)
   707 qed "The_split_eq";
   708 *)
   709 
   710 text {*
   711   Setup of internal @{text split_rule}.
   712 *}
   713 
   714 lemmas case_prodI = prod.case [THEN iffD2]
   715 
   716 lemma case_prodI2: "!!p. [| !!a b. p = (a, b) ==> c a b |] ==> case_prod c p"
   717   by (fact splitI2)
   718 
   719 lemma case_prodI2': "!!p. [| !!a b. (a, b) = p ==> c a b x |] ==> case_prod c p x"
   720   by (fact splitI2')
   721 
   722 lemma case_prodE: "case_prod c p ==> (!!x y. p = (x, y) ==> c x y ==> Q) ==> Q"
   723   by (fact splitE)
   724 
   725 lemma case_prodE': "case_prod c p z ==> (!!x y. p = (x, y) ==> c x y z ==> Q) ==> Q"
   726   by (fact splitE')
   727 
   728 declare case_prodI [intro!]
   729 
   730 lemma case_prod_beta:
   731   "case_prod f p = f (fst p) (snd p)"
   732   by (fact split_beta)
   733 
   734 lemma prod_cases3 [cases type]:
   735   obtains (fields) a b c where "y = (a, b, c)"
   736   by (cases y, case_tac b) blast
   737 
   738 lemma prod_induct3 [case_names fields, induct type]:
   739     "(!!a b c. P (a, b, c)) ==> P x"
   740   by (cases x) blast
   741 
   742 lemma prod_cases4 [cases type]:
   743   obtains (fields) a b c d where "y = (a, b, c, d)"
   744   by (cases y, case_tac c) blast
   745 
   746 lemma prod_induct4 [case_names fields, induct type]:
   747     "(!!a b c d. P (a, b, c, d)) ==> P x"
   748   by (cases x) blast
   749 
   750 lemma prod_cases5 [cases type]:
   751   obtains (fields) a b c d e where "y = (a, b, c, d, e)"
   752   by (cases y, case_tac d) blast
   753 
   754 lemma prod_induct5 [case_names fields, induct type]:
   755     "(!!a b c d e. P (a, b, c, d, e)) ==> P x"
   756   by (cases x) blast
   757 
   758 lemma prod_cases6 [cases type]:
   759   obtains (fields) a b c d e f where "y = (a, b, c, d, e, f)"
   760   by (cases y, case_tac e) blast
   761 
   762 lemma prod_induct6 [case_names fields, induct type]:
   763     "(!!a b c d e f. P (a, b, c, d, e, f)) ==> P x"
   764   by (cases x) blast
   765 
   766 lemma prod_cases7 [cases type]:
   767   obtains (fields) a b c d e f g where "y = (a, b, c, d, e, f, g)"
   768   by (cases y, case_tac f) blast
   769 
   770 lemma prod_induct7 [case_names fields, induct type]:
   771     "(!!a b c d e f g. P (a, b, c, d, e, f, g)) ==> P x"
   772   by (cases x) blast
   773 
   774 lemma split_def:
   775   "split = (\<lambda>c p. c (fst p) (snd p))"
   776   by (fact case_prod_unfold)
   777 
   778 definition internal_split :: "('a \<Rightarrow> 'b \<Rightarrow> 'c) \<Rightarrow> 'a \<times> 'b \<Rightarrow> 'c" where
   779   "internal_split == split"
   780 
   781 lemma internal_split_conv: "internal_split c (a, b) = c a b"
   782   by (simp only: internal_split_def split_conv)
   783 
   784 ML_file "Tools/split_rule.ML"
   785 
   786 hide_const internal_split
   787 
   788 
   789 subsubsection {* Derived operations *}
   790 
   791 definition curry    :: "('a \<times> 'b \<Rightarrow> 'c) \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'c" where
   792   "curry = (\<lambda>c x y. c (x, y))"
   793 
   794 lemma curry_conv [simp, code]: "curry f a b = f (a, b)"
   795   by (simp add: curry_def)
   796 
   797 lemma curryI [intro!]: "f (a, b) \<Longrightarrow> curry f a b"
   798   by (simp add: curry_def)
   799 
   800 lemma curryD [dest!]: "curry f a b \<Longrightarrow> f (a, b)"
   801   by (simp add: curry_def)
   802 
   803 lemma curryE: "curry f a b \<Longrightarrow> (f (a, b) \<Longrightarrow> Q) \<Longrightarrow> Q"
   804   by (simp add: curry_def)
   805 
   806 lemma curry_split [simp]: "curry (split f) = f"
   807   by (simp add: curry_def split_def)
   808 
   809 lemma split_curry [simp]: "split (curry f) = f"
   810   by (simp add: curry_def split_def)
   811 
   812 lemma curry_K: "curry (\<lambda>x. c) = (\<lambda>x y. c)"
   813 by(simp add: fun_eq_iff)
   814 
   815 text {*
   816   The composition-uncurry combinator.
   817 *}
   818 
   819 notation fcomp (infixl "\<circ>>" 60)
   820 
   821 definition scomp :: "('a \<Rightarrow> 'b \<times> 'c) \<Rightarrow> ('b \<Rightarrow> 'c \<Rightarrow> 'd) \<Rightarrow> 'a \<Rightarrow> 'd" (infixl "\<circ>\<rightarrow>" 60) where
   822   "f \<circ>\<rightarrow> g = (\<lambda>x. case_prod g (f x))"
   823 
   824 lemma scomp_unfold: "scomp = (\<lambda>f g x. g (fst (f x)) (snd (f x)))"
   825   by (simp add: fun_eq_iff scomp_def case_prod_unfold)
   826 
   827 lemma scomp_apply [simp]: "(f \<circ>\<rightarrow> g) x = case_prod g (f x)"
   828   by (simp add: scomp_unfold case_prod_unfold)
   829 
   830 lemma Pair_scomp: "Pair x \<circ>\<rightarrow> f = f x"
   831   by (simp add: fun_eq_iff)
   832 
   833 lemma scomp_Pair: "x \<circ>\<rightarrow> Pair = x"
   834   by (simp add: fun_eq_iff)
   835 
   836 lemma scomp_scomp: "(f \<circ>\<rightarrow> g) \<circ>\<rightarrow> h = f \<circ>\<rightarrow> (\<lambda>x. g x \<circ>\<rightarrow> h)"
   837   by (simp add: fun_eq_iff scomp_unfold)
   838 
   839 lemma scomp_fcomp: "(f \<circ>\<rightarrow> g) \<circ>> h = f \<circ>\<rightarrow> (\<lambda>x. g x \<circ>> h)"
   840   by (simp add: fun_eq_iff scomp_unfold fcomp_def)
   841 
   842 lemma fcomp_scomp: "(f \<circ>> g) \<circ>\<rightarrow> h = f \<circ>> (g \<circ>\<rightarrow> h)"
   843   by (simp add: fun_eq_iff scomp_unfold)
   844 
   845 code_printing
   846   constant scomp \<rightharpoonup> (Eval) infixl 3 "#->"
   847 
   848 no_notation fcomp (infixl "\<circ>>" 60)
   849 no_notation scomp (infixl "\<circ>\<rightarrow>" 60)
   850 
   851 text {*
   852   @{term map_prod} --- action of the product functor upon
   853   functions.
   854 *}
   855 
   856 definition map_prod :: "('a \<Rightarrow> 'c) \<Rightarrow> ('b \<Rightarrow> 'd) \<Rightarrow> 'a \<times> 'b \<Rightarrow> 'c \<times> 'd" where
   857   "map_prod f g = (\<lambda>(x, y). (f x, g y))"
   858 
   859 lemma map_prod_simp [simp, code]:
   860   "map_prod f g (a, b) = (f a, g b)"
   861   by (simp add: map_prod_def)
   862 
   863 functor map_prod: map_prod
   864   by (auto simp add: split_paired_all)
   865 
   866 lemma fst_map_prod [simp]:
   867   "fst (map_prod f g x) = f (fst x)"
   868   by (cases x) simp_all
   869 
   870 lemma snd_prod_fun [simp]:
   871   "snd (map_prod f g x) = g (snd x)"
   872   by (cases x) simp_all
   873 
   874 lemma fst_comp_map_prod [simp]:
   875   "fst \<circ> map_prod f g = f \<circ> fst"
   876   by (rule ext) simp_all
   877 
   878 lemma snd_comp_map_prod [simp]:
   879   "snd \<circ> map_prod f g = g \<circ> snd"
   880   by (rule ext) simp_all
   881 
   882 lemma map_prod_compose:
   883   "map_prod (f1 o f2) (g1 o g2) = (map_prod f1 g1 o map_prod f2 g2)"
   884   by (rule ext) (simp add: map_prod.compositionality comp_def)
   885 
   886 lemma map_prod_ident [simp]:
   887   "map_prod (%x. x) (%y. y) = (%z. z)"
   888   by (rule ext) (simp add: map_prod.identity)
   889 
   890 lemma map_prod_imageI [intro]:
   891   "(a, b) \<in> R \<Longrightarrow> (f a, g b) \<in> map_prod f g ` R"
   892   by (rule image_eqI) simp_all
   893 
   894 lemma prod_fun_imageE [elim!]:
   895   assumes major: "c \<in> map_prod f g ` R"
   896     and cases: "\<And>x y. c = (f x, g y) \<Longrightarrow> (x, y) \<in> R \<Longrightarrow> P"
   897   shows P
   898   apply (rule major [THEN imageE])
   899   apply (case_tac x)
   900   apply (rule cases)
   901   apply simp_all
   902   done
   903 
   904 definition apfst :: "('a \<Rightarrow> 'c) \<Rightarrow> 'a \<times> 'b \<Rightarrow> 'c \<times> 'b" where
   905   "apfst f = map_prod f id"
   906 
   907 definition apsnd :: "('b \<Rightarrow> 'c) \<Rightarrow> 'a \<times> 'b \<Rightarrow> 'a \<times> 'c" where
   908   "apsnd f = map_prod id f"
   909 
   910 lemma apfst_conv [simp, code]:
   911   "apfst f (x, y) = (f x, y)" 
   912   by (simp add: apfst_def)
   913 
   914 lemma apsnd_conv [simp, code]:
   915   "apsnd f (x, y) = (x, f y)" 
   916   by (simp add: apsnd_def)
   917 
   918 lemma fst_apfst [simp]:
   919   "fst (apfst f x) = f (fst x)"
   920   by (cases x) simp
   921 
   922 lemma fst_comp_apfst [simp]:
   923   "fst \<circ> apfst f = f \<circ> fst"
   924   by (simp add: fun_eq_iff)
   925 
   926 lemma fst_apsnd [simp]:
   927   "fst (apsnd f x) = fst x"
   928   by (cases x) simp
   929 
   930 lemma fst_comp_apsnd [simp]:
   931   "fst \<circ> apsnd f = fst"
   932   by (simp add: fun_eq_iff)
   933 
   934 lemma snd_apfst [simp]:
   935   "snd (apfst f x) = snd x"
   936   by (cases x) simp
   937 
   938 lemma snd_comp_apfst [simp]:
   939   "snd \<circ> apfst f = snd"
   940   by (simp add: fun_eq_iff)
   941 
   942 lemma snd_apsnd [simp]:
   943   "snd (apsnd f x) = f (snd x)"
   944   by (cases x) simp
   945 
   946 lemma snd_comp_apsnd [simp]:
   947   "snd \<circ> apsnd f = f \<circ> snd"
   948   by (simp add: fun_eq_iff)
   949 
   950 lemma apfst_compose:
   951   "apfst f (apfst g x) = apfst (f \<circ> g) x"
   952   by (cases x) simp
   953 
   954 lemma apsnd_compose:
   955   "apsnd f (apsnd g x) = apsnd (f \<circ> g) x"
   956   by (cases x) simp
   957 
   958 lemma apfst_apsnd [simp]:
   959   "apfst f (apsnd g x) = (f (fst x), g (snd x))"
   960   by (cases x) simp
   961 
   962 lemma apsnd_apfst [simp]:
   963   "apsnd f (apfst g x) = (g (fst x), f (snd x))"
   964   by (cases x) simp
   965 
   966 lemma apfst_id [simp] :
   967   "apfst id = id"
   968   by (simp add: fun_eq_iff)
   969 
   970 lemma apsnd_id [simp] :
   971   "apsnd id = id"
   972   by (simp add: fun_eq_iff)
   973 
   974 lemma apfst_eq_conv [simp]:
   975   "apfst f x = apfst g x \<longleftrightarrow> f (fst x) = g (fst x)"
   976   by (cases x) simp
   977 
   978 lemma apsnd_eq_conv [simp]:
   979   "apsnd f x = apsnd g x \<longleftrightarrow> f (snd x) = g (snd x)"
   980   by (cases x) simp
   981 
   982 lemma apsnd_apfst_commute:
   983   "apsnd f (apfst g p) = apfst g (apsnd f p)"
   984   by simp
   985 
   986 context
   987 begin
   988 
   989 local_setup {* Local_Theory.map_naming (Name_Space.mandatory_path "prod") *}
   990 
   991 definition swap :: "'a \<times> 'b \<Rightarrow> 'b \<times> 'a"
   992 where
   993   "swap p = (snd p, fst p)"
   994 
   995 end
   996 
   997 lemma swap_simp [simp]:
   998   "prod.swap (x, y) = (y, x)"
   999   by (simp add: prod.swap_def)
  1000 
  1001 lemma swap_swap [simp]:
  1002   "prod.swap (prod.swap p) = p"
  1003   by (cases p) simp
  1004 
  1005 lemma swap_comp_swap [simp]:
  1006   "prod.swap \<circ> prod.swap = id"
  1007   by (simp add: fun_eq_iff)
  1008 
  1009 lemma pair_in_swap_image [simp]:
  1010   "(y, x) \<in> prod.swap ` A \<longleftrightarrow> (x, y) \<in> A"
  1011   by (auto intro!: image_eqI)
  1012 
  1013 lemma inj_swap [simp]:
  1014   "inj_on prod.swap A"
  1015   by (rule inj_onI) auto
  1016 
  1017 lemma swap_inj_on:
  1018   "inj_on (\<lambda>(i, j). (j, i)) A"
  1019   by (rule inj_onI) auto
  1020 
  1021 lemma surj_swap [simp]:
  1022   "surj prod.swap"
  1023   by (rule surjI [of _ prod.swap]) simp
  1024 
  1025 lemma bij_swap [simp]:
  1026   "bij prod.swap"
  1027   by (simp add: bij_def)
  1028 
  1029 lemma case_swap [simp]:
  1030   "(case prod.swap p of (y, x) \<Rightarrow> f x y) = (case p of (x, y) \<Rightarrow> f x y)"
  1031   by (cases p) simp
  1032 
  1033 text {*
  1034   Disjoint union of a family of sets -- Sigma.
  1035 *}
  1036 
  1037 definition Sigma :: "'a set \<Rightarrow> ('a \<Rightarrow> 'b set) \<Rightarrow> ('a \<times> 'b) set" where
  1038   Sigma_def: "Sigma A B == UN x:A. UN y:B x. {Pair x y}"
  1039 
  1040 abbreviation
  1041   Times :: "'a set \<Rightarrow> 'b set \<Rightarrow> ('a \<times> 'b) set"
  1042     (infixr "<*>" 80) where
  1043   "A <*> B == Sigma A (%_. B)"
  1044 
  1045 notation (xsymbols)
  1046   Times  (infixr "\<times>" 80)
  1047 
  1048 notation (HTML output)
  1049   Times  (infixr "\<times>" 80)
  1050 
  1051 hide_const (open) Times
  1052 
  1053 syntax
  1054   "_Sigma" :: "[pttrn, 'a set, 'b set] => ('a * 'b) set"  ("(3SIGMA _:_./ _)" [0, 0, 10] 10)
  1055 translations
  1056   "SIGMA x:A. B" == "CONST Sigma A (%x. B)"
  1057 
  1058 lemma SigmaI [intro!]: "[| a:A;  b:B(a) |] ==> (a,b) : Sigma A B"
  1059   by (unfold Sigma_def) blast
  1060 
  1061 lemma SigmaE [elim!]:
  1062     "[| c: Sigma A B;
  1063         !!x y.[| x:A;  y:B(x);  c=(x,y) |] ==> P
  1064      |] ==> P"
  1065   -- {* The general elimination rule. *}
  1066   by (unfold Sigma_def) blast
  1067 
  1068 text {*
  1069   Elimination of @{term "(a, b) : A \<times> B"} -- introduces no
  1070   eigenvariables.
  1071 *}
  1072 
  1073 lemma SigmaD1: "(a, b) : Sigma A B ==> a : A"
  1074   by blast
  1075 
  1076 lemma SigmaD2: "(a, b) : Sigma A B ==> b : B a"
  1077   by blast
  1078 
  1079 lemma SigmaE2:
  1080     "[| (a, b) : Sigma A B;
  1081         [| a:A;  b:B(a) |] ==> P
  1082      |] ==> P"
  1083   by blast
  1084 
  1085 lemma Sigma_cong:
  1086      "\<lbrakk>A = B; !!x. x \<in> B \<Longrightarrow> C x = D x\<rbrakk>
  1087       \<Longrightarrow> (SIGMA x: A. C x) = (SIGMA x: B. D x)"
  1088   by auto
  1089 
  1090 lemma Sigma_mono: "[| A <= C; !!x. x:A ==> B x <= D x |] ==> Sigma A B <= Sigma C D"
  1091   by blast
  1092 
  1093 lemma Sigma_empty1 [simp]: "Sigma {} B = {}"
  1094   by blast
  1095 
  1096 lemma Sigma_empty2 [simp]: "A <*> {} = {}"
  1097   by blast
  1098 
  1099 lemma UNIV_Times_UNIV [simp]: "UNIV <*> UNIV = UNIV"
  1100   by auto
  1101 
  1102 lemma Compl_Times_UNIV1 [simp]: "- (UNIV <*> A) = UNIV <*> (-A)"
  1103   by auto
  1104 
  1105 lemma Compl_Times_UNIV2 [simp]: "- (A <*> UNIV) = (-A) <*> UNIV"
  1106   by auto
  1107 
  1108 lemma mem_Sigma_iff [iff]: "((a,b): Sigma A B) = (a:A & b:B(a))"
  1109   by blast
  1110 
  1111 lemma Times_subset_cancel2: "x:C ==> (A <*> C <= B <*> C) = (A <= B)"
  1112   by blast
  1113 
  1114 lemma Times_eq_cancel2: "x:C ==> (A <*> C = B <*> C) = (A = B)"
  1115   by (blast elim: equalityE)
  1116 
  1117 lemma SetCompr_Sigma_eq:
  1118     "Collect (split (%x y. P x & Q x y)) = (SIGMA x:Collect P. Collect (Q x))"
  1119   by blast
  1120 
  1121 lemma Collect_split [simp]: "{(a,b). P a & Q b} = Collect P <*> Collect Q"
  1122   by blast
  1123 
  1124 lemma UN_Times_distrib:
  1125   "(UN (a,b):(A <*> B). E a <*> F b) = (UNION A E) <*> (UNION B F)"
  1126   -- {* Suggested by Pierre Chartier *}
  1127   by blast
  1128 
  1129 lemma split_paired_Ball_Sigma [simp, no_atp]:
  1130     "(ALL z: Sigma A B. P z) = (ALL x:A. ALL y: B x. P(x,y))"
  1131   by blast
  1132 
  1133 lemma split_paired_Bex_Sigma [simp, no_atp]:
  1134     "(EX z: Sigma A B. P z) = (EX x:A. EX y: B x. P(x,y))"
  1135   by blast
  1136 
  1137 lemma Sigma_Un_distrib1: "(SIGMA i:I Un J. C(i)) = (SIGMA i:I. C(i)) Un (SIGMA j:J. C(j))"
  1138   by blast
  1139 
  1140 lemma Sigma_Un_distrib2: "(SIGMA i:I. A(i) Un B(i)) = (SIGMA i:I. A(i)) Un (SIGMA i:I. B(i))"
  1141   by blast
  1142 
  1143 lemma Sigma_Int_distrib1: "(SIGMA i:I Int J. C(i)) = (SIGMA i:I. C(i)) Int (SIGMA j:J. C(j))"
  1144   by blast
  1145 
  1146 lemma Sigma_Int_distrib2: "(SIGMA i:I. A(i) Int B(i)) = (SIGMA i:I. A(i)) Int (SIGMA i:I. B(i))"
  1147   by blast
  1148 
  1149 lemma Sigma_Diff_distrib1: "(SIGMA i:I - J. C(i)) = (SIGMA i:I. C(i)) - (SIGMA j:J. C(j))"
  1150   by blast
  1151 
  1152 lemma Sigma_Diff_distrib2: "(SIGMA i:I. A(i) - B(i)) = (SIGMA i:I. A(i)) - (SIGMA i:I. B(i))"
  1153   by blast
  1154 
  1155 lemma Sigma_Union: "Sigma (Union X) B = (UN A:X. Sigma A B)"
  1156   by blast
  1157 
  1158 text {*
  1159   Non-dependent versions are needed to avoid the need for higher-order
  1160   matching, especially when the rules are re-oriented.
  1161 *}
  1162 
  1163 lemma Times_Un_distrib1: "(A Un B) <*> C = (A <*> C) Un (B <*> C)"
  1164   by (fact Sigma_Un_distrib1)
  1165 
  1166 lemma Times_Int_distrib1: "(A Int B) <*> C = (A <*> C) Int (B <*> C)"
  1167   by (fact Sigma_Int_distrib1)
  1168 
  1169 lemma Times_Diff_distrib1: "(A - B) <*> C = (A <*> C) - (B <*> C)"
  1170   by (fact Sigma_Diff_distrib1)
  1171 
  1172 lemma Times_empty[simp]: "A \<times> B = {} \<longleftrightarrow> A = {} \<or> B = {}"
  1173   by auto
  1174 
  1175 lemma times_eq_iff: "A \<times> B = C \<times> D \<longleftrightarrow> A = C \<and> B = D \<or> ((A = {} \<or> B = {}) \<and> (C = {} \<or> D = {}))"
  1176   by auto
  1177 
  1178 lemma fst_image_times[simp]: "fst ` (A \<times> B) = (if B = {} then {} else A)"
  1179   by force
  1180 
  1181 lemma snd_image_times[simp]: "snd ` (A \<times> B) = (if A = {} then {} else B)"
  1182   by force
  1183 
  1184 lemma vimage_fst:
  1185   "fst -` A = A \<times> UNIV"
  1186   by auto
  1187 
  1188 lemma vimage_snd:
  1189   "snd -` A = UNIV \<times> A"
  1190   by auto
  1191 
  1192 lemma insert_times_insert[simp]:
  1193   "insert a A \<times> insert b B =
  1194    insert (a,b) (A \<times> insert b B \<union> insert a A \<times> B)"
  1195 by blast
  1196 
  1197 lemma vimage_Times: "f -` (A \<times> B) = ((fst \<circ> f) -` A) \<inter> ((snd \<circ> f) -` B)"
  1198   apply auto
  1199   apply (case_tac "f x")
  1200   apply auto
  1201   done
  1202 
  1203 lemma times_Int_times: "A \<times> B \<inter> C \<times> D = (A \<inter> C) \<times> (B \<inter> D)"
  1204   by auto
  1205 
  1206 lemma product_swap:
  1207   "prod.swap ` (A \<times> B) = B \<times> A"
  1208   by (auto simp add: set_eq_iff)
  1209 
  1210 lemma swap_product:
  1211   "(\<lambda>(i, j). (j, i)) ` (A \<times> B) = B \<times> A"
  1212   by (auto simp add: set_eq_iff)
  1213 
  1214 lemma image_split_eq_Sigma:
  1215   "(\<lambda>x. (f x, g x)) ` A = Sigma (f ` A) (\<lambda>x. g ` (f -` {x} \<inter> A))"
  1216 proof (safe intro!: imageI)
  1217   fix a b assume *: "a \<in> A" "b \<in> A" and eq: "f a = f b"
  1218   show "(f b, g a) \<in> (\<lambda>x. (f x, g x)) ` A"
  1219     using * eq[symmetric] by auto
  1220 qed simp_all
  1221 
  1222 definition product :: "'a set \<Rightarrow> 'b set \<Rightarrow> ('a \<times> 'b) set" where
  1223   [code_abbrev]: "product A B = A \<times> B"
  1224 
  1225 hide_const (open) product
  1226 
  1227 lemma member_product:
  1228   "x \<in> Product_Type.product A B \<longleftrightarrow> x \<in> A \<times> B"
  1229   by (simp add: product_def)
  1230 
  1231 text {* The following @{const map_prod} lemmas are due to Joachim Breitner: *}
  1232 
  1233 lemma map_prod_inj_on:
  1234   assumes "inj_on f A" and "inj_on g B"
  1235   shows "inj_on (map_prod f g) (A \<times> B)"
  1236 proof (rule inj_onI)
  1237   fix x :: "'a \<times> 'c" and y :: "'a \<times> 'c"
  1238   assume "x \<in> A \<times> B" hence "fst x \<in> A" and "snd x \<in> B" by auto
  1239   assume "y \<in> A \<times> B" hence "fst y \<in> A" and "snd y \<in> B" by auto
  1240   assume "map_prod f g x = map_prod f g y"
  1241   hence "fst (map_prod f g x) = fst (map_prod f g y)" by (auto)
  1242   hence "f (fst x) = f (fst y)" by (cases x,cases y,auto)
  1243   with `inj_on f A` and `fst x \<in> A` and `fst y \<in> A`
  1244   have "fst x = fst y" by (auto dest:dest:inj_onD)
  1245   moreover from `map_prod f g x = map_prod f g y`
  1246   have "snd (map_prod f g x) = snd (map_prod f g y)" by (auto)
  1247   hence "g (snd x) = g (snd y)" by (cases x,cases y,auto)
  1248   with `inj_on g B` and `snd x \<in> B` and `snd y \<in> B`
  1249   have "snd x = snd y" by (auto dest:dest:inj_onD)
  1250   ultimately show "x = y" by(rule prod_eqI)
  1251 qed
  1252 
  1253 lemma map_prod_surj:
  1254   fixes f :: "'a \<Rightarrow> 'b" and g :: "'c \<Rightarrow> 'd"
  1255   assumes "surj f" and "surj g"
  1256   shows "surj (map_prod f g)"
  1257 unfolding surj_def
  1258 proof
  1259   fix y :: "'b \<times> 'd"
  1260   from `surj f` obtain a where "fst y = f a" by (auto elim:surjE)
  1261   moreover
  1262   from `surj g` obtain b where "snd y = g b" by (auto elim:surjE)
  1263   ultimately have "(fst y, snd y) = map_prod f g (a,b)" by auto
  1264   thus "\<exists>x. y = map_prod f g x" by auto
  1265 qed
  1266 
  1267 lemma map_prod_surj_on:
  1268   assumes "f ` A = A'" and "g ` B = B'"
  1269   shows "map_prod f g ` (A \<times> B) = A' \<times> B'"
  1270 unfolding image_def
  1271 proof(rule set_eqI,rule iffI)
  1272   fix x :: "'a \<times> 'c"
  1273   assume "x \<in> {y\<Colon>'a \<times> 'c. \<exists>x\<Colon>'b \<times> 'd\<in>A \<times> B. y = map_prod f g x}"
  1274   then obtain y where "y \<in> A \<times> B" and "x = map_prod f g y" by blast
  1275   from `image f A = A'` and `y \<in> A \<times> B` have "f (fst y) \<in> A'" by auto
  1276   moreover from `image g B = B'` and `y \<in> A \<times> B` have "g (snd y) \<in> B'" by auto
  1277   ultimately have "(f (fst y), g (snd y)) \<in> (A' \<times> B')" by auto
  1278   with `x = map_prod f g y` show "x \<in> A' \<times> B'" by (cases y, auto)
  1279 next
  1280   fix x :: "'a \<times> 'c"
  1281   assume "x \<in> A' \<times> B'" hence "fst x \<in> A'" and "snd x \<in> B'" by auto
  1282   from `image f A = A'` and `fst x \<in> A'` have "fst x \<in> image f A" by auto
  1283   then obtain a where "a \<in> A" and "fst x = f a" by (rule imageE)
  1284   moreover from `image g B = B'` and `snd x \<in> B'`
  1285   obtain b where "b \<in> B" and "snd x = g b" by auto
  1286   ultimately have "(fst x, snd x) = map_prod f g (a,b)" by auto
  1287   moreover from `a \<in> A` and  `b \<in> B` have "(a , b) \<in> A \<times> B" by auto
  1288   ultimately have "\<exists>y \<in> A \<times> B. x = map_prod f g y" by auto
  1289   thus "x \<in> {x. \<exists>y \<in> A \<times> B. x = map_prod f g y}" by auto
  1290 qed
  1291 
  1292 
  1293 subsection {* Simproc for rewriting a set comprehension into a pointfree expression *}
  1294 
  1295 ML_file "Tools/set_comprehension_pointfree.ML"
  1296 
  1297 setup {*
  1298   Code_Preproc.map_pre (fn ctxt => ctxt addsimprocs
  1299     [Raw_Simplifier.make_simproc {name = "set comprehension", lhss = [@{cpat "Collect ?P"}],
  1300     proc = K Set_Comprehension_Pointfree.code_simproc, identifier = []}])
  1301 *}
  1302 
  1303 
  1304 subsection {* Inductively defined sets *}
  1305 
  1306 (* simplify {(x1, ..., xn). (x1, ..., xn) : S} to S *)
  1307 simproc_setup Collect_mem ("Collect t") = {*
  1308   fn _ => fn ctxt => fn ct =>
  1309     (case term_of ct of
  1310       S as Const (@{const_name Collect}, Type (@{type_name fun}, [_, T])) $ t =>
  1311         let val (u, _, ps) = HOLogic.strip_psplits t in
  1312           (case u of
  1313             (c as Const (@{const_name Set.member}, _)) $ q $ S' =>
  1314               (case try (HOLogic.strip_ptuple ps) q of
  1315                 NONE => NONE
  1316               | SOME ts =>
  1317                   if not (Term.is_open S') andalso
  1318                     ts = map Bound (length ps downto 0)
  1319                   then
  1320                     let val simp =
  1321                       full_simp_tac (put_simpset HOL_basic_ss ctxt
  1322                         addsimps [@{thm split_paired_all}, @{thm split_conv}]) 1
  1323                     in
  1324                       SOME (Goal.prove ctxt [] []
  1325                         (Const (@{const_name Pure.eq}, T --> T --> propT) $ S $ S')
  1326                         (K (EVERY
  1327                           [resolve_tac [eq_reflection] 1,
  1328                            resolve_tac @{thms subset_antisym} 1,
  1329                            resolve_tac [subsetI] 1, dresolve_tac [CollectD] 1, simp,
  1330                            resolve_tac [subsetI] 1, resolve_tac [CollectI] 1, simp])))
  1331                     end
  1332                   else NONE)
  1333           | _ => NONE)
  1334         end
  1335     | _ => NONE)
  1336 *}
  1337 
  1338 ML_file "Tools/inductive_set.ML"
  1339 
  1340 
  1341 subsection {* Legacy theorem bindings and duplicates *}
  1342 
  1343 lemma PairE:
  1344   obtains x y where "p = (x, y)"
  1345   by (fact prod.exhaust)
  1346 
  1347 lemmas Pair_eq = prod.inject
  1348 lemmas fst_conv = prod.sel(1)
  1349 lemmas snd_conv = prod.sel(2)
  1350 lemmas pair_collapse = prod.collapse
  1351 lemmas split = split_conv
  1352 lemmas Pair_fst_snd_eq = prod_eq_iff
  1353 
  1354 hide_const (open) prod
  1355 
  1356 end