src/HOL/Library/Quotient_List.thy
author huffman
Sun Apr 22 11:05:04 2012 +0200 (2012-04-22)
changeset 47660 7a5c681c0265
parent 47650 33ecf14d5ee9
child 47777 f29e7dcd7c40
permissions -rw-r--r--
new example theory for quotient/transfer
     1 (*  Title:      HOL/Library/Quotient_List.thy
     2     Author:     Cezary Kaliszyk, Christian Urban and Brian Huffman
     3 *)
     4 
     5 header {* Quotient infrastructure for the list type *}
     6 
     7 theory Quotient_List
     8 imports Main Quotient_Set
     9 begin
    10 
    11 subsection {* Relator for list type *}
    12 
    13 lemma map_id [id_simps]:
    14   "map id = id"
    15   by (fact List.map.id)
    16 
    17 lemma list_all2_eq [id_simps, relator_eq]:
    18   "list_all2 (op =) = (op =)"
    19 proof (rule ext)+
    20   fix xs ys
    21   show "list_all2 (op =) xs ys \<longleftrightarrow> xs = ys"
    22     by (induct xs ys rule: list_induct2') simp_all
    23 qed
    24 
    25 lemma list_all2_OO: "list_all2 (A OO B) = list_all2 A OO list_all2 B"
    26 proof (intro ext iffI)
    27   fix xs ys
    28   assume "list_all2 (A OO B) xs ys"
    29   thus "(list_all2 A OO list_all2 B) xs ys"
    30     unfolding OO_def
    31     by (induct, simp, simp add: list_all2_Cons1 list_all2_Cons2, fast)
    32 next
    33   fix xs ys
    34   assume "(list_all2 A OO list_all2 B) xs ys"
    35   then obtain zs where "list_all2 A xs zs" and "list_all2 B zs ys" ..
    36   thus "list_all2 (A OO B) xs ys"
    37     by (induct arbitrary: ys, simp, clarsimp simp add: list_all2_Cons1, fast)
    38 qed
    39 
    40 lemma list_reflp:
    41   assumes "reflp R"
    42   shows "reflp (list_all2 R)"
    43 proof (rule reflpI)
    44   from assms have *: "\<And>xs. R xs xs" by (rule reflpE)
    45   fix xs
    46   show "list_all2 R xs xs"
    47     by (induct xs) (simp_all add: *)
    48 qed
    49 
    50 lemma list_symp:
    51   assumes "symp R"
    52   shows "symp (list_all2 R)"
    53 proof (rule sympI)
    54   from assms have *: "\<And>xs ys. R xs ys \<Longrightarrow> R ys xs" by (rule sympE)
    55   fix xs ys
    56   assume "list_all2 R xs ys"
    57   then show "list_all2 R ys xs"
    58     by (induct xs ys rule: list_induct2') (simp_all add: *)
    59 qed
    60 
    61 lemma list_transp:
    62   assumes "transp R"
    63   shows "transp (list_all2 R)"
    64 proof (rule transpI)
    65   from assms have *: "\<And>xs ys zs. R xs ys \<Longrightarrow> R ys zs \<Longrightarrow> R xs zs" by (rule transpE)
    66   fix xs ys zs
    67   assume "list_all2 R xs ys" and "list_all2 R ys zs"
    68   then show "list_all2 R xs zs"
    69     by (induct arbitrary: zs) (auto simp: list_all2_Cons1 intro: *)
    70 qed
    71 
    72 lemma list_equivp [quot_equiv]:
    73   "equivp R \<Longrightarrow> equivp (list_all2 R)"
    74   by (blast intro: equivpI list_reflp list_symp list_transp elim: equivpE)
    75 
    76 lemma right_total_list_all2 [transfer_rule]:
    77   "right_total R \<Longrightarrow> right_total (list_all2 R)"
    78   unfolding right_total_def
    79   by (rule allI, induct_tac y, simp, simp add: list_all2_Cons2)
    80 
    81 lemma right_unique_list_all2 [transfer_rule]:
    82   "right_unique R \<Longrightarrow> right_unique (list_all2 R)"
    83   unfolding right_unique_def
    84   apply (rule allI, rename_tac xs, induct_tac xs)
    85   apply (auto simp add: list_all2_Cons1)
    86   done
    87 
    88 lemma bi_total_list_all2 [transfer_rule]:
    89   "bi_total A \<Longrightarrow> bi_total (list_all2 A)"
    90   unfolding bi_total_def
    91   apply safe
    92   apply (rename_tac xs, induct_tac xs, simp, simp add: list_all2_Cons1)
    93   apply (rename_tac ys, induct_tac ys, simp, simp add: list_all2_Cons2)
    94   done
    95 
    96 lemma bi_unique_list_all2 [transfer_rule]:
    97   "bi_unique A \<Longrightarrow> bi_unique (list_all2 A)"
    98   unfolding bi_unique_def
    99   apply (rule conjI)
   100   apply (rule allI, rename_tac xs, induct_tac xs)
   101   apply (simp, force simp add: list_all2_Cons1)
   102   apply (subst (2) all_comm, subst (1) all_comm)
   103   apply (rule allI, rename_tac xs, induct_tac xs)
   104   apply (simp, force simp add: list_all2_Cons2)
   105   done
   106 
   107 subsection {* Transfer rules for transfer package *}
   108 
   109 lemma Nil_transfer [transfer_rule]: "(list_all2 A) [] []"
   110   by simp
   111 
   112 lemma Cons_transfer [transfer_rule]:
   113   "(A ===> list_all2 A ===> list_all2 A) Cons Cons"
   114   unfolding fun_rel_def by simp
   115 
   116 lemma list_case_transfer [transfer_rule]:
   117   "(B ===> (A ===> list_all2 A ===> B) ===> list_all2 A ===> B)
   118     list_case list_case"
   119   unfolding fun_rel_def by (simp split: list.split)
   120 
   121 lemma list_rec_transfer [transfer_rule]:
   122   "(B ===> (A ===> list_all2 A ===> B ===> B) ===> list_all2 A ===> B)
   123     list_rec list_rec"
   124   unfolding fun_rel_def by (clarify, erule list_all2_induct, simp_all)
   125 
   126 lemma map_transfer [transfer_rule]:
   127   "((A ===> B) ===> list_all2 A ===> list_all2 B) map map"
   128   unfolding List.map_def by transfer_prover
   129 
   130 lemma append_transfer [transfer_rule]:
   131   "(list_all2 A ===> list_all2 A ===> list_all2 A) append append"
   132   unfolding List.append_def by transfer_prover
   133 
   134 lemma filter_transfer [transfer_rule]:
   135   "((A ===> op =) ===> list_all2 A ===> list_all2 A) filter filter"
   136   unfolding List.filter_def by transfer_prover
   137 
   138 lemma foldr_transfer [transfer_rule]:
   139   "((A ===> B ===> B) ===> list_all2 A ===> B ===> B) foldr foldr"
   140   unfolding List.foldr_def by transfer_prover
   141 
   142 lemma foldl_transfer [transfer_rule]:
   143   "((B ===> A ===> B) ===> B ===> list_all2 A ===> B) foldl foldl"
   144   unfolding List.foldl_def by transfer_prover
   145 
   146 lemma concat_transfer [transfer_rule]:
   147   "(list_all2 (list_all2 A) ===> list_all2 A) concat concat"
   148   unfolding List.concat_def by transfer_prover
   149 
   150 lemma drop_transfer [transfer_rule]:
   151   "(op = ===> list_all2 A ===> list_all2 A) drop drop"
   152   unfolding List.drop_def by transfer_prover
   153 
   154 lemma take_transfer [transfer_rule]:
   155   "(op = ===> list_all2 A ===> list_all2 A) take take"
   156   unfolding List.take_def by transfer_prover
   157 
   158 lemma length_transfer [transfer_rule]:
   159   "(list_all2 A ===> op =) length length"
   160   unfolding list_size_overloaded_def by transfer_prover
   161 
   162 lemma list_all_transfer [transfer_rule]:
   163   "((A ===> op =) ===> list_all2 A ===> op =) list_all list_all"
   164   unfolding fun_rel_def by (clarify, erule list_all2_induct, simp_all)
   165 
   166 lemma list_all2_transfer [transfer_rule]:
   167   "((A ===> B ===> op =) ===> list_all2 A ===> list_all2 B ===> op =)
   168     list_all2 list_all2"
   169   apply (rule fun_relI, rule fun_relI, erule list_all2_induct)
   170   apply (rule fun_relI, erule list_all2_induct, simp, simp)
   171   apply (rule fun_relI, erule list_all2_induct [of B])
   172   apply (simp, simp add: fun_rel_def)
   173   done
   174 
   175 lemma set_transfer [transfer_rule]:
   176   "(list_all2 A ===> set_rel A) set set"
   177   unfolding set_def by transfer_prover
   178 
   179 subsection {* Setup for lifting package *}
   180 
   181 lemma Quotient_list:
   182   assumes "Quotient R Abs Rep T"
   183   shows "Quotient (list_all2 R) (map Abs) (map Rep) (list_all2 T)"
   184 proof (unfold Quotient_alt_def, intro conjI allI impI)
   185   from assms have 1: "\<And>x y. T x y \<Longrightarrow> Abs x = y"
   186     unfolding Quotient_alt_def by simp
   187   fix xs ys assume "list_all2 T xs ys" thus "map Abs xs = ys"
   188     by (induct, simp, simp add: 1)
   189 next
   190   from assms have 2: "\<And>x. T (Rep x) x"
   191     unfolding Quotient_alt_def by simp
   192   fix xs show "list_all2 T (map Rep xs) xs"
   193     by (induct xs, simp, simp add: 2)
   194 next
   195   from assms have 3: "\<And>x y. R x y \<longleftrightarrow> T x (Abs x) \<and> T y (Abs y) \<and> Abs x = Abs y"
   196     unfolding Quotient_alt_def by simp
   197   fix xs ys show "list_all2 R xs ys \<longleftrightarrow> list_all2 T xs (map Abs xs) \<and>
   198     list_all2 T ys (map Abs ys) \<and> map Abs xs = map Abs ys"
   199     by (induct xs ys rule: list_induct2', simp_all, metis 3)
   200 qed
   201 
   202 declare [[map list = (list_all2, Quotient_list)]]
   203 
   204 lemma list_invariant_commute [invariant_commute]:
   205   "list_all2 (Lifting.invariant P) = Lifting.invariant (list_all P)"
   206   apply (simp add: fun_eq_iff list_all2_def list_all_iff Lifting.invariant_def Ball_def) 
   207   apply (intro allI) 
   208   apply (induct_tac rule: list_induct2') 
   209   apply simp_all 
   210   apply metis
   211 done
   212 
   213 subsection {* Rules for quotient package *}
   214 
   215 lemma list_quotient3 [quot_thm]:
   216   assumes "Quotient3 R Abs Rep"
   217   shows "Quotient3 (list_all2 R) (map Abs) (map Rep)"
   218 proof (rule Quotient3I)
   219   from assms have "\<And>x. Abs (Rep x) = x" by (rule Quotient3_abs_rep)
   220   then show "\<And>xs. map Abs (map Rep xs) = xs" by (simp add: comp_def)
   221 next
   222   from assms have "\<And>x y. R (Rep x) (Rep y) \<longleftrightarrow> x = y" by (rule Quotient3_rel_rep)
   223   then show "\<And>xs. list_all2 R (map Rep xs) (map Rep xs)"
   224     by (simp add: list_all2_map1 list_all2_map2 list_all2_eq)
   225 next
   226   fix xs ys
   227   from assms have "\<And>x y. R x x \<and> R y y \<and> Abs x = Abs y \<longleftrightarrow> R x y" by (rule Quotient3_rel)
   228   then show "list_all2 R xs ys \<longleftrightarrow> list_all2 R xs xs \<and> list_all2 R ys ys \<and> map Abs xs = map Abs ys"
   229     by (induct xs ys rule: list_induct2') auto
   230 qed
   231 
   232 declare [[mapQ3 list = (list_all2, list_quotient3)]]
   233 
   234 lemma cons_prs [quot_preserve]:
   235   assumes q: "Quotient3 R Abs Rep"
   236   shows "(Rep ---> (map Rep) ---> (map Abs)) (op #) = (op #)"
   237   by (auto simp add: fun_eq_iff comp_def Quotient3_abs_rep [OF q])
   238 
   239 lemma cons_rsp [quot_respect]:
   240   assumes q: "Quotient3 R Abs Rep"
   241   shows "(R ===> list_all2 R ===> list_all2 R) (op #) (op #)"
   242   by auto
   243 
   244 lemma nil_prs [quot_preserve]:
   245   assumes q: "Quotient3 R Abs Rep"
   246   shows "map Abs [] = []"
   247   by simp
   248 
   249 lemma nil_rsp [quot_respect]:
   250   assumes q: "Quotient3 R Abs Rep"
   251   shows "list_all2 R [] []"
   252   by simp
   253 
   254 lemma map_prs_aux:
   255   assumes a: "Quotient3 R1 abs1 rep1"
   256   and     b: "Quotient3 R2 abs2 rep2"
   257   shows "(map abs2) (map ((abs1 ---> rep2) f) (map rep1 l)) = map f l"
   258   by (induct l)
   259      (simp_all add: Quotient3_abs_rep[OF a] Quotient3_abs_rep[OF b])
   260 
   261 lemma map_prs [quot_preserve]:
   262   assumes a: "Quotient3 R1 abs1 rep1"
   263   and     b: "Quotient3 R2 abs2 rep2"
   264   shows "((abs1 ---> rep2) ---> (map rep1) ---> (map abs2)) map = map"
   265   and   "((abs1 ---> id) ---> map rep1 ---> id) map = map"
   266   by (simp_all only: fun_eq_iff map_prs_aux[OF a b] comp_def)
   267     (simp_all add: Quotient3_abs_rep[OF a] Quotient3_abs_rep[OF b])
   268 
   269 lemma map_rsp [quot_respect]:
   270   assumes q1: "Quotient3 R1 Abs1 Rep1"
   271   and     q2: "Quotient3 R2 Abs2 Rep2"
   272   shows "((R1 ===> R2) ===> (list_all2 R1) ===> list_all2 R2) map map"
   273   and   "((R1 ===> op =) ===> (list_all2 R1) ===> op =) map map"
   274   unfolding list_all2_eq [symmetric] by (rule map_transfer)+
   275 
   276 lemma foldr_prs_aux:
   277   assumes a: "Quotient3 R1 abs1 rep1"
   278   and     b: "Quotient3 R2 abs2 rep2"
   279   shows "abs2 (foldr ((abs1 ---> abs2 ---> rep2) f) (map rep1 l) (rep2 e)) = foldr f l e"
   280   by (induct l) (simp_all add: Quotient3_abs_rep[OF a] Quotient3_abs_rep[OF b])
   281 
   282 lemma foldr_prs [quot_preserve]:
   283   assumes a: "Quotient3 R1 abs1 rep1"
   284   and     b: "Quotient3 R2 abs2 rep2"
   285   shows "((abs1 ---> abs2 ---> rep2) ---> (map rep1) ---> rep2 ---> abs2) foldr = foldr"
   286   apply (simp add: fun_eq_iff)
   287   by (simp only: fun_eq_iff foldr_prs_aux[OF a b])
   288      (simp)
   289 
   290 lemma foldl_prs_aux:
   291   assumes a: "Quotient3 R1 abs1 rep1"
   292   and     b: "Quotient3 R2 abs2 rep2"
   293   shows "abs1 (foldl ((abs1 ---> abs2 ---> rep1) f) (rep1 e) (map rep2 l)) = foldl f e l"
   294   by (induct l arbitrary:e) (simp_all add: Quotient3_abs_rep[OF a] Quotient3_abs_rep[OF b])
   295 
   296 lemma foldl_prs [quot_preserve]:
   297   assumes a: "Quotient3 R1 abs1 rep1"
   298   and     b: "Quotient3 R2 abs2 rep2"
   299   shows "((abs1 ---> abs2 ---> rep1) ---> rep1 ---> (map rep2) ---> abs1) foldl = foldl"
   300   by (simp add: fun_eq_iff foldl_prs_aux [OF a b])
   301 
   302 (* induct_tac doesn't accept 'arbitrary', so we manually 'spec' *)
   303 lemma foldl_rsp[quot_respect]:
   304   assumes q1: "Quotient3 R1 Abs1 Rep1"
   305   and     q2: "Quotient3 R2 Abs2 Rep2"
   306   shows "((R1 ===> R2 ===> R1) ===> R1 ===> list_all2 R2 ===> R1) foldl foldl"
   307   by (rule foldl_transfer)
   308 
   309 lemma foldr_rsp[quot_respect]:
   310   assumes q1: "Quotient3 R1 Abs1 Rep1"
   311   and     q2: "Quotient3 R2 Abs2 Rep2"
   312   shows "((R1 ===> R2 ===> R2) ===> list_all2 R1 ===> R2 ===> R2) foldr foldr"
   313   by (rule foldr_transfer)
   314 
   315 lemma list_all2_rsp:
   316   assumes r: "\<forall>x y. R x y \<longrightarrow> (\<forall>a b. R a b \<longrightarrow> S x a = T y b)"
   317   and l1: "list_all2 R x y"
   318   and l2: "list_all2 R a b"
   319   shows "list_all2 S x a = list_all2 T y b"
   320   using l1 l2
   321   by (induct arbitrary: a b rule: list_all2_induct,
   322     auto simp: list_all2_Cons1 list_all2_Cons2 r)
   323 
   324 lemma [quot_respect]:
   325   "((R ===> R ===> op =) ===> list_all2 R ===> list_all2 R ===> op =) list_all2 list_all2"
   326   by (rule list_all2_transfer)
   327 
   328 lemma [quot_preserve]:
   329   assumes a: "Quotient3 R abs1 rep1"
   330   shows "((abs1 ---> abs1 ---> id) ---> map rep1 ---> map rep1 ---> id) list_all2 = list_all2"
   331   apply (simp add: fun_eq_iff)
   332   apply clarify
   333   apply (induct_tac xa xb rule: list_induct2')
   334   apply (simp_all add: Quotient3_abs_rep[OF a])
   335   done
   336 
   337 lemma [quot_preserve]:
   338   assumes a: "Quotient3 R abs1 rep1"
   339   shows "(list_all2 ((rep1 ---> rep1 ---> id) R) l m) = (l = m)"
   340   by (induct l m rule: list_induct2') (simp_all add: Quotient3_rel_rep[OF a])
   341 
   342 lemma list_all2_find_element:
   343   assumes a: "x \<in> set a"
   344   and b: "list_all2 R a b"
   345   shows "\<exists>y. (y \<in> set b \<and> R x y)"
   346   using b a by induct auto
   347 
   348 lemma list_all2_refl:
   349   assumes a: "\<And>x y. R x y = (R x = R y)"
   350   shows "list_all2 R x x"
   351   by (induct x) (auto simp add: a)
   352 
   353 end