src/Pure/Thy/thy_output.ML
author wenzelm
Mon Nov 29 11:22:40 2010 +0100 (2010-11-29)
changeset 40801 6cfacec435e6
parent 40800 330eb65c9469
child 40879 ca132ef44944
permissions -rw-r--r--
added document antiquotation @{file};
     1 (*  Title:      Pure/Thy/thy_output.ML
     2     Author:     Markus Wenzel, TU Muenchen
     3 
     4 Theory document output with antiquotations.
     5 *)
     6 
     7 signature THY_OUTPUT =
     8 sig
     9   val display_default: bool Unsynchronized.ref
    10   val quotes_default: bool Unsynchronized.ref
    11   val indent_default: int Unsynchronized.ref
    12   val source_default: bool Unsynchronized.ref
    13   val break_default: bool Unsynchronized.ref
    14   val display: bool Config.T
    15   val quotes: bool Config.T
    16   val indent: int Config.T
    17   val source: bool Config.T
    18   val break: bool Config.T
    19   val add_wrapper: ((unit -> string) -> unit -> string) -> Proof.context -> Proof.context
    20   val add_option: string -> (string -> Proof.context -> Proof.context) -> unit
    21   val defined_command: string -> bool
    22   val defined_option: string -> bool
    23   val print_antiquotations: unit -> unit
    24   val boolean: string -> bool
    25   val integer: string -> int
    26   val antiquotation: string -> 'a context_parser ->
    27     ({source: Args.src, state: Toplevel.state, context: Proof.context} -> 'a -> string) -> unit
    28   datatype markup = Markup | MarkupEnv | Verbatim
    29   val modes: string list Unsynchronized.ref
    30   val eval_antiquote: Scan.lexicon -> Toplevel.state -> Symbol_Pos.text * Position.T -> string
    31   val present_thy: Scan.lexicon -> (string -> string list) -> (markup -> string -> bool) ->
    32     (Toplevel.transition * Toplevel.state) list -> (Token.T, 'a) Source.source -> Buffer.T
    33   val pretty_text: Proof.context -> string -> Pretty.T
    34   val pretty_term: Proof.context -> term -> Pretty.T
    35   val pretty_thm: Proof.context -> thm -> Pretty.T
    36   val str_of_source: Args.src -> string
    37   val maybe_pretty_source: (Proof.context -> 'a -> Pretty.T) -> Proof.context ->
    38     Args.src -> 'a list -> Pretty.T list
    39   val output: Proof.context -> Pretty.T list -> string
    40 end;
    41 
    42 structure Thy_Output: THY_OUTPUT =
    43 struct
    44 
    45 (** global options **)
    46 
    47 val display_default = Unsynchronized.ref false;
    48 val quotes_default = Unsynchronized.ref false;
    49 val indent_default = Unsynchronized.ref 0;
    50 val source_default = Unsynchronized.ref false;
    51 val break_default = Unsynchronized.ref false;
    52 
    53 val (display, setup_display) = Attrib.config_bool "thy_output_display" (fn _ => ! display_default);
    54 val (quotes, setup_quotes) = Attrib.config_bool "thy_output_quotes" (fn _ => ! quotes_default);
    55 val (indent, setup_indent) = Attrib.config_int "thy_output_indent" (fn _ => ! indent_default);
    56 val (source, setup_source) = Attrib.config_bool "thy_output_source" (fn _ => ! source_default);
    57 val (break, setup_break) = Attrib.config_bool "thy_output_break" (fn _ => ! break_default);
    58 
    59 val _ = Context.>> (Context.map_theory
    60  (setup_display #> setup_quotes #> setup_indent #> setup_source #> setup_break));
    61 
    62 
    63 structure Wrappers = Proof_Data
    64 (
    65   type T = ((unit -> string) -> unit -> string) list;
    66   fun init _ = [];
    67 );
    68 
    69 fun add_wrapper wrapper = Wrappers.map (cons wrapper);
    70 
    71 val wrap = Wrappers.get #> fold (fn wrapper => fn f => wrapper f);
    72 
    73 
    74 
    75 (** maintain global antiquotations **)
    76 
    77 local
    78 
    79 val global_commands =
    80   Unsynchronized.ref
    81     (Symtab.empty: (Args.src -> Toplevel.state -> Proof.context -> string) Symtab.table);
    82 
    83 val global_options =
    84   Unsynchronized.ref (Symtab.empty: (string -> Proof.context -> Proof.context) Symtab.table);
    85 
    86 fun add_item kind name item tab =
    87  (if not (Symtab.defined tab name) then ()
    88   else warning ("Redefined document antiquotation " ^ kind ^ ": " ^ quote name);
    89   Symtab.update (name, item) tab);
    90 
    91 in
    92 
    93 fun add_command name cmd =
    94   CRITICAL (fn () => Unsynchronized.change global_commands (add_item "command" name cmd));
    95 fun add_option name opt =
    96   CRITICAL (fn () => Unsynchronized.change global_options (add_item "option" name opt));
    97 
    98 fun defined_command name = Symtab.defined (! global_commands) name;
    99 fun defined_option name = Symtab.defined (! global_options) name;
   100 
   101 fun command src =
   102   let val ((name, _), pos) = Args.dest_src src in
   103     (case Symtab.lookup (! global_commands) name of
   104       NONE => error ("Unknown document antiquotation: " ^ quote name ^ Position.str_of pos)
   105     | SOME f =>
   106        (Position.report pos (Markup.doc_antiq name);
   107         (fn state => fn ctxt => f src state ctxt handle ERROR msg =>
   108           cat_error msg ("The error(s) above occurred in document antiquotation: " ^
   109             quote name ^ Position.str_of pos))))
   110   end;
   111 
   112 fun option (name, s) ctxt =
   113   (case Symtab.lookup (! global_options) name of
   114     NONE => error ("Unknown document antiquotation option: " ^ quote name)
   115   | SOME opt => opt s ctxt);
   116 
   117 
   118 fun print_antiquotations () =
   119  [Pretty.big_list "document antiquotation commands:"
   120     (map Pretty.str (sort_strings (Symtab.keys (! global_commands)))),
   121   Pretty.big_list "document antiquotation options:"
   122     (map Pretty.str (sort_strings (Symtab.keys (! global_options))))]
   123  |> Pretty.chunks |> Pretty.writeln;
   124 
   125 end;
   126 
   127 fun antiquotation name scan out =
   128   add_command name
   129     (fn src => fn state => fn ctxt =>
   130       let val (x, ctxt') = Args.context_syntax "document antiquotation" scan src ctxt
   131       in out {source = src, state = state, context = ctxt'} x end);
   132 
   133 
   134 
   135 (** syntax of antiquotations **)
   136 
   137 (* option values *)
   138 
   139 fun boolean "" = true
   140   | boolean "true" = true
   141   | boolean "false" = false
   142   | boolean s = error ("Bad boolean value: " ^ quote s);
   143 
   144 fun integer s =
   145   let
   146     fun int ss =
   147       (case Library.read_int ss of (i, []) => i
   148       | _ => error ("Bad integer value: " ^ quote s));
   149   in (case Symbol.explode s of "-" :: ss => ~ (int ss) | ss => int ss) end;
   150 
   151 
   152 (* outer syntax *)
   153 
   154 local
   155 
   156 val property =
   157   Parse.xname -- Scan.optional (Parse.$$$ "=" |-- Parse.!!! Parse.xname) "";
   158 
   159 val properties =
   160   Scan.optional (Parse.$$$ "[" |-- Parse.!!! (Parse.enum "," property --| Parse.$$$ "]")) [];
   161 
   162 in
   163 
   164 val antiq =
   165   Parse.!!!
   166     (Parse.position Parse.liberal_name -- properties -- Args.parse --| Scan.ahead Parse.eof)
   167   >> (fn (((x, pos), y), z) => (y, Args.src ((x, z), pos)));
   168 
   169 end;
   170 
   171 
   172 (* eval_antiquote *)
   173 
   174 val modes = Unsynchronized.ref ([]: string list);
   175 
   176 fun eval_antiquote lex state (txt, pos) =
   177   let
   178     fun expand (Antiquote.Text ss) = Symbol_Pos.content ss
   179       | expand (Antiquote.Antiq (ss, (pos, _))) =
   180           let
   181             val (opts, src) = Token.read_antiq lex antiq (ss, pos);
   182             fun cmd ctxt = wrap ctxt (fn () => command src state ctxt) ();
   183             val preview_ctxt = fold option opts (Toplevel.presentation_context_of state);
   184             val print_ctxt = Context_Position.set_visible false preview_ctxt;
   185             val _ = cmd preview_ctxt;
   186           in Print_Mode.with_modes (! modes @ Latex.modes) (fn () => cmd print_ctxt) () end
   187       | expand (Antiquote.Open _) = ""
   188       | expand (Antiquote.Close _) = "";
   189     val ants = Antiquote.read (Symbol_Pos.explode (txt, pos), pos);
   190   in
   191     if Toplevel.is_toplevel state andalso not (forall Antiquote.is_text ants) then
   192       error ("Unknown context -- cannot expand document antiquotations" ^ Position.str_of pos)
   193     else implode (map expand ants)
   194   end;
   195 
   196 
   197 
   198 (** present theory source **)
   199 
   200 (*NB: arranging white space around command spans is a black art.*)
   201 
   202 (* presentation tokens *)
   203 
   204 datatype token =
   205     NoToken
   206   | BasicToken of Token.T
   207   | MarkupToken of string * (string * Position.T)
   208   | MarkupEnvToken of string * (string * Position.T)
   209   | VerbatimToken of string * Position.T;
   210 
   211 fun output_token lex state =
   212   let val eval = eval_antiquote lex state in
   213     fn NoToken => ""
   214      | BasicToken tok => Latex.output_basic tok
   215      | MarkupToken (cmd, txt) => Latex.output_markup cmd (eval txt)
   216      | MarkupEnvToken (cmd, txt) => Latex.output_markup_env cmd (eval txt)
   217      | VerbatimToken txt => Latex.output_verbatim (eval txt)
   218   end;
   219 
   220 fun basic_token pred (BasicToken tok) = pred tok
   221   | basic_token _ _ = false;
   222 
   223 val improper_token = basic_token (not o Token.is_proper);
   224 val comment_token = basic_token Token.is_comment;
   225 val blank_token = basic_token Token.is_blank;
   226 val newline_token = basic_token Token.is_newline;
   227 
   228 
   229 (* command spans *)
   230 
   231 type command = string * Position.T * string list;   (*name, position, tags*)
   232 type source = (token * (string * int)) list;        (*token, markup flag, meta-comment depth*)
   233 
   234 datatype span = Span of command * (source * source * source * source) * bool;
   235 
   236 fun make_span cmd src =
   237   let
   238     fun take_newline (tok :: toks) =
   239           if newline_token (fst tok) then ([tok], toks, true)
   240           else ([], tok :: toks, false)
   241       | take_newline [] = ([], [], false);
   242     val (((src_prefix, src_main), src_suffix1), (src_suffix2, src_appendix, newline)) =
   243       src
   244       |> take_prefix (improper_token o fst)
   245       ||>> take_suffix (improper_token o fst)
   246       ||>> take_prefix (comment_token o fst)
   247       ||> take_newline;
   248   in Span (cmd, (src_prefix, src_main, src_suffix1 @ src_suffix2, src_appendix), newline) end;
   249 
   250 
   251 (* present spans *)
   252 
   253 local
   254 
   255 fun err_bad_nesting pos =
   256   error ("Bad nesting of commands in presentation" ^ pos);
   257 
   258 fun edge which f (x: string option, y) =
   259   if x = y then I
   260   else (case which (x, y) of NONE => I | SOME txt => Buffer.add (f txt));
   261 
   262 val begin_tag = edge #2 Latex.begin_tag;
   263 val end_tag = edge #1 Latex.end_tag;
   264 fun open_delim delim e = edge #2 Latex.begin_delim e #> delim #> edge #2 Latex.end_delim e;
   265 fun close_delim delim e = edge #1 Latex.begin_delim e #> delim #> edge #1 Latex.end_delim e;
   266 
   267 in
   268 
   269 fun present_span lex default_tags span state state'
   270     (tag_stack, active_tag, newline, buffer, present_cont) =
   271   let
   272     val present = fold (fn (tok, (flag, 0)) =>
   273         Buffer.add (output_token lex state' tok)
   274         #> Buffer.add flag
   275       | _ => I);
   276 
   277     val Span ((cmd_name, cmd_pos, cmd_tags), srcs, span_newline) = span;
   278 
   279     val (tag, tags) = tag_stack;
   280     val tag' = try hd (fold Keyword.update_tags cmd_tags (the_list tag));
   281 
   282     val active_tag' =
   283       if is_some tag' then tag'
   284       else if cmd_name = "end" andalso not (Toplevel.is_toplevel state') then NONE
   285       else try hd (default_tags cmd_name);
   286     val edge = (active_tag, active_tag');
   287 
   288     val newline' =
   289       if is_none active_tag' then span_newline else newline;
   290 
   291     val nesting = Toplevel.level state' - Toplevel.level state;
   292     val tag_stack' =
   293       if nesting = 0 andalso not (Toplevel.is_proof state) then tag_stack
   294       else if nesting >= 0 then (tag', replicate nesting tag @ tags)
   295       else
   296         (case drop (~ nesting - 1) tags of
   297           tgs :: tgss => (tgs, tgss)
   298         | [] => err_bad_nesting (Position.str_of cmd_pos));
   299 
   300     val buffer' =
   301       buffer
   302       |> end_tag edge
   303       |> close_delim (fst present_cont) edge
   304       |> snd present_cont
   305       |> open_delim (present (#1 srcs)) edge
   306       |> begin_tag edge
   307       |> present (#2 srcs);
   308     val present_cont' =
   309       if newline then (present (#3 srcs), present (#4 srcs))
   310       else (I, present (#3 srcs) #> present (#4 srcs));
   311   in (tag_stack', active_tag', newline', buffer', present_cont') end;
   312 
   313 fun present_trailer ((_, tags), active_tag, _, buffer, present_cont) =
   314   if not (null tags) then err_bad_nesting " at end of theory"
   315   else
   316     buffer
   317     |> end_tag (active_tag, NONE)
   318     |> close_delim (fst present_cont) (active_tag, NONE)
   319     |> snd present_cont;
   320 
   321 end;
   322 
   323 
   324 (* present_thy *)
   325 
   326 datatype markup = Markup | MarkupEnv | Verbatim;
   327 
   328 local
   329 
   330 val space_proper =
   331   Scan.one Token.is_blank -- Scan.many Token.is_comment -- Scan.one Token.is_proper;
   332 
   333 val is_improper = not o (Token.is_proper orf Token.is_begin_ignore orf Token.is_end_ignore);
   334 val improper = Scan.many is_improper;
   335 val improper_end = Scan.repeat (Scan.unless space_proper (Scan.one is_improper));
   336 val blank_end = Scan.repeat (Scan.unless space_proper (Scan.one Token.is_blank));
   337 
   338 val opt_newline = Scan.option (Scan.one Token.is_newline);
   339 
   340 val ignore =
   341   Scan.depend (fn d => opt_newline |-- Scan.one Token.is_begin_ignore
   342     >> pair (d + 1)) ||
   343   Scan.depend (fn d => Scan.one Token.is_end_ignore --|
   344     (if d = 0 then Scan.fail_with (K "Bad nesting of meta-comments") else opt_newline)
   345     >> pair (d - 1));
   346 
   347 val tag = (improper -- Parse.$$$ "%" -- improper) |-- Parse.!!! (Parse.tag_name --| blank_end);
   348 
   349 val locale =
   350   Scan.option ((Parse.$$$ "(" -- improper -- Parse.$$$ "in") |--
   351     Parse.!!! (improper |-- Parse.xname --| (improper -- Parse.$$$ ")")));
   352 
   353 in
   354 
   355 fun present_thy lex default_tags is_markup command_results src =
   356   let
   357     (* tokens *)
   358 
   359     val ignored = Scan.state --| ignore
   360       >> (fn d => (NONE, (NoToken, ("", d))));
   361 
   362     fun markup mark mk flag = Scan.peek (fn d =>
   363       improper |--
   364         Parse.position
   365           (Scan.one (Token.is_kind Token.Command andf is_markup mark o Token.content_of)) --
   366       Scan.repeat tag --
   367       Parse.!!!! ((improper -- locale -- improper) |-- Parse.doc_source --| improper_end)
   368       >> (fn (((tok, pos), tags), txt) =>
   369         let val name = Token.content_of tok
   370         in (SOME (name, pos, tags), (mk (name, txt), (flag, d))) end));
   371 
   372     val command = Scan.peek (fn d =>
   373       Parse.position (Scan.one (Token.is_kind Token.Command)) --
   374       Scan.repeat tag
   375       >> (fn ((tok, pos), tags) =>
   376         let val name = Token.content_of tok
   377         in (SOME (name, pos, tags), (BasicToken tok, (Latex.markup_false, d))) end));
   378 
   379     val cmt = Scan.peek (fn d =>
   380       Parse.$$$ "--" |-- Parse.!!!! (improper |-- Parse.doc_source)
   381       >> (fn txt => (NONE, (MarkupToken ("cmt", txt), ("", d)))));
   382 
   383     val other = Scan.peek (fn d =>
   384        Parse.not_eof >> (fn tok => (NONE, (BasicToken tok, ("", d)))));
   385 
   386     val token =
   387       ignored ||
   388       markup Markup MarkupToken Latex.markup_true ||
   389       markup MarkupEnv MarkupEnvToken Latex.markup_true ||
   390       markup Verbatim (VerbatimToken o #2) "" ||
   391       command || cmt || other;
   392 
   393 
   394     (* spans *)
   395 
   396     val is_eof = fn (_, (BasicToken x, _)) => Token.is_eof x | _ => false;
   397     val stopper = Scan.stopper (K (NONE, (BasicToken Token.eof, ("", 0)))) is_eof;
   398 
   399     val cmd = Scan.one (is_some o fst);
   400     val non_cmd = Scan.one (is_none o fst andf not o is_eof) >> #2;
   401 
   402     val comments = Scan.many (comment_token o fst o snd);
   403     val blank = Scan.one (blank_token o fst o snd);
   404     val newline = Scan.one (newline_token o fst o snd);
   405     val before_cmd =
   406       Scan.option (newline -- comments) --
   407       Scan.option (newline -- comments) --
   408       Scan.option (blank -- comments) -- cmd;
   409 
   410     val span =
   411       Scan.repeat non_cmd -- cmd --
   412         Scan.repeat (Scan.unless before_cmd non_cmd) --
   413         Scan.option (newline >> (single o snd))
   414       >> (fn (((toks1, (cmd, tok2)), toks3), tok4) =>
   415           make_span (the cmd) (toks1 @ (tok2 :: (toks3 @ the_default [] tok4))));
   416 
   417     val spans =
   418       src
   419       |> Source.filter (not o Token.is_semicolon)
   420       |> Source.source' 0 Token.stopper (Scan.error (Scan.bulk token)) NONE
   421       |> Source.source stopper (Scan.error (Scan.bulk span)) NONE
   422       |> Source.exhaust;
   423 
   424 
   425     (* present commands *)
   426 
   427     fun present_command tr span st st' =
   428       Toplevel.setmp_thread_position tr (present_span lex default_tags span st st');
   429 
   430     fun present _ [] = I
   431       | present st (((tr, st'), span) :: rest) = present_command tr span st st' #> present st' rest;
   432   in
   433     if length command_results = length spans then
   434       ((NONE, []), NONE, true, Buffer.empty, (I, I))
   435       |> present Toplevel.toplevel (command_results ~~ spans)
   436       |> present_trailer
   437     else error "Messed-up outer syntax for presentation"
   438   end;
   439 
   440 end;
   441 
   442 
   443 
   444 (** setup default output **)
   445 
   446 (* options *)
   447 
   448 val _ = add_option "show_types" (Config.put show_types o boolean);
   449 val _ = add_option "show_sorts" (Config.put show_sorts o boolean);
   450 val _ = add_option "show_structs" (Config.put show_structs o boolean);
   451 val _ = add_option "show_question_marks" (Config.put show_question_marks o boolean);
   452 val _ = add_option "long_names" (add_wrapper o setmp_CRITICAL Name_Space.long_names o boolean);
   453 val _ = add_option "short_names" (add_wrapper o setmp_CRITICAL Name_Space.short_names o boolean);
   454 val _ = add_option "unique_names" (add_wrapper o setmp_CRITICAL Name_Space.unique_names o boolean);
   455 val _ = add_option "eta_contract" (Config.put eta_contract o boolean);
   456 val _ = add_option "display" (Config.put display o boolean);
   457 val _ = add_option "break" (Config.put break o boolean);
   458 val _ = add_option "quotes" (Config.put quotes o boolean);
   459 val _ = add_option "mode" (add_wrapper o Print_Mode.with_modes o single);
   460 val _ = add_option "margin" (add_wrapper o setmp_CRITICAL Pretty.margin_default o integer);
   461 val _ = add_option "indent" (Config.put indent o integer);
   462 val _ = add_option "source" (Config.put source o boolean);
   463 val _ = add_option "goals_limit" (Config.put Goal_Display.goals_limit o integer);
   464 
   465 
   466 (* basic pretty printing *)
   467 
   468 fun tweak_line ctxt s =
   469   if Config.get ctxt display then s else Symbol.strip_blanks s;
   470 
   471 fun pretty_text ctxt =
   472   Pretty.chunks o map Pretty.str o map (tweak_line ctxt) o Library.split_lines;
   473 
   474 fun pretty_term ctxt t = Syntax.pretty_term (Variable.auto_fixes t ctxt) t;
   475 
   476 fun pretty_thm ctxt = pretty_term ctxt o Thm.full_prop_of;
   477 
   478 fun pretty_term_style ctxt (style, t) =
   479   pretty_term ctxt (style t);
   480 
   481 fun pretty_thm_style ctxt (style, th) =
   482   pretty_term ctxt (style (Thm.full_prop_of th));
   483 
   484 fun pretty_term_typ ctxt (style, t) =
   485   let val t' = style t
   486   in pretty_term ctxt (Type.constraint (Term.fastype_of t') t') end;
   487 
   488 fun pretty_term_typeof ctxt (style, t) =
   489   Syntax.pretty_typ ctxt (Term.fastype_of (style t));
   490 
   491 fun pretty_const ctxt c =
   492   let
   493     val t = Const (c, Consts.type_scheme (ProofContext.consts_of ctxt) c)
   494       handle TYPE (msg, _, _) => error msg;
   495     val ([t'], _) = Variable.import_terms true [t] ctxt;
   496   in pretty_term ctxt t' end;
   497 
   498 fun pretty_abbrev ctxt s =
   499   let
   500     val t = Syntax.parse_term ctxt s |> singleton (ProofContext.standard_infer_types ctxt);
   501     fun err () = error ("Abbreviated constant expected: " ^ Syntax.string_of_term ctxt t);
   502     val (head, args) = Term.strip_comb t;
   503     val (c, T) = Term.dest_Const head handle TERM _ => err ();
   504     val (U, u) = Consts.the_abbreviation (ProofContext.consts_of ctxt) c
   505       handle TYPE _ => err ();
   506     val t' = Term.betapplys (Envir.expand_atom T (U, u), args);
   507     val eq = Logic.mk_equals (t, t');
   508     val ctxt' = Variable.auto_fixes eq ctxt;
   509   in ProofContext.pretty_term_abbrev ctxt' eq end;
   510 
   511 fun pretty_class ctxt =
   512   Pretty.str o Type.extern_class (ProofContext.tsig_of ctxt) o ProofContext.read_class ctxt;
   513 
   514 fun pretty_type ctxt s =
   515   let val Type (name, _) = ProofContext.read_type_name_proper ctxt false s
   516   in Pretty.str (Type.extern_type (ProofContext.tsig_of ctxt) name) end;
   517 
   518 fun pretty_prf full ctxt = Proof_Syntax.pretty_proof_of ctxt full;
   519 
   520 fun pretty_theory ctxt name =
   521   (Theory.requires (ProofContext.theory_of ctxt) name "presentation"; Pretty.str name);
   522 
   523 
   524 (* default output *)
   525 
   526 val str_of_source = space_implode " " o map Token.unparse o #2 o #1 o Args.dest_src;
   527 
   528 fun maybe_pretty_source pretty ctxt src xs =
   529   map (pretty ctxt) xs  (*always pretty in order to exhibit errors!*)
   530   |> (if Config.get ctxt source then K [pretty_text ctxt (str_of_source src)] else I);
   531 
   532 fun output ctxt prts =
   533   prts
   534   |> (if Config.get ctxt quotes then map Pretty.quote else I)
   535   |> (if Config.get ctxt display then
   536     map (Output.output o Pretty.string_of o Pretty.indent (Config.get ctxt indent))
   537     #> space_implode "\\isasep\\isanewline%\n"
   538     #> enclose "\\begin{isabelle}%\n" "%\n\\end{isabelle}"
   539   else
   540     map (Output.output o (if Config.get ctxt break then Pretty.string_of else Pretty.str_of))
   541     #> space_implode "\\isasep\\isanewline%\n"
   542     #> enclose "\\isa{" "}");
   543 
   544 
   545 
   546 (** concrete antiquotations **)
   547 
   548 (* basic entities *)
   549 
   550 local
   551 
   552 fun basic_entities name scan pretty = antiquotation name scan
   553   (fn {source, context, ...} => output context o maybe_pretty_source pretty context source);
   554 
   555 fun basic_entities_style name scan pretty = antiquotation name scan
   556   (fn {source, context, ...} => fn (style, xs) =>
   557     output context
   558       (maybe_pretty_source (fn ctxt => fn x => pretty ctxt (style, x)) context source xs));
   559 
   560 fun basic_entity name scan = basic_entities name (scan >> single);
   561 
   562 in
   563 
   564 val _ = basic_entities_style "thm" (Term_Style.parse -- Attrib.thms) pretty_thm_style;
   565 val _ = basic_entity "prop" (Term_Style.parse -- Args.prop) pretty_term_style;
   566 val _ = basic_entity "term" (Term_Style.parse -- Args.term) pretty_term_style;
   567 val _ = basic_entity "term_type" (Term_Style.parse -- Args.term) pretty_term_typ;
   568 val _ = basic_entity "typeof" (Term_Style.parse -- Args.term) pretty_term_typeof;
   569 val _ = basic_entity "const" (Args.const_proper false) pretty_const;
   570 val _ = basic_entity "abbrev" (Scan.lift Args.name_source) pretty_abbrev;
   571 val _ = basic_entity "typ" Args.typ_abbrev Syntax.pretty_typ;
   572 val _ = basic_entity "class" (Scan.lift Args.name) pretty_class;
   573 val _ = basic_entity "type" (Scan.lift Args.name) pretty_type;
   574 val _ = basic_entity "text" (Scan.lift Args.name) pretty_text;
   575 val _ = basic_entities "prf" Attrib.thms (pretty_prf false);
   576 val _ = basic_entities "full_prf" Attrib.thms (pretty_prf true);
   577 val _ = basic_entity "theory" (Scan.lift Args.name) pretty_theory;
   578 val _ = basic_entities_style "thm_style" (Term_Style.parse_bare -- Attrib.thms) pretty_thm_style;
   579 val _ = basic_entity "term_style" (Term_Style.parse_bare -- Args.term) pretty_term_style;
   580 
   581 end;
   582 
   583 
   584 (* goal state *)
   585 
   586 local
   587 
   588 fun proof_state state =
   589   (case try Toplevel.proof_of state of
   590     SOME prf => prf
   591   | _ => error "No proof state");
   592 
   593 fun goal_state name main_goal = antiquotation name (Scan.succeed ())
   594   (fn {state, context = ctxt, ...} => fn () => output ctxt
   595     [Pretty.chunks
   596       (Proof.pretty_goals main_goal (Proof.map_context (K ctxt) (proof_state state)))]);
   597 
   598 in
   599 
   600 val _ = goal_state "goals" true;
   601 val _ = goal_state "subgoals" false;
   602 
   603 end;
   604 
   605 
   606 (* embedded lemma *)
   607 
   608 val _ = Keyword.keyword "by";
   609 
   610 val _ = antiquotation "lemma"
   611   (Args.prop -- Scan.lift (Args.$$$ "by" |-- Method.parse -- Scan.option Method.parse))
   612   (fn {source, context, ...} => fn (prop, methods) =>
   613     let
   614       val prop_src =
   615         (case Args.dest_src source of ((a, arg :: _), pos) => Args.src ((a, [arg]), pos));
   616       val _ = context
   617         |> Proof.theorem NONE (K I) [[(prop, [])]]
   618         |> Proof.global_terminal_proof methods;
   619     in output context (maybe_pretty_source pretty_term context prop_src [prop]) end);
   620 
   621 
   622 (* ML text *)
   623 
   624 val verb_text =
   625   split_lines
   626   #> map (space_implode "\\verb,|," o map (enclose "\\verb|" "|") o space_explode "|")
   627   #> space_implode "\\isasep\\isanewline%\n";
   628 
   629 local
   630 
   631 fun ml_text name ml = antiquotation name (Scan.lift Args.name_source_position)
   632   (fn {context, ...} => fn (txt, pos) =>
   633    (ML_Context.eval_in (SOME context) false pos (ml pos txt);
   634     Symbol_Pos.content (Symbol_Pos.explode (txt, pos))
   635     |> (if Config.get context quotes then quote else I)
   636     |> (if Config.get context display then enclose "\\begin{verbatim}\n" "\n\\end{verbatim}"
   637         else verb_text)));
   638 
   639 fun ml_enclose bg en pos txt =
   640   ML_Lex.read Position.none bg @ ML_Lex.read pos txt @ ML_Lex.read Position.none en;
   641 
   642 in
   643 
   644 val _ = ml_text "ML" (ml_enclose "fn _ => (" ");");
   645 val _ = ml_text "ML_type" (ml_enclose "val _ = NONE : (" ") option;");
   646 val _ = ml_text "ML_struct" (ml_enclose "functor XXX() = struct structure XX = " " end;");
   647 
   648 val _ = ml_text "ML_functor"   (* FIXME formal treatment of functor name (!?) *)
   649   (fn pos => fn txt =>
   650     ML_Lex.read Position.none ("ML_Env.check_functor " ^
   651       ML_Syntax.print_string (Symbol_Pos.content (Symbol_Pos.explode (txt, pos)))));
   652 
   653 val _ = ml_text "ML_text" (K (K []));
   654 
   655 end;
   656 
   657 
   658 (* files *)
   659 
   660 val _ = antiquotation "file" (Scan.lift Args.name)
   661   (fn {context, ...} => fn path =>
   662     if File.exists (Path.explode path) then verb_text path
   663     else error ("Bad file: " ^ quote path));
   664 
   665 end;