src/Pure/goal.ML
author wenzelm
Sun Jul 30 21:28:52 2006 +0200 (2006-07-30)
changeset 20260 990dbc007ca6
parent 20250 c3f209752749
child 20290 3f886c176c9b
permissions -rw-r--r--
Thm.adjust_maxidx;
     1 (*  Title:      Pure/goal.ML
     2     ID:         $Id$
     3     Author:     Makarius and Lawrence C Paulson
     4 
     5 Goals in tactical theorem proving.
     6 *)
     7 
     8 signature BASIC_GOAL =
     9 sig
    10   val SELECT_GOAL: tactic -> int -> tactic
    11 end;
    12 
    13 signature GOAL =
    14 sig
    15   include BASIC_GOAL
    16   val init: cterm -> thm
    17   val protect: thm -> thm
    18   val conclude: thm -> thm
    19   val finish: thm -> thm
    20   val compose_hhf: thm -> int -> thm -> thm Seq.seq
    21   val compose_hhf_tac: thm -> int -> tactic
    22   val comp_hhf: thm -> thm -> thm
    23   val prove_raw: cterm list -> cterm -> (thm list -> tactic) -> thm
    24   val prove_multi: Context.proof -> string list -> term list -> term list ->
    25     ({prems: thm list, context: Context.proof} -> tactic) -> thm list
    26   val prove: Context.proof -> string list -> term list -> term ->
    27     ({prems: thm list, context: Context.proof} -> tactic) -> thm
    28   val prove_global: theory -> string list -> term list -> term -> (thm list -> tactic) -> thm
    29   val extract: int -> int -> thm -> thm Seq.seq
    30   val retrofit: int -> int -> thm -> thm -> thm Seq.seq
    31 end;
    32 
    33 structure Goal: GOAL =
    34 struct
    35 
    36 (** goals **)
    37 
    38 (*
    39   -------- (init)
    40   C ==> #C
    41 *)
    42 fun init ct = Drule.instantiate' [] [SOME ct] Drule.protectI;
    43 
    44 (*
    45    C
    46   --- (protect)
    47   #C
    48 *)
    49 fun protect th = th COMP Drule.incr_indexes th Drule.protectI;
    50 
    51 (*
    52   A ==> ... ==> #C
    53   ---------------- (conclude)
    54   A ==> ... ==> C
    55 *)
    56 fun conclude th =
    57   (case SINGLE (Thm.compose_no_flatten false (th, Thm.nprems_of th) 1)
    58       (Drule.incr_indexes th Drule.protectD) of
    59     SOME th' => th'
    60   | NONE => raise THM ("Failed to conclude goal", 0, [th]));
    61 
    62 (*
    63   #C
    64   --- (finish)
    65    C
    66 *)
    67 fun finish th =
    68   (case Thm.nprems_of th of
    69     0 => conclude th
    70   | n => raise THM ("Proof failed.\n" ^
    71       Pretty.string_of (Pretty.chunks (Display.pretty_goals n th)) ^
    72       ("\n" ^ string_of_int n ^ " unsolved goal(s)!"), 0, [th]));
    73 
    74 
    75 
    76 (** results **)
    77 
    78 (* composition of normal results *)
    79 
    80 fun compose_hhf tha i thb =
    81   Thm.bicompose false (false, Drule.lift_all (Thm.cprem_of thb i) tha, 0) i thb;
    82 
    83 fun compose_hhf_tac th i = PRIMSEQ (compose_hhf th i);
    84 
    85 fun comp_hhf tha thb =
    86   (case Seq.chop 2 (compose_hhf tha 1 thb) of
    87     ([th], _) => th
    88   | ([], _) => raise THM ("comp_hhf: no unifiers", 1, [tha, thb])
    89   | _  => raise THM ("comp_hhf: multiple unifiers", 1, [tha, thb]));
    90 
    91 
    92 
    93 (** tactical theorem proving **)
    94 
    95 (* prove_raw -- no checks, no normalization of result! *)
    96 
    97 fun prove_raw casms cprop tac =
    98   (case SINGLE (tac (map Assumption.assume casms)) (init cprop) of
    99     SOME th => Drule.implies_intr_list casms (finish th)
   100   | NONE => error "Tactic failed.");
   101 
   102 
   103 (* prove_multi *)
   104 
   105 fun prove_multi ctxt xs asms props tac =
   106   let
   107     val thy = Context.theory_of_proof ctxt;
   108     val string_of_term = Sign.string_of_term thy;
   109 
   110     fun err msg = cat_error msg
   111       ("The error(s) above occurred for the goal statement:\n" ^
   112         string_of_term (Logic.list_implies (asms, Logic.mk_conjunction_list props)));
   113 
   114     fun cert_safe t = Thm.cterm_of thy (Envir.beta_norm (Term.no_dummy_patterns t))
   115       handle TERM (msg, _) => err msg | TYPE (msg, _, _) => err msg;
   116     val casms = map cert_safe asms;
   117     val cprops = map cert_safe props;
   118 
   119     val (prems, ctxt') = ctxt
   120       |> Variable.add_fixes_direct xs
   121       |> fold Variable.declare_internal (asms @ props)
   122       |> Assumption.add_assumes casms;
   123 
   124     val goal = init (Conjunction.mk_conjunction_list cprops);
   125     val res =
   126       (case SINGLE (tac {prems = prems, context = ctxt'}) goal of
   127         NONE => err "Tactic failed."
   128       | SOME res => res);
   129     val [results] = Conjunction.elim_precise [length props] (finish res)
   130       handle THM (msg, _, _) => err msg;
   131     val _ = Unify.matches_list thy (map Thm.term_of cprops) (map Thm.prop_of results)
   132       orelse err ("Proved a different theorem: " ^ string_of_term (Thm.prop_of res));
   133   in
   134     results
   135     |> (Seq.hd o Assumption.exports false ctxt' ctxt)
   136     |> Variable.export ctxt' ctxt
   137     |> map Drule.zero_var_indexes
   138   end;
   139 
   140 
   141 (* prove *)
   142 
   143 fun prove ctxt xs asms prop tac = hd (prove_multi ctxt xs asms [prop] tac);
   144 
   145 fun prove_global thy xs asms prop tac =
   146   Drule.standard (prove (Context.init_proof thy) xs asms prop (fn {prems, ...} => tac prems));
   147 
   148 
   149 
   150 (** local goal states **)
   151 
   152 fun extract i n st =
   153   (if i < 1 orelse n < 1 orelse i + n - 1 > Thm.nprems_of st then Seq.empty
   154    else if n = 1 then Seq.single (Thm.cprem_of st i)
   155    else Seq.single (foldr1 Conjunction.mk_conjunction (map (Thm.cprem_of st) (i upto i + n - 1))))
   156   |> Seq.map (Thm.adjust_maxidx_cterm ~1 #> init);
   157 
   158 fun retrofit i n st' st =
   159   (if n = 1 then st
   160    else st |> Drule.rotate_prems (i - 1) |> Conjunction.uncurry n |> Drule.rotate_prems (1 - i))
   161   |> Thm.compose_no_flatten false (conclude st', Thm.nprems_of st') i;
   162 
   163 fun SELECT_GOAL tac i st =
   164   if Thm.nprems_of st = 1 andalso i = 1 then tac st
   165   else Seq.lifts (retrofit i 1) (Seq.maps tac (extract i 1 st)) st;
   166 
   167 end;
   168 
   169 structure BasicGoal: BASIC_GOAL = Goal;
   170 open BasicGoal;