src/Pure/Thy/thy_output.ML
author haftmann
Wed Oct 07 16:57:56 2009 +0200 (2009-10-07)
changeset 32890 77df12652210
parent 32738 15bb09ca0378
child 32898 e871d897969c
permissions -rw-r--r--
generalized term styles: transformations may depend on arguments; modernized term_style module; antiquotations thm, prop and term accepting term styles
     1 (*  Title:      Pure/Thy/thy_output.ML
     2     Author:     Markus Wenzel, TU Muenchen
     3 
     4 Theory document output with antiquotations.
     5 *)
     6 
     7 signature THY_OUTPUT =
     8 sig
     9   val display: bool Unsynchronized.ref
    10   val quotes: bool Unsynchronized.ref
    11   val indent: int Unsynchronized.ref
    12   val source: bool Unsynchronized.ref
    13   val break: bool Unsynchronized.ref
    14   val add_commands: (string * (Args.src -> Toplevel.state -> string)) list -> unit
    15   val add_options: (string * (string -> (unit -> string) -> unit -> string)) list -> unit
    16   val defined_command: string -> bool
    17   val defined_option: string -> bool
    18   val print_antiquotations: unit -> unit
    19   val boolean: string -> bool
    20   val integer: string -> int
    21   val antiquotation: string -> 'a context_parser ->
    22     ({state: Toplevel.state, source: Args.src, context: Proof.context} -> 'a -> string) -> unit
    23   datatype markup = Markup | MarkupEnv | Verbatim
    24   val modes: string list Unsynchronized.ref
    25   val eval_antiquote: Scan.lexicon -> Toplevel.state -> Symbol_Pos.text * Position.T -> string
    26   val present_thy: Scan.lexicon -> (string -> string list) -> (markup -> string -> bool) ->
    27     (Toplevel.transition * Toplevel.state) list -> (OuterLex.token, 'a) Source.source -> Buffer.T
    28   val pretty_text: string -> Pretty.T
    29   val pretty_term: Proof.context -> term -> Pretty.T
    30   val pretty_thm: Proof.context -> thm -> Pretty.T
    31   val str_of_source: Args.src -> string
    32   val maybe_pretty_source: ('a -> Pretty.T) -> Args.src -> 'a list -> Pretty.T list
    33   val output: Pretty.T list -> string
    34 end;
    35 
    36 structure ThyOutput: THY_OUTPUT =
    37 struct
    38 
    39 structure T = OuterLex;
    40 structure P = OuterParse;
    41 
    42 
    43 (** global options **)
    44 
    45 val display = Unsynchronized.ref false;
    46 val quotes = Unsynchronized.ref false;
    47 val indent = Unsynchronized.ref 0;
    48 val source = Unsynchronized.ref false;
    49 val break = Unsynchronized.ref false;
    50 
    51 
    52 
    53 (** maintain global antiquotations **)
    54 
    55 local
    56 
    57 val global_commands =
    58   Unsynchronized.ref (Symtab.empty: (Args.src -> Toplevel.state -> string) Symtab.table);
    59 
    60 val global_options =
    61   Unsynchronized.ref (Symtab.empty: (string -> (unit -> string) -> unit -> string) Symtab.table);
    62 
    63 fun add_item kind (name, x) tab =
    64  (if not (Symtab.defined tab name) then ()
    65   else warning ("Redefined document antiquotation " ^ kind ^ ": " ^ quote name);
    66   Symtab.update (name, x) tab);
    67 
    68 in
    69 
    70 fun add_commands xs =
    71   CRITICAL (fn () => Unsynchronized.change global_commands (fold (add_item "command") xs));
    72 fun add_options xs =
    73   CRITICAL (fn () => Unsynchronized.change global_options (fold (add_item "option") xs));
    74 
    75 fun defined_command name = Symtab.defined (! global_commands) name;
    76 fun defined_option name = Symtab.defined (! global_options) name;
    77 
    78 fun command src =
    79   let val ((name, _), pos) = Args.dest_src src in
    80     (case Symtab.lookup (! global_commands) name of
    81       NONE => error ("Unknown document antiquotation: " ^ quote name ^ Position.str_of pos)
    82     | SOME f =>
    83        (Position.report (Markup.doc_antiq name) pos;
    84         (fn state => f src state handle ERROR msg =>
    85           cat_error msg ("The error(s) above occurred in document antiquotation: " ^
    86             quote name ^ Position.str_of pos))))
    87   end;
    88 
    89 fun option (name, s) f () =
    90   (case Symtab.lookup (! global_options) name of
    91     NONE => error ("Unknown document antiquotation option: " ^ quote name)
    92   | SOME opt => opt s f ());
    93 
    94 fun options [] f = f
    95   | options (opt :: opts) f = option opt (options opts f);
    96 
    97 
    98 fun print_antiquotations () =
    99  [Pretty.big_list "document antiquotation commands:"
   100     (map Pretty.str (sort_strings (Symtab.keys (! global_commands)))),
   101   Pretty.big_list "document antiquotation options:"
   102     (map Pretty.str (sort_strings (Symtab.keys (! global_options))))]
   103  |> Pretty.chunks |> Pretty.writeln;
   104 
   105 end;
   106 
   107 fun antiquotation name scan out = add_commands [(name, fn src => fn state =>
   108   let val (x, ctxt) = Args.context_syntax "document antiquotation"
   109     scan src (Toplevel.presentation_context_of state)
   110   in out {source = src, state = state, context = ctxt} x end)];
   111 
   112 
   113 
   114 (** syntax of antiquotations **)
   115 
   116 (* option values *)
   117 
   118 fun boolean "" = true
   119   | boolean "true" = true
   120   | boolean "false" = false
   121   | boolean s = error ("Bad boolean value: " ^ quote s);
   122 
   123 fun integer s =
   124   let
   125     fun int ss =
   126       (case Library.read_int ss of (i, []) => i
   127       | _ => error ("Bad integer value: " ^ quote s));
   128   in (case Symbol.explode s of "-" :: ss => ~ (int ss) | ss => int ss) end;
   129 
   130 
   131 (* outer syntax *)
   132 
   133 local
   134 
   135 val property = P.xname -- Scan.optional (P.$$$ "=" |-- P.!!! P.xname) "";
   136 val properties = Scan.optional (P.$$$ "[" |-- P.!!! (P.enum "," property --| P.$$$ "]")) [];
   137 
   138 in
   139 
   140 val antiq = P.!!! (P.position P.xname -- properties -- Args.parse --| Scan.ahead P.eof)
   141   >> (fn (((x, pos), y), z) => (y, Args.src ((x, z), pos)));
   142 
   143 end;
   144 
   145 
   146 (* eval_antiquote *)
   147 
   148 val modes = Unsynchronized.ref ([]: string list);
   149 
   150 fun eval_antiquote lex state (txt, pos) =
   151   let
   152     fun expand (Antiquote.Text ss) = Symbol_Pos.content ss
   153       | expand (Antiquote.Antiq (ss, (pos, _))) =
   154           let val (opts, src) = T.read_antiq lex antiq (ss, pos) in
   155             options opts (fn () => command src state) ();  (*preview errors!*)
   156             PrintMode.with_modes (! modes @ Latex.modes)
   157               (Output.no_warnings (options opts (fn () => command src state))) ()
   158           end
   159       | expand (Antiquote.Open _) = ""
   160       | expand (Antiquote.Close _) = "";
   161     val ants = Antiquote.read (Symbol_Pos.explode (txt, pos), pos);
   162   in
   163     if Toplevel.is_toplevel state andalso not (forall Antiquote.is_text ants) then
   164       error ("Unknown context -- cannot expand document antiquotations" ^ Position.str_of pos)
   165     else implode (map expand ants)
   166   end;
   167 
   168 
   169 
   170 (** present theory source **)
   171 
   172 (*NB: arranging white space around command spans is a black art.*)
   173 
   174 (* presentation tokens *)
   175 
   176 datatype token =
   177     NoToken
   178   | BasicToken of T.token
   179   | MarkupToken of string * (string * Position.T)
   180   | MarkupEnvToken of string * (string * Position.T)
   181   | VerbatimToken of string * Position.T;
   182 
   183 fun output_token lex state =
   184   let val eval = eval_antiquote lex state in
   185     fn NoToken => ""
   186      | BasicToken tok => Latex.output_basic tok
   187      | MarkupToken (cmd, txt) => Latex.output_markup cmd (eval txt)
   188      | MarkupEnvToken (cmd, txt) => Latex.output_markup_env cmd (eval txt)
   189      | VerbatimToken txt => Latex.output_verbatim (eval txt)
   190   end;
   191 
   192 fun basic_token pred (BasicToken tok) = pred tok
   193   | basic_token _ _ = false;
   194 
   195 val improper_token = basic_token (not o T.is_proper);
   196 val comment_token = basic_token T.is_comment;
   197 val blank_token = basic_token T.is_blank;
   198 val newline_token = basic_token T.is_newline;
   199 
   200 
   201 (* command spans *)
   202 
   203 type command = string * Position.T * string list;   (*name, position, tags*)
   204 type source = (token * (string * int)) list;        (*token, markup flag, meta-comment depth*)
   205 
   206 datatype span = Span of command * (source * source * source * source) * bool;
   207 
   208 fun make_span cmd src =
   209   let
   210     fun take_newline (tok :: toks) =
   211           if newline_token (fst tok) then ([tok], toks, true)
   212           else ([], tok :: toks, false)
   213       | take_newline [] = ([], [], false);
   214     val (((src_prefix, src_main), src_suffix1), (src_suffix2, src_appendix, newline)) =
   215       src
   216       |> take_prefix (improper_token o fst)
   217       ||>> take_suffix (improper_token o fst)
   218       ||>> take_prefix (comment_token o fst)
   219       ||> take_newline;
   220   in Span (cmd, (src_prefix, src_main, src_suffix1 @ src_suffix2, src_appendix), newline) end;
   221 
   222 
   223 (* present spans *)
   224 
   225 local
   226 
   227 fun err_bad_nesting pos =
   228   error ("Bad nesting of commands in presentation" ^ pos);
   229 
   230 fun edge which f (x: string option, y) =
   231   if x = y then I
   232   else (case which (x, y) of NONE => I | SOME txt => Buffer.add (f txt));
   233 
   234 val begin_tag = edge #2 Latex.begin_tag;
   235 val end_tag = edge #1 Latex.end_tag;
   236 fun open_delim delim e = edge #2 Latex.begin_delim e #> delim #> edge #2 Latex.end_delim e;
   237 fun close_delim delim e = edge #1 Latex.begin_delim e #> delim #> edge #1 Latex.end_delim e;
   238 
   239 in
   240 
   241 fun present_span lex default_tags span state state'
   242     (tag_stack, active_tag, newline, buffer, present_cont) =
   243   let
   244     val present = fold (fn (tok, (flag, 0)) =>
   245         Buffer.add (output_token lex state' tok)
   246         #> Buffer.add flag
   247       | _ => I);
   248 
   249     val Span ((cmd_name, cmd_pos, cmd_tags), srcs, span_newline) = span;
   250 
   251     val (tag, tags) = tag_stack;
   252     val tag' = try hd (fold OuterKeyword.update_tags cmd_tags (the_list tag));
   253 
   254     val active_tag' =
   255       if is_some tag' then tag'
   256       else if cmd_name = "end" andalso not (Toplevel.is_toplevel state') then NONE
   257       else try hd (default_tags cmd_name);
   258     val edge = (active_tag, active_tag');
   259 
   260     val newline' =
   261       if is_none active_tag' then span_newline else newline;
   262 
   263     val nesting = Toplevel.level state' - Toplevel.level state;
   264     val tag_stack' =
   265       if nesting = 0 andalso not (Toplevel.is_proof state) then tag_stack
   266       else if nesting >= 0 then (tag', replicate nesting tag @ tags)
   267       else
   268         (case Library.drop (~ nesting - 1, tags) of
   269           tgs :: tgss => (tgs, tgss)
   270         | [] => err_bad_nesting (Position.str_of cmd_pos));
   271 
   272     val buffer' =
   273       buffer
   274       |> end_tag edge
   275       |> close_delim (fst present_cont) edge
   276       |> snd present_cont
   277       |> open_delim (present (#1 srcs)) edge
   278       |> begin_tag edge
   279       |> present (#2 srcs);
   280     val present_cont' =
   281       if newline then (present (#3 srcs), present (#4 srcs))
   282       else (I, present (#3 srcs) #> present (#4 srcs));
   283   in (tag_stack', active_tag', newline', buffer', present_cont') end;
   284 
   285 fun present_trailer ((_, tags), active_tag, _, buffer, present_cont) =
   286   if not (null tags) then err_bad_nesting " at end of theory"
   287   else
   288     buffer
   289     |> end_tag (active_tag, NONE)
   290     |> close_delim (fst present_cont) (active_tag, NONE)
   291     |> snd present_cont;
   292 
   293 end;
   294 
   295 
   296 (* present_thy *)
   297 
   298 datatype markup = Markup | MarkupEnv | Verbatim;
   299 
   300 local
   301 
   302 val space_proper =
   303   Scan.one T.is_blank -- Scan.many T.is_comment -- Scan.one T.is_proper;
   304 
   305 val is_improper = not o (T.is_proper orf T.is_begin_ignore orf T.is_end_ignore);
   306 val improper = Scan.many is_improper;
   307 val improper_end = Scan.repeat (Scan.unless space_proper (Scan.one is_improper));
   308 val blank_end = Scan.repeat (Scan.unless space_proper (Scan.one T.is_blank));
   309 
   310 val opt_newline = Scan.option (Scan.one T.is_newline);
   311 
   312 val ignore =
   313   Scan.depend (fn d => opt_newline |-- Scan.one T.is_begin_ignore
   314     >> pair (d + 1)) ||
   315   Scan.depend (fn d => Scan.one T.is_end_ignore --|
   316     (if d = 0 then Scan.fail_with (K "Bad nesting of meta-comments") else opt_newline)
   317     >> pair (d - 1));
   318 
   319 val tag = (improper -- P.$$$ "%" -- improper) |-- P.!!! (P.tag_name --| blank_end);
   320 
   321 val locale =
   322   Scan.option ((P.$$$ "(" -- improper -- P.$$$ "in") |--
   323     P.!!! (improper |-- P.xname --| (improper -- P.$$$ ")")));
   324 
   325 in
   326 
   327 fun present_thy lex default_tags is_markup command_results src =
   328   let
   329     (* tokens *)
   330 
   331     val ignored = Scan.state --| ignore
   332       >> (fn d => (NONE, (NoToken, ("", d))));
   333 
   334     fun markup mark mk flag = Scan.peek (fn d =>
   335       improper |-- P.position (Scan.one (T.is_kind T.Command andf is_markup mark o T.content_of)) --
   336       Scan.repeat tag --
   337       P.!!!! ((improper -- locale -- improper) |-- P.doc_source --| improper_end)
   338       >> (fn (((tok, pos), tags), txt) =>
   339         let val name = T.content_of tok
   340         in (SOME (name, pos, tags), (mk (name, txt), (flag, d))) end));
   341 
   342     val command = Scan.peek (fn d =>
   343       P.position (Scan.one (T.is_kind T.Command)) --
   344       Scan.repeat tag
   345       >> (fn ((tok, pos), tags) =>
   346         let val name = T.content_of tok
   347         in (SOME (name, pos, tags), (BasicToken tok, (Latex.markup_false, d))) end));
   348 
   349     val cmt = Scan.peek (fn d =>
   350       P.$$$ "--" |-- P.!!!! (improper |-- P.doc_source)
   351       >> (fn txt => (NONE, (MarkupToken ("cmt", txt), ("", d)))));
   352 
   353     val other = Scan.peek (fn d =>
   354        P.not_eof >> (fn tok => (NONE, (BasicToken tok, ("", d)))));
   355 
   356     val token =
   357       ignored ||
   358       markup Markup MarkupToken Latex.markup_true ||
   359       markup MarkupEnv MarkupEnvToken Latex.markup_true ||
   360       markup Verbatim (VerbatimToken o #2) "" ||
   361       command || cmt || other;
   362 
   363 
   364     (* spans *)
   365 
   366     val is_eof = fn (_, (BasicToken x, _)) => T.is_eof x | _ => false;
   367     val stopper = Scan.stopper (K (NONE, (BasicToken T.eof, ("", 0)))) is_eof;
   368 
   369     val cmd = Scan.one (is_some o fst);
   370     val non_cmd = Scan.one (is_none o fst andf not o is_eof) >> #2;
   371 
   372     val comments = Scan.many (comment_token o fst o snd);
   373     val blank = Scan.one (blank_token o fst o snd);
   374     val newline = Scan.one (newline_token o fst o snd);
   375     val before_cmd =
   376       Scan.option (newline -- comments) --
   377       Scan.option (newline -- comments) --
   378       Scan.option (blank -- comments) -- cmd;
   379 
   380     val span =
   381       Scan.repeat non_cmd -- cmd --
   382         Scan.repeat (Scan.unless before_cmd non_cmd) --
   383         Scan.option (newline >> (single o snd))
   384       >> (fn (((toks1, (cmd, tok2)), toks3), tok4) =>
   385           make_span (the cmd) (toks1 @ (tok2 :: (toks3 @ the_default [] tok4))));
   386 
   387     val spans =
   388       src
   389       |> Source.filter (not o T.is_semicolon)
   390       |> Source.source' 0 T.stopper (Scan.error (Scan.bulk token)) NONE
   391       |> Source.source stopper (Scan.error (Scan.bulk span)) NONE
   392       |> Source.exhaust;
   393 
   394 
   395     (* present commands *)
   396 
   397     fun present_command tr span st st' =
   398       Toplevel.setmp_thread_position tr (present_span lex default_tags span st st');
   399 
   400     fun present _ [] = I
   401       | present st (((tr, st'), span) :: rest) = present_command tr span st st' #> present st' rest;
   402   in
   403     if length command_results = length spans then
   404       ((NONE, []), NONE, true, Buffer.empty, (I, I))
   405       |> present Toplevel.toplevel (command_results ~~ spans)
   406       |> present_trailer
   407     else error "Messed-up outer syntax for presentation"
   408   end;
   409 
   410 end;
   411 
   412 
   413 
   414 (** setup default output **)
   415 
   416 (* options *)
   417 
   418 val _ = add_options
   419  [("show_types", Library.setmp Syntax.show_types o boolean),
   420   ("show_sorts", Library.setmp Syntax.show_sorts o boolean),
   421   ("show_structs", Library.setmp show_structs o boolean),
   422   ("show_question_marks", Library.setmp show_question_marks o boolean),
   423   ("long_names", Library.setmp NameSpace.long_names o boolean),
   424   ("short_names", Library.setmp NameSpace.short_names o boolean),
   425   ("unique_names", Library.setmp NameSpace.unique_names o boolean),
   426   ("eta_contract", Library.setmp Syntax.eta_contract o boolean),
   427   ("display", Library.setmp display o boolean),
   428   ("break", Library.setmp break o boolean),
   429   ("quotes", Library.setmp quotes o boolean),
   430   ("mode", fn s => fn f => PrintMode.with_modes [s] f),
   431   ("margin", Pretty.setmp_margin o integer),
   432   ("indent", Library.setmp indent o integer),
   433   ("source", Library.setmp source o boolean),
   434   ("goals_limit", Library.setmp goals_limit o integer)];
   435 
   436 
   437 (* basic pretty printing *)
   438 
   439 fun tweak_line s =
   440   if ! display then s else Symbol.strip_blanks s;
   441 
   442 val pretty_text = Pretty.chunks o map Pretty.str o map tweak_line o Library.split_lines;
   443 
   444 fun pretty_term ctxt t = Syntax.pretty_term (Variable.auto_fixes t ctxt) t;
   445 
   446 fun pretty_term_abbrev ctxt t = ProofContext.pretty_term_abbrev (Variable.auto_fixes t ctxt) t;
   447 
   448 fun pretty_term_typ ctxt t =
   449   Syntax.pretty_term ctxt (TypeInfer.constrain (Term.fastype_of t) t);
   450 
   451 fun pretty_term_typeof ctxt = Syntax.pretty_typ ctxt o Term.fastype_of;
   452 
   453 fun pretty_const ctxt c =
   454   let
   455     val t = Const (c, Consts.type_scheme (ProofContext.consts_of ctxt) c)
   456       handle TYPE (msg, _, _) => error msg;
   457     val ([t'], _) = Variable.import_terms true [t] ctxt;
   458   in pretty_term ctxt t' end;
   459 
   460 fun pretty_abbrev ctxt s =
   461   let
   462     val t = Syntax.parse_term ctxt s |> singleton (ProofContext.standard_infer_types ctxt);
   463     fun err () = error ("Abbreviated constant expected: " ^ Syntax.string_of_term ctxt t);
   464     val (head, args) = Term.strip_comb t;
   465     val (c, T) = Term.dest_Const head handle TERM _ => err ();
   466     val (U, u) = Consts.the_abbreviation (ProofContext.consts_of ctxt) c
   467       handle TYPE _ => err ();
   468     val t' = Term.betapplys (Envir.expand_atom T (U, u), args);
   469   in pretty_term_abbrev ctxt (Logic.mk_equals (t, t')) end;
   470 
   471 fun pretty_thm ctxt = pretty_term ctxt o Thm.full_prop_of;
   472 
   473 fun pretty_term_style ctxt (style, t) =
   474   pretty_term ctxt (style t);
   475 
   476 fun pretty_thm_style ctxt (style, th) =
   477   pretty_term_style ctxt (style, Thm.full_prop_of th);
   478 
   479 fun pretty_prf full ctxt = ProofSyntax.pretty_proof_of ctxt full;
   480 
   481 fun pretty_theory ctxt name =
   482   (Theory.requires (ProofContext.theory_of ctxt) name "presentation"; Pretty.str name);
   483 
   484 
   485 (* default output *)
   486 
   487 val str_of_source = space_implode " " o map T.unparse o #2 o #1 o Args.dest_src;
   488 
   489 fun maybe_pretty_source pretty src xs =
   490   map pretty xs  (*always pretty in order to exhibit errors!*)
   491   |> (if ! source then K [pretty_text (str_of_source src)] else I);
   492 
   493 fun output prts =
   494   prts
   495   |> (if ! quotes then map Pretty.quote else I)
   496   |> (if ! display then
   497     map (Output.output o Pretty.string_of o Pretty.indent (! indent))
   498     #> space_implode "\\isasep\\isanewline%\n"
   499     #> enclose "\\begin{isabelle}%\n" "%\n\\end{isabelle}"
   500   else
   501     map (Output.output o (if ! break then Pretty.string_of else Pretty.str_of))
   502     #> space_implode "\\isasep\\isanewline%\n"
   503     #> enclose "\\isa{" "}");
   504 
   505 
   506 
   507 (** concrete antiquotations **)
   508 
   509 (* basic entities *)
   510 
   511 local
   512 
   513 fun basic_entities name scan pretty = antiquotation name scan
   514   (fn {source, context, ...} => output o maybe_pretty_source (pretty context) source);
   515 
   516 fun basic_entities_style name scan pretty = antiquotation name scan
   517   (fn {source, context, ...} => fn (style, xs) =>
   518     output (maybe_pretty_source (fn x => pretty context (style, x)) source xs));
   519 
   520 fun basic_entity name scan = basic_entities name (scan >> single);
   521 
   522 in
   523 
   524 val _ = basic_entities_style "thm" (Term_Style.parse -- Attrib.thms) pretty_thm_style;
   525 val _ = basic_entities_style "thm_style" (Term_Style.parse_bare -- Attrib.thms) pretty_thm_style;
   526 val _ = basic_entity "prop" (Term_Style.parse -- Args.prop) pretty_term_style;
   527 val _ = basic_entity "term" (Term_Style.parse -- Args.term) pretty_term_style;
   528 val _ = basic_entity "term_style" (Term_Style.parse_bare -- Args.term) pretty_term_style;
   529 val _ = basic_entity "term_type" Args.term pretty_term_typ;
   530 val _ = basic_entity "typeof" Args.term pretty_term_typeof;
   531 val _ = basic_entity "const" Args.const_proper pretty_const;
   532 val _ = basic_entity "abbrev" (Scan.lift Args.name_source) pretty_abbrev;
   533 val _ = basic_entity "typ" Args.typ_abbrev Syntax.pretty_typ;
   534 val _ = basic_entity "text" (Scan.lift Args.name) (K pretty_text);
   535 val _ = basic_entities "prf" Attrib.thms (pretty_prf false);
   536 val _ = basic_entities "full_prf" Attrib.thms (pretty_prf true);
   537 val _ = basic_entity "theory" (Scan.lift Args.name) pretty_theory;
   538 
   539 end;
   540 
   541 
   542 (* goal state *)
   543 
   544 local
   545 
   546 fun proof_state state =
   547   (case try Toplevel.proof_of state of
   548     SOME prf => prf
   549   | _ => error "No proof state");
   550 
   551 fun goal_state name main_goal = antiquotation name (Scan.succeed ())
   552   (fn {state, ...} => fn () => output
   553     [Pretty.chunks (Proof.pretty_goals main_goal (proof_state state))]);
   554 
   555 in
   556 
   557 val _ = goal_state "goals" true;
   558 val _ = goal_state "subgoals" false;
   559 
   560 end;
   561 
   562 
   563 (* embedded lemma *)
   564 
   565 val _ = OuterKeyword.keyword "by";
   566 
   567 val _ = antiquotation "lemma"
   568   (Args.prop -- Scan.lift (Args.$$$ "by" |-- Method.parse -- Scan.option Method.parse))
   569   (fn {source, context, ...} => fn (prop, methods) =>
   570     let
   571       val prop_src =
   572         (case Args.dest_src source of ((a, arg :: _), pos) => Args.src ((a, [arg]), pos));
   573       val _ = context
   574         |> Proof.theorem_i NONE (K I) [[(prop, [])]]
   575         |> Proof.global_terminal_proof methods;
   576     in output (maybe_pretty_source (pretty_term context) prop_src [prop]) end);
   577 
   578 
   579 (* ML text *)
   580 
   581 local
   582 
   583 fun ml_text name ml = antiquotation name (Scan.lift Args.name_source_position)
   584   (fn {context, ...} => fn (txt, pos) =>
   585    (ML_Context.eval_in (SOME context) false pos (ml txt);
   586     Symbol_Pos.content (Symbol_Pos.explode (txt, pos))
   587     |> (if ! quotes then quote else I)
   588     |> (if ! display then enclose "\\begin{verbatim}\n" "\n\\end{verbatim}"
   589     else
   590       split_lines
   591       #> map (space_implode "\\verb,|," o map (enclose "\\verb|" "|") o space_explode "|")
   592       #> space_implode "\\isasep\\isanewline%\n")));
   593 
   594 in
   595 
   596 val _ = ml_text "ML" (fn txt => "fn _ => (" ^ txt ^ ");");
   597 val _ = ml_text "ML_type" (fn txt => "val _ = NONE : (" ^ txt ^ ") option;");
   598 val _ = ml_text "ML_struct" (fn txt => "functor XXX() = struct structure XX = " ^ txt ^ " end;");
   599 val _ = ml_text "ML_functor" (K "");  (*no check!*)
   600 val _ = ml_text "ML_text" (K "");
   601 
   602 end;
   603 
   604 end;