src/HOL/Wellfounded.thy
author haftmann
Thu Oct 13 22:56:19 2011 +0200 (2011-10-13)
changeset 45137 6e422d180de8
parent 45012 060f76635bfe
child 45139 bdcaa3f3a2f4
permissions -rw-r--r--
modernized definitions
     1 (*  Title:      HOL/Wellfounded.thy
     2     Author:     Tobias Nipkow
     3     Author:     Lawrence C Paulson
     4     Author:     Konrad Slind
     5     Author:     Alexander Krauss
     6 *)
     7 
     8 header {*Well-founded Recursion*}
     9 
    10 theory Wellfounded
    11 imports Transitive_Closure
    12 uses ("Tools/Function/size.ML")
    13 begin
    14 
    15 subsection {* Basic Definitions *}
    16 
    17 definition wf :: "('a * 'a) set => bool" where
    18   "wf r \<longleftrightarrow> (!P. (!x. (!y. (y,x):r --> P(y)) --> P(x)) --> (!x. P(x)))"
    19 
    20 definition wfP :: "('a => 'a => bool) => bool" where
    21   "wfP r \<longleftrightarrow> wf {(x, y). r x y}"
    22 
    23 lemma wfP_wf_eq [pred_set_conv]: "wfP (\<lambda>x y. (x, y) \<in> r) = wf r"
    24   by (simp add: wfP_def)
    25 
    26 lemma wfUNIVI: 
    27    "(!!P x. (ALL x. (ALL y. (y,x) : r --> P(y)) --> P(x)) ==> P(x)) ==> wf(r)"
    28   unfolding wf_def by blast
    29 
    30 lemmas wfPUNIVI = wfUNIVI [to_pred]
    31 
    32 text{*Restriction to domain @{term A} and range @{term B}.  If @{term r} is
    33     well-founded over their intersection, then @{term "wf r"}*}
    34 lemma wfI: 
    35  "[| r \<subseteq> A <*> B; 
    36      !!x P. [|\<forall>x. (\<forall>y. (y,x) : r --> P y) --> P x;  x : A; x : B |] ==> P x |]
    37   ==>  wf r"
    38   unfolding wf_def by blast
    39 
    40 lemma wf_induct: 
    41     "[| wf(r);           
    42         !!x.[| ALL y. (y,x): r --> P(y) |] ==> P(x)  
    43      |]  ==>  P(a)"
    44   unfolding wf_def by blast
    45 
    46 lemmas wfP_induct = wf_induct [to_pred]
    47 
    48 lemmas wf_induct_rule = wf_induct [rule_format, consumes 1, case_names less, induct set: wf]
    49 
    50 lemmas wfP_induct_rule = wf_induct_rule [to_pred, induct set: wfP]
    51 
    52 lemma wf_not_sym: "wf r ==> (a, x) : r ==> (x, a) ~: r"
    53   by (induct a arbitrary: x set: wf) blast
    54 
    55 lemma wf_asym:
    56   assumes "wf r" "(a, x) \<in> r"
    57   obtains "(x, a) \<notin> r"
    58   by (drule wf_not_sym[OF assms])
    59 
    60 lemma wf_not_refl [simp]: "wf r ==> (a, a) ~: r"
    61   by (blast elim: wf_asym)
    62 
    63 lemma wf_irrefl: assumes "wf r" obtains "(a, a) \<notin> r"
    64 by (drule wf_not_refl[OF assms])
    65 
    66 lemma wf_wellorderI:
    67   assumes wf: "wf {(x::'a::ord, y). x < y}"
    68   assumes lin: "OFCLASS('a::ord, linorder_class)"
    69   shows "OFCLASS('a::ord, wellorder_class)"
    70 using lin by (rule wellorder_class.intro)
    71   (blast intro: class.wellorder_axioms.intro wf_induct_rule [OF wf])
    72 
    73 lemma (in wellorder) wf:
    74   "wf {(x, y). x < y}"
    75 unfolding wf_def by (blast intro: less_induct)
    76 
    77 
    78 subsection {* Basic Results *}
    79 
    80 text {* Point-free characterization of well-foundedness *}
    81 
    82 lemma wfE_pf:
    83   assumes wf: "wf R"
    84   assumes a: "A \<subseteq> R `` A"
    85   shows "A = {}"
    86 proof -
    87   { fix x
    88     from wf have "x \<notin> A"
    89     proof induct
    90       fix x assume "\<And>y. (y, x) \<in> R \<Longrightarrow> y \<notin> A"
    91       then have "x \<notin> R `` A" by blast
    92       with a show "x \<notin> A" by blast
    93     qed
    94   } thus ?thesis by auto
    95 qed
    96 
    97 lemma wfI_pf:
    98   assumes a: "\<And>A. A \<subseteq> R `` A \<Longrightarrow> A = {}"
    99   shows "wf R"
   100 proof (rule wfUNIVI)
   101   fix P :: "'a \<Rightarrow> bool" and x
   102   let ?A = "{x. \<not> P x}"
   103   assume "\<forall>x. (\<forall>y. (y, x) \<in> R \<longrightarrow> P y) \<longrightarrow> P x"
   104   then have "?A \<subseteq> R `` ?A" by blast
   105   with a show "P x" by blast
   106 qed
   107 
   108 text{*Minimal-element characterization of well-foundedness*}
   109 
   110 lemma wfE_min:
   111   assumes wf: "wf R" and Q: "x \<in> Q"
   112   obtains z where "z \<in> Q" "\<And>y. (y, z) \<in> R \<Longrightarrow> y \<notin> Q"
   113   using Q wfE_pf[OF wf, of Q] by blast
   114 
   115 lemma wfI_min:
   116   assumes a: "\<And>x Q. x \<in> Q \<Longrightarrow> \<exists>z\<in>Q. \<forall>y. (y, z) \<in> R \<longrightarrow> y \<notin> Q"
   117   shows "wf R"
   118 proof (rule wfI_pf)
   119   fix A assume b: "A \<subseteq> R `` A"
   120   { fix x assume "x \<in> A"
   121     from a[OF this] b have "False" by blast
   122   }
   123   thus "A = {}" by blast
   124 qed
   125 
   126 lemma wf_eq_minimal: "wf r = (\<forall>Q x. x\<in>Q --> (\<exists>z\<in>Q. \<forall>y. (y,z)\<in>r --> y\<notin>Q))"
   127 apply auto
   128 apply (erule wfE_min, assumption, blast)
   129 apply (rule wfI_min, auto)
   130 done
   131 
   132 lemmas wfP_eq_minimal = wf_eq_minimal [to_pred]
   133 
   134 text{* Well-foundedness of transitive closure *}
   135 
   136 lemma wf_trancl:
   137   assumes "wf r"
   138   shows "wf (r^+)"
   139 proof -
   140   {
   141     fix P and x
   142     assume induct_step: "!!x. (!!y. (y, x) : r^+ ==> P y) ==> P x"
   143     have "P x"
   144     proof (rule induct_step)
   145       fix y assume "(y, x) : r^+"
   146       with `wf r` show "P y"
   147       proof (induct x arbitrary: y)
   148         case (less x)
   149         note hyp = `\<And>x' y'. (x', x) : r ==> (y', x') : r^+ ==> P y'`
   150         from `(y, x) : r^+` show "P y"
   151         proof cases
   152           case base
   153           show "P y"
   154           proof (rule induct_step)
   155             fix y' assume "(y', y) : r^+"
   156             with `(y, x) : r` show "P y'" by (rule hyp [of y y'])
   157           qed
   158         next
   159           case step
   160           then obtain x' where "(x', x) : r" and "(y, x') : r^+" by simp
   161           then show "P y" by (rule hyp [of x' y])
   162         qed
   163       qed
   164     qed
   165   } then show ?thesis unfolding wf_def by blast
   166 qed
   167 
   168 lemmas wfP_trancl = wf_trancl [to_pred]
   169 
   170 lemma wf_converse_trancl: "wf (r^-1) ==> wf ((r^+)^-1)"
   171   apply (subst trancl_converse [symmetric])
   172   apply (erule wf_trancl)
   173   done
   174 
   175 text {* Well-foundedness of subsets *}
   176 
   177 lemma wf_subset: "[| wf(r);  p<=r |] ==> wf(p)"
   178   apply (simp (no_asm_use) add: wf_eq_minimal)
   179   apply fast
   180   done
   181 
   182 lemmas wfP_subset = wf_subset [to_pred]
   183 
   184 text {* Well-foundedness of the empty relation *}
   185 
   186 lemma wf_empty [iff]: "wf {}"
   187   by (simp add: wf_def)
   188 
   189 lemma wfP_empty [iff]:
   190   "wfP (\<lambda>x y. False)"
   191 proof -
   192   have "wfP bot" by (fact wf_empty [to_pred bot_empty_eq2])
   193   then show ?thesis by (simp add: bot_fun_def)
   194 qed
   195 
   196 lemma wf_Int1: "wf r ==> wf (r Int r')"
   197   apply (erule wf_subset)
   198   apply (rule Int_lower1)
   199   done
   200 
   201 lemma wf_Int2: "wf r ==> wf (r' Int r)"
   202   apply (erule wf_subset)
   203   apply (rule Int_lower2)
   204   done  
   205 
   206 text {* Exponentiation *}
   207 
   208 lemma wf_exp:
   209   assumes "wf (R ^^ n)"
   210   shows "wf R"
   211 proof (rule wfI_pf)
   212   fix A assume "A \<subseteq> R `` A"
   213   then have "A \<subseteq> (R ^^ n) `` A" by (induct n) force+
   214   with `wf (R ^^ n)`
   215   show "A = {}" by (rule wfE_pf)
   216 qed
   217 
   218 text {* Well-foundedness of insert *}
   219 
   220 lemma wf_insert [iff]: "wf(insert (y,x) r) = (wf(r) & (x,y) ~: r^*)"
   221 apply (rule iffI)
   222  apply (blast elim: wf_trancl [THEN wf_irrefl]
   223               intro: rtrancl_into_trancl1 wf_subset 
   224                      rtrancl_mono [THEN [2] rev_subsetD])
   225 apply (simp add: wf_eq_minimal, safe)
   226 apply (rule allE, assumption, erule impE, blast) 
   227 apply (erule bexE)
   228 apply (rename_tac "a", case_tac "a = x")
   229  prefer 2
   230 apply blast 
   231 apply (case_tac "y:Q")
   232  prefer 2 apply blast
   233 apply (rule_tac x = "{z. z:Q & (z,y) : r^*}" in allE)
   234  apply assumption
   235 apply (erule_tac V = "ALL Q. (EX x. x : Q) --> ?P Q" in thin_rl) 
   236   --{*essential for speed*}
   237 txt{*Blast with new substOccur fails*}
   238 apply (fast intro: converse_rtrancl_into_rtrancl)
   239 done
   240 
   241 text{*Well-foundedness of image*}
   242 
   243 lemma wf_map_pair_image: "[| wf r; inj f |] ==> wf(map_pair f f ` r)"
   244 apply (simp only: wf_eq_minimal, clarify)
   245 apply (case_tac "EX p. f p : Q")
   246 apply (erule_tac x = "{p. f p : Q}" in allE)
   247 apply (fast dest: inj_onD, blast)
   248 done
   249 
   250 
   251 subsection {* Well-Foundedness Results for Unions *}
   252 
   253 lemma wf_union_compatible:
   254   assumes "wf R" "wf S"
   255   assumes "R O S \<subseteq> R"
   256   shows "wf (R \<union> S)"
   257 proof (rule wfI_min)
   258   fix x :: 'a and Q 
   259   let ?Q' = "{x \<in> Q. \<forall>y. (y, x) \<in> R \<longrightarrow> y \<notin> Q}"
   260   assume "x \<in> Q"
   261   obtain a where "a \<in> ?Q'"
   262     by (rule wfE_min [OF `wf R` `x \<in> Q`]) blast
   263   with `wf S`
   264   obtain z where "z \<in> ?Q'" and zmin: "\<And>y. (y, z) \<in> S \<Longrightarrow> y \<notin> ?Q'" by (erule wfE_min)
   265   { 
   266     fix y assume "(y, z) \<in> S"
   267     then have "y \<notin> ?Q'" by (rule zmin)
   268 
   269     have "y \<notin> Q"
   270     proof 
   271       assume "y \<in> Q"
   272       with `y \<notin> ?Q'` 
   273       obtain w where "(w, y) \<in> R" and "w \<in> Q" by auto
   274       from `(w, y) \<in> R` `(y, z) \<in> S` have "(w, z) \<in> R O S" by (rule rel_compI)
   275       with `R O S \<subseteq> R` have "(w, z) \<in> R" ..
   276       with `z \<in> ?Q'` have "w \<notin> Q" by blast 
   277       with `w \<in> Q` show False by contradiction
   278     qed
   279   }
   280   with `z \<in> ?Q'` show "\<exists>z\<in>Q. \<forall>y. (y, z) \<in> R \<union> S \<longrightarrow> y \<notin> Q" by blast
   281 qed
   282 
   283 
   284 text {* Well-foundedness of indexed union with disjoint domains and ranges *}
   285 
   286 lemma wf_UN: "[| ALL i:I. wf(r i);  
   287          ALL i:I. ALL j:I. r i ~= r j --> Domain(r i) Int Range(r j) = {}  
   288       |] ==> wf(UN i:I. r i)"
   289 apply (simp only: wf_eq_minimal, clarify)
   290 apply (rename_tac A a, case_tac "EX i:I. EX a:A. EX b:A. (b,a) : r i")
   291  prefer 2
   292  apply force 
   293 apply clarify
   294 apply (drule bspec, assumption)  
   295 apply (erule_tac x="{a. a:A & (EX b:A. (b,a) : r i) }" in allE)
   296 apply (blast elim!: allE)  
   297 done
   298 
   299 lemma wfP_SUP:
   300   "\<forall>i. wfP (r i) \<Longrightarrow> \<forall>i j. r i \<noteq> r j \<longrightarrow> inf (DomainP (r i)) (RangeP (r j)) = bot \<Longrightarrow> wfP (SUPR UNIV r)"
   301   by (rule wf_UN [where I=UNIV and r="\<lambda>i. {(x, y). r i x y}", to_pred SUP_UN_eq2])
   302     (simp_all add: Collect_def)
   303 
   304 lemma wf_Union: 
   305  "[| ALL r:R. wf r;  
   306      ALL r:R. ALL s:R. r ~= s --> Domain r Int Range s = {}  
   307   |] ==> wf(Union R)"
   308   using wf_UN[of R "\<lambda>i. i"] by (simp add: SUP_def)
   309 
   310 (*Intuition: we find an (R u S)-min element of a nonempty subset A
   311              by case distinction.
   312   1. There is a step a -R-> b with a,b : A.
   313      Pick an R-min element z of the (nonempty) set {a:A | EX b:A. a -R-> b}.
   314      By definition, there is z':A s.t. z -R-> z'. Because z is R-min in the
   315      subset, z' must be R-min in A. Because z' has an R-predecessor, it cannot
   316      have an S-successor and is thus S-min in A as well.
   317   2. There is no such step.
   318      Pick an S-min element of A. In this case it must be an R-min
   319      element of A as well.
   320 
   321 *)
   322 lemma wf_Un:
   323      "[| wf r; wf s; Domain r Int Range s = {} |] ==> wf(r Un s)"
   324   using wf_union_compatible[of s r] 
   325   by (auto simp: Un_ac)
   326 
   327 lemma wf_union_merge: 
   328   "wf (R \<union> S) = wf (R O R \<union> S O R \<union> S)" (is "wf ?A = wf ?B")
   329 proof
   330   assume "wf ?A"
   331   with wf_trancl have wfT: "wf (?A^+)" .
   332   moreover have "?B \<subseteq> ?A^+"
   333     by (subst trancl_unfold, subst trancl_unfold) blast
   334   ultimately show "wf ?B" by (rule wf_subset)
   335 next
   336   assume "wf ?B"
   337 
   338   show "wf ?A"
   339   proof (rule wfI_min)
   340     fix Q :: "'a set" and x 
   341     assume "x \<in> Q"
   342 
   343     with `wf ?B`
   344     obtain z where "z \<in> Q" and "\<And>y. (y, z) \<in> ?B \<Longrightarrow> y \<notin> Q" 
   345       by (erule wfE_min)
   346     then have A1: "\<And>y. (y, z) \<in> R O R \<Longrightarrow> y \<notin> Q"
   347       and A2: "\<And>y. (y, z) \<in> S O R \<Longrightarrow> y \<notin> Q"
   348       and A3: "\<And>y. (y, z) \<in> S \<Longrightarrow> y \<notin> Q"
   349       by auto
   350     
   351     show "\<exists>z\<in>Q. \<forall>y. (y, z) \<in> ?A \<longrightarrow> y \<notin> Q"
   352     proof (cases "\<forall>y. (y, z) \<in> R \<longrightarrow> y \<notin> Q")
   353       case True
   354       with `z \<in> Q` A3 show ?thesis by blast
   355     next
   356       case False 
   357       then obtain z' where "z'\<in>Q" "(z', z) \<in> R" by blast
   358 
   359       have "\<forall>y. (y, z') \<in> ?A \<longrightarrow> y \<notin> Q"
   360       proof (intro allI impI)
   361         fix y assume "(y, z') \<in> ?A"
   362         then show "y \<notin> Q"
   363         proof
   364           assume "(y, z') \<in> R" 
   365           then have "(y, z) \<in> R O R" using `(z', z) \<in> R` ..
   366           with A1 show "y \<notin> Q" .
   367         next
   368           assume "(y, z') \<in> S" 
   369           then have "(y, z) \<in> S O R" using  `(z', z) \<in> R` ..
   370           with A2 show "y \<notin> Q" .
   371         qed
   372       qed
   373       with `z' \<in> Q` show ?thesis ..
   374     qed
   375   qed
   376 qed
   377 
   378 lemma wf_comp_self: "wf R = wf (R O R)"  -- {* special case *}
   379   by (rule wf_union_merge [where S = "{}", simplified])
   380 
   381 
   382 subsection {* Acyclic relations *}
   383 
   384 definition acyclic :: "('a * 'a) set => bool" where
   385   "acyclic r \<longleftrightarrow> (!x. (x,x) ~: r^+)"
   386 
   387 abbreviation acyclicP :: "('a => 'a => bool) => bool" where
   388   "acyclicP r \<equiv> acyclic {(x, y). r x y}"
   389 
   390 lemma acyclic_irrefl:
   391   "acyclic r \<longleftrightarrow> irrefl (r^+)"
   392   by (simp add: acyclic_def irrefl_def)
   393 
   394 lemma acyclicI: "ALL x. (x, x) ~: r^+ ==> acyclic r"
   395   by (simp add: acyclic_def)
   396 
   397 lemma wf_acyclic: "wf r ==> acyclic r"
   398 apply (simp add: acyclic_def)
   399 apply (blast elim: wf_trancl [THEN wf_irrefl])
   400 done
   401 
   402 lemmas wfP_acyclicP = wf_acyclic [to_pred]
   403 
   404 lemma acyclic_insert [iff]:
   405      "acyclic(insert (y,x) r) = (acyclic r & (x,y) ~: r^*)"
   406 apply (simp add: acyclic_def trancl_insert)
   407 apply (blast intro: rtrancl_trans)
   408 done
   409 
   410 lemma acyclic_converse [iff]: "acyclic(r^-1) = acyclic r"
   411 by (simp add: acyclic_def trancl_converse)
   412 
   413 lemmas acyclicP_converse [iff] = acyclic_converse [to_pred]
   414 
   415 lemma acyclic_impl_antisym_rtrancl: "acyclic r ==> antisym(r^*)"
   416 apply (simp add: acyclic_def antisym_def)
   417 apply (blast elim: rtranclE intro: rtrancl_into_trancl1 rtrancl_trancl_trancl)
   418 done
   419 
   420 (* Other direction:
   421 acyclic = no loops
   422 antisym = only self loops
   423 Goalw [acyclic_def,antisym_def] "antisym( r^* ) ==> acyclic(r - Id)
   424 ==> antisym( r^* ) = acyclic(r - Id)";
   425 *)
   426 
   427 lemma acyclic_subset: "[| acyclic s; r <= s |] ==> acyclic r"
   428 apply (simp add: acyclic_def)
   429 apply (blast intro: trancl_mono)
   430 done
   431 
   432 text{* Wellfoundedness of finite acyclic relations*}
   433 
   434 lemma finite_acyclic_wf [rule_format]: "finite r ==> acyclic r --> wf r"
   435 apply (erule finite_induct, blast)
   436 apply (simp (no_asm_simp) only: split_tupled_all)
   437 apply simp
   438 done
   439 
   440 lemma finite_acyclic_wf_converse: "[|finite r; acyclic r|] ==> wf (r^-1)"
   441 apply (erule finite_converse [THEN iffD2, THEN finite_acyclic_wf])
   442 apply (erule acyclic_converse [THEN iffD2])
   443 done
   444 
   445 lemma wf_iff_acyclic_if_finite: "finite r ==> wf r = acyclic r"
   446 by (blast intro: finite_acyclic_wf wf_acyclic)
   447 
   448 
   449 subsection {* @{typ nat} is well-founded *}
   450 
   451 lemma less_nat_rel: "op < = (\<lambda>m n. n = Suc m)^++"
   452 proof (rule ext, rule ext, rule iffI)
   453   fix n m :: nat
   454   assume "m < n"
   455   then show "(\<lambda>m n. n = Suc m)^++ m n"
   456   proof (induct n)
   457     case 0 then show ?case by auto
   458   next
   459     case (Suc n) then show ?case
   460       by (auto simp add: less_Suc_eq_le le_less intro: tranclp.trancl_into_trancl)
   461   qed
   462 next
   463   fix n m :: nat
   464   assume "(\<lambda>m n. n = Suc m)^++ m n"
   465   then show "m < n"
   466     by (induct n)
   467       (simp_all add: less_Suc_eq_le reflexive le_less)
   468 qed
   469 
   470 definition
   471   pred_nat :: "(nat * nat) set" where
   472   "pred_nat = {(m, n). n = Suc m}"
   473 
   474 definition
   475   less_than :: "(nat * nat) set" where
   476   "less_than = pred_nat^+"
   477 
   478 lemma less_eq: "(m, n) \<in> pred_nat^+ \<longleftrightarrow> m < n"
   479   unfolding less_nat_rel pred_nat_def trancl_def by simp
   480 
   481 lemma pred_nat_trancl_eq_le:
   482   "(m, n) \<in> pred_nat^* \<longleftrightarrow> m \<le> n"
   483   unfolding less_eq rtrancl_eq_or_trancl by auto
   484 
   485 lemma wf_pred_nat: "wf pred_nat"
   486   apply (unfold wf_def pred_nat_def, clarify)
   487   apply (induct_tac x, blast+)
   488   done
   489 
   490 lemma wf_less_than [iff]: "wf less_than"
   491   by (simp add: less_than_def wf_pred_nat [THEN wf_trancl])
   492 
   493 lemma trans_less_than [iff]: "trans less_than"
   494   by (simp add: less_than_def)
   495 
   496 lemma less_than_iff [iff]: "((x,y): less_than) = (x<y)"
   497   by (simp add: less_than_def less_eq)
   498 
   499 lemma wf_less: "wf {(x, y::nat). x < y}"
   500   using wf_less_than by (simp add: less_than_def less_eq [symmetric])
   501 
   502 
   503 subsection {* Accessible Part *}
   504 
   505 text {*
   506  Inductive definition of the accessible part @{term "acc r"} of a
   507  relation; see also \cite{paulin-tlca}.
   508 *}
   509 
   510 inductive_set
   511   acc :: "('a * 'a) set => 'a set"
   512   for r :: "('a * 'a) set"
   513   where
   514     accI: "(!!y. (y, x) : r ==> y : acc r) ==> x : acc r"
   515 
   516 abbreviation
   517   termip :: "('a => 'a => bool) => 'a => bool" where
   518   "termip r \<equiv> accp (r\<inverse>\<inverse>)"
   519 
   520 abbreviation
   521   termi :: "('a * 'a) set => 'a set" where
   522   "termi r \<equiv> acc (r\<inverse>)"
   523 
   524 lemmas accpI = accp.accI
   525 
   526 text {* Induction rules *}
   527 
   528 theorem accp_induct:
   529   assumes major: "accp r a"
   530   assumes hyp: "!!x. accp r x ==> \<forall>y. r y x --> P y ==> P x"
   531   shows "P a"
   532   apply (rule major [THEN accp.induct])
   533   apply (rule hyp)
   534    apply (rule accp.accI)
   535    apply fast
   536   apply fast
   537   done
   538 
   539 theorems accp_induct_rule = accp_induct [rule_format, induct set: accp]
   540 
   541 theorem accp_downward: "accp r b ==> r a b ==> accp r a"
   542   apply (erule accp.cases)
   543   apply fast
   544   done
   545 
   546 lemma not_accp_down:
   547   assumes na: "\<not> accp R x"
   548   obtains z where "R z x" and "\<not> accp R z"
   549 proof -
   550   assume a: "\<And>z. \<lbrakk>R z x; \<not> accp R z\<rbrakk> \<Longrightarrow> thesis"
   551 
   552   show thesis
   553   proof (cases "\<forall>z. R z x \<longrightarrow> accp R z")
   554     case True
   555     hence "\<And>z. R z x \<Longrightarrow> accp R z" by auto
   556     hence "accp R x"
   557       by (rule accp.accI)
   558     with na show thesis ..
   559   next
   560     case False then obtain z where "R z x" and "\<not> accp R z"
   561       by auto
   562     with a show thesis .
   563   qed
   564 qed
   565 
   566 lemma accp_downwards_aux: "r\<^sup>*\<^sup>* b a ==> accp r a --> accp r b"
   567   apply (erule rtranclp_induct)
   568    apply blast
   569   apply (blast dest: accp_downward)
   570   done
   571 
   572 theorem accp_downwards: "accp r a ==> r\<^sup>*\<^sup>* b a ==> accp r b"
   573   apply (blast dest: accp_downwards_aux)
   574   done
   575 
   576 theorem accp_wfPI: "\<forall>x. accp r x ==> wfP r"
   577   apply (rule wfPUNIVI)
   578   apply (rule_tac P=P in accp_induct)
   579    apply blast
   580   apply blast
   581   done
   582 
   583 theorem accp_wfPD: "wfP r ==> accp r x"
   584   apply (erule wfP_induct_rule)
   585   apply (rule accp.accI)
   586   apply blast
   587   done
   588 
   589 theorem wfP_accp_iff: "wfP r = (\<forall>x. accp r x)"
   590   apply (blast intro: accp_wfPI dest: accp_wfPD)
   591   done
   592 
   593 
   594 text {* Smaller relations have bigger accessible parts: *}
   595 
   596 lemma accp_subset:
   597   assumes sub: "R1 \<le> R2"
   598   shows "accp R2 \<le> accp R1"
   599 proof (rule predicate1I)
   600   fix x assume "accp R2 x"
   601   then show "accp R1 x"
   602   proof (induct x)
   603     fix x
   604     assume ih: "\<And>y. R2 y x \<Longrightarrow> accp R1 y"
   605     with sub show "accp R1 x"
   606       by (blast intro: accp.accI)
   607   qed
   608 qed
   609 
   610 
   611 text {* This is a generalized induction theorem that works on
   612   subsets of the accessible part. *}
   613 
   614 lemma accp_subset_induct:
   615   assumes subset: "D \<le> accp R"
   616     and dcl: "\<And>x z. \<lbrakk>D x; R z x\<rbrakk> \<Longrightarrow> D z"
   617     and "D x"
   618     and istep: "\<And>x. \<lbrakk>D x; (\<And>z. R z x \<Longrightarrow> P z)\<rbrakk> \<Longrightarrow> P x"
   619   shows "P x"
   620 proof -
   621   from subset and `D x`
   622   have "accp R x" ..
   623   then show "P x" using `D x`
   624   proof (induct x)
   625     fix x
   626     assume "D x"
   627       and "\<And>y. R y x \<Longrightarrow> D y \<Longrightarrow> P y"
   628     with dcl and istep show "P x" by blast
   629   qed
   630 qed
   631 
   632 
   633 text {* Set versions of the above theorems *}
   634 
   635 lemmas acc_induct = accp_induct [to_set]
   636 
   637 lemmas acc_induct_rule = acc_induct [rule_format, induct set: acc]
   638 
   639 lemmas acc_downward = accp_downward [to_set]
   640 
   641 lemmas not_acc_down = not_accp_down [to_set]
   642 
   643 lemmas acc_downwards_aux = accp_downwards_aux [to_set]
   644 
   645 lemmas acc_downwards = accp_downwards [to_set]
   646 
   647 lemmas acc_wfI = accp_wfPI [to_set]
   648 
   649 lemmas acc_wfD = accp_wfPD [to_set]
   650 
   651 lemmas wf_acc_iff = wfP_accp_iff [to_set]
   652 
   653 lemmas acc_subset = accp_subset [to_set pred_subset_eq]
   654 
   655 lemmas acc_subset_induct = accp_subset_induct [to_set pred_subset_eq]
   656 
   657 
   658 subsection {* Tools for building wellfounded relations *}
   659 
   660 text {* Inverse Image *}
   661 
   662 lemma wf_inv_image [simp,intro!]: "wf(r) ==> wf(inv_image r (f::'a=>'b))"
   663 apply (simp (no_asm_use) add: inv_image_def wf_eq_minimal)
   664 apply clarify
   665 apply (subgoal_tac "EX (w::'b) . w : {w. EX (x::'a) . x: Q & (f x = w) }")
   666 prefer 2 apply (blast del: allE)
   667 apply (erule allE)
   668 apply (erule (1) notE impE)
   669 apply blast
   670 done
   671 
   672 text {* Measure functions into @{typ nat} *}
   673 
   674 definition measure :: "('a => nat) => ('a * 'a)set"
   675 where "measure = inv_image less_than"
   676 
   677 lemma in_measure[simp]: "((x,y) : measure f) = (f x < f y)"
   678   by (simp add:measure_def)
   679 
   680 lemma wf_measure [iff]: "wf (measure f)"
   681 apply (unfold measure_def)
   682 apply (rule wf_less_than [THEN wf_inv_image])
   683 done
   684 
   685 lemma wf_if_measure: fixes f :: "'a \<Rightarrow> nat"
   686 shows "(!!x. P x \<Longrightarrow> f(g x) < f x) \<Longrightarrow> wf {(y,x). P x \<and> y = g x}"
   687 apply(insert wf_measure[of f])
   688 apply(simp only: measure_def inv_image_def less_than_def less_eq)
   689 apply(erule wf_subset)
   690 apply auto
   691 done
   692 
   693 
   694 text{* Lexicographic combinations *}
   695 
   696 definition lex_prod :: "('a \<times>'a) set \<Rightarrow> ('b \<times> 'b) set \<Rightarrow> (('a \<times> 'b) \<times> ('a \<times> 'b)) set" (infixr "<*lex*>" 80) where
   697   "ra <*lex*> rb = {((a, b), (a', b')). (a, a') \<in> ra \<or> a = a' \<and> (b, b') \<in> rb}"
   698 
   699 lemma wf_lex_prod [intro!]: "[| wf(ra); wf(rb) |] ==> wf(ra <*lex*> rb)"
   700 apply (unfold wf_def lex_prod_def) 
   701 apply (rule allI, rule impI)
   702 apply (simp (no_asm_use) only: split_paired_All)
   703 apply (drule spec, erule mp) 
   704 apply (rule allI, rule impI)
   705 apply (drule spec, erule mp, blast) 
   706 done
   707 
   708 lemma in_lex_prod[simp]: 
   709   "(((a,b),(a',b')): r <*lex*> s) = ((a,a'): r \<or> (a = a' \<and> (b, b') : s))"
   710   by (auto simp:lex_prod_def)
   711 
   712 text{* @{term "op <*lex*>"} preserves transitivity *}
   713 
   714 lemma trans_lex_prod [intro!]: 
   715     "[| trans R1; trans R2 |] ==> trans (R1 <*lex*> R2)"
   716 by (unfold trans_def lex_prod_def, blast) 
   717 
   718 text {* lexicographic combinations with measure functions *}
   719 
   720 definition 
   721   mlex_prod :: "('a \<Rightarrow> nat) \<Rightarrow> ('a \<times> 'a) set \<Rightarrow> ('a \<times> 'a) set" (infixr "<*mlex*>" 80)
   722 where
   723   "f <*mlex*> R = inv_image (less_than <*lex*> R) (%x. (f x, x))"
   724 
   725 lemma wf_mlex: "wf R \<Longrightarrow> wf (f <*mlex*> R)"
   726 unfolding mlex_prod_def
   727 by auto
   728 
   729 lemma mlex_less: "f x < f y \<Longrightarrow> (x, y) \<in> f <*mlex*> R"
   730 unfolding mlex_prod_def by simp
   731 
   732 lemma mlex_leq: "f x \<le> f y \<Longrightarrow> (x, y) \<in> R \<Longrightarrow> (x, y) \<in> f <*mlex*> R"
   733 unfolding mlex_prod_def by auto
   734 
   735 text {* proper subset relation on finite sets *}
   736 
   737 definition finite_psubset  :: "('a set * 'a set) set"
   738 where "finite_psubset = {(A,B). A < B & finite B}"
   739 
   740 lemma wf_finite_psubset[simp]: "wf(finite_psubset)"
   741 apply (unfold finite_psubset_def)
   742 apply (rule wf_measure [THEN wf_subset])
   743 apply (simp add: measure_def inv_image_def less_than_def less_eq)
   744 apply (fast elim!: psubset_card_mono)
   745 done
   746 
   747 lemma trans_finite_psubset: "trans finite_psubset"
   748 by (simp add: finite_psubset_def less_le trans_def, blast)
   749 
   750 lemma in_finite_psubset[simp]: "(A, B) \<in> finite_psubset = (A < B & finite B)"
   751 unfolding finite_psubset_def by auto
   752 
   753 text {* max- and min-extension of order to finite sets *}
   754 
   755 inductive_set max_ext :: "('a \<times> 'a) set \<Rightarrow> ('a set \<times> 'a set) set" 
   756 for R :: "('a \<times> 'a) set"
   757 where
   758   max_extI[intro]: "finite X \<Longrightarrow> finite Y \<Longrightarrow> Y \<noteq> {} \<Longrightarrow> (\<And>x. x \<in> X \<Longrightarrow> \<exists>y\<in>Y. (x, y) \<in> R) \<Longrightarrow> (X, Y) \<in> max_ext R"
   759 
   760 lemma max_ext_wf:
   761   assumes wf: "wf r"
   762   shows "wf (max_ext r)"
   763 proof (rule acc_wfI, intro allI)
   764   fix M show "M \<in> acc (max_ext r)" (is "_ \<in> ?W")
   765   proof cases
   766     assume "finite M"
   767     thus ?thesis
   768     proof (induct M)
   769       show "{} \<in> ?W"
   770         by (rule accI) (auto elim: max_ext.cases)
   771     next
   772       fix M a assume "M \<in> ?W" "finite M"
   773       with wf show "insert a M \<in> ?W"
   774       proof (induct arbitrary: M)
   775         fix M a
   776         assume "M \<in> ?W"  and  [intro]: "finite M"
   777         assume hyp: "\<And>b M. (b, a) \<in> r \<Longrightarrow> M \<in> ?W \<Longrightarrow> finite M \<Longrightarrow> insert b M \<in> ?W"
   778         {
   779           fix N M :: "'a set"
   780           assume "finite N" "finite M"
   781           then
   782           have "\<lbrakk>M \<in> ?W ; (\<And>y. y \<in> N \<Longrightarrow> (y, a) \<in> r)\<rbrakk> \<Longrightarrow>  N \<union> M \<in> ?W"
   783             by (induct N arbitrary: M) (auto simp: hyp)
   784         }
   785         note add_less = this
   786         
   787         show "insert a M \<in> ?W"
   788         proof (rule accI)
   789           fix N assume Nless: "(N, insert a M) \<in> max_ext r"
   790           hence asm1: "\<And>x. x \<in> N \<Longrightarrow> (x, a) \<in> r \<or> (\<exists>y \<in> M. (x, y) \<in> r)"
   791             by (auto elim!: max_ext.cases)
   792 
   793           let ?N1 = "{ n \<in> N. (n, a) \<in> r }"
   794           let ?N2 = "{ n \<in> N. (n, a) \<notin> r }"
   795           have N: "?N1 \<union> ?N2 = N" by (rule set_eqI) auto
   796           from Nless have "finite N" by (auto elim: max_ext.cases)
   797           then have finites: "finite ?N1" "finite ?N2" by auto
   798           
   799           have "?N2 \<in> ?W"
   800           proof cases
   801             assume [simp]: "M = {}"
   802             have Mw: "{} \<in> ?W" by (rule accI) (auto elim: max_ext.cases)
   803 
   804             from asm1 have "?N2 = {}" by auto
   805             with Mw show "?N2 \<in> ?W" by (simp only:)
   806           next
   807             assume "M \<noteq> {}"
   808             have N2: "(?N2, M) \<in> max_ext r" 
   809               by (rule max_extI[OF _ _ `M \<noteq> {}`]) (insert asm1, auto intro: finites)
   810             
   811             with `M \<in> ?W` show "?N2 \<in> ?W" by (rule acc_downward)
   812           qed
   813           with finites have "?N1 \<union> ?N2 \<in> ?W" 
   814             by (rule add_less) simp
   815           then show "N \<in> ?W" by (simp only: N)
   816         qed
   817       qed
   818     qed
   819   next
   820     assume [simp]: "\<not> finite M"
   821     show ?thesis
   822       by (rule accI) (auto elim: max_ext.cases)
   823   qed
   824 qed
   825 
   826 lemma max_ext_additive: 
   827  "(A, B) \<in> max_ext R \<Longrightarrow> (C, D) \<in> max_ext R \<Longrightarrow>
   828   (A \<union> C, B \<union> D) \<in> max_ext R"
   829 by (force elim!: max_ext.cases)
   830 
   831 
   832 definition min_ext :: "('a \<times> 'a) set \<Rightarrow> ('a set \<times> 'a set) set"  where
   833   "min_ext r = {(X, Y) | X Y. X \<noteq> {} \<and> (\<forall>y \<in> Y. (\<exists>x \<in> X. (x, y) \<in> r))}"
   834 
   835 lemma min_ext_wf:
   836   assumes "wf r"
   837   shows "wf (min_ext r)"
   838 proof (rule wfI_min)
   839   fix Q :: "'a set set"
   840   fix x
   841   assume nonempty: "x \<in> Q"
   842   show "\<exists>m \<in> Q. (\<forall> n. (n, m) \<in> min_ext r \<longrightarrow> n \<notin> Q)"
   843   proof cases
   844     assume "Q = {{}}" thus ?thesis by (simp add: min_ext_def)
   845   next
   846     assume "Q \<noteq> {{}}"
   847     with nonempty
   848     obtain e x where "x \<in> Q" "e \<in> x" by force
   849     then have eU: "e \<in> \<Union>Q" by auto
   850     with `wf r` 
   851     obtain z where z: "z \<in> \<Union>Q" "\<And>y. (y, z) \<in> r \<Longrightarrow> y \<notin> \<Union>Q" 
   852       by (erule wfE_min)
   853     from z obtain m where "m \<in> Q" "z \<in> m" by auto
   854     from `m \<in> Q`
   855     show ?thesis
   856     proof (rule, intro bexI allI impI)
   857       fix n
   858       assume smaller: "(n, m) \<in> min_ext r"
   859       with `z \<in> m` obtain y where y: "y \<in> n" "(y, z) \<in> r" by (auto simp: min_ext_def)
   860       then show "n \<notin> Q" using z(2) by auto
   861     qed      
   862   qed
   863 qed
   864 
   865 text{* Bounded increase must terminate: *}
   866 
   867 lemma wf_bounded_measure:
   868 fixes ub :: "'a \<Rightarrow> nat" and f :: "'a \<Rightarrow> nat"
   869 assumes "!!a b. (b,a) : r \<Longrightarrow> ub b \<le> ub a & ub a \<ge> f b & f b > f a"
   870 shows "wf r"
   871 apply(rule wf_subset[OF wf_measure[of "%a. ub a - f a"]])
   872 apply (auto dest: assms)
   873 done
   874 
   875 lemma wf_bounded_set:
   876 fixes ub :: "'a \<Rightarrow> 'b set" and f :: "'a \<Rightarrow> 'b set"
   877 assumes "!!a b. (b,a) : r \<Longrightarrow>
   878   finite(ub a) & ub b \<subseteq> ub a & ub a \<supseteq> f b & f b \<supset> f a"
   879 shows "wf r"
   880 apply(rule wf_bounded_measure[of r "%a. card(ub a)" "%a. card(f a)"])
   881 apply(drule assms)
   882 apply (blast intro: card_mono finite_subset psubset_card_mono dest: psubset_eq[THEN iffD2])
   883 done
   884 
   885 
   886 subsection {* size of a datatype value *}
   887 
   888 use "Tools/Function/size.ML"
   889 
   890 setup Size.setup
   891 
   892 lemma size_bool [code]:
   893   "size (b\<Colon>bool) = 0" by (cases b) auto
   894 
   895 lemma nat_size [simp, code]: "size (n\<Colon>nat) = n"
   896   by (induct n) simp_all
   897 
   898 declare "prod.size" [no_atp]
   899 
   900 lemma [code]:
   901   "size (P :: 'a Predicate.pred) = 0" by (cases P) simp
   902 
   903 lemma [code]:
   904   "pred_size f P = 0" by (cases P) simp
   905 
   906 end