src/Tools/Code/code_target.ML
author haftmann
Thu Jul 08 16:19:24 2010 +0200 (2010-07-08)
changeset 37745 6315b6426200
parent 37528 42804fb5dd92
child 37748 0af0d45257be
permissions -rw-r--r--
checking generated code for various target languages
     1 (*  Title:      Tools/Code/code_target.ML
     2     Author:     Florian Haftmann, TU Muenchen
     3 
     4 Serializer from intermediate language ("Thin-gol") to target languages.
     5 *)
     6 
     7 signature CODE_TARGET =
     8 sig
     9   val cert_tyco: theory -> string -> string
    10   val read_tyco: theory -> string -> string
    11 
    12   type serializer
    13   type literals = Code_Printer.literals
    14   val add_target: string * (serializer * literals) -> theory -> theory
    15   val extend_target: string *
    16       (string * (Code_Thingol.naming -> Code_Thingol.program -> Code_Thingol.program))
    17     -> theory -> theory
    18   val assert_target: theory -> string -> string
    19 
    20   type destination
    21   type serialization
    22   val parse_args: 'a parser -> Token.T list -> 'a
    23   val stmt_names_of_destination: destination -> string list
    24   val mk_serialization: string -> ('a -> unit) option
    25     -> (Path.T option -> 'a -> unit)
    26     -> ('a -> string * string option list)
    27     -> 'a -> serialization
    28   val serialize: theory -> string -> int option -> string option -> Token.T list
    29     -> Code_Thingol.naming -> Code_Thingol.program -> string list -> serialization
    30   val serialize_custom: theory -> string * (serializer * literals)
    31     -> Code_Thingol.naming -> Code_Thingol.program -> string list -> string * string option list
    32   val the_literals: theory -> string -> literals
    33   val compile: serialization -> unit
    34   val export: serialization -> unit
    35   val file: Path.T -> serialization -> unit
    36   val string: string list -> serialization -> string
    37   val code_of: theory -> string -> int option -> string
    38     -> string list -> (Code_Thingol.naming -> string list) -> string
    39   val external_check: theory -> string -> string
    40     -> (Path.T -> Path.T) -> (string -> Path.T -> string -> string) -> Path.T -> unit
    41   val set_default_code_width: int -> theory -> theory
    42   val shell_command: string (*theory name*) -> string (*export_code expr*) -> unit
    43 
    44   val allow_abort: string -> theory -> theory
    45   type tyco_syntax = Code_Printer.tyco_syntax
    46   type proto_const_syntax = Code_Printer.proto_const_syntax
    47   val add_syntax_class: string -> class -> string option -> theory -> theory
    48   val add_syntax_inst: string -> class * string -> unit option -> theory -> theory
    49   val add_syntax_tyco: string -> string -> tyco_syntax option -> theory -> theory
    50   val add_syntax_const: string -> string -> proto_const_syntax option -> theory -> theory
    51   val add_reserved: string -> string -> theory -> theory
    52   val add_include: string -> string * (string * string list) option -> theory -> theory
    53 end;
    54 
    55 structure Code_Target : CODE_TARGET =
    56 struct
    57 
    58 open Basic_Code_Thingol;
    59 
    60 type literals = Code_Printer.literals;
    61 type tyco_syntax = Code_Printer.tyco_syntax;
    62 type proto_const_syntax = Code_Printer.proto_const_syntax;
    63 
    64 
    65 (** basics **)
    66 
    67 datatype destination = Compile | Export | File of Path.T | String of string list;
    68 type serialization = destination -> (string * string option list) option;
    69 
    70 fun compile f = (f Compile; ());
    71 fun export f = (f Export; ());
    72 fun file p f = (f (File p); ());
    73 fun string stmts f = fst (the (f (String stmts)));
    74 
    75 fun stmt_names_of_destination (String stmts) = stmts
    76   | stmt_names_of_destination _ = [];
    77 
    78 fun mk_serialization target (SOME comp) _ _ code Compile = (comp code; NONE)
    79   | mk_serialization target NONE _ _ _ Compile = error (target ^ ": no internal compilation")
    80   | mk_serialization target _ output _ code Export = (output NONE code ; NONE)
    81   | mk_serialization target _ output _ code (File file) = (output (SOME file) code; NONE)
    82   | mk_serialization target _ _ string code (String _) = SOME (string code);
    83 
    84 
    85 (** theory data **)
    86 
    87 datatype name_syntax_table = NameSyntaxTable of {
    88   class: string Symtab.table,
    89   instance: unit Symreltab.table,
    90   tyco: Code_Printer.tyco_syntax Symtab.table,
    91   const: Code_Printer.proto_const_syntax Symtab.table
    92 };
    93 
    94 fun mk_name_syntax_table ((class, instance), (tyco, const)) =
    95   NameSyntaxTable { class = class, instance = instance, tyco = tyco, const = const };
    96 fun map_name_syntax_table f (NameSyntaxTable { class, instance, tyco, const }) =
    97   mk_name_syntax_table (f ((class, instance), (tyco, const)));
    98 fun merge_name_syntax_table (NameSyntaxTable { class = class1, instance = instance1, tyco = tyco1, const = const1 },
    99     NameSyntaxTable { class = class2, instance = instance2, tyco = tyco2, const = const2 }) =
   100   mk_name_syntax_table (
   101     (Symtab.join (K snd) (class1, class2),
   102        Symreltab.join (K snd) (instance1, instance2)),
   103     (Symtab.join (K snd) (tyco1, tyco2),
   104        Symtab.join (K snd) (const1, const2))
   105   );
   106 
   107 type serializer =
   108   string option                         (*module name*)
   109   -> Token.T list                       (*arguments*)
   110   -> (string -> string)                 (*labelled_name*)
   111   -> string list                        (*reserved symbols*)
   112   -> (string * Pretty.T) list           (*includes*)
   113   -> (string -> string option)          (*module aliasses*)
   114   -> (string -> string option)          (*class syntax*)
   115   -> (string -> Code_Printer.tyco_syntax option)
   116   -> (string -> Code_Printer.const_syntax option)
   117   -> ((Pretty.T -> string) * (Pretty.T -> unit))
   118   -> Code_Thingol.program
   119   -> string list                        (*selected statements*)
   120   -> serialization;
   121 
   122 datatype serializer_entry = Serializer of serializer * Code_Printer.literals
   123   | Extends of string * (Code_Thingol.naming -> Code_Thingol.program -> Code_Thingol.program);
   124 
   125 datatype target = Target of {
   126   serial: serial,
   127   serializer: serializer_entry,
   128   reserved: string list,
   129   includes: (Pretty.T * string list) Symtab.table,
   130   name_syntax_table: name_syntax_table,
   131   module_alias: string Symtab.table
   132 };
   133 
   134 fun make_target ((serial, serializer), ((reserved, includes), (name_syntax_table, module_alias))) =
   135   Target { serial = serial, serializer = serializer, reserved = reserved, 
   136     includes = includes, name_syntax_table = name_syntax_table, module_alias = module_alias };
   137 fun map_target f ( Target { serial, serializer, reserved, includes, name_syntax_table, module_alias } ) =
   138   make_target (f ((serial, serializer), ((reserved, includes), (name_syntax_table, module_alias))));
   139 fun merge_target strict target (Target { serial = serial1, serializer = serializer,
   140   reserved = reserved1, includes = includes1,
   141   name_syntax_table = name_syntax_table1, module_alias = module_alias1 },
   142     Target { serial = serial2, serializer = _,
   143       reserved = reserved2, includes = includes2,
   144       name_syntax_table = name_syntax_table2, module_alias = module_alias2 }) =
   145   if serial1 = serial2 orelse not strict then
   146     make_target ((serial1, serializer),
   147       ((merge (op =) (reserved1, reserved2), Symtab.merge (K true) (includes1, includes2)),
   148         (merge_name_syntax_table (name_syntax_table1, name_syntax_table2),
   149           Symtab.join (K fst) (module_alias1, module_alias2))
   150     ))
   151   else
   152     error ("Incompatible serializers: " ^ quote target);
   153 
   154 fun the_serializer (Target { serializer, ... }) = serializer;
   155 fun the_reserved (Target { reserved, ... }) = reserved;
   156 fun the_includes (Target { includes, ... }) = includes;
   157 fun the_name_syntax (Target { name_syntax_table = NameSyntaxTable x, ... }) = x;
   158 fun the_module_alias (Target { module_alias , ... }) = module_alias;
   159 
   160 structure Targets = Theory_Data
   161 (
   162   type T = (target Symtab.table * string list) * int;
   163   val empty = ((Symtab.empty, []), 80);
   164   val extend = I;
   165   fun merge (((target1, exc1), width1), ((target2, exc2), width2)) : T =
   166     ((Symtab.join (merge_target true) (target1, target2),
   167       Library.merge (op =) (exc1, exc2)), Int.max (width1, width2));
   168 );
   169 
   170 val abort_allowed = snd o fst o Targets.get;
   171 
   172 fun assert_target thy target = if Symtab.defined ((fst o fst) (Targets.get thy)) target
   173   then target
   174   else error ("Unknown code target language: " ^ quote target);
   175 
   176 fun put_target (target, seri) thy =
   177   let
   178     val lookup_target = Symtab.lookup ((fst o fst) (Targets.get thy));
   179     val _ = case seri
   180      of Extends (super, _) => if is_some (lookup_target super) then ()
   181           else error ("Unknown code target language: " ^ quote super)
   182       | _ => ();
   183     val overwriting = case (Option.map the_serializer o lookup_target) target
   184      of NONE => false
   185       | SOME (Extends _) => true
   186       | SOME (Serializer _) => (case seri
   187          of Extends _ => error ("Will not overwrite existing target " ^ quote target)
   188           | _ => true);
   189     val _ = if overwriting
   190       then warning ("Overwriting existing target " ^ quote target)
   191       else (); 
   192   in
   193     thy
   194     |> (Targets.map o apfst o apfst o Symtab.update)
   195           (target, make_target ((serial (), seri), (([], Symtab.empty),
   196             (mk_name_syntax_table ((Symtab.empty, Symreltab.empty), (Symtab.empty, Symtab.empty)),
   197               Symtab.empty))))
   198   end;
   199 
   200 fun add_target (target, seri) = put_target (target, Serializer seri);
   201 fun extend_target (target, (super, modify)) =
   202   put_target (target, Extends (super, modify));
   203 
   204 fun map_target_data target f thy =
   205   let
   206     val _ = assert_target thy target;
   207   in
   208     thy
   209     |> (Targets.map o apfst o apfst o Symtab.map_entry target o map_target) f
   210   end;
   211 
   212 fun map_reserved target =
   213   map_target_data target o apsnd o apfst o apfst;
   214 fun map_includes target =
   215   map_target_data target o apsnd o apfst o apsnd;
   216 fun map_name_syntax target =
   217   map_target_data target o apsnd o apsnd o apfst o map_name_syntax_table;
   218 fun map_module_alias target =
   219   map_target_data target o apsnd o apsnd o apsnd;
   220 
   221 fun set_default_code_width k = (Targets.map o apsnd) (K k);
   222 
   223 
   224 (** serializer usage **)
   225 
   226 (* montage *)
   227 
   228 fun the_literals thy =
   229   let
   230     val ((targets, _), _) = Targets.get thy;
   231     fun literals target = case Symtab.lookup targets target
   232      of SOME data => (case the_serializer data
   233          of Serializer (_, literals) => literals
   234           | Extends (super, _) => literals super)
   235       | NONE => error ("Unknown code target language: " ^ quote target);
   236   in literals end;
   237 
   238 local
   239 
   240 fun activate_syntax lookup_name src_tab = Symtab.empty
   241   |> fold_map (fn thing_identifier => fn tab => case lookup_name thing_identifier
   242        of SOME name => (SOME name,
   243             Symtab.update_new (name, the (Symtab.lookup src_tab thing_identifier)) tab)
   244         | NONE => (NONE, tab)) (Symtab.keys src_tab)
   245   |>> map_filter I;
   246 
   247 fun activate_const_syntax thy literals src_tab naming = (Symtab.empty, naming)
   248   |> fold_map (fn thing_identifier => fn (tab, naming) =>
   249       case Code_Thingol.lookup_const naming thing_identifier
   250        of SOME name => let
   251               val (syn, naming') = Code_Printer.activate_const_syntax thy
   252                 literals (the (Symtab.lookup src_tab thing_identifier)) naming
   253             in (SOME name, (Symtab.update_new (name, syn) tab, naming')) end
   254         | NONE => (NONE, (tab, naming))) (Symtab.keys src_tab)
   255   |>> map_filter I;
   256 
   257 fun invoke_serializer thy abortable serializer literals reserved abs_includes 
   258     module_alias class instance tyco const module width args naming program2 names1 =
   259   let
   260     val (names_class, class') =
   261       activate_syntax (Code_Thingol.lookup_class naming) class;
   262     val names_inst = map_filter (Code_Thingol.lookup_instance naming)
   263       (Symreltab.keys instance);
   264     val (names_tyco, tyco') =
   265       activate_syntax (Code_Thingol.lookup_tyco naming) tyco;
   266     val (names_const, (const', _)) =
   267       activate_const_syntax thy literals const naming;
   268     val names_hidden = names_class @ names_inst @ names_tyco @ names_const;
   269     val names2 = subtract (op =) names_hidden names1;
   270     val program3 = Graph.subgraph (not o member (op =) names_hidden) program2;
   271     val names_all = Graph.all_succs program3 names2;
   272     val includes = abs_includes names_all;
   273     val program4 = Graph.subgraph (member (op =) names_all) program3;
   274     val empty_funs = filter_out (member (op =) abortable)
   275       (Code_Thingol.empty_funs program3);
   276     val _ = if null empty_funs then () else error ("No code equations for "
   277       ^ commas (map (Sign.extern_const thy) empty_funs));
   278   in
   279     serializer module args (Code_Thingol.labelled_name thy program2) reserved includes
   280       (Symtab.lookup module_alias) (Symtab.lookup class')
   281       (Symtab.lookup tyco') (Symtab.lookup const')
   282       (Code_Printer.string_of_pretty width, Code_Printer.writeln_pretty width)
   283       program4 names1
   284   end;
   285 
   286 fun mount_serializer thy alt_serializer target some_width module args naming program names =
   287   let
   288     val ((targets, abortable), default_width) = Targets.get thy;
   289     fun collapse_hierarchy target =
   290       let
   291         val data = case Symtab.lookup targets target
   292          of SOME data => data
   293           | NONE => error ("Unknown code target language: " ^ quote target);
   294       in case the_serializer data
   295        of Serializer _ => (I, data)
   296         | Extends (super, modify) => let
   297             val (modify', data') = collapse_hierarchy super
   298           in (modify' #> modify naming, merge_target false target (data', data)) end
   299       end;
   300     val (modify, data) = collapse_hierarchy target;
   301     val (serializer, _) = the_default (case the_serializer data
   302      of Serializer seri => seri) alt_serializer;
   303     val reserved = the_reserved data;
   304     fun select_include names_all (name, (content, cs)) =
   305       if null cs then SOME (name, content)
   306       else if exists (fn c => case Code_Thingol.lookup_const naming c
   307        of SOME name => member (op =) names_all name
   308         | NONE => false) cs
   309       then SOME (name, content) else NONE;
   310     fun includes names_all = map_filter (select_include names_all)
   311       ((Symtab.dest o the_includes) data);
   312     val module_alias = the_module_alias data;
   313     val { class, instance, tyco, const } = the_name_syntax data;
   314     val literals = the_literals thy target;
   315     val width = the_default default_width some_width;
   316   in
   317     invoke_serializer thy abortable serializer literals reserved
   318       includes module_alias class instance tyco const module width args naming (modify program) names
   319   end;
   320 
   321 in
   322 
   323 fun serialize thy = mount_serializer thy NONE;
   324 
   325 fun serialize_custom thy (target_name, seri) naming program names =
   326   mount_serializer thy (SOME seri) target_name NONE NONE [] naming program names (String [])
   327   |> the;
   328 
   329 end; (* local *)
   330 
   331 
   332 (* code presentation *)
   333 
   334 fun code_of thy target some_width module_name cs names_stmt =
   335   let
   336     val (names_cs, (naming, program)) = Code_Thingol.consts_program thy false cs;
   337   in
   338     string (names_stmt naming)
   339       (serialize thy target some_width (SOME module_name) [] naming program names_cs)
   340   end;
   341 
   342 
   343 (* code generation *)
   344 
   345 fun transitivly_non_empty_funs thy naming program =
   346   let
   347     val cs = subtract (op =) (abort_allowed thy) (Code_Thingol.empty_funs program);
   348     val names = map_filter (Code_Thingol.lookup_const naming) cs;
   349   in subtract (op =) (Graph.all_preds program names) (Graph.keys program) end;
   350 
   351 fun read_const_exprs thy cs =
   352   let
   353     val (cs1, cs2) = Code_Thingol.read_const_exprs thy cs;
   354     val (names2, (naming, program)) = Code_Thingol.consts_program thy true cs2;
   355     val names3 = transitivly_non_empty_funs thy naming program;
   356     val cs3 = map_filter (fn (c, name) =>
   357       if member (op =) names3 name then SOME c else NONE) (cs2 ~~ names2);
   358   in union (op =) cs3 cs1 end;
   359 
   360 fun external_check thy target env_var make_destination make_command p =
   361   let
   362     val env_param = getenv env_var;
   363     fun ext_check env_param =
   364       let 
   365         val module_name = "Code_Test";
   366         val (cs, (naming, program)) =
   367           Code_Thingol.consts_program thy false (read_const_exprs thy ["*"]);
   368         val destination = make_destination p;
   369         val _ = file destination (serialize thy target (SOME 80)
   370           (SOME module_name) [] naming program cs);
   371         val cmd = make_command env_param destination module_name;
   372       in if bash ("cd " ^ File.shell_path p ^ " && " ^ cmd) <> 0
   373         then error ("Code check failed for " ^ target ^ ": " ^ cmd)
   374         else ()
   375       end;
   376   in if env_param = ""
   377     then warning (env_var ^ " not set; skipped code check for " ^ target)
   378     else ext_check env_param
   379   end;
   380 
   381 fun export_code thy cs seris =
   382   let
   383     val (cs', (naming, program)) = Code_Thingol.consts_program thy false cs;
   384     fun mk_seri_dest dest = case dest
   385      of NONE => compile
   386       | SOME "-" => export
   387       | SOME f => file (Path.explode f)
   388     val _ = map (fn (((target, module), dest), args) =>
   389       (mk_seri_dest dest (serialize thy target NONE module args naming program cs'))) seris;
   390   in () end;
   391 
   392 fun export_code_cmd raw_cs seris thy = export_code thy (read_const_exprs thy raw_cs) seris;
   393 
   394 
   395 (** serializer configuration **)
   396 
   397 (* data access *)
   398 
   399 fun cert_class thy class =
   400   let
   401     val _ = AxClass.get_info thy class;
   402   in class end;
   403 
   404 fun read_class thy = cert_class thy o Sign.intern_class thy;
   405 
   406 fun cert_tyco thy tyco =
   407   let
   408     val _ = if Sign.declared_tyname thy tyco then ()
   409       else error ("No such type constructor: " ^ quote tyco);
   410   in tyco end;
   411 
   412 fun read_tyco thy = cert_tyco thy o Sign.intern_type thy;
   413 
   414 fun cert_inst thy (class, tyco) =
   415   (cert_class thy class, cert_tyco thy tyco);
   416 
   417 fun read_inst thy (raw_tyco, raw_class) =
   418   (read_class thy raw_class, read_tyco thy raw_tyco);
   419 
   420 fun gen_add_syntax upd del mapp check_x check_raw_syn prep_syn prep_x target raw_x some_raw_syn thy =
   421   let
   422     val x = prep_x thy raw_x |> tap (check_x thy);
   423     fun prep_check raw_syn = prep_syn (raw_syn |> tap (check_raw_syn thy target));
   424   in case some_raw_syn
   425    of SOME raw_syn => (map_name_syntax target o mapp) (upd (x, prep_check raw_syn)) thy
   426     | NONE => (map_name_syntax target o mapp) (del x) thy
   427   end;
   428 
   429 fun gen_add_syntax_class prep_class =
   430   gen_add_syntax Symtab.update Symtab.delete_safe (apfst o apfst) (K I) ((K o K o K) ()) I prep_class;
   431 
   432 fun gen_add_syntax_inst prep_inst =
   433   gen_add_syntax Symreltab.update Symreltab.delete_safe (apfst o apsnd) (K I) ((K o K o K) ()) I prep_inst;
   434 
   435 fun gen_add_syntax_tyco prep_tyco =
   436   gen_add_syntax Symtab.update Symtab.delete_safe (apsnd o apfst)
   437     (fn thy => fn tyco => fn (n, _) => if n <> Sign.arity_number thy tyco
   438       then error ("Number of arguments mismatch in syntax for type constructor " ^ quote tyco)
   439       else ()) ((K o K o K) ()) I prep_tyco;
   440 
   441 fun gen_add_syntax_const prep_const check_raw_syn prep_syn =
   442   gen_add_syntax Symtab.update Symtab.delete_safe (apsnd o apsnd)
   443     (fn thy => fn c => fn (n, _) => if n > Code.args_number thy c
   444       then error ("Too many arguments in syntax for constant " ^ quote c)
   445       else ()) check_raw_syn prep_syn prep_const;
   446 
   447 fun add_reserved target =
   448   let
   449     fun add sym syms = if member (op =) syms sym
   450       then error ("Reserved symbol " ^ quote sym ^ " already declared")
   451       else insert (op =) sym syms
   452   in map_reserved target o add end;
   453 
   454 fun gen_add_include read_const target args thy =
   455   let
   456     fun add (name, SOME (content, raw_cs)) incls =
   457           let
   458             val _ = if Symtab.defined incls name
   459               then warning ("Overwriting existing include " ^ name)
   460               else ();
   461             val cs = map (read_const thy) raw_cs;
   462           in Symtab.update (name, (Code_Printer.str content, cs)) incls end
   463       | add (name, NONE) incls = Symtab.delete name incls;
   464   in map_includes target (add args) thy end;
   465 
   466 val add_include = gen_add_include (K I);
   467 val add_include_cmd = gen_add_include Code.read_const;
   468 
   469 fun add_module_alias target (thyname, modlname) =
   470   let
   471     val xs = Long_Name.explode modlname;
   472     val xs' = map (Name.desymbolize true) xs;
   473   in if xs' = xs
   474     then map_module_alias target (Symtab.update (thyname, modlname))
   475     else error ("Invalid module name: " ^ quote modlname ^ "\n"
   476       ^ "perhaps try " ^ quote (Long_Name.implode xs'))
   477   end;
   478 
   479 fun gen_allow_abort prep_const raw_c thy =
   480   let
   481     val c = prep_const thy raw_c;
   482   in thy |> (Targets.map o apfst o apsnd) (insert (op =) c) end;
   483 
   484 
   485 (* concrete syntax *)
   486 
   487 local
   488 
   489 fun zip_list (x::xs) f g =
   490   f
   491   #-> (fn y =>
   492     fold_map (fn x => g |-- f >> pair x) xs
   493     #-> (fn xys => pair ((x, y) :: xys)));
   494 
   495 fun parse_multi_syntax parse_thing parse_syntax =
   496   Parse.and_list1 parse_thing
   497   #-> (fn things => Scan.repeat1 (Parse.$$$ "(" |-- Parse.name --
   498         (zip_list things parse_syntax (Parse.$$$ "and")) --| Parse.$$$ ")"));
   499 
   500 in
   501 
   502 val add_syntax_class = gen_add_syntax_class cert_class;
   503 val add_syntax_inst = gen_add_syntax_inst cert_inst;
   504 val add_syntax_tyco = gen_add_syntax_tyco cert_tyco;
   505 val add_syntax_const_simple = gen_add_syntax_const (K I) ((K o K o K) ()) Code_Printer.simple_const_syntax;
   506 val add_syntax_const = gen_add_syntax_const (K I) ((K o K o K) ()) I;
   507 val allow_abort = gen_allow_abort (K I);
   508 val add_reserved = add_reserved;
   509 val add_include = add_include;
   510 
   511 val add_syntax_class_cmd = gen_add_syntax_class read_class;
   512 val add_syntax_inst_cmd = gen_add_syntax_inst read_inst;
   513 val add_syntax_tyco_cmd = gen_add_syntax_tyco read_tyco;
   514 val add_syntax_const_simple_cmd = gen_add_syntax_const Code.read_const ((K o K o K) ()) Code_Printer.simple_const_syntax;
   515 val add_syntax_const_cmd = gen_add_syntax_const Code.read_const ((K o K o K) ()) I;
   516 
   517 val allow_abort_cmd = gen_allow_abort Code.read_const;
   518 
   519 fun parse_args f args =
   520   case Scan.read Token.stopper f args
   521    of SOME x => x
   522     | NONE => error "Bad serializer arguments";
   523 
   524 
   525 (** Isar setup **)
   526 
   527 val (inK, module_nameK, fileK) = ("in", "module_name", "file");
   528 
   529 val code_exprP =
   530   (Scan.repeat1 Parse.term_group
   531   -- Scan.repeat (Parse.$$$ inK |-- Parse.name
   532      -- Scan.option (Parse.$$$ module_nameK |-- Parse.name)
   533      -- Scan.option (Parse.$$$ fileK |-- Parse.name)
   534      -- Scan.optional (Parse.$$$ "(" |-- Args.parse --| Parse.$$$ ")") []
   535   ) >> (fn (raw_cs, seris) => export_code_cmd raw_cs seris));
   536 
   537 val _ = List.app Keyword.keyword [inK, module_nameK, fileK];
   538 
   539 val _ =
   540   Outer_Syntax.command "code_class" "define code syntax for class" Keyword.thy_decl (
   541     parse_multi_syntax Parse.xname (Scan.option Parse.string)
   542     >> (Toplevel.theory oo fold) (fn (target, syns) =>
   543           fold (fn (raw_class, syn) => add_syntax_class_cmd target raw_class syn) syns)
   544   );
   545 
   546 val _ =
   547   Outer_Syntax.command "code_instance" "define code syntax for instance" Keyword.thy_decl (
   548     parse_multi_syntax (Parse.xname --| Parse.$$$ "::" -- Parse.xname)
   549       (Scan.option (Parse.minus >> K ()))
   550     >> (Toplevel.theory oo fold) (fn (target, syns) =>
   551           fold (fn (raw_inst, add_del) => add_syntax_inst_cmd target raw_inst add_del) syns)
   552   );
   553 
   554 val _ =
   555   Outer_Syntax.command "code_type" "define code syntax for type constructor" Keyword.thy_decl (
   556     parse_multi_syntax Parse.xname (Code_Printer.parse_syntax I)
   557     >> (Toplevel.theory oo fold) (fn (target, syns) =>
   558           fold (fn (raw_tyco, syn) => add_syntax_tyco_cmd target raw_tyco syn) syns)
   559   );
   560 
   561 val _ =
   562   Outer_Syntax.command "code_const" "define code syntax for constant" Keyword.thy_decl (
   563     parse_multi_syntax Parse.term_group (Code_Printer.parse_syntax fst)
   564     >> (Toplevel.theory oo fold) (fn (target, syns) =>
   565       fold (fn (raw_const, syn) => add_syntax_const_simple_cmd target raw_const syn) syns)
   566   );
   567 
   568 val _ =
   569   Outer_Syntax.command "code_reserved" "declare words as reserved for target language"
   570     Keyword.thy_decl (
   571     Parse.name -- Scan.repeat1 Parse.name
   572     >> (fn (target, reserveds) => (Toplevel.theory o fold (add_reserved target)) reserveds)
   573   );
   574 
   575 val _ =
   576   Outer_Syntax.command "code_include" "declare piece of code to be included in generated code"
   577     Keyword.thy_decl (
   578     Parse.name -- Parse.name -- (Parse.text :|-- (fn "-" => Scan.succeed NONE
   579       | s => Scan.optional (Parse.$$$ "attach" |-- Scan.repeat1 Parse.term) [] >> pair s >> SOME))
   580     >> (fn ((target, name), content_consts) =>
   581         (Toplevel.theory o add_include_cmd target) (name, content_consts))
   582   );
   583 
   584 val _ =
   585   Outer_Syntax.command "code_modulename" "alias module to other name" Keyword.thy_decl (
   586     Parse.name -- Scan.repeat1 (Parse.name -- Parse.name)
   587     >> (fn (target, modlnames) => (Toplevel.theory o fold (add_module_alias target)) modlnames)
   588   );
   589 
   590 val _ =
   591   Outer_Syntax.command "code_abort" "permit constant to be implemented as program abort"
   592     Keyword.thy_decl (
   593     Scan.repeat1 Parse.term_group >> (Toplevel.theory o fold allow_abort_cmd)
   594   );
   595 
   596 val _ =
   597   Outer_Syntax.command "export_code" "generate executable code for constants"
   598     Keyword.diag (Parse.!!! code_exprP >> (fn f => Toplevel.keep (f o Toplevel.theory_of)));
   599 
   600 fun shell_command thyname cmd = Toplevel.program (fn _ =>
   601   (use_thy thyname; case Scan.read Token.stopper (Parse.!!! code_exprP)
   602     ((filter Token.is_proper o Outer_Syntax.scan Position.none) cmd)
   603    of SOME f => (writeln "Now generating code..."; f (theory thyname))
   604     | NONE => error ("Bad directive " ^ quote cmd)))
   605   handle Runtime.TOPLEVEL_ERROR => OS.Process.exit OS.Process.failure;
   606 
   607 end; (*local*)
   608 
   609 end; (*struct*)