src/Pure/Isar/specification.ML
author haftmann
Fri Apr 20 11:21:42 2007 +0200 (2007-04-20)
changeset 22744 5cbe966d67a2
parent 21860 c4492c6bf450
child 22923 6384c43da028
permissions -rw-r--r--
Isar definitions are now added explicitly to code theorem table
     1 (*  Title:      Pure/Isar/specification.ML
     2     ID:         $Id$
     3     Author:     Makarius
     4 
     5 Derived local theory specifications --- with type-inference and
     6 toplevel polymorphism.
     7 *)
     8 
     9 signature SPECIFICATION =
    10 sig
    11   val quiet_mode: bool ref
    12   val print_consts: local_theory -> (string * typ -> bool) -> (string * typ) list -> unit
    13   val read_specification: (string * string option * mixfix) list ->
    14     ((string * Attrib.src list) * string list) list -> local_theory ->
    15     (((string * typ) * mixfix) list * ((string * Attrib.src list) * term list) list) *
    16     local_theory
    17   val cert_specification: (string * typ option * mixfix) list ->
    18     ((string * Attrib.src list) * term list) list -> local_theory ->
    19     (((string * typ) * mixfix) list * ((string * Attrib.src list) * term list) list) *
    20     local_theory
    21   val axiomatization: (string * string option * mixfix) list ->
    22     ((bstring * Attrib.src list) * string list) list -> local_theory ->
    23     (term list * (bstring * thm list) list) * local_theory
    24   val axiomatization_i: (string * typ option * mixfix) list ->
    25     ((bstring * Attrib.src list) * term list) list -> local_theory ->
    26     (term list * (bstring * thm list) list) * local_theory
    27   val definition:
    28     (string * string option * mixfix) option * ((string * Attrib.src list) * string) ->
    29     local_theory -> (term * (bstring * thm)) * local_theory
    30   val definition_i:
    31     (string * typ option * mixfix) option * ((string * Attrib.src list) * term) ->
    32     local_theory -> (term * (bstring * thm)) * local_theory
    33   val abbreviation: Syntax.mode -> (string * string option * mixfix) option * string ->
    34     local_theory -> local_theory
    35   val abbreviation_i: Syntax.mode -> (string * typ option * mixfix) option * term ->
    36     local_theory -> local_theory
    37   val notation: Syntax.mode -> (string * mixfix) list -> local_theory -> local_theory
    38   val notation_i: Syntax.mode -> (term * mixfix) list -> local_theory -> local_theory
    39   val theorems: string -> ((bstring * Attrib.src list) * (thmref * Attrib.src list) list) list
    40     -> local_theory -> (bstring * thm list) list * local_theory
    41   val theorems_i: string -> ((bstring * Attrib.src list) * (thm list * Attrib.src list) list) list
    42     -> local_theory -> (bstring * thm list) list * local_theory
    43   val theorem: string -> Method.text option -> (thm list list -> local_theory -> local_theory) ->
    44     string * Attrib.src list -> Element.context Locale.element list -> Element.statement ->
    45     local_theory -> Proof.state
    46   val theorem_i: string -> Method.text option -> (thm list list -> local_theory -> local_theory) ->
    47     string * Attrib.src list -> Element.context_i Locale.element list -> Element.statement_i ->
    48     local_theory -> Proof.state
    49 end;
    50 
    51 structure Specification: SPECIFICATION =
    52 struct
    53 
    54 
    55 (* diagnostics *)
    56 
    57 val quiet_mode = ref false;
    58 
    59 fun print_consts _ _ [] = ()
    60   | print_consts ctxt pred cs =
    61       if ! quiet_mode then () else Pretty.writeln (ProofDisplay.pretty_consts ctxt pred cs);
    62 
    63 fun present_results ctxt res =
    64   if ! quiet_mode then () else ProofDisplay.present_results ctxt res;
    65 
    66 fun present_results' ctxt kind res = present_results ctxt ((kind, ""), res);
    67 
    68 
    69 (* prepare specification *)
    70 
    71 fun prep_specification prep_vars prep_propp prep_att raw_vars raw_specs ctxt =
    72   let
    73     val thy = ProofContext.theory_of ctxt;
    74 
    75     val (vars, vars_ctxt) = ctxt |> prep_vars raw_vars;
    76     val (xs, params_ctxt) = vars_ctxt |> ProofContext.add_fixes_i vars;
    77     val ((specs, vs), specs_ctxt) =
    78       prep_propp (params_ctxt, map (map (rpair []) o snd) raw_specs)
    79       |> swap |>> map (map fst)
    80       ||>> fold_map ProofContext.inferred_param xs;
    81 
    82     val params = vs ~~ map #3 vars;
    83     val names = map (fst o fst) raw_specs;
    84     val atts = map (map (prep_att thy) o snd o fst) raw_specs;
    85   in ((params, (names ~~ atts) ~~ specs), specs_ctxt) end;
    86 
    87 fun read_specification x =
    88   prep_specification ProofContext.read_vars ProofContext.read_propp Attrib.intern_src x;
    89 
    90 fun cert_specification x =
    91   prep_specification ProofContext.cert_vars ProofContext.cert_propp (K I) x;
    92 
    93 
    94 (* axiomatization *)
    95 
    96 fun gen_axioms prep raw_vars raw_specs lthy =
    97   let
    98     val (vars, specs) = fst (prep raw_vars raw_specs lthy);
    99     val cs = map fst vars;
   100     val spec_frees = member (op =) (fold (fold Term.add_frees o snd) specs []);
   101 
   102     val ((consts, axioms), lthy') = lthy
   103       |> LocalTheory.consts spec_frees vars
   104       ||> fold (fold Variable.auto_fixes o snd) specs   (* FIXME !? *)
   105       ||>> LocalTheory.axioms Thm.axiomK specs;
   106 
   107     (* FIXME generic target!? *)
   108     val hs = map (Term.head_of o #2 o Logic.dest_equals o Thm.prop_of o #2) consts;
   109     val lthy'' = lthy' |> LocalTheory.theory (Theory.add_finals_i false hs);
   110 
   111     val _ = print_consts lthy' spec_frees cs;
   112   in ((map #1 consts, axioms), lthy'') end;
   113 
   114 val axiomatization = gen_axioms read_specification;
   115 val axiomatization_i = gen_axioms cert_specification;
   116 
   117 
   118 (* definition *)
   119 
   120 fun gen_def prep (raw_var, (raw_a, raw_prop)) lthy =
   121   let
   122     val (vars, [((raw_name, atts), [prop])]) =
   123       fst (prep (the_list raw_var) [(raw_a, [raw_prop])] lthy);
   124     val (((x, T), rhs), prove) = LocalDefs.derived_def lthy true prop;
   125     val name = Thm.def_name_optional x raw_name;
   126     val mx = (case vars of [] => NoSyn | [((x', _), mx)] =>
   127       if x = x' then mx
   128       else error ("Head of definition " ^ quote x ^ " differs from declaration " ^ quote x'));
   129     val ((lhs, (_, th)), lthy2) = lthy
   130 (*    |> LocalTheory.def ((x, mx), ((name ^ "_raw", []), rhs));  FIXME *)
   131       |> LocalTheory.def Thm.definitionK ((x, mx), ((name, []), rhs));
   132     val ((b, [th']), lthy3) = lthy2
   133       |> LocalTheory.note Thm.definitionK
   134           ((name, CodegenData.add_func_attr false :: atts), [prove lthy2 th]);
   135 
   136     val lhs' = Morphism.term (LocalTheory.target_morphism lthy3) lhs;
   137     val _ = print_consts lthy3 (member (op =) (Term.add_frees lhs' [])) [(x, T)];
   138   in ((lhs, (b, th')), lthy3) end;
   139 
   140 val definition = gen_def read_specification;
   141 val definition_i = gen_def cert_specification;
   142 
   143 
   144 (* abbreviation *)
   145 
   146 fun gen_abbrev prep mode (raw_var, raw_prop) lthy =
   147   let
   148     val ((vars, [(_, [prop])]), _) =
   149       prep (the_list raw_var) [(("", []), [raw_prop])]
   150         (lthy |> ProofContext.set_expand_abbrevs false);
   151     val ((x, T), rhs) = LocalDefs.abs_def (#2 (LocalDefs.cert_def lthy prop));
   152     val mx = (case vars of [] => NoSyn | [((y, _), mx)] =>
   153       if x = y then mx
   154       else error ("Head of abbreviation " ^ quote x ^ " differs from declaration " ^ quote y));
   155     val lthy' = lthy
   156       |> ProofContext.set_syntax_mode mode    (* FIXME !? *)
   157       |> LocalTheory.abbrev mode ((x, mx), rhs) |> snd
   158       |> ProofContext.restore_syntax_mode lthy;
   159     val _ = print_consts lthy' (K false) [(x, T)]
   160   in lthy' end;
   161 
   162 val abbreviation = gen_abbrev read_specification;
   163 val abbreviation_i = gen_abbrev cert_specification;
   164 
   165 
   166 (* notation *)
   167 
   168 fun gen_notation prep_const mode args lthy =
   169   lthy |> LocalTheory.notation mode (map (apfst (prep_const lthy)) args);
   170 
   171 val notation = gen_notation ProofContext.read_const;
   172 val notation_i = gen_notation (K I);
   173 
   174 
   175 (* fact statements *)
   176 
   177 fun gen_theorems prep_thms prep_att kind raw_facts lthy =
   178   let
   179     val attrib = prep_att (ProofContext.theory_of lthy);
   180     val facts = raw_facts |> map (fn ((name, atts), bs) =>
   181       ((name, map attrib atts),
   182         bs |> map (fn (b, more_atts) => (prep_thms lthy b, map attrib more_atts))));
   183     val (res, lthy') = lthy |> LocalTheory.notes kind facts;
   184     val _ = present_results' lthy' kind res;
   185   in (res, lthy') end;
   186 
   187 val theorems = gen_theorems ProofContext.get_thms Attrib.intern_src;
   188 val theorems_i = gen_theorems (K I) (K I);
   189 
   190 
   191 (* complex goal statements *)
   192 
   193 local
   194 
   195 fun subtract_prems ctxt1 ctxt2 =
   196   Library.drop (length (Assumption.prems_of ctxt1), Assumption.prems_of ctxt2);
   197 
   198 fun prep_statement prep_att prep_stmt elems concl ctxt =
   199   (case concl of
   200     Element.Shows shows =>
   201       let
   202         val (_, loc_ctxt, elems_ctxt, propp) = prep_stmt elems (map snd shows) ctxt;
   203         val prems = subtract_prems loc_ctxt elems_ctxt;
   204         val stmt = Attrib.map_specs prep_att (map fst shows ~~ propp);
   205         val goal_ctxt = fold (fold (Variable.auto_fixes o fst)) propp elems_ctxt;
   206       in ((prems, stmt, []), goal_ctxt) end
   207   | Element.Obtains obtains =>
   208       let
   209         val case_names = obtains |> map_index
   210           (fn (i, ("", _)) => string_of_int (i + 1) | (_, (name, _)) => name);
   211         val constraints = obtains |> map (fn (_, (vars, _)) =>
   212           Locale.Elem (Element.Constrains
   213             (vars |> map_filter (fn (x, SOME T) => SOME (x, T) | _ => NONE))));
   214 
   215         val raw_propp = obtains |> map (fn (_, (_, props)) => map (rpair []) props);
   216         val (_, loc_ctxt, elems_ctxt, propp) = prep_stmt (elems @ constraints) raw_propp ctxt;
   217 
   218         val thesis = ObjectLogic.fixed_judgment (ProofContext.theory_of ctxt) AutoBind.thesisN;
   219 
   220         fun assume_case ((name, (vars, _)), asms) ctxt' =
   221           let
   222             val xs = map fst vars;
   223             val props = map fst asms;
   224             val (parms, _) = ctxt'
   225               |> fold Variable.declare_term props
   226               |> fold_map ProofContext.inferred_param xs;
   227             val asm = Term.list_all_free (parms, Logic.list_implies (props, thesis));
   228           in
   229             ctxt' |> (snd o ProofContext.add_fixes_i (map (fn x => (x, NONE, NoSyn)) xs));
   230             ctxt' |> Variable.auto_fixes asm
   231             |> ProofContext.add_assms_i Assumption.assume_export
   232               [((name, [ContextRules.intro_query NONE]), [(asm, [])])]
   233             |>> (fn [(_, [th])] => th)
   234           end;
   235 
   236         val atts = map (Attrib.internal o K)
   237           [RuleCases.consumes (~ (length obtains)), RuleCases.case_names case_names];
   238         val prems = subtract_prems loc_ctxt elems_ctxt;
   239         val stmt = [(("", atts), [(thesis, [])])];
   240 
   241         val (facts, goal_ctxt) = elems_ctxt
   242           |> (snd o ProofContext.add_fixes_i [(AutoBind.thesisN, NONE, NoSyn)])
   243           |> fold_map assume_case (obtains ~~ propp)
   244           |-> (fn ths => ProofContext.note_thmss_i Thm.assumptionK
   245                 [((Obtain.thatN, []), [(ths, [])])] #> #2 #> pair ths);
   246       in ((prems, stmt, facts), goal_ctxt) end);
   247 
   248 fun gen_theorem prep_att prep_stmt
   249     kind before_qed after_qed (name, raw_atts) raw_elems raw_concl lthy0 =
   250   let
   251     val _ = LocalTheory.affirm lthy0;
   252     val thy = ProofContext.theory_of lthy0;
   253 
   254     val (loc, ctxt, lthy) =
   255       (case (TheoryTarget.peek lthy0, exists (fn Locale.Expr _ => true | _ => false) raw_elems) of
   256         (SOME loc, true) => (* workaround non-modularity of in/includes *)  (* FIXME *)
   257           (SOME loc, ProofContext.init thy, LocalTheory.restore lthy0)
   258       | _ => (NONE, lthy0, lthy0));
   259 
   260     val attrib = prep_att thy;
   261     val atts = map attrib raw_atts;
   262 
   263     val elems = raw_elems |> map (Locale.map_elem (Element.map_ctxt_attrib attrib));
   264     val ((prems, stmt, facts), goal_ctxt) =
   265       prep_statement attrib (prep_stmt loc) elems raw_concl ctxt;
   266 
   267     fun after_qed' results goal_ctxt' =
   268       let val results' =
   269         burrow (map Goal.norm_result o ProofContext.export goal_ctxt' lthy) results
   270       in
   271         lthy
   272         |> LocalTheory.notes kind (map2 (fn (a, _) => fn ths => (a, [(ths, [])])) stmt results')
   273         |> (fn (res, lthy') =>
   274           (present_results lthy' ((kind, name), res);
   275             if name = "" andalso null atts then lthy'
   276             else #2 (LocalTheory.notes kind [((name, atts), [(maps #2 res, [])])] lthy')))
   277         |> after_qed results'
   278       end;
   279   in
   280     goal_ctxt
   281     |> ProofContext.note_thmss_i Thm.assumptionK [((AutoBind.assmsN, []), [(prems, [])])]
   282     |> snd
   283     |> Proof.theorem_i before_qed after_qed' (map snd stmt)
   284     |> Proof.refine_insert facts
   285   end;
   286 
   287 in
   288 
   289 val theorem = gen_theorem Attrib.intern_src Locale.read_context_statement_i;
   290 val theorem_i = gen_theorem (K I) Locale.cert_context_statement;
   291 
   292 end;
   293 
   294 end;