src/Pure/Isar/theory_target.ML
author wenzelm
Tue Nov 06 22:50:38 2007 +0100 (2007-11-06)
changeset 25320 618247e82f3d
parent 25311 aa750e3a581c
child 25372 a718f1ccaf1a
permissions -rw-r--r--
tuned;
     1 (*  Title:      Pure/Isar/theory_target.ML
     2     ID:         $Id$
     3     Author:     Makarius
     4 
     5 Common theory/locale/class targets.
     6 *)
     7 
     8 signature THEORY_TARGET =
     9 sig
    10   val peek: local_theory -> {target: string, is_locale: bool, is_class: bool}
    11   val init: string option -> theory -> local_theory
    12   val begin: string -> Proof.context -> local_theory
    13   val context: xstring -> theory -> local_theory
    14 end;
    15 
    16 structure TheoryTarget: THEORY_TARGET =
    17 struct
    18 
    19 (* context data *)
    20 
    21 datatype target = Target of {target: string, is_locale: bool, is_class: bool};
    22 
    23 fun make_target target is_locale is_class =
    24   Target {target = target, is_locale = is_locale, is_class = is_class};
    25 
    26 val global_target = make_target "" false false;
    27 
    28 structure Data = ProofDataFun
    29 (
    30   type T = target;
    31   fun init _ = global_target;
    32 );
    33 
    34 val peek = (fn Target args => args) o Data.get;
    35 
    36 
    37 (* pretty *)
    38 
    39 fun pretty (Target {target, is_locale, is_class}) ctxt =
    40   let
    41     val thy = ProofContext.theory_of ctxt;
    42     val target_name = (if is_class then "class " else "locale ") ^ Locale.extern thy target;
    43     val fixes = map (fn (x, T) => (x, SOME T, NoSyn)) (#1 (ProofContext.inferred_fixes ctxt));
    44     val assumes = map (fn A => (("", []), [(A, [])])) (map Thm.term_of (Assumption.assms_of ctxt));
    45     val elems =
    46       (if null fixes then [] else [Element.Fixes fixes]) @
    47       (if null assumes then [] else [Element.Assumes assumes]);
    48   in
    49     Pretty.block [Pretty.str "theory", Pretty.brk 1, Pretty.str (Context.theory_name thy)] ::
    50      (if target = "" then []
    51       else if null elems then [Pretty.str target_name]
    52       else [Pretty.big_list (target_name ^ " =")
    53         (map (Pretty.chunks o Element.pretty_ctxt ctxt) elems)])
    54   end;
    55 
    56 
    57 (* target declarations *)
    58 
    59 fun target_decl add (Target {target, ...}) d lthy =
    60   let
    61     val d' = Morphism.transform (LocalTheory.target_morphism lthy) d;
    62     val d0 = Morphism.form d';
    63   in
    64     if target = "" then
    65       lthy
    66       |> LocalTheory.theory (Context.theory_map d0)
    67       |> LocalTheory.target (Context.proof_map d0)
    68     else
    69       lthy
    70       |> LocalTheory.target (add target d')
    71   end;
    72 
    73 val type_syntax = target_decl Locale.add_type_syntax;
    74 val term_syntax = target_decl Locale.add_term_syntax;
    75 val declaration = target_decl Locale.add_declaration;
    76 
    77 fun target_naming (Target {target, ...}) lthy =
    78   (if target = "" then Sign.naming_of (ProofContext.theory_of lthy)
    79    else ProofContext.naming_of (LocalTheory.target_of lthy))
    80   |> NameSpace.qualified_names;
    81 
    82 fun class_target (Target {target, ...}) f =
    83   LocalTheory.raw_theory f #>
    84   LocalTheory.target (Class.refresh_syntax target);
    85 
    86 
    87 (* notes *)
    88 
    89 fun import_export_proof ctxt (name, raw_th) =
    90   let
    91     val thy = ProofContext.theory_of ctxt;
    92     val thy_ctxt = ProofContext.init thy;
    93     val certT = Thm.ctyp_of thy;
    94     val cert = Thm.cterm_of thy;
    95 
    96     (*export assumes/defines*)
    97     val th = Goal.norm_result raw_th;
    98     val (defs, th') = LocalDefs.export ctxt thy_ctxt th;
    99     val concl_conv = MetaSimplifier.rewrite true defs (Thm.cprop_of th);
   100     val assms = map (MetaSimplifier.rewrite_rule defs o Thm.assume) (Assumption.assms_of ctxt);
   101     val nprems = Thm.nprems_of th' - Thm.nprems_of th;
   102 
   103     (*export fixes*)
   104     val tfrees = map TFree (Thm.fold_terms Term.add_tfrees th' []);
   105     val frees = map Free (Thm.fold_terms Term.add_frees th' []);
   106     val (th'' :: vs) = (th' :: map (Drule.mk_term o cert) (map Logic.mk_type tfrees @ frees))
   107       |> Variable.export ctxt thy_ctxt
   108       |> Drule.zero_var_indexes_list;
   109 
   110     (*thm definition*)
   111     val result = th''
   112       |> PureThy.name_thm true true ""
   113       |> Goal.close_result
   114       |> fold PureThy.tag_rule (ContextPosition.properties_of ctxt)
   115       |> PureThy.name_thm true true name;
   116 
   117     (*import fixes*)
   118     val (tvars, vars) =
   119       chop (length tfrees) (map (Thm.term_of o Drule.dest_term) vs)
   120       |>> map Logic.dest_type;
   121 
   122     val instT = map_filter (fn (TVar v, T) => SOME (v, T) | _ => NONE) (tvars ~~ tfrees);
   123     val inst = filter (is_Var o fst) (vars ~~ frees);
   124     val cinstT = map (pairself certT o apfst TVar) instT;
   125     val cinst = map (pairself (cert o Term.map_types (TermSubst.instantiateT instT))) inst;
   126     val result' = Thm.instantiate (cinstT, cinst) result;
   127 
   128     (*import assumes/defines*)
   129     val assm_tac = FIRST' (map (fn assm => Tactic.compose_tac (false, assm, 0)) assms);
   130     val result'' =
   131       (case SINGLE (Seq.INTERVAL assm_tac 1 nprems) result' of
   132         NONE => raise THM ("Failed to re-import result", 0, [result'])
   133       | SOME res => LocalDefs.trans_props ctxt [res, Thm.symmetric concl_conv])
   134       |> Goal.norm_result
   135       |> PureThy.name_thm false false name;
   136 
   137   in (result'', result) end;
   138 
   139 fun notes (Target {target, is_locale, ...}) kind facts lthy =
   140   let
   141     val thy = ProofContext.theory_of lthy;
   142     val full = LocalTheory.full_name lthy;
   143 
   144     val facts' = facts
   145       |> map (fn (a, bs) => (a, PureThy.burrow_fact (PureThy.name_multi (full (fst a))) bs))
   146       |> PureThy.map_facts (import_export_proof lthy);
   147     val local_facts = PureThy.map_facts #1 facts'
   148       |> Attrib.map_facts (Attrib.attribute_i thy);
   149     val target_facts = PureThy.map_facts #1 facts'
   150       |> is_locale ? Element.facts_map (Element.morph_ctxt (LocalTheory.target_morphism lthy));
   151     val global_facts = PureThy.map_facts #2 facts'
   152       |> Attrib.map_facts (if is_locale then K I else Attrib.attribute_i thy);
   153   in
   154     lthy |> LocalTheory.theory
   155       (Sign.qualified_names
   156         #> PureThy.note_thmss_i kind global_facts #> snd
   157         #> Sign.restore_naming thy)
   158 
   159     |> is_locale ? LocalTheory.target (Locale.add_thmss target kind target_facts)
   160 
   161     |> ProofContext.qualified_names
   162     |> ProofContext.note_thmss_i kind local_facts
   163     ||> ProofContext.restore_naming lthy
   164   end;
   165 
   166 
   167 (* declare_const *)
   168 
   169 fun fork_mixfix (Target {is_locale, is_class, ...}) mx =
   170   if not is_locale then (NoSyn, NoSyn, mx)
   171   else if not is_class then (NoSyn, mx, NoSyn)
   172   else (mx, NoSyn, NoSyn);
   173 
   174 fun locale_const (Target {target, is_class, ...}) (prmode as (mode, _)) pos ((c, mx), rhs) phi =
   175   let
   176     val c' = Morphism.name phi c;
   177     val rhs' = Morphism.term phi rhs;
   178     val legacy_arg = (c', Term.close_schematic_term (Logic.legacy_varify rhs'));
   179     val arg = (c', Term.close_schematic_term rhs');
   180     (* FIXME workaround based on educated guess *)
   181     val class_global = is_class andalso c' = NameSpace.qualified (Class.class_prefix target) c;
   182   in
   183     not class_global ?
   184       (Context.mapping_result
   185         (Sign.add_abbrev PrintMode.internal pos legacy_arg)
   186         (ProofContext.add_abbrev PrintMode.internal pos arg)
   187       #-> (fn (lhs' as Const (d, _), _) =>
   188           Type.similar_types (rhs, rhs') ?
   189             (Context.mapping (Sign.revert_abbrev mode d) (ProofContext.revert_abbrev mode d) #>
   190              Morphism.form (ProofContext.target_notation true prmode [(lhs', mx)]))))
   191   end;
   192 
   193 fun declare_const (ta as Target {target, is_locale, is_class}) depends ((c, T), mx) lthy =
   194   let
   195     val pos = ContextPosition.properties_of lthy;
   196     val xs = filter depends (#1 (ProofContext.inferred_fixes (LocalTheory.target_of lthy)));
   197     val U = map #2 xs ---> T;
   198     val (mx1, mx2, mx3) = fork_mixfix ta mx;
   199     val (const, lthy') = lthy |> LocalTheory.theory_result (Sign.declare_const pos (c, U, mx3));
   200     val t = Term.list_comb (const, map Free xs);
   201   in
   202     lthy'
   203     |> is_locale ? term_syntax ta (locale_const ta Syntax.mode_default pos ((c, mx2), t))
   204     |> is_class ? class_target ta (Class.add_logical_const target pos ((c, mx1), t))
   205     |> LocalDefs.add_def ((c, NoSyn), t)
   206   end;
   207 
   208 
   209 (* abbrev *)
   210 
   211 fun abbrev (ta as Target {target, is_locale, is_class}) prmode ((c, mx), t) lthy =
   212   let
   213     val pos = ContextPosition.properties_of lthy;
   214     val thy_ctxt = ProofContext.init (ProofContext.theory_of lthy);
   215     val target_ctxt = LocalTheory.target_of lthy;
   216 
   217     val (mx1, mx2, mx3) = fork_mixfix ta mx;
   218     val t' = Assumption.export_term lthy target_ctxt t;
   219     val xs = map Free (rev (Variable.add_fixed target_ctxt t' []));
   220     val u = fold_rev lambda xs t';
   221     val global_rhs =
   222       singleton (Variable.export_terms (Variable.declare_term u target_ctxt) thy_ctxt) u;
   223   in
   224     lthy |>
   225      (if is_locale then
   226         LocalTheory.theory_result (Sign.add_abbrev PrintMode.internal pos (c, global_rhs))
   227         #-> (fn (lhs, _) =>
   228           let val lhs' = Term.list_comb (Logic.unvarify lhs, xs) in
   229             term_syntax ta (locale_const ta prmode pos ((c, mx2), lhs')) #>
   230             is_class ? class_target ta (Class.add_syntactic_const target prmode pos ((c, mx1), t'))
   231           end)
   232       else
   233         LocalTheory.theory
   234           (Sign.add_abbrev (#1 prmode) pos (c, global_rhs) #-> (fn (lhs, _) =>
   235            Sign.notation true prmode [(lhs, mx3)])))
   236     |> ProofContext.add_abbrev PrintMode.internal pos (c, t) |> snd
   237     |> LocalDefs.fixed_abbrev ((c, NoSyn), t)
   238   end;
   239 
   240 
   241 (* define *)
   242 
   243 fun define (ta as Target {target, is_locale, is_class})
   244     kind ((c, mx), ((name, atts), rhs)) lthy =
   245   let
   246     val thy = ProofContext.theory_of lthy;
   247     val thy_ctxt = ProofContext.init thy;
   248 
   249     val name' = Thm.def_name_optional c name;
   250     val (rhs', rhs_conv) =
   251       LocalDefs.export_cterm lthy thy_ctxt (Thm.cterm_of thy rhs) |>> Thm.term_of;
   252     val xs = Variable.add_fixed (LocalTheory.target_of lthy) rhs' [];
   253     val T = Term.fastype_of rhs;
   254 
   255     (*const*)
   256     val ((lhs, local_def), lthy2) = lthy |> declare_const ta (member (op =) xs) ((c, T), mx);
   257     val (_, lhs') = Logic.dest_equals (Thm.prop_of local_def);
   258 
   259     (*def*)
   260     val (global_def, lthy3) = lthy2
   261       |> LocalTheory.theory_result (Thm.add_def false (name', Logic.mk_equals (lhs', rhs')));
   262     val def = LocalDefs.trans_terms lthy3
   263       [(*c == global.c xs*)     local_def,
   264        (*global.c xs == rhs'*)  global_def,
   265        (*rhs' == rhs*)          Thm.symmetric rhs_conv];
   266 
   267     (*note*)
   268     val ([(res_name, [res])], lthy4) = lthy3
   269       |> notes ta kind [((name', atts), [([def], [])])];
   270   in ((lhs, (res_name, res)), lthy4) end;
   271 
   272 
   273 (* axioms *)
   274 
   275 fun axioms ta kind (vars, specs) lthy =
   276   let
   277     val thy_ctxt = ProofContext.init (ProofContext.theory_of lthy);
   278     val expanded_props = map (Assumption.export_term lthy thy_ctxt) (maps snd specs);
   279     val xs = fold Term.add_frees expanded_props [];
   280 
   281     (*consts*)
   282     val (consts, lthy') = fold_map (declare_const ta (member (op =) xs)) vars lthy;
   283     val global_consts = map (Term.dest_Const o Term.head_of o Thm.term_of o Thm.rhs_of o #2) consts;
   284 
   285     (*axioms*)
   286     val hyps = map Thm.term_of (Assumption.assms_of lthy');
   287     fun axiom ((name, atts), props) thy = thy
   288       |> fold_map (Thm.add_axiom hyps) (PureThy.name_multi name props)
   289       |-> (fn ths => pair ((name, atts), [(ths, [])]));
   290   in
   291     lthy'
   292     |> fold Variable.declare_term expanded_props
   293     |> LocalTheory.theory (fold (fn c => Theory.add_deps "" c []) global_consts)
   294     |> LocalTheory.theory_result (fold_map axiom specs)
   295     |-> notes ta kind
   296     |>> pair (map #1 consts)
   297   end;
   298 
   299 
   300 (* init *)
   301 
   302 local
   303 
   304 fun init_target _ NONE = global_target
   305   | init_target thy (SOME target) = make_target target true (Class.is_class thy target);
   306 
   307 fun init_ctxt (Target {target, is_locale, is_class}) =
   308   if not is_locale then ProofContext.init
   309   else if not is_class then Locale.init target
   310   else Class.init target;
   311 
   312 fun init_lthy (ta as Target {target, ...}) =
   313   Data.put ta #>
   314   LocalTheory.init (NameSpace.base target)
   315    {pretty = pretty ta,
   316     axioms = axioms ta,
   317     abbrev = abbrev ta,
   318     define = define ta,
   319     notes = notes ta,
   320     type_syntax = type_syntax ta,
   321     term_syntax = term_syntax ta,
   322     declaration = declaration ta,
   323     target_naming = target_naming ta,
   324     reinit = fn lthy => init_lthy_ctxt ta (ProofContext.theory_of lthy),
   325     exit = LocalTheory.target_of}
   326 and init_lthy_ctxt ta = init_lthy ta o init_ctxt ta;
   327 
   328 in
   329 
   330 fun init target thy = init_lthy_ctxt (init_target thy target) thy;
   331 fun begin target ctxt = init_lthy (init_target (ProofContext.theory_of ctxt) (SOME target)) ctxt;
   332 
   333 fun context "-" thy = init NONE thy
   334   | context target thy = init (SOME (Locale.intern thy target)) thy;
   335 
   336 end;
   337 
   338 end;
   339