src/HOL/Probability/Projective_Family.thy
author hoelzl
Mon Nov 19 12:29:02 2012 +0100 (2012-11-19)
changeset 50123 69b35a75caf3
parent 50101 a3bede207a04
child 50124 4161c834c2fd
permissions -rw-r--r--
merge extensional dependent function space from FuncSet with the one in Finite_Product_Measure
     1 (*  Title:      HOL/Probability/Projective_Family.thy
     2     Author:     Fabian Immler, TU München
     3     Author:     Johannes Hölzl, TU München
     4 *)
     5 
     6 header {*Projective Family*}
     7 
     8 theory Projective_Family
     9 imports Finite_Product_Measure Probability_Measure
    10 begin
    11 
    12 lemma (in product_prob_space) distr_restrict:
    13   assumes "J \<noteq> {}" "J \<subseteq> K" "finite K"
    14   shows "(\<Pi>\<^isub>M i\<in>J. M i) = distr (\<Pi>\<^isub>M i\<in>K. M i) (\<Pi>\<^isub>M i\<in>J. M i) (\<lambda>f. restrict f J)" (is "?P = ?D")
    15 proof (rule measure_eqI_generator_eq)
    16   have "finite J" using `J \<subseteq> K` `finite K` by (auto simp add: finite_subset)
    17   interpret J: finite_product_prob_space M J proof qed fact
    18   interpret K: finite_product_prob_space M K proof qed fact
    19 
    20   let ?J = "{Pi\<^isub>E J E | E. \<forall>i\<in>J. E i \<in> sets (M i)}"
    21   let ?F = "\<lambda>i. \<Pi>\<^isub>E k\<in>J. space (M k)"
    22   let ?\<Omega> = "(\<Pi>\<^isub>E k\<in>J. space (M k))"
    23   show "Int_stable ?J"
    24     by (rule Int_stable_PiE)
    25   show "range ?F \<subseteq> ?J" "(\<Union>i. ?F i) = ?\<Omega>"
    26     using `finite J` by (auto intro!: prod_algebraI_finite)
    27   { fix i show "emeasure ?P (?F i) \<noteq> \<infinity>" by simp }
    28   show "?J \<subseteq> Pow ?\<Omega>" by (auto simp: Pi_iff dest: sets_into_space)
    29   show "sets (\<Pi>\<^isub>M i\<in>J. M i) = sigma_sets ?\<Omega> ?J" "sets ?D = sigma_sets ?\<Omega> ?J"
    30     using `finite J` by (simp_all add: sets_PiM prod_algebra_eq_finite Pi_iff)
    31 
    32   fix X assume "X \<in> ?J"
    33   then obtain E where [simp]: "X = Pi\<^isub>E J E" and E: "\<forall>i\<in>J. E i \<in> sets (M i)" by auto
    34   with `finite J` have X: "X \<in> sets (Pi\<^isub>M J M)"
    35     by simp
    36 
    37   have "emeasure ?P X = (\<Prod> i\<in>J. emeasure (M i) (E i))"
    38     using E by (simp add: J.measure_times)
    39   also have "\<dots> = (\<Prod> i\<in>J. emeasure (M i) (if i \<in> J then E i else space (M i)))"
    40     by simp
    41   also have "\<dots> = (\<Prod> i\<in>K. emeasure (M i) (if i \<in> J then E i else space (M i)))"
    42     using `finite K` `J \<subseteq> K`
    43     by (intro setprod_mono_one_left) (auto simp: M.emeasure_space_1)
    44   also have "\<dots> = emeasure (Pi\<^isub>M K M) (\<Pi>\<^isub>E i\<in>K. if i \<in> J then E i else space (M i))"
    45     using E by (simp add: K.measure_times)
    46   also have "(\<Pi>\<^isub>E i\<in>K. if i \<in> J then E i else space (M i)) = (\<lambda>f. restrict f J) -` Pi\<^isub>E J E \<inter> (\<Pi>\<^isub>E i\<in>K. space (M i))"
    47     using `J \<subseteq> K` sets_into_space E by (force simp: Pi_iff PiE_def split: split_if_asm)
    48   finally show "emeasure (Pi\<^isub>M J M) X = emeasure ?D X"
    49     using X `J \<subseteq> K` apply (subst emeasure_distr)
    50     by (auto intro!: measurable_restrict_subset simp: space_PiM)
    51 qed
    52 
    53 lemma (in product_prob_space) emeasure_prod_emb[simp]:
    54   assumes L: "J \<noteq> {}" "J \<subseteq> L" "finite L" and X: "X \<in> sets (Pi\<^isub>M J M)"
    55   shows "emeasure (Pi\<^isub>M L M) (prod_emb L M J X) = emeasure (Pi\<^isub>M J M) X"
    56   by (subst distr_restrict[OF L])
    57      (simp add: prod_emb_def space_PiM emeasure_distr measurable_restrict_subset L X)
    58 
    59 definition
    60   limP :: "'i set \<Rightarrow> ('i \<Rightarrow> 'a measure) \<Rightarrow> ('i set \<Rightarrow> ('i \<Rightarrow> 'a) measure) \<Rightarrow> ('i \<Rightarrow> 'a) measure" where
    61   "limP I M P = extend_measure (\<Pi>\<^isub>E i\<in>I. space (M i))
    62     {(J, X). (J \<noteq> {} \<or> I = {}) \<and> finite J \<and> J \<subseteq> I \<and> X \<in> (\<Pi> j\<in>J. sets (M j))}
    63     (\<lambda>(J, X). prod_emb I M J (\<Pi>\<^isub>E j\<in>J. X j))
    64     (\<lambda>(J, X). emeasure (P J) (Pi\<^isub>E J X))"
    65 
    66 abbreviation "lim\<^isub>P \<equiv> limP"
    67 
    68 lemma space_limP[simp]: "space (limP I M P) = space (PiM I M)"
    69   by (auto simp add: limP_def space_PiM prod_emb_def intro!: space_extend_measure)
    70 
    71 lemma sets_limP[simp]: "sets (limP I M P) = sets (PiM I M)"
    72   by (auto simp add: limP_def sets_PiM prod_algebra_def prod_emb_def intro!: sets_extend_measure)
    73 
    74 lemma measurable_limP1[simp]: "measurable (limP I M P) M' = measurable (\<Pi>\<^isub>M i\<in>I. M i) M'"
    75   unfolding measurable_def by auto
    76 
    77 lemma measurable_limP2[simp]: "measurable M' (limP I M P) = measurable M' (\<Pi>\<^isub>M i\<in>I. M i)"
    78   unfolding measurable_def by auto
    79 
    80 locale projective_family =
    81   fixes I::"'i set" and P::"'i set \<Rightarrow> ('i \<Rightarrow> 'a) measure" and M::"('i \<Rightarrow> 'a measure)"
    82   assumes projective: "\<And>J H X. J \<noteq> {} \<Longrightarrow> J \<subseteq> H \<Longrightarrow> H \<subseteq> I \<Longrightarrow> finite H \<Longrightarrow> X \<in> sets (PiM J M) \<Longrightarrow>
    83      (P H) (prod_emb H M J X) = (P J) X"
    84   assumes proj_prob_space: "\<And>J. finite J \<Longrightarrow> prob_space (P J)"
    85   assumes proj_space: "\<And>J. finite J \<Longrightarrow> space (P J) = space (PiM J M)"
    86   assumes proj_sets: "\<And>J. finite J \<Longrightarrow> sets (P J) = sets (PiM J M)"
    87 begin
    88 
    89 lemma emeasure_limP:
    90   assumes "finite J"
    91   assumes "J \<subseteq> I"
    92   assumes A: "\<And>i. i\<in>J \<Longrightarrow> A i \<in> sets (M i)"
    93   shows "emeasure (limP J M P) (Pi\<^isub>E J A) = emeasure (P J) (Pi\<^isub>E J A)"
    94 proof -
    95   have "Pi\<^isub>E J (restrict A J) \<subseteq> (\<Pi>\<^isub>E i\<in>J. space (M i))"
    96     using sets_into_space[OF A] by (auto simp: PiE_iff) blast
    97   hence "emeasure (limP J M P) (Pi\<^isub>E J A) =
    98     emeasure (limP J M P) (prod_emb J M J (Pi\<^isub>E J A))"
    99     using assms(1-3) sets_into_space by (auto simp add: prod_emb_id PiE_def Pi_def)
   100   also have "\<dots> = emeasure (P J) (Pi\<^isub>E J A)"
   101   proof (rule emeasure_extend_measure_Pair[OF limP_def])
   102     show "positive (sets (limP J M P)) (P J)" unfolding positive_def by auto
   103     show "countably_additive (sets (limP J M P)) (P J)" unfolding countably_additive_def
   104       by (auto simp: suminf_emeasure proj_sets[OF `finite J`])
   105     show "(J \<noteq> {} \<or> J = {}) \<and> finite J \<and> J \<subseteq> J \<and> A \<in> (\<Pi> j\<in>J. sets (M j))"
   106       using assms by auto
   107     fix K and X::"'i \<Rightarrow> 'a set"
   108     show "prod_emb J M K (Pi\<^isub>E K X) \<in> Pow (\<Pi>\<^isub>E i\<in>J. space (M i))"
   109       by (auto simp: prod_emb_def)
   110     assume JX: "(K \<noteq> {} \<or> J = {}) \<and> finite K \<and> K \<subseteq> J \<and> X \<in> (\<Pi> j\<in>K. sets (M j))"
   111     thus "emeasure (P J) (prod_emb J M K (Pi\<^isub>E K X)) = emeasure (P K) (Pi\<^isub>E K X)"
   112       using assms
   113       apply (cases "J = {}")
   114       apply (simp add: prod_emb_id)
   115       apply (fastforce simp add: intro!: projective sets_PiM_I_finite)
   116       done
   117   qed
   118   finally show ?thesis .
   119 qed
   120 
   121 lemma limP_finite:
   122   assumes "finite J"
   123   assumes "J \<subseteq> I"
   124   shows "limP J M P = P J" (is "?P = _")
   125 proof (rule measure_eqI_generator_eq)
   126   let ?J = "{Pi\<^isub>E J E | E. \<forall>i\<in>J. E i \<in> sets (M i)}"
   127   let ?F = "\<lambda>i. \<Pi>\<^isub>E k\<in>J. space (M k)"
   128   let ?\<Omega> = "(\<Pi>\<^isub>E k\<in>J. space (M k))"
   129   show "Int_stable ?J"
   130     by (rule Int_stable_PiE)
   131   interpret prob_space "P J" using proj_prob_space `finite J` by simp
   132   show "emeasure ?P (?F _) \<noteq> \<infinity>" using assms `finite J` by (auto simp: emeasure_limP)
   133   show "?J \<subseteq> Pow ?\<Omega>" by (auto simp: Pi_iff dest: sets_into_space)
   134   show "sets (limP J M P) = sigma_sets ?\<Omega> ?J" "sets (P J) = sigma_sets ?\<Omega> ?J"
   135     using `finite J` proj_sets by (simp_all add: sets_PiM prod_algebra_eq_finite Pi_iff)
   136   fix X assume "X \<in> ?J"
   137   then obtain E where X: "X = Pi\<^isub>E J E" and E: "\<forall>i\<in>J. E i \<in> sets (M i)" by auto
   138   with `finite J` have "X \<in> sets (limP J M P)" by simp
   139   have emb_self: "prod_emb J M J (Pi\<^isub>E J E) = Pi\<^isub>E J E"
   140     using E sets_into_space
   141     by (auto intro!: prod_emb_PiE_same_index)
   142   show "emeasure (limP J M P) X = emeasure (P J) X"
   143     unfolding X using E
   144     by (intro emeasure_limP assms) simp
   145 qed (insert `finite J`, auto intro!: prod_algebraI_finite)
   146 
   147 lemma emeasure_fun_emb[simp]:
   148   assumes L: "J \<noteq> {}" "J \<subseteq> L" "finite L" "L \<subseteq> I" and X: "X \<in> sets (PiM J M)"
   149   shows "emeasure (limP L M P) (prod_emb L M J X) = emeasure (limP J M P) X"
   150   using assms
   151   by (subst limP_finite) (auto simp: limP_finite finite_subset projective)
   152 
   153 lemma prod_emb_injective:
   154   assumes "J \<noteq> {}" "J \<subseteq> L" "finite J" and sets: "X \<in> sets (Pi\<^isub>M J M)" "Y \<in> sets (Pi\<^isub>M J M)"
   155   assumes "prod_emb L M J X = prod_emb L M J Y"
   156   shows "X = Y"
   157 proof (rule injective_vimage_restrict)
   158   show "X \<subseteq> (\<Pi>\<^isub>E i\<in>J. space (M i))" "Y \<subseteq> (\<Pi>\<^isub>E i\<in>J. space (M i))"
   159     using sets[THEN sets_into_space] by (auto simp: space_PiM)
   160   have "\<forall>i\<in>L. \<exists>x. x \<in> space (M i)"
   161   proof
   162     fix i assume "i \<in> L"
   163     interpret prob_space "P {i}" using proj_prob_space by simp
   164     from not_empty show "\<exists>x. x \<in> space (M i)" by (auto simp add: proj_space space_PiM)
   165   qed
   166   from bchoice[OF this]
   167   show "(\<Pi>\<^isub>E i\<in>L. space (M i)) \<noteq> {}" by (auto simp: PiE_def)
   168   show "(\<lambda>x. restrict x J) -` X \<inter> (\<Pi>\<^isub>E i\<in>L. space (M i)) = (\<lambda>x. restrict x J) -` Y \<inter> (\<Pi>\<^isub>E i\<in>L. space (M i))"
   169     using `prod_emb L M J X = prod_emb L M J Y` by (simp add: prod_emb_def)
   170 qed fact
   171 
   172 abbreviation
   173   "emb L K X \<equiv> prod_emb L M K X"
   174 
   175 definition generator :: "('i \<Rightarrow> 'a) set set" where
   176   "generator = (\<Union>J\<in>{J. J \<noteq> {} \<and> finite J \<and> J \<subseteq> I}. emb I J ` sets (Pi\<^isub>M J M))"
   177 
   178 lemma generatorI':
   179   "J \<noteq> {} \<Longrightarrow> finite J \<Longrightarrow> J \<subseteq> I \<Longrightarrow> X \<in> sets (Pi\<^isub>M J M) \<Longrightarrow> emb I J X \<in> generator"
   180   unfolding generator_def by auto
   181 
   182 lemma algebra_generator:
   183   assumes "I \<noteq> {}" shows "algebra (\<Pi>\<^isub>E i\<in>I. space (M i)) generator" (is "algebra ?\<Omega> ?G")
   184   unfolding algebra_def algebra_axioms_def ring_of_sets_iff
   185 proof (intro conjI ballI)
   186   let ?G = generator
   187   show "?G \<subseteq> Pow ?\<Omega>"
   188     by (auto simp: generator_def prod_emb_def)
   189   from `I \<noteq> {}` obtain i where "i \<in> I" by auto
   190   then show "{} \<in> ?G"
   191     by (auto intro!: exI[of _ "{i}"] image_eqI[where x="\<lambda>i. {}"]
   192              simp: sigma_sets.Empty generator_def prod_emb_def)
   193   from `i \<in> I` show "?\<Omega> \<in> ?G"
   194     by (auto intro!: exI[of _ "{i}"] image_eqI[where x="Pi\<^isub>E {i} (\<lambda>i. space (M i))"]
   195              simp: generator_def prod_emb_def)
   196   fix A assume "A \<in> ?G"
   197   then obtain JA XA where XA: "JA \<noteq> {}" "finite JA" "JA \<subseteq> I" "XA \<in> sets (Pi\<^isub>M JA M)" and A: "A = emb I JA XA"
   198     by (auto simp: generator_def)
   199   fix B assume "B \<in> ?G"
   200   then obtain JB XB where XB: "JB \<noteq> {}" "finite JB" "JB \<subseteq> I" "XB \<in> sets (Pi\<^isub>M JB M)" and B: "B = emb I JB XB"
   201     by (auto simp: generator_def)
   202   let ?RA = "emb (JA \<union> JB) JA XA"
   203   let ?RB = "emb (JA \<union> JB) JB XB"
   204   have *: "A - B = emb I (JA \<union> JB) (?RA - ?RB)" "A \<union> B = emb I (JA \<union> JB) (?RA \<union> ?RB)"
   205     using XA A XB B by auto
   206   show "A - B \<in> ?G" "A \<union> B \<in> ?G"
   207     unfolding * using XA XB by (safe intro!: generatorI') auto
   208 qed
   209 
   210 lemma sets_PiM_generator:
   211   "sets (PiM I M) = sigma_sets (\<Pi>\<^isub>E i\<in>I. space (M i)) generator"
   212 proof cases
   213   assume "I = {}" then show ?thesis
   214     unfolding generator_def
   215     by (auto simp: sets_PiM_empty sigma_sets_empty_eq cong: conj_cong)
   216 next
   217   assume "I \<noteq> {}"
   218   show ?thesis
   219   proof
   220     show "sets (Pi\<^isub>M I M) \<subseteq> sigma_sets (\<Pi>\<^isub>E i\<in>I. space (M i)) generator"
   221       unfolding sets_PiM
   222     proof (safe intro!: sigma_sets_subseteq)
   223       fix A assume "A \<in> prod_algebra I M" with `I \<noteq> {}` show "A \<in> generator"
   224         by (auto intro!: generatorI' sets_PiM_I_finite elim!: prod_algebraE)
   225     qed
   226   qed (auto simp: generator_def space_PiM[symmetric] intro!: sigma_sets_subset)
   227 qed
   228 
   229 lemma generatorI:
   230   "J \<noteq> {} \<Longrightarrow> finite J \<Longrightarrow> J \<subseteq> I \<Longrightarrow> X \<in> sets (Pi\<^isub>M J M) \<Longrightarrow> A = emb I J X \<Longrightarrow> A \<in> generator"
   231   unfolding generator_def by auto
   232 
   233 definition
   234   "\<mu>G A =
   235     (THE x. \<forall>J. J \<noteq> {} \<longrightarrow> finite J \<longrightarrow> J \<subseteq> I \<longrightarrow> (\<forall>X\<in>sets (Pi\<^isub>M J M). A = emb I J X \<longrightarrow> x = emeasure (limP J M P) X))"
   236 
   237 lemma \<mu>G_spec:
   238   assumes J: "J \<noteq> {}" "finite J" "J \<subseteq> I" "A = emb I J X" "X \<in> sets (Pi\<^isub>M J M)"
   239   shows "\<mu>G A = emeasure (limP J M P) X"
   240   unfolding \<mu>G_def
   241 proof (intro the_equality allI impI ballI)
   242   fix K Y assume K: "K \<noteq> {}" "finite K" "K \<subseteq> I" "A = emb I K Y" "Y \<in> sets (Pi\<^isub>M K M)"
   243   have "emeasure (limP K M P) Y = emeasure (limP (K \<union> J) M P) (emb (K \<union> J) K Y)"
   244     using K J by simp
   245   also have "emb (K \<union> J) K Y = emb (K \<union> J) J X"
   246     using K J by (simp add: prod_emb_injective[of "K \<union> J" I])
   247   also have "emeasure (limP (K \<union> J) M P) (emb (K \<union> J) J X) = emeasure (limP J M P) X"
   248     using K J by simp
   249   finally show "emeasure (limP J M P) X = emeasure (limP K M P) Y" ..
   250 qed (insert J, force)
   251 
   252 lemma \<mu>G_eq:
   253   "J \<noteq> {} \<Longrightarrow> finite J \<Longrightarrow> J \<subseteq> I \<Longrightarrow> X \<in> sets (Pi\<^isub>M J M) \<Longrightarrow> \<mu>G (emb I J X) = emeasure (limP J M P) X"
   254   by (intro \<mu>G_spec) auto
   255 
   256 lemma generator_Ex:
   257   assumes *: "A \<in> generator"
   258   shows "\<exists>J X. J \<noteq> {} \<and> finite J \<and> J \<subseteq> I \<and> X \<in> sets (Pi\<^isub>M J M) \<and> A = emb I J X \<and> \<mu>G A = emeasure (limP J M P) X"
   259 proof -
   260   from * obtain J X where J: "J \<noteq> {}" "finite J" "J \<subseteq> I" "A = emb I J X" "X \<in> sets (Pi\<^isub>M J M)"
   261     unfolding generator_def by auto
   262   with \<mu>G_spec[OF this] show ?thesis by auto
   263 qed
   264 
   265 lemma generatorE:
   266   assumes A: "A \<in> generator"
   267   obtains J X where "J \<noteq> {}" "finite J" "J \<subseteq> I" "X \<in> sets (Pi\<^isub>M J M)" "emb I J X = A" "\<mu>G A = emeasure (limP J M P) X"
   268 proof -
   269   from generator_Ex[OF A] obtain X J where "J \<noteq> {}" "finite J" "J \<subseteq> I" "X \<in> sets (Pi\<^isub>M J M)" "emb I J X = A"
   270     "\<mu>G A = emeasure (limP J M P) X" by auto
   271   then show thesis by (intro that) auto
   272 qed
   273 
   274 lemma merge_sets:
   275   "J \<inter> K = {} \<Longrightarrow> A \<in> sets (Pi\<^isub>M (J \<union> K) M) \<Longrightarrow> x \<in> space (Pi\<^isub>M J M) \<Longrightarrow> (\<lambda>y. merge J K (x,y)) -` A \<inter> space (Pi\<^isub>M K M) \<in> sets (Pi\<^isub>M K M)"
   276   by simp
   277 
   278 lemma merge_emb:
   279   assumes "K \<subseteq> I" "J \<subseteq> I" and y: "y \<in> space (Pi\<^isub>M J M)"
   280   shows "((\<lambda>x. merge J (I - J) (y, x)) -` emb I K X \<inter> space (Pi\<^isub>M I M)) =
   281     emb I (K - J) ((\<lambda>x. merge J (K - J) (y, x)) -` emb (J \<union> K) K X \<inter> space (Pi\<^isub>M (K - J) M))"
   282 proof -
   283   have [simp]: "\<And>x J K L. merge J K (y, restrict x L) = merge J (K \<inter> L) (y, x)"
   284     by (auto simp: restrict_def merge_def)
   285   have [simp]: "\<And>x J K L. restrict (merge J K (y, x)) L = merge (J \<inter> L) (K \<inter> L) (y, x)"
   286     by (auto simp: restrict_def merge_def)
   287   have [simp]: "(I - J) \<inter> K = K - J" using `K \<subseteq> I` `J \<subseteq> I` by auto
   288   have [simp]: "(K - J) \<inter> (K \<union> J) = K - J" by auto
   289   have [simp]: "(K - J) \<inter> K = K - J" by auto
   290   from y `K \<subseteq> I` `J \<subseteq> I` show ?thesis
   291     by (simp split: split_merge add: prod_emb_def Pi_iff PiE_def extensional_merge_sub set_eq_iff space_PiM)
   292        auto
   293 qed
   294 
   295 lemma positive_\<mu>G:
   296   assumes "I \<noteq> {}"
   297   shows "positive generator \<mu>G"
   298 proof -
   299   interpret G!: algebra "\<Pi>\<^isub>E i\<in>I. space (M i)" generator by (rule algebra_generator) fact
   300   show ?thesis
   301   proof (intro positive_def[THEN iffD2] conjI ballI)
   302     from generatorE[OF G.empty_sets] guess J X . note this[simp]
   303     have "X = {}"
   304       by (rule prod_emb_injective[of J I]) simp_all
   305     then show "\<mu>G {} = 0" by simp
   306   next
   307     fix A assume "A \<in> generator"
   308     from generatorE[OF this] guess J X . note this[simp]
   309     show "0 \<le> \<mu>G A" by (simp add: emeasure_nonneg)
   310   qed
   311 qed
   312 
   313 lemma additive_\<mu>G:
   314   assumes "I \<noteq> {}"
   315   shows "additive generator \<mu>G"
   316 proof -
   317   interpret G!: algebra "\<Pi>\<^isub>E i\<in>I. space (M i)" generator by (rule algebra_generator) fact
   318   show ?thesis
   319   proof (intro additive_def[THEN iffD2] ballI impI)
   320     fix A assume "A \<in> generator" with generatorE guess J X . note J = this
   321     fix B assume "B \<in> generator" with generatorE guess K Y . note K = this
   322     assume "A \<inter> B = {}"
   323     have JK: "J \<union> K \<noteq> {}" "J \<union> K \<subseteq> I" "finite (J \<union> K)"
   324       using J K by auto
   325     have JK_disj: "emb (J \<union> K) J X \<inter> emb (J \<union> K) K Y = {}"
   326       apply (rule prod_emb_injective[of "J \<union> K" I])
   327       apply (insert `A \<inter> B = {}` JK J K)
   328       apply (simp_all add: Int prod_emb_Int)
   329       done
   330     have AB: "A = emb I (J \<union> K) (emb (J \<union> K) J X)" "B = emb I (J \<union> K) (emb (J \<union> K) K Y)"
   331       using J K by simp_all
   332     then have "\<mu>G (A \<union> B) = \<mu>G (emb I (J \<union> K) (emb (J \<union> K) J X \<union> emb (J \<union> K) K Y))"
   333       by simp
   334     also have "\<dots> = emeasure (limP (J \<union> K) M P) (emb (J \<union> K) J X \<union> emb (J \<union> K) K Y)"
   335       using JK J(1, 4) K(1, 4) by (simp add: \<mu>G_eq Un del: prod_emb_Un)
   336     also have "\<dots> = \<mu>G A + \<mu>G B"
   337       using J K JK_disj by (simp add: plus_emeasure[symmetric])
   338     finally show "\<mu>G (A \<union> B) = \<mu>G A + \<mu>G B" .
   339   qed
   340 qed
   341 
   342 end
   343 
   344 sublocale product_prob_space \<subseteq> projective_family I "\<lambda>J. PiM J M" M
   345 proof
   346   fix J::"'i set" assume "finite J"
   347   interpret f: finite_product_prob_space M J proof qed fact
   348   show "emeasure (Pi\<^isub>M J M) (space (Pi\<^isub>M J M)) \<noteq> \<infinity>" by simp
   349   show "\<exists>A. range A \<subseteq> sets (Pi\<^isub>M J M) \<and>
   350             (\<Union>i. A i) = space (Pi\<^isub>M J M) \<and>
   351             (\<forall>i. emeasure (Pi\<^isub>M J M) (A i) \<noteq> \<infinity>)" using sigma_finite[OF `finite J`]
   352     by (auto simp add: sigma_finite_measure_def)
   353   show "emeasure (Pi\<^isub>M J M) (space (Pi\<^isub>M J M)) = 1" by (rule f.emeasure_space_1)
   354 qed simp_all
   355 
   356 lemma (in product_prob_space) limP_PiM_finite[simp]:
   357   assumes "J \<noteq> {}" "finite J" "J \<subseteq> I" shows "limP J M (\<lambda>J. PiM J M) = PiM J M"
   358   using assms by (simp add: limP_finite)
   359 
   360 end