src/HOL/Product_Type.thy
author berghofe
Thu Jan 10 19:09:21 2008 +0100 (2008-01-10)
changeset 25885 6fbc3f54f819
parent 25534 d0b74fdd6067
child 26143 314c0bcb7df7
permissions -rw-r--r--
New interface for test data generators.
     1 (*  Title:      HOL/Product_Type.thy
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     4     Copyright   1992  University of Cambridge
     5 *)
     6 
     7 header {* Cartesian products *}
     8 
     9 theory Product_Type
    10 imports Inductive
    11 uses
    12   ("Tools/split_rule.ML")
    13   ("Tools/inductive_set_package.ML")
    14   ("Tools/inductive_realizer.ML")
    15   ("Tools/datatype_realizer.ML")
    16 begin
    17 
    18 subsection {* @{typ bool} is a datatype *}
    19 
    20 rep_datatype bool
    21   distinct True_not_False False_not_True
    22   induction bool_induct
    23 
    24 declare case_split [cases type: bool]
    25   -- "prefer plain propositional version"
    26 
    27 lemma [code func]:
    28   shows "False = P \<longleftrightarrow> \<not> P"
    29     and "True = P \<longleftrightarrow> P" 
    30     and "P = False \<longleftrightarrow> \<not> P" 
    31     and "P = True \<longleftrightarrow> P" by simp_all
    32 
    33 code_const "op = \<Colon> bool \<Rightarrow> bool \<Rightarrow> bool"
    34   (Haskell infixl 4 "==")
    35 
    36 code_instance bool :: eq
    37   (Haskell -)
    38 
    39 subsection {* Unit *}
    40 
    41 typedef unit = "{True}"
    42 proof
    43   show "True : ?unit" ..
    44 qed
    45 
    46 definition
    47   Unity :: unit    ("'(')")
    48 where
    49   "() = Abs_unit True"
    50 
    51 lemma unit_eq [noatp]: "u = ()"
    52   by (induct u) (simp add: unit_def Unity_def)
    53 
    54 text {*
    55   Simplification procedure for @{thm [source] unit_eq}.  Cannot use
    56   this rule directly --- it loops!
    57 *}
    58 
    59 ML_setup {*
    60   val unit_eq_proc =
    61     let val unit_meta_eq = mk_meta_eq @{thm unit_eq} in
    62       Simplifier.simproc @{theory} "unit_eq" ["x::unit"]
    63       (fn _ => fn _ => fn t => if HOLogic.is_unit t then NONE else SOME unit_meta_eq)
    64     end;
    65 
    66   Addsimprocs [unit_eq_proc];
    67 *}
    68 
    69 lemma unit_induct [noatp,induct type: unit]: "P () ==> P x"
    70   by simp
    71 
    72 rep_datatype unit
    73   induction unit_induct
    74 
    75 lemma unit_all_eq1: "(!!x::unit. PROP P x) == PROP P ()"
    76   by simp
    77 
    78 lemma unit_all_eq2: "(!!x::unit. PROP P) == PROP P"
    79   by (rule triv_forall_equality)
    80 
    81 text {*
    82   This rewrite counters the effect of @{text unit_eq_proc} on @{term
    83   [source] "%u::unit. f u"}, replacing it by @{term [source]
    84   f} rather than by @{term [source] "%u. f ()"}.
    85 *}
    86 
    87 lemma unit_abs_eta_conv [simp,noatp]: "(%u::unit. f ()) = f"
    88   by (rule ext) simp
    89 
    90 
    91 subsection {* Pairs *}
    92 
    93 subsubsection {* Type definition *}
    94 
    95 constdefs
    96   Pair_Rep :: "['a, 'b] => ['a, 'b] => bool"
    97   "Pair_Rep == (%a b. %x y. x=a & y=b)"
    98 
    99 global
   100 
   101 typedef (Prod)
   102   ('a, 'b) "*"    (infixr "*" 20)
   103     = "{f. EX a b. f = Pair_Rep (a::'a) (b::'b)}"
   104 proof
   105   fix a b show "Pair_Rep a b : ?Prod"
   106     by blast
   107 qed
   108 
   109 syntax (xsymbols)
   110   "*"      :: "[type, type] => type"         ("(_ \<times>/ _)" [21, 20] 20)
   111 syntax (HTML output)
   112   "*"      :: "[type, type] => type"         ("(_ \<times>/ _)" [21, 20] 20)
   113 
   114 local
   115 
   116 subsubsection {* Definitions *}
   117 
   118 global
   119 
   120 consts
   121   fst      :: "'a * 'b => 'a"
   122   snd      :: "'a * 'b => 'b"
   123   split    :: "[['a, 'b] => 'c, 'a * 'b] => 'c"
   124   curry    :: "['a * 'b => 'c, 'a, 'b] => 'c"
   125   prod_fun :: "['a => 'b, 'c => 'd, 'a * 'c] => 'b * 'd"
   126   Pair     :: "['a, 'b] => 'a * 'b"
   127   Sigma    :: "['a set, 'a => 'b set] => ('a * 'b) set"
   128 
   129 local
   130 
   131 defs
   132   Pair_def:     "Pair a b == Abs_Prod (Pair_Rep a b)"
   133   fst_def:      "fst p == THE a. EX b. p = Pair a b"
   134   snd_def:      "snd p == THE b. EX a. p = Pair a b"
   135   split_def:    "split == (%c p. c (fst p) (snd p))"
   136   curry_def:    "curry == (%c x y. c (Pair x y))"
   137   prod_fun_def: "prod_fun f g == split (%x y. Pair (f x) (g y))"
   138   Sigma_def [code func]:    "Sigma A B == UN x:A. UN y:B x. {Pair x y}"
   139 
   140 abbreviation
   141   Times :: "['a set, 'b set] => ('a * 'b) set"
   142     (infixr "<*>" 80) where
   143   "A <*> B == Sigma A (%_. B)"
   144 
   145 notation (xsymbols)
   146   Times  (infixr "\<times>" 80)
   147 
   148 notation (HTML output)
   149   Times  (infixr "\<times>" 80)
   150 
   151 
   152 subsubsection {* Concrete syntax *}
   153 
   154 text {*
   155   Patterns -- extends pre-defined type @{typ pttrn} used in
   156   abstractions.
   157 *}
   158 
   159 nonterminals
   160   tuple_args patterns
   161 
   162 syntax
   163   "_tuple"      :: "'a => tuple_args => 'a * 'b"        ("(1'(_,/ _'))")
   164   "_tuple_arg"  :: "'a => tuple_args"                   ("_")
   165   "_tuple_args" :: "'a => tuple_args => tuple_args"     ("_,/ _")
   166   "_pattern"    :: "[pttrn, patterns] => pttrn"         ("'(_,/ _')")
   167   ""            :: "pttrn => patterns"                  ("_")
   168   "_patterns"   :: "[pttrn, patterns] => patterns"      ("_,/ _")
   169   "@Sigma" ::"[pttrn, 'a set, 'b set] => ('a * 'b) set" ("(3SIGMA _:_./ _)" [0, 0, 10] 10)
   170 
   171 translations
   172   "(x, y)"       == "Pair x y"
   173   "_tuple x (_tuple_args y z)" == "_tuple x (_tuple_arg (_tuple y z))"
   174   "%(x,y,zs).b"  == "split(%x (y,zs).b)"
   175   "%(x,y).b"     == "split(%x y. b)"
   176   "_abs (Pair x y) t" => "%(x,y).t"
   177   (* The last rule accommodates tuples in `case C ... (x,y) ... => ...'
   178      The (x,y) is parsed as `Pair x y' because it is logic, not pttrn *)
   179   "SIGMA x:A. B" == "Sigma A (%x. B)"
   180 
   181 (* reconstructs pattern from (nested) splits, avoiding eta-contraction of body*)
   182 (* works best with enclosing "let", if "let" does not avoid eta-contraction   *)
   183 print_translation {*
   184 let fun split_tr' [Abs (x,T,t as (Abs abs))] =
   185       (* split (%x y. t) => %(x,y) t *)
   186       let val (y,t') = atomic_abs_tr' abs;
   187           val (x',t'') = atomic_abs_tr' (x,T,t');
   188     
   189       in Syntax.const "_abs" $ (Syntax.const "_pattern" $x'$y) $ t'' end
   190     | split_tr' [Abs (x,T,(s as Const ("split",_)$t))] =
   191        (* split (%x. (split (%y z. t))) => %(x,y,z). t *)
   192        let val (Const ("_abs",_)$(Const ("_pattern",_)$y$z)$t') = split_tr' [t];
   193            val (x',t'') = atomic_abs_tr' (x,T,t');
   194        in Syntax.const "_abs"$ 
   195            (Syntax.const "_pattern"$x'$(Syntax.const "_patterns"$y$z))$t'' end
   196     | split_tr' [Const ("split",_)$t] =
   197        (* split (split (%x y z. t)) => %((x,y),z). t *)   
   198        split_tr' [(split_tr' [t])] (* inner split_tr' creates next pattern *)
   199     | split_tr' [Const ("_abs",_)$x_y$(Abs abs)] =
   200        (* split (%pttrn z. t) => %(pttrn,z). t *)
   201        let val (z,t) = atomic_abs_tr' abs;
   202        in Syntax.const "_abs" $ (Syntax.const "_pattern" $x_y$z) $ t end
   203     | split_tr' _ =  raise Match;
   204 in [("split", split_tr')]
   205 end
   206 *}
   207 
   208 (* print "split f" as "\<lambda>(x,y). f x y" and "split (\<lambda>x. f x)" as "\<lambda>(x,y). f x y" *) 
   209 typed_print_translation {*
   210 let
   211   fun split_guess_names_tr' _ T [Abs (x,_,Abs _)] = raise Match
   212     | split_guess_names_tr' _ T  [Abs (x,xT,t)] =
   213         (case (head_of t) of
   214            Const ("split",_) => raise Match
   215          | _ => let 
   216                   val (_::yT::_) = binder_types (domain_type T) handle Bind => raise Match;
   217                   val (y,t') = atomic_abs_tr' ("y",yT,(incr_boundvars 1 t)$Bound 0); 
   218                   val (x',t'') = atomic_abs_tr' (x,xT,t');
   219                 in Syntax.const "_abs" $ (Syntax.const "_pattern" $x'$y) $ t'' end)
   220     | split_guess_names_tr' _ T [t] =
   221        (case (head_of t) of
   222            Const ("split",_) => raise Match 
   223          | _ => let 
   224                   val (xT::yT::_) = binder_types (domain_type T) handle Bind => raise Match;
   225                   val (y,t') = 
   226                         atomic_abs_tr' ("y",yT,(incr_boundvars 2 t)$Bound 1$Bound 0); 
   227                   val (x',t'') = atomic_abs_tr' ("x",xT,t');
   228                 in Syntax.const "_abs" $ (Syntax.const "_pattern" $x'$y) $ t'' end)
   229     | split_guess_names_tr' _ _ _ = raise Match;
   230 in [("split", split_guess_names_tr')]
   231 end 
   232 *}
   233 
   234 
   235 subsubsection {* Lemmas and proof tool setup *}
   236 
   237 lemma ProdI: "Pair_Rep a b : Prod"
   238   unfolding Prod_def by blast
   239 
   240 lemma Pair_Rep_inject: "Pair_Rep a b = Pair_Rep a' b' ==> a = a' & b = b'"
   241   apply (unfold Pair_Rep_def)
   242   apply (drule fun_cong [THEN fun_cong], blast)
   243   done
   244 
   245 lemma inj_on_Abs_Prod: "inj_on Abs_Prod Prod"
   246   apply (rule inj_on_inverseI)
   247   apply (erule Abs_Prod_inverse)
   248   done
   249 
   250 lemma Pair_inject:
   251   assumes "(a, b) = (a', b')"
   252     and "a = a' ==> b = b' ==> R"
   253   shows R
   254   apply (insert prems [unfolded Pair_def])
   255   apply (rule inj_on_Abs_Prod [THEN inj_onD, THEN Pair_Rep_inject, THEN conjE])
   256   apply (assumption | rule ProdI)+
   257   done
   258 
   259 lemma Pair_eq [iff]: "((a, b) = (a', b')) = (a = a' & b = b')"
   260   by (blast elim!: Pair_inject)
   261 
   262 lemma fst_conv [simp, code]: "fst (a, b) = a"
   263   unfolding fst_def by blast
   264 
   265 lemma snd_conv [simp, code]: "snd (a, b) = b"
   266   unfolding snd_def by blast
   267 
   268 lemma fst_eqD: "fst (x, y) = a ==> x = a"
   269   by simp
   270 
   271 lemma snd_eqD: "snd (x, y) = a ==> y = a"
   272   by simp
   273 
   274 lemma PairE_lemma: "EX x y. p = (x, y)"
   275   apply (unfold Pair_def)
   276   apply (rule Rep_Prod [unfolded Prod_def, THEN CollectE])
   277   apply (erule exE, erule exE, rule exI, rule exI)
   278   apply (rule Rep_Prod_inverse [symmetric, THEN trans])
   279   apply (erule arg_cong)
   280   done
   281 
   282 lemma PairE [cases type: *]: "(!!x y. p = (x, y) ==> Q) ==> Q"
   283   using PairE_lemma [of p] by blast
   284 
   285 ML {*
   286   local val PairE = thm "PairE" in
   287     fun pair_tac s =
   288       EVERY' [res_inst_tac [("p", s)] PairE, hyp_subst_tac, K prune_params_tac];
   289   end;
   290 *}
   291 
   292 lemma surjective_pairing: "p = (fst p, snd p)"
   293   -- {* Do not add as rewrite rule: invalidates some proofs in IMP *}
   294   by (cases p) simp
   295 
   296 lemmas pair_collapse = surjective_pairing [symmetric]
   297 declare pair_collapse [simp]
   298 
   299 lemma surj_pair [simp]: "EX x y. z = (x, y)"
   300   apply (rule exI)
   301   apply (rule exI)
   302   apply (rule surjective_pairing)
   303   done
   304 
   305 lemma split_paired_all: "(!!x. PROP P x) == (!!a b. PROP P (a, b))"
   306 proof
   307   fix a b
   308   assume "!!x. PROP P x"
   309   then show "PROP P (a, b)" .
   310 next
   311   fix x
   312   assume "!!a b. PROP P (a, b)"
   313   from `PROP P (fst x, snd x)` show "PROP P x" by simp
   314 qed
   315 
   316 lemmas split_tupled_all = split_paired_all unit_all_eq2
   317 
   318 text {*
   319   The rule @{thm [source] split_paired_all} does not work with the
   320   Simplifier because it also affects premises in congrence rules,
   321   where this can lead to premises of the form @{text "!!a b. ... =
   322   ?P(a, b)"} which cannot be solved by reflexivity.
   323 *}
   324 
   325 ML_setup {*
   326   (* replace parameters of product type by individual component parameters *)
   327   val safe_full_simp_tac = generic_simp_tac true (true, false, false);
   328   local (* filtering with exists_paired_all is an essential optimization *)
   329     fun exists_paired_all (Const ("all", _) $ Abs (_, T, t)) =
   330           can HOLogic.dest_prodT T orelse exists_paired_all t
   331       | exists_paired_all (t $ u) = exists_paired_all t orelse exists_paired_all u
   332       | exists_paired_all (Abs (_, _, t)) = exists_paired_all t
   333       | exists_paired_all _ = false;
   334     val ss = HOL_basic_ss
   335       addsimps [thm "split_paired_all", thm "unit_all_eq2", thm "unit_abs_eta_conv"]
   336       addsimprocs [unit_eq_proc];
   337   in
   338     val split_all_tac = SUBGOAL (fn (t, i) =>
   339       if exists_paired_all t then safe_full_simp_tac ss i else no_tac);
   340     val unsafe_split_all_tac = SUBGOAL (fn (t, i) =>
   341       if exists_paired_all t then full_simp_tac ss i else no_tac);
   342     fun split_all th =
   343    if exists_paired_all (#prop (Thm.rep_thm th)) then full_simplify ss th else th;
   344   end;
   345 
   346 change_claset (fn cs => cs addSbefore ("split_all_tac", split_all_tac));
   347 *}
   348 
   349 lemma split_paired_All [simp]: "(ALL x. P x) = (ALL a b. P (a, b))"
   350   -- {* @{text "[iff]"} is not a good idea because it makes @{text blast} loop *}
   351   by fast
   352 
   353 lemma curry_split [simp]: "curry (split f) = f"
   354   by (simp add: curry_def split_def)
   355 
   356 lemma split_curry [simp]: "split (curry f) = f"
   357   by (simp add: curry_def split_def)
   358 
   359 lemma curryI [intro!]: "f (a,b) ==> curry f a b"
   360   by (simp add: curry_def)
   361 
   362 lemma curryD [dest!]: "curry f a b ==> f (a,b)"
   363   by (simp add: curry_def)
   364 
   365 lemma curryE: "[| curry f a b ; f (a,b) ==> Q |] ==> Q"
   366   by (simp add: curry_def)
   367 
   368 lemma curry_conv [simp, code func]: "curry f a b = f (a,b)"
   369   by (simp add: curry_def)
   370 
   371 lemma prod_induct [induct type: *]: "!!x. (!!a b. P (a, b)) ==> P x"
   372   by fast
   373 
   374 rep_datatype prod
   375   inject Pair_eq
   376   induction prod_induct
   377 
   378 lemma split_paired_Ex [simp]: "(EX x. P x) = (EX a b. P (a, b))"
   379   by fast
   380 
   381 lemma split_conv [simp, code func]: "split c (a, b) = c a b"
   382   by (simp add: split_def)
   383 
   384 lemmas split = split_conv  -- {* for backwards compatibility *}
   385 
   386 lemmas splitI = split_conv [THEN iffD2, standard]
   387 lemmas splitD = split_conv [THEN iffD1, standard]
   388 
   389 lemma split_Pair_apply: "split (%x y. f (x, y)) = f"
   390   -- {* Subsumes the old @{text split_Pair} when @{term f} is the identity function. *}
   391   apply (rule ext)
   392   apply (tactic {* pair_tac "x" 1 *}, simp)
   393   done
   394 
   395 lemma split_paired_The: "(THE x. P x) = (THE (a, b). P (a, b))"
   396   -- {* Can't be added to simpset: loops! *}
   397   by (simp add: split_Pair_apply)
   398 
   399 lemma The_split: "The (split P) = (THE xy. P (fst xy) (snd xy))"
   400   by (simp add: split_def)
   401 
   402 lemma Pair_fst_snd_eq: "!!s t. (s = t) = (fst s = fst t & snd s = snd t)"
   403 by (simp only: split_tupled_all, simp)
   404 
   405 lemma prod_eqI [intro?]: "fst p = fst q ==> snd p = snd q ==> p = q"
   406   by (simp add: Pair_fst_snd_eq)
   407 
   408 lemma split_weak_cong: "p = q ==> split c p = split c q"
   409   -- {* Prevents simplification of @{term c}: much faster *}
   410   by (erule arg_cong)
   411 
   412 lemma split_eta: "(%(x, y). f (x, y)) = f"
   413   apply (rule ext)
   414   apply (simp only: split_tupled_all)
   415   apply (rule split_conv)
   416   done
   417 
   418 lemma cond_split_eta: "(!!x y. f x y = g (x, y)) ==> (%(x, y). f x y) = g"
   419   by (simp add: split_eta)
   420 
   421 text {*
   422   Simplification procedure for @{thm [source] cond_split_eta}.  Using
   423   @{thm [source] split_eta} as a rewrite rule is not general enough,
   424   and using @{thm [source] cond_split_eta} directly would render some
   425   existing proofs very inefficient; similarly for @{text
   426   split_beta}. *}
   427 
   428 ML_setup {*
   429 
   430 local
   431   val cond_split_eta_ss = HOL_basic_ss addsimps [thm "cond_split_eta"]
   432   fun  Pair_pat k 0 (Bound m) = (m = k)
   433   |    Pair_pat k i (Const ("Pair",  _) $ Bound m $ t) = i > 0 andalso
   434                         m = k+i andalso Pair_pat k (i-1) t
   435   |    Pair_pat _ _ _ = false;
   436   fun no_args k i (Abs (_, _, t)) = no_args (k+1) i t
   437   |   no_args k i (t $ u) = no_args k i t andalso no_args k i u
   438   |   no_args k i (Bound m) = m < k orelse m > k+i
   439   |   no_args _ _ _ = true;
   440   fun split_pat tp i (Abs  (_,_,t)) = if tp 0 i t then SOME (i,t) else NONE
   441   |   split_pat tp i (Const ("split", _) $ Abs (_, _, t)) = split_pat tp (i+1) t
   442   |   split_pat tp i _ = NONE;
   443   fun metaeq ss lhs rhs = mk_meta_eq (Goal.prove (Simplifier.the_context ss) [] []
   444         (HOLogic.mk_Trueprop (HOLogic.mk_eq (lhs,rhs)))
   445         (K (simp_tac (Simplifier.inherit_context ss cond_split_eta_ss) 1)));
   446 
   447   fun beta_term_pat k i (Abs (_, _, t)) = beta_term_pat (k+1) i t
   448   |   beta_term_pat k i (t $ u) = Pair_pat k i (t $ u) orelse
   449                         (beta_term_pat k i t andalso beta_term_pat k i u)
   450   |   beta_term_pat k i t = no_args k i t;
   451   fun  eta_term_pat k i (f $ arg) = no_args k i f andalso Pair_pat k i arg
   452   |    eta_term_pat _ _ _ = false;
   453   fun subst arg k i (Abs (x, T, t)) = Abs (x, T, subst arg (k+1) i t)
   454   |   subst arg k i (t $ u) = if Pair_pat k i (t $ u) then incr_boundvars k arg
   455                               else (subst arg k i t $ subst arg k i u)
   456   |   subst arg k i t = t;
   457   fun beta_proc ss (s as Const ("split", _) $ Abs (_, _, t) $ arg) =
   458         (case split_pat beta_term_pat 1 t of
   459         SOME (i,f) => SOME (metaeq ss s (subst arg 0 i f))
   460         | NONE => NONE)
   461   |   beta_proc _ _ = NONE;
   462   fun eta_proc ss (s as Const ("split", _) $ Abs (_, _, t)) =
   463         (case split_pat eta_term_pat 1 t of
   464           SOME (_,ft) => SOME (metaeq ss s (let val (f $ arg) = ft in f end))
   465         | NONE => NONE)
   466   |   eta_proc _ _ = NONE;
   467 in
   468   val split_beta_proc = Simplifier.simproc @{theory} "split_beta" ["split f z"] (K beta_proc);
   469   val split_eta_proc = Simplifier.simproc @{theory} "split_eta" ["split f"] (K eta_proc);
   470 end;
   471 
   472 Addsimprocs [split_beta_proc, split_eta_proc];
   473 *}
   474 
   475 lemma split_beta: "(%(x, y). P x y) z = P (fst z) (snd z)"
   476   by (subst surjective_pairing, rule split_conv)
   477 
   478 lemma split_split [noatp]: "R(split c p) = (ALL x y. p = (x, y) --> R(c x y))"
   479   -- {* For use with @{text split} and the Simplifier. *}
   480   by (insert surj_pair [of p], clarify, simp)
   481 
   482 text {*
   483   @{thm [source] split_split} could be declared as @{text "[split]"}
   484   done after the Splitter has been speeded up significantly;
   485   precompute the constants involved and don't do anything unless the
   486   current goal contains one of those constants.
   487 *}
   488 
   489 lemma split_split_asm [noatp]: "R (split c p) = (~(EX x y. p = (x, y) & (~R (c x y))))"
   490 by (subst split_split, simp)
   491 
   492 
   493 text {*
   494   \medskip @{term split} used as a logical connective or set former.
   495 
   496   \medskip These rules are for use with @{text blast}; could instead
   497   call @{text simp} using @{thm [source] split} as rewrite. *}
   498 
   499 lemma splitI2: "!!p. [| !!a b. p = (a, b) ==> c a b |] ==> split c p"
   500   apply (simp only: split_tupled_all)
   501   apply (simp (no_asm_simp))
   502   done
   503 
   504 lemma splitI2': "!!p. [| !!a b. (a, b) = p ==> c a b x |] ==> split c p x"
   505   apply (simp only: split_tupled_all)
   506   apply (simp (no_asm_simp))
   507   done
   508 
   509 lemma splitE: "split c p ==> (!!x y. p = (x, y) ==> c x y ==> Q) ==> Q"
   510   by (induct p) (auto simp add: split_def)
   511 
   512 lemma splitE': "split c p z ==> (!!x y. p = (x, y) ==> c x y z ==> Q) ==> Q"
   513   by (induct p) (auto simp add: split_def)
   514 
   515 lemma splitE2:
   516   "[| Q (split P z);  !!x y. [|z = (x, y); Q (P x y)|] ==> R |] ==> R"
   517 proof -
   518   assume q: "Q (split P z)"
   519   assume r: "!!x y. [|z = (x, y); Q (P x y)|] ==> R"
   520   show R
   521     apply (rule r surjective_pairing)+
   522     apply (rule split_beta [THEN subst], rule q)
   523     done
   524 qed
   525 
   526 lemma splitD': "split R (a,b) c ==> R a b c"
   527   by simp
   528 
   529 lemma mem_splitI: "z: c a b ==> z: split c (a, b)"
   530   by simp
   531 
   532 lemma mem_splitI2: "!!p. [| !!a b. p = (a, b) ==> z: c a b |] ==> z: split c p"
   533 by (simp only: split_tupled_all, simp)
   534 
   535 lemma mem_splitE:
   536   assumes major: "z: split c p"
   537     and cases: "!!x y. [| p = (x,y); z: c x y |] ==> Q"
   538   shows Q
   539   by (rule major [unfolded split_def] cases surjective_pairing)+
   540 
   541 declare mem_splitI2 [intro!] mem_splitI [intro!] splitI2' [intro!] splitI2 [intro!] splitI [intro!]
   542 declare mem_splitE [elim!] splitE' [elim!] splitE [elim!]
   543 
   544 ML_setup {*
   545 local (* filtering with exists_p_split is an essential optimization *)
   546   fun exists_p_split (Const ("split",_) $ _ $ (Const ("Pair",_)$_$_)) = true
   547     | exists_p_split (t $ u) = exists_p_split t orelse exists_p_split u
   548     | exists_p_split (Abs (_, _, t)) = exists_p_split t
   549     | exists_p_split _ = false;
   550   val ss = HOL_basic_ss addsimps [thm "split_conv"];
   551 in
   552 val split_conv_tac = SUBGOAL (fn (t, i) =>
   553     if exists_p_split t then safe_full_simp_tac ss i else no_tac);
   554 end;
   555 (* This prevents applications of splitE for already splitted arguments leading
   556    to quite time-consuming computations (in particular for nested tuples) *)
   557 change_claset (fn cs => cs addSbefore ("split_conv_tac", split_conv_tac));
   558 *}
   559 
   560 lemma split_eta_SetCompr [simp,noatp]: "(%u. EX x y. u = (x, y) & P (x, y)) = P"
   561   by (rule ext) fast
   562 
   563 lemma split_eta_SetCompr2 [simp,noatp]: "(%u. EX x y. u = (x, y) & P x y) = split P"
   564   by (rule ext) fast
   565 
   566 lemma split_part [simp]: "(%(a,b). P & Q a b) = (%ab. P & split Q ab)"
   567   -- {* Allows simplifications of nested splits in case of independent predicates. *}
   568   by (rule ext) blast
   569 
   570 (* Do NOT make this a simp rule as it
   571    a) only helps in special situations
   572    b) can lead to nontermination in the presence of split_def
   573 *)
   574 lemma split_comp_eq: 
   575   fixes f :: "'a => 'b => 'c" and g :: "'d => 'a"
   576   shows "(%u. f (g (fst u)) (snd u)) = (split (%x. f (g x)))"
   577   by (rule ext) auto
   578 
   579 lemma The_split_eq [simp]: "(THE (x',y'). x = x' & y = y') = (x, y)"
   580   by blast
   581 
   582 (*
   583 the following  would be slightly more general,
   584 but cannot be used as rewrite rule:
   585 ### Cannot add premise as rewrite rule because it contains (type) unknowns:
   586 ### ?y = .x
   587 Goal "[| P y; !!x. P x ==> x = y |] ==> (@(x',y). x = x' & P y) = (x,y)"
   588 by (rtac some_equality 1)
   589 by ( Simp_tac 1)
   590 by (split_all_tac 1)
   591 by (Asm_full_simp_tac 1)
   592 qed "The_split_eq";
   593 *)
   594 
   595 lemma injective_fst_snd: "!!x y. [|fst x = fst y; snd x = snd y|] ==> x = y"
   596   by auto
   597 
   598 
   599 text {*
   600   \bigskip @{term prod_fun} --- action of the product functor upon
   601   functions.
   602 *}
   603 
   604 lemma prod_fun [simp, code func]: "prod_fun f g (a, b) = (f a, g b)"
   605   by (simp add: prod_fun_def)
   606 
   607 lemma prod_fun_compose: "prod_fun (f1 o f2) (g1 o g2) = (prod_fun f1 g1 o prod_fun f2 g2)"
   608   apply (rule ext)
   609   apply (tactic {* pair_tac "x" 1 *}, simp)
   610   done
   611 
   612 lemma prod_fun_ident [simp]: "prod_fun (%x. x) (%y. y) = (%z. z)"
   613   apply (rule ext)
   614   apply (tactic {* pair_tac "z" 1 *}, simp)
   615   done
   616 
   617 lemma prod_fun_imageI [intro]: "(a, b) : r ==> (f a, g b) : prod_fun f g ` r"
   618   apply (rule image_eqI)
   619   apply (rule prod_fun [symmetric], assumption)
   620   done
   621 
   622 lemma prod_fun_imageE [elim!]:
   623   assumes major: "c: (prod_fun f g)`r"
   624     and cases: "!!x y. [| c=(f(x),g(y));  (x,y):r |] ==> P"
   625   shows P
   626   apply (rule major [THEN imageE])
   627   apply (rule_tac p = x in PairE)
   628   apply (rule cases)
   629    apply (blast intro: prod_fun)
   630   apply blast
   631   done
   632 
   633 
   634 definition
   635   upd_fst :: "('a \<Rightarrow> 'c) \<Rightarrow> 'a \<times> 'b \<Rightarrow> 'c \<times> 'b"
   636 where
   637   [code func del]: "upd_fst f = prod_fun f id"
   638 
   639 definition
   640   upd_snd :: "('b \<Rightarrow> 'c) \<Rightarrow> 'a \<times> 'b \<Rightarrow> 'a \<times> 'c"
   641 where
   642   [code func del]: "upd_snd f = prod_fun id f"
   643 
   644 lemma upd_fst_conv [simp, code]:
   645   "upd_fst f (x, y) = (f x, y)" 
   646   by (simp add: upd_fst_def)
   647 
   648 lemma upd_snd_conv [simp, code]:
   649   "upd_snd f (x, y) = (x, f y)" 
   650   by (simp add: upd_snd_def)
   651 
   652 text {*
   653   \bigskip Disjoint union of a family of sets -- Sigma.
   654 *}
   655 
   656 lemma SigmaI [intro!]: "[| a:A;  b:B(a) |] ==> (a,b) : Sigma A B"
   657   by (unfold Sigma_def) blast
   658 
   659 lemma SigmaE [elim!]:
   660     "[| c: Sigma A B;
   661         !!x y.[| x:A;  y:B(x);  c=(x,y) |] ==> P
   662      |] ==> P"
   663   -- {* The general elimination rule. *}
   664   by (unfold Sigma_def) blast
   665 
   666 text {*
   667   Elimination of @{term "(a, b) : A \<times> B"} -- introduces no
   668   eigenvariables.
   669 *}
   670 
   671 lemma SigmaD1: "(a, b) : Sigma A B ==> a : A"
   672   by blast
   673 
   674 lemma SigmaD2: "(a, b) : Sigma A B ==> b : B a"
   675   by blast
   676 
   677 lemma SigmaE2:
   678     "[| (a, b) : Sigma A B;
   679         [| a:A;  b:B(a) |] ==> P
   680      |] ==> P"
   681   by blast
   682 
   683 lemma Sigma_cong:
   684      "\<lbrakk>A = B; !!x. x \<in> B \<Longrightarrow> C x = D x\<rbrakk>
   685       \<Longrightarrow> (SIGMA x: A. C x) = (SIGMA x: B. D x)"
   686   by auto
   687 
   688 lemma Sigma_mono: "[| A <= C; !!x. x:A ==> B x <= D x |] ==> Sigma A B <= Sigma C D"
   689   by blast
   690 
   691 lemma Sigma_empty1 [simp]: "Sigma {} B = {}"
   692   by blast
   693 
   694 lemma Sigma_empty2 [simp]: "A <*> {} = {}"
   695   by blast
   696 
   697 lemma UNIV_Times_UNIV [simp]: "UNIV <*> UNIV = UNIV"
   698   by auto
   699 
   700 lemma Compl_Times_UNIV1 [simp]: "- (UNIV <*> A) = UNIV <*> (-A)"
   701   by auto
   702 
   703 lemma Compl_Times_UNIV2 [simp]: "- (A <*> UNIV) = (-A) <*> UNIV"
   704   by auto
   705 
   706 lemma mem_Sigma_iff [iff]: "((a,b): Sigma A B) = (a:A & b:B(a))"
   707   by blast
   708 
   709 lemma Times_subset_cancel2: "x:C ==> (A <*> C <= B <*> C) = (A <= B)"
   710   by blast
   711 
   712 lemma Times_eq_cancel2: "x:C ==> (A <*> C = B <*> C) = (A = B)"
   713   by (blast elim: equalityE)
   714 
   715 lemma SetCompr_Sigma_eq:
   716     "Collect (split (%x y. P x & Q x y)) = (SIGMA x:Collect P. Collect (Q x))"
   717   by blast
   718 
   719 text {*
   720   \bigskip Complex rules for Sigma.
   721 *}
   722 
   723 lemma Collect_split [simp]: "{(a,b). P a & Q b} = Collect P <*> Collect Q"
   724   by blast
   725 
   726 lemma UN_Times_distrib:
   727   "(UN (a,b):(A <*> B). E a <*> F b) = (UNION A E) <*> (UNION B F)"
   728   -- {* Suggested by Pierre Chartier *}
   729   by blast
   730 
   731 lemma split_paired_Ball_Sigma [simp,noatp]:
   732     "(ALL z: Sigma A B. P z) = (ALL x:A. ALL y: B x. P(x,y))"
   733   by blast
   734 
   735 lemma split_paired_Bex_Sigma [simp,noatp]:
   736     "(EX z: Sigma A B. P z) = (EX x:A. EX y: B x. P(x,y))"
   737   by blast
   738 
   739 lemma Sigma_Un_distrib1: "(SIGMA i:I Un J. C(i)) = (SIGMA i:I. C(i)) Un (SIGMA j:J. C(j))"
   740   by blast
   741 
   742 lemma Sigma_Un_distrib2: "(SIGMA i:I. A(i) Un B(i)) = (SIGMA i:I. A(i)) Un (SIGMA i:I. B(i))"
   743   by blast
   744 
   745 lemma Sigma_Int_distrib1: "(SIGMA i:I Int J. C(i)) = (SIGMA i:I. C(i)) Int (SIGMA j:J. C(j))"
   746   by blast
   747 
   748 lemma Sigma_Int_distrib2: "(SIGMA i:I. A(i) Int B(i)) = (SIGMA i:I. A(i)) Int (SIGMA i:I. B(i))"
   749   by blast
   750 
   751 lemma Sigma_Diff_distrib1: "(SIGMA i:I - J. C(i)) = (SIGMA i:I. C(i)) - (SIGMA j:J. C(j))"
   752   by blast
   753 
   754 lemma Sigma_Diff_distrib2: "(SIGMA i:I. A(i) - B(i)) = (SIGMA i:I. A(i)) - (SIGMA i:I. B(i))"
   755   by blast
   756 
   757 lemma Sigma_Union: "Sigma (Union X) B = (UN A:X. Sigma A B)"
   758   by blast
   759 
   760 text {*
   761   Non-dependent versions are needed to avoid the need for higher-order
   762   matching, especially when the rules are re-oriented.
   763 *}
   764 
   765 lemma Times_Un_distrib1: "(A Un B) <*> C = (A <*> C) Un (B <*> C)"
   766   by blast
   767 
   768 lemma Times_Int_distrib1: "(A Int B) <*> C = (A <*> C) Int (B <*> C)"
   769   by blast
   770 
   771 lemma Times_Diff_distrib1: "(A - B) <*> C = (A <*> C) - (B <*> C)"
   772   by blast
   773 
   774 
   775 lemma pair_imageI [intro]: "(a, b) : A ==> f a b : (%(a, b). f a b) ` A"
   776   apply (rule_tac x = "(a, b)" in image_eqI)
   777    apply auto
   778   done
   779 
   780 
   781 text {*
   782   Setup of internal @{text split_rule}.
   783 *}
   784 
   785 definition
   786   internal_split :: "('a \<Rightarrow> 'b \<Rightarrow> 'c) \<Rightarrow> 'a \<times> 'b \<Rightarrow> 'c"
   787 where
   788   "internal_split == split"
   789 
   790 lemma internal_split_conv: "internal_split c (a, b) = c a b"
   791   by (simp only: internal_split_def split_conv)
   792 
   793 hide const internal_split
   794 
   795 use "Tools/split_rule.ML"
   796 setup SplitRule.setup
   797 
   798 
   799 
   800 lemmas prod_caseI = prod.cases [THEN iffD2, standard]
   801 
   802 lemma prod_caseI2: "!!p. [| !!a b. p = (a, b) ==> c a b |] ==> prod_case c p"
   803   by auto
   804 
   805 lemma prod_caseI2': "!!p. [| !!a b. (a, b) = p ==> c a b x |] ==> prod_case c p x"
   806   by (auto simp: split_tupled_all)
   807 
   808 lemma prod_caseE: "prod_case c p ==> (!!x y. p = (x, y) ==> c x y ==> Q) ==> Q"
   809   by (induct p) auto
   810 
   811 lemma prod_caseE': "prod_case c p z ==> (!!x y. p = (x, y) ==> c x y z ==> Q) ==> Q"
   812   by (induct p) auto
   813 
   814 lemma prod_case_unfold: "prod_case = (%c p. c (fst p) (snd p))"
   815   by (simp add: expand_fun_eq)
   816 
   817 declare prod_caseI2' [intro!] prod_caseI2 [intro!] prod_caseI [intro!]
   818 declare prod_caseE' [elim!] prod_caseE [elim!]
   819 
   820 lemma prod_case_split:
   821   "prod_case = split"
   822   by (auto simp add: expand_fun_eq)
   823 
   824 
   825 subsection {* Further cases/induct rules for tuples *}
   826 
   827 lemma prod_cases3 [cases type]:
   828   obtains (fields) a b c where "y = (a, b, c)"
   829   by (cases y, case_tac b) blast
   830 
   831 lemma prod_induct3 [case_names fields, induct type]:
   832     "(!!a b c. P (a, b, c)) ==> P x"
   833   by (cases x) blast
   834 
   835 lemma prod_cases4 [cases type]:
   836   obtains (fields) a b c d where "y = (a, b, c, d)"
   837   by (cases y, case_tac c) blast
   838 
   839 lemma prod_induct4 [case_names fields, induct type]:
   840     "(!!a b c d. P (a, b, c, d)) ==> P x"
   841   by (cases x) blast
   842 
   843 lemma prod_cases5 [cases type]:
   844   obtains (fields) a b c d e where "y = (a, b, c, d, e)"
   845   by (cases y, case_tac d) blast
   846 
   847 lemma prod_induct5 [case_names fields, induct type]:
   848     "(!!a b c d e. P (a, b, c, d, e)) ==> P x"
   849   by (cases x) blast
   850 
   851 lemma prod_cases6 [cases type]:
   852   obtains (fields) a b c d e f where "y = (a, b, c, d, e, f)"
   853   by (cases y, case_tac e) blast
   854 
   855 lemma prod_induct6 [case_names fields, induct type]:
   856     "(!!a b c d e f. P (a, b, c, d, e, f)) ==> P x"
   857   by (cases x) blast
   858 
   859 lemma prod_cases7 [cases type]:
   860   obtains (fields) a b c d e f g where "y = (a, b, c, d, e, f, g)"
   861   by (cases y, case_tac f) blast
   862 
   863 lemma prod_induct7 [case_names fields, induct type]:
   864     "(!!a b c d e f g. P (a, b, c, d, e, f, g)) ==> P x"
   865   by (cases x) blast
   866 
   867 
   868 subsection {* Further lemmas *}
   869 
   870 lemma
   871   split_Pair: "split Pair x = x"
   872   unfolding split_def by auto
   873 
   874 lemma
   875   split_comp: "split (f \<circ> g) x = f (g (fst x)) (snd x)"
   876   by (cases x, simp)
   877 
   878 
   879 subsection {* Code generator setup *}
   880 
   881 instance unit :: eq ..
   882 
   883 lemma [code func]:
   884   "(u\<Colon>unit) = v \<longleftrightarrow> True" unfolding unit_eq [of u] unit_eq [of v] by rule+
   885 
   886 code_type unit
   887   (SML "unit")
   888   (OCaml "unit")
   889   (Haskell "()")
   890 
   891 code_instance unit :: eq
   892   (Haskell -)
   893 
   894 code_const "op = \<Colon> unit \<Rightarrow> unit \<Rightarrow> bool"
   895   (Haskell infixl 4 "==")
   896 
   897 code_const Unity
   898   (SML "()")
   899   (OCaml "()")
   900   (Haskell "()")
   901 
   902 code_reserved SML
   903   unit
   904 
   905 code_reserved OCaml
   906   unit
   907 
   908 instance * :: (eq, eq) eq ..
   909 
   910 lemma [code func]:
   911   "(x1\<Colon>'a\<Colon>eq, y1\<Colon>'b\<Colon>eq) = (x2, y2) \<longleftrightarrow> x1 = x2 \<and> y1 = y2" by auto
   912 
   913 lemma split_case_cert:
   914   assumes "CASE \<equiv> split f"
   915   shows "CASE (a, b) \<equiv> f a b"
   916   using assms by simp
   917 
   918 setup {*
   919   Code.add_case @{thm split_case_cert}
   920 *}
   921 
   922 code_type *
   923   (SML infix 2 "*")
   924   (OCaml infix 2 "*")
   925   (Haskell "!((_),/ (_))")
   926 
   927 code_instance * :: eq
   928   (Haskell -)
   929 
   930 code_const "op = \<Colon> 'a\<Colon>eq \<times> 'b\<Colon>eq \<Rightarrow> 'a \<times> 'b \<Rightarrow> bool"
   931   (Haskell infixl 4 "==")
   932 
   933 code_const Pair
   934   (SML "!((_),/ (_))")
   935   (OCaml "!((_),/ (_))")
   936   (Haskell "!((_),/ (_))")
   937 
   938 code_const fst and snd
   939   (Haskell "fst" and "snd")
   940 
   941 types_code
   942   "*"     ("(_ */ _)")
   943 attach (term_of) {*
   944 fun term_of_id_42 aF aT bF bT (x, y) = HOLogic.pair_const aT bT $ aF x $ bF y;
   945 *}
   946 attach (test) {*
   947 fun gen_id_42 aG aT bG bT i =
   948   let
   949     val (x, t) = aG i;
   950     val (y, u) = bG i
   951   in ((x, y), fn () => HOLogic.pair_const aT bT $ t () $ u ()) end;
   952 *}
   953 
   954 consts_code
   955   "Pair"    ("(_,/ _)")
   956 
   957 setup {*
   958 
   959 let
   960 
   961 fun strip_abs_split 0 t = ([], t)
   962   | strip_abs_split i (Abs (s, T, t)) =
   963       let
   964         val s' = Codegen.new_name t s;
   965         val v = Free (s', T)
   966       in apfst (cons v) (strip_abs_split (i-1) (subst_bound (v, t))) end
   967   | strip_abs_split i (u as Const ("split", _) $ t) = (case strip_abs_split (i+1) t of
   968         (v :: v' :: vs, u) => (HOLogic.mk_prod (v, v') :: vs, u)
   969       | _ => ([], u))
   970   | strip_abs_split i t = ([], t);
   971 
   972 fun let_codegen thy defs gr dep thyname brack t = (case strip_comb t of
   973     (t1 as Const ("Let", _), t2 :: t3 :: ts) =>
   974     let
   975       fun dest_let (l as Const ("Let", _) $ t $ u) =
   976           (case strip_abs_split 1 u of
   977              ([p], u') => apfst (cons (p, t)) (dest_let u')
   978            | _ => ([], l))
   979         | dest_let t = ([], t);
   980       fun mk_code (gr, (l, r)) =
   981         let
   982           val (gr1, pl) = Codegen.invoke_codegen thy defs dep thyname false (gr, l);
   983           val (gr2, pr) = Codegen.invoke_codegen thy defs dep thyname false (gr1, r);
   984         in (gr2, (pl, pr)) end
   985     in case dest_let (t1 $ t2 $ t3) of
   986         ([], _) => NONE
   987       | (ps, u) =>
   988           let
   989             val (gr1, qs) = foldl_map mk_code (gr, ps);
   990             val (gr2, pu) = Codegen.invoke_codegen thy defs dep thyname false (gr1, u);
   991             val (gr3, pargs) = foldl_map
   992               (Codegen.invoke_codegen thy defs dep thyname true) (gr2, ts)
   993           in
   994             SOME (gr3, Codegen.mk_app brack
   995               (Pretty.blk (0, [Pretty.str "let ", Pretty.blk (0, List.concat
   996                   (separate [Pretty.str ";", Pretty.brk 1] (map (fn (pl, pr) =>
   997                     [Pretty.block [Pretty.str "val ", pl, Pretty.str " =",
   998                        Pretty.brk 1, pr]]) qs))),
   999                 Pretty.brk 1, Pretty.str "in ", pu,
  1000                 Pretty.brk 1, Pretty.str "end"])) pargs)
  1001           end
  1002     end
  1003   | _ => NONE);
  1004 
  1005 fun split_codegen thy defs gr dep thyname brack t = (case strip_comb t of
  1006     (t1 as Const ("split", _), t2 :: ts) =>
  1007       (case strip_abs_split 1 (t1 $ t2) of
  1008          ([p], u) =>
  1009            let
  1010              val (gr1, q) = Codegen.invoke_codegen thy defs dep thyname false (gr, p);
  1011              val (gr2, pu) = Codegen.invoke_codegen thy defs dep thyname false (gr1, u);
  1012              val (gr3, pargs) = foldl_map
  1013                (Codegen.invoke_codegen thy defs dep thyname true) (gr2, ts)
  1014            in
  1015              SOME (gr2, Codegen.mk_app brack
  1016                (Pretty.block [Pretty.str "(fn ", q, Pretty.str " =>",
  1017                  Pretty.brk 1, pu, Pretty.str ")"]) pargs)
  1018            end
  1019        | _ => NONE)
  1020   | _ => NONE);
  1021 
  1022 in
  1023 
  1024   Codegen.add_codegen "let_codegen" let_codegen
  1025   #> Codegen.add_codegen "split_codegen" split_codegen
  1026 
  1027 end
  1028 *}
  1029 
  1030 
  1031 subsection {* Legacy bindings *}
  1032 
  1033 ML {*
  1034 val Collect_split = thm "Collect_split";
  1035 val Compl_Times_UNIV1 = thm "Compl_Times_UNIV1";
  1036 val Compl_Times_UNIV2 = thm "Compl_Times_UNIV2";
  1037 val PairE = thm "PairE";
  1038 val PairE_lemma = thm "PairE_lemma";
  1039 val Pair_Rep_inject = thm "Pair_Rep_inject";
  1040 val Pair_def = thm "Pair_def";
  1041 val Pair_eq = thm "Pair_eq";
  1042 val Pair_fst_snd_eq = thm "Pair_fst_snd_eq";
  1043 val Pair_inject = thm "Pair_inject";
  1044 val ProdI = thm "ProdI";
  1045 val SetCompr_Sigma_eq = thm "SetCompr_Sigma_eq";
  1046 val SigmaD1 = thm "SigmaD1";
  1047 val SigmaD2 = thm "SigmaD2";
  1048 val SigmaE = thm "SigmaE";
  1049 val SigmaE2 = thm "SigmaE2";
  1050 val SigmaI = thm "SigmaI";
  1051 val Sigma_Diff_distrib1 = thm "Sigma_Diff_distrib1";
  1052 val Sigma_Diff_distrib2 = thm "Sigma_Diff_distrib2";
  1053 val Sigma_Int_distrib1 = thm "Sigma_Int_distrib1";
  1054 val Sigma_Int_distrib2 = thm "Sigma_Int_distrib2";
  1055 val Sigma_Un_distrib1 = thm "Sigma_Un_distrib1";
  1056 val Sigma_Un_distrib2 = thm "Sigma_Un_distrib2";
  1057 val Sigma_Union = thm "Sigma_Union";
  1058 val Sigma_def = thm "Sigma_def";
  1059 val Sigma_empty1 = thm "Sigma_empty1";
  1060 val Sigma_empty2 = thm "Sigma_empty2";
  1061 val Sigma_mono = thm "Sigma_mono";
  1062 val The_split = thm "The_split";
  1063 val The_split_eq = thm "The_split_eq";
  1064 val The_split_eq = thm "The_split_eq";
  1065 val Times_Diff_distrib1 = thm "Times_Diff_distrib1";
  1066 val Times_Int_distrib1 = thm "Times_Int_distrib1";
  1067 val Times_Un_distrib1 = thm "Times_Un_distrib1";
  1068 val Times_eq_cancel2 = thm "Times_eq_cancel2";
  1069 val Times_subset_cancel2 = thm "Times_subset_cancel2";
  1070 val UNIV_Times_UNIV = thm "UNIV_Times_UNIV";
  1071 val UN_Times_distrib = thm "UN_Times_distrib";
  1072 val Unity_def = thm "Unity_def";
  1073 val cond_split_eta = thm "cond_split_eta";
  1074 val fst_conv = thm "fst_conv";
  1075 val fst_def = thm "fst_def";
  1076 val fst_eqD = thm "fst_eqD";
  1077 val inj_on_Abs_Prod = thm "inj_on_Abs_Prod";
  1078 val injective_fst_snd = thm "injective_fst_snd";
  1079 val mem_Sigma_iff = thm "mem_Sigma_iff";
  1080 val mem_splitE = thm "mem_splitE";
  1081 val mem_splitI = thm "mem_splitI";
  1082 val mem_splitI2 = thm "mem_splitI2";
  1083 val prod_eqI = thm "prod_eqI";
  1084 val prod_fun = thm "prod_fun";
  1085 val prod_fun_compose = thm "prod_fun_compose";
  1086 val prod_fun_def = thm "prod_fun_def";
  1087 val prod_fun_ident = thm "prod_fun_ident";
  1088 val prod_fun_imageE = thm "prod_fun_imageE";
  1089 val prod_fun_imageI = thm "prod_fun_imageI";
  1090 val prod_induct = thm "prod_induct";
  1091 val snd_conv = thm "snd_conv";
  1092 val snd_def = thm "snd_def";
  1093 val snd_eqD = thm "snd_eqD";
  1094 val split = thm "split";
  1095 val splitD = thm "splitD";
  1096 val splitD' = thm "splitD'";
  1097 val splitE = thm "splitE";
  1098 val splitE' = thm "splitE'";
  1099 val splitE2 = thm "splitE2";
  1100 val splitI = thm "splitI";
  1101 val splitI2 = thm "splitI2";
  1102 val splitI2' = thm "splitI2'";
  1103 val split_Pair_apply = thm "split_Pair_apply";
  1104 val split_beta = thm "split_beta";
  1105 val split_conv = thm "split_conv";
  1106 val split_def = thm "split_def";
  1107 val split_eta = thm "split_eta";
  1108 val split_eta_SetCompr = thm "split_eta_SetCompr";
  1109 val split_eta_SetCompr2 = thm "split_eta_SetCompr2";
  1110 val split_paired_All = thm "split_paired_All";
  1111 val split_paired_Ball_Sigma = thm "split_paired_Ball_Sigma";
  1112 val split_paired_Bex_Sigma = thm "split_paired_Bex_Sigma";
  1113 val split_paired_Ex = thm "split_paired_Ex";
  1114 val split_paired_The = thm "split_paired_The";
  1115 val split_paired_all = thm "split_paired_all";
  1116 val split_part = thm "split_part";
  1117 val split_split = thm "split_split";
  1118 val split_split_asm = thm "split_split_asm";
  1119 val split_tupled_all = thms "split_tupled_all";
  1120 val split_weak_cong = thm "split_weak_cong";
  1121 val surj_pair = thm "surj_pair";
  1122 val surjective_pairing = thm "surjective_pairing";
  1123 val unit_abs_eta_conv = thm "unit_abs_eta_conv";
  1124 val unit_all_eq1 = thm "unit_all_eq1";
  1125 val unit_all_eq2 = thm "unit_all_eq2";
  1126 val unit_eq = thm "unit_eq";
  1127 val unit_induct = thm "unit_induct";
  1128 *}
  1129 
  1130 
  1131 subsection {* Further inductive packages *}
  1132 
  1133 use "Tools/inductive_realizer.ML"
  1134 setup InductiveRealizer.setup
  1135 
  1136 use "Tools/inductive_set_package.ML"
  1137 setup InductiveSetPackage.setup
  1138 
  1139 use "Tools/datatype_realizer.ML"
  1140 setup DatatypeRealizer.setup
  1141 
  1142 end